configure.ac

   1 AC_INIT([util-linux],
   2         m4_esyscmd([tools/git-version-gen .tarball-version]),
   3         [kzak@redhat.com],,
   4         [http://www.kernel.org/pub/linux/utils/util-linux/])
   5
   6
   7 AC_PREREQ([2.60])
   8
   9 AC_CONFIG_AUX_DIR([config])
  10 AC_CONFIG_MACRO_DIR([m4])
  11 dnl AC_USE_SYSTEM_EXTENSIONS must be called before any macros that run
  12 dnl the compiler (like AC_PROG_LIBTOOL) to avoid autoconf errors.
  13 AC_USE_SYSTEM_EXTENSIONS
  14 AM_INIT_AUTOMAKE([-Wall foreign 1.10 tar-pax no-dist-gzip dist-xz subdir-objects])
  15
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  17                             [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  18 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  19
  20 AC_CONFIG_SRCDIR([sys-utils/mount.c])
  21 AC_PREFIX_DEFAULT([/usr])
  22
  23 dnl version details from <major>.<minor>[-<suffix>]
  24 PACKAGE_VERSION_MAJOR=$(echo $PACKAGE_VERSION | awk -F. '{print $1}')
  25 PACKAGE_VERSION_MINOR=$(echo $PACKAGE_VERSION | awk -F. '{
  26                                                    sub("-.*","",$2); print $2}')
  27 PACKAGE_VERSION_RELEASE=$(echo $PACKAGE_VERSION | awk -F. '{
  28                      sub("-.*","",$3); print $3 ~ /^@<:@0-9@:>@+$/ ? $3 : 0}')
  29
  30 dnl libblkid version
  31 LIBBLKID_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  32 LIBBLKID_DATE="06-Nov-2018"
  33 LIBBLKID_LT_MAJOR=1
  34 LIBBLKID_LT_MINOR=1
  35 LIBBLKID_LT_MICRO=0
  36 LIBBLKID_VERSION_INFO=`expr $LIBBLKID_LT_MAJOR + $LIBBLKID_LT_MINOR`:$LIBBLKID_LT_MICRO:$LIBBLKID_LT_MINOR
  37
  38 dnl libuuid version
  39 LIBUUID_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  40 LIBUUID_LT_MAJOR=1
  41 LIBUUID_LT_MINOR=3
  42 LIBUUID_LT_MICRO=0
  43 LIBUUID_VERSION_INFO=`expr $LIBUUID_LT_MAJOR + $LIBUUID_LT_MINOR`:$LIBUUID_LT_MICRO:$LIBUUID_LT_MINOR
  44
  45 dnl libmount version
  46 LIBMOUNT_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  47 LIBMOUNT_LT_MAJOR=1
  48 LIBMOUNT_LT_MINOR=1
  49 LIBMOUNT_LT_MICRO=0
  50 LIBMOUNT_VERSION_INFO=`expr $LIBMOUNT_LT_MAJOR + $LIBMOUNT_LT_MINOR`:$LIBMOUNT_LT_MICRO:$LIBMOUNT_LT_MINOR
  51
  52 dnl libsmartcols version
  53 LIBSMARTCOLS_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  54 LIBSMARTCOLS_LT_MAJOR=1
  55 LIBSMARTCOLS_LT_MINOR=1
  56 LIBSMARTCOLS_LT_MICRO=0
  57 LIBSMARTCOLS_VERSION_INFO=`expr $LIBSMARTCOLS_LT_MAJOR + $LIBSMARTCOLS_LT_MINOR`:$LIBSMARTCOLS_LT_MICRO:$LIBSMARTCOLS_LT_MINOR
  58
  59 dnl libfdisk version
  60 LIBFDISK_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  61 LIBFDISK_LT_MAJOR=1
  62 LIBFDISK_LT_MINOR=1
  63 LIBFDISK_LT_MICRO=0
  64 LIBFDISK_VERSION_INFO=`expr $LIBFDISK_LT_MAJOR + $LIBFDISK_LT_MINOR`:$LIBFDISK_LT_MICRO:$LIBFDISK_LT_MINOR
  65
  66 # Check whether exec_prefix=/usr:
  67 AS_CASE([$exec_prefix:$prefix],
  68 [NONE:NONE | NONE:/usr | /usr:*],
  69   [AC_MSG_NOTICE([Default --exec-prefix detected.])
  70    AS_CASE([$bindir],  ['${exec_prefix}/bin'],  [bindir=/bin;   AC_MSG_NOTICE([  --bindir defaults to /bin])  ])
  71    AS_CASE([$sbindir], ['${exec_prefix}/sbin'], [sbindir=/sbin; AC_MSG_NOTICE([  --sbindir defaults to /sbin])])
  72    AS_CASE([$libdir],  ['${exec_prefix}/lib'],  [libdir=/lib;   AC_MSG_NOTICE([  --libdir defaults to /lib])  ])
  73    AS_CASE([$libdir],  ['${exec_prefix}/lib64'],[libdir=/lib64; AC_MSG_NOTICE([  --libdir defaults to /lib64])  ])
  74   ]
  75 )
  76
  77
  78 # default for old versions without $runstatedir
  79 AS_IF([test x"$runstatedir" = x], [runstatedir='${localstatedir}/run'])
  80
  81 # our default if $localstatedir unchanged
  82 AS_CASE([$localstatedir:$runstatedir],
  83  [NONE:'${localstatedir}/run' | /var:'${localstatedir}/run' | NONE:'/run' ],
  84    [runstatedir=/run; AC_MSG_NOTICE([  --runstatedir defaults to /run])]
  85 )
  86
  87 AC_SUBST([runstatedir])
  88
  89
  90 # The original default values of {bin,sbin,lib}dir
  91 usrbin_execdir='${exec_prefix}/bin'
  92 AC_SUBST([usrbin_execdir])
  93
  94 usrsbin_execdir='${exec_prefix}/sbin'
  95 AC_SUBST([usrsbin_execdir])
  96
  97 AS_CASE([$libdir],
  98  ['${exec_prefix}/'* | '${prefix}/'* | /usr/* | "${prefix}"/* ],
  99    [usrlib_execdir=$libdir],
 100  [usrlib_execdir='${exec_prefix}'$libdir]
 101 )
 102 AC_SUBST([usrlib_execdir])
 103
 104
 105 AM_PROG_CC_C_O
 106 AC_PROG_MKDIR_P
 107 AC_PROG_CC_STDC
 108 AC_PROG_YACC
 109 AC_CANONICAL_HOST
 110 AC_C_CONST
 111 AC_C_VOLATILE
 112 AC_C_BIGENDIAN
 113
 114 dnl Compiler warnings
 115 UL_WARN_ADD([-fno-common])
 116 UL_WARN_ADD([-Wall])
 117 UL_WARN_ADD([-Werror=sequence-point])
 118 UL_WARN_ADD([-Wextra])
 119 UL_WARN_ADD([-Wextra-semi])
 120 UL_WARN_ADD([-Wembedded-directive])
 121 UL_WARN_ADD([-Wmissing-declarations])
 122 UL_WARN_ADD([-Wmissing-parameter-type])
 123 UL_WARN_ADD([-Wmissing-prototypes])
 124 UL_WARN_ADD([-Wno-missing-field-initializers])
 125 UL_WARN_ADD([-Wredundant-decls])
 126 UL_WARN_ADD([-Wsign-compare])
 127 UL_WARN_ADD([-Wtype-limits])
 128 UL_WARN_ADD([-Wuninitialized])
 129 UL_WARN_ADD([-Wunused-but-set-parameter])
 130 UL_WARN_ADD([-Wunused-but-set-variable])
 131 UL_WARN_ADD([-Wunused-parameter])
 132 UL_WARN_ADD([-Wunused-result])
 133 UL_WARN_ADD([-Wunused-variable])
 134 UL_WARN_ADD([-Wnested-externs])
 135 UL_WARN_ADD([-Wpointer-arith])
 136 UL_WARN_ADD([-Wstrict-prototypes])
 137 UL_WARN_ADD([-Wformat-security])
 138 UL_WARN_ADD([-Wimplicit-function-declaration])
 139 UL_WARN_ADD([-Wdiscarded-qualifiers])
 140 AC_SUBST([WARN_CFLAGS])
 141
 142 UL_WARN_ADD([-Wno-clobbered], [BSD_WARN_CFLAGS])
 143 AC_SUBST([BSD_WARN_CFLAGS])
 144
 145 UL_WARN_ADD([-Wno-cast-function-type], [PYTHON_WARN_CFLAGS])
 146 AC_SUBST([PYTHON_WARN_CFLAGS])
 147
 148 UL_WARN_ADD([-Wno-unused-parameter], [NO_UNUSED_WARN_CFLAGS])
 149 AC_SUBST([NO_UNUSED_WARN_CFLAGS])
 150
 151
 152 AC_ARG_ENABLE([asan],
 153   AS_HELP_STRING([--enable-asan], [compile with Address Sanitizer]),
 154   [], [enable_asan=no]
 155 )
 156 AS_IF([test "x$enable_asan" = xyes], [
 157   UL_WARN_ADD([-fsanitize=address])
 158 ])
 159
 160
 161
 162 dnl libtool-2
 163 LT_INIT
 164
 165 dnl check supported linker flags
 166 AX_CHECK_VSCRIPT
 167
 168 m4_ifndef([PKG_PROG_PKG_CONFIG],
 169   [m4_fatal([Could not locate the pkg-config autoconf
 170     macros. These are usually located in /usr/share/aclocal/pkg.m4.
 171     If your macros are in a different location, try setting the
 172     environment variable AL_OPTS="-I/other/macro/dir" before running
 173     ./autogen.sh or autoreconf again. Make sure pkg-config is installed.])])
 174 PKG_PROG_PKG_CONFIG
 175
 176 GTK_DOC_CHECK([1.10])
 177 AC_PATH_PROG([XSLTPROC], [xsltproc])
 178
 179 linux_os=no
 180 bsd_os=no
 181 AS_CASE([${host_os}],
 182   [*linux*],
 183      [linux_os=yes],
 184   [*darwin*],
 185      [darwin_os=yes],
 186   [*bsd*],
 187      [bsd_os=yes])
 188 AM_CONDITIONAL([LINUX], [test "x$linux_os" = xyes])
 189 AM_CONDITIONAL([DARWIN], [test "x$darwin_os" = xyes])
 190 AM_CONDITIONAL([BSD], [test "x$bsd_os" = xyes])
 191
 192 AS_IF([test  "x$darwin_os" = xyes], [
 193   AC_DEFINE([_DARWIN_C_SOURCE], [1], [Enable MAP_ANON in sys/mman.h on Mac OS X])
 194 ])
 195
 196 dnl define ARCH_<NAME> conditionals
 197 UL_SET_ARCH([I86], [i?86-*])
 198 UL_SET_ARCH([86_64], [x86_64*])
 199 UL_SET_ARCH([IA64], [ia64*])
 200 UL_SET_ARCH([S390], [s390*])
 201 UL_SET_ARCH([SPARC], [sparc*])
 202 UL_SET_ARCH([PPC], [ppc*|powerpc*])
 203 UL_SET_ARCH([M68K], [m68*])
 204 UL_SET_ARCH([MIPS], [mips*])
 205 UL_SET_ARCH([HPPA], [hppa*|parisc*])
 206
 207 AC_SYS_LARGEFILE
 208 AC_HEADER_ASSERT
 209 AC_STRUCT_TIMEZONE
 210
 211 dnl Don't forget to maintain alternatively allowed versions in autogen.sh!
 212 AM_GNU_GETTEXT_VERSION([0.18.3])
 213 AM_GNU_GETTEXT([external])
 214
 215 AS_IF([test -d "$srcdir/po"], [
 216   ALL_LINGUAS=`cd $srcdir/po > /dev/null && echo *.po | sed 's/\.po//g'`
 217 ], [
 218   ALL_LINGUAS="af am ar as be bg bn_IN bn ca cs cy da de el en_GB es et eu_ES fa fi fr gl gu he hi hr hu hy id is it ja ka kn ko ku lo lt lv mk ml mr ms my nb nl nn no nso or pa pl pt_BR pt ro ru si sk sl sq sr@Latn sr sv ta te th tr uk ur vi zh_CN zh_TW zu"
 219 ])
 220
 221 AC_CHECK_HEADERS([linux/compiler.h linux/blkpg.h linux/major.h], [], [], [
 222 #ifdef HAVE_LINUX_COMPILER_H
 223 #include <linux/compiler.h>
 224 #endif
 225 ])
 226 AC_CHECK_HEADERS([ \
 227         asm/io.h \
 228         err.h \
 229         errno.h \
 230         fcntl.h \
 231         getopt.h \
 232         inttypes.h \
 233         lastlog.h \
 234         libutil.h \
 235         linux/btrfs.h \
 236         linux/cdrom.h \
 237         linux/falloc.h \
 238         linux/watchdog.h \
 239         linux/fd.h \
 240         linux/raw.h \
 241         linux/tiocl.h \
 242         linux/version.h \
 243         linux/securebits.h \
 244         linux/net_namespace.h \
 245         locale.h \
 246         mntent.h \
 247         net/if.h \
 248         net/if_dl.h \
 249         netinet/in.h \
 250         paths.h \
 251         pty.h \
 252         security/pam_appl.h \
 253         stdint.h \
 254         stdio_ext.h \
 255         stdlib.h \
 256         endian.h \
 257         byteswap.h \
 258         sys/endian.h \
 259         sys/disk.h \
 260         sys/disklabel.h \
 261         sys/file.h \
 262         sys/io.h \
 263         sys/ioccom.h \
 264         sys/ioctl.h \
 265         sys/mkdev.h \
 266         sys/mount.h \
 267         sys/param.h \
 268         sys/prctl.h \
 269         sys/resource.h \
 270         sys/signalfd.h \
 271         sys/socket.h \
 272         sys/sockio.h \
 273         sys/stat.h \
 274         sys/sysmacros.h \
 275         sys/swap.h \
 276         sys/syscall.h \
 277         sys/time.h \
 278         sys/timex.h \
 279         sys/ttydefaults.h \
 280         sys/types.h \
 281         sys/ucred.h \
 282         sys/un.h \
 283         unistd.h \
 284         shadow.h \
 285         utmp.h \
 286         utmpx.h \
 287 ])
 288
 289 # There is a collision in old kernel-headers. The both files mount.h and fs.h
 290 # define MS_* macros. Fixed by kernel commit e462ec50cb5fad19f6003a3d8087f4a0945dd2b1.
 291 #
 292 AC_CHECK_HEADERS([linux/fs.h ], [], [],
 293  [#ifdef HAVE_SYS_MOUNT_H
 294    # include <linux/fs.h>
 295    # include <sys/mount.h>
 296   #endif
 297 ])
 298
 299 AC_CHECK_HEADERS([linux/gsmmux.h ], [], [],
 300  [#ifdef LINUX_GSMMUX_H
 301    # include <linux/gsmmux.h>
 302    #endif
 303 ])
 304
 305 AC_CHECK_HEADERS([security/pam_misc.h],
 306                 [AM_CONDITIONAL([HAVE_LINUXPAM], [true])],
 307                 [AM_CONDITIONAL([HAVE_LINUXPAM], [false])], [
 308 #ifdef HAVE_SECURITY_PAM_APPL_H
 309 #include <security/pam_appl.h>
 310 #endif
 311 ])
 312
 313 AC_CHECK_HEADERS([linux/blkzoned.h])
 314
 315 AC_CHECK_HEADERS([security/openpam.h], [], [], [
 316 #ifdef HAVE_SECURITY_PAM_APPL_H
 317 #include <security/pam_appl.h>
 318 #endif
 319 ])
 320
 321 AC_CHECK_HEADERS([langinfo.h],
 322                 [AM_CONDITIONAL([HAVE_LANGINFO], [true])],
 323                 [AM_CONDITIONAL([HAVE_LANGINFO], [false])])
 324
 325 AC_MSG_CHECKING([whether langinfo.h defines ALTMON_x constants])
 326 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 327         #include <langinfo.h>
 328 ]], [[
 329         char *str;
 330         str = nl_langinfo (ALTMON_1);
 331         str = nl_langinfo (ALTMON_2);
 332         str = nl_langinfo (ALTMON_3);
 333         str = nl_langinfo (ALTMON_4);
 334         str = nl_langinfo (ALTMON_5);
 335         str = nl_langinfo (ALTMON_6);
 336         str = nl_langinfo (ALTMON_7);
 337         str = nl_langinfo (ALTMON_8);
 338         str = nl_langinfo (ALTMON_9);
 339         str = nl_langinfo (ALTMON_10);
 340         str = nl_langinfo (ALTMON_11);
 341         str = nl_langinfo (ALTMON_12);
 342 ]])], [
 343         AC_MSG_RESULT([yes])
 344         AC_DEFINE([HAVE_LANGINFO_ALTMON], [1],
 345                 [Define if langinfo.h defines ALTMON_x constants])
 346 ], [
 347         AC_MSG_RESULT([no])
 348 ])
 349
 350
 351 AC_MSG_CHECKING([whether langinfo.h defines _NL_ABALTMON_x constants])
 352 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 353         #include <langinfo.h>
 354 ]], [[
 355         char *str;
 356         str = nl_langinfo (_NL_ABALTMON_1);
 357         str = nl_langinfo (_NL_ABALTMON_2);
 358         str = nl_langinfo (_NL_ABALTMON_3);
 359         str = nl_langinfo (_NL_ABALTMON_4);
 360         str = nl_langinfo (_NL_ABALTMON_5);
 361         str = nl_langinfo (_NL_ABALTMON_6);
 362         str = nl_langinfo (_NL_ABALTMON_7);
 363         str = nl_langinfo (_NL_ABALTMON_8);
 364         str = nl_langinfo (_NL_ABALTMON_9);
 365         str = nl_langinfo (_NL_ABALTMON_10);
 366         str = nl_langinfo (_NL_ABALTMON_11);
 367         str = nl_langinfo (_NL_ABALTMON_12);
 368 ]])], [
 369         AC_MSG_RESULT([yes])
 370         AC_DEFINE([HAVE_LANGINFO_NL_ABALTMON], [1],
 371                 [Define if langinfo.h defines _NL_ABALTMON_x constants])
 372 ], [
 373         AC_MSG_RESULT([no])
 374 ])
 375
 376
 377 dnl Convert some ac_cv_header_* variables to have_*
 378 dnl
 379 have_linux_version_h=$ac_cv_header_linux_version_h
 380 have_linux_blkzoned_h=$ac_cv_header_linux_blkzoned_h
 381 have_linux_btrfs_h=$ac_cv_header_linux_btrfs_h
 382 have_linux_raw_h=$ac_cv_header_linux_raw_h
 383 have_linux_securebits_h=$ac_cv_header_linux_securebits_h
 384 have_linux_watchdog_h=$ac_cv_header_linux_watchdog_h
 385 have_security_pam_appl_h=$ac_cv_header_security_pam_appl_h
 386 have_security_pam_misc_h=$ac_cv_header_security_pam_misc_h
 387 have_security_openpam_h=$ac_cv_header_security_openpam_h
 388 have_shadow_h=$ac_cv_header_shadow_h
 389 have_sys_signalfd_h=$ac_cv_header_sys_signalfd_h
 390 have_utmpx_h=$ac_cv_header_utmpx_h
 391
 392 AS_CASE([$linux_os:$have_linux_version_h],
 393   [yes:no],
 394     [AC_MSG_ERROR([kernel headers required on Linux])]
 395 )
 396
 397 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 398 #include <time.h>
 399 #include <unistd.h>
 400 ]], [[
 401     int a = 0;
 402     struct tm *tm = localtime(0);
 403     if (a == -1)  /* false */
 404         sleep(tm->tm_gmtoff);
 405 ]])],
 406 [AC_DEFINE([HAVE_TM_GMTOFF], [1], [Does struct tm have a field tm_gmtoff?])
 407 ])
 408
 409 AC_CHECK_MEMBERS([struct termios.c_line],,,
 410     [[#include <termios.h>]])
 411
 412 AC_CHECK_MEMBERS([struct stat.st_mtim.tv_nsec],,,
 413         [#include <sys/stat.h>])
 414
 415 AC_CHECK_DECLS([_NL_TIME_WEEK_1STDAY],[],[],[[#include <langinfo.h>]])
 416
 417 AC_CHECK_DECL([llseek],
 418         [AC_DEFINE([HAVE_LLSEEK_PROTOTYPE], [1],
 419                         [Define to 1 if have llseek prototype])],
 420         [],
 421         [#include <unistd.h>])
 422
 423 AC_CHECK_DECL([lseek64],
 424         [AC_DEFINE([HAVE_LSEEK64_PROTOTYPE], [1],
 425                         [Define to 1 if have lseek64 prototype])],
 426         [],
 427         [#define _LARGEFILE_SOURCE
 428          #define _LARGEFILE64_SOURCE
 429          #include <unistd.h>])
 430
 431 AC_CHECK_DECL([environ],
 432         [AC_DEFINE([HAVE_ENVIRON_DECL], [1],
 433                 [Define to 1 if have **environ prototype])],
 434 )
 435
 436 AC_CHECK_DECL([strsignal],
 437         [AC_DEFINE([HAVE_STRSIGNAL_DECL], [1],
 438                 [Define to 1 if have strsignal function prototype])],
 439 )
 440
 441 AC_CHECK_DECL([TIOCGLCKTRMIOS],
 442               [have_tiocglcktrmios=yes], [have_tiocglcktrmios=no],
 443               [#include <sys/ioctl.h>])
 444 AC_CHECK_DECL([SOCK_CLOEXEC],
 445               [have_sock_cloexec=yes], [have_sock_cloexec=no],
 446               [#include <sys/types.h>
 447                #include <sys/socket.h>])
 448 AC_CHECK_DECL([SOCK_NONBLOCK],
 449               [have_sock_nonblock=yes], [have_sock_nonblock=no],
 450               [#include <sys/types.h>
 451                #include <sys/socket.h>])
 452 AC_CHECK_DECL([SO_PASSCRED],
 453               [have_so_passcred=yes], [have_so_passcred=no],
 454               [#include <sys/types.h>
 455                #include <sys/socket.h>])
 456
 457 AC_CHECK_FUNCS([ \
 458         clearenv \
 459         __fpurge \
 460         fpurge \
 461         __fpending \
 462         secure_getenv \
 463         __secure_getenv \
 464         eaccess \
 465         err \
 466         errx \
 467         explicit_bzero \
 468         fsync \
 469         utimensat \
 470         getdomainname \
 471         getdtablesize \
 472         getexecname \
 473         getmntinfo \
 474         getrandom \
 475         getrlimit \
 476         getsgnam \
 477         inotify_init \
 478         jrand48 \
 479         lchown \
 480         llseek \
 481         lseek64 \
 482         mempcpy \
 483         mkostemp \
 484         nanosleep \
 485         ntp_gettime \
 486         personality \
 487         posix_fadvise \
 488         prctl \
 489         qsort_r \
 490         rpmatch \
 491         scandirat \
 492         setprogname \
 493         setresgid \
 494         setresuid \
 495         sched_setattr \
 496         sched_setscheduler \
 497         sigqueue \
 498         srandom \
 499         strnchr \
 500         strndup \
 501         strnlen \
 502         sysconf \
 503         sysinfo \
 504         timegm \
 505         usleep \
 506         vwarnx \
 507         warn \
 508         warnx \
 509 ])
 510 AC_FUNC_FSEEKO
 511
 512 AC_CHECK_FUNCS([openat fstatat unlinkat], [have_openat=yes], [have_openat=no])
 513 AC_CHECK_FUNCS([ioperm iopl], [have_io=yes])
 514 AC_CHECK_FUNCS([futimens], [have_futimens=yes])
 515 AC_CHECK_FUNCS([inotify_init1], [have_inotify_init1=yes])
 516 AC_CHECK_FUNCS([open_memstream], [have_open_memstream=yes],[have_open_memstream=no])
 517 AC_CHECK_FUNCS([reboot], [have_reboot=yes],[have_reboot=no])
 518 AC_CHECK_FUNCS([updwtmpx updwtmpx], [have_gnu_utmpx=yes], [have_gnu_utmpx=no])
 519 AC_CHECK_FUNCS([getusershell], [have_getusershell=yes],[have_getusershell=no])
 520
 521 AM_CONDITIONAL([HAVE_OPENAT], [test "x$have_openat" = xyes])
 522
 523 have_setns_syscall="yes"
 524 UL_CHECK_SYSCALL([setns])
 525 AS_IF([test "x$ul_cv_syscall_setns" = xno], [
 526    have_setns_syscall="no"
 527 ])
 528
 529 AC_CHECK_FUNCS([isnan], [],
 530         [AC_CHECK_LIB([m], [isnan], [MATH_LIBS="-lm"])]
 531         [AC_CHECK_LIB([m], [__isnan], [MATH_LIBS="-lm"])]
 532 )
 533 AC_SUBST([MATH_LIBS])
 534
 535
 536 dnl lib/mononotic.c may require -lrt
 537 AC_CHECK_FUNCS([clock_gettime], [],
 538         [AC_CHECK_LIB([rt], [clock_gettime], [REALTIME_LIBS="-lrt"])]
 539 )
 540
 541 have_timer="no"
 542 AC_CHECK_FUNCS([timer_create],
 543         [have_timer="yes"],
 544         [AC_CHECK_LIB([rt], [timer_create], [
 545                 have_timer="yes"
 546                 REALTIME_LIBS="-lrt"
 547         ],[
 548                 AC_SEARCH_LIBS([timer_create], [rt], [
 549                         AC_MSG_RESULT(yes)
 550                         have_timer="yes"
 551                         REALTIME_LIBS="-lrt -lpthread"
 552                 ],[], [-lpthread]
 553                 )
 554                 ])]
 555 )
 556
 557 AC_SUBST([REALTIME_LIBS])
 558
 559
 560 AC_CHECK_LIB([rtas], [rtas_get_sysparm], [
 561         RTAS_LIBS="-lrtas"
 562         AC_DEFINE_UNQUOTED([HAVE_LIBRTAS], [1], [Define if librtas exists]), [],
 563 ])
 564 AC_SUBST([RTAS_LIBS])
 565
 566
 567 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 568                 AC_DEFINE_UNQUOTED([HAVE_SA_LEN], [1], [Define if struct sockaddr contains sa_len]), [],
 569         [#include <sys/types.h>
 570          #include <sys/socket.h>])
 571
 572 SOCKET_LIBS=
 573 AC_SEARCH_LIBS([socket], [socket],
 574         [AS_IF([test x"$ac_cv_search_socket" != x"none required"],
 575                 [SOCKET_LIBS="$SOCKET_LIBS -lsocket"])
 576 ])
 577 AC_SUBST([SOCKET_LIBS])
 578
 579
 580 have_dirfd=no
 581 AC_CHECK_FUNCS([dirfd], [have_dirfd=yes], [have_dirfd=no])
 582 AS_IF([test x"$have_dirfd" = xno], [
 583         AC_CHECK_DECLS([dirfd],
 584                 [have_dirfd=yes], [have_dirfd=no],
 585                 [#include <sys/types.h>
 586                  #include <dirent.h>])
 587 ])
 588
 589 have_ddfd=no
 590 AS_IF([test x"$have_dirfd" = xno], [
 591         AC_CHECK_MEMBERS([DIR.dd_fd],
 592                 [have_ddfd=yes], [have_ddfd=no],
 593                 [#include <sys/types.h>
 594                  #include <dirent.h>])
 595 ])
 596
 597 AM_CONDITIONAL([HAVE_DIRFD], [test "x$have_dirfd" = xyes -o "x$have_ddfd" = xyes])
 598
 599
 600 AC_MSG_CHECKING([whether program_invocation_short_name is defined])
 601 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 602         #include <errno.h>
 603 ]], [[
 604         program_invocation_short_name = "test";
 605 ]])], [
 606         AC_MSG_RESULT([yes])
 607         AC_DEFINE([HAVE_PROGRAM_INVOCATION_SHORT_NAME], [1],
 608                 [Define if program_invocation_short_name is defined])
 609 ], [
 610         AC_MSG_RESULT([no])
 611 ])
 612
 613
 614 AC_MSG_CHECKING([whether __progname is defined])
 615 AC_LINK_IFELSE([AC_LANG_PROGRAM([extern char *__progname;],
 616            [if (*__progname == 0) return 1;])],
 617            AC_DEFINE([HAVE___PROGNAME], [1], [Define if __progname is defined])
 618            AC_MSG_RESULT([yes]),
 619            AC_MSG_RESULT([no]))
 620
 621 dnl Static compilation
 622 m4_define([UL_STATIC_PROGRAMS], [losetup, mount, umount, fdisk, sfdisk, blkid, nsenter, unshare])
 623
 624 AC_ARG_ENABLE([static-programs],
 625   [AS_HELP_STRING([--enable-static-programs=LIST],
 626       [link static the programs in LIST (comma-separated,
 627       supported for ]m4_defn([UL_STATIC_PROGRAMS])[)])])
 628
 629 AS_CASE([$enable_static_programs],
 630   [yes],
 631     [enable_static_programs=m4_quote(UL_STATIC_PROGRAMS)],
 632   [no],
 633     [enable_static_programs=]
 634 )
 635
 636 dnl Set all the individual AM_CONDITIONALs
 637 m4_foreach([UL_PRG], m4_defn([UL_STATIC_PROGRAMS]), [
 638   AS_CASE([,$enable_static_programs,],
 639    [*,UL_PRG,*], [static_[]UL_PRG=yes]
 640   )
 641   AS_IF([test "x$static_[]UL_PRG" = xyes], [AC_MSG_NOTICE([enable static build: UL_PRG.])])
 642   AM_CONDITIONAL([HAVE_STATIC_]m4_toupper(UL_PRG),
 643     [test "x$static_[]UL_PRG" = xyes])
 644 ])
 645
 646
 647 AC_ARG_ENABLE([all-programs],
 648   AS_HELP_STRING([--disable-all-programs], [disable everything, might be overridden by --enable-<name>]),
 649   [], [enable_all_programs=undefined]
 650 )
 651
 652 AS_CASE([$enable_all_programs],
 653   [yes], [AC_MSG_WARN([force to build all programs by default])
 654           ul_default_estate=check],
 655   [no],  [AC_MSG_WARN([disable all programs by default])
 656           ul_default_estate=no]
 657 )
 658
 659
 660 AX_CHECK_TLS
 661
 662 AC_DEFUN([UL_SCANF_TYPE_MODIFIER], [dnl
 663 # include <stdio.h>
 664 # include <stdlib.h>
 665 int main()
 666 {
 667         int i;
 668         int rc = 1;
 669         char *s;
 670         i = sscanf("x", $1, &s);
 671         if (i == 1  && *s == 'x')
 672                 rc = 0;
 673         free(s);
 674         return rc;
 675 }])
 676
 677 AC_CACHE_VAL([scanf_cv_alloc_modifier],
 678   AC_RUN_IFELSE([AC_LANG_SOURCE([UL_SCANF_TYPE_MODIFIER(["%ms"])])],
 679     [scanf_cv_alloc_modifier=ms],
 680     AC_RUN_IFELSE([AC_LANG_SOURCE([UL_SCANF_TYPE_MODIFIER(["%as"])])],
 681       [scanf_cv_alloc_modifier=as],
 682       [scanf_cv_alloc_modifier=no]
 683     )
 684     ,
 685
 686     [AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 687      #include <stdio.h>
 688      #include <unistd.h>
 689
 690      #if defined(__GLIBC__) && !defined(__UCLIBC__)
 691
 692      #if !(__GLIBC_PREREQ(2, 7))
 693      #error %m is not available
 694      #endif
 695
 696      #elif defined(_POSIX_VERSION)
 697
 698      #if _POSIX_VERSION < 200809L
 699      #error %m is not available
 700      #endif
 701
 702      #else
 703      #error Your C-library is not supported.
 704      #endif
 705      ])],
 706     [scanf_cv_alloc_modifier=ms],
 707     [scanf_cv_alloc_modifier=no])]
 708   )
 709 )
 710
 711 AC_MSG_CHECKING([scanf string alloc modifiers])
 712 AS_CASE([$scanf_cv_alloc_modifier],
 713   [ms],
 714     [AC_MSG_RESULT([(%ms) yes])
 715      AC_DEFINE([HAVE_SCANF_MS_MODIFIER], [1], [scanf %ms modifier])
 716      have_scanf_alloc_modifier=yes],
 717   [as],
 718     [AC_MSG_RESULT([(%as) yes])
 719      have_scanf_alloc_modifier=yes
 720      AC_DEFINE([HAVE_SCANF_AS_MODIFIER], [1], [scanf %as modifier])],
 721   [AC_MSG_RESULT([no])
 722    have_scanf_alloc_modifier=no]
 723 )
 724
 725
 726 AC_ARG_WITH([util], AS_HELP_STRING([--without-util], [compile without libutil]),
 727   [], [with_util=auto]
 728 )
 729 AS_IF([test "x$with_util" = xno], [
 730   AM_CONDITIONAL([HAVE_UTIL], [false])
 731   have_util=no
 732 ], [
 733   UL_CHECK_LIB([util], [openpty])
 734 ])
 735
 736
 737 AC_CHECK_TYPES([union semun], [], [], [[
 738 #include <sys/sem.h>
 739 ]])
 740 AC_CHECK_TYPES([loff_t])
 741
 742
 743 AC_ARG_ENABLE([widechar],
 744   AS_HELP_STRING([--disable-widechar], [do not compile wide character support]),
 745   [], [enable_widechar=check]
 746 )
 747 UL_BUILD_INIT([widechar])
 748 UL_REQUIRES_COMPILE([widechar], [[
 749   #include <wchar.h>
 750   #include <wctype.h>
 751   #include <stdio.h>
 752   ]], [[
 753     wchar_t wc;
 754     wint_t w;
 755     w = fgetwc(stdin);
 756     if (w == WEOF) exit(1);
 757     wc = w;
 758     fputwc(wc,stdout);
 759   ]],
 760   [wchar_t support])
 761
 762 AS_IF([test "x$build_widechar" = xyes ], [
 763   AC_DEFINE([HAVE_WIDECHAR], [1], [Do we have wide character support?])
 764 ])
 765
 766
 767 AC_CHECK_TYPES([cpu_set_t], [have_cpu_set_t=yes], [], [[
 768 #include <sched.h>
 769 ]])
 770
 771 AM_CONDITIONAL([HAVE_CPU_SET_T], [test "x$have_cpu_set_t" = xyes])
 772
 773 AC_CHECK_TYPES([sighandler_t], [], [], [[
 774 #include <signal.h>
 775 ]])
 776
 777 AC_CHECK_DECLS([CPU_ALLOC], [], [], [[
 778 #include <sched.h>
 779 ]])
 780
 781 # on Solaris, you can't mix and match standards, since we use c99
 782 # aparently at this stage, XOPEN_SOURCE will conflict.  As workaround,
 783 # check for crypt.h and use that without XOPEN_SOURCE.
 784 have_crypt=no
 785 AC_CHECK_HEADERS([crypt.h])
 786 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 787 #ifdef HAVE_CRYPT_H
 788 #include <crypt.h>
 789 #else
 790 #define _XOPEN_SOURCE
 791 #include <unistd.h>
 792 #endif
 793 ]], [[
 794 char *c = crypt("abc","pw");
 795 ]])],[],[
 796   LIBS="$LIBS -lcrypt"
 797   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 798   #ifdef HAVE_CRYPT_H
 799   #include <crypt.h>
 800   #else
 801   #define _XOPEN_SOURCE
 802   #include <unistd.h>
 803   #endif
 804   ]], [[
 805   char *c = crypt("abc","pw");
 806   ]])],[
 807   AC_DEFINE([HAVE_LIBCRYPT], [1], [Do we need -lcrypt?])
 808   have_libcrypt=yes
 809   have_crypt=yes
 810   ],[
 811   AC_MSG_WARN([crypt() is not available])
 812   ])
 813 ])
 814 AM_CONDITIONAL([HAVE_LIBCRYPT], [test "x$have_libcrypt" = xyes])
 815
 816
 817 AC_ARG_WITH([selinux],
 818   AS_HELP_STRING([--with-selinux], [compile with SELinux support]),
 819   [], [with_selinux=no]
 820 )
 821
 822 AS_IF([test "x$with_selinux" = xno], [
 823   AM_CONDITIONAL([HAVE_SELINUX], [false])
 824 ], [
 825   PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.0],
 826         [AC_DEFINE([HAVE_LIBSELINUX], [1], [Define if SELinux is available])
 827          UL_PKG_STATIC([SELINUX_LIBS_STATIC], [libselinux])
 828          AM_CONDITIONAL([HAVE_SELINUX], [true])
 829          have_selinux=yes],
 830         [have_selinux=no])
 831
 832   AS_CASE([$with_selinux:$have_selinux],
 833     [yes:no], [AC_MSG_ERROR([SELinux selected but libselinux not found or too old])]
 834   )
 835
 836   AS_IF([test "x$have_selinux" = xyes], [
 837     UL_SET_FLAGS([], [], [$SELINUX_LIBS])
 838     # This function is missing in old libselinux 1.xx versions
 839     AC_CHECK_FUNCS([security_get_initial_context])
 840     UL_RESTORE_FLAGS
 841   ])
 842 ])
 843 AC_SUBST([SELINUX_LIBS])
 844 AC_SUBST([SELINUX_LIBS_STATIC])
 845
 846
 847 AC_ARG_WITH([audit],
 848   AS_HELP_STRING([--with-audit], [compile with audit support]),
 849   [], [with_audit=no]
 850 )
 851
 852 AS_IF([test "x$with_audit" = xno], [
 853   AM_CONDITIONAL([HAVE_AUDIT], [false])
 854 ], [
 855   UL_CHECK_LIB([audit], [audit_log_user_message])
 856   AS_CASE([$with_audit:$have_audit],
 857     [yes:no],
 858       [AC_MSG_ERROR([Audit selected but libaudit not found (or does not support audit_log_user_message())])]
 859   )
 860 ])
 861
 862 AC_ARG_WITH([udev], AS_HELP_STRING([--without-udev], [compile without udev support]),
 863   [], [with_udev=auto]
 864 )
 865
 866 AS_IF([test "x$with_udev" = xno], [
 867   AM_CONDITIONAL([HAVE_UDEV], [false])
 868 ], [
 869   UL_CHECK_LIB([udev], [udev_new])
 870   AS_CASE([$with_udev:$have_udev],
 871     [yes:no],
 872       [AC_MSG_ERROR([udev selected but libudev not found])]
 873   )
 874 ])
 875
 876
 877 dnl wide-char ncurses
 878 AC_ARG_WITH([ncursesw],
 879   AS_HELP_STRING([--without-ncursesw], [do not build with wide-char ncurses]),
 880   [], [with_ncursesw=auto]
 881 )
 882 have_ncursesw=no
 883 have_ncursesw_header=no
 884 AS_IF([test "x$with_ncursesw" != xno], [
 885   UL_NCURSES_CHECK([ncursesw])
 886   AS_IF([test "x$have_ncursesw" = xyes], [
 887     AC_CHECK_HEADERS([ncursesw/ncurses.h], [have_ncursesw_header=yes])
 888     AC_CHECK_HEADERS([ncursesw/term.h])
 889
 890     # Define HAVE_NCURSES_H only if check for HAVE_NCURSESW_NCURSES_H is
 891     # unsuccessful to avoid too many *_H permitations in config.h
 892     AS_IF([test "x$have_ncursesw_header" = xno], [
 893            AC_CHECK_HEADERS([ncurses.h], [have_ncursesw_header=yes])
 894            AC_CHECK_HEADERS([term.h])
 895     ])
 896     AS_IF([test "x$have_ncursesw_header" = xno], [have_ncursesw=no])
 897   ])
 898   AS_IF([test "x$have_ncursesw" = xyes], [
 899     CURSES_LIB_NAME="ncursesw"
 900     AC_DEFINE([HAVE_LIBNCURSESW], [1], [Define if ncursesw library available])
 901   ])
 902 ])
 903 AS_CASE([$with_ncursesw:$have_ncursesw],
 904   [yes:no], [AC_MSG_ERROR([ncursesw selected, but library not found])])
 905
 906
 907 dnl non-wide ncurses
 908 AC_ARG_WITH([ncurses],
 909   AS_HELP_STRING([--with-ncurses], [build with non-wide ncurses]),
 910   [], [with_ncurses=auto]
 911 )
 912 have_ncurses=no
 913 have_ncurses_header=no
 914 AS_CASE([$with_ncurses:$build_widechar],
 915   [yes:yes], [AC_MSG_ERROR([wide-char support enabled, but non-wide ncurses selects])])
 916
 917 AS_IF([test "x$have_ncursesw" = xno -a "x$with_ncurses" != xno ], [
 918   UL_NCURSES_CHECK([ncurses])
 919   AS_IF([test "x$have_ncurses" = xyes], [
 920     AC_CHECK_HEADERS([ncurses/ncurses.h], [have_ncurses_header=yes])
 921     AC_CHECK_HEADERS([ncurses/term.h])
 922
 923     # Define HAVE_NCURSES_H only if check for HAVE_NCURSES_NCURSES_H is
 924     # unsuccessful to avoid too many *_H permitations in config.h
 925     AS_IF([test "x$have_ncurses_header" = xno], [
 926            AC_CHECK_HEADERS([ncurses.h], [have_ncurses_header=yes])
 927            AC_CHECK_HEADERS([term.h])
 928     ])
 929     AS_IF([test "x$have_ncurses_header" = xno], [have_ncurses=no])
 930   ])
 931   AS_IF([test "x$have_ncurses" = xyes], [
 932     CURSES_LIB_NAME="ncurses"
 933     AC_DEFINE([HAVE_LIBNCURSES], [1], [Define if ncurses library available])
 934   ])
 935 ])
 936 AS_CASE([$with_ncurses:$have_ncurses],
 937   [yes:no], [AC_MSG_ERROR([ncurses selected, but library not found])])
 938
 939 AC_SUBST([NCURSES_CFLAGS])
 940 AC_SUBST([NCURSES_LIBS])
 941 AM_CONDITIONAL([HAVE_NCURSES], [test "x$have_ncursesw" = xyes -o  "x$have_ncurses" = xyes])
 942
 943
 944 AC_ARG_WITH([slang],
 945   AS_HELP_STRING([--with-slang], [compile cfdisk with slang rather than ncurses]),
 946   [], [with_slang=no]
 947 )
 948 have_slang=no
 949 AS_IF([test "x$with_slang" = xyes], [
 950   AC_CHECK_HEADERS([slang.h slang/slang.h])
 951   AC_CHECK_HEADERS([slcurses.h slang/slcurses.h],
 952                    [have_slang=yes], [], [
 953 #ifdef HAVE_SLANG_H
 954 #include <slang.h>
 955 #elif defined(HAVE_SLANG_SLANG_H)
 956 #include <slang/slang.h>
 957 #endif
 958 ])
 959   AS_IF([test "x$have_slang" = xno], [
 960     AC_MSG_ERROR([slang selected but slcurses.h not found])],
 961     [CURSES_LIB_NAME=slang
 962   ])
 963 ])
 964 AM_CONDITIONAL([HAVE_SLANG], [test "x$have_slang" = xyes])
 965
 966
 967 AS_IF([test "x$have_slang" = xyes -o "x$have_ncursesw" = xyes -o "x$have_ncurses" = xyes], [
 968         AC_CHECK_LIB([$CURSES_LIB_NAME], use_default_colors, [
 969                      AC_DEFINE(HAVE_USE_DEFAULT_COLORS, 1,
 970                                [Define if curses library has the use_default_colors().])
 971         ])
 972         AC_CHECK_LIB([$CURSES_LIB_NAME], resizeterm, [
 973                      AC_DEFINE(HAVE_RESIZETERM, 1,
 974                                [Define if curses library has the resizeterm().])
 975         ])
 976 ])
 977
 978
 979 AC_ARG_WITH([tinfo], AS_HELP_STRING([--without-tinfo], [compile without libtinfo]),
 980   [], [with_tinfo=auto]
 981 )
 982 have_tinfo=no
 983 have_tinfow=no
 984 AS_IF([test "x$with_tinfo" != xno], [
 985   AS_IF([test "x$have_ncursesw" = xyes], [
 986     UL_TINFO_CHECK([tinfow])
 987   ])
 988   AS_IF([test "x$have_tinfow" = xno], [
 989     UL_TINFO_CHECK([tinfo])
 990   ])
 991 ])
 992 AC_SUBST([TINFO_LIBS])
 993 AC_SUBST([TINFO_LIBS_STATIC])
 994 AC_SUBST([TINFO_CFLAGS])
 995 AM_CONDITIONAL([HAVE_TINFO], [test "x$have_tinfo" = xyes -o "x$have_tinfow" = xyes])
 996 AS_IF([test "x$have_tinfo" = xyes -o "x$have_tinfow" = xyes], [
 997   AC_DEFINE(HAVE_LIBTINFO, 1, [Define if libtinfo or libtinfow available.])
 998 ])
 999
1000
1001 AC_ARG_WITH([readline],
1002   AS_HELP_STRING([--without-readline], [do not build with GNU Readline support]),
1003   [], [with_readline=auto]
1004 )
1005
1006 AS_IF([test "x$with_readline" = xno], [
1007   AM_CONDITIONAL([HAVE_READLINE], [false])
1008 ], [
1009   UL_CHECK_LIB([readline], [readline])
1010   AS_CASE([$with_readline:$have_readline],
1011     [yes:no],
1012       [AC_MSG_ERROR([readline selected but libreadline not found ])],
1013     [*:yes],
1014       [READLINE_LIBS="-lreadline"
1015        READLINE_LIBS_STATIC="-lreadline $TINFO_LIBS_STATIC"]
1016   )
1017 ])
1018 AC_SUBST([READLINE_LIBS])
1019 AC_SUBST([READLINE_LIBS_STATIC])
1020
1021
1022 AC_ARG_WITH([utempter],
1023   AS_HELP_STRING([--with-utempter], [compile script(1) with libutempter]),
1024   [], [with_utempter=no]
1025 )
1026
1027 AS_IF([test "x$with_utempter" = xyes], [
1028   UL_CHECK_LIB([utempter], [utempter_add_record])
1029   AS_IF([test "x$have_utempter" = xno], [
1030     AC_MSG_ERROR([utempter selected but libutempter not found])
1031   ])
1032 ], [
1033   AM_CONDITIONAL([HAVE_UTEMPTER], [false])
1034 ])
1035
1036
1037 dnl
1038 dnl libuuid
1039 dnl
1040 AC_ARG_ENABLE([libuuid],
1041   AS_HELP_STRING([--disable-libuuid], [do not build libuuid and uuid utilities]),
1042   [], [UL_DEFAULT_ENABLE([libuuid], [yes])]
1043 )
1044 UL_BUILD_INIT([libuuid])
1045 AC_SUBST([LIBUUID_VERSION])
1046 AC_SUBST([LIBUUID_VERSION_INFO])
1047 AM_CONDITIONAL(BUILD_LIBUUID, test "x$build_libuuid" = xyes)
1048
1049 AC_ARG_ENABLE([libuuid-force-uuidd],
1050   AS_HELP_STRING([--enable-libuuid-force-uuidd], [support uuidd even though the daemon is not built]),
1051   [], [enable_libuuid_force_uuidd=no]
1052 )
1053
1054 AS_IF([test "x$build_libuuid" = xyes], [
1055   AC_DEFINE(HAVE_LIBUUID, 1, [Define to 1 if you have the -luuid.])
1056 ])
1057
1058 dnl
1059 dnl libblkid
1060 dnl
1061 AC_ARG_ENABLE([libblkid],
1062   AS_HELP_STRING([--disable-libblkid], [do not build libblkid and many related utilities]),
1063   [], [UL_DEFAULT_ENABLE([libblkid], [check])]
1064 )
1065 UL_BUILD_INIT([libblkid])
1066 UL_REQUIRES_HAVE([libblkid], [openat], [openat functions])
1067 UL_REQUIRES_HAVE([libblkid], [dirfd,ddfd], [dirfd or ddfd function])
1068 AC_SUBST([LIBBLKID_DATE])
1069 AC_SUBST([LIBBLKID_VERSION])
1070 AC_SUBST([LIBBLKID_VERSION_INFO])
1071 AC_DEFINE_UNQUOTED([LIBBLKID_VERSION], ["$LIBBLKID_VERSION"], [libblkid version string])
1072 AC_DEFINE_UNQUOTED([LIBBLKID_DATE], ["$LIBBLKID_DATE"], [libblkid date string])
1073 AS_IF([test "x$build_libblkid" = xyes], [
1074   AC_DEFINE([HAVE_LIBBLKID], [1], [Define to 1 if you have the -lblkid.])
1075 ])
1076 AM_CONDITIONAL([BUILD_LIBBLKID], [test "x$build_libblkid" = xyes])
1077 AM_CONDITIONAL([BUILD_LIBBLKID_TESTS], [test "x$build_libblkid" = xyes -a "x$enable_static" = xyes])
1078
1079 dnl
1080 dnl libmount
1081 dnl
1082 AC_ARG_ENABLE([libmount],
1083   AS_HELP_STRING([--disable-libmount], [do not build libmount]),
1084   [], [UL_DEFAULT_ENABLE([libmount], [check])]
1085 )
1086 UL_BUILD_INIT([libmount])
1087 UL_REQUIRES_BUILD([libmount], [libblkid])
1088 UL_REQUIRES_HAVE([libmount], [scanf_alloc_modifier], [scanf string alloc modifier])
1089 UL_REQUIRES_HAVE([libmount], [dirfd,ddfd], [dirfd or ddfd function])
1090 AM_CONDITIONAL([BUILD_LIBMOUNT], [test "x$build_libmount" = xyes])
1091 AM_CONDITIONAL([BUILD_LIBMOUNT_TESTS], [test "x$build_libmount" = xyes -a "x$enable_static" = xyes])
1092 AS_IF([test "x$build_libmount" = xyes], [
1093   AC_DEFINE(HAVE_LIBMOUNT, 1, [Define if libmount available.])
1094   AS_IF([test "x$have_setns_syscall" = "xyes"], [
1095     AC_DEFINE([USE_LIBMOUNT_SUPPORT_NAMESPACES], [1], [Define to 1 if want to support namepaces.])
1096   ],[
1097     AC_MSG_WARN([libmount will be compiled without namespaces support])
1098   ])
1099 ])
1100
1101 AC_SUBST([LIBMOUNT_VERSION])
1102 AC_SUBST([LIBMOUNT_MAJOR_VERSION], $PACKAGE_VERSION_MAJOR)
1103 AC_SUBST([LIBMOUNT_MINOR_VERSION], $PACKAGE_VERSION_MINOR)
1104 AC_SUBST([LIBMOUNT_PATCH_VERSION], $PACKAGE_VERSION_RELEASE)
1105 AC_SUBST([LIBMOUNT_VERSION_INFO])
1106 AC_DEFINE_UNQUOTED([LIBMOUNT_VERSION], ["$LIBMOUNT_VERSION"], [libmount version string])
1107
1108 AC_ARG_ENABLE([libmount-support-mtab],
1109   AS_HELP_STRING([--enable-libmount-support-mtab], [support /etc/mtab (default is use /proc/self/mountinfo)]),
1110   [], [enable_libmount_support_mtab=no]
1111 )
1112
1113 AS_IF([test "x$enable_libmount_support_mtab" = xyes], [
1114   AC_DEFINE([USE_LIBMOUNT_SUPPORT_MTAB], [1], [Define to 1 if want to support mtab.])
1115 ])
1116
1117 dnl
1118 dnl libsmartcols
1119 dnl
1120 AC_ARG_ENABLE([libsmartcols],
1121   AS_HELP_STRING([--disable-libsmartcols], [do not build libsmartcols]),
1122   [], [UL_DEFAULT_ENABLE([libsmartcols], [yes])]
1123 )
1124 UL_BUILD_INIT([libsmartcols])
1125 AM_CONDITIONAL([BUILD_LIBSMARTCOLS], [test "x$build_libsmartcols" = xyes])
1126
1127 AC_SUBST([LIBSMARTCOLS_VERSION])
1128 AC_SUBST([LIBSMARTCOLS_VERSION_INFO])
1129 AC_DEFINE_UNQUOTED([LIBSMARTCOLS_VERSION], ["$LIBSMARTCOLS_VERSION"], [libsmartcols version string])
1130
1131
1132 dnl
1133 dnl libfdisk
1134 dnl
1135 AC_ARG_ENABLE([libfdisk],
1136   AS_HELP_STRING([--disable-libfdisk], [do not build libfdisk]),
1137   [], [UL_DEFAULT_ENABLE([libfdisk], [check])]
1138 )
1139 UL_BUILD_INIT([libfdisk])
1140 UL_REQUIRES_BUILD([libfdisk], [libuuid])
1141 AM_CONDITIONAL([BUILD_LIBFDISK], [test "x$build_libfdisk" = xyes])
1142 AM_CONDITIONAL([BUILD_LIBFDISK_TESTS], [test "x$build_libfdisk" = xyes -a "x$enable_static" = xyes])
1143
1144 AS_IF([test "x$build_libblkid" = xyes],
1145   [LIBFDISK_PC_REQUIRES="uuid blkid"],[LIBFDISK_PC_REQUIRES="uuid"])
1146 AC_SUBST([LIBFDISK_PC_REQUIRES])
1147
1148 AC_SUBST([LIBFDISK_VERSION])
1149 AC_SUBST([LIBFDISK_MAJOR_VERSION], $PACKAGE_VERSION_MAJOR)
1150 AC_SUBST([LIBFDISK_MINOR_VERSION], $PACKAGE_VERSION_MINOR)
1151 AC_SUBST([LIBFDISK_PATCH_VERSION], $PACKAGE_VERSION_RELEASE)
1152 AC_SUBST([LIBFDISK_VERSION_INFO])
1153 AC_DEFINE_UNQUOTED([LIBFDISK_VERSION], ["$LIBFDISK_VERSION"], [libfdisk version string])
1154
1155
1156 AC_ARG_ENABLE([fdisks],
1157   AS_HELP_STRING([--disable-fdisks], [do not build fdisk(8), sfdisk(8) and cfdisk(8)]),
1158   [], [UL_DEFAULT_ENABLE([fdisks], [check])]
1159 )
1160 enable_fdisk=$enable_fdisks
1161 enable_sfdisk=$enable_fdisks
1162 enable_cfdisk=$enable_fdisks
1163
1164 UL_BUILD_INIT([fdisk])
1165 UL_REQUIRES_HAVE([fdisk], [openat], [openat functions])
1166 UL_REQUIRES_HAVE([fdisk], [dirfd,ddfd], [dirfd or ddfd function])
1167 UL_REQUIRES_BUILD([fdisk], [libfdisk])
1168 UL_REQUIRES_BUILD([fdisk], [libsmartcols])
1169 AM_CONDITIONAL([BUILD_FDISK], [test "x$build_fdisk" = xyes])
1170
1171
1172 UL_BUILD_INIT([sfdisk])
1173 UL_REQUIRES_HAVE([sfdisk], [openat], [openat functions])
1174 UL_REQUIRES_HAVE([sfdisk], [dirfd,ddfd], [dirfd or ddfd function])
1175 UL_REQUIRES_BUILD([sfdisk], [libfdisk])
1176 UL_REQUIRES_BUILD([sfdisk], [libsmartcols])
1177 AM_CONDITIONAL([BUILD_SFDISK], [test "x$build_sfdisk" = xyes])
1178
1179
1180 UL_BUILD_INIT([cfdisk])
1181 UL_REQUIRES_BUILD([cfdisk], [libfdisk])
1182 UL_REQUIRES_BUILD([cfdisk], [libsmartcols])
1183 UL_REQUIRES_HAVE([cfdisk], [open_memstream], [open_memstream function])
1184 UL_REQUIRES_HAVE([cfdisk], [ncursesw,slang,ncurses], [ncursesw, ncurses or slang library])
1185 AM_CONDITIONAL([BUILD_CFDISK], [test "x$build_cfdisk" = xyes])
1186
1187
1188 AC_ARG_ENABLE([mount],
1189   AS_HELP_STRING([--disable-mount], [do not build mount(8) and umount(8)]),
1190   [], [UL_DEFAULT_ENABLE([mount], [check])]
1191 )
1192 UL_BUILD_INIT([mount])
1193 UL_REQUIRES_LINUX([mount])
1194 UL_REQUIRES_BUILD([mount], [libmount])
1195 AM_CONDITIONAL([BUILD_MOUNT], [test "x$build_mount" = xyes])
1196
1197
1198 AC_ARG_ENABLE([losetup],
1199   AS_HELP_STRING([--disable-losetup], [do not build losetup]),
1200   [], [UL_DEFAULT_ENABLE([losetup], [check])]
1201 )
1202 UL_BUILD_INIT([losetup])
1203 UL_REQUIRES_LINUX([losetup])
1204 UL_REQUIRES_BUILD([losetup], [libsmartcols])
1205 AM_CONDITIONAL([BUILD_LOSETUP], [test "x$build_losetup" = xyes])
1206
1207 AC_ARG_ENABLE([zramctl],
1208   AS_HELP_STRING([--disable-zramctl], [do not build zramctl]),
1209   [], [UL_DEFAULT_ENABLE([zramctl], [check])]
1210 )
1211 UL_BUILD_INIT([zramctl])
1212 UL_REQUIRES_LINUX([zramctl])
1213 UL_REQUIRES_BUILD([zramctl], [libsmartcols])
1214 AM_CONDITIONAL([BUILD_ZRAMCTL], [test "x$build_zramctl" = xyes])
1215
1216 AC_ARG_ENABLE([fsck],
1217   AS_HELP_STRING([--disable-fsck], [do not build fsck]),
1218   [], [UL_DEFAULT_ENABLE([fsck], [check])]
1219 )
1220 UL_BUILD_INIT([fsck])
1221 UL_REQUIRES_BUILD([fsck], [libmount])
1222 AM_CONDITIONAL([BUILD_FSCK], [test "x$build_fsck" = xyes])
1223
1224
1225 AC_ARG_ENABLE([partx],
1226   AS_HELP_STRING([--disable-partx], [do not build addpart, delpart, partx]),
1227   [], [UL_DEFAULT_ENABLE([partx], [check])]
1228 )
1229 UL_BUILD_INIT([partx])
1230 UL_REQUIRES_LINUX([partx])
1231 UL_REQUIRES_BUILD([partx], [libblkid])
1232 UL_REQUIRES_BUILD([partx], [libsmartcols])
1233 AM_CONDITIONAL([BUILD_PARTX], [test "x$build_partx" = xyes])
1234
1235
1236 AC_ARG_ENABLE([uuidd],
1237   AS_HELP_STRING([--disable-uuidd], [do not build the uuid daemon]),
1238   [], [UL_DEFAULT_ENABLE([uuidd], [check])]
1239 )
1240 UL_BUILD_INIT([uuidd])
1241 UL_REQUIRES_BUILD([uuidd], [libuuid])
1242 UL_REQUIRES_HAVE([uuidd], [timer], [timer_create function])
1243 UL_REQUIRES_HAVE([uuidd], [sys_signalfd_h], [sys/signalfd.h header])
1244 AS_IF([test "x$build_uuidd" = xyes || test "x$enable_libuuid_force_uuidd" = xyes], [
1245   AC_DEFINE([HAVE_UUIDD], [1], [Define to 1 if you want to use uuid daemon.])
1246 ])
1247 AM_CONDITIONAL([BUILD_UUIDD], [test "x$build_uuidd" = xyes])
1248
1249
1250 UL_BUILD_INIT([uuidgen], [check])
1251 UL_REQUIRES_BUILD([uuidgen], [libuuid])
1252 AM_CONDITIONAL([BUILD_UUIDGEN], [test "x$build_uuidgen" = xyes])
1253
1254 UL_BUILD_INIT([uuidparse], [check])
1255 UL_REQUIRES_BUILD([uuidparse], [libuuid])
1256 UL_REQUIRES_BUILD([uuidparse], [libsmartcols])
1257 AM_CONDITIONAL([BUILD_UUIDPARSE], [test "x$build_uuidparse" = xyes])
1258
1259 UL_BUILD_INIT([blkid], [check])
1260 UL_REQUIRES_BUILD([blkid], [libblkid])
1261 AM_CONDITIONAL([BUILD_BLKID], [test "x$build_blkid" = xyes])
1262
1263 UL_BUILD_INIT([findfs], [check])
1264 UL_REQUIRES_BUILD([findfs], [libblkid])
1265 AM_CONDITIONAL([BUILD_FINDFS], [test "x$build_findfs" = xyes])
1266
1267 UL_BUILD_INIT([wipefs], [check])
1268 UL_REQUIRES_BUILD([wipefs], [libblkid])
1269 UL_REQUIRES_BUILD([wipefs], [libsmartcols])
1270 AM_CONDITIONAL([BUILD_WIPEFS], [test "x$build_wipefs" = xyes])
1271
1272 UL_BUILD_INIT([findmnt], [check])
1273 UL_REQUIRES_BUILD([findmnt], [libmount])
1274 UL_REQUIRES_BUILD([findmnt], [libblkid])
1275 UL_REQUIRES_BUILD([findmnt], [libsmartcols])
1276 AM_CONDITIONAL([BUILD_FINDMNT], [test "x$build_findmnt" = xyes])
1277
1278
1279 AC_ARG_ENABLE([mountpoint],
1280   AS_HELP_STRING([--disable-mountpoint], [do not build mountpoint]),
1281   [], [UL_DEFAULT_ENABLE([mountpoint], [check])]
1282 )
1283 UL_BUILD_INIT([mountpoint])
1284 UL_REQUIRES_BUILD([mountpoint], [libmount])
1285 AM_CONDITIONAL([BUILD_MOUNTPOINT], [test "x$build_mountpoint" = xyes])
1286
1287
1288 AC_ARG_ENABLE([fallocate],
1289   AS_HELP_STRING([--disable-fallocate], [do not build fallocate]),
1290   [], [UL_DEFAULT_ENABLE([fallocate], [check])]
1291 )
1292 UL_BUILD_INIT([fallocate])
1293 UL_REQUIRES_LINUX([fallocate])
1294 UL_REQUIRES_SYSCALL_CHECK([fallocate], [UL_CHECK_SYSCALL([fallocate])])
1295 AM_CONDITIONAL([BUILD_FALLOCATE], [test "x$build_fallocate" = xyes])
1296
1297 AS_IF([test "x$build_fallocate" = xyes], [
1298   dnl check for valid fallocate() function
1299   dnl with 32 bits glibc 2.10, fallocate() exists but not fallocate64()
1300   dnl when _FILE_OFFSET_BITS==64, fallocate() is redirect to fallocate64()
1301   dnl and program can't be linked.
1302   dnl AC_CHECK_FUNC can't catch such errors since it's redefining
1303   dnl function prototype.
1304   AC_MSG_CHECKING([for valid fallocate() function])
1305   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1306 #ifdef HAVE_UNISTD_H
1307 # include <unistd.h>
1308 #endif
1309 #ifdef HAVE_SYS_TYPES_H
1310 # include <sys/types.h>
1311 #endif
1312 #ifdef HAVE_LINUX_FALLOC_H
1313 # include <linux/falloc.h>
1314 #endif
1315 #ifdef HAVE_FCNTL_H
1316 # include <fcntl.h>
1317 #endif
1318 ]],[[
1319    long ret;
1320    ret = fallocate(0, FALLOC_FL_KEEP_SIZE, 0xfffffffful, 0xfffffffful);
1321    if (ret != 0) {
1322       return 1;
1323    }
1324    ]])],[
1325   AC_MSG_RESULT([yes])
1326   AC_DEFINE([HAVE_FALLOCATE], [1], [Have valid fallocate() function])],[
1327   AC_MSG_RESULT([no])])
1328 ])
1329
1330 AS_IF([test "x$build_fallocate" = xyes], [
1331   dnl check for valid posix_fallocate() function
1332   AC_MSG_CHECKING([for valid posix_fallocate() function])
1333   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1334 #ifdef HAVE_UNISTD_H
1335 # include <unistd.h>
1336 #endif
1337 #ifdef HAVE_SYS_TYPES_H
1338 # include <sys/types.h>
1339 #endif
1340 #ifdef HAVE_LINUX_FALLOC_H
1341 # include <linux/falloc.h>
1342 #endif
1343 #ifdef HAVE_FCNTL_H
1344 # include <fcntl.h>
1345 #endif
1346 ]],[[
1347    long ret;
1348    ret = posix_fallocate(0, 0xfffffffful, 0xfffffffful);
1349    if (ret != 0) {
1350       return 1;
1351    }
1352    ]])],[
1353   AC_MSG_RESULT([yes])
1354   AC_DEFINE([HAVE_POSIX_FALLOCATE], [1], [Have valid posix_fallocate() function])],[
1355   AC_MSG_RESULT([no])])
1356 ])
1357
1358
1359 AC_ARG_ENABLE([unshare],
1360   AS_HELP_STRING([--disable-unshare], [do not build unshare]),
1361   [], [UL_DEFAULT_ENABLE([unshare], [check])]
1362 )
1363 UL_BUILD_INIT([unshare])
1364 UL_REQUIRES_LINUX([unshare])
1365 UL_REQUIRES_SYSCALL_CHECK([unshare], [UL_CHECK_SYSCALL([unshare])])
1366 AM_CONDITIONAL([BUILD_UNSHARE], [test "x$build_unshare" = xyes])
1367 AC_CHECK_FUNCS([unshare])
1368
1369 AC_ARG_ENABLE([nsenter],
1370   AS_HELP_STRING([--disable-nsenter], [do not build nsenter]),
1371   [], [UL_DEFAULT_ENABLE([nsenter], [check])]
1372 )
1373 UL_BUILD_INIT([nsenter])
1374 UL_REQUIRES_LINUX([nsenter])
1375 UL_REQUIRES_HAVE([nsenter], [setns_syscall], [setns syscall])
1376 AM_CONDITIONAL([BUILD_NSENTER], [test "x$build_nsenter" = xyes])
1377 AC_CHECK_FUNCS([setns])
1378
1379
1380 AC_ARG_WITH([cap_ng],
1381   AS_HELP_STRING([--without-cap-ng], [compile without libcap-ng]),
1382   [], [with_cap_ng=auto]
1383 )
1384 AS_IF([test "x$with_cap_ng" = xno], [
1385   AM_CONDITIONAL([HAVE_CAP_NG], [false])
1386   have_cap_ng=no
1387 ],[
1388   UL_CHECK_LIB([cap-ng], [capng_apply], [cap_ng])
1389 ])
1390
1391
1392 AC_ARG_ENABLE([setpriv],
1393   AS_HELP_STRING([--disable-setpriv], [do not build setpriv]),
1394   [], [UL_DEFAULT_ENABLE([setpriv], [check])]
1395 )
1396 UL_BUILD_INIT([setpriv])
1397 UL_REQUIRES_LINUX([setpriv])
1398 UL_REQUIRES_HAVE([setpriv], [linux_securebits_h], [securebits.h header file])
1399 UL_REQUIRES_HAVE([setpriv], [cap_ng], [libcap-ng library])
1400 AM_CONDITIONAL([BUILD_SETPRIV], [test "x$build_setpriv" = xyes])
1401
1402
1403 AC_ARG_ENABLE([eject],
1404   AS_HELP_STRING([--disable-eject], [do not build eject]),
1405   [], [UL_DEFAULT_ENABLE([eject], [check])]
1406 )
1407 UL_BUILD_INIT([eject])
1408 UL_REQUIRES_LINUX([eject])
1409 UL_REQUIRES_BUILD([eject], [libmount])
1410 AM_CONDITIONAL([BUILD_EJECT], [test "x$build_eject" = xyes])
1411
1412
1413 AC_ARG_ENABLE([agetty],
1414   AS_HELP_STRING([--disable-agetty], [do not build agetty]),
1415   [], [UL_DEFAULT_ENABLE([agetty], [check])]
1416 )
1417 UL_BUILD_INIT([agetty])
1418 UL_REQUIRES_HAVE([agetty], [utmpx_h], [utmpx.h header])
1419 UL_REQUIRES_HAVE([agetty], [gnu_utmpx], [GNU utmpx functions])
1420 AM_CONDITIONAL([BUILD_AGETTY], [test "x$build_agetty" = xyes])
1421 AS_IF([test "x$have_futimens" = xyes -a "x$have_inotify_init1" = xyes ], [
1422   AC_DEFINE([AGETTY_RELOAD], [1], [Enable agetty --reload feature])
1423 ],[
1424   AC_MSG_WARN([futimens or inotify_init1 not found; agetty(8) will not provide ---reload functionality])
1425 ])
1426
1427
1428 AC_ARG_ENABLE([plymouth_support],
1429   AS_HELP_STRING([--disable-plymouth_support], [don not care about plymouth in sylogin(8) and agetty(8)]),
1430   [], [enable_plymouth_support=check]
1431 )
1432 UL_BUILD_INIT([plymouth_support])
1433 UL_REQUIRES_HAVE([plymouth_support], [tiocglcktrmios], [TIOCGLCKTRMIOS flag])
1434 UL_REQUIRES_HAVE([plymouth_support], [sock_cloexec], [SOCK_CLOEXEC flag])
1435 UL_REQUIRES_HAVE([plymouth_support], [sock_nonblock], [SOCK_NONBLOCK flag])
1436 UL_REQUIRES_HAVE([plymouth_support], [so_passcred], [SO_PASSCRED flag])
1437 AM_CONDITIONAL([USE_PLYMOUTH_SUPPORT], [test "x$build_plymouth_support" = xyes])
1438 AS_IF([test "x$build_plymouth_support" = xyes ], [
1439     AC_DEFINE([USE_PLYMOUTH_SUPPORT], [1], [Enable plymouth support feature for sulogin and aggety])
1440 ])
1441
1442
1443 AC_ARG_WITH([libz],
1444   AS_HELP_STRING([--without-libz], [compile without libz]),
1445   [], [with_libz=auto]
1446 )
1447 AS_IF([test "x$with_libz" = xno], [have_z=no], [
1448   AC_CHECK_LIB([z], [crc32], [have_z=yes], [have_z=no])
1449 ])
1450
1451
1452 AC_ARG_ENABLE([cramfs],
1453   AS_HELP_STRING([--disable-cramfs], [do not build fsck.cramfs, mkfs.cramfs]),
1454   [], [UL_DEFAULT_ENABLE([cramfs], [check])]
1455 )
1456 UL_BUILD_INIT([cramfs])
1457 UL_REQUIRES_HAVE([cramfs], [z], [z library])
1458 AM_CONDITIONAL([BUILD_CRAMFS], [test "x$build_cramfs" = xyes])
1459
1460
1461 AC_ARG_ENABLE([bfs],
1462   AS_HELP_STRING([--disable-bfs], [do not build mkfs.bfs]),
1463   [], [UL_DEFAULT_ENABLE([bfs], [yes])]
1464 )
1465 UL_BUILD_INIT([bfs])
1466 AM_CONDITIONAL([BUILD_BFS], [test "x$build_bfs" = xyes])
1467
1468
1469 AC_ARG_ENABLE([minix],
1470   AS_HELP_STRING([--disable-minix], [do not build fsck.minix, mkfs.minix]),
1471   [], [UL_DEFAULT_ENABLE([minix], [yes])]
1472 )
1473 UL_BUILD_INIT([minix])
1474 AM_CONDITIONAL([BUILD_MINIX], [test "x$build_minix" = xyes])
1475
1476
1477 AC_ARG_ENABLE([fdformat],
1478   AS_HELP_STRING([--disable-fdformat], [do not build fdformat]),
1479   [], [UL_DEFAULT_ENABLE([fdformat], [check])]
1480 )
1481 UL_BUILD_INIT([fdformat])
1482 UL_REQUIRES_LINUX([fdformat])
1483 AM_CONDITIONAL([BUILD_FDFORMAT], [test "x$build_fdformat" = xyes])
1484
1485
1486 AC_ARG_ENABLE([hwclock],
1487   AS_HELP_STRING([--disable-hwclock], [do not build hwclock]),
1488   [], [UL_DEFAULT_ENABLE([hwclock], [check])]
1489 )
1490 have_linuxdummy=$linux_os
1491
1492 UL_BUILD_INIT([hwclock])
1493 UL_REQUIRES_HAVE([hwclock], [io, linuxdummy], [ioperm iopl function or Linux])
1494 AM_CONDITIONAL([BUILD_HWCLOCK], [test "x$build_hwclock" = xyes])
1495
1496
1497 UL_BUILD_INIT([mkfs], [yes])
1498 AM_CONDITIONAL([BUILD_MKFS], [test "x$build_mkfs" = xyes])
1499
1500 UL_BUILD_INIT([isosize], [yes])
1501 AM_CONDITIONAL([BUILD_ISOSIZE], [test "x$build_isosize" = xyes])
1502
1503
1504 UL_BUILD_INIT([fstrim], [check])
1505 UL_REQUIRES_LINUX([fstrim])
1506 UL_REQUIRES_BUILD([fstrim], [libmount])
1507 AM_CONDITIONAL([BUILD_FSTRIM], [test "x$build_fstrim" = xyes])
1508
1509
1510 UL_BUILD_INIT([swapon], [check])
1511 UL_REQUIRES_LINUX([swapon])
1512 UL_REQUIRES_SYSCALL_CHECK([swapon], [UL_CHECK_SYSCALL([swapon])], [swapon])
1513 UL_REQUIRES_SYSCALL_CHECK([swapon], [UL_CHECK_SYSCALL([swapoff])], [swapoff])
1514 UL_REQUIRES_BUILD([swapon], [libblkid])
1515 UL_REQUIRES_BUILD([swapon], [libmount])
1516 UL_REQUIRES_BUILD([swapon], [libsmartcols])
1517 AM_CONDITIONAL([BUILD_SWAPON], [test "x$build_swapon" = xyes])
1518 AC_CHECK_FUNCS([swapon])
1519 AC_CHECK_FUNCS([swapoff])
1520
1521
1522 UL_BUILD_INIT([lsblk], [check])
1523 UL_REQUIRES_LINUX([lsblk])
1524 UL_REQUIRES_BUILD([lsblk], [libblkid])
1525 UL_REQUIRES_BUILD([lsblk], [libmount])
1526 UL_REQUIRES_BUILD([lsblk], [libsmartcols])
1527 AM_CONDITIONAL([BUILD_LSBLK], [test "x$build_lsblk" = xyes])
1528
1529
1530 UL_BUILD_INIT([lscpu], [check])
1531 UL_REQUIRES_LINUX([lscpu])
1532 UL_REQUIRES_BUILD([lscpu], [libsmartcols])
1533 UL_REQUIRES_HAVE([lscpu], [cpu_set_t], [cpu_set_t type])
1534 AM_CONDITIONAL([BUILD_LSCPU], [test "x$build_lscpu" = xyes])
1535
1536
1537 AC_ARG_ENABLE([lslogins],
1538   AS_HELP_STRING([--disable-lslogins], [do not build lslogins]),
1539   [], [UL_DEFAULT_ENABLE([lslogins], [check])]
1540 )
1541 UL_BUILD_INIT([lslogins])
1542 UL_REQUIRES_BUILD([lslogins], [libsmartcols])
1543 UL_REQUIRES_HAVE([lslogins], [shadow_h], [shadow.h header])
1544 UL_REQUIRES_HAVE([lslogins], [utmpx_h], [utmpx.h header])
1545 UL_REQUIRES_HAVE([lslogins], [gnu_utmpx], [GNU utmpx functions])
1546 AM_CONDITIONAL([BUILD_LSLOGINS], [test "x$build_lslogins" = xyes])
1547
1548
1549 UL_BUILD_INIT([chcpu], [check])
1550 UL_REQUIRES_LINUX([chcpu])
1551 UL_REQUIRES_HAVE([chcpu], [cpu_set_t], [cpu_set_t type])
1552 AM_CONDITIONAL([BUILD_CHCPU], [test "x$build_chcpu" = xyes])
1553
1554
1555 AC_ARG_ENABLE([wdctl],
1556   AS_HELP_STRING([--disable-wdctl], [do not build wdctl]),
1557   [], [UL_DEFAULT_ENABLE([wdctl], [check])]
1558 )
1559 UL_BUILD_INIT([wdctl])
1560 UL_REQUIRES_LINUX([wdctl])
1561 UL_REQUIRES_BUILD([wdctl], [libsmartcols])
1562 UL_REQUIRES_HAVE([wdctl], [linux_watchdog_h], [linux/watchdog.h header file])
1563 AM_CONDITIONAL([BUILD_WDCTL], [test "x$build_wdctl" = xyes])
1564
1565
1566 UL_BUILD_INIT([swaplabel], [check])
1567 UL_REQUIRES_BUILD([swaplabel], [libblkid])
1568 AM_CONDITIONAL([BUILD_SWAPLABEL], [test "x$build_swaplabel" = xyes])
1569
1570
1571 UL_BUILD_INIT([mkswap], [yes])
1572 AM_CONDITIONAL([BUILD_MKSWAP], [test "x$build_mkswap" = xyes])
1573 AS_IF([test "x$build_mkswap" = xyes -a "x$build_libuuid" != xyes], [
1574   AC_MSG_WARN([uuid library is not found; mkswap(8) will not generate UUIDs])
1575 ])
1576
1577
1578 AC_ARG_ENABLE([cal],
1579   AS_HELP_STRING([--disable-cal], [do not build cal]),
1580   [], [UL_DEFAULT_ENABLE([cal], [check])]
1581 )
1582 UL_BUILD_INIT([cal])
1583 AM_CONDITIONAL([BUILD_CAL], [test "x$build_cal" = xyes])
1584
1585 AC_ARG_ENABLE([logger],
1586   AS_HELP_STRING([--disable-logger], [do not build logger]),
1587   [], [UL_DEFAULT_ENABLE([logger], [check])]
1588 )
1589 UL_BUILD_INIT([logger])
1590 AM_CONDITIONAL([BUILD_LOGGER], [test "x$build_logger" = xyes])
1591
1592 UL_BUILD_INIT([look], [yes])
1593 AM_CONDITIONAL([BUILD_LOOK], [test "x$build_look" = xyes])
1594
1595 UL_BUILD_INIT([mcookie], [yes])
1596 AM_CONDITIONAL([BUILD_MCOOKIE], [test "x$build_mcookie" = xyes])
1597
1598 UL_BUILD_INIT([namei], [yes])
1599 AM_CONDITIONAL([BUILD_NAMEI], [test "x$build_namei" = xyes])
1600
1601 matriplet="$($CC -print-multiarch 2>/dev/null || true)"
1602 if test "x$matriplet" != "x"; then
1603   AC_DEFINE_UNQUOTED([MULTIARCHTRIPLET], ["$matriplet"],
1604   ["Multi-arch triplet for whereis library search path"])
1605 fi
1606 UL_BUILD_INIT([whereis], [yes])
1607 AM_CONDITIONAL([BUILD_WHEREIS], [test "x$build_whereis" = xyes])
1608
1609 UL_BUILD_INIT([getopt], [yes])
1610 AM_CONDITIONAL([BUILD_GETOPT], [test "x$build_getopt" = xyes])
1611
1612
1613 UL_BUILD_INIT([blockdev], [check])
1614 UL_REQUIRES_LINUX([blockdev])
1615 AM_CONDITIONAL([BUILD_BLOCKDEV], [test "x$build_blockdev" = xyes])
1616
1617
1618 UL_BUILD_INIT([prlimit], [check])
1619 UL_REQUIRES_LINUX([prlimit])
1620 UL_REQUIRES_BUILD([prlimit], [libsmartcols])
1621 UL_REQUIRES_SYSCALL_CHECK([prlimit], [UL_CHECK_SYSCALL([prlimit64])], [prlimit64])
1622 AM_CONDITIONAL([BUILD_PRLIMIT], [test "x$build_prlimit" = xyes])
1623 AS_IF([test "x$build_prlimit" = xyes], [
1624   AC_CHECK_FUNCS([prlimit])
1625 ])
1626
1627
1628 UL_BUILD_INIT([lslocks], [check])
1629 UL_REQUIRES_LINUX([lslocks])
1630 UL_REQUIRES_BUILD([lslocks], [libmount])
1631 UL_REQUIRES_BUILD([lslocks], [libsmartcols])
1632 AM_CONDITIONAL([BUILD_LSLOCKS], [test "x$build_lslocks" = xyes])
1633
1634
1635 AC_ARG_ENABLE([switch_root],
1636   AS_HELP_STRING([--disable-switch_root], [do not build switch_root]),
1637   [], [UL_DEFAULT_ENABLE([switch_root], [check])]
1638 )
1639 UL_BUILD_INIT([switch_root])
1640 UL_REQUIRES_LINUX([switch_root])
1641 UL_REQUIRES_HAVE([switch_root], [openat], [openat function])
1642 UL_REQUIRES_HAVE([switch_root], [dirfd,ddfd], [dirfd or ddfd function])
1643 AM_CONDITIONAL([BUILD_SWITCH_ROOT], [test "x$build_switch_root" = xyes])
1644
1645
1646 AC_ARG_ENABLE([pivot_root],
1647   AS_HELP_STRING([--disable-pivot_root], [do not build pivot_root]),
1648   [], [UL_DEFAULT_ENABLE([pivot_root], [check])]
1649 )
1650 UL_BUILD_INIT([pivot_root])
1651 UL_REQUIRES_LINUX([pivot_root])
1652 UL_REQUIRES_SYSCALL_CHECK([pivot_root], [UL_CHECK_SYSCALL([pivot_root])])
1653 AM_CONDITIONAL([BUILD_PIVOT_ROOT], [test "x$build_pivot_root" = xyes])
1654
1655
1656 UL_BUILD_INIT([flock], [check])
1657 UL_REQUIRES_HAVE([flock], [timer], [timer_create function])
1658 AM_CONDITIONAL([BUILD_FLOCK], [test "x$build_flock" = xyes])
1659
1660
1661 AC_ARG_ENABLE([lsmem],
1662   AS_HELP_STRING([--disable-lsmem], [do not build lsmem]),
1663   [], [UL_DEFAULT_ENABLE([lsmem], [check])]
1664 )
1665 UL_BUILD_INIT([lsmem])
1666 UL_REQUIRES_LINUX([lsmem])
1667 UL_REQUIRES_BUILD([lsmem], [libsmartcols])
1668 AM_CONDITIONAL([BUILD_LSMEM], [test "x$build_lsmem" = xyes])
1669
1670
1671 AC_ARG_ENABLE([chmem],
1672   AS_HELP_STRING([--disable-chmem], [do not build chmem]),
1673   [], [UL_DEFAULT_ENABLE([chmem], [check])]
1674 )
1675 UL_BUILD_INIT([chmem])
1676 UL_REQUIRES_LINUX([chmem])
1677 AM_CONDITIONAL([BUILD_CHMEM], [test "x$build_chmem" = xyes])
1678
1679 UL_BUILD_INIT([ipcmk], [yes])
1680 AM_CONDITIONAL([BUILD_IPCMK], [test "x$build_ipcmk" = xyes])
1681
1682
1683 AC_ARG_ENABLE([ipcrm],
1684   AS_HELP_STRING([--disable-ipcrm], [do not build ipcrm]),
1685   [], [UL_DEFAULT_ENABLE([ipcrm], [yes])]
1686 )
1687 UL_BUILD_INIT([ipcrm])
1688 AM_CONDITIONAL([BUILD_IPCRM], [test "x$build_ipcrm" = xyes])
1689
1690 AC_ARG_ENABLE([ipcs],
1691   AS_HELP_STRING([--disable-ipcs], [do not build ipcs]),
1692   [], [UL_DEFAULT_ENABLE([ipcs], [yes])]
1693 )
1694 UL_BUILD_INIT([ipcs])
1695 AM_CONDITIONAL([BUILD_IPCS], [test "x$build_ipcs" = xyes])
1696
1697 UL_BUILD_INIT([choom], [check])
1698 UL_REQUIRES_LINUX([choom])
1699 AM_CONDITIONAL([BUILD_CHOOM], [test "x$build_choom" = xyes])
1700
1701 UL_BUILD_INIT([lsipc], [check])
1702 UL_REQUIRES_LINUX([lsipc])
1703 UL_REQUIRES_BUILD([lsipc], [libsmartcols])
1704 AM_CONDITIONAL([BUILD_LSIPC], [test "x$build_lsipc" = xyes])
1705
1706 UL_BUILD_INIT([lsns], [check])
1707 UL_REQUIRES_LINUX([lsns])
1708 UL_REQUIRES_BUILD([lsns], [libsmartcols])
1709 UL_REQUIRES_BUILD([lsns], [libmount])
1710 AM_CONDITIONAL([BUILD_LSNS], [test "x$build_lsns" = xyes])
1711
1712 UL_BUILD_INIT([renice], [yes])
1713 AM_CONDITIONAL([BUILD_RENICE], [test "x$build_renice" = xyes])
1714
1715
1716 AC_ARG_ENABLE([rfkill],
1717   AS_HELP_STRING([--disable-rfkill], [do not build rfkill]),
1718   [], [UL_DEFAULT_ENABLE([rfkill], [check])]
1719 )
1720 UL_BUILD_INIT([rfkill])
1721 UL_REQUIRES_LINUX([rfkill])
1722 UL_REQUIRES_BUILD([rfkill], [libsmartcols])
1723 AM_CONDITIONAL([BUILD_RFKILL], [test "x$build_rfkill" = xyes])
1724
1725
1726 UL_BUILD_INIT([setsid], [yes])
1727 AM_CONDITIONAL([BUILD_SETSID], [test "x$build_setsid" = xyes])
1728
1729 UL_BUILD_INIT([readprofile], [check])
1730 UL_REQUIRES_LINUX([readprofile])
1731 AM_CONDITIONAL([BUILD_READPROFILE], [test "x$build_readprofile" = xyes])
1732
1733 UL_BUILD_INIT([dmesg], [check])
1734 UL_REQUIRES_LINUX([dmesg])
1735 AM_CONDITIONAL([BUILD_DMESG], [test "x$build_dmesg" = xyes])
1736
1737 UL_BUILD_INIT([ctrlaltdel], [check])
1738 UL_REQUIRES_LINUX([ctrlaltdel])
1739 dnl we assume reboot() to be the 1-argument variant, because even considering
1740 dnl widely used alternative C libraries like uclibc, dietlibc and musl,
1741 dnl reboot() with multiple arguments is yet only found in glibc versions
1742 dnl earlier than 2.x.
1743 UL_REQUIRES_HAVE([ctrlaltdel], [reboot], [reboot function])
1744 AM_CONDITIONAL([BUILD_CTRLALTDEL], [test "x$build_ctrlaltdel" = xyes])
1745
1746 UL_BUILD_INIT([fincore], [check])
1747 UL_REQUIRES_LINUX([fincore])
1748 UL_REQUIRES_BUILD([fincore], [libsmartcols])
1749 AM_CONDITIONAL([BUILD_FINCORE], [test "x$build_fincore" = xyes])
1750
1751 UL_BUILD_INIT([fsfreeze], [check])
1752 UL_REQUIRES_LINUX([fsfreeze])
1753 AM_CONDITIONAL([BUILD_FSFREEZE], [test "x$build_fsfreeze" = xyes])
1754
1755 UL_BUILD_INIT([blkdiscard], [check])
1756 UL_REQUIRES_LINUX([blkdiscard])
1757 AM_CONDITIONAL([BUILD_BLKDISCARD], [test "x$build_blkdiscard" = xyes])
1758
1759 UL_BUILD_INIT([blkzone], [check])
1760 UL_REQUIRES_LINUX([blkzone])
1761 UL_REQUIRES_HAVE([blkzone], [linux_blkzoned_h], [linux/blkzoned.h header])
1762 AM_CONDITIONAL([BUILD_BLKZONE], [test "x$build_blkzone" = xyes])
1763
1764 UL_BUILD_INIT([ldattach], [check])
1765 UL_REQUIRES_LINUX([ldattach])
1766 AM_CONDITIONAL([BUILD_LDATTACH], [test "x$build_ldattach" = xyes])
1767
1768 UL_BUILD_INIT([rtcwake], [check])
1769 UL_REQUIRES_LINUX([rtcwake])
1770 AM_CONDITIONAL([BUILD_RTCWAKE], [test "x$build_rtcwake" = xyes])
1771
1772 UL_BUILD_INIT([setarch], [check])
1773 UL_REQUIRES_LINUX([setarch])
1774 AM_CONDITIONAL([BUILD_SETARCH], [test "x$build_setarch" = xyes])
1775
1776 UL_BUILD_INIT([script], [check])
1777 UL_REQUIRES_HAVE([script], [sys_signalfd_h], [sys/signalfd.h header])
1778 AM_CONDITIONAL([BUILD_SCRIPT], [test "x$build_script" = xyes])
1779
1780 UL_BUILD_INIT([scriptreplay], [yes])
1781 AM_CONDITIONAL([BUILD_SCRIPTREPLAY], [test "x$build_scriptreplay" = xyes])
1782
1783 UL_BUILD_INIT([col], [yes])
1784 AM_CONDITIONAL([BUILD_COL], [test "x$build_col" = xyes])
1785
1786 UL_BUILD_INIT([colcrt], [yes])
1787 AM_CONDITIONAL([BUILD_COLCRT], [test "x$build_colcrt" = xyes])
1788
1789 UL_BUILD_INIT([colrm], [yes])
1790 AM_CONDITIONAL([BUILD_COLRM], [test "x$build_colrm" = xyes])
1791
1792 UL_BUILD_INIT([column], [check])
1793 UL_REQUIRES_BUILD([column], [libsmartcols])
1794 AM_CONDITIONAL([BUILD_COLUMN], [test "x$build_column" = xyes])
1795
1796 UL_BUILD_INIT([hexdump], [yes])
1797 AM_CONDITIONAL([BUILD_HEXDUMP], [test "x$build_hexdump" = xyes])
1798
1799 UL_BUILD_INIT([rev], [yes])
1800 AM_CONDITIONAL([BUILD_REV], [test "x$build_rev" = xyes])
1801
1802
1803 AC_ARG_ENABLE([tunelp],
1804   AS_HELP_STRING([--enable-tunelp], [build tunelp]),
1805   [], [UL_DEFAULT_ENABLE([tunelp], [no])]
1806 )
1807 UL_BUILD_INIT([tunelp])
1808 UL_REQUIRES_LINUX([tunelp])
1809 AM_CONDITIONAL([BUILD_TUNELP], [test "x$build_tunelp" = xyes])
1810
1811
1812 AC_ARG_ENABLE([kill],
1813   AS_HELP_STRING([--disable-kill], [do not build kill]),
1814   [], [UL_DEFAULT_ENABLE([kill], [check])]
1815 )
1816 UL_BUILD_INIT([kill])
1817 UL_REQUIRES_LINUX([kill])
1818 AM_CONDITIONAL([BUILD_KILL], [test "x$build_kill" = xyes])
1819
1820
1821 AC_ARG_ENABLE([last],
1822   AS_HELP_STRING([--disable-last], [do not build last]),
1823   [], [UL_DEFAULT_ENABLE([last], [check])]
1824 )
1825 UL_BUILD_INIT([last])
1826 UL_REQUIRES_HAVE([last], [utmpx_h], [utmpx.h header])
1827 UL_REQUIRES_HAVE([last], [gnu_utmpx], [GNU utmpx functions])
1828 AM_CONDITIONAL([BUILD_LAST], [test "x$build_last" = xyes])
1829
1830
1831 AC_ARG_ENABLE([utmpdump],
1832   AS_HELP_STRING([--disable-utmpdump], [do not build utmpdump]),
1833   [], [UL_DEFAULT_ENABLE([utmpdump], [check])]
1834 )
1835 UL_BUILD_INIT([utmpdump])
1836 UL_REQUIRES_HAVE([utmpdump], [utmpx_h], [utmpx.h header])
1837 UL_REQUIRES_HAVE([utmpdump], [gnu_utmpx], [GNU utmpx functions])
1838 AM_CONDITIONAL([BUILD_UTMPDUMP], [test "x$build_utmpdump" = xyes])
1839
1840
1841 AC_ARG_ENABLE([line],
1842   AS_HELP_STRING([--enable-line], [build line]),
1843   [], [UL_DEFAULT_ENABLE([line], [no])]
1844 )
1845 UL_BUILD_INIT([line])
1846 AM_CONDITIONAL([BUILD_LINE], [test "x$build_line" = xyes])
1847
1848
1849 AC_ARG_ENABLE([mesg],
1850   AS_HELP_STRING([--disable-mesg], [do not build mesg]),
1851   [], [UL_DEFAULT_ENABLE([mesg], [yes])]
1852 )
1853 UL_BUILD_INIT([mesg])
1854 AM_CONDITIONAL([BUILD_MESG], [test "x$build_mesg" = xyes])
1855
1856
1857 AC_ARG_ENABLE([raw],
1858   AS_HELP_STRING([--disable-raw], [do not build raw]),
1859   [], [UL_DEFAULT_ENABLE([raw], [check])]
1860 )
1861 UL_BUILD_INIT([raw])
1862 UL_REQUIRES_LINUX([raw])
1863 UL_REQUIRES_HAVE([raw], [linux_raw_h], [raw.h header file])
1864 AM_CONDITIONAL([BUILD_RAW], [test "x$build_raw" = xyes])
1865
1866
1867 AC_ARG_ENABLE([rename],
1868   AS_HELP_STRING([--disable-rename], [do not build rename]),
1869   [], [UL_DEFAULT_ENABLE([rename], [yes])]
1870 )
1871 UL_BUILD_INIT([rename])
1872 AM_CONDITIONAL([BUILD_RENAME], [test "x$build_rename" = xyes])
1873
1874
1875 AC_ARG_ENABLE([vipw],
1876   AS_HELP_STRING([--enable-vipw], [build vipw]),
1877   [], [UL_DEFAULT_ENABLE([vipw], [no])]
1878 )
1879 UL_BUILD_INIT([vipw])
1880 UL_REQUIRES_HAVE([vipw], [shadow_h], [shadow.h header])
1881 AM_CONDITIONAL([BUILD_VIPW], [test "x$build_vipw" = xyes])
1882
1883
1884 AC_ARG_ENABLE([newgrp],
1885   AS_HELP_STRING([--enable-newgrp], [build newgrp]),
1886   [], [UL_DEFAULT_ENABLE([newgrp], [no])]
1887 )
1888 UL_BUILD_INIT([newgrp])
1889 UL_REQUIRES_HAVE([newgrp], [crypt], [crypt function])
1890 AM_CONDITIONAL([BUILD_NEWGRP], [test "x$build_newgrp" = xyes])
1891
1892
1893 AC_ARG_WITH([user], AS_HELP_STRING([--without-user], [compile without libuser (remote chsh)]),
1894   [], [with_user=check]
1895 )
1896 have_user=no
1897 AS_IF([test "x$with_user" != xno], [
1898   PKG_CHECK_MODULES(LIBUSER,[libuser >= 0.58], [have_user=yes], [have_user=no])
1899   AS_CASE([$with_user:$have_user],
1900     [yes:no],
1901       [AC_MSG_ERROR([user selected but libuser not found])],
1902     [*:yes],
1903       [AC_DEFINE([HAVE_LIBUSER], [1], [Define if libuser is available])]
1904   )
1905   # temporary solution, libuser has stupid .pc where are exported all
1906   # private dependencies to Requires: instead of Requires.private:
1907   AS_IF([test "x$have_user" = xyes], [
1908     LIBUSER_LIBS=-luser
1909   ])
1910 ])
1911 AM_CONDITIONAL([HAVE_USER], [test "x$have_user" = xyes])
1912
1913 AC_ARG_ENABLE([chfn-chsh-password],
1914   AS_HELP_STRING([--disable-chfn-chsh-password], [do not require the user to enter the password in chfn and chsh]),
1915   [], [enable_chfn_chsh_password=yes]
1916 )
1917
1918 AC_ARG_ENABLE([chfn-chsh],
1919   AS_HELP_STRING([--enable-chfn-chsh], [build chfn and chsh]),
1920   [], [UL_DEFAULT_ENABLE([chfn_chsh], [check])]
1921 )
1922 UL_BUILD_INIT([chfn_chsh])
1923 UL_REQUIRES_HAVE([chfn_chsh], [shadow_h], [shadow.h header])
1924 UL_REQUIRES_HAVE([chfn_chsh], [getusershell], [getusershell function])
1925
1926 AS_IF([test "x$enable_chfn_chsh_password" = xyes -o "x$have_user" = xyes], [
1927   UL_REQUIRES_HAVE([chfn_chsh], [security_pam_appl_h], [PAM header file])
1928   AC_DEFINE([CHFN_CHSH_PASSWORD], [1], [Should chfn and chsh require the user to enter the password?])
1929 ])
1930 AM_CONDITIONAL([BUILD_CHFN_CHSH], [test "x$build_chfn_chsh" = xyes])
1931 AM_CONDITIONAL([CHFN_CHSH_PASSWORD], [test "x$enable_chfn_chsh_password" = xyes])
1932
1933 AC_ARG_ENABLE([chsh-only-listed],
1934   AS_HELP_STRING([--disable-chsh-only-listed], [chsh: allow shells not in /etc/shells]),
1935   [], enable_chsh_only_listed=yes
1936 )
1937
1938 AS_IF([test "x$enable_chsh_only_listed" = xyes], [
1939   AC_DEFINE([ONLY_LISTED_SHELLS], [1], [Should chsh allow only shells in /etc/shells?])
1940 ])
1941
1942
1943 AC_ARG_ENABLE([login],
1944   AS_HELP_STRING([--disable-login], [do not build login]),
1945   [], [UL_DEFAULT_ENABLE([login], [check])]
1946 )
1947 UL_BUILD_INIT([login])
1948 UL_REQUIRES_HAVE([login], [security_pam_appl_h], [PAM header file])
1949 UL_REQUIRES_HAVE([login], [security_pam_misc_h, security_openpam_h], [PAM conversation functions])
1950 UL_REQUIRES_HAVE([login], [utmpx_h], [utmpx.h header])
1951 UL_REQUIRES_HAVE([login], [gnu_utmpx], [GNU utmpx functions])
1952 AM_CONDITIONAL([BUILD_LOGIN], [test "x$build_login" = xyes])
1953
1954 AC_ARG_ENABLE([login-chown-vcs],
1955   AS_HELP_STRING([--enable-login-chown-vcs], [let login chown /dev/vcsN]),
1956   [], [enable_login_chown_vcs=no]
1957 )
1958
1959 AS_IF([test "x$enable_login_chown_vcs" = xyes], [
1960   AC_DEFINE([LOGIN_CHOWN_VCS], [1], [Should login chown /dev/vcsN?])
1961 ])
1962
1963 AC_ARG_ENABLE([login-stat-mail],
1964   AS_HELP_STRING([--enable-login-stat-mail], [let login stat() the mailbox]),
1965   [], [enable_login_stat_mail=no]
1966 )
1967
1968 AS_IF([test "x$enable_login_stat_mail" = xyes], [
1969   AC_DEFINE([LOGIN_STAT_MAIL], [1], [Should login stat() the mailbox?])
1970 ])
1971
1972
1973 AC_ARG_ENABLE([nologin],
1974   AS_HELP_STRING([--disable-nologin], [do not build nologin]),
1975   [], [UL_DEFAULT_ENABLE([nologin], [yes])]
1976 )
1977 UL_BUILD_INIT([nologin])
1978 AM_CONDITIONAL([BUILD_NOLOGIN], [test "x$build_nologin" = xyes])
1979
1980
1981 AC_ARG_ENABLE([sulogin],
1982   AS_HELP_STRING([--disable-sulogin], [do not build sulogin]),
1983   [], [UL_DEFAULT_ENABLE([sulogin], [check])]
1984 )
1985 UL_BUILD_INIT([sulogin])
1986 UL_REQUIRES_HAVE([sulogin], [crypt], [crypt function])
1987 UL_REQUIRES_HAVE([sulogin], [shadow_h], [shadow.h header])
1988 AM_CONDITIONAL([BUILD_SULOGIN], [test "x$build_sulogin" = xyes])
1989
1990
1991 AC_ARG_ENABLE([su],
1992   AS_HELP_STRING([--disable-su], [do not build su]),
1993   [], [UL_DEFAULT_ENABLE([su], [check])]
1994 )
1995 UL_BUILD_INIT([su])
1996 UL_REQUIRES_HAVE([su], [security_pam_appl_h], [PAM header file])
1997 UL_REQUIRES_HAVE([su], [utmpx_h], [utmpx.h header])
1998 UL_REQUIRES_HAVE([su], [gnu_utmpx], [GNU utmpx functions])
1999 AM_CONDITIONAL([BUILD_SU], [test "x$build_su" = xyes])
2000
2001
2002 AC_ARG_ENABLE([runuser],
2003   AS_HELP_STRING([--disable-runuser], [do not build runuser]),
2004   [], [UL_DEFAULT_ENABLE([runuser], [check])]
2005 )
2006 UL_BUILD_INIT([runuser])
2007 UL_REQUIRES_HAVE([runuser], [security_pam_appl_h], [PAM header file])
2008 UL_REQUIRES_HAVE([runuser], [utmpx_h], [utmpx.h header])
2009 UL_REQUIRES_HAVE([runuser], [gnu_utmpx], [GNU utmpx functions])
2010 AM_CONDITIONAL([BUILD_RUNUSER], [test "x$build_runuser" = xyes])
2011
2012
2013 AC_ARG_ENABLE([ul],
2014   AS_HELP_STRING([--disable-ul], [do not build ul]),
2015   [], [UL_DEFAULT_ENABLE([ul], [check])]
2016 )
2017 UL_BUILD_INIT([ul])
2018 UL_REQUIRES_HAVE([ul], [ncursesw, ncurses], [ncursesw or ncurses libraries])
2019 AM_CONDITIONAL([BUILD_UL], [test "x$build_ul" = xyes])
2020
2021
2022 AC_ARG_ENABLE([more],
2023   AS_HELP_STRING([--disable-more], [do not build more]),
2024   [], [UL_DEFAULT_ENABLE([more], [check])]
2025 )
2026 UL_BUILD_INIT([more])
2027 UL_REQUIRES_HAVE([more], [ncursesw, ncurses], [ncursesw or ncurses libraries])
2028 AM_CONDITIONAL([BUILD_MORE], [test "x$build_more" = xyes])
2029
2030
2031 AC_ARG_ENABLE([pg],
2032   AS_HELP_STRING([--enable-pg], [build pg]),
2033   [], [UL_DEFAULT_ENABLE([pg], [no])]
2034 )
2035 UL_BUILD_INIT([pg])
2036 UL_REQUIRES_HAVE([pg], [ncursesw, ncurses], [ncursesw or ncurses library])
2037 AM_CONDITIONAL([BUILD_PG], [test "x$build_pg" = xyes])
2038
2039
2040 AC_ARG_ENABLE([setterm],
2041   AS_HELP_STRING([--disable-setterm], [do not build setterm]),
2042   [], [UL_DEFAULT_ENABLE([setterm], [check])]
2043 )
2044 UL_BUILD_INIT([setterm])
2045 UL_REQUIRES_LINUX([setterm])
2046 UL_REQUIRES_HAVE([setterm], [ncursesw, ncurses], [ncursesw or ncurses library])
2047 AM_CONDITIONAL([BUILD_SETTERM], [test "x$build_setterm" = xyes])
2048
2049 # build_schedutils= is just configure-only variable to control
2050 # ionice, taskset and chrt
2051 AC_ARG_ENABLE([schedutils],
2052   AS_HELP_STRING([--disable-schedutils], [do not build chrt, ionice, taskset]),
2053   [], [UL_DEFAULT_ENABLE([schedutils], [check])]
2054 )
2055
2056
2057 UL_ENABLE_ALIAS([ionice], [schedutils])
2058 UL_BUILD_INIT([ionice])
2059 UL_REQUIRES_SYSCALL_CHECK([ionice],
2060         [UL_CHECK_SYSCALL([ioprio_set],
2061           [alpha],      [442],
2062           [i*86],       [289],
2063           [ia64*],      [1274],
2064           [powerpc*],   [273],
2065           [s390*],      [282],
2066           [sparc*],     [196],
2067           [sh*],        [288],
2068           [x86_64*],    [251])],
2069         [ioprio_set])
2070
2071 UL_REQUIRES_SYSCALL_CHECK([ionice],
2072         [UL_CHECK_SYSCALL([ioprio_get],
2073           [alpha],      [443],
2074           [i*86],       [290],
2075           [ia64*],      [1275],
2076           [powerpc*],   [274],
2077           [s390*],      [283],
2078           [sparc*],     [218],
2079           [sh*],        [289],
2080           [x86_64*],    [252])],
2081         [ioprio_get])
2082
2083 AM_CONDITIONAL([BUILD_IONICE], [test "x$build_ionice" = xyes])
2084
2085
2086 UL_ENABLE_ALIAS([taskset], [schedutils])
2087 UL_BUILD_INIT([taskset])
2088 UL_REQUIRES_HAVE([taskset], [cpu_set_t], [cpu_set_t type])
2089 UL_REQUIRES_SYSCALL_CHECK([taskset],
2090         [UL_CHECK_SYSCALL([sched_getaffinity])],
2091         [sched_getaffinity])
2092 AM_CONDITIONAL([BUILD_TASKSET], [test "x$build_taskset" = xyes])
2093
2094
2095 have_schedsetter=no
2096 AS_IF([test "x$ac_cv_func_sched_setscheduler" = xyes], [have_schedsetter=yes],
2097       [test "x$ac_cv_func_sched_setattr" = xyes], [have_schedsetter=yes])
2098
2099 UL_ENABLE_ALIAS([chrt], [schedutils])
2100 UL_BUILD_INIT([chrt])
2101 UL_REQUIRES_HAVE([chrt], [schedsetter], [sched_set functions])
2102 AM_CONDITIONAL([BUILD_CHRT], [test "x$build_chrt" = xyes])
2103
2104 AS_IF([test "x$build_chrt" = xyes], [
2105         UL_CHECK_SYSCALL([sched_setattr])
2106 ])
2107
2108
2109 AC_ARG_ENABLE([wall],
2110   AS_HELP_STRING([--disable-wall], [do not build wall]),
2111   [], [UL_DEFAULT_ENABLE([wall], [check])]
2112 )
2113 UL_BUILD_INIT([wall])
2114 UL_REQUIRES_HAVE([wall], [utmpx_h], [utmpx.h header])
2115 AM_CONDITIONAL([BUILD_WALL], [test "x$build_wall" = xyes])
2116
2117
2118 AC_ARG_ENABLE([write],
2119   AS_HELP_STRING([--enable-write], [build write]),
2120   [], [UL_DEFAULT_ENABLE([write], [no])]
2121 )
2122 UL_BUILD_INIT([write])
2123 UL_REQUIRES_HAVE([write], [utmpx_h], [utmpx.h header])
2124 UL_REQUIRES_HAVE([write], [gnu_utmpx], [GNU utmpx functions])
2125 AM_CONDITIONAL([BUILD_WRITE], [test "x$build_write" = xyes])
2126
2127
2128 AC_ARG_WITH([btrfs],
2129   AS_HELP_STRING([--without-btrfs], [do not build with btrfs support]),
2130   [], [with_btrfs=check]
2131 )
2132 have_btrfs=no
2133 AS_IF([test "x$with_btrfs" != xno], [
2134   AS_CASE([$with_btrfs:$have_linux_btrfs_h],
2135     [yes:no],
2136     [AC_MSG_ERROR([btrfs selected but linux/btrfs.h not found])],
2137     [check:no],
2138        [AC_MSG_WARN([linux/btrfs.h not found, do not build with btrfs support])],
2139     [*:yes],
2140        [have_btrfs=yes
2141         AC_DEFINE([HAVE_BTRFS_SUPPORT], [1], [Define if btrfs stuff is available])]
2142   )
2143 ])
2144 AM_CONDITIONAL([HAVE_BTRFS], [test "x$have_btrfs" = xyes])
2145
2146
2147 AC_ARG_WITH([systemd],
2148   AS_HELP_STRING([--without-systemd], [do not build with systemd support]),
2149   [], [with_systemd=check]
2150 )
2151
2152 have_systemd=no
2153 AS_IF([test "x$with_systemd" != xno], [
2154   # new version -- all libsystemd-* libs merged into libsystemd
2155   PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [have_systemd=yes], [have_systemd=no])
2156   # old versions
2157   AS_IF([test "x$have_systemd" != "xyes"], [
2158     PKG_CHECK_MODULES([SYSTEMD_DAEMON], [libsystemd-daemon],
2159                       [have_systemd_daemon=yes], [have_systemd_daemon=no])
2160     PKG_CHECK_MODULES([SYSTEMD_JOURNAL], [libsystemd-journal],
2161                       [have_systemd_journal=yes], [have_systemd_journal=no])
2162     AS_IF([test "x$have_systemd_daemon" = "xyes" -a "x$have_systemd_journal" = "xyes" ],[
2163            have_systemd=yes])
2164   ])
2165   AS_CASE([$with_systemd:$have_systemd],
2166     [yes:no],
2167       [AC_MSG_ERROR([systemd expected but libsystemd not found])],
2168     [*:yes],
2169        AC_DEFINE([HAVE_LIBSYSTEMD], [1], [Define if libsystemd is available])
2170   )
2171 ])
2172 AM_CONDITIONAL([HAVE_SYSTEMD], [test "x$have_systemd" = xyes])
2173
2174
2175 AC_ARG_WITH([systemdsystemunitdir],
2176   AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [directory for systemd unit files (requires systemd support)]),
2177   [], [with_systemdsystemunitdir=check]
2178 )
2179 AS_IF([test "x$with_systemdsystemunitdir" = xcheck], [
2180   AS_IF([test "x$have_systemd" = xyes], [
2181     with_systemdsystemunitdir=`$PKG_CONFIG --variable=systemdsystemunitdir systemd`
2182   ],[
2183     with_systemdsystemunitdir=no
2184   ])
2185 ])
2186 AS_IF([test "x$with_systemdsystemunitdir" != "xno"], [
2187   AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
2188 ])
2189
2190
2191 AC_ARG_WITH([smack],
2192   AS_HELP_STRING([--with-smack], [build with SMACK support]),
2193   [], [with_smack=no]
2194 )
2195 AS_IF([test "x$with_smack" = xyes], [
2196   AC_DEFINE([HAVE_SMACK], [1], [Add SMACK support])
2197 ])
2198
2199
2200 AC_ARG_WITH([bashcompletiondir],
2201   AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
2202   [],
2203   [AS_IF([`$PKG_CONFIG --exists bash-completion`], [
2204     with_bashcompletiondir=`$PKG_CONFIG --variable=completionsdir bash-completion`
2205   ], [
2206     with_bashcompletiondir=${datadir}/bash-completion/completions
2207   ])
2208 ])
2209 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
2210
2211 AC_ARG_ENABLE([bash-completion],
2212   AS_HELP_STRING([--disable-bash-completion], [do not install bash completion files]),
2213   [], [enable_bash_completion=yes]
2214 )
2215
2216 AM_CONDITIONAL([BUILD_BASH_COMPLETION], [test "x$enable_bash_completion" = xyes])
2217
2218
2219 AC_ARG_WITH([python],
2220   AS_HELP_STRING([--without-python], [do not build python bindings, use --with-python={2,3} to force version]),
2221   [], [with_python=check withval=check]
2222 )
2223
2224 have_python=no
2225 have_libpython=no
2226 AS_IF([test "x$with_python" != xno], [
2227   # We follow distributions default and look for PKG module name "python"
2228   # (minimal version is 2) but if major version is explicitly specified by
2229   # --with-python=2 or --with-python=3 then we look for PKG module "python2" or
2230   # "python3".
2231   AS_IF([test "x$withval" != xno -a "x$withval" != xyes -a "x$withval" != xcheck],
2232         [pymajor="$withval"; PYTHON=python${pymajor}], [pymajor="2"])
2233
2234   # check for python interpreter
2235   AM_PATH_PYTHON([$pymajor], [have_python=yes], [have_python=no])
2236   AS_CASE([$with_python:$have_python],
2237     [yes:no],
2238       [AC_MSG_ERROR([python selected but python interpreter not found])],
2239     [check:no],
2240        [AC_MSG_WARN([python interpreter not found, do not build python bindings])],
2241     [*:yes],
2242        # check for python development stuff
2243        [PKG_CHECK_MODULES([PYTHON], [python-$PYTHON_VERSION],
2244                           [have_libpython=yes], [have_libpython=no])]
2245   )
2246 ])
2247
2248
2249 AC_ARG_ENABLE([pylibmount],
2250   AS_HELP_STRING([--disable-pylibmount], [do not build pylibmount]),
2251   [], [UL_DEFAULT_ENABLE([pylibmount], [check])]
2252 )
2253 UL_BUILD_INIT([pylibmount])
2254 UL_REQUIRES_HAVE([pylibmount], [libpython], [libpython])
2255 UL_REQUIRES_BUILD([pylibmount], [libmount])
2256 AM_CONDITIONAL([BUILD_PYLIBMOUNT], [test "x$build_pylibmount" = "xyes"])
2257
2258 # We need to introduce a verbatim dependency into the Makefile, without automake
2259 # trying to interpret it, so push it as a AM_SUBST_NOTMAKE variable.
2260 verbatim_pylibmount_dependency='
2261
2262 # pylibmountexec module must be installed after usrlib_exec libraries,
2263 # otherwise the libtool relink step will fail to find libmount.la and
2264 # will try -lmount which is possibly not available.
2265 install-pylibmountexecLTLIBRARIES: install-usrlib_execLTLIBRARIES
2266
2267 '
2268 AC_SUBST([verbatim_pylibmount_dependency])
2269 AM_SUBST_NOTMAKE([verbatim_pylibmount_dependency])
2270
2271 AC_ARG_ENABLE([pg-bell],
2272   AS_HELP_STRING([--disable-pg-bell], [let pg not ring the bell on invalid keys]),
2273   [], [enable_pg_bell=yes]
2274 )
2275
2276 AS_IF([test "x$enable_pg_bell" = xyes], [
2277   AC_DEFINE([PG_BELL], [1], [Should pg ring the bell on invalid keys?])
2278 ])
2279
2280
2281 AC_DEFUN([FS_PATHS_DEFAULT], [/sbin:/sbin/fs.d:/sbin/fs])
2282 AC_ARG_ENABLE([fs-paths-default],
2283   AS_HELP_STRING([--enable-fs-paths-default=paths], [default search path for fs helpers @<:@FS_PATHS_DEFAULT@:>@]),
2284   [AS_CASE([$enableval],
2285     [yes], [fs_paths_defaults="FS_PATHS_DEFAULT"],
2286     [no],  [fs_paths_defaults=""],
2287     [fs_paths_defaults="$enableval"]
2288   )],
2289   [fs_paths_defaults="FS_PATHS_DEFAULT"]
2290 )
2291 AC_ARG_ENABLE([fs-paths-extra],
2292   AS_HELP_STRING([--enable-fs-paths-extra=paths], [additional search paths for fs helpers]),
2293   [AS_CASE([$enableval],
2294      [yes|no], [fs_paths_extra=""],
2295      [fs_paths_extra="$enableval"]
2296   )],
2297   [fs_paths_extra=""]
2298 )
2299 fs_paths="$fs_paths_defaults"
2300 AS_IF([test "x$fs_paths_extra" != "x"], [
2301   AS_IF([test "x$fs_paths" != "x"], [
2302     fs_paths="${fs_paths}:"
2303   ])
2304   fs_paths="${fs_paths}${fs_paths_extra}"
2305 ])
2306 AC_DEFINE_UNQUOTED([FS_SEARCH_PATH], "$fs_paths", [search path for fs helpers])
2307
2308
2309 AC_ARG_ENABLE([use-tty-group],
2310   AS_HELP_STRING([--disable-use-tty-group], [do not install wall and write setgid tty]),
2311   [], [enable_use_tty_group=yes]
2312 )
2313 AM_CONDITIONAL([USE_TTY_GROUP], [test "x$enable_use_tty_group" = xyes])
2314
2315 AS_IF([test "x$enable_use_tty_group" = xyes], [
2316   AC_DEFINE([USE_TTY_GROUP], [1], [Should wall and write be installed setgid tty?])
2317 ])
2318
2319
2320 AC_ARG_ENABLE([sulogin-emergency-mount],
2321   AS_HELP_STRING([--enable-sulogin-emergency-mount],
2322                  [use emergency mount of /dev and /proc for sulogin]),
2323   [], [enable_sulogin_emergency_mount=no]
2324 )
2325
2326 AS_IF([test "x$enable_sulogin_emergency_mount" = xyes], [
2327   AC_DEFINE([USE_SULOGIN_EMERGENCY_MOUNT], [1],
2328             [Should sulogin use a emergency mount of /dev and /proc?])
2329 ])
2330
2331
2332 AC_ARG_ENABLE([usrdir-path],
2333   AS_HELP_STRING([--enable-usrdir-path], [use only /usr paths in PATH env. variable (recommended on systems with /bin -> /usr/bin symlinks)]),
2334   [], [enable_usrdir_path=no]
2335 )
2336
2337 AS_IF([test "x$enable_usrdir_path" = xyes], [
2338   AC_DEFINE([USE_USRDIR_PATHS_ONLY], [1], [Define to 1 to remove /bin and /sbin from PATH env.variable])
2339 ])
2340
2341
2342 AC_ARG_ENABLE([makeinstall-chown],
2343   AS_HELP_STRING([--disable-makeinstall-chown], [do not do chown-like operations during "make install"]),
2344   [], [enable_makeinstall_chown=yes]
2345 )
2346 AM_CONDITIONAL([MAKEINSTALL_DO_CHOWN], [test "x$enable_makeinstall_chown" = xyes])
2347
2348
2349 AC_ARG_ENABLE([makeinstall-setuid],
2350   AS_HELP_STRING([--disable-makeinstall-setuid], [do not do setuid chmod operations during "make install"]),
2351   [], [enable_makeinstall_setuid=yes]
2352 )
2353 AM_CONDITIONAL([MAKEINSTALL_DO_SETUID], [test "x$enable_makeinstall_setuid" = xyes])
2354
2355
2356 AC_ARG_ENABLE([colors-default],
2357   AS_HELP_STRING([--disable-colors-default], [do not colorize output from utils by default]),
2358   [], [enable_colors_default=yes]
2359 )
2360 AS_IF([test "x$enable_colors_default" = xyes], [
2361   AC_DEFINE([USE_COLORS_BY_DEFAULT], [1], [Enables colorized output from utils by default])
2362 ])
2363
2364
2365 AC_ARG_VAR([SUID_CFLAGS],
2366            [CFLAGS used for binaries which are usually with the suid bit])
2367 AC_ARG_VAR([SUID_LDFLAGS],
2368            [LDFLAGS used for binaries which are usually with the suid bit])
2369
2370 AC_ARG_VAR([DAEMON_CFLAGS],
2371            [CFLAGS used for binaries which are usually executed as daemons])
2372 AC_ARG_VAR([DAEMON_LDFLAGS],
2373            [LDFLAGS used for binaries which are usually executed as daemons])
2374
2375 AC_ARG_VAR([SOLIB_CFLAGS],
2376            [CFLAGS used for shared libraries])
2377 AC_ARG_VAR([SOLIB_LDFLAGS],
2378            [LDFLAGS used for shared libraries])
2379
2380 AC_ARG_VAR([ADJTIME_PATH],
2381            [Path to hwclock adjtime file, default /etc/adjtime])
2382 AS_IF([test "x$ADJTIME_PATH" = x], [ADJTIME_PATH="/etc/adjtime"])
2383 AC_DEFINE_UNQUOTED([CONFIG_ADJTIME_PATH], "$ADJTIME_PATH", [Path to hwclock adjtime file])
2384
2385
2386 LIBS=""
2387
2388
2389 AC_CONFIG_HEADERS([config.h])
2390
2391 #
2392 # Don't use configure.ac to replace install paths! See Makefile PATHFILES for
2393 # more details.
2394 #
2395 AC_CONFIG_FILES([
2396 Makefile
2397 libblkid/docs/Makefile
2398 libblkid/docs/version.xml
2399 libblkid/src/blkid.h
2400 libfdisk/docs/Makefile
2401 libfdisk/docs/version.xml
2402 libfdisk/src/libfdisk.h
2403 libmount/docs/Makefile
2404 libmount/docs/version.xml
2405 libmount/src/libmount.h
2406 libsmartcols/docs/Makefile
2407 libsmartcols/docs/version.xml
2408 libsmartcols/src/libsmartcols.h
2409 po/Makefile.in
2410 ])
2411
2412 AC_OUTPUT
2413
2414 AC_MSG_RESULT([
2415         ${PACKAGE}  ${VERSION}
2416
2417         prefix:            ${prefix}
2418         exec prefix:       ${exec_prefix}
2419
2420         runstatedir:       ${runstatedir}
2421         bindir:            ${bindir}
2422         sbindir:           ${sbindir}
2423         libdir:            ${libdir}
2424         includedir:        ${includedir}
2425         usrbin_execdir:    ${usrbin_execdir}
2426         usrsbin_execdir:   ${usrsbin_execdir}
2427         usrlib_execdir:    ${usrlib_execdir}
2428
2429         compiler:          ${CC}
2430         cflags:            ${CFLAGS}
2431         suid cflags:       ${SUID_CFLAGS}
2432         ldflags:           ${LDFLAGS}
2433         suid ldflags:      ${SUID_LDFLAGS}
2434
2435         Python:            ${PYTHON}
2436         Python version:    ${PYTHON_VERSION}
2437         Python libs:       ${pyexecdir}
2438
2439         Bash completions:  ${with_bashcompletiondir}
2440         Systemd support:   ${have_systemd}
2441         Systemd unitdir:   ${with_systemdsystemunitdir}
2442         Btrfs support:     ${have_btrfs}
2443         Wide-char support: ${build_widechar}
2444
2445         warnings:
2446
2447 ${WARN_CFLAGS}
2448
2449         Type 'make' or 'make <utilname>' to compile.
2450 ])