configure.in

   1 dnl
   2 dnl "$Id: configure.in,v 1.93 2001/05/31 19:33:10 mike Exp $"
   3 dnl
   4 dnl   Configuration script for the Common UNIX Printing System (CUPS).
   5 dnl
   6 dnl   Copyright 1997-2001 by Easy Software Products, all rights reserved.
   7 dnl
   8 dnl   These coded instructions, statements, and computer programs are the
   9 dnl   property of Easy Software Products and are protected by Federal
  10 dnl   copyright law.  Distribution and use rights are outlined in the file
  11 dnl   "LICENSE.txt" which should have been included with this file.  If this
  12 dnl   file is missing or damaged please contact Easy Software Products
  13 dnl   at:
  14 dnl
  15 dnl       Attn: CUPS Licensing Information
  16 dnl       Easy Software Products
  17 dnl       44141 Airport View Drive, Suite 204
  18 dnl       Hollywood, Maryland 20636-3111 USA
  19 dnl
  20 dnl       Voice: (301) 373-9603
  21 dnl       EMail: cups-info@cups.org
  22 dnl         WWW: http://www.cups.org
  23 dnl
  24
  25 AC_INIT(cups/cups.h)
  26 AC_CONFIG_HEADER(config.h)
  27 AC_PREFIX_DEFAULT(/)
  28
  29 dnl Get the operating system and version number...
  30
  31 uname=`uname`
  32 uversion=`uname -r | sed -e '1,$s/[[^0-9]]//g'`
  33 if test "$uname" = "IRIX64"; then
  34     uname="IRIX"
  35 fi
  36
  37 dnl Clear the debugging and non-shared library options unless the user asks
  38 dnl for them...
  39
  40 OPTIM=""
  41 AC_SUBST(OPTIM)
  42 PICFLAG=1
  43 CFLAGS="${CFLAGS:=}"
  44 CXXFLAGS="${CXXFLAGS:=}"
  45 DSOFLAGS="${DSOFLAGS:=}"
  46 AC_SUBST(DSOFLAGS)
  47
  48 AC_ARG_ENABLE(debug, [  --enable-debug        turn on debugging [default=no]],[if eval "test x$enable_debug = xyes"; then
  49         OPTIM="-g"
  50 fi])
  51 AC_ARG_ENABLE(shared, [  --enable-shared        turn on shared libraries [default=yes]])
  52 AC_ARG_ENABLE(ssl, [  --enable-ssl           turn on SSL/TLS support [default=no]])
  53 AC_ARG_ENABLE(libtool_unsupported, [  --enable-libtool-unsupported=LIBTOOL_PATH
  54                           turn on building with libtool (UNSUPPORTED!) [default=no]],[if eval "test x$enable_libtool_unsupported != xno"; then
  55         LIBTOOL="$enable_libtool_unsupported"
  56         enable_shared=no
  57         echo "WARNING: libtool is not supported or endorsed by Easy Software Products."
  58         echo "         WE DO NOT PROVIDE TECHNICAL SUPPORT FOR LIBTOOL PROBLEMS."
  59         echo "         (even if you have a support contract)"
  60 else
  61         LIBTOOL=""
  62 fi])
  63
  64 if test "$enable_shared" != "no"; then
  65         case "$uname" in
  66                 SunOS* | UNIX_S*)
  67                         LIBCUPS="libcups.so.2"
  68                         LIBCUPSIMAGE="libcupsimage.so.2"
  69                         DSO="\$(CC)"
  70                         DSOFLAGS="$DSOFLAGS -Wl,-h,\$@ -G \$(OPTIM)"
  71                         ;;
  72                 HP-UX*)
  73                         LIBCUPS="libcups.sl.2"
  74                         LIBCUPSIMAGE="libcupsimage.sl.2"
  75                         DSO="ld"
  76                         DSOFLAGS="$DSOFLAGS -b -z +h \$@"
  77                         ;;
  78                 FreeBSD* | NetBSD* | OpenBSD*)
  79                         LIBCUPS="libcups.so.2"
  80                         LIBCUPSIMAGE="libcupsimage.so.2"
  81                         DSO="\$(CC)"
  82                         DSOFLAGS="$DSOFLAGS -Wl,-soname,\$@ -shared \$(OPTIM)"
  83                         ;;
  84                 OSF1* | Linux*)
  85                         LIBCUPS="libcups.so.2"
  86                         LIBCUPSIMAGE="libcupsimage.so.2"
  87                         DSO="\$(CC)"
  88                         DSOFLAGS="$DSOFLAGS -Wl,-soname,\$@ -shared \$(OPTIM)"
  89                         ;;
  90                 IRIX*)
  91                         LIBCUPS="libcups.so.2"
  92                         LIBCUPSIMAGE="libcupsimage.so.2"
  93                         DSO="\$(CC)"
  94                         DSOFLAGS="$DSOFLAGS -soname \$@ -shared \$(OPTIM)"
  95                         ;;
  96                 AIX*)
  97                         AC_MSG_WARN(Shared library support for AIX not available yet - defaulting to static)
  98                         enable_shared=no
  99                         PICFLAG=0
 100                         LIBCUPS="libcups.a"
 101                         LIBCUPSIMAGE="libcupsimage.a"
 102                         DSO=":"
 103                         ;;
 104                 *)
 105                         echo "Warning: shared libraries may not be supported.  Trying -shared"
 106                         echo "         option with compiler."
 107                         LIBCUPS="libcups.so.2"
 108                         LIBCUPSIMAGE="libcupsimage.so.2"
 109                         DSO="\$(CC)"
 110                         DSOFLAGS="$DSOFLAGS -Wl,-soname,\$@ -shared \$(OPTIM)"
 111                         ;;
 112         esac
 113 else
 114         PICFLAG=0
 115         LIBCUPS="libcups.a"
 116         LIBCUPSIMAGE="libcupsimage.a"
 117         DSO=":"
 118 fi
 119
 120 if test "$LIBTOOL" != ""; then
 121         LIBCUPS="libcups.la"
 122         LIBCUPSIMAGE="libcupsimage.la"
 123         LINKCUPS="../cups/\$(LIBCUPS)"
 124         LINKCUPSIMAGE="../filter/\$(LIBCUPSIMAGE)"
 125         DSO=":"
 126         DSOFLAGS=""
 127 else
 128         LINKCUPS="-L../cups -lcups"
 129         LINKCUPSIMAGE="-L../filter -lcupsimage"
 130
 131         if test $enable_shared = no; then
 132                 LINKCUPS="$LINKCUPS \$(SSLLIBS)"
 133         fi
 134 fi
 135
 136 AC_ARG_ENABLE(pam, [  --enable-pam        turn on PAM support [default=yes]])
 137
 138 # Don't use PAM with AIX...
 139 if test $uname = AIX; then
 140         enable_pam=no
 141 fi
 142
 143 AC_ARG_WITH(fontpath, [  --with-fontpath     set font path for pstoraster],fontpath="$withval",fontpath="")
 144 AC_ARG_WITH(docdir, [  --with-docdir       set path for documentation],docdir="$withval",docdir="")
 145 AC_ARG_WITH(logdir, [  --with-logdir       set path for log files],logdir="$withval",logdir="")
 146 AC_ARG_WITH(rcdir, [  --with-rcdir        set path for rc scripts],rcdir="$withval",rcdir="")
 147
 148 dnl Checks for programs...
 149 AC_PROG_AWK
 150 AC_PROG_CC
 151 AC_PROG_CXX
 152 AC_PROG_CPP
 153 AC_PROG_RANLIB
 154 AC_PATH_PROG(AR,ar)
 155 AC_PATH_PROG(CHMOD,chmod)
 156 AC_PATH_PROG(CHOWN,chown)
 157 AC_PATH_PROG(CP,cp)
 158 AC_PATH_PROG(MV,mv)
 159 AC_PATH_PROG(NROFF,nroff)
 160 if test "$NROFF" = ""; then
 161     AC_PATH_PROG(GROFF,groff)
 162     if test "$GROFF" = ""; then
 163         NROFF="echo"
 164     else
 165         NROFF="$GROFF -T ascii"
 166     fi
 167 fi
 168 AC_PATH_PROG(HTMLDOC,htmldoc)
 169 AC_PATH_PROG(MKDIR,mkdir)
 170 AC_PATH_PROG(RM,rm)
 171 AC_PATH_PROG(SED,sed)
 172
 173 dnl Architecture checks...
 174 AC_C_BIGENDIAN
 175
 176 dnl Check for libraries...
 177 AC_CHECK_LIB(c,crypt,LIBS="$LIBS")
 178 if test "$ac_cv_lib_c_crypt" = "no"; then
 179         AC_CHECK_LIB(crypt,crypt)
 180 fi
 181 AC_CHECK_LIB(sec,getspent)
 182 AC_CHECK_LIB(gen,getspent)
 183
 184 LIBMALLOC=""
 185 AC_CHECK_LIB(c,mallinfo,LIBS="$LIBS"; AC_DEFINE(HAVE_MALLINFO),LIBS="$LIBS")
 186 if test "$ac_cv_lib_c_mallinfo" = "no"; then
 187         AC_CHECK_LIB(malloc,mallinfo,
 188                      LIBS="$LIBS"
 189                      LIBMALLOC="-lmalloc"
 190                      AC_DEFINE(HAVE_MALLINFO),
 191                      LIBS="$LIBS")
 192 fi
 193 AC_SUBST(LIBMALLOC)
 194
 195 if test "$enable_pam" != "no"; then
 196         OLDLIBS="$LIBS"
 197         AC_CHECK_LIB(dl,dlopen)
 198         AC_CHECK_LIB(pam,pam_start)
 199         if test "$ac_cv_lib_pam_pam_start" != "no"; then
 200                 if test -d /etc/pam.d; then
 201                         PAMDIR="/etc/pam.d"
 202                 fi
 203         else
 204                 PAMDIR=""
 205                 LIBS="$OLDLIBS"
 206         fi
 207         AC_SUBST(PAMDIR)
 208 fi
 209
 210 NETLIBS=""
 211 AC_SUBST(NETLIBS)
 212 AC_CHECK_LIB(socket,socket,
 213 if test "$uname" != "IRIX"; then
 214         NETLIBS="-lsocket"
 215 else
 216         echo "Not using -lsocket since you are running IRIX."
 217 fi)
 218 AC_CHECK_LIB(nsl,gethostbyaddr,
 219 if test "$uname" != "IRIX"; then
 220         NETLIBS="$NETLIBS -lnsl"
 221 else
 222         echo "Not using -lnsl since you are running IRIX."
 223 fi)
 224
 225 dnl Encryption support...
 226
 227 SSLLIBS=""
 228 AC_SUBST(SSLLIBS)
 229
 230 if test "$enable_ssl" = "yes"; then
 231         dnl Save the current libraries so the crypto stuff isn't always
 232         dnl included...
 233         SAVELIBS="$LIBS"
 234
 235         dnl Some ELF systems can't resolve all the symbols in libcrypto
 236         dnl if libcrypto was linked against RSAREF, and fail to link the
 237         dnl test program correctly, even though a correct installation
 238         dnl of OpenSSL exists.  So we test the linking three times in
 239         dnl case the RSAREF libraries are needed.
 240
 241         for libcrypto in \
 242                 "-lcrypto" \
 243                 "-lcrypto -lrsaref" \
 244                 "-lcrypto -lRSAglue -lrsaref"
 245         do
 246                 AC_CHECK_LIB(ssl,SSL_new,
 247                         [SSLLIBS="-lssl $libcrypto"
 248                          AC_DEFINE(HAVE_LIBSSL)],,
 249                         $libcrypto
 250                 )
 251                 if test "x${SSLLIBS}" != "x"; then
 252                         break
 253                 fi
 254         done
 255
 256         LIBS="$SAVELIBS"
 257 fi
 258
 259 dnl Save the current libraries since we don't want the image libraries
 260 dnl included with every program...
 261 SAVELIBS="$LIBS"
 262
 263 dnl Check for image libraries...
 264 LIBJPEG=""
 265 LIBPNG=""
 266 LIBTIFF=""
 267 LIBZ=""
 268
 269 AC_SUBST(LIBJPEG)
 270 AC_SUBST(LIBPNG)
 271 AC_SUBST(LIBTIFF)
 272 AC_SUBST(LIBZ)
 273
 274 AC_CHECK_LIB(jpeg, jpeg_destroy_decompress,
 275     AC_DEFINE(HAVE_LIBJPEG)
 276     LIBJPEG="-ljpeg"
 277     LIBS="$LIBS -ljpeg")
 278
 279 AC_CHECK_LIB(z, gzgets,
 280     AC_DEFINE(HAVE_LIBZ)
 281     LIBZ="-lz"
 282     LIBS="$LIBS -lz")
 283
 284 dnl PNG library uses math library functions...
 285 AC_CHECK_LIB(m, pow)
 286
 287 AC_CHECK_LIB(png, png_set_tRNS_to_alpha,
 288     AC_DEFINE(HAVE_LIBPNG)
 289     LIBPNG="-lpng")
 290
 291 AC_CHECK_LIB(tiff, TIFFReadScanline,
 292     AC_DEFINE(HAVE_LIBTIFF)
 293     LIBTIFF="-ltiff")
 294
 295 dnl Restore original LIBS settings...
 296 LIBS="$SAVELIBS"
 297
 298 dnl Checks for header files.
 299 AC_HEADER_STDC
 300 AC_HEADER_DIRENT
 301 AC_CHECK_HEADER(crypt.h,AC_DEFINE(HAVE_CRYPT_H))
 302 AC_CHECK_HEADER(malloc.h,AC_DEFINE(HAVE_MALLOC_H))
 303 AC_CHECK_HEADER(shadow.h,AC_DEFINE(HAVE_SHADOW_H))
 304 AC_CHECK_HEADER(stddef.h,AC_DEFINE(HAVE_STDDEF_H))
 305 AC_CHECK_HEADER(stdlib.h,AC_DEFINE(HAVE_STDLIB_H))
 306 AC_CHECK_HEADER(string.h,AC_DEFINE(HAVE_STRING_H))
 307 AC_CHECK_HEADER(strings.h,AC_DEFINE(HAVE_STRINGS_H))
 308 AC_CHECK_HEADER(usersec.h,AC_DEFINE(HAVE_USERSEC_H))
 309 AC_CHECK_HEADER(sys/ioctl.h,AC_DEFINE(HAVE_SYS_IOCTL_H))
 310
 311 dnl Checks for string functions.
 312 AC_CHECK_FUNCS(strdup)
 313 AC_CHECK_FUNCS(strcasecmp)
 314 AC_CHECK_FUNCS(strncasecmp)
 315 if test "$uname" = "HP-UX" -a "$uversion" = "1020"; then
 316         echo Forcing snprintf emulation for HP-UX.
 317 else
 318         AC_CHECK_FUNCS(snprintf)
 319         AC_CHECK_FUNCS(vsnprintf)
 320 fi
 321
 322 dnl Check OS version and use appropriate format string for strftime...
 323 AC_MSG_CHECKING(for correct format string to use with strftime)
 324
 325 case "$uname" in
 326         IRIX* | SunOS*)
 327                 # IRIX and SunOS
 328                 AC_MSG_RESULT(NULL)
 329                 AC_DEFINE(CUPS_STRFTIME_FORMAT, NULL)
 330                 ;;
 331         *)
 332                 # All others
 333                 AC_MSG_RESULT("%c")
 334                 AC_DEFINE(CUPS_STRFTIME_FORMAT, "%c")
 335                 ;;
 336 esac
 337
 338 dnl Checks for vsyslog function.
 339 AC_CHECK_FUNCS(vsyslog)
 340
 341 dnl Checks for signal functions.
 342 if test "$uname" != "Linux"; then
 343         AC_CHECK_FUNCS(sigset)
 344 fi
 345
 346 AC_CHECK_FUNCS(sigaction)
 347
 348 dnl Checks for wait functions.
 349 AC_CHECK_FUNCS(waitpid)
 350 AC_CHECK_FUNCS(wait3)
 351
 352 dnl Update compiler options...
 353 if test -n "$GCC"; then
 354         CXX="$CC"
 355
 356         if test -z "$OPTIM"; then
 357                 OPTIM="-O2"
 358         fi
 359         if test $PICFLAG = 1; then
 360                 OPTIM="-fPIC $OPTIM"
 361         fi
 362         OPTIM="-Wall $OPTIM"
 363 else
 364         case $uname in
 365                 AIX*)
 366                         if test -z "$OPTIM"; then
 367                                 OPTIM="-O2 -qmaxmem=6000"
 368                         fi
 369                         ;;
 370                 HP-UX*)
 371                         if test -z "$OPTIM"; then
 372                                 OPTIM="+O2"
 373                         fi
 374                         CFLAGS="-Ae $CFLAGS"
 375                         OPTIM="+DAportable $OPTIM"
 376                         if test $PICFLAG = 1; then
 377                                 OPTIM="+z $OPTIM"
 378                         fi
 379                         ;;
 380                 IRIX*)
 381                         if test -z "$OPTIM"; then
 382                                 OPTIM="-O2"
 383                         fi
 384                         if test $uversion -ge 62; then
 385                                 OPTIM="$OPTIM -n32 -mips3"
 386                         fi
 387                         OPTIM="-fullwarn $OPTIM"
 388                         ;;
 389                 SunOS*)
 390                         # Solaris
 391                         if test -z "$OPTIM"; then
 392                                 OPTIM="-xO4"
 393                         fi
 394                         OPTIM="$OPTIM -xarch=generic"
 395                         if test $PICFLAG = 1; then
 396                                 OPTIM="-KPIC $OPTIM"
 397                         fi
 398                         ;;
 399                 UNIX_SVR*)
 400                         # UnixWare
 401                         if test -z "$OPTIM"; then
 402                                 OPTIM="-O"
 403                         fi
 404                         if test $PICFLAG = 1; then
 405                                 OPTIM="-KPIC $OPTIM"
 406                         fi
 407                         ;;
 408                 *)
 409                         # Running some other operating system; inform the user they
 410                         # should contribute the necessary options to
 411                         # cups-support@cups.org...
 412                         echo "Building CUPS with default compiler optimizations; contact"
 413                         echo "cups-support@cups.org with uname and compiler options needed"
 414                         echo "for your platform, or set the CFLAGS environment variable"
 415                         echo "before running configure."
 416                         ;;
 417         esac
 418 fi
 419
 420 if test "$DSO" != ":"; then
 421         # When using DSOs the image libraries are linked to libcupsimage.so
 422         # rather than to the executables.  This makes things smaller if you
 423         # are using any static libraries, and it also allows us to distribute
 424         # a single DSO rather than a bunch...
 425         DSOLIBS="\$(LIBPNG) \$(LIBTIFF) \$(LIBJPEG) \$(LIBZ)"
 426         IMGLIBS=""
 427
 428         # The *BSD, HP-UX, and Solaris run-time linkers need help when
 429         # deciding where to find a DSO.  Add linker options to tell them
 430         # where to find the DSO (usually in /usr/lib...  duh!)
 431         case $uname in
 432                 HP-UX*)
 433                         # HP-UX
 434                         DSOFLAGS="+b $libdir +fb $DSOFLAGS"
 435                         LDFLAGS="$LDFLAGS -Wl,+b,$libdir,+fb"
 436                         ;;
 437                 SunOS*)
 438                         # Solaris
 439                         DSOFLAGS="-R$libdir $DSOFLAGS"
 440                         LDFLAGS="$LDFLAGS -R$libdir"
 441                         ;;
 442                 FreeBSD* | NetBSD* | OpenBSD*)
 443                         # *BSD
 444                         DSOFLAGS="-Wl,-R$libdir $DSOFLAGS"
 445                         LDFLAGS="$LDFLAGS -Wl,-R$libdir"
 446                         ;;
 447         esac
 448 else
 449         DSOLIBS=""
 450         IMGLIBS="\$(LIBPNG) \$(LIBTIFF) \$(LIBJPEG) \$(LIBZ)"
 451 fi
 452
 453 AC_SUBST(DSO)
 454 AC_SUBST(DSOLIBS)
 455 AC_SUBST(IMGLIBS)
 456 AC_SUBST(LIBCUPS)
 457 AC_SUBST(LIBCUPSIMAGE)
 458 AC_SUBST(LIBTOOL)
 459 AC_SUBST(LINKCUPS)
 460 AC_SUBST(LINKCUPSIMAGE)
 461
 462 dnl Fix "prefix" variable if it hasn't been specified...
 463 if test "$prefix" = "NONE"; then
 464         prefix="/"
 465 fi
 466
 467 dnl Fix "exec_prefix" variable if it hasn't been specified...
 468 if test "$exec_prefix" = "NONE"; then
 469         if test "$prefix" = "/"; then
 470                 exec_prefix="/usr"
 471         else
 472                 exec_prefix="$prefix"
 473         fi
 474 fi
 475
 476 dnl Fix "sharedstatedir" variable if it hasn't been specified...
 477 if test "$sharedstatedir" = "\${prefix}/com" -a "$prefix" = "/"; then
 478         sharedstatedir="/usr/com"
 479 fi
 480
 481 dnl Fix "datadir" variable if it hasn't been specified...
 482 if test "$datadir" = "\${prefix}/share"; then
 483         if test "$prefix" = "/"; then
 484                 datadir="/usr/share"
 485         else
 486                 datadir="$prefix/share"
 487         fi
 488 fi
 489
 490 dnl Fix "includedir" variable if it hasn't been specified...
 491 if test "$includedir" = "\${prefix}/include" -a "$prefix" = "/"; then
 492         includedir="/usr/include"
 493 fi
 494
 495 dnl Fix "localstatedir" variable if it hasn't been specified...
 496 if test "$localstatedir" = "\${prefix}/var"; then
 497         if test "$prefix" = "/"; then
 498                 localstatedir="/var"
 499         else
 500                 localstatedir="$prefix/var"
 501         fi
 502 fi
 503
 504 dnl Fix "sysconfdir" variable if it hasn't been specified...
 505 if test "$sysconfdir" = "\${prefix}/etc"; then
 506         if test "$prefix" = "/"; then
 507                 sysconfdir="/etc"
 508         else
 509                 sysconfdir="$prefix/etc"
 510         fi
 511 fi
 512
 513 dnl Fix "libdir" variable for IRIX 6.x...
 514 if test "$uname" = "IRIX" -a $uversion -ge 62; then
 515         libdir="$exec_prefix/lib32"
 516 fi
 517
 518 dnl Fix "mandir" variable...
 519 if test "$mandir" = "\${prefix}/man" -a "$prefix" = "/"; then
 520         case "$uname" in
 521                 FreeBSD* | NetBSD* | OpenBSD* | AIX*)
 522                         # *BSD + AIX
 523                         mandir="/usr/share/man"
 524                         AMANDIR="/usr/share/man"
 525                         ;;
 526                 IRIX*)
 527                         # SGI IRIX
 528                         mandir="/usr/share/catman/u_man"
 529                         AMANDIR="/usr/share/catman/a_man"
 530                         ;;
 531                 *)
 532                         # All others
 533                         mandir="/usr/man"
 534                         AMANDIR="/usr/man"
 535                         ;;
 536         esac
 537 else
 538         AMANDIR="$mandir"
 539 fi
 540
 541 AC_SUBST(AMANDIR)
 542
 543 dnl Fix "fontpath" variable...
 544 if test "x$fontpath" = "x"; then
 545         fontpath="$datadir/cups/fonts"
 546 fi
 547
 548 dnl Setup manpage extensions...
 549 case "$uname" in
 550         FreeBSD* | NetBSD* | OpenBSD*)
 551                 # *BSD
 552                 CAT1EXT=0
 553                 CAT5EXT=0
 554                 CAT8EXT=0
 555                 MAN8EXT=8
 556                 ;;
 557         IRIX*)
 558                 # SGI IRIX
 559                 CAT1EXT=z
 560                 CAT5EXT=z
 561                 CAT8EXT=z
 562                 MAN8EXT=1m
 563                 ;;
 564         SunOS* | HP-UX*)
 565                 # Solaris and HP-UX
 566                 CAT1EXT=1
 567                 CAT5EXT=5
 568                 CAT8EXT=1m
 569                 MAN8EXT=1m
 570                 ;;
 571         *)
 572                 # All others
 573                 CAT1EXT=1
 574                 CAT5EXT=5
 575                 CAT8EXT=8
 576                 MAN8EXT=8
 577                 ;;
 578 esac
 579
 580 AC_SUBST(CAT1EXT)
 581 AC_SUBST(CAT5EXT)
 582 AC_SUBST(CAT8EXT)
 583 AC_SUBST(MAN8EXT)
 584
 585 dnl Setup init.d locations...
 586 if test x$rcdir = x; then
 587         case "$uname" in
 588                 FreeBSD* | OpenBSD*)
 589                         # FreeBSD and OpenBSD
 590                         INITDIR=""
 591                         INITDDIR=""
 592                         ;;
 593
 594                 NetBSD*)
 595                         # NetBSD
 596                         INITDIR=""
 597                         INITDDIR="/etc/rc.d"
 598                         ;;
 599
 600                 Linux*)
 601                         # Linux seems to choose an init.d directory at random...
 602                         if test -d /sbin/init.d; then
 603                                 # SuSE
 604                                 INITDIR="/sbin/init.d"
 605                                 INITDDIR=".."
 606                         else
 607                                 if test -d /etc/rc.d; then
 608                                         # RedHat
 609                                         INITDIR="/etc/rc.d"
 610                                         INITDDIR="../init.d"
 611                                 else
 612                                         # Others
 613                                         INITDIR="/etc"
 614                                         INITDDIR="../init.d"
 615                                 fi
 616                         fi
 617                         ;;
 618
 619                 OSF1* | HP-UX*)
 620                         INITDIR="/sbin"
 621                         INITDDIR="../init.d"
 622                         ;;
 623
 624                 AIX*)
 625                         INITDIR="/etc/rc.d"
 626                         INITDDIR=".."
 627                         ;;
 628
 629                 *)
 630                         INITDIR="/etc"
 631                         INITDDIR="../init.d"
 632                         ;;
 633
 634         esac
 635 else
 636         INITDIR=""
 637         INITDDIR="$rcdir"
 638 fi
 639
 640 AC_SUBST(INITDIR)
 641 AC_SUBST(INITDDIR)
 642
 643 dnl Setup default locations...
 644 CUPS_SERVERROOT='${sysconfdir}/cups'
 645 CUPS_REQUESTS='${localstatedir}/spool/cups'
 646
 647 AC_DEFINE_UNQUOTED(CUPS_SERVERROOT, "$sysconfdir/cups")
 648 AC_DEFINE_UNQUOTED(CUPS_REQUESTS, "$localstatedir/spool/cups")
 649
 650 if test x$logdir = x; then
 651         CUPS_LOGDIR='${localstatedir}/log/cups'
 652         AC_DEFINE_UNQUOTED(CUPS_LOGDIR, "$localstatedir/log/cups")
 653 else
 654         CUPS_LOGDIR="$logdir"
 655         AC_DEFINE_UNQUOTED(CUPS_LOGDIR, "$logdir")
 656 fi
 657
 658 dnl See what directory to put server executables...
 659 case "$uname" in
 660         FreeBSD* | NetBSD* | OpenBSD*)
 661                 # *BSD
 662                 INSTALL_SYSV=""
 663                 CUPS_SERVERBIN='${exec_prefix}/libexec/cups'
 664                 AC_DEFINE_UNQUOTED(CUPS_SERVERBIN, "$exec_prefix/libexec/cups")
 665                 ;;
 666         *)
 667                 # All others
 668                 INSTALL_SYSV="install-sysv"
 669                 CUPS_SERVERBIN='${exec_prefix}/lib/cups'
 670                 AC_DEFINE_UNQUOTED(CUPS_SERVERBIN, "$exec_prefix/lib/cups")
 671                 ;;
 672 esac
 673
 674 AC_SUBST(INSTALL_SYSV)
 675 AC_SUBST(CUPS_SERVERROOT)
 676 AC_SUBST(CUPS_SERVERBIN)
 677 AC_SUBST(CUPS_LOGDIR)
 678 AC_SUBST(CUPS_REQUESTS)
 679
 680 dnl Set the CUPS_LOCALE directory...
 681 case "$uname" in
 682         Linux* | FreeBSD* | NetBSD* | OpenBSD*)
 683                 CUPS_LOCALEDIR='${datadir}/locale'
 684                 AC_DEFINE_UNQUOTED(CUPS_LOCALEDIR, "$datadir/locale")
 685                 ;;
 686
 687         OSF1* | AIX*)
 688                 CUPS_LOCALEDIR='${exec_prefix}/lib/nls/msg'
 689                 AC_DEFINE_UNQUOTED(CUPS_LOCALEDIR, "$exec_prefix/lib/nls/msg")
 690                 ;;
 691
 692         *)
 693                 # This is the standard System V location...
 694                 CUPS_LOCALEDIR='${exec_prefix}/lib/locale'
 695                 AC_DEFINE_UNQUOTED(CUPS_LOCALEDIR, "$exec_prefix/lib/locale")
 696                 ;;
 697 esac
 698
 699 AC_SUBST(CUPS_LOCALEDIR)
 700
 701 dnl Set the CUPS_DATADIR directory...
 702 CUPS_DATADIR='${datadir}/cups'
 703 AC_DEFINE_UNQUOTED(CUPS_DATADIR, "$datadir/cups")
 704 AC_SUBST(CUPS_DATADIR)
 705
 706 dnl Set the CUPS_DOCROOT directory...
 707 if test x$docdir = x; then
 708         CUPS_DOCROOT='${datadir}/doc/cups'
 709         docdir="$datadir/doc/cups"
 710 else
 711         CUPS_DOCROOT="$docdir"
 712 fi
 713
 714 AC_DEFINE_UNQUOTED(CUPS_DOCROOT, "$docdir")
 715 AC_SUBST(CUPS_DOCROOT)
 716
 717 dnl Set the CUPS_FONTPATH directory...
 718 AC_DEFINE_UNQUOTED(CUPS_FONTPATH, "$fontpath")
 719
 720 AC_OUTPUT(Makedefs cups.sh)
 721
 722 dnl
 723 dnl End of "$Id: configure.in,v 1.93 2001/05/31 19:33:10 mike Exp $".
 724 dnl