configure.in

   1 dnl
   2 dnl "$Id: configure.in,v 1.95 2001/06/22 19:21:47 mike Exp $"
   3 dnl
   4 dnl   Configuration script for the Common UNIX Printing System (CUPS).
   5 dnl
   6 dnl   Copyright 1997-2001 by Easy Software Products, all rights reserved.
   7 dnl
   8 dnl   These coded instructions, statements, and computer programs are the
   9 dnl   property of Easy Software Products and are protected by Federal
  10 dnl   copyright law.  Distribution and use rights are outlined in the file
  11 dnl   "LICENSE.txt" which should have been included with this file.  If this
  12 dnl   file is missing or damaged please contact Easy Software Products
  13 dnl   at:
  14 dnl
  15 dnl       Attn: CUPS Licensing Information
  16 dnl       Easy Software Products
  17 dnl       44141 Airport View Drive, Suite 204
  18 dnl       Hollywood, Maryland 20636-3111 USA
  19 dnl
  20 dnl       Voice: (301) 373-9603
  21 dnl       EMail: cups-info@cups.org
  22 dnl         WWW: http://www.cups.org
  23 dnl
  24
  25 AC_INIT(cups/cups.h)
  26 AC_CONFIG_HEADER(config.h)
  27 AC_PREFIX_DEFAULT(/)
  28
  29 dnl Get the operating system and version number...
  30
  31 uname=`uname`
  32 uversion=`uname -r | sed -e '1,$s/[[^0-9]]//g'`
  33 if test "$uname" = "IRIX64"; then
  34     uname="IRIX"
  35 fi
  36
  37 dnl Clear the debugging and non-shared library options unless the user asks
  38 dnl for them...
  39
  40 OPTIM=""
  41 AC_SUBST(OPTIM)
  42 PICFLAG=1
  43 CFLAGS="${CFLAGS:=}"
  44 CXXFLAGS="${CXXFLAGS:=}"
  45 DSOFLAGS="${DSOFLAGS:=}"
  46 AC_SUBST(DSOFLAGS)
  47
  48 AC_ARG_ENABLE(debug, [  --enable-debug        turn on debugging [default=no]],[if eval "test x$enable_debug = xyes"; then
  49         OPTIM="-g"
  50 fi])
  51 AC_ARG_ENABLE(shared, [  --enable-shared        turn on shared libraries [default=yes]])
  52 AC_ARG_ENABLE(ssl, [  --enable-ssl           turn on SSL/TLS support [default=no]])
  53 AC_ARG_ENABLE(libtool_unsupported, [  --enable-libtool-unsupported=LIBTOOL_PATH
  54                           turn on building with libtool (UNSUPPORTED!) [default=no]],[if eval "test x$enable_libtool_unsupported != xno"; then
  55         LIBTOOL="$enable_libtool_unsupported"
  56         enable_shared=no
  57         echo "WARNING: libtool is not supported or endorsed by Easy Software Products."
  58         echo "         WE DO NOT PROVIDE TECHNICAL SUPPORT FOR LIBTOOL PROBLEMS."
  59         echo "         (even if you have a support contract)"
  60 else
  61         LIBTOOL=""
  62 fi])
  63
  64 if test "$enable_shared" != "no"; then
  65         case "$uname" in
  66                 SunOS* | UNIX_S*)
  67                         LIBCUPS="libcups.so.2"
  68                         LIBCUPSIMAGE="libcupsimage.so.2"
  69                         DSO="\$(CC)"
  70                         DSOFLAGS="$DSOFLAGS -Wl,-h,\$@ -G \$(OPTIM)"
  71                         ;;
  72                 HP-UX*)
  73                         LIBCUPS="libcups.sl.2"
  74                         LIBCUPSIMAGE="libcupsimage.sl.2"
  75                         DSO="ld"
  76                         DSOFLAGS="$DSOFLAGS -b -z +h \$@"
  77                         ;;
  78                 FreeBSD* | NetBSD* | OpenBSD*)
  79                         LIBCUPS="libcups.so.2"
  80                         LIBCUPSIMAGE="libcupsimage.so.2"
  81                         DSO="\$(CC)"
  82                         DSOFLAGS="$DSOFLAGS -Wl,-soname,\$@ -shared \$(OPTIM)"
  83                         ;;
  84                 OSF1* | Linux*)
  85                         LIBCUPS="libcups.so.2"
  86                         LIBCUPSIMAGE="libcupsimage.so.2"
  87                         DSO="\$(CC)"
  88                         DSOFLAGS="$DSOFLAGS -Wl,-soname,\$@ -shared \$(OPTIM)"
  89                         ;;
  90                 IRIX*)
  91                         LIBCUPS="libcups.so.2"
  92                         LIBCUPSIMAGE="libcupsimage.so.2"
  93                         DSO="\$(CC)"
  94                         DSOFLAGS="$DSOFLAGS -soname \$@ -shared \$(OPTIM)"
  95                         ;;
  96                 AIX*)
  97                         AC_MSG_WARN(Shared library support for AIX not available yet - defaulting to static)
  98                         enable_shared=no
  99                         PICFLAG=0
 100                         LIBCUPS="libcups.a"
 101                         LIBCUPSIMAGE="libcupsimage.a"
 102                         DSO=":"
 103                         ;;
 104                 *)
 105                         echo "Warning: shared libraries may not be supported.  Trying -shared"
 106                         echo "         option with compiler."
 107                         LIBCUPS="libcups.so.2"
 108                         LIBCUPSIMAGE="libcupsimage.so.2"
 109                         DSO="\$(CC)"
 110                         DSOFLAGS="$DSOFLAGS -Wl,-soname,\$@ -shared \$(OPTIM)"
 111                         ;;
 112         esac
 113 else
 114         PICFLAG=0
 115         LIBCUPS="libcups.a"
 116         LIBCUPSIMAGE="libcupsimage.a"
 117         DSO=":"
 118 fi
 119
 120 if test "$LIBTOOL" != ""; then
 121         LIBCUPS="libcups.la"
 122         LIBCUPSIMAGE="libcupsimage.la"
 123         LINKCUPS="../cups/\$(LIBCUPS)"
 124         LINKCUPSIMAGE="../filter/\$(LIBCUPSIMAGE)"
 125         DSO=":"
 126         DSOFLAGS=""
 127 else
 128         LINKCUPS="-L../cups -lcups"
 129         LINKCUPSIMAGE="-L../filter -lcupsimage"
 130
 131         if test $enable_shared = no; then
 132                 LINKCUPS="$LINKCUPS \$(SSLLIBS)"
 133         fi
 134 fi
 135
 136 AC_ARG_ENABLE(pam, [  --enable-pam        turn on PAM support [default=yes]])
 137
 138 # Don't use PAM with AIX...
 139 if test $uname = AIX; then
 140         enable_pam=no
 141 fi
 142
 143 AC_ARG_WITH(fontpath, [  --with-fontpath     set font path for pstoraster],fontpath="$withval",fontpath="")
 144 AC_ARG_WITH(docdir, [  --with-docdir       set path for documentation],docdir="$withval",docdir="")
 145 AC_ARG_WITH(logdir, [  --with-logdir       set path for log files],logdir="$withval",logdir="")
 146 AC_ARG_WITH(rcdir, [  --with-rcdir        set path for rc scripts],rcdir="$withval",rcdir="")
 147
 148 dnl Checks for programs...
 149 AC_PROG_AWK
 150 AC_PROG_CC
 151 AC_PROG_CXX
 152 AC_PROG_CPP
 153 AC_PROG_RANLIB
 154 AC_PATH_PROG(AR,ar)
 155 AC_PATH_PROG(CHMOD,chmod)
 156 AC_PATH_PROG(CHOWN,chown)
 157 AC_PATH_PROG(CP,cp)
 158 AC_PATH_PROG(MV,mv)
 159 AC_PATH_PROG(NROFF,nroff)
 160 if test "$NROFF" = ""; then
 161     AC_PATH_PROG(GROFF,groff)
 162     if test "$GROFF" = ""; then
 163         NROFF="echo"
 164     else
 165         NROFF="$GROFF -T ascii"
 166     fi
 167 fi
 168 AC_PATH_PROG(HTMLDOC,htmldoc)
 169 AC_PATH_PROG(MKDIR,mkdir)
 170 AC_PATH_PROG(RM,rm)
 171 AC_PATH_PROG(SED,sed)
 172
 173 dnl Architecture checks...
 174 AC_C_BIGENDIAN
 175
 176 dnl Check for libraries...
 177 AC_CHECK_LIB(c,crypt,LIBS="$LIBS")
 178 if test "$ac_cv_lib_c_crypt" = "no"; then
 179         AC_CHECK_LIB(crypt,crypt)
 180 fi
 181 AC_CHECK_LIB(sec,getspent)
 182 AC_CHECK_LIB(gen,getspent)
 183
 184 LIBMALLOC=""
 185 AC_CHECK_LIB(c,mallinfo,LIBS="$LIBS"; AC_DEFINE(HAVE_MALLINFO),LIBS="$LIBS")
 186 if test "$ac_cv_lib_c_mallinfo" = "no"; then
 187         AC_CHECK_LIB(malloc,mallinfo,
 188                      LIBS="$LIBS"
 189                      LIBMALLOC="-lmalloc"
 190                      AC_DEFINE(HAVE_MALLINFO),
 191                      LIBS="$LIBS")
 192 fi
 193 AC_SUBST(LIBMALLOC)
 194
 195 if test "$enable_pam" != "no"; then
 196         OLDLIBS="$LIBS"
 197         AC_CHECK_LIB(dl,dlopen)
 198         AC_CHECK_LIB(pam,pam_start)
 199         if test "$ac_cv_lib_pam_pam_start" != "no"; then
 200                 if test -d /etc/pam.d; then
 201                         PAMDIR="/etc/pam.d"
 202                 fi
 203         else
 204                 PAMDIR=""
 205                 LIBS="$OLDLIBS"
 206         fi
 207         AC_SUBST(PAMDIR)
 208 fi
 209
 210 NETLIBS=""
 211 AC_SUBST(NETLIBS)
 212 AC_CHECK_LIB(socket,socket,
 213 if test "$uname" != "IRIX"; then
 214         NETLIBS="-lsocket"
 215 else
 216         echo "Not using -lsocket since you are running IRIX."
 217 fi)
 218 AC_CHECK_LIB(nsl,gethostbyaddr,
 219 if test "$uname" != "IRIX"; then
 220         NETLIBS="$NETLIBS -lnsl"
 221 else
 222         echo "Not using -lnsl since you are running IRIX."
 223 fi)
 224
 225 dnl Encryption support...
 226
 227 SSLLIBS=""
 228 AC_SUBST(SSLLIBS)
 229
 230 if test "$enable_ssl" = "yes"; then
 231         dnl Save the current libraries so the crypto stuff isn't always
 232         dnl included...
 233         SAVELIBS="$LIBS"
 234
 235         dnl Some ELF systems can't resolve all the symbols in libcrypto
 236         dnl if libcrypto was linked against RSAREF, and fail to link the
 237         dnl test program correctly, even though a correct installation
 238         dnl of OpenSSL exists.  So we test the linking three times in
 239         dnl case the RSAREF libraries are needed.
 240
 241         for libcrypto in \
 242                 "-lcrypto" \
 243                 "-lcrypto -lrsaref" \
 244                 "-lcrypto -lRSAglue -lrsaref"
 245         do
 246                 AC_CHECK_LIB(ssl,SSL_new,
 247                         [SSLLIBS="-lssl $libcrypto"
 248                          AC_DEFINE(HAVE_LIBSSL)],,
 249                         $libcrypto
 250                 )
 251                 if test "x${SSLLIBS}" != "x"; then
 252                         break
 253                 fi
 254         done
 255
 256         LIBS="$SAVELIBS"
 257 fi
 258
 259 dnl Save the current libraries since we don't want the image libraries
 260 dnl included with every program...
 261 SAVELIBS="$LIBS"
 262
 263 dnl Check for image libraries...
 264 LIBJPEG=""
 265 LIBPNG=""
 266 LIBTIFF=""
 267 LIBZ=""
 268
 269 AC_SUBST(LIBJPEG)
 270 AC_SUBST(LIBPNG)
 271 AC_SUBST(LIBTIFF)
 272 AC_SUBST(LIBZ)
 273
 274 AC_CHECK_HEADER(jpeglib.h,
 275     AC_CHECK_LIB(jpeg, jpeg_destroy_decompress,
 276         AC_DEFINE(HAVE_LIBJPEG)
 277         LIBJPEG="-ljpeg"
 278         LIBS="$LIBS -ljpeg"))
 279
 280 AC_CHECK_HEADER(zlib.h,
 281     AC_CHECK_LIB(z, gzgets,
 282         AC_DEFINE(HAVE_LIBZ)
 283         LIBZ="-lz"
 284         LIBS="$LIBS -lz"))
 285
 286 dnl PNG library uses math library functions...
 287 AC_CHECK_LIB(m, pow)
 288
 289 AC_CHECK_HEADER(png.h,
 290     AC_CHECK_LIB(png, png_set_tRNS_to_alpha,
 291         AC_DEFINE(HAVE_LIBPNG)
 292         LIBPNG="-lpng"))
 293
 294 AC_CHECK_HEADER(tiff.h,
 295     AC_CHECK_LIB(tiff, TIFFReadScanline,
 296         AC_DEFINE(HAVE_LIBTIFF)
 297         LIBTIFF="-ltiff"))
 298
 299 dnl Restore original LIBS settings...
 300 LIBS="$SAVELIBS"
 301
 302 dnl Checks for header files.
 303 AC_HEADER_STDC
 304 AC_HEADER_DIRENT
 305 AC_CHECK_HEADER(crypt.h,AC_DEFINE(HAVE_CRYPT_H))
 306 AC_CHECK_HEADER(malloc.h,AC_DEFINE(HAVE_MALLOC_H))
 307 AC_CHECK_HEADER(shadow.h,AC_DEFINE(HAVE_SHADOW_H))
 308 AC_CHECK_HEADER(stddef.h,AC_DEFINE(HAVE_STDDEF_H))
 309 AC_CHECK_HEADER(stdlib.h,AC_DEFINE(HAVE_STDLIB_H))
 310 AC_CHECK_HEADER(string.h,AC_DEFINE(HAVE_STRING_H))
 311 AC_CHECK_HEADER(strings.h,AC_DEFINE(HAVE_STRINGS_H))
 312 AC_CHECK_HEADER(usersec.h,AC_DEFINE(HAVE_USERSEC_H))
 313 AC_CHECK_HEADER(sys/ioctl.h,AC_DEFINE(HAVE_SYS_IOCTL_H))
 314
 315 dnl Checks for string functions.
 316 AC_CHECK_FUNCS(strdup)
 317 AC_CHECK_FUNCS(strcasecmp)
 318 AC_CHECK_FUNCS(strncasecmp)
 319 if test "$uname" = "HP-UX" -a "$uversion" = "1020"; then
 320         echo Forcing snprintf emulation for HP-UX.
 321 else
 322         AC_CHECK_FUNCS(snprintf)
 323         AC_CHECK_FUNCS(vsnprintf)
 324 fi
 325
 326 dnl Check OS version and use appropriate format string for strftime...
 327 AC_MSG_CHECKING(for correct format string to use with strftime)
 328
 329 case "$uname" in
 330         IRIX* | SunOS*)
 331                 # IRIX and SunOS
 332                 AC_MSG_RESULT(NULL)
 333                 AC_DEFINE(CUPS_STRFTIME_FORMAT, NULL)
 334                 ;;
 335         *)
 336                 # All others
 337                 AC_MSG_RESULT("%c")
 338                 AC_DEFINE(CUPS_STRFTIME_FORMAT, "%c")
 339                 ;;
 340 esac
 341
 342 dnl Checks for mkstemp function.
 343 AC_CHECK_FUNCS(mkstemp)
 344
 345 dnl Checks for vsyslog function.
 346 AC_CHECK_FUNCS(vsyslog)
 347
 348 dnl Checks for signal functions.
 349 if test "$uname" != "Linux"; then
 350         AC_CHECK_FUNCS(sigset)
 351 fi
 352
 353 AC_CHECK_FUNCS(sigaction)
 354
 355 dnl Checks for wait functions.
 356 AC_CHECK_FUNCS(waitpid)
 357 AC_CHECK_FUNCS(wait3)
 358
 359 dnl Update compiler options...
 360 if test -n "$GCC"; then
 361         CXX="$CC"
 362
 363         if test -z "$OPTIM"; then
 364                 OPTIM="-O2"
 365         fi
 366         if test $PICFLAG = 1; then
 367                 OPTIM="-fPIC $OPTIM"
 368         fi
 369         OPTIM="-Wall $OPTIM"
 370 else
 371         case $uname in
 372                 AIX*)
 373                         if test -z "$OPTIM"; then
 374                                 OPTIM="-O2 -qmaxmem=6000"
 375                         fi
 376                         ;;
 377                 HP-UX*)
 378                         if test -z "$OPTIM"; then
 379                                 OPTIM="+O2"
 380                         fi
 381                         CFLAGS="-Ae $CFLAGS"
 382                         OPTIM="+DAportable $OPTIM"
 383                         if test $PICFLAG = 1; then
 384                                 OPTIM="+z $OPTIM"
 385                         fi
 386                         ;;
 387                 IRIX*)
 388                         if test -z "$OPTIM"; then
 389                                 OPTIM="-O2"
 390                         fi
 391                         if test $uversion -ge 62; then
 392                                 OPTIM="$OPTIM -n32 -mips3"
 393                         fi
 394                         OPTIM="-fullwarn $OPTIM"
 395                         ;;
 396                 SunOS*)
 397                         # Solaris
 398                         if test -z "$OPTIM"; then
 399                                 OPTIM="-xO4"
 400                         fi
 401                         OPTIM="$OPTIM -xarch=generic"
 402                         if test $PICFLAG = 1; then
 403                                 OPTIM="-KPIC $OPTIM"
 404                         fi
 405                         ;;
 406                 UNIX_SVR*)
 407                         # UnixWare
 408                         if test -z "$OPTIM"; then
 409                                 OPTIM="-O"
 410                         fi
 411                         if test $PICFLAG = 1; then
 412                                 OPTIM="-KPIC $OPTIM"
 413                         fi
 414                         ;;
 415                 *)
 416                         # Running some other operating system; inform the user they
 417                         # should contribute the necessary options to
 418                         # cups-support@cups.org...
 419                         echo "Building CUPS with default compiler optimizations; contact"
 420                         echo "cups-support@cups.org with uname and compiler options needed"
 421                         echo "for your platform, or set the CFLAGS environment variable"
 422                         echo "before running configure."
 423                         ;;
 424         esac
 425 fi
 426
 427 if test "$DSO" != ":"; then
 428         # When using DSOs the image libraries are linked to libcupsimage.so
 429         # rather than to the executables.  This makes things smaller if you
 430         # are using any static libraries, and it also allows us to distribute
 431         # a single DSO rather than a bunch...
 432         DSOLIBS="\$(LIBPNG) \$(LIBTIFF) \$(LIBJPEG) \$(LIBZ)"
 433         IMGLIBS=""
 434
 435         # The *BSD, HP-UX, and Solaris run-time linkers need help when
 436         # deciding where to find a DSO.  Add linker options to tell them
 437         # where to find the DSO (usually in /usr/lib...  duh!)
 438         case $uname in
 439                 HP-UX*)
 440                         # HP-UX
 441                         DSOFLAGS="+b $libdir +fb $DSOFLAGS"
 442                         LDFLAGS="$LDFLAGS -Wl,+b,$libdir,+fb"
 443                         ;;
 444                 SunOS*)
 445                         # Solaris
 446                         DSOFLAGS="-R$libdir $DSOFLAGS"
 447                         LDFLAGS="$LDFLAGS -R$libdir"
 448                         ;;
 449                 FreeBSD* | NetBSD* | OpenBSD*)
 450                         # *BSD
 451                         DSOFLAGS="-Wl,-R$libdir $DSOFLAGS"
 452                         LDFLAGS="$LDFLAGS -Wl,-R$libdir"
 453                         ;;
 454         esac
 455 else
 456         DSOLIBS=""
 457         IMGLIBS="\$(LIBPNG) \$(LIBTIFF) \$(LIBJPEG) \$(LIBZ)"
 458 fi
 459
 460 AC_SUBST(DSO)
 461 AC_SUBST(DSOLIBS)
 462 AC_SUBST(IMGLIBS)
 463 AC_SUBST(LIBCUPS)
 464 AC_SUBST(LIBCUPSIMAGE)
 465 AC_SUBST(LIBTOOL)
 466 AC_SUBST(LINKCUPS)
 467 AC_SUBST(LINKCUPSIMAGE)
 468
 469 dnl Fix "prefix" variable if it hasn't been specified...
 470 if test "$prefix" = "NONE"; then
 471         prefix="/"
 472 fi
 473
 474 dnl Fix "exec_prefix" variable if it hasn't been specified...
 475 if test "$exec_prefix" = "NONE"; then
 476         if test "$prefix" = "/"; then
 477                 exec_prefix="/usr"
 478         else
 479                 exec_prefix="$prefix"
 480         fi
 481 fi
 482
 483 dnl Fix "sharedstatedir" variable if it hasn't been specified...
 484 if test "$sharedstatedir" = "\${prefix}/com" -a "$prefix" = "/"; then
 485         sharedstatedir="/usr/com"
 486 fi
 487
 488 dnl Fix "datadir" variable if it hasn't been specified...
 489 if test "$datadir" = "\${prefix}/share"; then
 490         if test "$prefix" = "/"; then
 491                 datadir="/usr/share"
 492         else
 493                 datadir="$prefix/share"
 494         fi
 495 fi
 496
 497 dnl Fix "includedir" variable if it hasn't been specified...
 498 if test "$includedir" = "\${prefix}/include" -a "$prefix" = "/"; then
 499         includedir="/usr/include"
 500 fi
 501
 502 dnl Fix "localstatedir" variable if it hasn't been specified...
 503 if test "$localstatedir" = "\${prefix}/var"; then
 504         if test "$prefix" = "/"; then
 505                 localstatedir="/var"
 506         else
 507                 localstatedir="$prefix/var"
 508         fi
 509 fi
 510
 511 dnl Fix "sysconfdir" variable if it hasn't been specified...
 512 if test "$sysconfdir" = "\${prefix}/etc"; then
 513         if test "$prefix" = "/"; then
 514                 sysconfdir="/etc"
 515         else
 516                 sysconfdir="$prefix/etc"
 517         fi
 518 fi
 519
 520 dnl Fix "libdir" variable for IRIX 6.x...
 521 if test "$uname" = "IRIX" -a $uversion -ge 62; then
 522         libdir="$exec_prefix/lib32"
 523 fi
 524
 525 dnl Fix "mandir" variable...
 526 if test "$mandir" = "\${prefix}/man" -a "$prefix" = "/"; then
 527         case "$uname" in
 528                 FreeBSD* | NetBSD* | OpenBSD* | AIX*)
 529                         # *BSD + AIX
 530                         mandir="/usr/share/man"
 531                         AMANDIR="/usr/share/man"
 532                         ;;
 533                 IRIX*)
 534                         # SGI IRIX
 535                         mandir="/usr/share/catman/u_man"
 536                         AMANDIR="/usr/share/catman/a_man"
 537                         ;;
 538                 *)
 539                         # All others
 540                         mandir="/usr/man"
 541                         AMANDIR="/usr/man"
 542                         ;;
 543         esac
 544 else
 545         AMANDIR="$mandir"
 546 fi
 547
 548 AC_SUBST(AMANDIR)
 549
 550 dnl Fix "fontpath" variable...
 551 if test "x$fontpath" = "x"; then
 552         fontpath="$datadir/cups/fonts"
 553 fi
 554
 555 dnl Setup manpage extensions...
 556 case "$uname" in
 557         FreeBSD* | NetBSD* | OpenBSD*)
 558                 # *BSD
 559                 CAT1EXT=0
 560                 CAT5EXT=0
 561                 CAT8EXT=0
 562                 MAN8EXT=8
 563                 ;;
 564         IRIX*)
 565                 # SGI IRIX
 566                 CAT1EXT=z
 567                 CAT5EXT=z
 568                 CAT8EXT=z
 569                 MAN8EXT=1m
 570                 ;;
 571         SunOS* | HP-UX*)
 572                 # Solaris and HP-UX
 573                 CAT1EXT=1
 574                 CAT5EXT=5
 575                 CAT8EXT=1m
 576                 MAN8EXT=1m
 577                 ;;
 578         *)
 579                 # All others
 580                 CAT1EXT=1
 581                 CAT5EXT=5
 582                 CAT8EXT=8
 583                 MAN8EXT=8
 584                 ;;
 585 esac
 586
 587 AC_SUBST(CAT1EXT)
 588 AC_SUBST(CAT5EXT)
 589 AC_SUBST(CAT8EXT)
 590 AC_SUBST(MAN8EXT)
 591
 592 dnl Setup init.d locations...
 593 if test x$rcdir = x; then
 594         case "$uname" in
 595                 FreeBSD* | OpenBSD*)
 596                         # FreeBSD and OpenBSD
 597                         INITDIR=""
 598                         INITDDIR=""
 599                         ;;
 600
 601                 NetBSD*)
 602                         # NetBSD
 603                         INITDIR=""
 604                         INITDDIR="/etc/rc.d"
 605                         ;;
 606
 607                 Linux*)
 608                         # Linux seems to choose an init.d directory at random...
 609                         if test -d /sbin/init.d; then
 610                                 # SuSE
 611                                 INITDIR="/sbin/init.d"
 612                                 INITDDIR=".."
 613                         else
 614                                 if test -d /etc/rc.d; then
 615                                         # RedHat
 616                                         INITDIR="/etc/rc.d"
 617                                         INITDDIR="../init.d"
 618                                 else
 619                                         # Others
 620                                         INITDIR="/etc"
 621                                         INITDDIR="../init.d"
 622                                 fi
 623                         fi
 624                         ;;
 625
 626                 OSF1* | HP-UX*)
 627                         INITDIR="/sbin"
 628                         INITDDIR="../init.d"
 629                         ;;
 630
 631                 AIX*)
 632                         INITDIR="/etc/rc.d"
 633                         INITDDIR=".."
 634                         ;;
 635
 636                 *)
 637                         INITDIR="/etc"
 638                         INITDDIR="../init.d"
 639                         ;;
 640
 641         esac
 642 else
 643         INITDIR=""
 644         INITDDIR="$rcdir"
 645 fi
 646
 647 AC_SUBST(INITDIR)
 648 AC_SUBST(INITDDIR)
 649
 650 dnl Setup default locations...
 651 CUPS_SERVERROOT='${sysconfdir}/cups'
 652 CUPS_REQUESTS='${localstatedir}/spool/cups'
 653
 654 AC_DEFINE_UNQUOTED(CUPS_SERVERROOT, "$sysconfdir/cups")
 655 AC_DEFINE_UNQUOTED(CUPS_REQUESTS, "$localstatedir/spool/cups")
 656
 657 if test x$logdir = x; then
 658         CUPS_LOGDIR='${localstatedir}/log/cups'
 659         AC_DEFINE_UNQUOTED(CUPS_LOGDIR, "$localstatedir/log/cups")
 660 else
 661         CUPS_LOGDIR="$logdir"
 662         AC_DEFINE_UNQUOTED(CUPS_LOGDIR, "$logdir")
 663 fi
 664
 665 dnl See what directory to put server executables...
 666 case "$uname" in
 667         FreeBSD* | NetBSD* | OpenBSD*)
 668                 # *BSD
 669                 INSTALL_SYSV=""
 670                 CUPS_SERVERBIN='${exec_prefix}/libexec/cups'
 671                 AC_DEFINE_UNQUOTED(CUPS_SERVERBIN, "$exec_prefix/libexec/cups")
 672                 ;;
 673         *)
 674                 # All others
 675                 INSTALL_SYSV="install-sysv"
 676                 CUPS_SERVERBIN='${exec_prefix}/lib/cups'
 677                 AC_DEFINE_UNQUOTED(CUPS_SERVERBIN, "$exec_prefix/lib/cups")
 678                 ;;
 679 esac
 680
 681 AC_SUBST(INSTALL_SYSV)
 682 AC_SUBST(CUPS_SERVERROOT)
 683 AC_SUBST(CUPS_SERVERBIN)
 684 AC_SUBST(CUPS_LOGDIR)
 685 AC_SUBST(CUPS_REQUESTS)
 686
 687 dnl Set the CUPS_LOCALE directory...
 688 case "$uname" in
 689         Linux* | FreeBSD* | NetBSD* | OpenBSD*)
 690                 CUPS_LOCALEDIR='${datadir}/locale'
 691                 AC_DEFINE_UNQUOTED(CUPS_LOCALEDIR, "$datadir/locale")
 692                 ;;
 693
 694         OSF1* | AIX*)
 695                 CUPS_LOCALEDIR='${exec_prefix}/lib/nls/msg'
 696                 AC_DEFINE_UNQUOTED(CUPS_LOCALEDIR, "$exec_prefix/lib/nls/msg")
 697                 ;;
 698
 699         *)
 700                 # This is the standard System V location...
 701                 CUPS_LOCALEDIR='${exec_prefix}/lib/locale'
 702                 AC_DEFINE_UNQUOTED(CUPS_LOCALEDIR, "$exec_prefix/lib/locale")
 703                 ;;
 704 esac
 705
 706 AC_SUBST(CUPS_LOCALEDIR)
 707
 708 dnl Set the CUPS_DATADIR directory...
 709 CUPS_DATADIR='${datadir}/cups'
 710 AC_DEFINE_UNQUOTED(CUPS_DATADIR, "$datadir/cups")
 711 AC_SUBST(CUPS_DATADIR)
 712
 713 dnl Set the CUPS_DOCROOT directory...
 714 if test x$docdir = x; then
 715         CUPS_DOCROOT='${datadir}/doc/cups'
 716         docdir="$datadir/doc/cups"
 717 else
 718         CUPS_DOCROOT="$docdir"
 719 fi
 720
 721 AC_DEFINE_UNQUOTED(CUPS_DOCROOT, "$docdir")
 722 AC_SUBST(CUPS_DOCROOT)
 723
 724 dnl Set the CUPS_FONTPATH directory...
 725 AC_DEFINE_UNQUOTED(CUPS_FONTPATH, "$fontpath")
 726
 727 AC_OUTPUT(Makedefs cups.sh)
 728
 729 dnl
 730 dnl End of "$Id: configure.in,v 1.95 2001/06/22 19:21:47 mike Exp $".
 731 dnl