config-scripts/cups-directories.m4

   1 dnl
   2 dnl "$Id: cups-directories.m4 7799 2008-07-25 20:06:08Z mike $"
   3 dnl
   4 dnl   Directory stuff for CUPS.
   5 dnl
   6 dnl   Copyright 2007-2012 by Apple Inc.
   7 dnl   Copyright 1997-2007 by Easy Software Products, all rights reserved.
   8 dnl
   9 dnl   These coded instructions, statements, and computer programs are the
  10 dnl   property of Apple Inc. and are protected by Federal copyright
  11 dnl   law.  Distribution and use rights are outlined in the file "LICENSE.txt"
  12 dnl   which should have been included with this file.  If this file is
  13 dnl   file is missing or damaged, see the license at "http://www.cups.org/".
  14 dnl
  15
  16 AC_PREFIX_DEFAULT(/)
  17
  18 dnl Fix "prefix" variable if it hasn't been specified...
  19 if test "$prefix" = "NONE"; then
  20         prefix="/"
  21 fi
  22
  23 dnl Fix "exec_prefix" variable if it hasn't been specified...
  24 if test "$exec_prefix" = "NONE"; then
  25         if test "$prefix" = "/"; then
  26                 exec_prefix="/usr"
  27         else
  28                 exec_prefix="$prefix"
  29         fi
  30 fi
  31
  32 dnl Fix "bindir" variable...
  33 if test "$bindir" = "\${exec_prefix}/bin"; then
  34         bindir="$exec_prefix/bin"
  35 fi
  36
  37 AC_DEFINE_UNQUOTED(CUPS_BINDIR, "$bindir")
  38
  39 dnl Fix "sbindir" variable...
  40 if test "$sbindir" = "\${exec_prefix}/sbin"; then
  41         sbindir="$exec_prefix/sbin"
  42 fi
  43
  44 AC_DEFINE_UNQUOTED(CUPS_SBINDIR, "$sbindir")
  45
  46 dnl Fix "sharedstatedir" variable if it hasn't been specified...
  47 if test "$sharedstatedir" = "\${prefix}/com" -a "$prefix" = "/"; then
  48         sharedstatedir="/usr/com"
  49 fi
  50
  51 dnl Fix "datarootdir" variable if it hasn't been specified...
  52 if test "$datarootdir" = "\${prefix}/share"; then
  53         if test "$prefix" = "/"; then
  54                 datarootdir="/usr/share"
  55         else
  56                 datarootdir="$prefix/share"
  57         fi
  58 fi
  59
  60 dnl Fix "datadir" variable if it hasn't been specified...
  61 if test "$datadir" = "\${prefix}/share"; then
  62         if test "$prefix" = "/"; then
  63                 datadir="/usr/share"
  64         else
  65                 datadir="$prefix/share"
  66         fi
  67 elif test "$datadir" = "\${datarootdir}"; then
  68         datadir="$datarootdir"
  69 fi
  70
  71 dnl Fix "includedir" variable if it hasn't been specified...
  72 if test "$includedir" = "\${prefix}/include" -a "$prefix" = "/"; then
  73         includedir="/usr/include"
  74 fi
  75
  76 dnl Fix "localstatedir" variable if it hasn't been specified...
  77 if test "$localstatedir" = "\${prefix}/var"; then
  78         if test "$prefix" = "/"; then
  79                 if test "$uname" = Darwin; then
  80                         localstatedir="/private/var"
  81                 else
  82                         localstatedir="/var"
  83                 fi
  84         else
  85                 localstatedir="$prefix/var"
  86         fi
  87 fi
  88
  89 dnl Fix "sysconfdir" variable if it hasn't been specified...
  90 if test "$sysconfdir" = "\${prefix}/etc"; then
  91         if test "$prefix" = "/"; then
  92                 if test "$uname" = Darwin; then
  93                         sysconfdir="/private/etc"
  94                 else
  95                         sysconfdir="/etc"
  96                 fi
  97         else
  98                 sysconfdir="$prefix/etc"
  99         fi
 100 fi
 101
 102 dnl Fix "libdir" variable...
 103 if test "$libdir" = "\${exec_prefix}/lib"; then
 104         case "$uname" in
 105                 Linux*)
 106                         if test -d /usr/lib64 -a ! -d /usr/lib64/fakeroot; then
 107                                 libdir="$exec_prefix/lib64"
 108                         fi
 109                         ;;
 110                 HP-UX*)
 111                         if test -d /usr/lib/hpux32; then
 112                                 libdir="$exec_prefix/lib/hpux32"
 113                         fi
 114                         ;;
 115         esac
 116 fi
 117
 118 dnl Setup private include directory...
 119 AC_ARG_WITH(privateinclude, [  --with-privateinclude   set path for private include files, default=none],privateinclude="$withval",privateinclude="")
 120 if test "x$privateinclude" != x -a "x$privateinclude" != xnone; then
 121         PRIVATEINCLUDE="$privateinclude/cups"
 122 else
 123         privateinclude=""
 124         PRIVATEINCLUDE=""
 125 fi
 126 AC_SUBST(privateinclude)
 127 AC_SUBST(PRIVATEINCLUDE)
 128
 129 dnl Setup init.d locations...
 130 AC_ARG_WITH(rcdir, [  --with-rcdir            set path for rc scripts],rcdir="$withval",rcdir="")
 131 AC_ARG_WITH(rclevels, [  --with-rclevels         set run levels for rc scripts],rclevels="$withval",rclevels="2 3 5")
 132 AC_ARG_WITH(rcstart, [  --with-rcstart          set start number for rc scripts],rcstart="$withval",rcstart="99")
 133 AC_ARG_WITH(rcstop, [  --with-rcstop           set stop number for rc scripts],rcstop="$withval",rcstop="00")
 134 AC_ARG_WITH(smfmanifestdir, [  --with-smfmanifestdir   set path for Solaris SMF manifest],smfmanifestdir="$withval",smfmanifestdir="")
 135
 136 INITDIR=""
 137 INITDDIR=""
 138 RCLEVELS="$rclevels"
 139 RCSTART="$rcstart"
 140 RCSTOP="$rcstop"
 141 SMFMANIFESTDIR=""
 142
 143 if test x$rcdir = x; then
 144         case "$uname" in
 145                 AIX*)
 146                         INITDIR="/etc/rc.d"
 147                         ;;
 148
 149                 Darwin*)
 150                         # Darwin and MacOS X...
 151                         if test -x /sbin/launchd; then
 152                                 INITDDIR="/System/Library/LaunchDaemons"
 153                         else
 154                                 INITDDIR="/System/Library/StartupItems/PrintingServices"
 155                         fi
 156                         ;;
 157
 158                 FreeBSD* | OpenBSD* | MirBSD* | ekkoBSD*)
 159                         # FreeBSD and OpenBSD
 160                         ;;
 161
 162                 HP-UX*)
 163                         INITDIR="/sbin"
 164                         RCLEVELS="2"
 165                         RCSTART="380"
 166                         RCSTOP="620"
 167                         ;;
 168
 169                 Linux | GNU | GNU/k*BSD*)
 170                         # Linux/HURD seems to choose an init.d directory at random...
 171                         if test -d /sbin/init.d; then
 172                                 # SuSE
 173                                 INITDIR="/sbin/init.d"
 174                         else
 175                                 if test -d /etc/init.d; then
 176                                         # Others
 177                                         INITDIR="/etc"
 178                                 else
 179                                         # RedHat
 180                                         INITDIR="/etc/rc.d"
 181                                 fi
 182                         fi
 183                         RCSTART="81"
 184                         RCSTOP="36"
 185                         ;;
 186
 187                 NetBSD*)
 188                         # NetBSD
 189                         INITDDIR="/etc/rc.d"
 190                         ;;
 191
 192                 OSF1*)
 193                         INITDIR="/sbin"
 194                         ;;
 195
 196                 SunOS*)
 197                         # Solaris
 198                         if test "x$smfmanifestdir" != x; then
 199                                 SMFMANIFESTDIR=$smfmanifestdir
 200                         else
 201                                 INITDIR="/etc"
 202                                 RCSTART="81"
 203                         fi
 204                         ;;
 205
 206                 *)
 207                         INITDIR="/etc"
 208                         ;;
 209
 210         esac
 211 elif test "x$rcdir" != xno; then
 212         if test "x$rclevels" = x; then
 213                 INITDDIR="$rcdir"
 214         else
 215                 INITDIR="$rcdir"
 216         fi
 217 fi
 218
 219 AC_SUBST(INITDIR)
 220 AC_SUBST(INITDDIR)
 221 AC_SUBST(RCLEVELS)
 222 AC_SUBST(RCSTART)
 223 AC_SUBST(RCSTOP)
 224 AC_SUBST(SMFMANIFESTDIR)
 225
 226 dnl Xinetd support...
 227 AC_ARG_WITH(xinetd, [  --with-xinetd           set path for xinetd config files],XINETD="$withval",XINETD="")
 228
 229 if test "x$XINETD" = x -a ! -x /sbin/launchd; then
 230         for dir in /private/etc/xinetd.d /etc/xinetd.d /usr/local/etc/xinetd.d; do
 231                 if test -d $dir; then
 232                         XINETD="$dir"
 233                         break
 234                 fi
 235         done
 236 elif test "x$XINETD" = xno; then
 237         XINETD=""
 238 fi
 239
 240 AC_SUBST(XINETD)
 241
 242 dnl LPD sharing support...
 243 AC_ARG_WITH(lpdconfig, [  --with-lpdconfig        set URI for LPD config file],
 244         LPDCONFIG="$withval", LPDCONFIG="")
 245
 246 if test "x$LPDCONFIG" = x; then
 247         if test -f /System/Library/LaunchDaemons/org.cups.cups-lpd.plist; then
 248                 LPDCONFIG="launchd:///System/Library/LaunchDaemons/org.cups.cups-lpd.plist"
 249         elif test "x$XINETD" != x; then
 250                 LPDCONFIG="xinetd://$XINETD/cups-lpd"
 251         fi
 252 fi
 253
 254 if test "x$LPDCONFIG" = xoff; then
 255         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_LPD_CONFIG, "")
 256 else
 257         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_LPD_CONFIG, "$LPDCONFIG")
 258 fi
 259
 260 dnl SMB sharing support...
 261 AC_ARG_WITH(smbconfig, [  --with-smbconfig        set URI for Samba config file],
 262         SMBCONFIG="$withval", SMBCONFIG="")
 263
 264 if test "x$SMBCONFIG" = x; then
 265         if test -f /System/Library/LaunchDaemons/smbd.plist; then
 266                 SMBCONFIG="launchd:///System/Library/LaunchDaemons/smbd.plist"
 267         else
 268                 for dir in /etc /etc/samba /usr/local/etc; do
 269                         if test -f $dir/smb.conf; then
 270                                 SMBCONFIG="samba://$dir/smb.conf"
 271                                 break
 272                         fi
 273                 done
 274         fi
 275 fi
 276
 277 if test "x$SMBCONFIG" = xoff; then
 278         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_SMB_CONFIG, "")
 279 else
 280         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_SMB_CONFIG, "$SMBCONFIG")
 281 fi
 282
 283 dnl Setup default locations...
 284 # Cache data...
 285 AC_ARG_WITH(cachedir, [  --with-cachedir         set path for cache files],cachedir="$withval",cachedir="")
 286
 287 if test x$cachedir = x; then
 288         if test "x$uname" = xDarwin; then
 289                 CUPS_CACHEDIR="$localstatedir/spool/cups/cache"
 290         else
 291                 CUPS_CACHEDIR="$localstatedir/cache/cups"
 292         fi
 293 else
 294         CUPS_CACHEDIR="$cachedir"
 295 fi
 296 AC_DEFINE_UNQUOTED(CUPS_CACHEDIR, "$CUPS_CACHEDIR")
 297 AC_SUBST(CUPS_CACHEDIR)
 298
 299 # Data files
 300 CUPS_DATADIR="$datadir/cups"
 301 AC_DEFINE_UNQUOTED(CUPS_DATADIR, "$datadir/cups")
 302 AC_SUBST(CUPS_DATADIR)
 303
 304 # Icon directory
 305 AC_ARG_WITH(icondir, [  --with-icondir          set path for application icons],icondir="$withval",icondir="")
 306
 307 if test "x$icondir" = x -a -d /usr/share/icons; then
 308         ICONDIR="/usr/share/icons"
 309 else
 310         ICONDIR="$icondir"
 311 fi
 312
 313 AC_SUBST(ICONDIR)
 314
 315 # Menu directory
 316 AC_ARG_WITH(menudir, [  --with-menudir          set path for application menus],menudir="$withval",menudir="")
 317
 318 if test "x$menudir" = x -a -d /usr/share/applications; then
 319         MENUDIR="/usr/share/applications"
 320 else
 321         MENUDIR="$menudir"
 322 fi
 323
 324 AC_SUBST(MENUDIR)
 325
 326 # Documentation files
 327 AC_ARG_WITH(docdir, [  --with-docdir           set path for documentation],docdir="$withval",docdir="")
 328
 329 if test x$docdir = x; then
 330         CUPS_DOCROOT="$datadir/doc/cups"
 331         docdir="$datadir/doc/cups"
 332 else
 333         CUPS_DOCROOT="$docdir"
 334 fi
 335
 336 AC_DEFINE_UNQUOTED(CUPS_DOCROOT, "$docdir")
 337 AC_SUBST(CUPS_DOCROOT)
 338
 339 # Fonts
 340 AC_ARG_WITH(fontpath, [  --with-fontpath         set font path for pstoraster],fontpath="$withval",fontpath="")
 341
 342 if test "x$fontpath" = "x"; then
 343         CUPS_FONTPATH="$datadir/cups/fonts"
 344 else
 345         CUPS_FONTPATH="$fontpath"
 346 fi
 347
 348 AC_SUBST(CUPS_FONTPATH)
 349 AC_DEFINE_UNQUOTED(CUPS_FONTPATH, "$CUPS_FONTPATH")
 350
 351 # Locale data
 352 if test "$localedir" = "\${datarootdir}/locale"; then
 353         case "$uname" in
 354                 Linux | GNU | *BSD* | Darwin*)
 355                         CUPS_LOCALEDIR="$datarootdir/locale"
 356                         ;;
 357
 358                 OSF1* | AIX*)
 359                         CUPS_LOCALEDIR="$exec_prefix/lib/nls/msg"
 360                         ;;
 361
 362                 *)
 363                         # This is the standard System V location...
 364                         CUPS_LOCALEDIR="$exec_prefix/lib/locale"
 365                         ;;
 366         esac
 367 else
 368         CUPS_LOCALEDIR="$localedir"
 369 fi
 370
 371 AC_DEFINE_UNQUOTED(CUPS_LOCALEDIR, "$CUPS_LOCALEDIR")
 372 AC_SUBST(CUPS_LOCALEDIR)
 373
 374 # Log files...
 375 AC_ARG_WITH(logdir, [  --with-logdir           set path for log files],logdir="$withval",logdir="")
 376
 377 if test x$logdir = x; then
 378         CUPS_LOGDIR="$localstatedir/log/cups"
 379         AC_DEFINE_UNQUOTED(CUPS_LOGDIR, "$localstatedir/log/cups")
 380 else
 381         CUPS_LOGDIR="$logdir"
 382 fi
 383 AC_DEFINE_UNQUOTED(CUPS_LOGDIR, "$CUPS_LOGDIR")
 384 AC_SUBST(CUPS_LOGDIR)
 385
 386 # Longer-term spool data
 387 CUPS_REQUESTS="$localstatedir/spool/cups"
 388 AC_DEFINE_UNQUOTED(CUPS_REQUESTS, "$localstatedir/spool/cups")
 389 AC_SUBST(CUPS_REQUESTS)
 390
 391 # Server executables...
 392 case "$uname" in
 393         *BSD* | Darwin*)
 394                 # *BSD and Darwin (MacOS X)
 395                 INSTALL_SYSV=""
 396                 CUPS_SERVERBIN="$exec_prefix/libexec/cups"
 397                 ;;
 398         *)
 399                 # All others
 400                 INSTALL_SYSV="install-sysv"
 401                 CUPS_SERVERBIN="$exec_prefix/lib/cups"
 402                 ;;
 403 esac
 404
 405 AC_DEFINE_UNQUOTED(CUPS_SERVERBIN, "$CUPS_SERVERBIN")
 406 AC_SUBST(CUPS_SERVERBIN)
 407 AC_SUBST(INSTALL_SYSV)
 408
 409 # Configuration files
 410 CUPS_SERVERROOT="$sysconfdir/cups"
 411 AC_DEFINE_UNQUOTED(CUPS_SERVERROOT, "$sysconfdir/cups")
 412 AC_SUBST(CUPS_SERVERROOT)
 413
 414 # Transient run-time state
 415 case "$uname" in
 416         Darwin*)
 417                 # Darwin (OS X)
 418                 CUPS_STATEDIR="$CUPS_SERVERROOT"
 419                 ;;
 420         *)
 421                 # All others
 422                 CUPS_STATEDIR="$localstatedir/run/cups"
 423                 ;;
 424 esac
 425 AC_DEFINE_UNQUOTED(CUPS_STATEDIR, "$CUPS_STATEDIR")
 426 AC_SUBST(CUPS_STATEDIR)
 427
 428 dnl
 429 dnl End of "$Id: cups-directories.m4 7799 2008-07-25 20:06:08Z mike $".
 430 dnl