config-scripts/cups-pdf.m4

   1 dnl
   2 dnl "$Id: cups-pdf.m4 7449 2008-04-14 18:27:53Z mike $"
   3 dnl
   4 dnl   PDF filter configuration stuff for the Common UNIX Printing System (CUPS).
   5 dnl
   6 dnl   Copyright 2007-2009 by Apple Inc.
   7 dnl   Copyright 2006 by Easy Software Products, all rights reserved.
   8 dnl
   9 dnl   These coded instructions, statements, and computer programs are the
  10 dnl   property of Apple Inc. and are protected by Federal copyright
  11 dnl   law.  Distribution and use rights are outlined in the file "LICENSE.txt"
  12 dnl   which should have been included with this file.  If this file is
  13 dnl   file is missing or damaged, see the license at "http://www.cups.org/".
  14 dnl
  15
  16 AC_ARG_WITH(pdftops, [  --with-pdftops          set pdftops filter (gs,/path/to/gs,pdftops,/path/to/pdftops,none), default=pdftops ])
  17
  18 PDFTOPS=""
  19 CUPS_PDFTOPS=""
  20 CUPS_GHOSTSCRIPT=""
  21
  22 case "x$with_pdftops" in
  23         x) # Default/auto
  24         if test $uname != Darwin; then
  25                 AC_PATH_PROG(CUPS_PDFTOPS, pdftops)
  26                 if test "x$CUPS_PDFTOPS" != x; then
  27                         AC_DEFINE(HAVE_PDFTOPS)
  28                         PDFTOPS="pdftops"
  29                 else
  30                         AC_PATH_PROG(CUPS_GHOSTSCRIPT, gs)
  31                         if test "x$CUPS_GHOSTSCRIPT" != x; then
  32                                 AC_DEFINE(HAVE_GHOSTSCRIPT)
  33                                 PDFTOPS="pdftops"
  34                         fi
  35                 fi
  36         fi
  37         ;;
  38
  39         xgs)
  40         AC_PATH_PROG(CUPS_GHOSTSCRIPT, gs)
  41         if test "x$CUPS_GHOSTSCRIPT" != x; then
  42                 AC_DEFINE(HAVE_GHOSTSCRIPT)
  43                 PDFTOPS="pdftops"
  44         else
  45                 AC_MSG_ERROR(Unable to find gs program!)
  46                 exit 1
  47         fi
  48         ;;
  49
  50         x/*/gs) # Use /path/to/gs without any check:
  51         CUPS_GHOSTSCRIPT="$with_pdftops"
  52         AC_DEFINE(HAVE_GHOSTSCRIPT)
  53         PDFTOPS="pdftops"
  54         ;;
  55
  56         xpdftops)
  57         AC_PATH_PROG(CUPS_PDFTOPS, pdftops)
  58         if test "x$CUPS_PDFTOPS" != x; then
  59                 AC_DEFINE(HAVE_PDFTOPS)
  60                 PDFTOPS="pdftops"
  61         else
  62                 AC_MSG_ERROR(Unable to find pdftops program!)
  63                 exit 1
  64         fi
  65         ;;
  66
  67         x/*/pdftops) # Use /path/to/pdftops without any check:
  68         CUPS_PDFTOPS="$with_pdftops"
  69         AC_DEFINE(HAVE_PDFTOPS)
  70         PDFTOPS="pdftops"
  71         ;;
  72
  73         xnone) # Make no pdftops filter if with_pdftops=none:
  74         ;;
  75
  76         *) # Invalid with_pdftops value:
  77         AC_MSG_ERROR(Invalid with_pdftops value!)
  78         exit 1
  79         ;;
  80 esac
  81
  82 AC_DEFINE_UNQUOTED(CUPS_PDFTOPS, "$CUPS_PDFTOPS")
  83 AC_DEFINE_UNQUOTED(CUPS_GHOSTSCRIPT, "$CUPS_GHOSTSCRIPT")
  84 AC_SUBST(PDFTOPS)
  85
  86 dnl
  87 dnl End of "$Id: cups-pdf.m4 7449 2008-04-14 18:27:53Z mike $".
  88 dnl