configure.in

   1 dnl
   2 dnl "$Id: configure.in,v 1.83.2.2 2001/05/13 18:37:58 mike Exp $"
   3 dnl
   4 dnl   Configuration script for the Common UNIX Printing System (CUPS).
   5 dnl
   6 dnl   Copyright 1997-2001 by Easy Software Products, all rights reserved.
   7 dnl
   8 dnl   These coded instructions, statements, and computer programs are the
   9 dnl   property of Easy Software Products and are protected by Federal
  10 dnl   copyright law.  Distribution and use rights are outlined in the file
  11 dnl   "LICENSE.txt" which should have been included with this file.  If this
  12 dnl   file is missing or damaged please contact Easy Software Products
  13 dnl   at:
  14 dnl
  15 dnl       Attn: CUPS Licensing Information
  16 dnl       Easy Software Products
  17 dnl       44141 Airport View Drive, Suite 204
  18 dnl       Hollywood, Maryland 20636-3111 USA
  19 dnl
  20 dnl       Voice: (301) 373-9603
  21 dnl       EMail: cups-info@cups.org
  22 dnl         WWW: http://www.cups.org
  23 dnl
  24
  25 AC_INIT(cups/cups.h)
  26 AC_CONFIG_HEADER(config.h)
  27 AC_PREFIX_DEFAULT(/)
  28
  29 dnl Get the operating system and version number...
  30
  31 uname=`uname`
  32 uversion=`uname -r | sed -e '1,$s/[[^0-9]]//g'`
  33 if test "$uname" = "IRIX64"; then
  34     uname="IRIX"
  35 fi
  36
  37 dnl Clear the debugging and non-shared library options unless the user asks
  38 dnl for them...
  39
  40 OPTIM=""
  41 AC_SUBST(OPTIM)
  42 PICFLAG=1
  43 CFLAGS="${CFLAGS:=}"
  44 CXXFLAGS="${CXXFLAGS:=}"
  45 DSOFLAGS="${DSOFLAGS:=}"
  46 AC_SUBST(DSOFLAGS)
  47
  48 AC_ARG_ENABLE(debug, [  --enable-debug        turn on debugging [default=no]],[if eval "test x$enable_debug = xyes"; then
  49         OPTIM="-g"
  50 fi])
  51 AC_ARG_ENABLE(shared, [  --enable-shared        turn on shared libraries [default=yes]])
  52 AC_ARG_ENABLE(ssl, [  --enable-ssl           turn on SSL/TLS support [default=yes]])
  53 AC_ARG_ENABLE(libtool_unsupported, [  --enable-libtool-unsupported=LIBTOOL_PATH
  54                           turn on building with libtool (UNSUPPORTED!) [default=no]],[if eval "test x$enable_libtool_unsupported != xno"; then
  55         LIBTOOL="$enable_libtool_unsupported"
  56         enable_shared=no
  57         echo "WARNING: libtool is not supported or endorsed by Easy Software Products."
  58         echo "         WE DO NOT PROVIDE TECHNICAL SUPPORT FOR LIBTOOL PROBLEMS."
  59         echo "         (even if you have a support contract)"
  60 else
  61         LIBTOOL=""
  62 fi])
  63
  64 if test "$enable_shared" != "no"; then
  65         case "$uname" in
  66                 SunOS* | UNIX_S*)
  67                         LIBCUPS="libcups.so.3"
  68                         LIBCUPSIMAGE="libcupsimage.so.2"
  69                         DSO="\$(CC)"
  70                         DSOFLAGS="$DSOFLAGS -Wl,-h,\$@ -G \$(OPTIM)"
  71                         ;;
  72                 HP-UX*)
  73                         LIBCUPS="libcups.sl.3"
  74                         LIBCUPSIMAGE="libcupsimage.sl.2"
  75                         DSO="ld"
  76                         DSOFLAGS="$DSOFLAGS -b -z +h \$@"
  77                         ;;
  78                 FreeBSD* | NetBSD* | OpenBSD*)
  79                         LIBCUPS="libcups.so.3"
  80                         LIBCUPSIMAGE="libcupsimage.so.2"
  81                         DSO="\$(CC)"
  82                         DSOFLAGS="$DSOFLAGS -Wl,-soname,\$@ -shared \$(OPTIM)"
  83                         ;;
  84                 OSF1* | Linux*)
  85                         LIBCUPS="libcups.so.3"
  86                         LIBCUPSIMAGE="libcupsimage.so.2"
  87                         DSO="\$(CC)"
  88                         DSOFLAGS="$DSOFLAGS -Wl,-soname,\$@ -shared \$(OPTIM)"
  89                         ;;
  90                 IRIX*)
  91                         LIBCUPS="libcups.so.3"
  92                         LIBCUPSIMAGE="libcupsimage.so.2"
  93                         DSO="\$(CC)"
  94                         DSOFLAGS="$DSOFLAGS -soname \$@ -shared \$(OPTIM)"
  95                         ;;
  96                 AIX*)
  97                         AC_MSG_WARN(Shared library support for AIX not available yet - defaulting to static)
  98                         enable_shared=no
  99                         PICFLAG=0
 100                         LIBCUPS="libcups.a"
 101                         LIBCUPSIMAGE="libcupsimage.a"
 102                         DSO=":"
 103                         ;;
 104                 *)
 105                         echo "Warning: shared libraries may not be supported.  Trying -shared"
 106                         echo "         option with compiler."
 107                         LIBCUPS="libcups.so.3"
 108                         LIBCUPSIMAGE="libcupsimage.so.2"
 109                         DSO="\$(CC)"
 110                         DSOFLAGS="$DSOFLAGS -Wl,-soname,\$@ -shared \$(OPTIM)"
 111                         ;;
 112         esac
 113 else
 114         PICFLAG=0
 115         LIBCUPS="libcups.a"
 116         LIBCUPSIMAGE="libcupsimage.a"
 117         DSO=":"
 118 fi
 119
 120 if test "$LIBTOOL" != ""; then
 121         LIBCUPS="libcups.la"
 122         LIBCUPSIMAGE="libcupsimage.la"
 123         LINKCUPS="../cups/\$(LIBCUPS)"
 124         LINKCUPSIMAGE="../filter/\$(LIBCUPSIMAGE)"
 125         DSO=":"
 126         DSOFLAGS=""
 127 else
 128         LINKCUPS="-L../cups -lcups"
 129         LINKCUPSIMAGE="-L../filter -lcupsimage"
 130 fi
 131
 132 AC_ARG_ENABLE(pam, [  --enable-pam        turn on PAM support [default=yes]])
 133
 134 # Don't use PAM with AIX...
 135 if test $uname = AIX; then
 136         enable_pam=no
 137 fi
 138
 139 AC_ARG_WITH(fontpath, [  --with-fontpath     set font path for pstoraster],fontpath="$withval",fontpath="")
 140 AC_ARG_WITH(docdir, [  --with-docdir       set path for documentation],docdir="$withval",docdir="")
 141 AC_ARG_WITH(logdir, [  --with-logdir       set path for log files],logdir="$withval",logdir="")
 142
 143 dnl Checks for programs...
 144 AC_PROG_AWK
 145 AC_PROG_CC
 146 AC_PROG_CXX
 147 AC_PROG_CPP
 148 AC_PROG_RANLIB
 149 AC_PATH_PROG(AR,ar)
 150 AC_PATH_PROG(CHMOD,chmod)
 151 AC_PATH_PROG(CHOWN,chown)
 152 AC_PATH_PROG(CP,cp)
 153 AC_PATH_PROG(MV,mv)
 154 AC_PATH_PROG(NROFF,nroff)
 155 if test "$NROFF" = ""; then
 156     AC_PATH_PROG(GROFF,groff)
 157     if test "$GROFF" = ""; then
 158         NROFF="echo"
 159     else
 160         NROFF="$GROFF -T ascii"
 161     fi
 162 fi
 163 AC_PATH_PROG(HTMLDOC,htmldoc)
 164 AC_PATH_PROG(MKDIR,mkdir)
 165 AC_PATH_PROG(RM,rm)
 166 AC_PATH_PROG(SED,sed)
 167
 168 dnl Architecture checks...
 169 AC_C_BIGENDIAN
 170
 171 dnl Check for libraries...
 172 AC_CHECK_LIB(c,crypt,LIBS="$LIBS")
 173 if test "$ac_cv_lib_c_crypt" = "no"; then
 174         AC_CHECK_LIB(crypt,crypt)
 175 fi
 176 AC_CHECK_LIB(sec,getspent)
 177
 178 LIBMALLOC=""
 179 AC_CHECK_LIB(c,mallinfo,LIBS="$LIBS"; AC_DEFINE(HAVE_MALLINFO),LIBS="$LIBS")
 180 if test "$ac_cv_lib_c_mallinfo" = "no"; then
 181         AC_CHECK_LIB(malloc,mallinfo,
 182                      LIBS="$LIBS"
 183                      LIBMALLOC="-lmalloc"
 184                      AC_DEFINE(HAVE_MALLINFO),
 185                      LIBS="$LIBS")
 186 fi
 187 AC_SUBST(LIBMALLOC)
 188
 189 if test "$enable_pam" != "no"; then
 190         OLDLIBS="$LIBS"
 191         AC_CHECK_LIB(dl,dlopen)
 192         AC_CHECK_LIB(pam,pam_start)
 193         if test "$ac_cv_lib_pam_pam_start" != "no"; then
 194                 PAMDIR="/etc/pam.d"
 195         else
 196                 PAMDIR=""
 197                 LIBS="$OLDLIBS"
 198         fi
 199         AC_SUBST(PAMDIR)
 200 fi
 201
 202 NETLIBS=""
 203 AC_SUBST(NETLIBS)
 204 AC_CHECK_LIB(socket,socket,
 205 if test "$uname" != "IRIX"; then
 206         NETLIBS="-lsocket"
 207 else
 208         echo "Not using -lsocket since you are running IRIX."
 209 fi)
 210 AC_CHECK_LIB(nsl,gethostbyaddr,
 211 if test "$uname" != "IRIX"; then
 212         NETLIBS="$NETLIBS -lnsl"
 213 else
 214         echo "Not using -lnsl since you are running IRIX."
 215 fi)
 216
 217 dnl Encryption support...
 218
 219 SSLLIBS=""
 220 AC_SUBST(SSLLIBS)
 221
 222 if test "$enable_ssl" != "no"; then
 223         dnl Save the current libraries so the crypto stuff isn't always
 224         dnl included...
 225         SAVELIBS="$LIBS"
 226
 227         dnl Some ELF systems can't resolve all the symbols in libcrypto
 228         dnl if libcrypto was linked against RSAREF, and fail to link the
 229         dnl test program correctly, even though a correct installation
 230         dnl of OpenSSL exists.  So we test the linking three times in
 231         dnl case the RSAREF libraries are needed.
 232
 233         for libcrypto in \
 234                 "-lcrypto" \
 235                 "-lcrypto -lrsaref" \
 236                 "-lcrypto -lRSAglue -lrsaref"
 237         do
 238                 AC_CHECK_LIB(ssl,SSL_new,
 239                         [SSLLIBS="-lssl $libcrypto"
 240                          AC_DEFINE(HAVE_LIBSSL)],,
 241                         $libcrypto
 242                 )
 243                 if test "x${SSLLIBS}" != "x"; then
 244                         break
 245                 fi
 246         done
 247
 248         LIBS="$SAVELIBS"
 249 fi
 250
 251 dnl Save the current libraries since we don't want the image libraries
 252 dnl included with every program...
 253 SAVELIBS="$LIBS"
 254
 255 dnl Check for image libraries...
 256 LIBJPEG=""
 257 LIBPNG=""
 258 LIBTIFF=""
 259 LIBZ=""
 260
 261 AC_SUBST(LIBJPEG)
 262 AC_SUBST(LIBPNG)
 263 AC_SUBST(LIBTIFF)
 264 AC_SUBST(LIBZ)
 265
 266 AC_CHECK_LIB(jpeg, jpeg_destroy_decompress,
 267     AC_DEFINE(HAVE_LIBJPEG)
 268     LIBJPEG="-ljpeg"
 269     LIBS="$LIBS -ljpeg")
 270
 271 AC_CHECK_LIB(z, gzgets,
 272     AC_DEFINE(HAVE_LIBZ)
 273     LIBZ="-lz"
 274     LIBS="$LIBS -lz")
 275
 276 dnl PNG library uses math library functions...
 277 AC_CHECK_LIB(m, pow)
 278
 279 AC_CHECK_LIB(png, png_set_tRNS_to_alpha,
 280     AC_DEFINE(HAVE_LIBPNG)
 281     LIBPNG="-lpng")
 282
 283 AC_CHECK_LIB(tiff, TIFFReadScanline,
 284     AC_DEFINE(HAVE_LIBTIFF)
 285     LIBTIFF="-ltiff")
 286
 287 dnl Restore original LIBS settings...
 288 LIBS="$SAVELIBS"
 289
 290 dnl Checks for header files.
 291 AC_HEADER_STDC
 292 AC_HEADER_DIRENT
 293 AC_CHECK_HEADER(crypt.h,AC_DEFINE(HAVE_CRYPT_H))
 294 AC_CHECK_HEADER(malloc.h,AC_DEFINE(HAVE_MALLOC_H))
 295 AC_CHECK_HEADER(shadow.h,AC_DEFINE(HAVE_SHADOW_H))
 296 AC_CHECK_HEADER(stddef.h,AC_DEFINE(HAVE_STDDEF_H))
 297 AC_CHECK_HEADER(stdlib.h,AC_DEFINE(HAVE_STDLIB_H))
 298 AC_CHECK_HEADER(string.h,AC_DEFINE(HAVE_STRING_H))
 299 AC_CHECK_HEADER(strings.h,AC_DEFINE(HAVE_STRINGS_H))
 300 AC_CHECK_HEADER(usersec.h,AC_DEFINE(HAVE_USERSEC_H))
 301 AC_CHECK_HEADER(sys/ioctl.h,AC_DEFINE(HAVE_SYS_IOCTL_H))
 302
 303 dnl Checks for string functions.
 304 AC_CHECK_FUNCS(strdup)
 305 AC_CHECK_FUNCS(strcasecmp)
 306 AC_CHECK_FUNCS(strncasecmp)
 307 if test "$uname" = "HP-UX" -a "$uversion" = "1020"; then
 308         echo Forcing snprintf emulation for HP-UX.
 309 else
 310         AC_CHECK_FUNCS(snprintf)
 311         AC_CHECK_FUNCS(vsnprintf)
 312 fi
 313
 314 dnl Check OS version and use appropriate format string for strftime...
 315 AC_MSG_CHECKING(for correct format string to use with strftime)
 316
 317 case "$uname" in
 318         IRIX* | SunOS*)
 319                 # IRIX and SunOS
 320                 AC_MSG_RESULT(NULL)
 321                 AC_DEFINE(CUPS_STRFTIME_FORMAT, NULL)
 322                 ;;
 323         *)
 324                 # All others
 325                 AC_MSG_RESULT("%c")
 326                 AC_DEFINE(CUPS_STRFTIME_FORMAT, "%c")
 327                 ;;
 328 esac
 329
 330 dnl Checks for vsyslog function.
 331 AC_CHECK_FUNCS(vsyslog)
 332
 333 dnl Checks for signal functions.
 334 if test "$uname" != "Linux"; then
 335         AC_CHECK_FUNCS(sigset)
 336 fi
 337
 338 AC_CHECK_FUNCS(sigaction)
 339
 340 dnl Checks for wait functions.
 341 AC_CHECK_FUNCS(waitpid)
 342 AC_CHECK_FUNCS(wait3)
 343
 344 dnl Update compiler options...
 345 if test -n "$GCC"; then
 346         CXX="$CC"
 347
 348         if test -z "$OPTIM"; then
 349                 OPTIM="-O2"
 350         fi
 351         if test $PICFLAG = 1; then
 352                 OPTIM="-fPIC $OPTIM"
 353         fi
 354         OPTIM="-Wall $OPTIM"
 355 else
 356         case $uname in
 357                 AIX*)
 358                         if test -z "$OPTIM"; then
 359                                 OPTIM="-O2 -qmaxmem=6000"
 360                         fi
 361                         ;;
 362                 HP-UX*)
 363                         if test -z "$OPTIM"; then
 364                                 OPTIM="+O2"
 365                         fi
 366                         CFLAGS="-Ae $CFLAGS"
 367                         OPTIM="+DAportable $OPTIM"
 368                         if test $PICFLAG = 1; then
 369                                 OPTIM="+z $OPTIM"
 370                         fi
 371                         ;;
 372                 IRIX*)
 373                         if test -z "$OPTIM"; then
 374                                 OPTIM="-O2"
 375                         fi
 376                         if test $uversion -ge 62; then
 377                                 OPTIM="$OPTIM -n32 -mips3"
 378                         fi
 379                         OPTIM="-fullwarn $OPTIM"
 380                         ;;
 381                 SunOS*)
 382                         # Solaris
 383                         if test -z "$OPTIM"; then
 384                                 OPTIM="-xO4"
 385                         fi
 386                         OPTIM="$OPTIM -xarch=generic"
 387                         if test $PICFLAG = 1; then
 388                                 OPTIM="-KPIC $OPTIM"
 389                         fi
 390                         ;;
 391                 *)
 392                         # Running some other operating system; inform the user they
 393                         # should contribute the necessary options to
 394                         # cups-support@cups.org...
 395                         echo "Building CUPS with default compiler optimizations; contact"
 396                         echo "cups-support@cups.org with uname and compiler options needed"
 397                         echo "for your platform, or set the CFLAGS environment variable"
 398                         echo "before running configure."
 399                         ;;
 400         esac
 401 fi
 402
 403 if test "$DSO" != ":"; then
 404         # When using DSOs the image libraries are linked to libcupsimage.so
 405         # rather than to the executables.  This makes things smaller if you
 406         # are using any static libraries, and it also allows us to distribute
 407         # a single DSO rather than a bunch...
 408         DSOLIBS="\$(LIBPNG) \$(LIBTIFF) \$(LIBJPEG) \$(LIBZ)"
 409         IMGLIBS=""
 410
 411         # The *BSD, HP-UX, and Solaris run-time linkers need help when
 412         # deciding where to find a DSO.  Add linker options to tell them
 413         # where to find the DSO (usually in /usr/lib...  duh!)
 414         case $uname in
 415                 HP-UX*)
 416                         # HP-UX
 417                         DSOFLAGS="+b $libdir +fb $DSOFLAGS"
 418                         LDFLAGS="$LDFLAGS -Wl,+b,$libdir,+fb"
 419                         ;;
 420                 SunOS*)
 421                         # Solaris
 422                         DSOFLAGS="-R$libdir $DSOFLAGS"
 423                         LDFLAGS="$LDFLAGS -R$libdir"
 424                         ;;
 425                 FreeBSD* | NetBSD* | OpenBSD*)
 426                         # *BSD
 427                         DSOFLAGS="-Wl,-R$libdir $DSOFLAGS"
 428                         LDFLAGS="$LDFLAGS -Wl,-R$libdir"
 429                         ;;
 430         esac
 431 else
 432         DSOLIBS=""
 433         IMGLIBS="\$(LIBPNG) \$(LIBTIFF) \$(LIBJPEG) \$(LIBZ)"
 434 fi
 435
 436 AC_SUBST(DSO)
 437 AC_SUBST(DSOLIBS)
 438 AC_SUBST(IMGLIBS)
 439 AC_SUBST(LIBCUPS)
 440 AC_SUBST(LIBCUPSIMAGE)
 441 AC_SUBST(LIBTOOL)
 442 AC_SUBST(LINKCUPS)
 443 AC_SUBST(LINKCUPSIMAGE)
 444
 445 dnl Fix "prefix" variable if it hasn't been specified...
 446 if test "$prefix" = "NONE"; then
 447         prefix="/"
 448 fi
 449
 450 dnl Fix "exec_prefix" variable if it hasn't been specified...
 451 if test "$exec_prefix" = "NONE"; then
 452         if test "$prefix" = "/"; then
 453                 exec_prefix="/usr"
 454         else
 455                 exec_prefix="$prefix"
 456         fi
 457 fi
 458
 459 dnl Fix "sharedstatedir" variable if it hasn't been specified...
 460 if test "$sharedstatedir" = "\${prefix}/com" -a "$prefix" = "/"; then
 461         sharedstatedir="/usr/com"
 462 fi
 463
 464 dnl Fix "datadir" variable if it hasn't been specified...
 465 if test "$datadir" = "\${prefix}/share"; then
 466         if test "$prefix" = "/"; then
 467                 datadir="/usr/share"
 468         else
 469                 datadir="$prefix/share"
 470         fi
 471 fi
 472
 473 dnl Fix "includedir" variable if it hasn't been specified...
 474 if test "$includedir" = "\${prefix}/include" -a "$prefix" = "/"; then
 475         includedir="/usr/include"
 476 fi
 477
 478 dnl Fix "localstatedir" variable if it hasn't been specified...
 479 if test "$localstatedir" = "\${prefix}/var"; then
 480         if test "$prefix" = "/"; then
 481                 localstatedir="/var"
 482         else
 483                 localstatedir="$prefix/var"
 484         fi
 485 fi
 486
 487 dnl Fix "sysconfdir" variable if it hasn't been specified...
 488 if test "$sysconfdir" = "\${prefix}/etc"; then
 489         if test "$prefix" = "/"; then
 490                 sysconfdir="/etc"
 491         else
 492                 sysconfdir="$prefix/etc"
 493         fi
 494 fi
 495
 496 dnl Fix "libdir" variable for IRIX 6.x...
 497 if test "$uname" = "IRIX" -a $uversion -ge 62; then
 498         libdir="$exec_prefix/lib32"
 499 fi
 500
 501 dnl Fix "mandir" variable...
 502 if test "$mandir" = "\${prefix}/man" -a "$prefix" = "/"; then
 503         case "$uname" in
 504                 FreeBSD* | NetBSD* | OpenBSD* | AIX*)
 505                         # *BSD + AIX
 506                         mandir="/usr/share/man"
 507                         AMANDIR="/usr/share/man"
 508                         ;;
 509                 IRIX*)
 510                         # SGI IRIX
 511                         mandir="/usr/share/catman/u_man"
 512                         AMANDIR="/usr/share/catman/a_man"
 513                         ;;
 514                 *)
 515                         # All others
 516                         mandir="/usr/man"
 517                         AMANDIR="/usr/man"
 518                         ;;
 519         esac
 520 else
 521         AMANDIR="$mandir"
 522 fi
 523
 524 AC_SUBST(AMANDIR)
 525
 526 dnl Fix "fontpath" variable...
 527 if test "x$fontpath" = "x"; then
 528         fontpath="$datadir/cups/fonts"
 529 fi
 530
 531 dnl Setup manpage extensions...
 532 case "$uname" in
 533         FreeBSD* | NetBSD* | OpenBSD*)
 534                 # *BSD
 535                 CAT1EXT=0
 536                 CAT5EXT=0
 537                 CAT8EXT=0
 538                 MAN8EXT=8
 539                 ;;
 540         IRIX*)
 541                 # SGI IRIX
 542                 CAT1EXT=z
 543                 CAT5EXT=z
 544                 CAT8EXT=z
 545                 MAN8EXT=1m
 546                 ;;
 547         SunOS* | HP-UX*)
 548                 # Solaris and HP-UX
 549                 CAT1EXT=1
 550                 CAT5EXT=5
 551                 CAT8EXT=1m
 552                 MAN8EXT=1m
 553                 ;;
 554         *)
 555                 # All others
 556                 CAT1EXT=1
 557                 CAT5EXT=5
 558                 CAT8EXT=8
 559                 MAN8EXT=8
 560                 ;;
 561 esac
 562
 563 AC_SUBST(CAT1EXT)
 564 AC_SUBST(CAT5EXT)
 565 AC_SUBST(CAT8EXT)
 566 AC_SUBST(MAN8EXT)
 567
 568 dnl Setup init.d locations...
 569 case "$uname" in
 570         FreeBSD* | OpenBSD*)
 571                 # FreeBSD and OpenBSD
 572                 INITDIR=""
 573                 INITDDIR=""
 574                 ;;
 575
 576         NetBSD*)
 577                 # NetBSD
 578                 INITDIR=""
 579                 INITDDIR="/etc/rc.d"
 580                 ;;
 581
 582         Linux*)
 583                 # Linux seems to choose an init.d directory at random...
 584                 if test -d /sbin/init.d; then
 585                         # SuSE
 586                         INITDIR="/sbin/init.d"
 587                         INITDDIR=".."
 588                 else
 589                         if test -d /etc/rc.d; then
 590                                 # RedHat
 591                                 INITDIR="/etc/rc.d"
 592                                 INITDDIR="../init.d"
 593                         else
 594                                 # Others
 595                                 INITDIR="/etc"
 596                                 INITDDIR="../init.d"
 597                         fi
 598                 fi
 599                 ;;
 600
 601         OSF1* | HP-UX*)
 602                 INITDIR="/sbin"
 603                 INITDDIR="../init.d"
 604                 ;;
 605
 606         AIX*)
 607                 INITDIR="/etc/rc.d"
 608                 INITDDIR=".."
 609                 ;;
 610
 611         *)
 612                 INITDIR="/etc"
 613                 INITDDIR="../init.d"
 614                 ;;
 615
 616 esac
 617
 618 AC_SUBST(INITDIR)
 619 AC_SUBST(INITDDIR)
 620
 621 dnl Setup default locations...
 622 CUPS_SERVERROOT='${sysconfdir}/cups'
 623 CUPS_REQUESTS='${localstatedir}/spool/cups'
 624
 625 AC_DEFINE_UNQUOTED(CUPS_SERVERROOT, "$sysconfdir/cups")
 626 AC_DEFINE_UNQUOTED(CUPS_REQUESTS, "$localstatedir/spool/cups")
 627
 628 if test x$logdir = x; then
 629         CUPS_LOGDIR='${localstatedir}/log/cups'
 630         AC_DEFINE_UNQUOTED(CUPS_LOGDIR, "$localstatedir/log/cups")
 631 else
 632         CUPS_LOGDIR="$logdir"
 633         AC_DEFINE_UNQUOTED(CUPS_LOGDIR, "$logdir")
 634 fi
 635
 636 dnl See what directory to put server executables...
 637 case "$uname" in
 638         FreeBSD* | NetBSD* | OpenBSD*)
 639                 # *BSD
 640                 INSTALL_SYSV=""
 641                 CUPS_SERVERBIN='${exec_prefix}/libexec/cups'
 642                 AC_DEFINE_UNQUOTED(CUPS_SERVERBIN, "$exec_prefix/libexec/cups")
 643                 ;;
 644         *)
 645                 # All others
 646                 INSTALL_SYSV="install-sysv"
 647                 CUPS_SERVERBIN='${exec_prefix}/lib/cups'
 648                 AC_DEFINE_UNQUOTED(CUPS_SERVERBIN, "$exec_prefix/lib/cups")
 649                 ;;
 650 esac
 651
 652 AC_SUBST(INSTALL_SYSV)
 653 AC_SUBST(CUPS_SERVERROOT)
 654 AC_SUBST(CUPS_SERVERBIN)
 655 AC_SUBST(CUPS_LOGDIR)
 656 AC_SUBST(CUPS_REQUESTS)
 657
 658 dnl Set the CUPS_LOCALE directory...
 659 case "$uname" in
 660         Linux* | FreeBSD* | NetBSD* | OpenBSD*)
 661                 CUPS_LOCALEDIR='${datadir}/locale'
 662                 AC_DEFINE_UNQUOTED(CUPS_LOCALEDIR, "$datadir/locale")
 663                 ;;
 664
 665         OSF1* | AIX*)
 666                 CUPS_LOCALEDIR='${exec_prefix}/lib/nls/msg'
 667                 AC_DEFINE_UNQUOTED(CUPS_LOCALEDIR, "$exec_prefix/lib/nls/msg")
 668                 ;;
 669
 670         *)
 671                 # This is the standard System V location...
 672                 CUPS_LOCALEDIR='${exec_prefix}/lib/locale'
 673                 AC_DEFINE_UNQUOTED(CUPS_LOCALEDIR, "$exec_prefix/lib/locale")
 674                 ;;
 675 esac
 676
 677 AC_SUBST(CUPS_LOCALEDIR)
 678
 679 dnl Set the CUPS_DATADIR directory...
 680 CUPS_DATADIR='${datadir}/cups'
 681 AC_DEFINE_UNQUOTED(CUPS_DATADIR, "$datadir/cups")
 682 AC_SUBST(CUPS_DATADIR)
 683
 684 dnl Set the CUPS_DOCROOT directory...
 685 if test x$docdir = x; then
 686         CUPS_DOCROOT='${datadir}/doc/cups'
 687         docdir="$datadir/doc/cups"
 688 else
 689         CUPS_DOCROOT="$docdir"
 690 fi
 691
 692 AC_DEFINE_UNQUOTED(CUPS_DOCROOT, "$docdir")
 693 AC_SUBST(CUPS_DOCROOT)
 694
 695 dnl Set the CUPS_FONTPATH directory...
 696 AC_DEFINE_UNQUOTED(CUPS_FONTPATH, "$fontpath")
 697
 698 AC_OUTPUT(Makedefs cups.sh)
 699
 700 dnl
 701 dnl End of "$Id: configure.in,v 1.83.2.2 2001/05/13 18:37:58 mike Exp $".
 702 dnl