configure.ac

   1 AC_INIT(version.h)
   2 AC_PREREQ(2.54)
   3 AC_CONFIG_AUX_DIR(config)
   4 AC_CONFIG_HEADERS([lib/config.h])
   5 AH_BOTTOM([#include <dirpaths.h>])
   6 MCONFIG=./MCONFIG
   7 AC_SUBST_FILE(MCONFIG)
   8 BINARY_TYPE=bin
   9 dnl
  10 dnl This is to figure out the version number and the date....
  11 dnl
  12 E2FSPROGS_VERSION=`grep E2FSPROGS_VERSION ${srcdir}/version.h  \
  13         | awk '{print $3}' | tr \" " " | awk '{print $1}'`
  14 DATE=`grep E2FSPROGS_DATE ${srcdir}/version.h | awk '{print $3}' \
  15         | tr \" " "`
  16 E2FSPROGS_DAY=$(echo $DATE | awk -F- '{print $1}' | sed -e '/^[[1-9]]$/s/^/0/')
  17 MONTH=`echo $DATE | awk -F- '{print $2}'`
  18 YEAR=`echo $DATE | awk -F- '{print $3}'`
  19
  20 if expr $YEAR ">" 1900 > /dev/null ; then
  21         E2FSPROGS_YEAR=$YEAR
  22 elif expr $YEAR ">" 90 >/dev/null ; then
  23         E2FSPROGS_YEAR=19$YEAR
  24 else
  25         E2FSPROGS_YEAR=20$YEAR
  26 fi
  27
  28 case $MONTH in
  29 Jan)    MONTH_NUM=01; E2FSPROGS_MONTH="January" ;;
  30 Feb)    MONTH_NUM=02; E2FSPROGS_MONTH="February" ;;
  31 Mar)    MONTH_NUM=03; E2FSPROGS_MONTH="March" ;;
  32 Apr)    MONTH_NUM=04; E2FSPROGS_MONTH="April" ;;
  33 May)    MONTH_NUM=05; E2FSPROGS_MONTH="May" ;;
  34 Jun)    MONTH_NUM=06; E2FSPROGS_MONTH="June" ;;
  35 Jul)    MONTH_NUM=07; E2FSPROGS_MONTH="July" ;;
  36 Aug)    MONTH_NUM=08; E2FSPROGS_MONTH="August" ;;
  37 Sep)    MONTH_NUM=09; E2FSPROGS_MONTH="September" ;;
  38 Oct)    MONTH_NUM=10; E2FSPROGS_MONTH="October" ;;
  39 Nov)    MONTH_NUM=11; E2FSPROGS_MONTH="November" ;;
  40 Dec)    MONTH_NUM=12; E2FSPROGS_MONTH="December" ;;
  41 *)      AC_MSG_WARN([Unknown month $MONTH??]) ;;
  42 esac
  43
  44 base_ver=`echo $E2FSPROGS_VERSION | \
  45                sed -e 's/-WIP//' -e 's/pre-//' -e 's/-PLUS//'`
  46
  47 date_spec=${E2FSPROGS_YEAR}.${MONTH_NUM}.${E2FSPROGS_DAY}
  48
  49 case $E2FSPROGS_VERSION in
  50 *-WIP|pre-*)
  51         E2FSPROGS_PKGVER="$base_ver~WIP.$date_spec"
  52         ;;
  53 *)
  54         E2FSPROGS_PKGVER="$base_ver"
  55         ;;
  56 esac
  57
  58 unset DATE MONTH YEAR base_ver pre_vers date_spec
  59 AC_MSG_RESULT([Generating configuration file for e2fsprogs version $E2FSPROGS_VERSION])
  60 AC_MSG_RESULT([Release date is ${E2FSPROGS_MONTH}, ${E2FSPROGS_YEAR}])
  61 AC_SUBST(E2FSPROGS_YEAR)
  62 AC_SUBST(E2FSPROGS_MONTH)
  63 AC_SUBST(E2FSPROGS_DAY)
  64 AC_SUBST(E2FSPROGS_VERSION)
  65 AC_SUBST(E2FSPROGS_PKGVER)
  66 dnl
  67 dnl Use diet libc
  68 dnl
  69 WITH_DIET_LIBC=
  70 AC_ARG_WITH([diet-libc],
  71 [  --with-diet-libc        use diet libc],
  72 CC="diet cc -nostdinc"
  73 WITH_DIET_LIBC=yes
  74 if test -z "$LIBS"
  75 then
  76         LIBS="-lcompat"
  77 else
  78         LIBS="$LIBS -lcompat"
  79 fi
  80 AC_MSG_RESULT(CC=$CC))dnl
  81 dnl
  82 AC_CANONICAL_HOST
  83 dnl
  84 dnl Check to see if libdl exists for the sake of dlopen
  85 dnl
  86 DLOPEN_LIB=''
  87 AC_CHECK_LIB(dl, dlopen,DLOPEN_LIB=-ldl)
  88 AC_SUBST(DLOPEN_LIB)
  89 dnl
  90 AC_ARG_WITH([cc],
  91 AC_HELP_STRING([--with-cc],[no longer supported, use CC= instead]),
  92 AC_MSG_ERROR([--with-cc no longer supported; use CC= instead]))
  93 dnl
  94 AC_ARG_WITH([ccopts],
  95 AC_HELP_STRING([--with-ccopts],[no longer supported, use CFLAGS= instead]),
  96 AC_MSG_ERROR([--with-ccopts no longer supported; use CFLAGS= instead]))
  97 dnl
  98 AC_ARG_WITH([ldopts],
  99 AC_HELP_STRING([--with-ldopts],[no longer supported, use LDFLAGS= instead]),
 100 AC_MSG_ERROR([--with-ldopts no longer supported; use LDFLAGS= instead]))
 101 dnl
 102 AC_PROG_CC
 103 if test "$GCC" = yes; then
 104    RDYNAMIC="-rdynamic"
 105    AC_SUBST(RDYNAMIC)
 106 fi
 107 AC_PROG_CPP
 108 dnl
 109 dnl Alpha computers use fast and imprecise floating point code that may
 110 dnl miss exceptions by default. Force sane options if we're using GCC.
 111 AC_MSG_CHECKING(for additional special compiler flags)
 112 if test "$GCC" = yes
 113 then
 114     case "$host_cpu" in
 115         alpha)          addcflags="-mieee" ;;
 116     esac
 117 fi
 118 if test "x$addcflags" != x
 119 then
 120     AC_MSG_RESULT($addcflags)
 121     CFLAGS="$addcflags $CFLAGS"
 122 else
 123     AC_MSG_RESULT([[(none)]])
 124 fi
 125 AC_USE_SYSTEM_EXTENSIONS
 126 dnl
 127 dnl Set default values for library extensions.  Will be dealt with after
 128 dnl parsing configuration options, which may modify these
 129 dnl
 130 LIB_EXT=.a
 131 STATIC_LIB_EXT=.a
 132 PROFILED_LIB_EXT=.a
 133 dnl
 134 dnl Allow separate `root_prefix' to be specified
 135 dnl
 136 AC_ARG_WITH([root-prefix],
 137 [  --with-root-prefix=PREFIX override prefix variable for files to be placed in the root],
 138 root_prefix=$withval,
 139 root_prefix=NONE)dnl
 140 dnl
 141 dnl handle --enable-maintainer-mode
 142 dnl
 143 AC_ARG_ENABLE([maintainer-mode],
 144 [  --enable-maintainer-mode enable makefile rules useful for maintainers],
 145 if test "$enableval" = "no"
 146 then
 147         MAINTAINER_CMT=#
 148         AC_MSG_RESULT([Disabling maintainer mode])
 149 else
 150         MAINTAINER_CMT=
 151         AC_MSG_RESULT([Enabling maintainer mode])
 152 fi
 153 ,
 154 MAINTAINER_CMT=#
 155 AC_MSG_RESULT([Disabling maintainer mode by default])
 156 )
 157 AC_SUBST(MAINTAINER_CMT)
 158 dnl
 159 dnl handle --enable-symlink-install
 160 dnl
 161 AC_ARG_ENABLE([symlink-install],
 162 [  --enable-symlink-install use symlinks when installing instead of hard links],
 163 if test "$enableval" = "no"
 164 then
 165         LINK_INSTALL_FLAGS=-f
 166         AC_MSG_RESULT([Disabling symlinks for install])
 167 else
 168         LINK_INSTALL_FLAGS=-sf
 169         AC_MSG_RESULT([Enabling symlinks for install])
 170 fi
 171 ,
 172 LINK_INSTALL_FLAGS=-f
 173 AC_MSG_RESULT([Disabling symlinks for install by default])
 174 )
 175 AC_SUBST(LINK_INSTALL_FLAGS)
 176 dnl
 177 dnl handle --enable-relative-symlinks
 178 dnl
 179 relative_symlink_defined=
 180 AC_ARG_ENABLE([relative-symlinks],
 181 [  --enable-relative-symlinks use relative symlinks when installing],
 182 if test "$enableval" = "no"
 183 then
 184         SYMLINK_RELATIVE=
 185         relative_symlink_defined=yes
 186         AC_MSG_RESULT([Disabling relative symlinks for install])
 187 else
 188         SYMLINK_RELATIVE=--relative
 189         relative_symlink_defined=yes
 190         AC_MSG_RESULT([Enabling relative symlinks for install])
 191 fi)
 192 AC_ARG_ENABLE([symlink-relative-symlinks],,
 193 if test "$enableval" = "no"
 194 then
 195         SYMLINK_RELATIVE=yes
 196         AC_MSG_RESULT([Disabling relative symlinks for install])
 197 else
 198         SYMLINK_RELATIVE=--relative
 199         AC_MSG_RESULT([Enabling relative symlinks for install])
 200 fi
 201 ,
 202 if test -z "$relative_symlink_defined"
 203 then
 204         SYMLINK_RELATIVE=
 205 AC_MSG_RESULT([Disabling relative symlinks for install by default])
 206 fi
 207 )
 208 AC_SUBST(SYMLINK_RELATIVE)
 209 dnl
 210 dnl handle --enable-symlink-build
 211 dnl
 212 AC_ARG_ENABLE([symlink-build],
 213 [  --enable-symlink-build  use symlinks while building instead of hard links],
 214 if test "$enableval" = "no"
 215 then
 216         LINK_BUILD_FLAGS=
 217         AC_MSG_RESULT([Disabling symlinks for build])
 218 else
 219         LINK_BUILD_FLAGS=-s
 220         AC_MSG_RESULT([Enabling symlinks for build])
 221 fi
 222 ,
 223 LINK_BUILD_FLAGS=
 224 AC_MSG_RESULT([Disabling symlinks for build by default])
 225 )
 226 AC_SUBST(LINK_BUILD_FLAGS)
 227 dnl
 228 dnl handle --enable-verbose-makecmds
 229 dnl
 230 AC_ARG_ENABLE([verbose-makecmds],
 231 [  --enable-verbose-makecmds enable verbose make command output],
 232 if test "$enableval" = "no"
 233 then
 234         AC_MSG_RESULT([Disabling verbose make commands])
 235         E=@echo
 236         ES=echo
 237         Q=@
 238 else
 239         AC_MSG_RESULT([Enabling verbose make commands])
 240         E=@\\#
 241         ES=\\#
 242         Q=
 243 fi
 244 ,
 245 AC_MSG_RESULT([Disabling verbose make commands])
 246 E=@echo
 247 ES=echo
 248 Q=@
 249 )
 250 AC_SUBST(E)
 251 AC_SUBST(ES)
 252 AC_SUBST(Q)
 253 dnl
 254 dnl This needs to be before all of the --enable-*-shlibs options
 255 dnl
 256 E2_PKG_CONFIG_STATIC=--static
 257 LDFLAG_DYNAMIC=
 258 PRIVATE_LIBS_CMT=
 259 dnl
 260 dnl handle --enable-elf-shlibs
 261 dnl
 262 AC_ARG_ENABLE([elf-shlibs],
 263 [  --enable-elf-shlibs    select ELF shared libraries],
 264 if test "$enableval" = "no"
 265 then
 266         ELF_CMT=#
 267         MAKEFILE_ELF=/dev/null
 268         AC_MSG_RESULT([Disabling ELF shared libraries])
 269 else
 270         E2_PKG_CONFIG_STATIC=
 271         ELF_CMT=
 272         MAKEFILE_ELF=$srcdir/lib/Makefile.elf-lib
 273         [case "$host_os" in
 274         solaris2.*)
 275                 MAKEFILE_ELF=$srcdir/lib/Makefile.solaris-lib
 276         ;;
 277         esac]
 278         BINARY_TYPE=elfbin
 279         LIB_EXT=.so
 280         PRIVATE_LIBS_CMT=#
 281         LDFLAG_DYNAMIC=['-Wl,-rpath-link,$(top_builddir)/lib']
 282         AC_MSG_RESULT([Enabling ELF shared libraries])
 283 fi
 284 ,
 285 MAKEFILE_ELF=/dev/null
 286 ELF_CMT=#
 287 AC_MSG_RESULT([Disabling ELF shared libraries by default])
 288 )
 289 AC_SUBST(ELF_CMT)
 290 AC_SUBST_FILE(MAKEFILE_ELF)
 291 dnl
 292 dnl handle --enable-bsd-shlibs
 293 dnl
 294 AC_ARG_ENABLE([bsd-shlibs],
 295 [  --enable-bsd-shlibs    select BSD shared libraries],
 296 if test "$enableval" = "no"
 297 then
 298         BSDLIB_CMT=#
 299         MAKEFILE_BSDLIB=/dev/null
 300         AC_MSG_RESULT([Disabling BSD shared libraries])
 301 else
 302         E2_PKG_CONFIG_STATIC=
 303         BSDLIB_CMT=
 304         MAKEFILE_BSDLIB=$srcdir/lib/Makefile.bsd-lib
 305         LIB_EXT=.so
 306         [case "$host_os" in
 307         darwin*)
 308                 MAKEFILE_BSDLIB=$srcdir/lib/Makefile.darwin-lib
 309                 LIB_EXT=.dylib
 310         ;;
 311         esac]
 312         AC_MSG_RESULT([Enabling BSD shared libraries])
 313 fi
 314 ,
 315 MAKEFILE_BSDLIB=/dev/null
 316 BSDLIB_CMT=#
 317 AC_MSG_RESULT([Disabling BSD shared libraries by default])
 318 )
 319 AC_SUBST(BSDLIB_CMT)
 320 AC_SUBST_FILE(MAKEFILE_BSDLIB)
 321 dnl
 322 dnl handle --enable-profile
 323 dnl
 324 AC_ARG_ENABLE([profile],
 325 [  --enable-profile       build profiling libraries],
 326 if test "$enableval" = "no"
 327 then
 328         PROFILE_CMT=#
 329         MAKEFILE_PROFILE=/dev/null
 330         AC_MSG_RESULT([Disabling profiling libraries])
 331 else
 332         PROFILE_CMT=
 333         MAKEFILE_PROFILE=$srcdir/lib/Makefile.profile
 334         PROFILED_LIB_EXT=_p.a
 335         AC_MSG_RESULT([Building profiling libraries])
 336 fi
 337 ,
 338 PROFILE_CMT=#
 339 MAKEFILE_PROFILE=/dev/null
 340 AC_MSG_RESULT([Disabling profiling libraries by default])
 341 )
 342 AC_SUBST(PROFILE_CMT)
 343 AC_SUBST_FILE(MAKEFILE_PROFILE)
 344 dnl
 345 dnl handle --enable-gcov
 346 dnl
 347 AC_ARG_ENABLE([gcov],
 348 [  --enable-gcov                  build for coverage testing using gcov],
 349 if test "$enableval" = "yes"
 350 then
 351         CFLAGS="-g -fprofile-arcs -ftest-coverage"
 352         LDFLAGS="-fprofile-arcs -ftest-coverage"
 353         AC_MSG_RESULT([Enabling gcov support])
 354 fi
 355 )
 356 dnl
 357 dnl handle --enable-hardening
 358 dnl
 359 CFLAGS_SHLIB="${CFLAGS_SHLIB:-$CFLAGS}"
 360 CFLAGS_STLIB="${CFLAGS_STLIB:-$CFLAGS}"
 361 LDFLAGS_SHLIB=${LDFLAGS_SHLIB:-$LDFLAGS}
 362 LDFLAGS_STATIC=${LDFLAGS_STATIC:-$LDFLAGS}
 363 AC_ARG_ENABLE([hardening],
 364 [  --enable-hardening             build for coverage testing using gcov],
 365 if test "$enableval" = "yes"
 366 then
 367         HARDEN_CFLAGS="-D_FORTIFY_SOURCE=2 -fstack-protector-strong"
 368         HARDEN_LDFLAGS=["-Wl,-z,relro -Wl,-z,now"]
 369         CFLAGS="$CFLAGS $HARDEN_CFLAGS -fPIE"
 370         CFLAGS_SHLIB="$CFLAGS_SHLIB $HARDEN_CFLAGS"
 371         CFLAGS_STLIB="$CFLAGS_STLIB $HARDEN_CFLAGS -fPIE"
 372         LDFLAGS="$LDFLAGS $HARDEN_LDFLAGS -fPIE -pie"
 373         LDFLAGS_STATIC="$LDFLAGS_STATIC $HARDEN_LDFLAGS"
 374         LDFLAGS_SHLIB="$LDFLAGS_SHLIB $HARDEN_LDFLAGS"
 375         AC_MSG_RESULT([Enabling hardening support])
 376 fi
 377 )
 378 dnl
 379 dnl Substitute library extensions
 380 dnl
 381 AC_SUBST(LIB_EXT)
 382 AC_SUBST(STATIC_LIB_EXT)
 383 AC_SUBST(PROFILED_LIB_EXT)
 384 AC_SUBST(LDFLAG_DYNAMIC)
 385 AC_SUBST(PRIVATE_LIBS_CMT)
 386 dnl
 387 dnl handle --enable-jbd-debug
 388 dnl
 389 AC_ARG_ENABLE([jbd-debug],
 390 [  --enable-jbd-debug     enable journal debugging],
 391 if test "$enableval" = "no"
 392 then
 393         AC_MSG_RESULT([Disabling journal debugging])
 394 else
 395         AC_DEFINE(CONFIG_JBD_DEBUG, 1,
 396                 [Define to 1 if debugging ext3/4 journal code])
 397         AC_MSG_RESULT([Enabling journal debugging])
 398 fi
 399 ,
 400 AC_MSG_RESULT([Disabling journal debugging by default])
 401 )
 402 dnl
 403 dnl handle --enable-blkid-debug
 404 dnl
 405 AC_ARG_ENABLE([blkid-debug],
 406 [  --enable-blkid-debug    enable blkid debugging],
 407 if test "$enableval" = "no"
 408 then
 409         AC_MSG_RESULT([Disabling blkid debugging])
 410 else
 411         AC_DEFINE(CONFIG_BLKID_DEBUG, 1,
 412                 [Define to 1 if debugging the blkid library])
 413         AC_MSG_RESULT([Enabling blkid debugging])
 414 fi
 415 ,
 416 AC_MSG_RESULT([Disabling blkid debugging by default])
 417 )
 418 dnl
 419 dnl handle --enable-testio-debug
 420 dnl
 421 AC_ARG_ENABLE([testio-debug],
 422 [  --disable-testio-debug  disable the use of the test I/O manager for debugging],
 423 AH_TEMPLATE([CONFIG_TESTIO_DEBUG],
 424         [Define to 1 if the testio I/O manager should be enabled])
 425 if test "$enableval" = "no"
 426 then
 427         AC_MSG_RESULT([Disabling testio debugging])
 428         TEST_IO_CMT="#"
 429 else
 430         TEST_IO_CMT=
 431         AC_DEFINE(CONFIG_TESTIO_DEBUG, 1)
 432         AC_MSG_RESULT([Enabling testio debugging])
 433 fi
 434 ,
 435 AC_MSG_RESULT([Enabling testio debugging by default])
 436 AC_DEFINE(CONFIG_TESTIO_DEBUG, 1)
 437 TEST_IO_CMT=
 438 )
 439 AC_SUBST(TEST_IO_CMT)
 440 dnl
 441 dnl handle --disable-libuuid
 442 dnl
 443 PKG_PROG_PKG_CONFIG
 444 LIBUUID=
 445 DEPLIBUUID=
 446 STATIC_LIBUUID=
 447 DEPSTATIC_LIBUUID=
 448 PROFILED_LIBUUID=
 449 DEPPROFILED_LIBUUID=
 450 UUID_CMT=
 451 AC_ARG_ENABLE([libuuid],
 452 [  --enable-libuuid       build and use private uuid library],
 453 if test "$enableval" = "no"
 454 then
 455         if test -z "$PKG_CONFIG"; then
 456                 AC_MSG_ERROR([pkg-config not installed; please install it.])
 457         fi
 458
 459         AC_CHECK_LIB(uuid, uuid_generate,
 460                 [LIBUUID=`$PKG_CONFIG --libs uuid`;
 461                  STATIC_LIBUUID=`$PKG_CONFIG --static --libs uuid`],
 462                 [AC_MSG_ERROR([external uuid library not found])])
 463         PROFILED_LIBUUID=$LIBUUID
 464         UUID_CMT=#
 465         AC_MSG_RESULT([Disabling private uuid library])
 466 else
 467         LIBUUID='$(LIB)/libuuid'$LIB_EXT
 468         DEPLIBUUID=$LIBUUID
 469         STATIC_LIBUUID='$(LIB)/libuuid'$STATIC_LIB_EXT
 470         DEPSTATIC_LIBUUID=$STATIC_LIBUUID
 471         PROFILED_LIBUUID='$(LIB)/libuuid'$PROFILED_LIB_EXT
 472         DEPPROFILED_LIBUUID=$PROFILED_LIBUUID
 473         AC_MSG_RESULT([Enabling private uuid library])
 474 fi
 475 ,
 476 if test -n "$PKG_CONFIG"; then
 477         AC_CHECK_LIB(uuid, uuid_generate,
 478                 [LIBUUID=`$PKG_CONFIG --libs uuid`;
 479                  STATIC_LIBUUID=`$PKG_CONFIG --static --libs uuid`])
 480 fi
 481 if test -n "$LIBUUID"; then
 482         PROFILED_LIBUUID=$LIBUUID
 483         UUID_CMT=#
 484         AC_MSG_RESULT([Using system uuid by default])
 485 else
 486         LIBUUID='$(LIB)/libuuid'$LIB_EXT
 487         DEPLIBUUID=$LIBUUID
 488         STATIC_LIBUUID='$(LIB)/libuuid'$STATIC_LIB_EXT
 489         DEPSTATIC_LIBUUID=$STATIC_LIBUUID
 490         PROFILED_LIBUUID='$(LIB)/libuuid'$PROFILED_LIB_EXT
 491         DEPPROFILED_LIBUUID=$PROFILED_LIBUUID
 492         AC_MSG_RESULT([Enabling private uuid library by default])
 493 fi
 494 )
 495 AC_SUBST(LIBUUID)
 496 AC_SUBST(DEPLIBUUID)
 497 AC_SUBST(STATIC_LIBUUID)
 498 AC_SUBST(DEPSTATIC_LIBUUID)
 499 AC_SUBST(PROFILED_LIBUUID)
 500 AC_SUBST(DEPPROFILED_LIBUUID)
 501 AC_SUBST(UUID_CMT)
 502 dnl
 503 dnl handle --disable-libblkid
 504 dnl
 505 PKG_PROG_PKG_CONFIG
 506 LIBBLKID=
 507 DEPLIBBLKID=
 508 STATIC_LIBBLKID=
 509 DEPSTATIC_LIBBLKID=
 510 PROFILED_LIBBLKID=
 511 DEPPROFILED_LIBBLKID=
 512 BLKID_CMT=
 513 AH_TEMPLATE([CONFIG_BUILD_FINDFS], [Define to 1 to compile findfs])
 514 AC_ARG_ENABLE([libblkid],
 515 [  --enable-libblkid      build and use private blkid library],
 516 if test "$enableval" = "no"
 517 then
 518         if test -z "$PKG_CONFIG"; then
 519                 AC_MSG_ERROR([pkg-config not installed; please install it.])
 520         fi
 521
 522         AC_CHECK_LIB(blkid, blkid_get_cache,
 523                 [LIBBLKID=`$PKG_CONFIG --libs blkid`;
 524                  STATIC_LIBBLKID=`$PKG_CONFIG --static --libs blkid`],
 525                 [AC_MSG_ERROR([external blkid library not found])], -luuid)
 526         BLKID_CMT=#
 527         PROFILED_LIBBLKID=$LIBBLKID
 528         AC_MSG_RESULT([Disabling private blkid library])
 529 else
 530         LIBBLKID='$(LIB)/libblkid'$LIB_EXT
 531         DEPLIBBLKID=$LIBBLKID
 532         STATIC_LIBBLKID='$(LIB)/libblkid'$STATIC_LIB_EXT
 533         DEPSTATIC_LIBBLKID=$STATIC_LIBBLKID
 534         PROFILED_LIBBLKID='$(LIB)/libblkid'$PROFILED_LIB_EXT
 535         DEPPROFILED_LIBBLKID=$PROFILED_LIBBLKID
 536         AC_DEFINE(CONFIG_BUILD_FINDFS, 1)
 537         AC_MSG_RESULT([Enabling private blkid library])
 538 fi
 539 ,
 540 if test -n "$PKG_CONFIG"; then
 541         AC_CHECK_LIB(blkid, blkid_get_cache,
 542                 [LIBBLKID=`$PKG_CONFIG --libs blkid`;
 543                  STATIC_LIBBLKID=`$PKG_CONFIG --static --libs blkid`])
 544 fi
 545 if test -n "$LIBBLKID"; then
 546         BLKID_CMT=#
 547         PROFILED_LIBBLKID=$LIBBLKID
 548         AC_MSG_RESULT([Using system blkid library by default])
 549 else
 550         LIBBLKID='$(LIB)/libblkid'$LIB_EXT
 551         DEPLIBBLKID=$LIBBLKID
 552         STATIC_LIBBLKID='$(LIB)/libblkid'$STATIC_LIB_EXT
 553         DEPSTATIC_LIBBLKID=$STATIC_LIBBLKID
 554         PROFILED_LIBBLKID='$(LIB)/libblkid'$PROFILED_LIB_EXT
 555         DEPPROFILED_LIBBLKID=$PROFILED_LIBBLKID
 556         AC_DEFINE(CONFIG_BUILD_FINDFS, 1)
 557         AC_MSG_RESULT([Enabling private blkid library by default])
 558 fi
 559 )
 560 AC_SUBST(LIBBLKID)
 561 AC_SUBST(DEPLIBBLKID)
 562 AC_SUBST(STATIC_LIBBLKID)
 563 AC_SUBST(DEPSTATIC_LIBBLKID)
 564 AC_SUBST(PROFILED_LIBBLKID)
 565 AC_SUBST(DEPPROFILED_LIBBLKID)
 566 AC_SUBST(BLKID_CMT)
 567 dnl
 568 dnl handle --enable-subset
 569 dnl
 570 ALL_CMT=
 571 AC_ARG_ENABLE([subset],
 572 [  --enable-subset        enable subset-only build],
 573 if test "$enableval" = "no"
 574 then
 575         AC_MSG_RESULT([Disabling subset-only build])
 576 else
 577         ALL_CMT=#
 578         AC_MSG_RESULT([Enabling subset-only-build])
 579 fi
 580 ,)
 581 AC_SUBST(ALL_CMT)
 582 dnl
 583 dnl handle --disable-backtrace
 584 dnl
 585 AH_TEMPLATE([DISABLE_BACKTRACE], [Define to 1 to disable use of backtrace])
 586 AC_ARG_ENABLE([backtrace],
 587 [  --disable-backtrace    disable use backtrace],
 588 if test "$enableval" = "no"
 589 then
 590         AC_MSG_RESULT([Disabling use of backtrace])
 591         AC_DEFINE(DISABLE_BACKTRACE, 1)
 592 else
 593         AC_MSG_RESULT([Enabling use of backtrace])
 594 fi
 595 ,
 596 AC_MSG_RESULT([Enabling use of backtrace by default])
 597 )
 598 dnl
 599 dnl handle --enable-debugfs
 600 dnl
 601 AC_ARG_ENABLE([debugfs],
 602 [  --disable-debugfs      disable support of debugfs program],
 603 if test "$enableval" = "no"
 604 then
 605         AC_MSG_RESULT([Disabling debugfs support])
 606         DEBUGFS_CMT="#"
 607 else
 608         DEBUGFS_CMT=
 609         AC_MSG_RESULT([Enabling debugfs support])
 610 fi
 611 ,
 612 AC_MSG_RESULT([Enabling debugfs support by default])
 613 DEBUGFS_CMT=
 614 )
 615 AC_SUBST(DEBUGFS_CMT)
 616 dnl
 617 dnl handle --enable-imager
 618 dnl
 619 AC_ARG_ENABLE([imager],
 620 [  --disable-imager       disable support of e2image program],
 621 if test "$enableval" = "no"
 622 then
 623         AC_MSG_RESULT([Disabling e2image support])
 624         IMAGER_CMT="#"
 625 else
 626         IMAGER_CMT=
 627         AC_MSG_RESULT([Enabling e2image support])
 628 fi
 629 ,
 630 AC_MSG_RESULT([Enabling e2image support by default])
 631 IMAGER_CMT=
 632 )
 633 AC_SUBST(IMAGER_CMT)
 634 dnl
 635 dnl handle --enable-resizer
 636 dnl
 637 AC_ARG_ENABLE([resizer],
 638 [  --disable-resizer      disable support of e2resize program],
 639 if test "$enableval" = "no"
 640 then
 641         AC_MSG_RESULT([Disabling e2resize support])
 642         RESIZER_CMT="#"
 643 else
 644         RESIZER_CMT=
 645         AC_MSG_RESULT([Enabling e2resize support])
 646 fi
 647 ,
 648 AC_MSG_RESULT([Enabling e2resize support by default])
 649 RESIZER_CMT=
 650 )
 651 AC_SUBST(RESIZER_CMT)
 652 dnl
 653 dnl handle --enable-defrag
 654 dnl
 655 AC_ARG_ENABLE([defrag],
 656 [  --disable-defrag       disable support of e4defrag program],
 657 if test "$enableval" = "no"
 658 then
 659         AC_MSG_RESULT([Disabling e4defrag support])
 660         DEFRAG_CMT="#"
 661 else
 662         DEFRAG_CMT=
 663         AC_MSG_RESULT([Enabling e4defrag support])
 664 fi
 665 ,
 666 if test -z "$WITH_DIET_LIBC"
 667 then
 668         AC_MSG_RESULT([Enabling e4defrag support by default])
 669         DEFRAG_CMT=
 670 else
 671         AC_MSG_RESULT([Disabling e4defrag support by default])
 672         DEFRAG_CMT="#"
 673 fi
 674 )
 675 AC_SUBST(DEFRAG_CMT)
 676 dnl
 677 dnl See whether to install the `fsck' wrapper program (that calls e2fsck)
 678 dnl
 679 AC_ARG_ENABLE([fsck],
 680 [  --enable-fsck           build fsck wrapper program],
 681 [if test "$enableval" = "no"
 682 then
 683         FSCK_PROG='' FSCK_MAN=''
 684         AC_MSG_RESULT([Not building fsck wrapper])
 685 else
 686         FSCK_PROG=fsck FSCK_MAN=fsck.8
 687         AC_MSG_RESULT([Building fsck wrapper])
 688 fi]
 689 ,
 690 [case "$host_os" in
 691   gnu*)
 692     FSCK_PROG='' FSCK_MAN=''
 693     AC_MSG_RESULT([Not building fsck wrapper by default])
 694     ;;
 695   *)
 696     FSCK_PROG=fsck FSCK_MAN=fsck.8
 697     AC_MSG_RESULT([Building fsck wrapper by default])
 698 esac]
 699 )
 700 AC_SUBST(FSCK_PROG)
 701 AC_SUBST(FSCK_MAN)
 702 dnl
 703 dnl See whether to install the `e2initrd-helper' program
 704 dnl
 705 AC_ARG_ENABLE([e2initrd-helper],
 706 [  --enable-e2initrd-helper build e2initrd-helper program],
 707 [if test "$enableval" = "no"
 708 then
 709         E2INITRD_PROG='' E2INITRD_MAN=''
 710         AC_MSG_RESULT([Not building e2initrd helper])
 711 else
 712         E2INITRD_PROG=e2initrd_helper E2INITRD_MAN=e2initrd_helper.8
 713         AC_MSG_RESULT([Building e2initrd helper])
 714 fi]
 715 ,
 716 E2INITRD_PROG=e2initrd_helper E2INITRD_MAN=e2initrd_helper.8
 717 AC_MSG_RESULT([Building e2initrd helper by default])
 718 )
 719 AC_SUBST(E2INITRD_PROG)
 720 AC_SUBST(E2INITRD_MAN)
 721 dnl
 722 dnl
 723 dnl
 724 AC_ARG_ENABLE([tls],
 725 [  --disable-tls           disable use of thread local support],
 726 [if test "$enableval" = "no"
 727 then
 728         try_tls=""
 729         AC_MSG_RESULT([Disabling thread local support])
 730 else
 731         try_tls="yes"
 732         AC_MSG_RESULT([Enabling thread local support])
 733 fi]
 734 ,
 735 if test -n "$WITH_DIET_LIBC"
 736 then
 737         try_tls=""
 738         AC_MSG_RESULT([Diet libc does not support thread local support])
 739 else
 740         try_tls="yes"
 741         AC_MSG_RESULT([Try using thread local support by default])
 742 fi
 743 )
 744 if test "$try_tls" = "yes"
 745 then
 746 AX_TLS
 747 fi
 748 dnl
 749 dnl
 750 dnl
 751 AH_TEMPLATE([USE_UUIDD], [Define to 1 to build uuidd])
 752 AC_ARG_ENABLE([uuidd],
 753 [  --disable-uuidd         disable building the uuid daemon],
 754 [if test "$enableval" = "no"
 755 then
 756         AC_MSG_RESULT([Not building uuidd])
 757         UUIDD_CMT="#"
 758 else
 759         AC_DEFINE(USE_UUIDD, 1)
 760         UUIDD_CMT=""
 761         AC_MSG_RESULT([Building uuidd])
 762 fi]
 763 ,
 764 AC_DEFINE(USE_UUIDD, 1)
 765 if test -z "$UUID_CMT"
 766 then
 767         UUIDD_CMT=""
 768         AC_MSG_RESULT([Building uuidd by default])
 769 else
 770         UUIDD_CMT="#"
 771         AC_MSG_RESULT([Disabling uuidd by default])
 772 fi
 773 )
 774 AC_SUBST(UUIDD_CMT)
 775 dnl
 776 dnl handle --disable-mmp
 777 dnl
 778 AH_TEMPLATE([CONFIG_MMP], [Define to 1 to enable mmp support])
 779 AC_ARG_ENABLE([mmp],
 780 [  --disable-mmp           disable support mmp, Multi Mount Protection],
 781 if test "$enableval" = "no"
 782 then
 783         AC_MSG_RESULT([Disabling mmp support])
 784 else
 785         AC_MSG_RESULT([Enabling mmp support])
 786         AC_DEFINE(CONFIG_MMP, 1)
 787 fi
 788 ,
 789 AC_MSG_RESULT([Enabling mmp support by default])
 790 AC_DEFINE(CONFIG_MMP, 1)
 791 )
 792 dnl
 793 dnl handle --disable-tdb
 794 dnl
 795 AH_TEMPLATE([CONFIG_TDB], [Define to 1 to enable tdb support])
 796 AC_ARG_ENABLE([tdb],
 797 [  --disable-tdb           disable tdb support],
 798 if test "$enableval" = "no"
 799 then
 800         AC_MSG_RESULT([Disabling tdb support])
 801         TDB_CMT="#"
 802         TDB_MAN_COMMENT='.\"'
 803 else
 804         AC_MSG_RESULT([Enabling tdb support])
 805         AC_DEFINE(CONFIG_TDB, 1)
 806         TDB_CMT=""
 807         TDB_MAN_COMMENT=""
 808 fi
 809 ,
 810 AC_MSG_RESULT([Enabling mmp support by default])
 811 AC_DEFINE(CONFIG_TDB, 1)
 812 TDB_CMT=""
 813 TDB_MAN_COMMENT=""
 814 )
 815 AC_SUBST(TDB_CMT)
 816 AC_SUBST(TDB_MAN_COMMENT)
 817 dnl
 818 dnl handle --disable-bmap-stats
 819 dnl
 820 AH_TEMPLATE([ENABLE_BMAP_STATS], [Define to 1 to enable bitmap stats.])
 821 AC_ARG_ENABLE([bmap-stats],
 822 [  --disable-bmap-stats    disable collection of bitmap stats.],
 823 if test "$enableval" = "no"
 824 then
 825         AC_MSG_RESULT([Disabling bitmap statistics support])
 826 else
 827         AC_MSG_RESULT([Enabling bitmap statistics support])
 828         AC_DEFINE(ENABLE_BMAP_STATS, 1)
 829 fi
 830 ,
 831 AC_MSG_RESULT([Enabling bitmap statistics support by default])
 832 AC_DEFINE(ENABLE_BMAP_STATS, 1)
 833 )
 834 dnl
 835 dnl handle --enable-bmap-stats-ops
 836 dnl
 837 AH_TEMPLATE([ENABLE_BMAP_STATS_OPS], [Define to 1 to enable bitmap stats.])
 838 AC_ARG_ENABLE([bmap-stats-ops],
 839 [  --enable-bmap-stats-ops enable collection of additional bitmap stats],
 840 if test "$enableval" = "no"
 841 then
 842         AC_MSG_RESULT([Disabling additional bitmap statistics])
 843 else
 844         dnl There has to be a better way!
 845         AS_IF([test "x${enable_bmap_stats}" = "xno"],
 846          AC_MSG_FAILURE([Error --enable-bmap-stats-ops requires bmap-stats]))
 847
 848         AC_MSG_RESULT([Enabling additional bitmap statistics])
 849         AC_DEFINE(ENABLE_BMAP_STATS_OPS, 1)
 850 fi
 851 ,
 852 AC_MSG_RESULT([Disabling additional bitmap statistics by default])
 853 )
 854 dnl
 855 dnl
 856 dnl
 857 MAKEFILE_LIBRARY=$srcdir/lib/Makefile.library
 858 AC_SUBST_FILE(MAKEFILE_LIBRARY)
 859 dnl
 860 dnl Add internationalization support, using gettext.
 861 dnl
 862 GETTEXT_PACKAGE=e2fsprogs
 863 PACKAGE=e2fsprogs
 864 VERSION="$E2FSPROGS_VERSION"
 865 VERSION=0.14.1
 866 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [package name for gettext])
 867 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [version for gettext])
 868 AC_SUBST(GETTEXT_PACKAGE)
 869 AC_SUBST(PACKAGE)
 870 AC_SUBST(VERSION)
 871
 872 AM_GNU_GETTEXT
 873 dnl
 874 dnl End of configuration options
 875 dnl
 876 AC_SUBST(BINARY_TYPE)
 877 AC_PROG_MAKE_SET
 878 CHECK_GNU_MAKE
 879 AC_PATH_PROG(LN, ln, ln)
 880 AC_PROG_MKDIR_P
 881 AC_PROG_LN_S
 882 AC_PATH_PROG(MV, mv, mv)
 883 AC_PATH_PROG(CP, cp, cp)
 884 AC_PATH_PROG(RM, rm, rm)
 885 AC_PATH_PROG(CHMOD, chmod, :)
 886 AC_PROG_AWK
 887 AC_PROG_EGREP
 888 AC_PATH_PROG(SED, sed, sed)
 889 AC_PATH_PROG(PERL, perl, perl)
 890 AC_PATH_PROG(LDCONFIG, ldconfig, :)
 891 AC_CHECK_TOOL(AR, ar, ar)
 892 AC_CHECK_TOOL(RANLIB, ranlib, :)
 893 AC_CHECK_TOOL(STRIP, strip, :)
 894 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, )
 895 if test "_$MAKEINFO" = "_"; then
 896     MAKEINFO="echo Makeinfo is missing. Info documentation will not be built."
 897 else
 898     case "$MAKEINFO" in
 899       */missing.*)
 900         AC_MSG_WARN([
 901 *** Makeinfo is missing. Info documentation will not be built.])
 902         ;;
 903       *)
 904         ;;
 905     esac
 906 fi
 907 AC_SUBST(MAKEINFO)
 908 AC_PROG_INSTALL
 909 # See if we need a separate native compiler.
 910 if test $cross_compiling = no; then
 911   BUILD_CC="$CC"
 912   AC_SUBST(BUILD_CC)
 913 else
 914   AC_CHECK_PROGS(BUILD_CC, gcc cc)
 915 fi
 916 AC_CHECK_HEADERS(m4_flatten([
 917         dirent.h
 918         errno.h
 919         execinfo.h
 920         getopt.h
 921         malloc.h
 922         mntent.h
 923         paths.h
 924         semaphore.h
 925         setjmp.h
 926         signal.h
 927         stdarg.h
 928         stdint.h
 929         stdlib.h
 930         termios.h
 931         termio.h
 932         unistd.h
 933         utime.h
 934         attr/xattr.h
 935         linux/falloc.h
 936         linux/fd.h
 937         linux/fsmap.h
 938         linux/major.h
 939         linux/loop.h
 940         linux/types.h
 941         net/if_dl.h
 942         netinet/in.h
 943         sys/acl.h
 944         sys/disklabel.h
 945         sys/disk.h
 946         sys/file.h
 947         sys/ioctl.h
 948         sys/key.h
 949         sys/mkdev.h
 950         sys/mman.h
 951         sys/mount.h
 952         sys/prctl.h
 953         sys/resource.h
 954         sys/select.h
 955         sys/socket.h
 956         sys/sockio.h
 957         sys/stat.h
 958         sys/syscall.h
 959         sys/sysctl.h
 960         sys/sysmacros.h
 961         sys/time.h
 962         sys/types.h
 963         sys/un.h
 964         sys/wait.h
 965         sys/xattr.h
 966 ]))
 967 dnl Check where to find a dd(1) that supports iflag=fullblock
 968 dnl and oflag=append
 969 AC_MSG_CHECKING([for a dd(1) program that supports iflag=fullblock])
 970 DD=
 971 for i in dd gdd ; do
 972         if "$i" if=/dev/null of=/dev/null count=1 bs=10k 2>/dev/null iflag=fullblock oflag=append ; then
 973                 DD=$i
 974                 break
 975         fi
 976 done
 977 if test -n "$DD" ; then
 978         AC_MSG_RESULT([$DD])
 979 else
 980         AC_MSG_RESULT([not found, using dd])
 981         DD=dd
 982         AC_MSG_WARN([No GNU-compatible dd(1) program found, expect some self-test failures.])
 983 fi
 984 AC_SUBST([DD])
 985
 986 AC_CHECK_HEADERS(net/if.h,,,
 987 [[
 988 #if HAVE_SYS_TYPES_H
 989 #include <sys/types.h>
 990 #endif
 991 #if HAVE_SYS_SOCKET
 992 #include <sys/socket.h>
 993 #endif
 994 ]])
 995 AC_FUNC_VPRINTF
 996 dnl Check to see if dirent has member d_reclen. On cygwin those d_reclen
 997 dnl is not declared.
 998 AC_CHECK_MEMBER(struct dirent.d_reclen,[AC_DEFINE(HAVE_RECLEN_DIRENT, 1,
 999                        [Define to 1 if dirent has d_reclen])],,
1000                 [#include <dirent.h>])
1001 AC_CHECK_MEMBERS([struct stat.st_atim])
1002 dnl Check to see if ssize_t was declared
1003 AC_CHECK_TYPE(ssize_t,[AC_DEFINE(HAVE_TYPE_SSIZE_T, 1,
1004                 [Define to 1 if ssize_t declared])],,
1005               [#include <sys/types.h>])
1006 dnl
1007 dnl Check to see if llseek() is declared in unistd.h.  On some libc's
1008 dnl it is, and on others it isn't..... Thank you glibc developers....
1009 dnl
1010 AC_CHECK_DECL(llseek,[AC_DEFINE(HAVE_LLSEEK_PROTOTYPE, 1,
1011                         [Define to 1 if llseek declared in unistd.h])],,
1012               [#include <unistd.h>])
1013 dnl
1014 dnl Check to see if lseek64() is declared in unistd.h.  Glibc's header files
1015 dnl are so convoluted that I can't tell whether it will always be defined,
1016 dnl and if it isn't defined while lseek64 is defined in the library,
1017 dnl disaster will strike.
1018 dnl
1019 dnl Warning!  Use of --enable-gcc-wall may throw off this test.
1020 dnl
1021 dnl
1022 AC_CHECK_DECL(lseek64,[AC_DEFINE(HAVE_LSEEK64_PROTOTYPE, 1,
1023                         [Define to 1 if lseek64 declared in unistd.h])],,
1024                 [#define _LARGEFILE_SOURCE
1025                  #define _LARGEFILE64_SOURCE
1026                  #include <unistd.h>])
1027 dnl
1028 dnl Word sizes...
1029 dnl
1030 AC_CHECK_SIZEOF(short)
1031 AC_CHECK_SIZEOF(int)
1032 AC_CHECK_SIZEOF(long)
1033 AC_CHECK_SIZEOF(long long)
1034 AC_CHECK_SIZEOF(off_t)
1035 AC_CHECK_SIZEOF(time_t)
1036 SIZEOF_SHORT=$ac_cv_sizeof_short
1037 SIZEOF_INT=$ac_cv_sizeof_int
1038 SIZEOF_LONG=$ac_cv_sizeof_long
1039 SIZEOF_LONG_LONG=$ac_cv_sizeof_long_long
1040 SIZEOF_OFF_T=$ac_cv_sizeof_off_t
1041 SIZEOF_TIME_T=$ac_cv_sizeof_time_t
1042 AC_SUBST(SIZEOF_SHORT)
1043 AC_SUBST(SIZEOF_INT)
1044 AC_SUBST(SIZEOF_LONG)
1045 AC_SUBST(SIZEOF_LONG_LONG)
1046 AC_SUBST(SIZEOF_OFF_T)
1047 AC_SUBST(SIZEOF_TIME_T)
1048 AC_C_BIGENDIAN
1049 if test $cross_compiling = no; then
1050   BUILD_CC="$BUILD_CC" CPP="$CPP" /bin/sh $ac_aux_dir/parse-types.sh
1051 else
1052   CROSS_COMPILE="1" BUILD_CC="$BUILD_CC" CPP="$CPP" /bin/sh $ac_aux_dir/parse-types.sh
1053 fi
1054 ASM_TYPES_HEADER=./asm_types.h
1055 AC_SUBST_FILE(ASM_TYPES_HEADER)
1056 dnl
1057 dnl Save the configuration #defines needed for the public ext2fs.h
1058 dnl header file
1059 dnl
1060 echo "/* These defines are needed for the public ext2fs.h header file */" \
1061      > public_config.h
1062 if grep HAVE_SYS_TYPES_H confdefs.h > tmp_config.$$; then
1063   uniq tmp_config.$$ >> public_config.h
1064 else
1065   echo "#undef HAVE_SYS_TYPES_H" >> public_config.h
1066 fi
1067 if grep WORDS_BIGENDIAN confdefs.h > tmp_config.$$; then
1068   uniq tmp_config.$$ >> public_config.h
1069 else
1070   echo "#undef WORDS_BIGENDIAN" >> public_config.h
1071 fi
1072 rm -f tmp_config.$$
1073 PUBLIC_CONFIG_HEADER=./public_config.h
1074 AC_SUBST_FILE(PUBLIC_CONFIG_HEADER)
1075 dnl
1076 dnl See if we have inttypes.h and if intptr_t is defined
1077 dnl
1078 AC_CHECK_HEADERS([inttypes.h])
1079 AC_CHECK_TYPES(intptr_t)
1080 dnl
1081 dnl See if struct stat has a st_flags field, in which case we can get file
1082 dnl flags somewhat portably.  Also check for the analogous setter, chflags().
1083 dnl
1084 AC_MSG_CHECKING(whether struct stat has a st_flags field)
1085 AC_CACHE_VAL(e2fsprogs_cv_struct_st_flags,
1086         AC_TRY_COMPILE([#include <sys/stat.h>],
1087                 [struct stat stat; stat.st_flags = 0;],
1088                 [e2fsprogs_cv_struct_st_flags=yes],
1089                 [e2fsprogs_cv_struct_st_flags=no]))
1090 AC_MSG_RESULT($e2fsprogs_cv_struct_st_flags)
1091 if test "$e2fsprogs_cv_struct_st_flags" = yes; then
1092   AC_MSG_CHECKING(whether st_flags field is useful)
1093   AC_CACHE_VAL(e2fsprogs_cv_struct_st_flags_immut,
1094         AC_TRY_COMPILE([#include <sys/stat.h>],
1095                 [struct stat stat; stat.st_flags |= UF_IMMUTABLE;],
1096                 [e2fsprogs_cv_struct_st_flags_immut=yes],
1097                 [e2fsprogs_cv_struct_st_flags_immut=no]))
1098   AC_MSG_RESULT($e2fsprogs_cv_struct_st_flags_immut)
1099   if test "$e2fsprogs_cv_struct_st_flags_immut" = yes; then
1100           AC_DEFINE(HAVE_STAT_FLAGS, 1,
1101                 [Define to 1 if struct stat has st_flags])
1102   fi
1103 fi
1104 dnl
1105 dnl Check for the presence of SA_LEN
1106 dnl
1107 AC_CHECK_MEMBER(struct sockaddr.sa_len,
1108                 AC_DEFINE_UNQUOTED(HAVE_SA_LEN,1,
1109                         [Define to 1 if if struct sockaddr contains sa_len]),,
1110         [#include <sys/types.h>
1111          #include <sys/socket.h>])
1112 dnl
1113 dnl This will add -lblkid to the AC_CHECK_FUNCS search if we are using
1114 dnl the system-provided blkid library
1115 dnl
1116 if test -n "$BLKID_CMT"; then
1117   AC_SEARCH_LIBS([blkid_probe_all], [blkid])
1118 fi
1119 dnl
1120 if test -n "$DLOPEN_LIB" ; then
1121    ac_cv_func_dlopen=yes
1122 fi
1123 AC_CHECK_FUNCS(m4_flatten([
1124         __secure_getenv
1125         add_key
1126         backtrace
1127         blkid_probe_get_topology
1128         blkid_probe_enable_partitions
1129         chflags
1130         dlopen
1131         fadvise64
1132         fallocate
1133         fallocate64
1134         fchown
1135         fcntl
1136         fdatasync
1137         fstat64
1138         fsync
1139         ftruncate64
1140         futimes
1141         getcwd
1142         getdtablesize
1143         gethostname
1144         getmntinfo
1145         getpwuid_r
1146         getrlimit
1147         getrusage
1148         jrand48
1149         keyctl
1150         llistxattr
1151         llseek
1152         lseek64
1153         mallinfo
1154         mbstowcs
1155         memalign
1156         mempcpy
1157         mmap
1158         msync
1159         nanosleep
1160         open64
1161         pathconf
1162         posix_fadvise
1163         posix_fadvise64
1164         posix_memalign
1165         prctl
1166         pread
1167         pwrite
1168         pread64
1169         pwrite64
1170         secure_getenv
1171         setmntent
1172         setresgid
1173         setresuid
1174         snprintf
1175         srandom
1176         stpcpy
1177         strcasecmp
1178         strdup
1179         strnlen
1180         strptime
1181         strtoull
1182         sync_file_range
1183         sysconf
1184         usleep
1185         utime
1186         utimes
1187         valloc
1188 ]))
1189 dnl
1190 dnl Check to see if -lsocket is required (solaris) to make something
1191 dnl that uses socket() to compile; this is needed for the UUID library
1192 dnl
1193 SOCKET_LIB=''
1194 AC_CHECK_LIB(socket, socket, [SOCKET_LIB=-lsocket])
1195 AC_SUBST(SOCKET_LIB)
1196 dnl
1197 dnl See if libmagic exists
1198 dnl
1199 AC_CHECK_LIB(magic, magic_file, [MAGIC_LIB=-lmagic
1200 AC_CHECK_HEADERS([magic.h])])
1201 if test "$ac_cv_func_dlopen" = yes ; then
1202    MAGIC_LIB=$DLOPEN_LIB
1203 fi
1204 AC_SUBST(MAGIC_LIB)
1205 dnl
1206 dnl Check to see if librt is required for clock_gettime() (glibc < 2.17)
1207 dnl
1208 AC_CHECK_LIB(rt, clock_gettime, [CLOCK_GETTIME_LIB=-lrt])
1209 AC_SUBST(CLOCK_GETTIME_LIB)
1210 dnl
1211 dnl Check to see if the FUSE library is -lfuse or -losxfuse
1212 dnl
1213 FUSE_CMT=
1214 FUSE_LIB=
1215 dnl osxfuse.dylib supersedes fuselib.dylib
1216 AC_ARG_ENABLE([fuse2fs],
1217 [  --disable-fuse2fs      do not build fuse2fs],
1218 if test "$enableval" = "no"
1219 then
1220         FUSE_CMT="#"
1221         AC_MSG_RESULT([Disabling fuse2fs])
1222 else
1223         AC_CHECK_HEADERS([pthread.h fuse.h], [],
1224 [AC_MSG_FAILURE([Cannot find fuse2fs headers.])],
1225 [#define _FILE_OFFSET_BITS      64
1226 #define FUSE_USE_VERSION 29])
1227
1228         AC_PREPROC_IFELSE(
1229 [AC_LANG_PROGRAM([[#define FUSE_USE_VERSION 29
1230 #ifdef __linux__
1231 #include <linux/fs.h>
1232 #include <linux/falloc.h>
1233 #include <linux/xattr.h>
1234 #endif
1235 ]], [])], [], [AC_MSG_FAILURE([Cannot find fuse2fs Linux headers.])])
1236
1237         AC_CHECK_LIB(osxfuse, fuse_main, [FUSE_LIB=-losxfuse],
1238                 [AC_CHECK_LIB(fuse, fuse_main, [FUSE_LIB=-lfuse],
1239                               [AC_MSG_FAILURE([Cannot find fuse library.])])])
1240         AC_MSG_RESULT([Enabling fuse2fs])
1241 fi
1242 ,
1243 AC_CHECK_HEADERS([pthread.h fuse.h], [], [FUSE_CMT="#"],
1244 [#define _FILE_OFFSET_BITS      64
1245 #define FUSE_USE_VERSION 29
1246 #ifdef __linux__
1247 # include <linux/fs.h>
1248 # include <linux/falloc.h>
1249 # include <linux/xattr.h>
1250 #endif])
1251 if test -z "$FUSE_CMT"
1252 then
1253         AC_CHECK_LIB(osxfuse, fuse_main, [FUSE_LIB=-losxfuse],
1254 [AC_CHECK_LIB(fuse, fuse_main, [FUSE_LIB=-lfuse], [FUSE_CMT="#"])])
1255 fi
1256 if test -z "$FUSE_CMT"
1257 then
1258         AC_MSG_RESULT([Enabling fuse2fs by default.])
1259 fi
1260 )
1261 AC_SUBST(FUSE_LIB)
1262 AC_SUBST(FUSE_CMT)
1263 dnl
1264 dnl See if optreset exists
1265 dnl
1266 AC_MSG_CHECKING(for optreset)
1267 AC_CACHE_VAL(ac_cv_have_optreset,
1268 [AC_EGREP_HEADER(optreset, unistd.h,
1269   ac_cv_have_optreset=yes, ac_cv_have_optreset=no)])dnl
1270 AC_MSG_RESULT($ac_cv_have_optreset)
1271 if test $ac_cv_have_optreset = yes; then
1272   AC_DEFINE(HAVE_OPTRESET, 1, [Define to 1 if optreset for getopt is present])
1273 fi
1274 dnl
1275 dnl Test for sem_init, and which library it might require:
1276 dnl
1277 AH_TEMPLATE([HAVE_SEM_INIT], [Define to 1 if sem_init() exists])
1278 SEM_INIT_LIB=''
1279 echo GL_THREADS_API: ${gl_threads_api}
1280 if test "${gl_threads_api}" != none
1281 then
1282   AC_CHECK_FUNC(sem_init, ,
1283     AC_CHECK_LIB(pthread, sem_init,
1284         AC_DEFINE(HAVE_SEM_INIT, 1)
1285         SEM_INIT_LIB=-lpthread,
1286     AC_CHECK_LIB(rt, sem_init,
1287         AC_DEFINE(HAVE_SEM_INIT, 1)
1288         SEM_INIT_LIB=-lrt,
1289     AC_CHECK_LIB(posix4, sem_init,
1290         AC_DEFINE(HAVE_SEM_INIT, 1)
1291         SEM_INIT_LIB=-lposix4))))dnl
1292 fi
1293 AC_SUBST(SEM_INIT_LIB)
1294 dnl
1295 dnl Check for unified diff
1296 dnl
1297 AC_MSG_CHECKING(for unified diff option)
1298 if diff -u $0 $0 > /dev/null 2>&1 ; then
1299    UNI_DIFF_OPTS=-u
1300 else
1301    UNI_DIFF_OPTS=-c
1302 fi
1303 AC_MSG_RESULT($UNI_DIFF_OPTS)
1304 AC_SUBST(UNI_DIFF_OPTS)
1305 dnl
1306 dnl We use the EXT2 ioctls only under Linux
1307 dnl
1308 case "$host_os" in
1309 linux*)
1310         AC_DEFINE(HAVE_EXT2_IOCTLS, 1, [Define to 1 if Ext2 ioctls present])
1311         ;;
1312 esac
1313 dnl
1314 dnl OS-specific uncomment control
1315 dnl
1316 LINUX_CMT="#"
1317 CYGWIN_CMT="#"
1318 UNIX_CMT=
1319 case "$host_os" in
1320 linux*)
1321         LINUX_CMT=
1322         ;;
1323 cygwin)
1324         CYGWIN_CMT=
1325         UNIX_CMT="#"
1326         ;;
1327 esac
1328 AC_SUBST(LINUX_CMT)
1329 AC_SUBST(CYGWIN_CMT)
1330 AC_SUBST(UNIX_CMT)
1331 dnl
1332 dnl Linux and Hurd places root files in the / by default
1333 dnl
1334 case "$host_os" in
1335 linux* | gnu* | k*bsd*-gnu)
1336         if test "$prefix" = NONE -a "$root_prefix" = NONE ; then
1337                 root_prefix="";
1338                 AC_MSG_RESULT([On $host_os systems, root_prefix defaults to ''])
1339         fi
1340         ;;
1341 esac
1342 dnl
1343 dnl On Linux/hurd, force the prefix to be /usr
1344 dnl
1345 case "$host_os" in
1346 linux* | gnu* | k*bsd*-gnu)
1347         if test "$prefix" = NONE ; then
1348                 prefix="/usr";
1349                 AC_MSG_RESULT([On $host_os systems, prefix defaults to /usr])
1350                 if test "$mandir" = '${prefix}/man' ; then
1351                         AC_MSG_RESULT([...and mandir defaults to /usr/share/man])
1352                         mandir=/usr/share/man
1353                 fi
1354         fi
1355 ;;
1356 esac
1357 if test "$root_prefix" = NONE ; then
1358         if test "$prefix" = NONE ; then
1359                 root_prefix="$ac_default_prefix"
1360         else
1361                 root_prefix="$prefix"
1362         fi
1363         root_bindir=$bindir
1364         root_sbindir=$sbindir
1365         root_libdir=$libdir
1366         root_sysconfdir=$sysconfdir
1367 else
1368         root_bindir='${root_prefix}/bin'
1369         root_sbindir='${root_prefix}/sbin'
1370         root_libdir='${root_prefix}/lib'
1371         root_sysconfdir='${root_prefix}/etc'
1372 fi
1373 if test "$bindir" != '${exec_prefix}/bin'; then
1374     root_bindir=$bindir
1375     AC_MSG_RESULT([Setting root_bindir to $root_bindir])
1376 fi
1377 if test "$sbindir" != '${exec_prefix}/sbin'; then
1378     root_sbindir=$sbindir
1379     AC_MSG_RESULT([Setting root_sbindir to $root_sbindir])
1380 fi
1381 if test "$libdir" != '${exec_prefix}/lib'; then
1382     root_libdir=$libdir
1383     AC_MSG_RESULT([Setting root_libdir to $root_libdir])
1384 fi
1385 if test "$sysconfdir" != '${prefix}/etc'; then
1386     root_sysconfdir=$sysconfdir
1387     AC_MSG_RESULT([Setting root_sysconfdir to $root_sysconfdir])
1388 fi
1389 AC_SUBST(root_prefix)
1390 AC_SUBST(root_bindir)
1391 AC_SUBST(root_sbindir)
1392 AC_SUBST(root_libdir)
1393 AC_SUBST(root_sysconfdir)
1394 dnl
1395 dnl Allow specification of the multiarch arch
1396 dnl
1397 AC_ARG_WITH([multiarch],
1398 [  --with-multiarch=ARCH specify the multiarch triplet],
1399 if test "$withval" = "lib64"; then
1400     libdir=/usr/lib64
1401     root_libdir=/lib64
1402 else
1403     libdir=$libdir/$withval
1404     root_libdir=$root_libdir/$withval
1405 fi
1406 )dnl
1407 dnl
1408 dnl See if -static works.  This could fail if the linker does not
1409 dnl support -static, or if required external libraries are not available
1410 dnl in static form.
1411 dnl
1412 AC_MSG_CHECKING([whether we can link with -static])
1413 AC_CACHE_VAL(ac_cv_e2fsprogs_use_static,
1414 [SAVE_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS_STATIC -static"
1415 AC_TRY_LINK([#include <stdio.h>],[fflush(stdout);],
1416  ac_cv_e2fsprogs_use_static=yes, ac_cv_e2fsprogs_use_static=no)
1417 LDFLAGS=$SAVE_LDFLAGS])
1418 dnl
1419 dnl Regardless of how the test turns out, Solaris doesn't handle -static
1420 dnl This is caused by the socket library requiring the nsl library, which
1421 dnl requires the -dl library, which only works for dynamically linked
1422 dnl programs.  It basically means you can't have statically linked programs
1423 dnl which use the network under Solaris.
1424 dnl
1425 case "$host_os" in
1426 solaris2.*)
1427         ac_cv_e2fsprogs_use_static=no
1428 ;;
1429 esac
1430 AC_MSG_RESULT($ac_cv_e2fsprogs_use_static)
1431 if test $ac_cv_e2fsprogs_use_static = yes; then
1432         LDFLAGS_STATIC="$LDFLAGS_STATIC -static"
1433 fi
1434 AC_SUBST(LDFLAGS_STATIC)
1435 dnl
1436 dnl Work around mysterious Darwin / GNU libintl problem
1437 dnl (__asm__ redirection doesn't work for some mysterious reason.  Looks like
1438 dnl Apple hacked gcc somehow?)
1439 dnl
1440 case "$host_os" in
1441 darwin*)
1442         AC_MSG_RESULT([Using Apple Darwin / GNU libintl workaround])
1443         AC_DEFINE(_INTL_REDIRECT_MACROS, 1,
1444                 [Define to 1 if Apple Darwin libintl workaround is needed])
1445         ;;
1446 esac
1447 dnl
1448 dnl Only try to run the test suite if we're not cross compiling.
1449 dnl
1450 if test "$cross_compiling" = yes ; then
1451   DO_TEST_SUITE=
1452 else
1453   DO_TEST_SUITE=check
1454 fi
1455 AC_SUBST(DO_TEST_SUITE)
1456 dnl
1457 dnl Only include the intl include files if we're building with them
1458 dnl
1459 INCLUDES='-I. -I$(top_builddir)/lib -I$(top_srcdir)/lib'
1460 if test -n "$CPPFLAGS" ; then
1461         INCLUDES="$INCLUDES $CPPFLAGS"
1462 fi
1463 if test "$USE_INCLUDED_LIBINTL" = "yes" ; then
1464         INCLUDES=$INCLUDES' -I$(top_builddir)/intl -I$(top_srcdir)/intl'
1465 fi
1466 if test -n "$WITH_DIET_LIBC" ; then
1467         INCLUDES="$INCLUDES -D_REENTRANT"
1468 fi
1469 AC_SUBST(INCLUDES)
1470 dnl
1471 dnl Build CFLAGS
1472 dnl
1473 if test $cross_compiling = no; then
1474    BUILD_CFLAGS="$CFLAGS $CPPFLAGS $INCLUDES -DHAVE_CONFIG_H"
1475    BUILD_LDFLAGS="$LDFLAGS"
1476 fi
1477 AC_SUBST(BUILD_CFLAGS)
1478 AC_SUBST(BUILD_LDFLAGS)
1479 dnl
1480 dnl Define CFLAGS and LDFLAGS for shared libraries
1481 dnl
1482 CFLAGS_SHLIB=${CFLAGS_SHLIB:-$CFLAGS}
1483 CFLAGS_STLIB=${CFLAGS_STLIB:-$CFLAGS}
1484 LDFLAGS_SHLIB=${LDFLAGS_SHLIB:-$LDFLAGS}
1485 AC_SUBST(CFLAGS_SHLIB)
1486 AC_SUBST(CFLAGS_STLIB)
1487 AC_SUBST(LDFLAGS_SHLIB)
1488 dnl
1489 dnl Make our output files, being sure that we create the some miscellaneous
1490 dnl directories
1491 dnl
1492 test -d lib || mkdir lib
1493 test -d include || mkdir include
1494 test -d include/linux || mkdir include/linux
1495 test -d include/asm || mkdir include/asm
1496 if test -z "$UUID_CMT" ; then
1497         uuid_out_list="lib/uuid/Makefile lib/uuid/uuid.pc \
1498                 lib/uuid/uuid_types.h"
1499 fi
1500 if test -z "$BLKID_CMT" ; then
1501         blkid_out_list="lib/blkid/Makefile lib/blkid/blkid.pc \
1502                 lib/blkid/blkid_types.h"
1503 fi
1504 for i in MCONFIG Makefile \
1505         util/Makefile util/subst.conf util/gen-tarball util/install-symlink \
1506         lib/et/Makefile lib/ss/Makefile lib/e2p/Makefile \
1507         lib/ext2fs/Makefile lib/ext2fs/ext2_types.h \
1508         $uuid_out_list $blkid_out_list lib/support/Makefile \
1509         lib/ss/ss.pc lib/et/com_err.pc lib/e2p/e2p.pc lib/ext2fs/ext2fs.pc \
1510         misc/Makefile ext2ed/Makefile e2fsck/Makefile \
1511         debugfs/Makefile tests/Makefile tests/progs/Makefile \
1512         resize/Makefile doc/Makefile intl/Makefile \
1513         intl/libgnuintl.h po/Makefile.in ; do
1514         if test -d `dirname ${srcdir}/$i` ; then
1515                 outlist="$outlist $i"
1516         fi
1517 done
1518 AC_OUTPUT($outlist)
1519 if test -f util/gen-tarball; then chmod +x util/gen-tarball; fi