config-scripts/cups-gssapi.m4

   1 dnl
   2 dnl   "$Id$"
   3 dnl
   4 dnl   GSSAPI/Kerberos library detection.
   5 dnl
   6 dnl   Copyright 2007 by Apple Inc.
   7 dnl   Copyright 2006-2007 by Easy Software Products.
   8 dnl
   9 dnl   This file contains Kerberos support code, copyright 2006 by
  10 dnl   Jelmer Vernooij.
  11 dnl
  12 dnl   These coded instructions, statements, and computer programs are the
  13 dnl   property of Apple Inc. and are protected by Federal copyright
  14 dnl   law.  Distribution and use rights are outlined in the file "LICENSE.txt"
  15 dnl   which should have been included with this file.  If this file is
  16 dnl   file is missing or damaged, see the license at "http://www.cups.org/".
  17 dnl
  18
  19 AC_ARG_ENABLE(gssapi, [  --enable-gssapi         turn on GSSAPI support, default=yes])
  20
  21 LIBGSSAPI=""
  22
  23 if test x$enable_gssapi != xno; then
  24         AC_PATH_PROG(KRB5CONFIG, krb5-config)
  25         if test "x$KRB5CONFIG" != x; then
  26                 case "$uname" in
  27                         Darwin)
  28                                 # Mac OS X weak-links to the Kerberos framework...
  29                                 LIBGSSAPI="-weak_framework Kerberos"
  30                                 ;;
  31                         SunOS*)
  32                                 # Solaris has a non-standard krb5-config, don't use it!
  33                                 AC_CHECK_LIB(gss, gss_display_status,
  34                                         AC_DEFINE(HAVE_GSSAPI, 1, [Whether GSSAPI is available])
  35                                         CFLAGS="`$KRB5CONFIG --cflags` $CFLAGS"
  36                                         CPPFLAGS="`$KRB5CONFIG --cflags` $CPPFLAGS"
  37                                         LIBGSSAPI="-lgss `$KRB5CONFIG --libs`")
  38                                 ;;
  39                         *)
  40                                 # Other platforms just ask for GSSAPI
  41                                 CFLAGS="`$KRB5CONFIG --cflags gssapi` $CFLAGS"
  42                                 CPPFLAGS="`$KRB5CONFIG --cflags gssapi` $CPPFLAGS"
  43                                 LIBGSSAPI="`$KRB5CONFIG --libs gssapi`"
  44                                 ;;
  45                 esac
  46                 AC_DEFINE(HAVE_GSSAPI, 1, [Whether GSSAPI is available])
  47         else
  48                 # Check for vendor-specific implementations...
  49                 case "$uname" in
  50                         HP-UX*)
  51                                 AC_CHECK_LIB(gss, gss_display_status,
  52                                         AC_DEFINE(HAVE_GSSAPI, 1, [Whether GSSAPI is available])
  53                                         LIBGSSAPI="-lgss -lgssapi_krb5")
  54                                 ;;
  55                         SunOS*)
  56                                 AC_CHECK_LIB(gss, gss_display_status,
  57                                         AC_DEFINE(HAVE_GSSAPI, 1, [Whether GSSAPI is available])
  58                                         LIBGSSAPI="-lgss")
  59                                 ;;
  60                 esac
  61         fi
  62
  63         if test "x$LIBGSSAPI" != x; then
  64                 AC_CHECK_HEADER(krb5.h, AC_DEFINE(HAVE_KRB5_H))
  65                 AC_CHECK_HEADER(gssapi.h, AC_DEFINE(HAVE_GSSAPI_H))
  66                 AC_CHECK_HEADER(gssapi/gssapi.h, AC_DEFINE(HAVE_GSSAPI_GSSAPI_H))
  67                 AC_CHECK_HEADER(gssapi/gssapi_generic.h, AC_DEFINE(HAVE_GSSAPI_GSSAPI_GENERIC_H))
  68                 AC_CHECK_HEADER(gssapi/gssapi_krb5.h, AC_DEFINE(HAVE_GSSAPI_GSSAPI_KRB5_H))
  69
  70                 SAVELIBS="$LIBS"
  71                 LIBS="$LIBS $LIBGSSAPI"
  72
  73                 AC_CHECK_FUNC(gsskrb5_register_acceptor_identity,
  74                               AC_DEFINE(HAVE_GSSKRB5_REGISTER_ACCEPTOR_IDENTITY))
  75                 AC_CHECK_FUNC(krb5_cc_new_unique, AC_DEFINE(HAVE_KRB5_CC_NEW_UNIQUE))
  76
  77                 AC_MSG_CHECKING(for GSS_C_NT_HOSTBASED_SERVICE)
  78                 if test $ac_cv_header_gssapi_gssapi_h = yes; then
  79                         AC_TRY_COMPILE([ #include <gssapi/gssapi.h> ],
  80                                        [ gss_OID foo = GSS_C_NT_HOSTBASED_SERVICE; ],
  81                                        AC_DEFINE(HAVE_GSS_C_NT_HOSTBASED_SERVICE)
  82                                        AC_MSG_RESULT(yes),
  83                                        AC_MSG_RESULT(no))
  84                 else
  85                         AC_TRY_COMPILE([ #include <gssapi.h> ],
  86                                        [ gss_OID foo = GSS_C_NT_HOSTBASED_SERVICE; ],
  87                                        AC_DEFINE(HAVE_GSS_C_NT_HOSTBASED_SERVICE)
  88                                        AC_MSG_RESULT(yes),
  89                                        AC_MSG_RESULT(no))
  90                 fi
  91
  92                 LIBS="$SAVELIBS"
  93
  94                 AC_MSG_CHECKING(for Heimdal Kerberos)
  95                 AC_TRY_COMPILE([ #include <krb5.h> ],
  96                                [ char *tmp = heimdal_version; ],
  97                                AC_DEFINE(HAVE_HEIMDAL)
  98                                AC_MSG_RESULT(yes),
  99                                AC_MSG_RESULT(no))
 100         fi
 101 fi
 102
 103 dnl Default GSS service name...
 104 AC_ARG_WITH(gssservicename, [  --with-gssservicename   set default gss service name],
 105         default_gssservicename="$withval",
 106         default_gssservicename="default")
 107
 108 if test x$default_gssservicename != xno; then
 109         if test "x$default_gssservicename" = "xdefault"; then
 110                 CUPS_DEFAULT_GSSSERVICENAME="ipp"
 111         else
 112                 CUPS_DEFAULT_GSSSERVICENAME="$default_gssservicename"
 113         fi
 114 else
 115         CUPS_DEFAULT_GSSSERVICENAME=""
 116 fi
 117
 118 AC_SUBST(LIBGSSAPI)
 119 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_GSSSERVICENAME, "$CUPS_DEFAULT_GSSSERVICENAME")
 120
 121 dnl
 122 dnl End of "$Id$".
 123 dnl