config-scripts/cups-network.m4

   1 dnl
   2 dnl "$Id: cups-network.m4 7127 2007-12-17 18:05:32Z mike $"
   3 dnl
   4 dnl   Networking stuff for the Common UNIX Printing System (CUPS).
   5 dnl
   6 dnl   Copyright 2007-2008 by Apple Inc.
   7 dnl   Copyright 1997-2005 by Easy Software Products, all rights reserved.
   8 dnl
   9 dnl   These coded instructions, statements, and computer programs are the
  10 dnl   property of Apple Inc. and are protected by Federal copyright
  11 dnl   law.  Distribution and use rights are outlined in the file "LICENSE.txt"
  12 dnl   which should have been included with this file.  If this file is
  13 dnl   file is missing or damaged, see the license at "http://www.cups.org/".
  14 dnl
  15
  16 AC_CHECK_HEADER(resolv.h,AC_DEFINE(HAVE_RESOLV_H))
  17 AC_SEARCH_LIBS(socket, socket)
  18 AC_SEARCH_LIBS(gethostbyaddr, nsl)
  19 AC_SEARCH_LIBS(getifaddrs, nsl, AC_DEFINE(HAVE_GETIFADDRS))
  20 AC_SEARCH_LIBS(hstrerror, nsl socket resolv, AC_DEFINE(HAVE_HSTRERROR))
  21 AC_SEARCH_LIBS(rresvport_af, nsl, AC_DEFINE(HAVE_RRESVPORT_AF))
  22 AC_SEARCH_LIBS(__res_init, resolv bind, AC_DEFINE(HAVE_RES_INIT),
  23         AC_SEARCH_LIBS(res_9_init, resolv bind, AC_DEFINE(HAVE_RES_INIT),
  24         AC_SEARCH_LIBS(res_init, resolv bind, AC_DEFINE(HAVE_RES_INIT))))
  25
  26 # Tru64 5.1b leaks file descriptors with these functions; disable until
  27 # we can come up with a test for this...
  28 if test "$uname" != "OSF1"; then
  29         AC_SEARCH_LIBS(getaddrinfo, nsl, AC_DEFINE(HAVE_GETADDRINFO))
  30         AC_SEARCH_LIBS(getnameinfo, nsl, AC_DEFINE(HAVE_GETNAMEINFO))
  31 fi
  32
  33 AC_CHECK_MEMBER(struct sockaddr.sa_len,,, [#include <sys/socket.h>])
  34 AC_CHECK_HEADER(sys/sockio.h, AC_DEFINE(HAVE_SYS_SOCKIO_H))
  35
  36 CUPS_DEFAULT_DOMAINSOCKET=""
  37
  38 dnl Domain socket support...
  39 AC_ARG_WITH(domainsocket, [  --with-domainsocket     set unix domain socket name],
  40         default_domainsocket="$withval",
  41         default_domainsocket="")
  42
  43 if test x$enable_domainsocket != xno -a x$default_domainsocket != xno; then
  44         if test "x$default_domainsocket" = x; then
  45                 case "$uname" in
  46                         Darwin*)
  47                                 # Darwin and MaxOS X do their own thing...
  48                                 CUPS_DEFAULT_DOMAINSOCKET="$localstatedir/run/cupsd"
  49                                 ;;
  50                         *)
  51                                 # All others use FHS standard...
  52                                 CUPS_DEFAULT_DOMAINSOCKET="$CUPS_STATEDIR/cups.sock"
  53                                 ;;
  54                 esac
  55         else
  56                 CUPS_DEFAULT_DOMAINSOCKET="$default_domainsocket"
  57         fi
  58
  59         CUPS_LISTEN_DOMAINSOCKET="Listen $CUPS_DEFAULT_DOMAINSOCKET"
  60
  61         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_DOMAINSOCKET, "$CUPS_DEFAULT_DOMAINSOCKET")
  62 else
  63         CUPS_LISTEN_DOMAINSOCKET=""
  64 fi
  65
  66 AC_SUBST(CUPS_DEFAULT_DOMAINSOCKET)
  67 AC_SUBST(CUPS_LISTEN_DOMAINSOCKET)
  68
  69 AC_CHECK_HEADERS(AppleTalk/at_proto.h,AC_DEFINE(HAVE_APPLETALK_AT_PROTO_H),,
  70         [#include <netat/appletalk.h>])
  71
  72 dnl
  73 dnl End of "$Id: cups-network.m4 7127 2007-12-17 18:05:32Z mike $".
  74 dnl