config-scripts/cups-ssl.m4

   1 dnl
   2 dnl "$Id: cups-ssl.m4 5525 2006-05-15 13:52:16Z mike $"
   3 dnl
   4 dnl   OpenSSL/GNUTLS stuff for the Common UNIX Printing System (CUPS).
   5 dnl
   6 dnl   Copyright 1997-2006 by Easy Software Products, all rights reserved.
   7 dnl
   8 dnl   These coded instructions, statements, and computer programs are the
   9 dnl   property of Easy Software Products and are protected by Federal
  10 dnl   copyright law.  Distribution and use rights are outlined in the file
  11 dnl   "LICENSE.txt" which should have been included with this file.  If this
  12 dnl   file is missing or damaged please contact Easy Software Products
  13 dnl   at:
  14 dnl
  15 dnl       Attn: CUPS Licensing Information
  16 dnl       Easy Software Products
  17 dnl       44141 Airport View Drive, Suite 204
  18 dnl       Hollywood, Maryland 20636 USA
  19 dnl
  20 dnl       Voice: (301) 373-9600
  21 dnl       EMail: cups-info@cups.org
  22 dnl         WWW: http://www.cups.org
  23 dnl
  24
  25 AC_ARG_ENABLE(ssl, [  --enable-ssl            turn on SSL/TLS support, default=yes])
  26 AC_ARG_ENABLE(cdsassl, [  --enable-cdsassl        use CDSA for SSL/TLS support, default=first])
  27 AC_ARG_ENABLE(gnutls, [  --enable-gnutls         use GNU TLS for SSL/TLS support, default=second])
  28 AC_ARG_ENABLE(openssl, [  --enable-openssl        use OpenSSL for SSL/TLS support, default=third])
  29 AC_ARG_WITH(openssl-libs, [  --with-openssl-libs     set directory for OpenSSL library],
  30     LDFLAGS="-L$withval $LDFLAGS"
  31     DSOFLAGS="-L$withval $DSOFLAGS",)
  32 AC_ARG_WITH(openssl-includes, [  --with-openssl-includes set directory for OpenSSL includes],
  33     CFLAGS="-I$withval $CFLAGS"
  34     CXXFLAGS="-I$withval $CXXFLAGS"
  35     CPPFLAGS="-I$withval $CPPFLAGS",)
  36
  37 SSLFLAGS=""
  38 SSLLIBS=""
  39 ENCRYPTION_REQUIRED=""
  40
  41 if test x$enable_ssl != xno; then
  42     dnl Look for CDSA...
  43     if test "x${SSLLIBS}" = "x" -a "x${enable_cdsassl}" != "xno"; then
  44         if test $uname = Darwin; then
  45             AC_CHECK_HEADER(Security/SecureTransport.h,
  46                 [SSLLIBS="-framework CoreFoundation -framework Security"
  47                  # MacOS X doesn't (yet) come with pre-installed encryption
  48                  # certificates for CUPS, so don't enable encryption on
  49                  # /admin just yet...
  50                  #ENCRYPTION_REQUIRED="  Encryption Required"
  51                  AC_DEFINE(HAVE_SSL)
  52                  AC_DEFINE(HAVE_CDSASSL)])
  53         fi
  54     fi
  55
  56     dnl Then look for GNU TLS...
  57     if test "x${SSLLIBS}" = "x" -a "x${enable_gnutls}" != "xno"; then
  58         AC_PATH_PROG(LIBGNUTLSCONFIG,libgnutls-config)
  59         if test "x$LIBGNUTLSCONFIG" != x; then
  60             SSLLIBS=`$LIBGNUTLSCONFIG --libs`
  61             SSLFLAGS=`$LIBGNUTLSCONFIG --cflags`
  62             ENCRYPTION_REQUIRED="  Encryption Required"
  63             AC_DEFINE(HAVE_SSL)
  64             AC_DEFINE(HAVE_GNUTLS)
  65         fi
  66     fi
  67
  68     dnl Check for the OpenSSL library last...
  69     if test "x${SSLLIBS}" = "x" -a "x${enable_openssl}" != "xno"; then
  70         AC_CHECK_HEADER(openssl/ssl.h,
  71             dnl Save the current libraries so the crypto stuff isn't always
  72             dnl included...
  73             SAVELIBS="$LIBS"
  74
  75             dnl Some ELF systems can't resolve all the symbols in libcrypto
  76             dnl if libcrypto was linked against RSAREF, and fail to link the
  77             dnl test program correctly, even though a correct installation
  78             dnl of OpenSSL exists.  So we test the linking three times in
  79             dnl case the RSAREF libraries are needed.
  80
  81             for libcrypto in \
  82                 "-lcrypto" \
  83                 "-lcrypto -lrsaref" \
  84                 "-lcrypto -lRSAglue -lrsaref"
  85             do
  86                 AC_CHECK_LIB(ssl,SSL_new,
  87                     [SSLFLAGS="-DOPENSSL_DISABLE_OLD_DES_SUPPORT"
  88                      SSLLIBS="-lssl $libcrypto"
  89                      ENCRYPTION_REQUIRED="  Encryption Required"
  90                      AC_DEFINE(HAVE_SSL)
  91                      AC_DEFINE(HAVE_LIBSSL)],,
  92                     $libcrypto)
  93
  94                 if test "x${SSLLIBS}" != "x"; then
  95                     break
  96                 fi
  97             done
  98
  99             LIBS="$SAVELIBS")
 100     fi
 101 fi
 102
 103 if test "x$SSLLIBS" != x; then
 104     AC_MSG_RESULT([    Using SSLLIBS="$SSLLIBS"])
 105     AC_MSG_RESULT([    Using SSLFLAGS="$SSLFLAGS"])
 106 fi
 107
 108 AC_SUBST(SSLFLAGS)
 109 AC_SUBST(SSLLIBS)
 110 AC_SUBST(ENCRYPTION_REQUIRED)
 111
 112 EXPORT_SSLLIBS="$SSLLIBS"
 113 AC_SUBST(EXPORT_SSLLIBS)
 114
 115
 116 dnl
 117 dnl End of "$Id: cups-ssl.m4 5525 2006-05-15 13:52:16Z mike $".
 118 dnl