config-scripts/cups-directories.m4

   1 dnl
   2 dnl "$Id: cups-directories.m4 7799 2008-07-25 20:06:08Z mike $"
   3 dnl
   4 dnl   Directory stuff for the Common UNIX Printing System (CUPS).
   5 dnl
   6 dnl   Copyright 2007 by Apple Inc.
   7 dnl   Copyright 1997-2007 by Easy Software Products, all rights reserved.
   8 dnl
   9 dnl   These coded instructions, statements, and computer programs are the
  10 dnl   property of Apple Inc. and are protected by Federal copyright
  11 dnl   law.  Distribution and use rights are outlined in the file "LICENSE.txt"
  12 dnl   which should have been included with this file.  If this file is
  13 dnl   file is missing or damaged, see the license at "http://www.cups.org/".
  14 dnl
  15
  16 AC_PREFIX_DEFAULT(/)
  17
  18 dnl Fix "prefix" variable if it hasn't been specified...
  19 if test "$prefix" = "NONE"; then
  20         prefix="/"
  21 fi
  22
  23 dnl Fix "exec_prefix" variable if it hasn't been specified...
  24 if test "$exec_prefix" = "NONE"; then
  25         if test "$prefix" = "/"; then
  26                 exec_prefix="/usr"
  27         else
  28                 exec_prefix="$prefix"
  29         fi
  30 fi
  31
  32 dnl Fix "bindir" variable...
  33 if test "$bindir" = "\${exec_prefix}/bin"; then
  34         bindir="$exec_prefix/bin"
  35 fi
  36
  37 AC_DEFINE_UNQUOTED(CUPS_BINDIR, "$bindir")
  38
  39 dnl Fix "sbindir" variable...
  40 if test "$sbindir" = "\${exec_prefix}/sbin"; then
  41         sbindir="$exec_prefix/sbin"
  42 fi
  43
  44 AC_DEFINE_UNQUOTED(CUPS_SBINDIR, "$sbindir")
  45
  46 dnl Fix "sharedstatedir" variable if it hasn't been specified...
  47 if test "$sharedstatedir" = "\${prefix}/com" -a "$prefix" = "/"; then
  48         sharedstatedir="/usr/com"
  49 fi
  50
  51 dnl Fix "datarootdir" variable if it hasn't been specified...
  52 if test "$datarootdir" = "\${prefix}/share"; then
  53         if test "$prefix" = "/"; then
  54                 datarootdir="/usr/share"
  55         else
  56                 datarootdir="$prefix/share"
  57         fi
  58 fi
  59
  60 dnl Fix "datadir" variable if it hasn't been specified...
  61 if test "$datadir" = "\${prefix}/share"; then
  62         if test "$prefix" = "/"; then
  63                 datadir="/usr/share"
  64         else
  65                 datadir="$prefix/share"
  66         fi
  67 elif test "$datadir" = "\${datarootdir}"; then
  68         datadir="$datarootdir"
  69 fi
  70
  71 dnl Fix "includedir" variable if it hasn't been specified...
  72 if test "$includedir" = "\${prefix}/include" -a "$prefix" = "/"; then
  73         includedir="/usr/include"
  74 fi
  75
  76 dnl Fix "localstatedir" variable if it hasn't been specified...
  77 if test "$localstatedir" = "\${prefix}/var"; then
  78         if test "$prefix" = "/"; then
  79                 if test "$uname" = Darwin; then
  80                         localstatedir="/private/var"
  81                 else
  82                         localstatedir="/var"
  83                 fi
  84         else
  85                 localstatedir="$prefix/var"
  86         fi
  87 fi
  88
  89 dnl Fix "sysconfdir" variable if it hasn't been specified...
  90 if test "$sysconfdir" = "\${prefix}/etc"; then
  91         if test "$prefix" = "/"; then
  92                 if test "$uname" = Darwin; then
  93                         sysconfdir="/private/etc"
  94                 else
  95                         sysconfdir="/etc"
  96                 fi
  97         else
  98                 sysconfdir="$prefix/etc"
  99         fi
 100 fi
 101
 102 dnl Fix "libdir" variable...
 103 if test "$libdir" = "\${exec_prefix}/lib"; then
 104         case "$uname" in
 105                 IRIX*)
 106                         libdir="$exec_prefix/lib32"
 107                         ;;
 108                 Linux*)
 109                         if test -d /usr/lib64; then
 110                                 libdir="$exec_prefix/lib64"
 111                         fi
 112                         ;;
 113                 HP-UX*)
 114                         if test -d /usr/lib/hpux32; then
 115                                 libdir="$exec_prefix/lib/hpux32"
 116                         fi
 117                         ;;
 118         esac
 119 fi
 120
 121 dnl Setup private include directory...
 122 AC_ARG_WITH(privateinclude, [  --with-privateinclude   set path for private include files, default=none],privatedir="$withval",privatedir="")
 123 if test "x$privateinclude" != x -a "x$privateinclude" != xnone; then
 124         PRIVATEINCLUDE="$privateinclude/cups"
 125 else
 126         privateinclude=""
 127         PRIVATEINCLUDE=""
 128 fi
 129 AC_SUBST(privateinclude)
 130 AC_SUBST(PRIVATEINCLUDE)
 131
 132 dnl Setup init.d locations...
 133 AC_ARG_WITH(rcdir, [  --with-rcdir            set path for rc scripts],rcdir="$withval",rcdir="")
 134 AC_ARG_WITH(rclevels, [  --with-rclevels         set run levels for rc scripts],rclevels="$withval",rclevels="2 3 5")
 135 AC_ARG_WITH(rcstart, [  --with-rcstart          set start number for rc scripts],rcstart="$withval",rcstart="99")
 136 AC_ARG_WITH(rcstop, [  --with-rcstop           set stop number for rc scripts],rcstop="$withval",rcstop="00")
 137 AC_ARG_WITH(smfmanifestdir, [  --with-smfmanifestdir   set path for Solaris SMF manifest],smfmanifestdir="$withval",smfmanifestdir="")
 138
 139 INITDIR=""
 140 INITDDIR=""
 141 RCLEVELS="$rclevels"
 142 RCSTART="$rcstart"
 143 RCSTOP="$rcstop"
 144 SMFMANIFESTDIR=""
 145
 146 if test x$rcdir = x; then
 147         case "$uname" in
 148                 AIX*)
 149                         INITDIR="/etc/rc.d"
 150                         ;;
 151
 152                 Darwin*)
 153                         # Darwin and MacOS X...
 154                         if test -x /sbin/launchd; then
 155                                 INITDDIR="/System/Library/LaunchDaemons"
 156                         else
 157                                 INITDDIR="/System/Library/StartupItems/PrintingServices"
 158                         fi
 159                         ;;
 160
 161                 FreeBSD* | OpenBSD* | MirBSD* | ekkoBSD*)
 162                         # FreeBSD and OpenBSD
 163                         ;;
 164
 165                 HP-UX*)
 166                         INITDIR="/sbin"
 167                         RCLEVELS="2"
 168                         RCSTART="380"
 169                         RCSTOP="620"
 170                         ;;
 171
 172                 IRIX*)
 173                         # IRIX
 174                         INITDIR="/etc"
 175                         RCSTART="60"
 176                         RCSTOP="25"
 177                         ;;
 178
 179                 Linux | GNU | GNU/k*BSD*)
 180                         # Linux/HURD seems to choose an init.d directory at random...
 181                         if test -d /sbin/init.d; then
 182                                 # SuSE
 183                                 INITDIR="/sbin/init.d"
 184                         else
 185                                 if test -d /etc/init.d; then
 186                                         # Others
 187                                         INITDIR="/etc"
 188                                 else
 189                                         # RedHat
 190                                         INITDIR="/etc/rc.d"
 191                                 fi
 192                         fi
 193                         RCSTART="81"
 194                         RCSTOP="36"
 195                         ;;
 196
 197                 NetBSD*)
 198                         # NetBSD
 199                         INITDDIR="/etc/rc.d"
 200                         ;;
 201
 202                 OSF1*)
 203                         INITDIR="/sbin"
 204                         ;;
 205
 206                 SunOS*)
 207                         # Solaris
 208                         if test "x$smfmanifestdir" != x; then
 209                                 SMFMANIFESTDIR=$smfmanifestdir
 210                         else
 211                                 INITDIR="/etc"
 212                                 RCSTART="81"
 213                         fi
 214                         ;;
 215
 216                 *)
 217                         INITDIR="/etc"
 218                         ;;
 219
 220         esac
 221 elif test "x$rcdir" != xno; then
 222         if test "x$rclevels" = x; then
 223                 INITDDIR="$rcdir"
 224         else
 225                 INITDIR="$rcdir"
 226         fi
 227 fi
 228
 229 AC_SUBST(INITDIR)
 230 AC_SUBST(INITDDIR)
 231 AC_SUBST(RCLEVELS)
 232 AC_SUBST(RCSTART)
 233 AC_SUBST(RCSTOP)
 234 AC_SUBST(SMFMANIFESTDIR)
 235
 236 dnl Xinetd support...
 237 AC_ARG_WITH(xinetd, [  --with-xinetd           set path for xinetd config files],XINETD="$withval",XINETD="")
 238
 239 if test "x$XINETD" = x -a ! -x /sbin/launchd; then
 240         for dir in /private/etc/xinetd.d /etc/xinetd.d /usr/local/etc/xinetd.d; do
 241                 if test -d $dir; then
 242                         XINETD="$dir"
 243                         break
 244                 fi
 245         done
 246 elif test "x$XINETD" = xno; then
 247         XINETD=""
 248 fi
 249
 250 AC_SUBST(XINETD)
 251
 252 dnl LPD sharing support...
 253 AC_ARG_WITH(lpdconfig, [  --with-lpdconfig        set URI for LPD config file],
 254         LPDCONFIG="$withval", LPDCONFIG="")
 255
 256 if test "x$LPDCONFIG" = x; then
 257         if test -f /System/Library/LaunchDaemons/org.cups.cups-lpd.plist; then
 258                 LPDCONFIG="launchd:///System/Library/LaunchDaemons/org.cups.cups-lpd.plist"
 259         elif test "x$XINETD" != x; then
 260                 LPDCONFIG="xinetd://$XINETD/cups-lpd"
 261         fi
 262 fi
 263
 264 if test "x$LPDCONFIG" = xoff; then
 265         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_LPD_CONFIG, "")
 266 else
 267         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_LPD_CONFIG, "$LPDCONFIG")
 268 fi
 269
 270 dnl SMB sharing support...
 271 AC_ARG_WITH(smbconfig, [  --with-smbconfig        set URI for Samba config file],
 272         SMBCONFIG="$withval", SMBCONFIG="")
 273
 274 if test "x$SMBCONFIG" = x; then
 275         if test -f /System/Library/LaunchDaemons/smbd.plist; then
 276                 SMBCONFIG="launchd:///System/Library/LaunchDaemons/smbd.plist"
 277         else
 278                 for dir in /etc /etc/samba /usr/local/etc; do
 279                         if test -f $dir/smb.conf; then
 280                                 SMBCONFIG="samba://$dir/smb.conf"
 281                                 break
 282                         fi
 283                 done
 284         fi
 285 fi
 286
 287 if test "x$SMBCONFIG" = xoff; then
 288         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_SMB_CONFIG, "")
 289 else
 290         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_SMB_CONFIG, "$SMBCONFIG")
 291 fi
 292
 293 dnl Setup default locations...
 294 # Cache data...
 295 AC_ARG_WITH(cachedir, [  --with-cachedir         set path for cache files],cachedir="$withval",cachedir="")
 296
 297 if test x$cachedir = x; then
 298         if test "x$uname" = xDarwin; then
 299                 CUPS_CACHEDIR="$localstatedir/spool/cups/cache"
 300         else
 301                 CUPS_CACHEDIR="$localstatedir/cache/cups"
 302         fi
 303 else
 304         CUPS_CACHEDIR="$cachedir"
 305 fi
 306 AC_DEFINE_UNQUOTED(CUPS_CACHEDIR, "$CUPS_CACHEDIR")
 307 AC_SUBST(CUPS_CACHEDIR)
 308
 309 # Data files
 310 CUPS_DATADIR="$datadir/cups"
 311 AC_DEFINE_UNQUOTED(CUPS_DATADIR, "$datadir/cups")
 312 AC_SUBST(CUPS_DATADIR)
 313
 314 # Icon directory
 315 AC_ARG_WITH(icondir, [  --with-icondir          set path for application icons],icondir="$withval",icondir="")
 316
 317 if test "x$icondir" = x -a -d /usr/share/icons; then
 318         ICONDIR="/usr/share/icons"
 319 else
 320         ICONDIR="$icondir"
 321 fi
 322
 323 AC_SUBST(ICONDIR)
 324
 325 # Menu directory
 326 AC_ARG_WITH(menudir, [  --with-menudir          set path for application menus],menudir="$withval",menudir="")
 327
 328 if test "x$menudir" = x -a -d /usr/share/applications; then
 329         MENUDIR="/usr/share/applications"
 330 else
 331         MENUDIR="$menudir"
 332 fi
 333
 334 AC_SUBST(MENUDIR)
 335
 336 # Documentation files
 337 AC_ARG_WITH(docdir, [  --with-docdir           set path for documentation],docdir="$withval",docdir="")
 338
 339 if test x$docdir = x; then
 340         CUPS_DOCROOT="$datadir/doc/cups"
 341         docdir="$datadir/doc/cups"
 342 else
 343         CUPS_DOCROOT="$docdir"
 344 fi
 345
 346 AC_DEFINE_UNQUOTED(CUPS_DOCROOT, "$docdir")
 347 AC_SUBST(CUPS_DOCROOT)
 348
 349 # Fonts
 350 AC_ARG_WITH(fontpath, [  --with-fontpath         set font path for pstoraster],fontpath="$withval",fontpath="")
 351
 352 if test "x$fontpath" = "x"; then
 353         CUPS_FONTPATH="$datadir/cups/fonts"
 354 else
 355         CUPS_FONTPATH="$fontpath"
 356 fi
 357
 358 AC_SUBST(CUPS_FONTPATH)
 359 AC_DEFINE_UNQUOTED(CUPS_FONTPATH, "$CUPS_FONTPATH")
 360
 361 # Locale data
 362 if test "$localedir" = "\${datarootdir}/locale"; then
 363         case "$uname" in
 364                 Linux | GNU | *BSD* | Darwin*)
 365                         CUPS_LOCALEDIR="$datarootdir/locale"
 366                         ;;
 367
 368                 OSF1* | AIX*)
 369                         CUPS_LOCALEDIR="$exec_prefix/lib/nls/msg"
 370                         ;;
 371
 372                 *)
 373                         # This is the standard System V location...
 374                         CUPS_LOCALEDIR="$exec_prefix/lib/locale"
 375                         ;;
 376         esac
 377 else
 378         CUPS_LOCALEDIR="$localedir"
 379 fi
 380
 381 AC_DEFINE_UNQUOTED(CUPS_LOCALEDIR, "$CUPS_LOCALEDIR")
 382 AC_SUBST(CUPS_LOCALEDIR)
 383
 384 # Log files...
 385 AC_ARG_WITH(logdir, [  --with-logdir           set path for log files],logdir="$withval",logdir="")
 386
 387 if test x$logdir = x; then
 388         CUPS_LOGDIR="$localstatedir/log/cups"
 389         AC_DEFINE_UNQUOTED(CUPS_LOGDIR, "$localstatedir/log/cups")
 390 else
 391         CUPS_LOGDIR="$logdir"
 392 fi
 393 AC_DEFINE_UNQUOTED(CUPS_LOGDIR, "$CUPS_LOGDIR")
 394 AC_SUBST(CUPS_LOGDIR)
 395
 396 # Longer-term spool data
 397 CUPS_REQUESTS="$localstatedir/spool/cups"
 398 AC_DEFINE_UNQUOTED(CUPS_REQUESTS, "$localstatedir/spool/cups")
 399 AC_SUBST(CUPS_REQUESTS)
 400
 401 # Server executables...
 402 case "$uname" in
 403         *BSD* | Darwin*)
 404                 # *BSD and Darwin (MacOS X)
 405                 INSTALL_SYSV=""
 406                 CUPS_SERVERBIN="$exec_prefix/libexec/cups"
 407                 ;;
 408         *)
 409                 # All others
 410                 INSTALL_SYSV="install-sysv"
 411                 CUPS_SERVERBIN="$exec_prefix/lib/cups"
 412                 ;;
 413 esac
 414
 415 AC_DEFINE_UNQUOTED(CUPS_SERVERBIN, "$CUPS_SERVERBIN")
 416 AC_SUBST(CUPS_SERVERBIN)
 417 AC_SUBST(INSTALL_SYSV)
 418
 419 # Configuration files
 420 CUPS_SERVERROOT="$sysconfdir/cups"
 421 AC_DEFINE_UNQUOTED(CUPS_SERVERROOT, "$sysconfdir/cups")
 422 AC_SUBST(CUPS_SERVERROOT)
 423
 424 # Transient run-time state
 425 case "$uname" in
 426         Darwin*)
 427                 # Darwin (Mac OS X)
 428                 CUPS_STATEDIR="$CUPS_SERVERROOT"
 429                 ;;
 430         *)
 431                 # All others
 432                 CUPS_STATEDIR="$localstatedir/run/cups"
 433                 ;;
 434 esac
 435 AC_DEFINE_UNQUOTED(CUPS_STATEDIR, "$CUPS_STATEDIR")
 436 AC_SUBST(CUPS_STATEDIR)
 437
 438 dnl
 439 dnl End of "$Id: cups-directories.m4 7799 2008-07-25 20:06:08Z mike $".
 440 dnl