configure.ac

   1 AC_INIT([util-linux],
   2         m4_esyscmd([tools/git-version-gen .tarball-version]),
   3         [kzak@redhat.com],,
   4         [http://www.kernel.org/pub/linux/utils/util-linux/])
   5
   6
   7 AC_PREREQ([2.60])
   8
   9 AC_CONFIG_AUX_DIR([config])
  10 AC_CONFIG_MACRO_DIR([m4])
  11 dnl AC_USE_SYSTEM_EXTENSIONS must be called before any macros that run
  12 dnl the compiler (like AC_PROG_LIBTOOL) to avoid autoconf errors.
  13 AC_USE_SYSTEM_EXTENSIONS
  14 AM_INIT_AUTOMAKE([-Wall foreign 1.10 tar-pax no-dist-gzip dist-xz subdir-objects])
  15
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  17                             [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  18 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  19
  20 AC_CONFIG_SRCDIR([sys-utils/mount.c])
  21 AC_PREFIX_DEFAULT([/usr])
  22
  23 dnl version details from <major>.<minor>[-<suffix>]
  24 PACKAGE_VERSION_MAJOR=$(echo $PACKAGE_VERSION | awk -F. '{print $1}')
  25 PACKAGE_VERSION_MINOR=$(echo $PACKAGE_VERSION | awk -F. '{
  26                                                    sub("-.*","",$2); print $2}')
  27 PACKAGE_VERSION_RELEASE=$(echo $PACKAGE_VERSION | awk -F. '{
  28                      sub("-.*","",$3); print $3 ~ /^@<:@0-9@:>@+$/ ? $3 : 0}')
  29
  30 dnl libblkid version
  31 LIBBLKID_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  32 LIBBLKID_DATE="14-Jun-2019"
  33 LIBBLKID_LT_MAJOR=1
  34 LIBBLKID_LT_MINOR=1
  35 LIBBLKID_LT_MICRO=0
  36 LIBBLKID_VERSION_INFO=`expr $LIBBLKID_LT_MAJOR + $LIBBLKID_LT_MINOR`:$LIBBLKID_LT_MICRO:$LIBBLKID_LT_MINOR
  37
  38 dnl libuuid version
  39 LIBUUID_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  40 LIBUUID_LT_MAJOR=1
  41 LIBUUID_LT_MINOR=3
  42 LIBUUID_LT_MICRO=0
  43 LIBUUID_VERSION_INFO=`expr $LIBUUID_LT_MAJOR + $LIBUUID_LT_MINOR`:$LIBUUID_LT_MICRO:$LIBUUID_LT_MINOR
  44
  45 dnl libmount version
  46 LIBMOUNT_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  47 LIBMOUNT_LT_MAJOR=1
  48 LIBMOUNT_LT_MINOR=1
  49 LIBMOUNT_LT_MICRO=0
  50 LIBMOUNT_VERSION_INFO=`expr $LIBMOUNT_LT_MAJOR + $LIBMOUNT_LT_MINOR`:$LIBMOUNT_LT_MICRO:$LIBMOUNT_LT_MINOR
  51
  52 dnl libsmartcols version
  53 LIBSMARTCOLS_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  54 LIBSMARTCOLS_LT_MAJOR=1
  55 LIBSMARTCOLS_LT_MINOR=1
  56 LIBSMARTCOLS_LT_MICRO=0
  57 LIBSMARTCOLS_VERSION_INFO=`expr $LIBSMARTCOLS_LT_MAJOR + $LIBSMARTCOLS_LT_MINOR`:$LIBSMARTCOLS_LT_MICRO:$LIBSMARTCOLS_LT_MINOR
  58
  59 dnl libfdisk version
  60 LIBFDISK_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  61 LIBFDISK_LT_MAJOR=1
  62 LIBFDISK_LT_MINOR=1
  63 LIBFDISK_LT_MICRO=0
  64 LIBFDISK_VERSION_INFO=`expr $LIBFDISK_LT_MAJOR + $LIBFDISK_LT_MINOR`:$LIBFDISK_LT_MICRO:$LIBFDISK_LT_MINOR
  65
  66 # Check whether exec_prefix=/usr:
  67 AS_CASE([$exec_prefix:$prefix],
  68 [NONE:NONE | NONE:/usr | /usr:*],
  69   [AC_MSG_NOTICE([Default --exec-prefix detected.])
  70    AS_CASE([$bindir],  ['${exec_prefix}/bin'],  [bindir=/bin;   AC_MSG_NOTICE([  --bindir defaults to /bin])  ])
  71    AS_CASE([$sbindir], ['${exec_prefix}/sbin'], [sbindir=/sbin; AC_MSG_NOTICE([  --sbindir defaults to /sbin])])
  72    AS_CASE([$libdir],  ['${exec_prefix}/lib'],  [libdir=/lib;   AC_MSG_NOTICE([  --libdir defaults to /lib])  ])
  73    AS_CASE([$libdir],  ['${exec_prefix}/lib64'],[libdir=/lib64; AC_MSG_NOTICE([  --libdir defaults to /lib64])  ])
  74   ]
  75 )
  76
  77
  78 # default for old versions without $runstatedir
  79 AS_IF([test x"$runstatedir" = x], [runstatedir='${localstatedir}/run'])
  80
  81 # our default if $localstatedir unchanged
  82 AS_CASE([$localstatedir:$runstatedir],
  83  [NONE:'${localstatedir}/run' | /var:'${localstatedir}/run' | NONE:'/run' ],
  84    [runstatedir=/run; AC_MSG_NOTICE([  --runstatedir defaults to /run])]
  85 )
  86
  87 AC_SUBST([runstatedir])
  88
  89
  90 # The original default values of {bin,sbin,lib}dir
  91 usrbin_execdir='${exec_prefix}/bin'
  92 AC_SUBST([usrbin_execdir])
  93
  94 usrsbin_execdir='${exec_prefix}/sbin'
  95 AC_SUBST([usrsbin_execdir])
  96
  97 AS_CASE([$libdir],
  98  ['${exec_prefix}/'* | '${prefix}/'* | /usr/* | "${prefix}"/* ],
  99    [usrlib_execdir=$libdir],
 100  [usrlib_execdir='${exec_prefix}'$libdir]
 101 )
 102 AC_SUBST([usrlib_execdir])
 103
 104
 105 AM_PROG_CC_C_O
 106 AC_PROG_MKDIR_P
 107 AC_PROG_CC_STDC
 108 AC_PROG_YACC
 109 AC_CANONICAL_HOST
 110 AC_C_CONST
 111 AC_C_VOLATILE
 112 AC_C_BIGENDIAN
 113
 114 dnl Compiler warnings
 115 UL_WARN_ADD([-fno-common])
 116 UL_WARN_ADD([-Wall])
 117 UL_WARN_ADD([-Werror=sequence-point])
 118 UL_WARN_ADD([-Wextra])
 119 UL_WARN_ADD([-Wextra-semi])
 120 UL_WARN_ADD([-Wembedded-directive])
 121 UL_WARN_ADD([-Wmissing-declarations])
 122 UL_WARN_ADD([-Wmissing-parameter-type])
 123 UL_WARN_ADD([-Wmissing-prototypes])
 124 UL_WARN_ADD([-Wno-missing-field-initializers])
 125 UL_WARN_ADD([-Wredundant-decls])
 126 UL_WARN_ADD([-Wsign-compare])
 127 UL_WARN_ADD([-Wtype-limits])
 128 UL_WARN_ADD([-Wuninitialized])
 129 UL_WARN_ADD([-Wunused-but-set-parameter])
 130 UL_WARN_ADD([-Wunused-but-set-variable])
 131 UL_WARN_ADD([-Wunused-parameter])
 132 UL_WARN_ADD([-Wunused-result])
 133 UL_WARN_ADD([-Wunused-variable])
 134 UL_WARN_ADD([-Wnested-externs])
 135 UL_WARN_ADD([-Wpointer-arith])
 136 UL_WARN_ADD([-Wstrict-prototypes])
 137 UL_WARN_ADD([-Wformat-security])
 138 UL_WARN_ADD([-Wimplicit-function-declaration])
 139 UL_WARN_ADD([-Wdiscarded-qualifiers])
 140 AC_SUBST([WARN_CFLAGS])
 141
 142 UL_WARN_ADD([-Wno-clobbered], [BSD_WARN_CFLAGS])
 143 AC_SUBST([BSD_WARN_CFLAGS])
 144
 145 UL_WARN_ADD([-Wno-cast-function-type], [PYTHON_WARN_CFLAGS])
 146 AC_SUBST([PYTHON_WARN_CFLAGS])
 147
 148 UL_WARN_ADD([-Wno-unused-parameter], [NO_UNUSED_WARN_CFLAGS])
 149 AC_SUBST([NO_UNUSED_WARN_CFLAGS])
 150
 151
 152 AC_ARG_ENABLE([asan],
 153   AS_HELP_STRING([--enable-asan], [compile with Address Sanitizer]),
 154   [], [enable_asan=no]
 155 )
 156 AS_IF([test "x$enable_asan" = xyes], [
 157   UL_WARN_ADD([-fsanitize=address])
 158   ASAN_LDFLAGS="-fsanitize=address"
 159 ])
 160 AC_SUBST([ASAN_LDFLAGS])
 161
 162 dnl libtool-2
 163 LT_INIT
 164
 165 dnl check supported linker flags
 166 AX_CHECK_VSCRIPT
 167
 168 m4_ifndef([PKG_PROG_PKG_CONFIG],
 169   [m4_fatal([Could not locate the pkg-config autoconf
 170     macros. These are usually located in /usr/share/aclocal/pkg.m4.
 171     If your macros are in a different location, try setting the
 172     environment variable AL_OPTS="-I/other/macro/dir" before running
 173     ./autogen.sh or autoreconf again. Make sure pkg-config is installed.])])
 174 PKG_PROG_PKG_CONFIG
 175 PKG_INSTALLDIR(['${usrlib_execdir}/pkgconfig'])
 176
 177 GTK_DOC_CHECK([1.10])
 178 AC_PATH_PROG([XSLTPROC], [xsltproc])
 179
 180 linux_os=no
 181 bsd_os=no
 182 AS_CASE([${host_os}],
 183   [*linux*],
 184      [linux_os=yes],
 185   [*darwin*],
 186      [darwin_os=yes],
 187   [*bsd*],
 188      [bsd_os=yes])
 189 AM_CONDITIONAL([LINUX], [test "x$linux_os" = xyes])
 190 AM_CONDITIONAL([DARWIN], [test "x$darwin_os" = xyes])
 191 AM_CONDITIONAL([BSD], [test "x$bsd_os" = xyes])
 192
 193 AS_IF([test  "x$darwin_os" = xyes], [
 194   AC_DEFINE([_DARWIN_C_SOURCE], [1], [Enable MAP_ANON in sys/mman.h on Mac OS X])
 195 ])
 196
 197 dnl define ARCH_<NAME> conditionals
 198 UL_SET_ARCH([I86], [i?86-*])
 199 UL_SET_ARCH([86_64], [x86_64*])
 200 UL_SET_ARCH([IA64], [ia64*])
 201 UL_SET_ARCH([S390], [s390*])
 202 UL_SET_ARCH([SPARC], [sparc*])
 203 UL_SET_ARCH([PPC], [ppc*|powerpc*])
 204 UL_SET_ARCH([M68K], [m68*])
 205 UL_SET_ARCH([MIPS], [mips*])
 206 UL_SET_ARCH([HPPA], [hppa*|parisc*])
 207
 208 AC_SYS_LARGEFILE
 209 AC_HEADER_ASSERT
 210 AC_STRUCT_TIMEZONE
 211
 212 dnl Don't forget to maintain alternatively allowed versions in autogen.sh!
 213 AM_GNU_GETTEXT_VERSION([0.18.3])
 214 AM_GNU_GETTEXT([external])
 215
 216 AS_IF([test -d "$srcdir/po"], [
 217   ALL_LINGUAS=`cd $srcdir/po > /dev/null && echo *.po | sed 's/\.po//g'`
 218 ], [
 219   ALL_LINGUAS="af am ar as be bg bn_IN bn ca cs cy da de el en_GB es et eu_ES fa fi fr gl gu he hi hr hu hy id is it ja ka kn ko ku lo lt lv mk ml mr ms my nb nl nn no nso or pa pl pt_BR pt ro ru si sk sl sq sr@Latn sr sv ta te th tr uk ur vi zh_CN zh_TW zu"
 220 ])
 221
 222 AC_CHECK_HEADERS([linux/compiler.h linux/blkpg.h linux/major.h], [], [], [
 223 #ifdef HAVE_LINUX_COMPILER_H
 224 #include <linux/compiler.h>
 225 #endif
 226 ])
 227 AC_CHECK_HEADERS([ \
 228         asm/io.h \
 229         err.h \
 230         errno.h \
 231         fcntl.h \
 232         getopt.h \
 233         inttypes.h \
 234         lastlog.h \
 235         libutil.h \
 236         linux/btrfs.h \
 237         linux/cdrom.h \
 238         linux/falloc.h \
 239         linux/watchdog.h \
 240         linux/fd.h \
 241         linux/raw.h \
 242         linux/tiocl.h \
 243         linux/version.h \
 244         linux/securebits.h \
 245         linux/net_namespace.h \
 246         locale.h \
 247         mntent.h \
 248         net/if.h \
 249         net/if_dl.h \
 250         netinet/in.h \
 251         paths.h \
 252         pty.h \
 253         security/pam_appl.h \
 254         stdint.h \
 255         stdio_ext.h \
 256         stdlib.h \
 257         endian.h \
 258         byteswap.h \
 259         sys/endian.h \
 260         sys/disk.h \
 261         sys/disklabel.h \
 262         sys/file.h \
 263         sys/io.h \
 264         sys/ioccom.h \
 265         sys/ioctl.h \
 266         sys/mkdev.h \
 267         sys/mount.h \
 268         sys/param.h \
 269         sys/prctl.h \
 270         sys/resource.h \
 271         sys/signalfd.h \
 272         sys/socket.h \
 273         sys/sockio.h \
 274         sys/stat.h \
 275         sys/sysmacros.h \
 276         sys/swap.h \
 277         sys/syscall.h \
 278         sys/time.h \
 279         sys/timex.h \
 280         sys/ttydefaults.h \
 281         sys/types.h \
 282         sys/ucred.h \
 283         sys/un.h \
 284         unistd.h \
 285         shadow.h \
 286         utmp.h \
 287         utmpx.h \
 288 ])
 289
 290 # There is a collision in old kernel-headers. The both files mount.h and fs.h
 291 # define MS_* macros. Fixed by kernel commit e462ec50cb5fad19f6003a3d8087f4a0945dd2b1.
 292 #
 293 AC_CHECK_HEADERS([linux/fs.h ], [], [],
 294  [#ifdef HAVE_SYS_MOUNT_H
 295    # include <linux/fs.h>
 296    # include <sys/mount.h>
 297   #endif
 298 ])
 299
 300 AC_CHECK_HEADERS([linux/gsmmux.h ], [], [],
 301  [#ifdef LINUX_GSMMUX_H
 302    # include <linux/gsmmux.h>
 303    #endif
 304 ])
 305
 306 AC_CHECK_HEADERS([security/pam_misc.h],
 307                 [AM_CONDITIONAL([HAVE_LINUXPAM], [true])],
 308                 [AM_CONDITIONAL([HAVE_LINUXPAM], [false])], [
 309 #ifdef HAVE_SECURITY_PAM_APPL_H
 310 #include <security/pam_appl.h>
 311 #endif
 312 ])
 313
 314 AC_CHECK_HEADERS([linux/blkzoned.h])
 315
 316 AC_CHECK_HEADERS([security/openpam.h], [], [], [
 317 #ifdef HAVE_SECURITY_PAM_APPL_H
 318 #include <security/pam_appl.h>
 319 #endif
 320 ])
 321
 322 AC_CHECK_HEADERS([langinfo.h],
 323                 [AM_CONDITIONAL([HAVE_LANGINFO], [true])],
 324                 [AM_CONDITIONAL([HAVE_LANGINFO], [false])])
 325
 326 AC_MSG_CHECKING([whether langinfo.h defines ALTMON_x constants])
 327 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 328         #include <langinfo.h>
 329 ]], [[
 330         char *str;
 331         str = nl_langinfo (ALTMON_1);
 332         str = nl_langinfo (ALTMON_2);
 333         str = nl_langinfo (ALTMON_3);
 334         str = nl_langinfo (ALTMON_4);
 335         str = nl_langinfo (ALTMON_5);
 336         str = nl_langinfo (ALTMON_6);
 337         str = nl_langinfo (ALTMON_7);
 338         str = nl_langinfo (ALTMON_8);
 339         str = nl_langinfo (ALTMON_9);
 340         str = nl_langinfo (ALTMON_10);
 341         str = nl_langinfo (ALTMON_11);
 342         str = nl_langinfo (ALTMON_12);
 343 ]])], [
 344         AC_MSG_RESULT([yes])
 345         AC_DEFINE([HAVE_LANGINFO_ALTMON], [1],
 346                 [Define if langinfo.h defines ALTMON_x constants])
 347 ], [
 348         AC_MSG_RESULT([no])
 349 ])
 350
 351
 352 AC_MSG_CHECKING([whether langinfo.h defines _NL_ABALTMON_x constants])
 353 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 354         #include <langinfo.h>
 355 ]], [[
 356         char *str;
 357         str = nl_langinfo (_NL_ABALTMON_1);
 358         str = nl_langinfo (_NL_ABALTMON_2);
 359         str = nl_langinfo (_NL_ABALTMON_3);
 360         str = nl_langinfo (_NL_ABALTMON_4);
 361         str = nl_langinfo (_NL_ABALTMON_5);
 362         str = nl_langinfo (_NL_ABALTMON_6);
 363         str = nl_langinfo (_NL_ABALTMON_7);
 364         str = nl_langinfo (_NL_ABALTMON_8);
 365         str = nl_langinfo (_NL_ABALTMON_9);
 366         str = nl_langinfo (_NL_ABALTMON_10);
 367         str = nl_langinfo (_NL_ABALTMON_11);
 368         str = nl_langinfo (_NL_ABALTMON_12);
 369 ]])], [
 370         AC_MSG_RESULT([yes])
 371         AC_DEFINE([HAVE_LANGINFO_NL_ABALTMON], [1],
 372                 [Define if langinfo.h defines _NL_ABALTMON_x constants])
 373 ], [
 374         AC_MSG_RESULT([no])
 375 ])
 376
 377
 378 dnl Convert some ac_cv_header_* variables to have_*
 379 dnl
 380 have_linux_version_h=$ac_cv_header_linux_version_h
 381 have_linux_blkzoned_h=$ac_cv_header_linux_blkzoned_h
 382 have_linux_btrfs_h=$ac_cv_header_linux_btrfs_h
 383 have_linux_raw_h=$ac_cv_header_linux_raw_h
 384 have_linux_securebits_h=$ac_cv_header_linux_securebits_h
 385 have_linux_watchdog_h=$ac_cv_header_linux_watchdog_h
 386 have_security_pam_appl_h=$ac_cv_header_security_pam_appl_h
 387 have_security_pam_misc_h=$ac_cv_header_security_pam_misc_h
 388 have_security_openpam_h=$ac_cv_header_security_openpam_h
 389 have_shadow_h=$ac_cv_header_shadow_h
 390 have_sys_signalfd_h=$ac_cv_header_sys_signalfd_h
 391 have_utmpx_h=$ac_cv_header_utmpx_h
 392
 393 AS_CASE([$linux_os:$have_linux_version_h],
 394   [yes:no],
 395     [AC_MSG_ERROR([kernel headers required on Linux])]
 396 )
 397
 398 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 399 #include <time.h>
 400 #include <unistd.h>
 401 ]], [[
 402     int a = 0;
 403     struct tm *tm = localtime(0);
 404     if (a == -1)  /* false */
 405         sleep(tm->tm_gmtoff);
 406 ]])],
 407 [AC_DEFINE([HAVE_TM_GMTOFF], [1], [Does struct tm have a field tm_gmtoff?])
 408 ])
 409
 410 AC_CHECK_MEMBERS([struct termios.c_line],,,
 411     [[#include <termios.h>]])
 412
 413 AC_CHECK_MEMBERS([struct stat.st_mtim.tv_nsec],,,
 414         [#include <sys/stat.h>])
 415
 416 AC_CHECK_DECLS([_NL_TIME_WEEK_1STDAY],[],[],[[#include <langinfo.h>]])
 417
 418 AC_CHECK_DECL([llseek],
 419         [AC_DEFINE([HAVE_LLSEEK_PROTOTYPE], [1],
 420                         [Define to 1 if have llseek prototype])],
 421         [],
 422         [#include <unistd.h>])
 423
 424 AC_CHECK_DECL([lseek64],
 425         [AC_DEFINE([HAVE_LSEEK64_PROTOTYPE], [1],
 426                         [Define to 1 if have lseek64 prototype])],
 427         [],
 428         [#define _LARGEFILE_SOURCE
 429          #define _LARGEFILE64_SOURCE
 430          #include <unistd.h>])
 431
 432 AC_CHECK_DECL([environ],
 433         [AC_DEFINE([HAVE_ENVIRON_DECL], [1],
 434                 [Define to 1 if have **environ prototype])],
 435 )
 436
 437 AC_CHECK_DECL([strsignal],
 438         [AC_DEFINE([HAVE_STRSIGNAL_DECL], [1],
 439                 [Define to 1 if have strsignal function prototype])],
 440 )
 441
 442 AC_CHECK_DECL([TIOCGLCKTRMIOS],
 443               [have_tiocglcktrmios=yes], [have_tiocglcktrmios=no],
 444               [#include <sys/ioctl.h>])
 445 AC_CHECK_DECL([SOCK_CLOEXEC],
 446               [have_sock_cloexec=yes], [have_sock_cloexec=no],
 447               [#include <sys/types.h>
 448                #include <sys/socket.h>])
 449 AC_CHECK_DECL([SOCK_NONBLOCK],
 450               [have_sock_nonblock=yes], [have_sock_nonblock=no],
 451               [#include <sys/types.h>
 452                #include <sys/socket.h>])
 453 AC_CHECK_DECL([SO_PASSCRED],
 454               [have_so_passcred=yes], [have_so_passcred=no],
 455               [#include <sys/types.h>
 456                #include <sys/socket.h>])
 457
 458 AC_CHECK_FUNCS([ \
 459         clearenv \
 460         __fpurge \
 461         fpurge \
 462         __fpending \
 463         secure_getenv \
 464         __secure_getenv \
 465         eaccess \
 466         err \
 467         errx \
 468         explicit_bzero \
 469         fsync \
 470         utimensat \
 471         getdomainname \
 472         getdtablesize \
 473         getexecname \
 474         getmntinfo \
 475         getrandom \
 476         getrlimit \
 477         getsgnam \
 478         inotify_init \
 479         jrand48 \
 480         lchown \
 481         llseek \
 482         lseek64 \
 483         mempcpy \
 484         mkostemp \
 485         nanosleep \
 486         ntp_gettime \
 487         personality \
 488         posix_fadvise \
 489         prctl \
 490         qsort_r \
 491         rpmatch \
 492         scandirat \
 493         setprogname \
 494         setresgid \
 495         setresuid \
 496         sched_setattr \
 497         sched_setscheduler \
 498         sigqueue \
 499         srandom \
 500         strnchr \
 501         strndup \
 502         strnlen \
 503         sysconf \
 504         sysinfo \
 505         timegm \
 506         usleep \
 507         vwarnx \
 508         warn \
 509         warnx \
 510 ])
 511 AC_FUNC_FSEEKO
 512
 513 AC_CHECK_FUNCS([openat fstatat unlinkat], [have_openat=yes], [have_openat=no])
 514 AC_CHECK_FUNCS([ioperm iopl], [have_io=yes])
 515 AC_CHECK_FUNCS([futimens], [have_futimens=yes])
 516 AC_CHECK_FUNCS([inotify_init1], [have_inotify_init1=yes])
 517 AC_CHECK_FUNCS([open_memstream], [have_open_memstream=yes],[have_open_memstream=no])
 518 AC_CHECK_FUNCS([reboot], [have_reboot=yes],[have_reboot=no])
 519 AC_CHECK_FUNCS([updwtmpx updwtmpx], [have_gnu_utmpx=yes], [have_gnu_utmpx=no])
 520 AC_CHECK_FUNCS([getusershell], [have_getusershell=yes],[have_getusershell=no])
 521
 522 AM_CONDITIONAL([HAVE_OPENAT], [test "x$have_openat" = xyes])
 523
 524 have_setns_syscall="yes"
 525 UL_CHECK_SYSCALL([setns])
 526 AS_IF([test "x$ul_cv_syscall_setns" = xno], [
 527    have_setns_syscall="no"
 528 ])
 529
 530 AC_CHECK_FUNCS([isnan], [],
 531         [AC_CHECK_LIB([m], [isnan], [MATH_LIBS="-lm"])]
 532         [AC_CHECK_LIB([m], [__isnan], [MATH_LIBS="-lm"])]
 533 )
 534 AC_SUBST([MATH_LIBS])
 535
 536
 537 dnl lib/mononotic.c may require -lrt
 538 AC_CHECK_FUNCS([clock_gettime], [],
 539         [AC_CHECK_LIB([rt], [clock_gettime], [REALTIME_LIBS="-lrt"])]
 540 )
 541
 542 have_timer="no"
 543 AC_CHECK_FUNCS([timer_create],
 544         [have_timer="yes"],
 545         [AC_CHECK_LIB([rt], [timer_create], [
 546                 have_timer="yes"
 547                 REALTIME_LIBS="-lrt"
 548                 AC_DEFINE_UNQUOTED([HAVE_TIMER_CREATE], [1], [Define if timer_create exist in -lrt])
 549         ],[
 550                 AC_SEARCH_LIBS([timer_create], [rt], [
 551                         AC_MSG_RESULT(yes)
 552                         have_timer="yes"
 553                         REALTIME_LIBS="-lrt -lpthread"
 554                         AC_DEFINE_UNQUOTED([HAVE_TIMER_CREATE], [1], [Define if timer_create exist in -lrt -lpthread])
 555                 ],[], [-lpthread]
 556                 )
 557         ])]
 558 )
 559
 560 AC_SUBST([REALTIME_LIBS])
 561
 562 AS_IF([test x"$have_timer" = xno], [
 563        AC_CHECK_FUNCS([setitimer], [have_timer="yes"], [have_timer="no"])
 564 ])
 565
 566
 567 AC_CHECK_LIB([rtas], [rtas_get_sysparm], [
 568         RTAS_LIBS="-lrtas"
 569         AC_DEFINE_UNQUOTED([HAVE_LIBRTAS], [1], [Define if librtas exists]), [],
 570 ])
 571 AC_SUBST([RTAS_LIBS])
 572
 573
 574 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 575                 AC_DEFINE_UNQUOTED([HAVE_SA_LEN], [1], [Define if struct sockaddr contains sa_len]), [],
 576         [#include <sys/types.h>
 577          #include <sys/socket.h>])
 578
 579 SOCKET_LIBS=
 580 AC_SEARCH_LIBS([socket], [socket],
 581         [AS_IF([test x"$ac_cv_search_socket" != x"none required"],
 582                 [SOCKET_LIBS="$SOCKET_LIBS -lsocket"])
 583 ])
 584 AC_SUBST([SOCKET_LIBS])
 585
 586
 587 have_dirfd=no
 588 AC_CHECK_FUNCS([dirfd], [have_dirfd=yes], [have_dirfd=no])
 589 AS_IF([test x"$have_dirfd" = xno], [
 590         AC_CHECK_DECLS([dirfd],
 591                 [have_dirfd=yes], [have_dirfd=no],
 592                 [#include <sys/types.h>
 593                  #include <dirent.h>])
 594 ])
 595
 596 have_ddfd=no
 597 AS_IF([test x"$have_dirfd" = xno], [
 598         AC_CHECK_MEMBERS([DIR.dd_fd],
 599                 [have_ddfd=yes], [have_ddfd=no],
 600                 [#include <sys/types.h>
 601                  #include <dirent.h>])
 602 ])
 603
 604 AM_CONDITIONAL([HAVE_DIRFD], [test "x$have_dirfd" = xyes -o "x$have_ddfd" = xyes])
 605
 606
 607 AC_MSG_CHECKING([whether program_invocation_short_name is defined])
 608 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 609         #include <errno.h>
 610 ]], [[
 611         program_invocation_short_name = "test";
 612 ]])], [
 613         AC_MSG_RESULT([yes])
 614         AC_DEFINE([HAVE_PROGRAM_INVOCATION_SHORT_NAME], [1],
 615                 [Define if program_invocation_short_name is defined])
 616 ], [
 617         AC_MSG_RESULT([no])
 618 ])
 619
 620
 621 AC_MSG_CHECKING([whether __progname is defined])
 622 AC_LINK_IFELSE([AC_LANG_PROGRAM([extern char *__progname;],
 623            [if (*__progname == 0) return 1;])],
 624            AC_DEFINE([HAVE___PROGNAME], [1], [Define if __progname is defined])
 625            AC_MSG_RESULT([yes]),
 626            AC_MSG_RESULT([no]))
 627
 628 dnl Static compilation
 629 m4_define([UL_STATIC_PROGRAMS], [losetup, mount, umount, fdisk, sfdisk, blkid, nsenter, unshare])
 630
 631 AC_ARG_ENABLE([static-programs],
 632   [AS_HELP_STRING([--enable-static-programs=LIST],
 633       [link static the programs in LIST (comma-separated,
 634       supported for ]m4_defn([UL_STATIC_PROGRAMS])[)])])
 635
 636 AS_CASE([$enable_static_programs],
 637   [yes],
 638     [enable_static_programs=m4_quote(UL_STATIC_PROGRAMS)],
 639   [no],
 640     [enable_static_programs=]
 641 )
 642
 643 dnl Set all the individual AM_CONDITIONALs
 644 m4_foreach([UL_PRG], m4_defn([UL_STATIC_PROGRAMS]), [
 645   AS_CASE([,$enable_static_programs,],
 646    [*,UL_PRG,*], [static_[]UL_PRG=yes]
 647   )
 648   AS_IF([test "x$static_[]UL_PRG" = xyes], [AC_MSG_NOTICE([enable static build: UL_PRG.])])
 649   AM_CONDITIONAL([HAVE_STATIC_]m4_toupper(UL_PRG),
 650     [test "x$static_[]UL_PRG" = xyes])
 651 ])
 652
 653
 654 AC_ARG_ENABLE([all-programs],
 655   AS_HELP_STRING([--disable-all-programs], [disable everything, might be overridden by --enable-<name>]),
 656   [], [enable_all_programs=undefined]
 657 )
 658
 659 AS_CASE([$enable_all_programs],
 660   [yes], [AC_MSG_WARN([force to build all programs by default])
 661           ul_default_estate=check],
 662   [no],  [AC_MSG_WARN([disable all programs by default])
 663           ul_default_estate=no]
 664 )
 665
 666
 667 AX_CHECK_TLS
 668
 669 AC_DEFUN([UL_SCANF_TYPE_MODIFIER], [dnl
 670 # include <stdio.h>
 671 # include <stdlib.h>
 672 int main()
 673 {
 674         int i;
 675         int rc = 1;
 676         char *s;
 677         i = sscanf("x", $1, &s);
 678         if (i == 1  && *s == 'x')
 679                 rc = 0;
 680         free(s);
 681         return rc;
 682 }])
 683
 684 AC_CACHE_VAL([scanf_cv_alloc_modifier],
 685   AC_RUN_IFELSE([AC_LANG_SOURCE([UL_SCANF_TYPE_MODIFIER(["%ms"])])],
 686     [scanf_cv_alloc_modifier=ms],
 687     AC_RUN_IFELSE([AC_LANG_SOURCE([UL_SCANF_TYPE_MODIFIER(["%as"])])],
 688       [scanf_cv_alloc_modifier=as],
 689       [scanf_cv_alloc_modifier=no]
 690     )
 691     ,
 692
 693     [AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 694      #include <stdio.h>
 695      #include <unistd.h>
 696
 697      #if defined(__GLIBC__) && !defined(__UCLIBC__)
 698
 699      #if !(__GLIBC_PREREQ(2, 7))
 700      #error %m is not available
 701      #endif
 702
 703      #elif defined(_POSIX_VERSION)
 704
 705      #if _POSIX_VERSION < 200809L
 706      #error %m is not available
 707      #endif
 708
 709      #else
 710      #error Your C-library is not supported.
 711      #endif
 712      ])],
 713     [scanf_cv_alloc_modifier=ms],
 714     [scanf_cv_alloc_modifier=no])]
 715   )
 716 )
 717
 718 AC_MSG_CHECKING([scanf string alloc modifiers])
 719 AS_CASE([$scanf_cv_alloc_modifier],
 720   [ms],
 721     [AC_MSG_RESULT([(%ms) yes])
 722      AC_DEFINE([HAVE_SCANF_MS_MODIFIER], [1], [scanf %ms modifier])
 723      have_scanf_alloc_modifier=yes],
 724   [as],
 725     [AC_MSG_RESULT([(%as) yes])
 726      have_scanf_alloc_modifier=yes
 727      AC_DEFINE([HAVE_SCANF_AS_MODIFIER], [1], [scanf %as modifier])],
 728   [AC_MSG_RESULT([no])
 729    have_scanf_alloc_modifier=no]
 730 )
 731
 732
 733 AC_ARG_WITH([util], AS_HELP_STRING([--without-util], [compile without libutil]),
 734   [], [with_util=auto]
 735 )
 736 AS_IF([test "x$with_util" = xno], [
 737   AM_CONDITIONAL([HAVE_UTIL], [false])
 738   have_util=no
 739 ], [
 740   UL_CHECK_LIB([util], [openpty])
 741 ])
 742
 743
 744 AC_CHECK_TYPES([union semun], [], [], [[
 745 #include <sys/sem.h>
 746 ]])
 747 AC_CHECK_TYPES([loff_t])
 748
 749
 750 AC_ARG_ENABLE([widechar],
 751   AS_HELP_STRING([--disable-widechar], [do not compile wide character support]),
 752   [], [enable_widechar=check]
 753 )
 754 UL_BUILD_INIT([widechar])
 755 UL_REQUIRES_COMPILE([widechar], [[
 756   #include <wchar.h>
 757   #include <wctype.h>
 758   #include <stdio.h>
 759   #include <stdlib.h>
 760   ]], [[
 761     wchar_t wc;
 762     wint_t w;
 763     w = fgetwc(stdin);
 764     if (w == WEOF) exit(1);
 765     wc = w;
 766     fputwc(wc,stdout);
 767   ]],
 768   [wchar_t support])
 769
 770 AS_IF([test "x$build_widechar" = xyes ], [
 771   AC_DEFINE([HAVE_WIDECHAR], [1], [Do we have wide character support?])
 772 ])
 773
 774
 775 AC_CHECK_TYPES([cpu_set_t], [have_cpu_set_t=yes], [], [[
 776 #include <sched.h>
 777 ]])
 778
 779 AM_CONDITIONAL([HAVE_CPU_SET_T], [test "x$have_cpu_set_t" = xyes])
 780
 781 AC_CHECK_TYPES([sighandler_t], [], [], [[
 782 #include <signal.h>
 783 ]])
 784
 785 AC_CHECK_DECLS([CPU_ALLOC], [], [], [[
 786 #include <sched.h>
 787 ]])
 788
 789 # on Solaris, you can't mix and match standards, since we use c99
 790 # aparently at this stage, XOPEN_SOURCE will conflict.  As workaround,
 791 # check for crypt.h and use that without XOPEN_SOURCE.
 792 have_crypt=no
 793 AC_CHECK_HEADERS([crypt.h])
 794 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 795 #ifdef HAVE_CRYPT_H
 796 #include <crypt.h>
 797 #else
 798 #define _XOPEN_SOURCE
 799 #include <unistd.h>
 800 #endif
 801 ]], [[
 802 char *c = crypt("abc","pw");
 803 ]])],[
 804   have_libcrypt=no
 805   have_crypt=yes
 806 ],[
 807   LIBS="$LIBS -lcrypt"
 808   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 809   #ifdef HAVE_CRYPT_H
 810   #include <crypt.h>
 811   #else
 812   #define _XOPEN_SOURCE
 813   #include <unistd.h>
 814   #endif
 815   ]], [[
 816   char *c = crypt("abc","pw");
 817   ]])],[
 818   AC_DEFINE([HAVE_LIBCRYPT], [1], [Do we need -lcrypt?])
 819   have_libcrypt=yes
 820   have_crypt=yes
 821   ],[
 822   AC_MSG_WARN([crypt() is not available])
 823   ])
 824 ])
 825 AM_CONDITIONAL([HAVE_LIBCRYPT], [test "x$have_libcrypt" = xyes])
 826
 827
 828 AC_ARG_WITH([selinux],
 829   AS_HELP_STRING([--with-selinux], [compile with SELinux support]),
 830   [], [with_selinux=no]
 831 )
 832
 833 AS_IF([test "x$with_selinux" = xno], [
 834   AM_CONDITIONAL([HAVE_SELINUX], [false])
 835 ], [
 836   PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.0],
 837         [AC_DEFINE([HAVE_LIBSELINUX], [1], [Define if SELinux is available])
 838          UL_PKG_STATIC([SELINUX_LIBS_STATIC], [libselinux])
 839          AM_CONDITIONAL([HAVE_SELINUX], [true])
 840          have_selinux=yes],
 841         [have_selinux=no])
 842
 843   AS_CASE([$with_selinux:$have_selinux],
 844     [yes:no], [AC_MSG_ERROR([SELinux selected but libselinux not found or too old])]
 845   )
 846
 847   AS_IF([test "x$have_selinux" = xyes], [
 848     UL_SET_FLAGS([], [], [$SELINUX_LIBS])
 849     # This function is missing in old libselinux 1.xx versions
 850     AC_CHECK_FUNCS([security_get_initial_context])
 851     UL_RESTORE_FLAGS
 852   ])
 853 ])
 854 AC_SUBST([SELINUX_LIBS])
 855 AC_SUBST([SELINUX_LIBS_STATIC])
 856
 857
 858 AC_ARG_WITH([audit],
 859   AS_HELP_STRING([--with-audit], [compile with audit support]),
 860   [], [with_audit=no]
 861 )
 862
 863 AS_IF([test "x$with_audit" = xno], [
 864   AM_CONDITIONAL([HAVE_AUDIT], [false])
 865 ], [
 866   UL_CHECK_LIB([audit], [audit_log_user_message])
 867   AS_CASE([$with_audit:$have_audit],
 868     [yes:no],
 869       [AC_MSG_ERROR([Audit selected but libaudit not found (or does not support audit_log_user_message())])]
 870   )
 871 ])
 872
 873 AC_ARG_WITH([udev], AS_HELP_STRING([--without-udev], [compile without udev support]),
 874   [], [with_udev=auto]
 875 )
 876
 877 AS_IF([test "x$with_udev" = xno], [
 878   AM_CONDITIONAL([HAVE_UDEV], [false])
 879 ], [
 880   UL_CHECK_LIB([udev], [udev_new])
 881   AS_CASE([$with_udev:$have_udev],
 882     [yes:no],
 883       [AC_MSG_ERROR([udev selected but libudev not found])]
 884   )
 885 ])
 886
 887
 888 dnl wide-char ncurses
 889 AC_ARG_WITH([ncursesw],
 890   AS_HELP_STRING([--without-ncursesw], [do not build with wide-char ncurses]),
 891   [], [with_ncursesw=auto]
 892 )
 893 have_ncursesw=no
 894 have_ncursesw_header=no
 895 AS_IF([test "x$with_ncursesw" != xno], [
 896   UL_NCURSES_CHECK([ncursesw])
 897   AS_IF([test "x$have_ncursesw" = xyes], [
 898     AC_CHECK_HEADERS([ncursesw/ncurses.h], [have_ncursesw_header=yes])
 899     AC_CHECK_HEADERS([ncursesw/term.h])
 900
 901     # Define HAVE_NCURSES_H only if check for HAVE_NCURSESW_NCURSES_H is
 902     # unsuccessful to avoid too many *_H permitations in config.h
 903     AS_IF([test "x$have_ncursesw_header" = xno], [
 904            AC_CHECK_HEADERS([ncurses.h], [have_ncursesw_header=yes])
 905            AC_CHECK_HEADERS([term.h])
 906     ])
 907     AS_IF([test "x$have_ncursesw_header" = xno], [have_ncursesw=no])
 908   ])
 909   AS_IF([test "x$have_ncursesw" = xyes], [
 910     CURSES_LIB_NAME="ncursesw"
 911     AC_DEFINE([HAVE_LIBNCURSESW], [1], [Define if ncursesw library available])
 912   ])
 913 ])
 914 AS_CASE([$with_ncursesw:$have_ncursesw],
 915   [yes:no], [AC_MSG_ERROR([ncursesw selected, but library not found])])
 916
 917
 918 dnl non-wide ncurses
 919 AC_ARG_WITH([ncurses],
 920   AS_HELP_STRING([--with-ncurses], [build with non-wide ncurses]),
 921   [], [with_ncurses=auto]
 922 )
 923 have_ncurses=no
 924 have_ncurses_header=no
 925 AS_CASE([$with_ncurses:$build_widechar],
 926   [yes:yes], [AC_MSG_ERROR([wide-char support enabled, but non-wide ncurses selects])])
 927
 928 AS_IF([test "x$have_ncursesw" = xno -a "x$with_ncurses" != xno ], [
 929   UL_NCURSES_CHECK([ncurses])
 930   AS_IF([test "x$have_ncurses" = xyes], [
 931     AC_CHECK_HEADERS([ncurses/ncurses.h], [have_ncurses_header=yes])
 932     AC_CHECK_HEADERS([ncurses/term.h])
 933
 934     # Define HAVE_NCURSES_H only if check for HAVE_NCURSES_NCURSES_H is
 935     # unsuccessful to avoid too many *_H permitations in config.h
 936     AS_IF([test "x$have_ncurses_header" = xno], [
 937            AC_CHECK_HEADERS([ncurses.h], [have_ncurses_header=yes])
 938            AC_CHECK_HEADERS([term.h])
 939     ])
 940     AS_IF([test "x$have_ncurses_header" = xno], [have_ncurses=no])
 941   ])
 942   AS_IF([test "x$have_ncurses" = xyes], [
 943     CURSES_LIB_NAME="ncurses"
 944     AC_DEFINE([HAVE_LIBNCURSES], [1], [Define if ncurses library available])
 945   ])
 946 ])
 947 AS_CASE([$with_ncurses:$have_ncurses],
 948   [yes:no], [AC_MSG_ERROR([ncurses selected, but library not found])])
 949
 950 AC_SUBST([NCURSES_CFLAGS])
 951 AC_SUBST([NCURSES_LIBS])
 952 AM_CONDITIONAL([HAVE_NCURSES], [test "x$have_ncursesw" = xyes -o  "x$have_ncurses" = xyes])
 953
 954
 955 AC_ARG_WITH([slang],
 956   AS_HELP_STRING([--with-slang], [compile cfdisk with slang rather than ncurses]),
 957   [], [with_slang=no]
 958 )
 959 have_slang=no
 960 AS_IF([test "x$with_slang" = xyes], [
 961   AC_CHECK_HEADERS([slang.h slang/slang.h])
 962   AC_CHECK_HEADERS([slcurses.h slang/slcurses.h],
 963                    [have_slang=yes], [], [
 964 #ifdef HAVE_SLANG_H
 965 #include <slang.h>
 966 #elif defined(HAVE_SLANG_SLANG_H)
 967 #include <slang/slang.h>
 968 #endif
 969 ])
 970   AS_IF([test "x$have_slang" = xno], [
 971     AC_MSG_ERROR([slang selected but slcurses.h not found])],
 972     [CURSES_LIB_NAME=slang
 973   ])
 974 ])
 975 AM_CONDITIONAL([HAVE_SLANG], [test "x$have_slang" = xyes])
 976
 977
 978 AS_IF([test "x$have_slang" = xyes -o "x$have_ncursesw" = xyes -o "x$have_ncurses" = xyes], [
 979         AC_CHECK_LIB([$CURSES_LIB_NAME], use_default_colors, [
 980                      AC_DEFINE(HAVE_USE_DEFAULT_COLORS, 1,
 981                                [Define if curses library has the use_default_colors().])
 982         ])
 983         AC_CHECK_LIB([$CURSES_LIB_NAME], resizeterm, [
 984                      AC_DEFINE(HAVE_RESIZETERM, 1,
 985                                [Define if curses library has the resizeterm().])
 986         ])
 987 ])
 988
 989
 990 AC_ARG_WITH([tinfo], AS_HELP_STRING([--without-tinfo], [compile without libtinfo]),
 991   [], [with_tinfo=auto]
 992 )
 993 have_tinfo=no
 994 have_tinfow=no
 995 AS_IF([test "x$with_tinfo" != xno], [
 996   AS_IF([test "x$have_ncursesw" = xyes], [
 997     UL_TINFO_CHECK([tinfow])
 998   ])
 999   AS_IF([test "x$have_tinfow" = xno], [
1000     UL_TINFO_CHECK([tinfo])
1001   ])
1002 ])
1003 AC_SUBST([TINFO_LIBS])
1004 AC_SUBST([TINFO_LIBS_STATIC])
1005 AC_SUBST([TINFO_CFLAGS])
1006 AM_CONDITIONAL([HAVE_TINFO], [test "x$have_tinfo" = xyes -o "x$have_tinfow" = xyes])
1007 AS_IF([test "x$have_tinfo" = xyes -o "x$have_tinfow" = xyes], [
1008   AC_DEFINE(HAVE_LIBTINFO, 1, [Define if libtinfo or libtinfow available.])
1009 ])
1010
1011
1012 AC_ARG_WITH([readline],
1013   AS_HELP_STRING([--without-readline], [do not build with GNU Readline support]),
1014   [], [with_readline=auto]
1015 )
1016
1017 AS_IF([test "x$with_readline" = xno], [
1018   AM_CONDITIONAL([HAVE_READLINE], [false])
1019 ], [
1020   UL_CHECK_LIB([readline], [readline])
1021   AS_CASE([$with_readline:$have_readline],
1022     [yes:no],
1023       [AC_MSG_ERROR([readline selected but libreadline not found ])],
1024     [*:yes],
1025       [READLINE_LIBS="-lreadline"
1026        READLINE_LIBS_STATIC="-lreadline $TINFO_LIBS_STATIC"]
1027   )
1028 ])
1029 AC_SUBST([READLINE_LIBS])
1030 AC_SUBST([READLINE_LIBS_STATIC])
1031
1032
1033 AC_ARG_WITH([utempter],
1034   AS_HELP_STRING([--with-utempter], [compile script(1) with libutempter]),
1035   [], [with_utempter=no]
1036 )
1037
1038 AS_IF([test "x$with_utempter" = xyes], [
1039   UL_CHECK_LIB([utempter], [utempter_add_record])
1040   AS_IF([test "x$have_utempter" = xno], [
1041     AC_MSG_ERROR([utempter selected but libutempter not found])
1042   ])
1043 ], [
1044   AM_CONDITIONAL([HAVE_UTEMPTER], [false])
1045 ])
1046
1047
1048 dnl
1049 dnl libuuid
1050 dnl
1051 AC_ARG_ENABLE([libuuid],
1052   AS_HELP_STRING([--disable-libuuid], [do not build libuuid and uuid utilities]),
1053   [], [UL_DEFAULT_ENABLE([libuuid], [yes])]
1054 )
1055 UL_BUILD_INIT([libuuid])
1056 AC_SUBST([LIBUUID_VERSION])
1057 AC_SUBST([LIBUUID_VERSION_INFO])
1058 AM_CONDITIONAL(BUILD_LIBUUID, test "x$build_libuuid" = xyes)
1059
1060 AC_ARG_ENABLE([libuuid-force-uuidd],
1061   AS_HELP_STRING([--enable-libuuid-force-uuidd], [support uuidd even though the daemon is not built]),
1062   [], [enable_libuuid_force_uuidd=no]
1063 )
1064
1065 AS_IF([test "x$build_libuuid" = xyes], [
1066   AC_DEFINE(HAVE_LIBUUID, 1, [Define to 1 if you have the -luuid.])
1067 ])
1068
1069 dnl
1070 dnl libblkid
1071 dnl
1072 AC_ARG_ENABLE([libblkid],
1073   AS_HELP_STRING([--disable-libblkid], [do not build libblkid and many related utilities]),
1074   [], [UL_DEFAULT_ENABLE([libblkid], [check])]
1075 )
1076 UL_BUILD_INIT([libblkid])
1077 UL_REQUIRES_HAVE([libblkid], [openat], [openat functions])
1078 UL_REQUIRES_HAVE([libblkid], [dirfd,ddfd], [dirfd or ddfd function])
1079 AC_SUBST([LIBBLKID_DATE])
1080 AC_SUBST([LIBBLKID_VERSION])
1081 AC_SUBST([LIBBLKID_VERSION_INFO])
1082 AC_DEFINE_UNQUOTED([LIBBLKID_VERSION], ["$LIBBLKID_VERSION"], [libblkid version string])
1083 AC_DEFINE_UNQUOTED([LIBBLKID_DATE], ["$LIBBLKID_DATE"], [libblkid date string])
1084 AS_IF([test "x$build_libblkid" = xyes], [
1085   AC_DEFINE([HAVE_LIBBLKID], [1], [Define to 1 if you have the -lblkid.])
1086 ])
1087 AM_CONDITIONAL([BUILD_LIBBLKID], [test "x$build_libblkid" = xyes])
1088 AM_CONDITIONAL([BUILD_LIBBLKID_TESTS], [test "x$build_libblkid" = xyes -a "x$enable_static" = xyes])
1089
1090 dnl
1091 dnl libmount
1092 dnl
1093 AC_ARG_ENABLE([libmount],
1094   AS_HELP_STRING([--disable-libmount], [do not build libmount]),
1095   [], [UL_DEFAULT_ENABLE([libmount], [check])]
1096 )
1097 UL_BUILD_INIT([libmount])
1098 UL_REQUIRES_BUILD([libmount], [libblkid])
1099 UL_REQUIRES_HAVE([libmount], [scanf_alloc_modifier], [scanf string alloc modifier])
1100 UL_REQUIRES_HAVE([libmount], [dirfd,ddfd], [dirfd or ddfd function])
1101 AM_CONDITIONAL([BUILD_LIBMOUNT], [test "x$build_libmount" = xyes])
1102 AM_CONDITIONAL([BUILD_LIBMOUNT_TESTS], [test "x$build_libmount" = xyes -a "x$enable_static" = xyes])
1103 AS_IF([test "x$build_libmount" = xyes], [
1104   AC_DEFINE(HAVE_LIBMOUNT, 1, [Define if libmount available.])
1105   AS_IF([test "x$have_setns_syscall" = "xyes"], [
1106     AC_DEFINE([USE_LIBMOUNT_SUPPORT_NAMESPACES], [1], [Define to 1 if want to support namepaces.])
1107   ],[
1108     AC_MSG_WARN([libmount will be compiled without namespaces support])
1109   ])
1110 ])
1111
1112 AC_SUBST([LIBMOUNT_VERSION])
1113 AC_SUBST([LIBMOUNT_MAJOR_VERSION], $PACKAGE_VERSION_MAJOR)
1114 AC_SUBST([LIBMOUNT_MINOR_VERSION], $PACKAGE_VERSION_MINOR)
1115 AC_SUBST([LIBMOUNT_PATCH_VERSION], $PACKAGE_VERSION_RELEASE)
1116 AC_SUBST([LIBMOUNT_VERSION_INFO])
1117 AC_DEFINE_UNQUOTED([LIBMOUNT_VERSION], ["$LIBMOUNT_VERSION"], [libmount version string])
1118
1119 AC_ARG_ENABLE([libmount-support-mtab],
1120   AS_HELP_STRING([--enable-libmount-support-mtab], [support /etc/mtab (default is use /proc/self/mountinfo)]),
1121   [], [enable_libmount_support_mtab=no]
1122 )
1123
1124 AS_IF([test "x$enable_libmount_support_mtab" = xyes], [
1125   AC_DEFINE([USE_LIBMOUNT_SUPPORT_MTAB], [1], [Define to 1 if want to support mtab.])
1126 ])
1127
1128 dnl
1129 dnl libsmartcols
1130 dnl
1131 AC_ARG_ENABLE([libsmartcols],
1132   AS_HELP_STRING([--disable-libsmartcols], [do not build libsmartcols]),
1133   [], [UL_DEFAULT_ENABLE([libsmartcols], [yes])]
1134 )
1135 UL_BUILD_INIT([libsmartcols])
1136 AM_CONDITIONAL([BUILD_LIBSMARTCOLS], [test "x$build_libsmartcols" = xyes])
1137
1138 AC_SUBST([LIBSMARTCOLS_VERSION])
1139 AC_SUBST([LIBSMARTCOLS_VERSION_INFO])
1140 AC_DEFINE_UNQUOTED([LIBSMARTCOLS_VERSION], ["$LIBSMARTCOLS_VERSION"], [libsmartcols version string])
1141
1142
1143 dnl
1144 dnl libfdisk
1145 dnl
1146 AC_ARG_ENABLE([libfdisk],
1147   AS_HELP_STRING([--disable-libfdisk], [do not build libfdisk]),
1148   [], [UL_DEFAULT_ENABLE([libfdisk], [check])]
1149 )
1150 UL_BUILD_INIT([libfdisk])
1151 UL_REQUIRES_BUILD([libfdisk], [libuuid])
1152 AM_CONDITIONAL([BUILD_LIBFDISK], [test "x$build_libfdisk" = xyes])
1153 AM_CONDITIONAL([BUILD_LIBFDISK_TESTS], [test "x$build_libfdisk" = xyes -a "x$enable_static" = xyes])
1154
1155 AS_IF([test "x$build_libblkid" = xyes],
1156   [LIBFDISK_PC_REQUIRES="uuid blkid"],[LIBFDISK_PC_REQUIRES="uuid"])
1157 AC_SUBST([LIBFDISK_PC_REQUIRES])
1158
1159 AC_SUBST([LIBFDISK_VERSION])
1160 AC_SUBST([LIBFDISK_MAJOR_VERSION], $PACKAGE_VERSION_MAJOR)
1161 AC_SUBST([LIBFDISK_MINOR_VERSION], $PACKAGE_VERSION_MINOR)
1162 AC_SUBST([LIBFDISK_PATCH_VERSION], $PACKAGE_VERSION_RELEASE)
1163 AC_SUBST([LIBFDISK_VERSION_INFO])
1164 AC_DEFINE_UNQUOTED([LIBFDISK_VERSION], ["$LIBFDISK_VERSION"], [libfdisk version string])
1165
1166
1167 AC_ARG_ENABLE([fdisks],
1168   AS_HELP_STRING([--disable-fdisks], [do not build fdisk(8), sfdisk(8) and cfdisk(8)]),
1169   [], [UL_DEFAULT_ENABLE([fdisks], [check])]
1170 )
1171 enable_fdisk=$enable_fdisks
1172 enable_sfdisk=$enable_fdisks
1173 enable_cfdisk=$enable_fdisks
1174
1175 UL_BUILD_INIT([fdisk])
1176 UL_REQUIRES_HAVE([fdisk], [openat], [openat functions])
1177 UL_REQUIRES_HAVE([fdisk], [dirfd,ddfd], [dirfd or ddfd function])
1178 UL_REQUIRES_BUILD([fdisk], [libfdisk])
1179 UL_REQUIRES_BUILD([fdisk], [libsmartcols])
1180 AM_CONDITIONAL([BUILD_FDISK], [test "x$build_fdisk" = xyes])
1181
1182
1183 UL_BUILD_INIT([sfdisk])
1184 UL_REQUIRES_HAVE([sfdisk], [openat], [openat functions])
1185 UL_REQUIRES_HAVE([sfdisk], [dirfd,ddfd], [dirfd or ddfd function])
1186 UL_REQUIRES_BUILD([sfdisk], [libfdisk])
1187 UL_REQUIRES_BUILD([sfdisk], [libsmartcols])
1188 AM_CONDITIONAL([BUILD_SFDISK], [test "x$build_sfdisk" = xyes])
1189
1190
1191 UL_BUILD_INIT([cfdisk])
1192 UL_REQUIRES_BUILD([cfdisk], [libfdisk])
1193 UL_REQUIRES_BUILD([cfdisk], [libsmartcols])
1194 UL_REQUIRES_HAVE([cfdisk], [open_memstream], [open_memstream function])
1195 UL_REQUIRES_HAVE([cfdisk], [ncursesw,slang,ncurses], [ncursesw, ncurses or slang library])
1196 AM_CONDITIONAL([BUILD_CFDISK], [test "x$build_cfdisk" = xyes])
1197
1198
1199 AC_ARG_ENABLE([mount],
1200   AS_HELP_STRING([--disable-mount], [do not build mount(8) and umount(8)]),
1201   [], [UL_DEFAULT_ENABLE([mount], [check])]
1202 )
1203 UL_BUILD_INIT([mount])
1204 UL_REQUIRES_LINUX([mount])
1205 UL_REQUIRES_BUILD([mount], [libmount])
1206 AM_CONDITIONAL([BUILD_MOUNT], [test "x$build_mount" = xyes])
1207
1208
1209 AC_ARG_ENABLE([losetup],
1210   AS_HELP_STRING([--disable-losetup], [do not build losetup]),
1211   [], [UL_DEFAULT_ENABLE([losetup], [check])]
1212 )
1213 UL_BUILD_INIT([losetup])
1214 UL_REQUIRES_LINUX([losetup])
1215 UL_REQUIRES_BUILD([losetup], [libsmartcols])
1216 AM_CONDITIONAL([BUILD_LOSETUP], [test "x$build_losetup" = xyes])
1217
1218 AC_ARG_ENABLE([zramctl],
1219   AS_HELP_STRING([--disable-zramctl], [do not build zramctl]),
1220   [], [UL_DEFAULT_ENABLE([zramctl], [check])]
1221 )
1222 UL_BUILD_INIT([zramctl])
1223 UL_REQUIRES_LINUX([zramctl])
1224 UL_REQUIRES_BUILD([zramctl], [libsmartcols])
1225 AM_CONDITIONAL([BUILD_ZRAMCTL], [test "x$build_zramctl" = xyes])
1226
1227 AC_ARG_ENABLE([fsck],
1228   AS_HELP_STRING([--disable-fsck], [do not build fsck]),
1229   [], [UL_DEFAULT_ENABLE([fsck], [check])]
1230 )
1231 UL_BUILD_INIT([fsck])
1232 UL_REQUIRES_BUILD([fsck], [libmount])
1233 AM_CONDITIONAL([BUILD_FSCK], [test "x$build_fsck" = xyes])
1234
1235
1236 AC_ARG_ENABLE([partx],
1237   AS_HELP_STRING([--disable-partx], [do not build addpart, delpart, partx]),
1238   [], [UL_DEFAULT_ENABLE([partx], [check])]
1239 )
1240 UL_BUILD_INIT([partx])
1241 UL_REQUIRES_LINUX([partx])
1242 UL_REQUIRES_BUILD([partx], [libblkid])
1243 UL_REQUIRES_BUILD([partx], [libsmartcols])
1244 AM_CONDITIONAL([BUILD_PARTX], [test "x$build_partx" = xyes])
1245
1246
1247 AC_ARG_ENABLE([uuidd],
1248   AS_HELP_STRING([--disable-uuidd], [do not build the uuid daemon]),
1249   [], [UL_DEFAULT_ENABLE([uuidd], [check])]
1250 )
1251 UL_BUILD_INIT([uuidd])
1252 UL_REQUIRES_BUILD([uuidd], [libuuid])
1253 UL_REQUIRES_HAVE([uuidd], [timer], [timer_create function])
1254 UL_REQUIRES_HAVE([uuidd], [sys_signalfd_h], [sys/signalfd.h header])
1255 AS_IF([test "x$build_uuidd" = xyes || test "x$enable_libuuid_force_uuidd" = xyes], [
1256   AC_DEFINE([HAVE_UUIDD], [1], [Define to 1 if you want to use uuid daemon.])
1257 ])
1258 AM_CONDITIONAL([BUILD_UUIDD], [test "x$build_uuidd" = xyes])
1259
1260
1261 UL_BUILD_INIT([uuidgen], [check])
1262 UL_REQUIRES_BUILD([uuidgen], [libuuid])
1263 AM_CONDITIONAL([BUILD_UUIDGEN], [test "x$build_uuidgen" = xyes])
1264
1265 UL_BUILD_INIT([uuidparse], [check])
1266 UL_REQUIRES_BUILD([uuidparse], [libuuid])
1267 UL_REQUIRES_BUILD([uuidparse], [libsmartcols])
1268 AM_CONDITIONAL([BUILD_UUIDPARSE], [test "x$build_uuidparse" = xyes])
1269
1270 UL_BUILD_INIT([blkid], [check])
1271 UL_REQUIRES_BUILD([blkid], [libblkid])
1272 AM_CONDITIONAL([BUILD_BLKID], [test "x$build_blkid" = xyes])
1273
1274 UL_BUILD_INIT([findfs], [check])
1275 UL_REQUIRES_BUILD([findfs], [libblkid])
1276 AM_CONDITIONAL([BUILD_FINDFS], [test "x$build_findfs" = xyes])
1277
1278 UL_BUILD_INIT([wipefs], [check])
1279 UL_REQUIRES_BUILD([wipefs], [libblkid])
1280 UL_REQUIRES_BUILD([wipefs], [libsmartcols])
1281 AM_CONDITIONAL([BUILD_WIPEFS], [test "x$build_wipefs" = xyes])
1282
1283 UL_BUILD_INIT([findmnt], [check])
1284 UL_REQUIRES_BUILD([findmnt], [libmount])
1285 UL_REQUIRES_BUILD([findmnt], [libblkid])
1286 UL_REQUIRES_BUILD([findmnt], [libsmartcols])
1287 AM_CONDITIONAL([BUILD_FINDMNT], [test "x$build_findmnt" = xyes])
1288
1289
1290 AC_ARG_ENABLE([mountpoint],
1291   AS_HELP_STRING([--disable-mountpoint], [do not build mountpoint]),
1292   [], [UL_DEFAULT_ENABLE([mountpoint], [check])]
1293 )
1294 UL_BUILD_INIT([mountpoint])
1295 UL_REQUIRES_BUILD([mountpoint], [libmount])
1296 AM_CONDITIONAL([BUILD_MOUNTPOINT], [test "x$build_mountpoint" = xyes])
1297
1298
1299 AC_ARG_ENABLE([fallocate],
1300   AS_HELP_STRING([--disable-fallocate], [do not build fallocate]),
1301   [], [UL_DEFAULT_ENABLE([fallocate], [check])]
1302 )
1303 UL_BUILD_INIT([fallocate])
1304 UL_REQUIRES_LINUX([fallocate])
1305 UL_REQUIRES_SYSCALL_CHECK([fallocate], [UL_CHECK_SYSCALL([fallocate])])
1306 AM_CONDITIONAL([BUILD_FALLOCATE], [test "x$build_fallocate" = xyes])
1307
1308 AS_IF([test "x$build_fallocate" = xyes], [
1309   dnl check for valid fallocate() function
1310   dnl with 32 bits glibc 2.10, fallocate() exists but not fallocate64()
1311   dnl when _FILE_OFFSET_BITS==64, fallocate() is redirect to fallocate64()
1312   dnl and program can't be linked.
1313   dnl AC_CHECK_FUNC can't catch such errors since it's redefining
1314   dnl function prototype.
1315   AC_MSG_CHECKING([for valid fallocate() function])
1316   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1317 #ifdef HAVE_UNISTD_H
1318 # include <unistd.h>
1319 #endif
1320 #ifdef HAVE_SYS_TYPES_H
1321 # include <sys/types.h>
1322 #endif
1323 #ifdef HAVE_LINUX_FALLOC_H
1324 # include <linux/falloc.h>
1325 #endif
1326 #ifdef HAVE_FCNTL_H
1327 # include <fcntl.h>
1328 #endif
1329 ]],[[
1330    long ret;
1331    ret = fallocate(0, FALLOC_FL_KEEP_SIZE, 0xfffffffful, 0xfffffffful);
1332    if (ret != 0) {
1333       return 1;
1334    }
1335    ]])],[
1336   AC_MSG_RESULT([yes])
1337   AC_DEFINE([HAVE_FALLOCATE], [1], [Have valid fallocate() function])],[
1338   AC_MSG_RESULT([no])])
1339 ])
1340
1341 AS_IF([test "x$build_fallocate" = xyes], [
1342   dnl check for valid posix_fallocate() function
1343   AC_MSG_CHECKING([for valid posix_fallocate() function])
1344   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1345 #ifdef HAVE_UNISTD_H
1346 # include <unistd.h>
1347 #endif
1348 #ifdef HAVE_SYS_TYPES_H
1349 # include <sys/types.h>
1350 #endif
1351 #ifdef HAVE_LINUX_FALLOC_H
1352 # include <linux/falloc.h>
1353 #endif
1354 #ifdef HAVE_FCNTL_H
1355 # include <fcntl.h>
1356 #endif
1357 ]],[[
1358    long ret;
1359    ret = posix_fallocate(0, 0xfffffffful, 0xfffffffful);
1360    if (ret != 0) {
1361       return 1;
1362    }
1363    ]])],[
1364   AC_MSG_RESULT([yes])
1365   AC_DEFINE([HAVE_POSIX_FALLOCATE], [1], [Have valid posix_fallocate() function])],[
1366   AC_MSG_RESULT([no])])
1367 ])
1368
1369
1370 AC_ARG_ENABLE([unshare],
1371   AS_HELP_STRING([--disable-unshare], [do not build unshare]),
1372   [], [UL_DEFAULT_ENABLE([unshare], [check])]
1373 )
1374 UL_BUILD_INIT([unshare])
1375 UL_REQUIRES_LINUX([unshare])
1376 UL_REQUIRES_SYSCALL_CHECK([unshare], [UL_CHECK_SYSCALL([unshare])])
1377 AM_CONDITIONAL([BUILD_UNSHARE], [test "x$build_unshare" = xyes])
1378 AC_CHECK_FUNCS([unshare])
1379
1380 AC_ARG_ENABLE([nsenter],
1381   AS_HELP_STRING([--disable-nsenter], [do not build nsenter]),
1382   [], [UL_DEFAULT_ENABLE([nsenter], [check])]
1383 )
1384 UL_BUILD_INIT([nsenter])
1385 UL_REQUIRES_LINUX([nsenter])
1386 UL_REQUIRES_HAVE([nsenter], [setns_syscall], [setns syscall])
1387 AM_CONDITIONAL([BUILD_NSENTER], [test "x$build_nsenter" = xyes])
1388 AC_CHECK_FUNCS([setns])
1389
1390
1391 AC_ARG_WITH([cap_ng],
1392   AS_HELP_STRING([--without-cap-ng], [compile without libcap-ng]),
1393   [], [with_cap_ng=auto]
1394 )
1395 AS_IF([test "x$with_cap_ng" = xno], [
1396   AM_CONDITIONAL([HAVE_CAP_NG], [false])
1397   have_cap_ng=no
1398 ],[
1399   UL_CHECK_LIB([cap-ng], [capng_apply], [cap_ng])
1400 ])
1401
1402
1403 AC_ARG_ENABLE([setpriv],
1404   AS_HELP_STRING([--disable-setpriv], [do not build setpriv]),
1405   [], [UL_DEFAULT_ENABLE([setpriv], [check])]
1406 )
1407 UL_BUILD_INIT([setpriv])
1408 UL_REQUIRES_LINUX([setpriv])
1409 UL_REQUIRES_HAVE([setpriv], [linux_securebits_h], [securebits.h header file])
1410 UL_REQUIRES_HAVE([setpriv], [cap_ng], [libcap-ng library])
1411 AM_CONDITIONAL([BUILD_SETPRIV], [test "x$build_setpriv" = xyes])
1412
1413 PKG_CHECK_MODULES([PCRE], [libpcre2-8], [have_pcre=yes], [have_pcre=no])
1414 AS_IF([test "x$have_pcre" = xyes ], [
1415     AC_DEFINE([HAVE_PCRE], [1], [Define if libpcre2 is available])
1416 ])
1417 AM_CONDITIONAL([HAVE_PCRE], [test "x$have_pcre" = xyes])
1418
1419 AC_ARG_ENABLE([hardlink],
1420   AS_HELP_STRING([--disable-hardlink], [do not build hardlink]),
1421   [], [UL_DEFAULT_ENABLE([hardlink], [check])]
1422 )
1423 UL_BUILD_INIT([hardlink])
1424 AM_CONDITIONAL([BUILD_HARDLINK], [test "x$build_hardlink" = xyes])
1425
1426 AC_ARG_ENABLE([eject],
1427   AS_HELP_STRING([--disable-eject], [do not build eject]),
1428   [], [UL_DEFAULT_ENABLE([eject], [check])]
1429 )
1430 UL_BUILD_INIT([eject])
1431 UL_REQUIRES_LINUX([eject])
1432 UL_REQUIRES_BUILD([eject], [libmount])
1433 AM_CONDITIONAL([BUILD_EJECT], [test "x$build_eject" = xyes])
1434
1435
1436 AC_ARG_ENABLE([agetty],
1437   AS_HELP_STRING([--disable-agetty], [do not build agetty]),
1438   [], [UL_DEFAULT_ENABLE([agetty], [check])]
1439 )
1440 UL_BUILD_INIT([agetty])
1441 UL_REQUIRES_HAVE([agetty], [utmpx_h], [utmpx.h header])
1442 UL_REQUIRES_HAVE([agetty], [gnu_utmpx], [GNU utmpx functions])
1443 AM_CONDITIONAL([BUILD_AGETTY], [test "x$build_agetty" = xyes])
1444 AS_IF([test "x$have_futimens" = xyes -a "x$have_inotify_init1" = xyes ], [
1445   AC_DEFINE([AGETTY_RELOAD], [1], [Enable agetty --reload feature])
1446 ],[
1447   AC_MSG_WARN([futimens or inotify_init1 not found; agetty(8) will not provide ---reload functionality])
1448 ])
1449
1450
1451 AC_ARG_ENABLE([plymouth_support],
1452   AS_HELP_STRING([--disable-plymouth_support], [do not care about plymouth in sylogin(8) and agetty(8)]),
1453   [], [enable_plymouth_support=check]
1454 )
1455 UL_BUILD_INIT([plymouth_support])
1456 UL_REQUIRES_HAVE([plymouth_support], [tiocglcktrmios], [TIOCGLCKTRMIOS flag])
1457 UL_REQUIRES_HAVE([plymouth_support], [sock_cloexec], [SOCK_CLOEXEC flag])
1458 UL_REQUIRES_HAVE([plymouth_support], [sock_nonblock], [SOCK_NONBLOCK flag])
1459 UL_REQUIRES_HAVE([plymouth_support], [so_passcred], [SO_PASSCRED flag])
1460 AM_CONDITIONAL([USE_PLYMOUTH_SUPPORT], [test "x$build_plymouth_support" = xyes])
1461 AS_IF([test "x$build_plymouth_support" = xyes ], [
1462     AC_DEFINE([USE_PLYMOUTH_SUPPORT], [1], [Enable plymouth support feature for sulogin and aggety])
1463 ])
1464
1465
1466 AC_ARG_WITH([libz],
1467   AS_HELP_STRING([--without-libz], [compile without libz]),
1468   [], [with_libz=auto]
1469 )
1470 AS_IF([test "x$with_libz" = xno], [have_z=no], [
1471   AC_CHECK_LIB([z], [crc32], [have_z=yes], [have_z=no])
1472 ])
1473
1474
1475 AC_ARG_ENABLE([cramfs],
1476   AS_HELP_STRING([--disable-cramfs], [do not build fsck.cramfs, mkfs.cramfs]),
1477   [], [UL_DEFAULT_ENABLE([cramfs], [check])]
1478 )
1479 UL_BUILD_INIT([cramfs])
1480 UL_REQUIRES_HAVE([cramfs], [z], [z library])
1481 AM_CONDITIONAL([BUILD_CRAMFS], [test "x$build_cramfs" = xyes])
1482
1483
1484 AC_ARG_ENABLE([bfs],
1485   AS_HELP_STRING([--disable-bfs], [do not build mkfs.bfs]),
1486   [], [UL_DEFAULT_ENABLE([bfs], [yes])]
1487 )
1488 UL_BUILD_INIT([bfs])
1489 AM_CONDITIONAL([BUILD_BFS], [test "x$build_bfs" = xyes])
1490
1491
1492 AC_ARG_ENABLE([minix],
1493   AS_HELP_STRING([--disable-minix], [do not build fsck.minix, mkfs.minix]),
1494   [], [UL_DEFAULT_ENABLE([minix], [yes])]
1495 )
1496 UL_BUILD_INIT([minix])
1497 AM_CONDITIONAL([BUILD_MINIX], [test "x$build_minix" = xyes])
1498
1499
1500 AC_ARG_ENABLE([fdformat],
1501   AS_HELP_STRING([--disable-fdformat], [do not build fdformat]),
1502   [], [UL_DEFAULT_ENABLE([fdformat], [check])]
1503 )
1504 UL_BUILD_INIT([fdformat])
1505 UL_REQUIRES_LINUX([fdformat])
1506 AM_CONDITIONAL([BUILD_FDFORMAT], [test "x$build_fdformat" = xyes])
1507
1508
1509 AC_ARG_ENABLE([hwclock],
1510   AS_HELP_STRING([--disable-hwclock], [do not build hwclock]),
1511   [], [UL_DEFAULT_ENABLE([hwclock], [check])]
1512 )
1513 have_linuxdummy=$linux_os
1514
1515 UL_BUILD_INIT([hwclock])
1516 UL_REQUIRES_HAVE([hwclock], [io, linuxdummy], [ioperm iopl function or Linux])
1517 AM_CONDITIONAL([BUILD_HWCLOCK], [test "x$build_hwclock" = xyes])
1518
1519 AC_ARG_ENABLE([hwclock_cmos],
1520   AS_HELP_STRING([--disable-hwclock-cmos], [do not use CMOS clock]),
1521   [], [enable_hwclock_cmos=check]
1522 )
1523 UL_BUILD_INIT([hwclock_cmos])
1524 UL_REQUIRES_BUILD([hwclock_cmos], [hwclock])
1525 UL_REQUIRES_ARCH([hwclock_cmos], [i?86-*,x86_64*])
1526 AM_CONDITIONAL([USE_HWCLOCK_CMOS], [test "x$build_hwclock_cmos" = xyes])
1527 AS_IF([test "x$build_hwclock_cmos" = xyes ], [
1528     AC_DEFINE([USE_HWCLOCK_CMOS], [1], [Define to 1 if want to use CMOS clock.])
1529 ])
1530
1531
1532 UL_BUILD_INIT([mkfs], [yes])
1533 AM_CONDITIONAL([BUILD_MKFS], [test "x$build_mkfs" = xyes])
1534
1535 UL_BUILD_INIT([isosize], [yes])
1536 AM_CONDITIONAL([BUILD_ISOSIZE], [test "x$build_isosize" = xyes])
1537
1538
1539 UL_BUILD_INIT([fstrim], [check])
1540 UL_REQUIRES_LINUX([fstrim])
1541 UL_REQUIRES_BUILD([fstrim], [libmount])
1542 AM_CONDITIONAL([BUILD_FSTRIM], [test "x$build_fstrim" = xyes])
1543
1544
1545 UL_BUILD_INIT([swapon], [check])
1546 UL_REQUIRES_LINUX([swapon])
1547 UL_REQUIRES_SYSCALL_CHECK([swapon], [UL_CHECK_SYSCALL([swapon])], [swapon])
1548 UL_REQUIRES_SYSCALL_CHECK([swapon], [UL_CHECK_SYSCALL([swapoff])], [swapoff])
1549 UL_REQUIRES_BUILD([swapon], [libblkid])
1550 UL_REQUIRES_BUILD([swapon], [libmount])
1551 UL_REQUIRES_BUILD([swapon], [libsmartcols])
1552 AM_CONDITIONAL([BUILD_SWAPON], [test "x$build_swapon" = xyes])
1553 AC_CHECK_FUNCS([swapon])
1554 AC_CHECK_FUNCS([swapoff])
1555
1556
1557 UL_BUILD_INIT([lsblk], [check])
1558 UL_REQUIRES_LINUX([lsblk])
1559 UL_REQUIRES_BUILD([lsblk], [libblkid])
1560 UL_REQUIRES_BUILD([lsblk], [libmount])
1561 UL_REQUIRES_BUILD([lsblk], [libsmartcols])
1562 AM_CONDITIONAL([BUILD_LSBLK], [test "x$build_lsblk" = xyes])
1563
1564
1565 UL_BUILD_INIT([lscpu], [check])
1566 UL_REQUIRES_LINUX([lscpu])
1567 UL_REQUIRES_BUILD([lscpu], [libsmartcols])
1568 UL_REQUIRES_HAVE([lscpu], [cpu_set_t], [cpu_set_t type])
1569 AM_CONDITIONAL([BUILD_LSCPU], [test "x$build_lscpu" = xyes])
1570
1571
1572 AC_ARG_ENABLE([lslogins],
1573   AS_HELP_STRING([--disable-lslogins], [do not build lslogins]),
1574   [], [UL_DEFAULT_ENABLE([lslogins], [check])]
1575 )
1576 UL_BUILD_INIT([lslogins])
1577 UL_REQUIRES_BUILD([lslogins], [libsmartcols])
1578 UL_REQUIRES_HAVE([lslogins], [shadow_h], [shadow.h header])
1579 UL_REQUIRES_HAVE([lslogins], [utmpx_h], [utmpx.h header])
1580 UL_REQUIRES_HAVE([lslogins], [gnu_utmpx], [GNU utmpx functions])
1581 AM_CONDITIONAL([BUILD_LSLOGINS], [test "x$build_lslogins" = xyes])
1582
1583
1584 UL_BUILD_INIT([chcpu], [check])
1585 UL_REQUIRES_LINUX([chcpu])
1586 UL_REQUIRES_HAVE([chcpu], [cpu_set_t], [cpu_set_t type])
1587 AM_CONDITIONAL([BUILD_CHCPU], [test "x$build_chcpu" = xyes])
1588
1589
1590 AC_ARG_ENABLE([wdctl],
1591   AS_HELP_STRING([--disable-wdctl], [do not build wdctl]),
1592   [], [UL_DEFAULT_ENABLE([wdctl], [check])]
1593 )
1594 UL_BUILD_INIT([wdctl])
1595 UL_REQUIRES_LINUX([wdctl])
1596 UL_REQUIRES_BUILD([wdctl], [libsmartcols])
1597 UL_REQUIRES_HAVE([wdctl], [linux_watchdog_h], [linux/watchdog.h header file])
1598 AM_CONDITIONAL([BUILD_WDCTL], [test "x$build_wdctl" = xyes])
1599
1600
1601 UL_BUILD_INIT([swaplabel], [check])
1602 UL_REQUIRES_BUILD([swaplabel], [libblkid])
1603 AM_CONDITIONAL([BUILD_SWAPLABEL], [test "x$build_swaplabel" = xyes])
1604
1605
1606 UL_BUILD_INIT([mkswap], [yes])
1607 AM_CONDITIONAL([BUILD_MKSWAP], [test "x$build_mkswap" = xyes])
1608 AS_IF([test "x$build_mkswap" = xyes -a "x$build_libuuid" != xyes], [
1609   AC_MSG_WARN([uuid library is not found; mkswap(8) will not generate UUIDs])
1610 ])
1611
1612
1613 AC_ARG_ENABLE([cal],
1614   AS_HELP_STRING([--disable-cal], [do not build cal]),
1615   [], [UL_DEFAULT_ENABLE([cal], [check])]
1616 )
1617 UL_BUILD_INIT([cal])
1618 AM_CONDITIONAL([BUILD_CAL], [test "x$build_cal" = xyes])
1619
1620 AC_ARG_ENABLE([logger],
1621   AS_HELP_STRING([--disable-logger], [do not build logger]),
1622   [], [UL_DEFAULT_ENABLE([logger], [check])]
1623 )
1624 UL_BUILD_INIT([logger])
1625 AM_CONDITIONAL([BUILD_LOGGER], [test "x$build_logger" = xyes])
1626
1627 UL_BUILD_INIT([look], [yes])
1628 AM_CONDITIONAL([BUILD_LOOK], [test "x$build_look" = xyes])
1629
1630 UL_BUILD_INIT([mcookie], [yes])
1631 AM_CONDITIONAL([BUILD_MCOOKIE], [test "x$build_mcookie" = xyes])
1632
1633 UL_BUILD_INIT([namei], [yes])
1634 AM_CONDITIONAL([BUILD_NAMEI], [test "x$build_namei" = xyes])
1635
1636 matriplet="$($CC -print-multiarch 2>/dev/null || true)"
1637 if test "x$matriplet" != "x"; then
1638   AC_DEFINE_UNQUOTED([MULTIARCHTRIPLET], ["$matriplet"],
1639   ["Multi-arch triplet for whereis library search path"])
1640 fi
1641 UL_BUILD_INIT([whereis], [yes])
1642 AM_CONDITIONAL([BUILD_WHEREIS], [test "x$build_whereis" = xyes])
1643
1644 UL_BUILD_INIT([getopt], [yes])
1645 AM_CONDITIONAL([BUILD_GETOPT], [test "x$build_getopt" = xyes])
1646
1647
1648 UL_BUILD_INIT([blockdev], [check])
1649 UL_REQUIRES_LINUX([blockdev])
1650 AM_CONDITIONAL([BUILD_BLOCKDEV], [test "x$build_blockdev" = xyes])
1651
1652
1653 UL_BUILD_INIT([prlimit], [check])
1654 UL_REQUIRES_LINUX([prlimit])
1655 UL_REQUIRES_BUILD([prlimit], [libsmartcols])
1656 UL_REQUIRES_SYSCALL_CHECK([prlimit], [UL_CHECK_SYSCALL([prlimit64])], [prlimit64])
1657 AM_CONDITIONAL([BUILD_PRLIMIT], [test "x$build_prlimit" = xyes])
1658 AS_IF([test "x$build_prlimit" = xyes], [
1659   AC_CHECK_FUNCS([prlimit])
1660 ])
1661
1662
1663 UL_BUILD_INIT([lslocks], [check])
1664 UL_REQUIRES_LINUX([lslocks])
1665 UL_REQUIRES_BUILD([lslocks], [libmount])
1666 UL_REQUIRES_BUILD([lslocks], [libsmartcols])
1667 AM_CONDITIONAL([BUILD_LSLOCKS], [test "x$build_lslocks" = xyes])
1668
1669
1670 AC_ARG_ENABLE([switch_root],
1671   AS_HELP_STRING([--disable-switch_root], [do not build switch_root]),
1672   [], [UL_DEFAULT_ENABLE([switch_root], [check])]
1673 )
1674 UL_BUILD_INIT([switch_root])
1675 UL_REQUIRES_LINUX([switch_root])
1676 UL_REQUIRES_HAVE([switch_root], [openat], [openat function])
1677 UL_REQUIRES_HAVE([switch_root], [dirfd,ddfd], [dirfd or ddfd function])
1678 AM_CONDITIONAL([BUILD_SWITCH_ROOT], [test "x$build_switch_root" = xyes])
1679
1680
1681 AC_ARG_ENABLE([pivot_root],
1682   AS_HELP_STRING([--disable-pivot_root], [do not build pivot_root]),
1683   [], [UL_DEFAULT_ENABLE([pivot_root], [check])]
1684 )
1685 UL_BUILD_INIT([pivot_root])
1686 UL_REQUIRES_LINUX([pivot_root])
1687 UL_REQUIRES_SYSCALL_CHECK([pivot_root], [UL_CHECK_SYSCALL([pivot_root])])
1688 AM_CONDITIONAL([BUILD_PIVOT_ROOT], [test "x$build_pivot_root" = xyes])
1689
1690
1691 UL_BUILD_INIT([flock], [check])
1692 UL_REQUIRES_HAVE([flock], [timer], [timer_create/setitimer function])
1693 AM_CONDITIONAL([BUILD_FLOCK], [test "x$build_flock" = xyes])
1694
1695
1696 AC_ARG_ENABLE([lsmem],
1697   AS_HELP_STRING([--disable-lsmem], [do not build lsmem]),
1698   [], [UL_DEFAULT_ENABLE([lsmem], [check])]
1699 )
1700 UL_BUILD_INIT([lsmem])
1701 UL_REQUIRES_LINUX([lsmem])
1702 UL_REQUIRES_BUILD([lsmem], [libsmartcols])
1703 AM_CONDITIONAL([BUILD_LSMEM], [test "x$build_lsmem" = xyes])
1704
1705
1706 AC_ARG_ENABLE([chmem],
1707   AS_HELP_STRING([--disable-chmem], [do not build chmem]),
1708   [], [UL_DEFAULT_ENABLE([chmem], [check])]
1709 )
1710 UL_BUILD_INIT([chmem])
1711 UL_REQUIRES_LINUX([chmem])
1712 AM_CONDITIONAL([BUILD_CHMEM], [test "x$build_chmem" = xyes])
1713
1714 UL_BUILD_INIT([ipcmk], [yes])
1715 AM_CONDITIONAL([BUILD_IPCMK], [test "x$build_ipcmk" = xyes])
1716
1717
1718 AC_ARG_ENABLE([ipcrm],
1719   AS_HELP_STRING([--disable-ipcrm], [do not build ipcrm]),
1720   [], [UL_DEFAULT_ENABLE([ipcrm], [yes])]
1721 )
1722 UL_BUILD_INIT([ipcrm])
1723 AM_CONDITIONAL([BUILD_IPCRM], [test "x$build_ipcrm" = xyes])
1724
1725 AC_ARG_ENABLE([ipcs],
1726   AS_HELP_STRING([--disable-ipcs], [do not build ipcs]),
1727   [], [UL_DEFAULT_ENABLE([ipcs], [yes])]
1728 )
1729 UL_BUILD_INIT([ipcs])
1730 AM_CONDITIONAL([BUILD_IPCS], [test "x$build_ipcs" = xyes])
1731
1732 UL_BUILD_INIT([choom], [check])
1733 UL_REQUIRES_LINUX([choom])
1734 AM_CONDITIONAL([BUILD_CHOOM], [test "x$build_choom" = xyes])
1735
1736 UL_BUILD_INIT([lsipc], [check])
1737 UL_REQUIRES_LINUX([lsipc])
1738 UL_REQUIRES_BUILD([lsipc], [libsmartcols])
1739 AM_CONDITIONAL([BUILD_LSIPC], [test "x$build_lsipc" = xyes])
1740
1741 UL_BUILD_INIT([lsns], [check])
1742 UL_REQUIRES_LINUX([lsns])
1743 UL_REQUIRES_BUILD([lsns], [libsmartcols])
1744 UL_REQUIRES_BUILD([lsns], [libmount])
1745 AM_CONDITIONAL([BUILD_LSNS], [test "x$build_lsns" = xyes])
1746
1747 UL_BUILD_INIT([renice], [yes])
1748 AM_CONDITIONAL([BUILD_RENICE], [test "x$build_renice" = xyes])
1749
1750
1751 AC_ARG_ENABLE([rfkill],
1752   AS_HELP_STRING([--disable-rfkill], [do not build rfkill]),
1753   [], [UL_DEFAULT_ENABLE([rfkill], [check])]
1754 )
1755 UL_BUILD_INIT([rfkill])
1756 UL_REQUIRES_LINUX([rfkill])
1757 UL_REQUIRES_BUILD([rfkill], [libsmartcols])
1758 AM_CONDITIONAL([BUILD_RFKILL], [test "x$build_rfkill" = xyes])
1759
1760
1761 UL_BUILD_INIT([setsid], [yes])
1762 AM_CONDITIONAL([BUILD_SETSID], [test "x$build_setsid" = xyes])
1763
1764 UL_BUILD_INIT([readprofile], [check])
1765 UL_REQUIRES_LINUX([readprofile])
1766 AM_CONDITIONAL([BUILD_READPROFILE], [test "x$build_readprofile" = xyes])
1767
1768 UL_BUILD_INIT([dmesg], [check])
1769 UL_REQUIRES_LINUX([dmesg])
1770 AM_CONDITIONAL([BUILD_DMESG], [test "x$build_dmesg" = xyes])
1771
1772 UL_BUILD_INIT([ctrlaltdel], [check])
1773 UL_REQUIRES_LINUX([ctrlaltdel])
1774 dnl we assume reboot() to be the 1-argument variant, because even considering
1775 dnl widely used alternative C libraries like uclibc, dietlibc and musl,
1776 dnl reboot() with multiple arguments is yet only found in glibc versions
1777 dnl earlier than 2.x.
1778 UL_REQUIRES_HAVE([ctrlaltdel], [reboot], [reboot function])
1779 AM_CONDITIONAL([BUILD_CTRLALTDEL], [test "x$build_ctrlaltdel" = xyes])
1780
1781 UL_BUILD_INIT([fincore], [check])
1782 UL_REQUIRES_LINUX([fincore])
1783 UL_REQUIRES_BUILD([fincore], [libsmartcols])
1784 AM_CONDITIONAL([BUILD_FINCORE], [test "x$build_fincore" = xyes])
1785
1786 UL_BUILD_INIT([fsfreeze], [check])
1787 UL_REQUIRES_LINUX([fsfreeze])
1788 AM_CONDITIONAL([BUILD_FSFREEZE], [test "x$build_fsfreeze" = xyes])
1789
1790 UL_BUILD_INIT([blkdiscard], [check])
1791 UL_REQUIRES_LINUX([blkdiscard])
1792 AM_CONDITIONAL([BUILD_BLKDISCARD], [test "x$build_blkdiscard" = xyes])
1793
1794 UL_BUILD_INIT([blkzone], [check])
1795 UL_REQUIRES_LINUX([blkzone])
1796 UL_REQUIRES_HAVE([blkzone], [linux_blkzoned_h], [linux/blkzoned.h header])
1797 AM_CONDITIONAL([BUILD_BLKZONE], [test "x$build_blkzone" = xyes])
1798
1799 UL_BUILD_INIT([ldattach], [check])
1800 UL_REQUIRES_LINUX([ldattach])
1801 AM_CONDITIONAL([BUILD_LDATTACH], [test "x$build_ldattach" = xyes])
1802
1803 UL_BUILD_INIT([rtcwake], [check])
1804 UL_REQUIRES_LINUX([rtcwake])
1805 AM_CONDITIONAL([BUILD_RTCWAKE], [test "x$build_rtcwake" = xyes])
1806
1807 UL_BUILD_INIT([setarch], [check])
1808 UL_REQUIRES_LINUX([setarch])
1809 AM_CONDITIONAL([BUILD_SETARCH], [test "x$build_setarch" = xyes])
1810
1811 UL_BUILD_INIT([script], [check])
1812 UL_REQUIRES_HAVE([script], [sys_signalfd_h], [sys/signalfd.h header])
1813 AM_CONDITIONAL([BUILD_SCRIPT], [test "x$build_script" = xyes])
1814
1815 UL_BUILD_INIT([scriptreplay], [yes])
1816 AM_CONDITIONAL([BUILD_SCRIPTREPLAY], [test "x$build_scriptreplay" = xyes])
1817
1818 UL_BUILD_INIT([col], [yes])
1819 AM_CONDITIONAL([BUILD_COL], [test "x$build_col" = xyes])
1820
1821 UL_BUILD_INIT([colcrt], [yes])
1822 AM_CONDITIONAL([BUILD_COLCRT], [test "x$build_colcrt" = xyes])
1823
1824 UL_BUILD_INIT([colrm], [yes])
1825 AM_CONDITIONAL([BUILD_COLRM], [test "x$build_colrm" = xyes])
1826
1827 UL_BUILD_INIT([column], [check])
1828 UL_REQUIRES_BUILD([column], [libsmartcols])
1829 AM_CONDITIONAL([BUILD_COLUMN], [test "x$build_column" = xyes])
1830
1831 UL_BUILD_INIT([hexdump], [yes])
1832 AM_CONDITIONAL([BUILD_HEXDUMP], [test "x$build_hexdump" = xyes])
1833
1834 UL_BUILD_INIT([rev], [yes])
1835 AM_CONDITIONAL([BUILD_REV], [test "x$build_rev" = xyes])
1836
1837
1838 AC_ARG_ENABLE([tunelp],
1839   AS_HELP_STRING([--enable-tunelp], [build tunelp]),
1840   [], [UL_DEFAULT_ENABLE([tunelp], [no])]
1841 )
1842 UL_BUILD_INIT([tunelp])
1843 UL_REQUIRES_LINUX([tunelp])
1844 AM_CONDITIONAL([BUILD_TUNELP], [test "x$build_tunelp" = xyes])
1845
1846
1847 AC_ARG_ENABLE([kill],
1848   AS_HELP_STRING([--disable-kill], [do not build kill]),
1849   [], [UL_DEFAULT_ENABLE([kill], [check])]
1850 )
1851 UL_BUILD_INIT([kill])
1852 UL_REQUIRES_LINUX([kill])
1853 AM_CONDITIONAL([BUILD_KILL], [test "x$build_kill" = xyes])
1854
1855
1856 AC_ARG_ENABLE([last],
1857   AS_HELP_STRING([--disable-last], [do not build last]),
1858   [], [UL_DEFAULT_ENABLE([last], [check])]
1859 )
1860 UL_BUILD_INIT([last])
1861 UL_REQUIRES_HAVE([last], [utmpx_h], [utmpx.h header])
1862 UL_REQUIRES_HAVE([last], [gnu_utmpx], [GNU utmpx functions])
1863 AM_CONDITIONAL([BUILD_LAST], [test "x$build_last" = xyes])
1864
1865
1866 AC_ARG_ENABLE([utmpdump],
1867   AS_HELP_STRING([--disable-utmpdump], [do not build utmpdump]),
1868   [], [UL_DEFAULT_ENABLE([utmpdump], [check])]
1869 )
1870 UL_BUILD_INIT([utmpdump])
1871 UL_REQUIRES_HAVE([utmpdump], [utmpx_h], [utmpx.h header])
1872 UL_REQUIRES_HAVE([utmpdump], [gnu_utmpx], [GNU utmpx functions])
1873 AM_CONDITIONAL([BUILD_UTMPDUMP], [test "x$build_utmpdump" = xyes])
1874
1875
1876 AC_ARG_ENABLE([line],
1877   AS_HELP_STRING([--enable-line], [build line]),
1878   [], [UL_DEFAULT_ENABLE([line], [no])]
1879 )
1880 UL_BUILD_INIT([line])
1881 AM_CONDITIONAL([BUILD_LINE], [test "x$build_line" = xyes])
1882
1883
1884 AC_ARG_ENABLE([mesg],
1885   AS_HELP_STRING([--disable-mesg], [do not build mesg]),
1886   [], [UL_DEFAULT_ENABLE([mesg], [yes])]
1887 )
1888 UL_BUILD_INIT([mesg])
1889 AM_CONDITIONAL([BUILD_MESG], [test "x$build_mesg" = xyes])
1890
1891
1892 AC_ARG_ENABLE([raw],
1893   AS_HELP_STRING([--disable-raw], [do not build raw]),
1894   [], [UL_DEFAULT_ENABLE([raw], [check])]
1895 )
1896 UL_BUILD_INIT([raw])
1897 UL_REQUIRES_LINUX([raw])
1898 UL_REQUIRES_HAVE([raw], [linux_raw_h], [raw.h header file])
1899 AM_CONDITIONAL([BUILD_RAW], [test "x$build_raw" = xyes])
1900
1901
1902 AC_ARG_ENABLE([rename],
1903   AS_HELP_STRING([--disable-rename], [do not build rename]),
1904   [], [UL_DEFAULT_ENABLE([rename], [yes])]
1905 )
1906 UL_BUILD_INIT([rename])
1907 AM_CONDITIONAL([BUILD_RENAME], [test "x$build_rename" = xyes])
1908
1909
1910 AC_ARG_ENABLE([vipw],
1911   AS_HELP_STRING([--enable-vipw], [build vipw]),
1912   [], [UL_DEFAULT_ENABLE([vipw], [no])]
1913 )
1914 UL_BUILD_INIT([vipw])
1915 UL_REQUIRES_HAVE([vipw], [shadow_h], [shadow.h header])
1916 AM_CONDITIONAL([BUILD_VIPW], [test "x$build_vipw" = xyes])
1917
1918
1919 AC_ARG_ENABLE([newgrp],
1920   AS_HELP_STRING([--enable-newgrp], [build newgrp]),
1921   [], [UL_DEFAULT_ENABLE([newgrp], [no])]
1922 )
1923 UL_BUILD_INIT([newgrp])
1924 UL_REQUIRES_HAVE([newgrp], [crypt], [crypt function])
1925 AM_CONDITIONAL([BUILD_NEWGRP], [test "x$build_newgrp" = xyes])
1926
1927
1928 AC_ARG_WITH([user], AS_HELP_STRING([--without-user], [compile without libuser (remote chsh)]),
1929   [], [with_user=check]
1930 )
1931 have_user=no
1932 AS_IF([test "x$with_user" != xno], [
1933   PKG_CHECK_MODULES(LIBUSER,[libuser >= 0.58], [have_user=yes], [have_user=no])
1934   AS_CASE([$with_user:$have_user],
1935     [yes:no],
1936       [AC_MSG_ERROR([user selected but libuser not found])],
1937     [*:yes],
1938       [AC_DEFINE([HAVE_LIBUSER], [1], [Define if libuser is available])]
1939   )
1940   # temporary solution, libuser has stupid .pc where are exported all
1941   # private dependencies to Requires: instead of Requires.private:
1942   AS_IF([test "x$have_user" = xyes], [
1943     LIBUSER_LIBS=-luser
1944   ])
1945 ])
1946 AM_CONDITIONAL([HAVE_USER], [test "x$have_user" = xyes])
1947
1948 AC_ARG_ENABLE([chfn-chsh-password],
1949   AS_HELP_STRING([--disable-chfn-chsh-password], [do not require the user to enter the password in chfn and chsh]),
1950   [], [enable_chfn_chsh_password=yes]
1951 )
1952
1953 AC_ARG_ENABLE([chfn-chsh],
1954   AS_HELP_STRING([--enable-chfn-chsh], [build chfn and chsh]),
1955   [], [UL_DEFAULT_ENABLE([chfn_chsh], [check])]
1956 )
1957 UL_BUILD_INIT([chfn_chsh])
1958 UL_REQUIRES_HAVE([chfn_chsh], [shadow_h], [shadow.h header])
1959 UL_REQUIRES_HAVE([chfn_chsh], [getusershell], [getusershell function])
1960
1961 AS_IF([test "x$enable_chfn_chsh_password" = xyes -o "x$have_user" = xyes], [
1962   UL_REQUIRES_HAVE([chfn_chsh], [security_pam_appl_h], [PAM header file])
1963   AC_DEFINE([CHFN_CHSH_PASSWORD], [1], [Should chfn and chsh require the user to enter the password?])
1964 ])
1965 AM_CONDITIONAL([BUILD_CHFN_CHSH], [test "x$build_chfn_chsh" = xyes])
1966 AM_CONDITIONAL([CHFN_CHSH_PASSWORD], [test "x$enable_chfn_chsh_password" = xyes])
1967
1968 AC_ARG_ENABLE([chsh-only-listed],
1969   AS_HELP_STRING([--disable-chsh-only-listed], [chsh: allow shells not in /etc/shells]),
1970   [], enable_chsh_only_listed=yes
1971 )
1972
1973 AS_IF([test "x$enable_chsh_only_listed" = xyes], [
1974   AC_DEFINE([ONLY_LISTED_SHELLS], [1], [Should chsh allow only shells in /etc/shells?])
1975 ])
1976
1977
1978 AC_ARG_ENABLE([login],
1979   AS_HELP_STRING([--disable-login], [do not build login]),
1980   [], [UL_DEFAULT_ENABLE([login], [check])]
1981 )
1982 UL_BUILD_INIT([login])
1983 UL_REQUIRES_HAVE([login], [security_pam_appl_h], [PAM header file])
1984 UL_REQUIRES_HAVE([login], [security_pam_misc_h, security_openpam_h], [PAM conversation functions])
1985 UL_REQUIRES_HAVE([login], [utmpx_h], [utmpx.h header])
1986 UL_REQUIRES_HAVE([login], [gnu_utmpx], [GNU utmpx functions])
1987 AM_CONDITIONAL([BUILD_LOGIN], [test "x$build_login" = xyes])
1988
1989 AC_ARG_ENABLE([login-chown-vcs],
1990   AS_HELP_STRING([--enable-login-chown-vcs], [let login chown /dev/vcsN]),
1991   [], [enable_login_chown_vcs=no]
1992 )
1993
1994 AS_IF([test "x$enable_login_chown_vcs" = xyes], [
1995   AC_DEFINE([LOGIN_CHOWN_VCS], [1], [Should login chown /dev/vcsN?])
1996 ])
1997
1998 AC_ARG_ENABLE([login-stat-mail],
1999   AS_HELP_STRING([--enable-login-stat-mail], [let login stat() the mailbox]),
2000   [], [enable_login_stat_mail=no]
2001 )
2002
2003 AS_IF([test "x$enable_login_stat_mail" = xyes], [
2004   AC_DEFINE([LOGIN_STAT_MAIL], [1], [Should login stat() the mailbox?])
2005 ])
2006
2007
2008 AC_ARG_ENABLE([nologin],
2009   AS_HELP_STRING([--disable-nologin], [do not build nologin]),
2010   [], [UL_DEFAULT_ENABLE([nologin], [yes])]
2011 )
2012 UL_BUILD_INIT([nologin])
2013 AM_CONDITIONAL([BUILD_NOLOGIN], [test "x$build_nologin" = xyes])
2014
2015
2016 AC_ARG_ENABLE([sulogin],
2017   AS_HELP_STRING([--disable-sulogin], [do not build sulogin]),
2018   [], [UL_DEFAULT_ENABLE([sulogin], [check])]
2019 )
2020 UL_BUILD_INIT([sulogin])
2021 UL_REQUIRES_HAVE([sulogin], [crypt], [crypt function])
2022 UL_REQUIRES_HAVE([sulogin], [shadow_h], [shadow.h header])
2023 AM_CONDITIONAL([BUILD_SULOGIN], [test "x$build_sulogin" = xyes])
2024
2025
2026 AC_ARG_ENABLE([su],
2027   AS_HELP_STRING([--disable-su], [do not build su]),
2028   [], [UL_DEFAULT_ENABLE([su], [check])]
2029 )
2030 UL_BUILD_INIT([su])
2031 UL_REQUIRES_HAVE([su], [security_pam_appl_h], [PAM header file])
2032 UL_REQUIRES_HAVE([su], [utmpx_h], [utmpx.h header])
2033 UL_REQUIRES_HAVE([su], [gnu_utmpx], [GNU utmpx functions])
2034 AM_CONDITIONAL([BUILD_SU], [test "x$build_su" = xyes])
2035
2036
2037 AC_ARG_ENABLE([runuser],
2038   AS_HELP_STRING([--disable-runuser], [do not build runuser]),
2039   [], [UL_DEFAULT_ENABLE([runuser], [check])]
2040 )
2041 UL_BUILD_INIT([runuser])
2042 UL_REQUIRES_HAVE([runuser], [security_pam_appl_h], [PAM header file])
2043 UL_REQUIRES_HAVE([runuser], [utmpx_h], [utmpx.h header])
2044 UL_REQUIRES_HAVE([runuser], [gnu_utmpx], [GNU utmpx functions])
2045 AM_CONDITIONAL([BUILD_RUNUSER], [test "x$build_runuser" = xyes])
2046
2047
2048 AC_ARG_ENABLE([ul],
2049   AS_HELP_STRING([--disable-ul], [do not build ul]),
2050   [], [UL_DEFAULT_ENABLE([ul], [check])]
2051 )
2052 UL_BUILD_INIT([ul])
2053 UL_REQUIRES_HAVE([ul], [ncursesw, ncurses], [ncursesw or ncurses libraries])
2054 AM_CONDITIONAL([BUILD_UL], [test "x$build_ul" = xyes])
2055
2056
2057 AC_ARG_ENABLE([more],
2058   AS_HELP_STRING([--disable-more], [do not build more]),
2059   [], [UL_DEFAULT_ENABLE([more], [check])]
2060 )
2061 UL_BUILD_INIT([more])
2062 UL_REQUIRES_HAVE([more], [ncursesw, ncurses], [ncursesw or ncurses libraries])
2063 AM_CONDITIONAL([BUILD_MORE], [test "x$build_more" = xyes])
2064
2065
2066 AC_ARG_ENABLE([pg],
2067   AS_HELP_STRING([--enable-pg], [build pg]),
2068   [], [UL_DEFAULT_ENABLE([pg], [no])]
2069 )
2070 UL_BUILD_INIT([pg])
2071 UL_REQUIRES_HAVE([pg], [ncursesw, ncurses], [ncursesw or ncurses library])
2072 AM_CONDITIONAL([BUILD_PG], [test "x$build_pg" = xyes])
2073
2074
2075 AC_ARG_ENABLE([setterm],
2076   AS_HELP_STRING([--disable-setterm], [do not build setterm]),
2077   [], [UL_DEFAULT_ENABLE([setterm], [check])]
2078 )
2079 UL_BUILD_INIT([setterm])
2080 UL_REQUIRES_LINUX([setterm])
2081 UL_REQUIRES_HAVE([setterm], [ncursesw, ncurses], [ncursesw or ncurses library])
2082 AM_CONDITIONAL([BUILD_SETTERM], [test "x$build_setterm" = xyes])
2083
2084 # build_schedutils= is just configure-only variable to control
2085 # ionice, taskset and chrt
2086 AC_ARG_ENABLE([schedutils],
2087   AS_HELP_STRING([--disable-schedutils], [do not build chrt, ionice, taskset]),
2088   [], [UL_DEFAULT_ENABLE([schedutils], [check])]
2089 )
2090
2091
2092 UL_ENABLE_ALIAS([ionice], [schedutils])
2093 UL_BUILD_INIT([ionice])
2094 UL_REQUIRES_SYSCALL_CHECK([ionice],
2095         [UL_CHECK_SYSCALL([ioprio_set],
2096           [alpha],      [442],
2097           [i*86],       [289],
2098           [ia64*],      [1274],
2099           [powerpc*],   [273],
2100           [s390*],      [282],
2101           [sparc*],     [196],
2102           [sh*],        [288],
2103           [x86_64*],    [251])],
2104         [ioprio_set])
2105
2106 UL_REQUIRES_SYSCALL_CHECK([ionice],
2107         [UL_CHECK_SYSCALL([ioprio_get],
2108           [alpha],      [443],
2109           [i*86],       [290],
2110           [ia64*],      [1275],
2111           [powerpc*],   [274],
2112           [s390*],      [283],
2113           [sparc*],     [218],
2114           [sh*],        [289],
2115           [x86_64*],    [252])],
2116         [ioprio_get])
2117
2118 AM_CONDITIONAL([BUILD_IONICE], [test "x$build_ionice" = xyes])
2119
2120
2121 UL_ENABLE_ALIAS([taskset], [schedutils])
2122 UL_BUILD_INIT([taskset])
2123 UL_REQUIRES_HAVE([taskset], [cpu_set_t], [cpu_set_t type])
2124 UL_REQUIRES_SYSCALL_CHECK([taskset],
2125         [UL_CHECK_SYSCALL([sched_getaffinity])],
2126         [sched_getaffinity])
2127 AM_CONDITIONAL([BUILD_TASKSET], [test "x$build_taskset" = xyes])
2128
2129
2130 have_schedsetter=no
2131 AS_IF([test "x$ac_cv_func_sched_setscheduler" = xyes], [have_schedsetter=yes],
2132       [test "x$ac_cv_func_sched_setattr" = xyes], [have_schedsetter=yes])
2133
2134 UL_ENABLE_ALIAS([chrt], [schedutils])
2135 UL_BUILD_INIT([chrt])
2136 UL_REQUIRES_HAVE([chrt], [schedsetter], [sched_set functions])
2137 AM_CONDITIONAL([BUILD_CHRT], [test "x$build_chrt" = xyes])
2138
2139 AS_IF([test "x$build_chrt" = xyes], [
2140         UL_CHECK_SYSCALL([sched_setattr])
2141 ])
2142
2143
2144 AC_ARG_ENABLE([wall],
2145   AS_HELP_STRING([--disable-wall], [do not build wall]),
2146   [], [UL_DEFAULT_ENABLE([wall], [check])]
2147 )
2148 UL_BUILD_INIT([wall])
2149 UL_REQUIRES_HAVE([wall], [utmpx_h], [utmpx.h header])
2150 AM_CONDITIONAL([BUILD_WALL], [test "x$build_wall" = xyes])
2151
2152
2153 AC_ARG_ENABLE([write],
2154   AS_HELP_STRING([--enable-write], [build write]),
2155   [], [UL_DEFAULT_ENABLE([write], [no])]
2156 )
2157 UL_BUILD_INIT([write])
2158 UL_REQUIRES_HAVE([write], [utmpx_h], [utmpx.h header])
2159 UL_REQUIRES_HAVE([write], [gnu_utmpx], [GNU utmpx functions])
2160 AM_CONDITIONAL([BUILD_WRITE], [test "x$build_write" = xyes])
2161
2162
2163 AC_ARG_WITH([btrfs],
2164   AS_HELP_STRING([--without-btrfs], [do not build with btrfs support]),
2165   [], [with_btrfs=check]
2166 )
2167 have_btrfs=no
2168 AS_IF([test "x$with_btrfs" != xno], [
2169   AS_CASE([$with_btrfs:$have_linux_btrfs_h],
2170     [yes:no],
2171     [AC_MSG_ERROR([btrfs selected but linux/btrfs.h not found])],
2172     [check:no],
2173        [AC_MSG_WARN([linux/btrfs.h not found, do not build with btrfs support])],
2174     [*:yes],
2175        [have_btrfs=yes
2176         AC_DEFINE([HAVE_BTRFS_SUPPORT], [1], [Define if btrfs stuff is available])]
2177   )
2178 ])
2179 AM_CONDITIONAL([HAVE_BTRFS], [test "x$have_btrfs" = xyes])
2180
2181
2182 AC_ARG_WITH([systemd],
2183   AS_HELP_STRING([--without-systemd], [do not build with systemd support]),
2184   [], [with_systemd=check]
2185 )
2186
2187 have_systemd=no
2188 AS_IF([test "x$with_systemd" != xno], [
2189   # new version -- all libsystemd-* libs merged into libsystemd
2190   PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [have_systemd=yes], [have_systemd=no])
2191   # old versions
2192   AS_IF([test "x$have_systemd" != "xyes"], [
2193     PKG_CHECK_MODULES([SYSTEMD_DAEMON], [libsystemd-daemon],
2194                       [have_systemd_daemon=yes], [have_systemd_daemon=no])
2195     PKG_CHECK_MODULES([SYSTEMD_JOURNAL], [libsystemd-journal],
2196                       [have_systemd_journal=yes], [have_systemd_journal=no])
2197     AS_IF([test "x$have_systemd_daemon" = "xyes" -a "x$have_systemd_journal" = "xyes" ],[
2198            have_systemd=yes])
2199   ])
2200   AS_CASE([$with_systemd:$have_systemd],
2201     [yes:no],
2202       [AC_MSG_ERROR([systemd expected but libsystemd not found])],
2203     [*:yes],
2204        AC_DEFINE([HAVE_LIBSYSTEMD], [1], [Define if libsystemd is available])
2205   )
2206 ])
2207 AM_CONDITIONAL([HAVE_SYSTEMD], [test "x$have_systemd" = xyes])
2208
2209
2210 AC_ARG_WITH([systemdsystemunitdir],
2211   AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [directory for systemd unit files (requires systemd support)]),
2212   [], [with_systemdsystemunitdir=check]
2213 )
2214 AS_IF([test "x$with_systemdsystemunitdir" = xcheck], [
2215   AS_IF([test "x$have_systemd" = xyes], [
2216     with_systemdsystemunitdir=`$PKG_CONFIG --variable=systemdsystemunitdir systemd`
2217   ],[
2218     with_systemdsystemunitdir=no
2219   ])
2220 ])
2221 AS_IF([test "x$with_systemdsystemunitdir" != "xno"], [
2222   AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
2223 ])
2224
2225
2226 AC_ARG_WITH([smack],
2227   AS_HELP_STRING([--with-smack], [build with SMACK support]),
2228   [], [with_smack=no]
2229 )
2230 AS_IF([test "x$with_smack" = xyes], [
2231   AC_DEFINE([HAVE_SMACK], [1], [Add SMACK support])
2232 ])
2233
2234
2235 AC_ARG_WITH([bashcompletiondir],
2236   AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
2237   [],
2238   [AS_IF([`$PKG_CONFIG --exists bash-completion`], [
2239     with_bashcompletiondir=`$PKG_CONFIG --variable=completionsdir bash-completion`
2240   ], [
2241     with_bashcompletiondir=${datadir}/bash-completion/completions
2242   ])
2243 ])
2244 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
2245
2246 AC_ARG_ENABLE([bash-completion],
2247   AS_HELP_STRING([--disable-bash-completion], [do not install bash completion files]),
2248   [], [enable_bash_completion=yes]
2249 )
2250
2251 AM_CONDITIONAL([BUILD_BASH_COMPLETION], [test "x$enable_bash_completion" = xyes])
2252
2253
2254 AC_ARG_WITH([python],
2255   AS_HELP_STRING([--without-python], [do not build python bindings, use --with-python={2,3} to force version]),
2256   [], [with_python=check withval=check]
2257 )
2258
2259 have_python=no
2260 have_libpython=no
2261 AS_IF([test "x$with_python" != xno], [
2262   # We follow distributions default and look for PKG module name "python"
2263   # (minimal version is 2) but if major version is explicitly specified by
2264   # --with-python=2 or --with-python=3 then we look for PKG module "python2" or
2265   # "python3".
2266   AS_IF([test "x$withval" != xno -a "x$withval" != xyes -a "x$withval" != xcheck],
2267         [pymajor="$withval"; PYTHON=python${pymajor}], [pymajor="2"])
2268
2269   # check for python interpreter
2270   AM_PATH_PYTHON([$pymajor], [have_python=yes], [have_python=no])
2271   AS_CASE([$with_python:$have_python],
2272     [yes:no],
2273       [AC_MSG_ERROR([python selected but python interpreter not found])],
2274     [check:no],
2275        [AC_MSG_WARN([python interpreter not found, do not build python bindings])],
2276     [*:yes],
2277        # check for python development stuff
2278        [PKG_CHECK_MODULES([PYTHON], [python-$PYTHON_VERSION],
2279                           [have_libpython=yes], [have_libpython=no])]
2280   )
2281 ])
2282
2283
2284 AC_ARG_ENABLE([pylibmount],
2285   AS_HELP_STRING([--disable-pylibmount], [do not build pylibmount]),
2286   [], [UL_DEFAULT_ENABLE([pylibmount], [check])]
2287 )
2288 UL_BUILD_INIT([pylibmount])
2289 UL_REQUIRES_HAVE([pylibmount], [libpython], [libpython])
2290 UL_REQUIRES_BUILD([pylibmount], [libmount])
2291 AM_CONDITIONAL([BUILD_PYLIBMOUNT], [test "x$build_pylibmount" = "xyes"])
2292
2293 # We need to introduce a verbatim dependency into the Makefile, without automake
2294 # trying to interpret it, so push it as a AM_SUBST_NOTMAKE variable.
2295 verbatim_pylibmount_dependency='
2296
2297 # pylibmountexec module must be installed after usrlib_exec libraries,
2298 # otherwise the libtool relink step will fail to find libmount.la and
2299 # will try -lmount which is possibly not available.
2300 install-pylibmountexecLTLIBRARIES: install-usrlib_execLTLIBRARIES
2301
2302 '
2303 AC_SUBST([verbatim_pylibmount_dependency])
2304 AM_SUBST_NOTMAKE([verbatim_pylibmount_dependency])
2305
2306 AC_ARG_ENABLE([pg-bell],
2307   AS_HELP_STRING([--disable-pg-bell], [let pg not ring the bell on invalid keys]),
2308   [], [enable_pg_bell=yes]
2309 )
2310
2311 AS_IF([test "x$enable_pg_bell" = xyes], [
2312   AC_DEFINE([PG_BELL], [1], [Should pg ring the bell on invalid keys?])
2313 ])
2314
2315
2316 AC_DEFUN([FS_PATHS_DEFAULT], [/sbin:/sbin/fs.d:/sbin/fs])
2317 AC_ARG_ENABLE([fs-paths-default],
2318   AS_HELP_STRING([--enable-fs-paths-default=paths], [default search path for fs helpers @<:@FS_PATHS_DEFAULT@:>@]),
2319   [AS_CASE([$enableval],
2320     [yes], [fs_paths_defaults="FS_PATHS_DEFAULT"],
2321     [no],  [fs_paths_defaults=""],
2322     [fs_paths_defaults="$enableval"]
2323   )],
2324   [fs_paths_defaults="FS_PATHS_DEFAULT"]
2325 )
2326 AC_ARG_ENABLE([fs-paths-extra],
2327   AS_HELP_STRING([--enable-fs-paths-extra=paths], [additional search paths for fs helpers]),
2328   [AS_CASE([$enableval],
2329      [yes|no], [fs_paths_extra=""],
2330      [fs_paths_extra="$enableval"]
2331   )],
2332   [fs_paths_extra=""]
2333 )
2334 fs_paths="$fs_paths_defaults"
2335 AS_IF([test "x$fs_paths_extra" != "x"], [
2336   AS_IF([test "x$fs_paths" != "x"], [
2337     fs_paths="${fs_paths}:"
2338   ])
2339   fs_paths="${fs_paths}${fs_paths_extra}"
2340 ])
2341 AC_DEFINE_UNQUOTED([FS_SEARCH_PATH], "$fs_paths", [search path for fs helpers])
2342
2343
2344 AC_ARG_ENABLE([use-tty-group],
2345   AS_HELP_STRING([--disable-use-tty-group], [do not install wall and write setgid tty]),
2346   [], [enable_use_tty_group=yes]
2347 )
2348 AM_CONDITIONAL([USE_TTY_GROUP], [test "x$enable_use_tty_group" = xyes])
2349
2350 AS_IF([test "x$enable_use_tty_group" = xyes], [
2351   AC_DEFINE([USE_TTY_GROUP], [1], [Should wall and write be installed setgid tty?])
2352 ])
2353
2354
2355 AC_ARG_ENABLE([sulogin-emergency-mount],
2356   AS_HELP_STRING([--enable-sulogin-emergency-mount],
2357                  [use emergency mount of /dev and /proc for sulogin]),
2358   [], [enable_sulogin_emergency_mount=no]
2359 )
2360
2361 AS_IF([test "x$enable_sulogin_emergency_mount" = xyes], [
2362   AC_DEFINE([USE_SULOGIN_EMERGENCY_MOUNT], [1],
2363             [Should sulogin use a emergency mount of /dev and /proc?])
2364 ])
2365
2366
2367 AC_ARG_ENABLE([usrdir-path],
2368   AS_HELP_STRING([--enable-usrdir-path], [use only /usr paths in PATH env. variable (recommended on systems with /bin -> /usr/bin symlinks)]),
2369   [], [enable_usrdir_path=no]
2370 )
2371
2372 AS_IF([test "x$enable_usrdir_path" = xyes], [
2373   AC_DEFINE([USE_USRDIR_PATHS_ONLY], [1], [Define to 1 to remove /bin and /sbin from PATH env.variable])
2374 ])
2375
2376
2377 AC_ARG_ENABLE([makeinstall-chown],
2378   AS_HELP_STRING([--disable-makeinstall-chown], [do not do chown-like operations during "make install"]),
2379   [], [enable_makeinstall_chown=yes]
2380 )
2381 AM_CONDITIONAL([MAKEINSTALL_DO_CHOWN], [test "x$enable_makeinstall_chown" = xyes])
2382
2383
2384 AC_ARG_ENABLE([makeinstall-setuid],
2385   AS_HELP_STRING([--disable-makeinstall-setuid], [do not do setuid chmod operations during "make install"]),
2386   [], [enable_makeinstall_setuid=yes]
2387 )
2388 AM_CONDITIONAL([MAKEINSTALL_DO_SETUID], [test "x$enable_makeinstall_setuid" = xyes])
2389
2390
2391 AC_ARG_ENABLE([colors-default],
2392   AS_HELP_STRING([--disable-colors-default], [do not colorize output from utils by default]),
2393   [], [enable_colors_default=yes]
2394 )
2395 AS_IF([test "x$enable_colors_default" = xyes], [
2396   AC_DEFINE([USE_COLORS_BY_DEFAULT], [1], [Enables colorized output from utils by default])
2397 ])
2398
2399
2400 AC_ARG_VAR([SUID_CFLAGS],
2401            [CFLAGS used for binaries which are usually with the suid bit])
2402 AC_ARG_VAR([SUID_LDFLAGS],
2403            [LDFLAGS used for binaries which are usually with the suid bit])
2404
2405 AC_ARG_VAR([DAEMON_CFLAGS],
2406            [CFLAGS used for binaries which are usually executed as daemons])
2407 AC_ARG_VAR([DAEMON_LDFLAGS],
2408            [LDFLAGS used for binaries which are usually executed as daemons])
2409
2410 AC_ARG_VAR([SOLIB_CFLAGS],
2411            [CFLAGS used for shared libraries])
2412 AC_ARG_VAR([SOLIB_LDFLAGS],
2413            [LDFLAGS used for shared libraries])
2414
2415 AC_ARG_VAR([ADJTIME_PATH],
2416            [Path to hwclock adjtime file, default /etc/adjtime])
2417 AS_IF([test "x$ADJTIME_PATH" = x], [ADJTIME_PATH="/etc/adjtime"])
2418 AC_DEFINE_UNQUOTED([CONFIG_ADJTIME_PATH], "$ADJTIME_PATH", [Path to hwclock adjtime file])
2419
2420
2421 LIBS=""
2422
2423
2424 AC_CONFIG_HEADERS([config.h])
2425
2426 #
2427 # Don't use configure.ac to replace install paths! See Makefile PATHFILES for
2428 # more details.
2429 #
2430 AC_CONFIG_FILES([
2431 Makefile
2432 libblkid/docs/Makefile
2433 libblkid/docs/version.xml
2434 libblkid/src/blkid.h
2435 libfdisk/docs/Makefile
2436 libfdisk/docs/version.xml
2437 libfdisk/src/libfdisk.h
2438 libmount/docs/Makefile
2439 libmount/docs/version.xml
2440 libmount/src/libmount.h
2441 libsmartcols/docs/Makefile
2442 libsmartcols/docs/version.xml
2443 libsmartcols/src/libsmartcols.h
2444 po/Makefile.in
2445 ])
2446
2447 AC_OUTPUT
2448
2449 AC_MSG_RESULT([
2450         ${PACKAGE}  ${VERSION}
2451
2452         prefix:            ${prefix}
2453         exec prefix:       ${exec_prefix}
2454
2455         runstatedir:       ${runstatedir}
2456         bindir:            ${bindir}
2457         sbindir:           ${sbindir}
2458         libdir:            ${libdir}
2459         includedir:        ${includedir}
2460         usrbin_execdir:    ${usrbin_execdir}
2461         usrsbin_execdir:   ${usrsbin_execdir}
2462         usrlib_execdir:    ${usrlib_execdir}
2463
2464         compiler:          ${CC}
2465         cflags:            ${CFLAGS}
2466         suid cflags:       ${SUID_CFLAGS}
2467         ldflags:           ${LDFLAGS}
2468         suid ldflags:      ${SUID_LDFLAGS}
2469         ASAN enabled:      ${enable_asan}
2470
2471         Python:            ${PYTHON}
2472         Python version:    ${PYTHON_VERSION}
2473         Python libs:       ${pyexecdir}
2474
2475         Bash completions:  ${with_bashcompletiondir}
2476         Systemd support:   ${have_systemd}
2477         Systemd unitdir:   ${with_systemdsystemunitdir}
2478         Btrfs support:     ${have_btrfs}
2479         Wide-char support: ${build_widechar}
2480
2481         warnings:
2482
2483 ${WARN_CFLAGS}
2484
2485         Type 'make' or 'make <utilname>' to compile.
2486 ])