config-scripts/cups-directories.m4

   1 dnl
   2 dnl "$Id: cups-directories.m4 6838 2007-08-22 20:00:19Z mike $"
   3 dnl
   4 dnl   Directory stuff for the Common UNIX Printing System (CUPS).
   5 dnl
   6 dnl   Copyright 2007 by Apple Inc.
   7 dnl   Copyright 1997-2007 by Easy Software Products, all rights reserved.
   8 dnl
   9 dnl   These coded instructions, statements, and computer programs are the
  10 dnl   property of Apple Inc. and are protected by Federal copyright
  11 dnl   law.  Distribution and use rights are outlined in the file "LICENSE.txt"
  12 dnl   which should have been included with this file.  If this file is
  13 dnl   file is missing or damaged, see the license at "http://www.cups.org/".
  14 dnl
  15
  16 AC_PREFIX_DEFAULT(/)
  17
  18 dnl Fix "prefix" variable if it hasn't been specified...
  19 if test "$prefix" = "NONE"; then
  20         prefix="/"
  21 fi
  22
  23 dnl Fix "exec_prefix" variable if it hasn't been specified...
  24 if test "$exec_prefix" = "NONE"; then
  25         if test "$prefix" = "/"; then
  26                 exec_prefix="/usr"
  27         else
  28                 exec_prefix="$prefix"
  29         fi
  30 fi
  31
  32 dnl Fix "bindir" variable...
  33 if test "$bindir" = "\${exec_prefix}/bin"; then
  34         bindir="$exec_prefix/bin"
  35 fi
  36
  37 AC_DEFINE_UNQUOTED(CUPS_BINDIR, "$bindir")
  38
  39 dnl Fix "sbindir" variable...
  40 if test "$sbindir" = "\${exec_prefix}/sbin"; then
  41         sbindir="$exec_prefix/sbin"
  42 fi
  43
  44 AC_DEFINE_UNQUOTED(CUPS_SBINDIR, "$sbindir")
  45
  46 dnl Fix "sharedstatedir" variable if it hasn't been specified...
  47 if test "$sharedstatedir" = "\${prefix}/com" -a "$prefix" = "/"; then
  48         sharedstatedir="/usr/com"
  49 fi
  50
  51 dnl Fix "datarootdir" variable if it hasn't been specified...
  52 if test "$datarootdir" = "\${prefix}/share"; then
  53         if test "$prefix" = "/"; then
  54                 datarootdir="/usr/share"
  55         else
  56                 datarootdir="$prefix/share"
  57         fi
  58 fi
  59
  60 dnl Fix "datadir" variable if it hasn't been specified...
  61 if test "$datadir" = "\${prefix}/share"; then
  62         if test "$prefix" = "/"; then
  63                 datadir="/usr/share"
  64         else
  65                 datadir="$prefix/share"
  66         fi
  67 elif test "$datadir" = "\${datarootdir}"; then
  68         datadir="$datarootdir"
  69 fi
  70
  71 dnl Fix "includedir" variable if it hasn't been specified...
  72 if test "$includedir" = "\${prefix}/include" -a "$prefix" = "/"; then
  73         includedir="/usr/include"
  74 fi
  75
  76 dnl Fix "localstatedir" variable if it hasn't been specified...
  77 if test "$localstatedir" = "\${prefix}/var"; then
  78         if test "$prefix" = "/"; then
  79                 if test "$uname" = Darwin; then
  80                         localstatedir="/private/var"
  81                 else
  82                         localstatedir="/var"
  83                 fi
  84         else
  85                 localstatedir="$prefix/var"
  86         fi
  87 fi
  88
  89 dnl Fix "sysconfdir" variable if it hasn't been specified...
  90 if test "$sysconfdir" = "\${prefix}/etc"; then
  91         if test "$prefix" = "/"; then
  92                 if test "$uname" = Darwin; then
  93                         sysconfdir="/private/etc"
  94                 else
  95                         sysconfdir="/etc"
  96                 fi
  97         else
  98                 sysconfdir="$prefix/etc"
  99         fi
 100 fi
 101
 102 dnl Fix "libdir" variable for IRIX 6.x...
 103 if test "$libdir" = "\${exec_prefix}/lib"; then
 104         if test "$uname" = "IRIX"; then
 105                 libdir="$exec_prefix/lib32"
 106         else
 107                 if test "$uname" = Linux -a -d /usr/lib64; then
 108                         libdir="$exec_prefix/lib64"
 109                 else
 110                         libdir="$exec_prefix/lib"
 111                 fi
 112         fi
 113 fi
 114
 115 dnl Setup init.d locations...
 116 AC_ARG_WITH(rcdir, [  --with-rcdir            set path for rc scripts],rcdir="$withval",rcdir="")
 117 AC_ARG_WITH(rclevels, [  --with-rclevels         set run levels for rc scripts],rclevels="$withval",rclevels="2 3 5")
 118 AC_ARG_WITH(rcstart, [  --with-rcstart          set start number for rc scripts],rcstart="$withval",rcstart="99")
 119 AC_ARG_WITH(rcstop, [  --with-rcstop           set stop number for rc scripts],rcstop="$withval",rcstop="00")
 120
 121 INITDIR=""
 122 INITDDIR=""
 123 RCLEVELS="$rclevels"
 124 RCSTART="$rcstart"
 125 RCSTOP="$rcstop"
 126
 127 if test x$rcdir = x; then
 128         case "$uname" in
 129                 AIX*)
 130                         INITDIR="/etc/rc.d"
 131                         ;;
 132
 133                 Darwin*)
 134                         # Darwin and MacOS X...
 135                         if test -x /sbin/launchd; then
 136                                 INITDDIR="/System/Library/LaunchDaemons"
 137                         else
 138                                 INITDDIR="/System/Library/StartupItems/PrintingServices"
 139                         fi
 140                         ;;
 141
 142                 FreeBSD* | OpenBSD* | MirBSD* | ekkoBSD*)
 143                         # FreeBSD and OpenBSD
 144                         ;;
 145
 146                 HP-UX*)
 147                         INITDIR="/sbin"
 148                         RCLEVELS="2"
 149                         RCSTART="620"
 150                         RCSTOP="380"
 151                         ;;
 152
 153                 IRIX*)
 154                         # IRIX
 155                         INITDIR="/etc"
 156                         RCSTART="60"
 157                         RCSTOP="25"
 158                         ;;
 159
 160                 Linux | GNU)
 161                         # Linux/HURD seems to choose an init.d directory at random...
 162                         if test -d /sbin/init.d; then
 163                                 # SuSE
 164                                 INITDIR="/sbin/init.d"
 165                         else
 166                                 if test -d /etc/init.d; then
 167                                         # Others
 168                                         INITDIR="/etc"
 169                                 else
 170                                         # RedHat
 171                                         INITDIR="/etc/rc.d"
 172                                 fi
 173                         fi
 174                         RCSTART="81"
 175                         RCSTOP="36"
 176                         ;;
 177
 178                 NetBSD*)
 179                         # NetBSD
 180                         INITDDIR="/etc/rc.d"
 181                         ;;
 182
 183                 OSF1*)
 184                         INITDIR="/sbin"
 185                         ;;
 186
 187                 SunOS*)
 188                         # Solaris
 189                         INITDIR="/etc"
 190                         RCSTART="81"
 191                         ;;
 192
 193                 *)
 194                         INITDIR="/etc"
 195                         ;;
 196
 197         esac
 198 else
 199         if test "x$rclevels" = x; then
 200                 INITDDIR="$rcdir"
 201         else
 202                 INITDIR="$rcdir"
 203         fi
 204 fi
 205
 206 AC_SUBST(INITDIR)
 207 AC_SUBST(INITDDIR)
 208 AC_SUBST(RCLEVELS)
 209 AC_SUBST(RCSTART)
 210 AC_SUBST(RCSTOP)
 211
 212 dnl Xinetd support...
 213 AC_ARG_WITH(xinetd, [  --with-xinetd           set path for xinetd config files],XINETD="$withval",XINETD="")
 214
 215 if test "x$XINETD" = x -a ! -x /sbin/launchd; then
 216         for dir in /private/etc/xinetd.d /etc/xinetd.d /usr/local/etc/xinetd.d; do
 217                 if test -d $dir; then
 218                         XINETD="$dir"
 219                         break
 220                 fi
 221         done
 222 fi
 223
 224 AC_SUBST(XINETD)
 225
 226 dnl Setup default locations...
 227 # Cache data...
 228 AC_ARG_WITH(cachedir, [  --with-cachedir         set path for cache files],cachedir="$withval",cachedir="")
 229
 230 if test x$cachedir = x; then
 231         if test "x$uname" = xDarwin; then
 232                 CUPS_CACHEDIR="$localstatedir/spool/cups/cache"
 233         else
 234                 CUPS_CACHEDIR="$localstatedir/cache/cups"
 235         fi
 236 else
 237         CUPS_CACHEDIR="$cachedir"
 238 fi
 239 AC_DEFINE_UNQUOTED(CUPS_CACHEDIR, "$CUPS_CACHEDIR")
 240 AC_SUBST(CUPS_CACHEDIR)
 241
 242 # Data files
 243 CUPS_DATADIR="$datadir/cups"
 244 AC_DEFINE_UNQUOTED(CUPS_DATADIR, "$datadir/cups")
 245 AC_SUBST(CUPS_DATADIR)
 246
 247 # Icon directory
 248 AC_ARG_WITH(icondir, [  --with-icondir          set path for application icons],icondir="$withval",icondir="")
 249
 250 if test "x$icondir" = x -a -d /usr/share/icons; then
 251         ICONDIR="/usr/share/icons"
 252 else
 253         ICONDIR="$icondir"
 254 fi
 255
 256 AC_SUBST(ICONDIR)
 257
 258 # Menu directory
 259 AC_ARG_WITH(menudir, [  --with-menudir          set path for application menus],menudir="$withval",menudir="")
 260
 261 if test "x$menudir" = x -a -d /usr/share/applications; then
 262         MENUDIR="/usr/share/applications"
 263 else
 264         MENUDIR="$menudir"
 265 fi
 266
 267 AC_SUBST(MENUDIR)
 268
 269 # Documentation files
 270 AC_ARG_WITH(docdir, [  --with-docdir           set path for documentation],docdir="$withval",docdir="")
 271
 272 if test x$docdir = x; then
 273         CUPS_DOCROOT="$datadir/doc/cups"
 274         docdir="$datadir/doc/cups"
 275 else
 276         CUPS_DOCROOT="$docdir"
 277 fi
 278
 279 AC_DEFINE_UNQUOTED(CUPS_DOCROOT, "$docdir")
 280 AC_SUBST(CUPS_DOCROOT)
 281
 282 # Fonts
 283 AC_ARG_WITH(fontpath, [  --with-fontpath         set font path for pstoraster],fontpath="$withval",fontpath="")
 284
 285 if test "x$fontpath" = "x"; then
 286         CUPS_FONTPATH="$datadir/cups/fonts"
 287 else
 288         CUPS_FONTPATH="$fontpath"
 289 fi
 290
 291 AC_SUBST(CUPS_FONTPATH)
 292 AC_DEFINE_UNQUOTED(CUPS_FONTPATH, "$CUPS_FONTPATH")
 293
 294 # Locale data
 295 if test "$localedir" = "\${datarootdir}/locale"; then
 296         case "$uname" in
 297                 Linux | GNU | *BSD* | Darwin*)
 298                         CUPS_LOCALEDIR="$datarootdir/locale"
 299                         ;;
 300
 301                 OSF1* | AIX*)
 302                         CUPS_LOCALEDIR="$exec_prefix/lib/nls/msg"
 303                         ;;
 304
 305                 *)
 306                         # This is the standard System V location...
 307                         CUPS_LOCALEDIR="$exec_prefix/lib/locale"
 308                         ;;
 309         esac
 310 else
 311         CUPS_LOCALEDIR="$localedir"
 312 fi
 313
 314 AC_DEFINE_UNQUOTED(CUPS_LOCALEDIR, "$CUPS_LOCALEDIR")
 315 AC_SUBST(CUPS_LOCALEDIR)
 316
 317 # Log files...
 318 AC_ARG_WITH(logdir, [  --with-logdir           set path for log files],logdir="$withval",logdir="")
 319
 320 if test x$logdir = x; then
 321         CUPS_LOGDIR="$localstatedir/log/cups"
 322         AC_DEFINE_UNQUOTED(CUPS_LOGDIR, "$localstatedir/log/cups")
 323 else
 324         CUPS_LOGDIR="$logdir"
 325 fi
 326 AC_DEFINE_UNQUOTED(CUPS_LOGDIR, "$CUPS_LOGDIR")
 327 AC_SUBST(CUPS_LOGDIR)
 328
 329 # Longer-term spool data
 330 CUPS_REQUESTS="$localstatedir/spool/cups"
 331 AC_DEFINE_UNQUOTED(CUPS_REQUESTS, "$localstatedir/spool/cups")
 332 AC_SUBST(CUPS_REQUESTS)
 333
 334 # Server executables...
 335 case "$uname" in
 336         *BSD* | Darwin*)
 337                 # *BSD and Darwin (MacOS X)
 338                 INSTALL_SYSV=""
 339                 CUPS_SERVERBIN="$exec_prefix/libexec/cups"
 340                 ;;
 341         *)
 342                 # All others
 343                 INSTALL_SYSV="install-sysv"
 344                 CUPS_SERVERBIN="$exec_prefix/lib/cups"
 345                 ;;
 346 esac
 347
 348 AC_DEFINE_UNQUOTED(CUPS_SERVERBIN, "$CUPS_SERVERBIN")
 349 AC_SUBST(CUPS_SERVERBIN)
 350 AC_SUBST(INSTALL_SYSV)
 351
 352 # Configuration files
 353 CUPS_SERVERROOT="$sysconfdir/cups"
 354 AC_DEFINE_UNQUOTED(CUPS_SERVERROOT, "$sysconfdir/cups")
 355 AC_SUBST(CUPS_SERVERROOT)
 356
 357 # Transient run-time state
 358 CUPS_STATEDIR="$localstatedir/run/cups"
 359 AC_DEFINE_UNQUOTED(CUPS_STATEDIR, "$localstatedir/run/cups")
 360 AC_SUBST(CUPS_STATEDIR)
 361
 362 dnl
 363 dnl End of "$Id: cups-directories.m4 6838 2007-08-22 20:00:19Z mike $".
 364 dnl