configure.ac

   1 AC_INIT([util-linux],
   2         m4_esyscmd([tools/git-version-gen .tarball-version]),
   3         [kzak@redhat.com],,
   4         [http://www.kernel.org/pub/linux/utils/util-linux/])
   5
   6
   7 AC_PREREQ([2.60])
   8
   9 AC_CONFIG_AUX_DIR([config])
  10 AC_CONFIG_MACRO_DIR([m4])
  11 dnl AC_USE_SYSTEM_EXTENSIONS must be called before any macros that run
  12 dnl the compiler (like AC_PROG_LIBTOOL) to avoid autoconf errors.
  13 AC_USE_SYSTEM_EXTENSIONS
  14 AM_INIT_AUTOMAKE([-Wall foreign 1.10 tar-pax no-dist-gzip dist-xz subdir-objects])
  15
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  17                             [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  18 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  19
  20 AC_CONFIG_SRCDIR([sys-utils/mount.c])
  21 AC_PREFIX_DEFAULT([/usr])
  22
  23 dnl version details from <major>.<minor>[-<suffix>]
  24 PACKAGE_VERSION_MAJOR=$(echo $PACKAGE_VERSION | awk -F. '{print $1}')
  25 PACKAGE_VERSION_MINOR=$(echo $PACKAGE_VERSION | awk -F. '{
  26                                                    sub("-.*","",$2); print $2}')
  27 PACKAGE_VERSION_RELEASE=$(echo $PACKAGE_VERSION | awk -F. '{
  28                      sub("-.*","",$3); print $3 ~ /^@<:@0-9@:>@+$/ ? $3 : 0}')
  29
  30 dnl libblkid version
  31 LIBBLKID_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  32 LIBBLKID_DATE="14-Jun-2019"
  33 LIBBLKID_LT_MAJOR=1
  34 LIBBLKID_LT_MINOR=1
  35 LIBBLKID_LT_MICRO=0
  36 LIBBLKID_VERSION_INFO=`expr $LIBBLKID_LT_MAJOR + $LIBBLKID_LT_MINOR`:$LIBBLKID_LT_MICRO:$LIBBLKID_LT_MINOR
  37
  38 dnl libuuid version
  39 LIBUUID_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  40 LIBUUID_LT_MAJOR=1
  41 LIBUUID_LT_MINOR=3
  42 LIBUUID_LT_MICRO=0
  43 LIBUUID_VERSION_INFO=`expr $LIBUUID_LT_MAJOR + $LIBUUID_LT_MINOR`:$LIBUUID_LT_MICRO:$LIBUUID_LT_MINOR
  44
  45 dnl libmount version
  46 LIBMOUNT_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  47 LIBMOUNT_LT_MAJOR=1
  48 LIBMOUNT_LT_MINOR=1
  49 LIBMOUNT_LT_MICRO=0
  50 LIBMOUNT_VERSION_INFO=`expr $LIBMOUNT_LT_MAJOR + $LIBMOUNT_LT_MINOR`:$LIBMOUNT_LT_MICRO:$LIBMOUNT_LT_MINOR
  51
  52 dnl libsmartcols version
  53 LIBSMARTCOLS_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  54 LIBSMARTCOLS_LT_MAJOR=1
  55 LIBSMARTCOLS_LT_MINOR=1
  56 LIBSMARTCOLS_LT_MICRO=0
  57 LIBSMARTCOLS_VERSION_INFO=`expr $LIBSMARTCOLS_LT_MAJOR + $LIBSMARTCOLS_LT_MINOR`:$LIBSMARTCOLS_LT_MICRO:$LIBSMARTCOLS_LT_MINOR
  58
  59 dnl libfdisk version
  60 LIBFDISK_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  61 LIBFDISK_LT_MAJOR=1
  62 LIBFDISK_LT_MINOR=1
  63 LIBFDISK_LT_MICRO=0
  64 LIBFDISK_VERSION_INFO=`expr $LIBFDISK_LT_MAJOR + $LIBFDISK_LT_MINOR`:$LIBFDISK_LT_MICRO:$LIBFDISK_LT_MINOR
  65
  66 # Check whether exec_prefix=/usr:
  67 AS_CASE([$exec_prefix:$prefix],
  68 [NONE:NONE | NONE:/usr | /usr:*],
  69   [AC_MSG_NOTICE([Default --exec-prefix detected.])
  70    AS_CASE([$bindir],  ['${exec_prefix}/bin'],  [bindir=/bin;   AC_MSG_NOTICE([  --bindir defaults to /bin])  ])
  71    AS_CASE([$sbindir], ['${exec_prefix}/sbin'], [sbindir=/sbin; AC_MSG_NOTICE([  --sbindir defaults to /sbin])])
  72    AS_CASE([$libdir],  ['${exec_prefix}/lib'],  [libdir=/lib;   AC_MSG_NOTICE([  --libdir defaults to /lib])  ])
  73    AS_CASE([$libdir],  ['${exec_prefix}/lib64'],[libdir=/lib64; AC_MSG_NOTICE([  --libdir defaults to /lib64])  ])
  74   ]
  75 )
  76
  77
  78 # default for old versions without $runstatedir
  79 AS_IF([test x"$runstatedir" = x], [runstatedir='${localstatedir}/run'])
  80
  81 # our default if $localstatedir unchanged
  82 AS_CASE([$localstatedir:$runstatedir],
  83  [NONE:'${localstatedir}/run' | /var:'${localstatedir}/run' | NONE:'/run' ],
  84    [runstatedir=/run; AC_MSG_NOTICE([  --runstatedir defaults to /run])]
  85 )
  86
  87 AC_SUBST([runstatedir])
  88
  89
  90 # The original default values of {bin,sbin,lib}dir
  91 usrbin_execdir='${exec_prefix}/bin'
  92 AC_SUBST([usrbin_execdir])
  93
  94 usrsbin_execdir='${exec_prefix}/sbin'
  95 AC_SUBST([usrsbin_execdir])
  96
  97 AS_CASE([$libdir],
  98  ['${exec_prefix}/'* | '${prefix}/'* | /usr/* | "${prefix}"/* ],
  99    [usrlib_execdir=$libdir],
 100  [usrlib_execdir='${exec_prefix}'$libdir]
 101 )
 102 AC_SUBST([usrlib_execdir])
 103
 104
 105 AM_PROG_CC_C_O
 106 AC_PROG_MKDIR_P
 107 AC_PROG_CC_STDC
 108 AC_PROG_YACC
 109 AC_CANONICAL_HOST
 110 AC_C_CONST
 111 AC_C_VOLATILE
 112 AC_C_BIGENDIAN
 113
 114 dnl Compiler warnings
 115 UL_WARN_ADD([-fno-common])
 116 UL_WARN_ADD([-Wall])
 117 UL_WARN_ADD([-Werror=sequence-point])
 118 UL_WARN_ADD([-Wextra])
 119 UL_WARN_ADD([-Wextra-semi])
 120 UL_WARN_ADD([-Wembedded-directive])
 121 UL_WARN_ADD([-Wmissing-declarations])
 122 UL_WARN_ADD([-Wmissing-parameter-type])
 123 UL_WARN_ADD([-Wmissing-prototypes])
 124 UL_WARN_ADD([-Wno-missing-field-initializers])
 125 UL_WARN_ADD([-Wredundant-decls])
 126 UL_WARN_ADD([-Wsign-compare])
 127 UL_WARN_ADD([-Wtype-limits])
 128 UL_WARN_ADD([-Wuninitialized])
 129 UL_WARN_ADD([-Wunused-but-set-parameter])
 130 UL_WARN_ADD([-Wunused-but-set-variable])
 131 UL_WARN_ADD([-Wunused-parameter])
 132 UL_WARN_ADD([-Wunused-result])
 133 UL_WARN_ADD([-Wunused-variable])
 134 UL_WARN_ADD([-Wnested-externs])
 135 UL_WARN_ADD([-Wpointer-arith])
 136 UL_WARN_ADD([-Wstrict-prototypes])
 137 UL_WARN_ADD([-Wformat-security])
 138 UL_WARN_ADD([-Wimplicit-function-declaration])
 139 UL_WARN_ADD([-Wdiscarded-qualifiers])
 140 AC_SUBST([WARN_CFLAGS])
 141
 142 UL_WARN_ADD([-Wno-clobbered], [BSD_WARN_CFLAGS])
 143 AC_SUBST([BSD_WARN_CFLAGS])
 144
 145 UL_WARN_ADD([-Wno-cast-function-type], [PYTHON_WARN_CFLAGS])
 146 AC_SUBST([PYTHON_WARN_CFLAGS])
 147
 148 UL_WARN_ADD([-Wno-unused-parameter], [NO_UNUSED_WARN_CFLAGS])
 149 AC_SUBST([NO_UNUSED_WARN_CFLAGS])
 150
 151
 152 AC_ARG_ENABLE([asan],
 153   AS_HELP_STRING([--enable-asan], [compile with Address Sanitizer]),
 154   [], [enable_asan=no]
 155 )
 156 AS_IF([test "x$enable_asan" = xyes], [
 157   UL_WARN_ADD([-fsanitize=address])
 158   ASAN_LDFLAGS="-fsanitize=address"
 159 ])
 160 AC_SUBST([ASAN_LDFLAGS])
 161
 162 dnl libtool-2
 163 LT_INIT
 164
 165 dnl check supported linker flags
 166 AX_CHECK_VSCRIPT
 167
 168 m4_ifndef([PKG_PROG_PKG_CONFIG],
 169   [m4_fatal([Could not locate the pkg-config autoconf
 170     macros. These are usually located in /usr/share/aclocal/pkg.m4.
 171     If your macros are in a different location, try setting the
 172     environment variable AL_OPTS="-I/other/macro/dir" before running
 173     ./autogen.sh or autoreconf again. Make sure pkg-config is installed.])])
 174 PKG_PROG_PKG_CONFIG
 175 PKG_INSTALLDIR(['${usrlib_execdir}/pkgconfig'])
 176
 177 GTK_DOC_CHECK([1.10])
 178 AC_PATH_PROG([XSLTPROC], [xsltproc])
 179
 180 linux_os=no
 181 bsd_os=no
 182 AS_CASE([${host_os}],
 183   [*linux*],
 184      [linux_os=yes],
 185   [*darwin*],
 186      [darwin_os=yes],
 187   [*bsd*],
 188      [bsd_os=yes])
 189 AM_CONDITIONAL([LINUX], [test "x$linux_os" = xyes])
 190 AM_CONDITIONAL([DARWIN], [test "x$darwin_os" = xyes])
 191 AM_CONDITIONAL([BSD], [test "x$bsd_os" = xyes])
 192
 193 AS_IF([test  "x$darwin_os" = xyes], [
 194   AC_DEFINE([_DARWIN_C_SOURCE], [1], [Enable MAP_ANON in sys/mman.h on Mac OS X])
 195 ])
 196
 197 dnl define ARCH_<NAME> conditionals
 198 UL_SET_ARCH([I86], [i?86-*])
 199 UL_SET_ARCH([86_64], [x86_64*])
 200 UL_SET_ARCH([IA64], [ia64*])
 201 UL_SET_ARCH([S390], [s390*])
 202 UL_SET_ARCH([SPARC], [sparc*])
 203 UL_SET_ARCH([PPC], [ppc*|powerpc*])
 204 UL_SET_ARCH([M68K], [m68*])
 205 UL_SET_ARCH([MIPS], [mips*])
 206 UL_SET_ARCH([HPPA], [hppa*|parisc*])
 207
 208 AC_SYS_LARGEFILE
 209 AC_HEADER_ASSERT
 210 AC_STRUCT_TIMEZONE
 211
 212 dnl Don't forget to maintain alternatively allowed versions in autogen.sh!
 213 AM_GNU_GETTEXT_VERSION([0.18.3])
 214 AM_GNU_GETTEXT([external])
 215
 216 AS_IF([test -d "$srcdir/po"], [
 217   ALL_LINGUAS=`cd $srcdir/po > /dev/null && echo *.po | sed 's/\.po//g'`
 218 ], [
 219   ALL_LINGUAS="af am ar as be bg bn_IN bn ca cs cy da de el en_GB es et eu_ES fa fi fr gl gu he hi hr hu hy id is it ja ka kn ko ku lo lt lv mk ml mr ms my nb nl nn no nso or pa pl pt_BR pt ro ru si sk sl sq sr@Latn sr sv ta te th tr uk ur vi zh_CN zh_TW zu"
 220 ])
 221
 222 AC_CHECK_HEADERS([linux/compiler.h linux/blkpg.h linux/major.h], [], [], [
 223 #ifdef HAVE_LINUX_COMPILER_H
 224 #include <linux/compiler.h>
 225 #endif
 226 ])
 227 AC_CHECK_HEADERS([ \
 228         asm/io.h \
 229         err.h \
 230         errno.h \
 231         fcntl.h \
 232         getopt.h \
 233         inttypes.h \
 234         lastlog.h \
 235         libutil.h \
 236         linux/btrfs.h \
 237         linux/cdrom.h \
 238         linux/falloc.h \
 239         linux/watchdog.h \
 240         linux/fd.h \
 241         linux/raw.h \
 242         linux/tiocl.h \
 243         linux/version.h \
 244         linux/securebits.h \
 245         linux/net_namespace.h \
 246         linux/capability.h \
 247         locale.h \
 248         mntent.h \
 249         net/if.h \
 250         net/if_dl.h \
 251         netinet/in.h \
 252         paths.h \
 253         pty.h \
 254         security/pam_appl.h \
 255         stdint.h \
 256         stdio_ext.h \
 257         stdlib.h \
 258         endian.h \
 259         byteswap.h \
 260         sys/endian.h \
 261         sys/disk.h \
 262         sys/disklabel.h \
 263         sys/file.h \
 264         sys/io.h \
 265         sys/ioccom.h \
 266         sys/ioctl.h \
 267         sys/mkdev.h \
 268         sys/mount.h \
 269         sys/param.h \
 270         sys/prctl.h \
 271         sys/resource.h \
 272         sys/signalfd.h \
 273         sys/socket.h \
 274         sys/sockio.h \
 275         sys/stat.h \
 276         sys/sysmacros.h \
 277         sys/swap.h \
 278         sys/syscall.h \
 279         sys/time.h \
 280         sys/timex.h \
 281         sys/ttydefaults.h \
 282         sys/types.h \
 283         sys/ucred.h \
 284         sys/un.h \
 285         unistd.h \
 286         shadow.h \
 287         utmp.h \
 288         utmpx.h \
 289 ])
 290
 291 # There is a collision in old kernel-headers. The both files mount.h and fs.h
 292 # define MS_* macros. Fixed by kernel commit e462ec50cb5fad19f6003a3d8087f4a0945dd2b1.
 293 #
 294 AC_CHECK_HEADERS([linux/fs.h ], [], [],
 295  [#ifdef HAVE_SYS_MOUNT_H
 296    # include <linux/fs.h>
 297    # include <sys/mount.h>
 298   #endif
 299 ])
 300
 301 AC_CHECK_HEADERS([linux/gsmmux.h ], [], [],
 302  [#ifdef LINUX_GSMMUX_H
 303    # include <linux/gsmmux.h>
 304    #endif
 305 ])
 306
 307 AC_CHECK_HEADERS([security/pam_misc.h],
 308                 [AM_CONDITIONAL([HAVE_LINUXPAM], [true])],
 309                 [AM_CONDITIONAL([HAVE_LINUXPAM], [false])], [
 310 #ifdef HAVE_SECURITY_PAM_APPL_H
 311 #include <security/pam_appl.h>
 312 #endif
 313 ])
 314
 315 AC_CHECK_HEADERS([linux/blkzoned.h])
 316
 317 AC_CHECK_HEADERS([security/openpam.h], [], [], [
 318 #ifdef HAVE_SECURITY_PAM_APPL_H
 319 #include <security/pam_appl.h>
 320 #endif
 321 ])
 322
 323 AC_CHECK_HEADERS([langinfo.h],
 324                 [AM_CONDITIONAL([HAVE_LANGINFO], [true])],
 325                 [AM_CONDITIONAL([HAVE_LANGINFO], [false])])
 326
 327 AC_MSG_CHECKING([whether langinfo.h defines ALTMON_x constants])
 328 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 329         #include <langinfo.h>
 330 ]], [[
 331         char *str;
 332         str = nl_langinfo (ALTMON_1);
 333         str = nl_langinfo (ALTMON_2);
 334         str = nl_langinfo (ALTMON_3);
 335         str = nl_langinfo (ALTMON_4);
 336         str = nl_langinfo (ALTMON_5);
 337         str = nl_langinfo (ALTMON_6);
 338         str = nl_langinfo (ALTMON_7);
 339         str = nl_langinfo (ALTMON_8);
 340         str = nl_langinfo (ALTMON_9);
 341         str = nl_langinfo (ALTMON_10);
 342         str = nl_langinfo (ALTMON_11);
 343         str = nl_langinfo (ALTMON_12);
 344 ]])], [
 345         AC_MSG_RESULT([yes])
 346         AC_DEFINE([HAVE_LANGINFO_ALTMON], [1],
 347                 [Define if langinfo.h defines ALTMON_x constants])
 348 ], [
 349         AC_MSG_RESULT([no])
 350 ])
 351
 352
 353 AC_MSG_CHECKING([whether langinfo.h defines _NL_ABALTMON_x constants])
 354 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 355         #include <langinfo.h>
 356 ]], [[
 357         char *str;
 358         str = nl_langinfo (_NL_ABALTMON_1);
 359         str = nl_langinfo (_NL_ABALTMON_2);
 360         str = nl_langinfo (_NL_ABALTMON_3);
 361         str = nl_langinfo (_NL_ABALTMON_4);
 362         str = nl_langinfo (_NL_ABALTMON_5);
 363         str = nl_langinfo (_NL_ABALTMON_6);
 364         str = nl_langinfo (_NL_ABALTMON_7);
 365         str = nl_langinfo (_NL_ABALTMON_8);
 366         str = nl_langinfo (_NL_ABALTMON_9);
 367         str = nl_langinfo (_NL_ABALTMON_10);
 368         str = nl_langinfo (_NL_ABALTMON_11);
 369         str = nl_langinfo (_NL_ABALTMON_12);
 370 ]])], [
 371         AC_MSG_RESULT([yes])
 372         AC_DEFINE([HAVE_LANGINFO_NL_ABALTMON], [1],
 373                 [Define if langinfo.h defines _NL_ABALTMON_x constants])
 374 ], [
 375         AC_MSG_RESULT([no])
 376 ])
 377
 378
 379 dnl Convert some ac_cv_header_* variables to have_*
 380 dnl
 381 have_linux_version_h=$ac_cv_header_linux_version_h
 382 have_linux_blkzoned_h=$ac_cv_header_linux_blkzoned_h
 383 have_linux_btrfs_h=$ac_cv_header_linux_btrfs_h
 384 have_linux_raw_h=$ac_cv_header_linux_raw_h
 385 have_linux_securebits_h=$ac_cv_header_linux_securebits_h
 386 have_linux_capability_h=$ac_cv_header_linux_capability_h
 387 have_linux_watchdog_h=$ac_cv_header_linux_watchdog_h
 388 have_security_pam_appl_h=$ac_cv_header_security_pam_appl_h
 389 have_security_pam_misc_h=$ac_cv_header_security_pam_misc_h
 390 have_security_openpam_h=$ac_cv_header_security_openpam_h
 391 have_shadow_h=$ac_cv_header_shadow_h
 392 have_sys_signalfd_h=$ac_cv_header_sys_signalfd_h
 393 have_utmpx_h=$ac_cv_header_utmpx_h
 394
 395 AS_CASE([$linux_os:$have_linux_version_h],
 396   [yes:no],
 397     [AC_MSG_ERROR([kernel headers required on Linux])]
 398 )
 399
 400 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 401 #include <time.h>
 402 #include <unistd.h>
 403 ]], [[
 404     int a = 0;
 405     struct tm *tm = localtime(0);
 406     if (a == -1)  /* false */
 407         sleep(tm->tm_gmtoff);
 408 ]])],
 409 [AC_DEFINE([HAVE_TM_GMTOFF], [1], [Does struct tm have a field tm_gmtoff?])
 410 ])
 411
 412 AC_CHECK_MEMBERS([struct termios.c_line],,,
 413     [[#include <termios.h>]])
 414
 415 AC_CHECK_MEMBERS([struct stat.st_mtim.tv_nsec],,,
 416         [#include <sys/stat.h>])
 417
 418 AC_CHECK_DECLS([_NL_TIME_WEEK_1STDAY],[],[],[[#include <langinfo.h>]])
 419
 420 AC_CHECK_DECL([llseek],
 421         [AC_DEFINE([HAVE_LLSEEK_PROTOTYPE], [1],
 422                         [Define to 1 if have llseek prototype])],
 423         [],
 424         [#include <unistd.h>])
 425
 426 AC_CHECK_DECL([lseek64],
 427         [AC_DEFINE([HAVE_LSEEK64_PROTOTYPE], [1],
 428                         [Define to 1 if have lseek64 prototype])],
 429         [],
 430         [#define _LARGEFILE_SOURCE
 431          #define _LARGEFILE64_SOURCE
 432          #include <unistd.h>])
 433
 434 AC_CHECK_DECL([environ],
 435         [AC_DEFINE([HAVE_ENVIRON_DECL], [1],
 436                 [Define to 1 if have **environ prototype])],
 437 )
 438
 439 AC_CHECK_DECL([strsignal],
 440         [AC_DEFINE([HAVE_STRSIGNAL_DECL], [1],
 441                 [Define to 1 if have strsignal function prototype])],
 442 )
 443
 444 AC_CHECK_DECL([TIOCGLCKTRMIOS],
 445               [have_tiocglcktrmios=yes], [have_tiocglcktrmios=no],
 446               [#include <sys/ioctl.h>])
 447 AC_CHECK_DECL([SOCK_CLOEXEC],
 448               [have_sock_cloexec=yes], [have_sock_cloexec=no],
 449               [#include <sys/types.h>
 450                #include <sys/socket.h>])
 451 AC_CHECK_DECL([SOCK_NONBLOCK],
 452               [have_sock_nonblock=yes], [have_sock_nonblock=no],
 453               [#include <sys/types.h>
 454                #include <sys/socket.h>])
 455 AC_CHECK_DECL([SO_PASSCRED],
 456               [have_so_passcred=yes], [have_so_passcred=no],
 457               [#include <sys/types.h>
 458                #include <sys/socket.h>])
 459
 460 AC_CHECK_FUNCS([ \
 461         clearenv \
 462         __fpurge \
 463         fpurge \
 464         __fpending \
 465         secure_getenv \
 466         __secure_getenv \
 467         eaccess \
 468         err \
 469         errx \
 470         explicit_bzero \
 471         fmemopen \
 472         fsync \
 473         utimensat \
 474         getdomainname \
 475         getdtablesize \
 476         getexecname \
 477         getmntinfo \
 478         getrandom \
 479         getrlimit \
 480         getsgnam \
 481         inotify_init \
 482         jrand48 \
 483         lchown \
 484         llseek \
 485         lseek64 \
 486         mempcpy \
 487         mkostemp \
 488         nanosleep \
 489         ntp_gettime \
 490         personality \
 491         posix_fadvise \
 492         prctl \
 493         qsort_r \
 494         rpmatch \
 495         scandirat \
 496         setprogname \
 497         setresgid \
 498         setresuid \
 499         sched_setattr \
 500         sched_setscheduler \
 501         sigqueue \
 502         srandom \
 503         strnchr \
 504         strndup \
 505         strnlen \
 506         sysconf \
 507         sysinfo \
 508         timegm \
 509         usleep \
 510         vwarnx \
 511         warn \
 512         warnx \
 513 ])
 514 AC_FUNC_FSEEKO
 515
 516 AC_CHECK_FUNCS([openat fstatat unlinkat], [have_openat=yes], [have_openat=no])
 517 AC_CHECK_FUNCS([ioperm iopl], [have_io=yes])
 518 AC_CHECK_FUNCS([futimens], [have_futimens=yes])
 519 AC_CHECK_FUNCS([inotify_init1], [have_inotify_init1=yes])
 520 AC_CHECK_FUNCS([open_memstream], [have_open_memstream=yes],[have_open_memstream=no])
 521 AC_CHECK_FUNCS([reboot], [have_reboot=yes],[have_reboot=no])
 522 AC_CHECK_FUNCS([updwtmpx updwtmpx], [have_gnu_utmpx=yes], [have_gnu_utmpx=no])
 523 AC_CHECK_FUNCS([getusershell], [have_getusershell=yes],[have_getusershell=no])
 524
 525 AM_CONDITIONAL([HAVE_OPENAT], [test "x$have_openat" = xyes])
 526
 527 have_setns_syscall="yes"
 528 UL_CHECK_SYSCALL([setns])
 529 AS_IF([test "x$ul_cv_syscall_setns" = xno], [
 530    have_setns_syscall="no"
 531 ])
 532
 533 AC_CHECK_FUNCS([isnan], [],
 534         [AC_CHECK_LIB([m], [isnan], [MATH_LIBS="-lm"])]
 535         [AC_CHECK_LIB([m], [__isnan], [MATH_LIBS="-lm"])]
 536 )
 537 AC_SUBST([MATH_LIBS])
 538
 539
 540 dnl lib/mononotic.c may require -lrt
 541 AC_CHECK_FUNCS([clock_gettime], [],
 542         [AC_CHECK_LIB([rt], [clock_gettime], [REALTIME_LIBS="-lrt"])]
 543 )
 544
 545 have_timer="no"
 546 AC_CHECK_FUNCS([timer_create],
 547         [have_timer="yes"],
 548         [AC_CHECK_LIB([rt], [timer_create], [
 549                 have_timer="yes"
 550                 REALTIME_LIBS="-lrt"
 551                 AC_DEFINE_UNQUOTED([HAVE_TIMER_CREATE], [1], [Define if timer_create exist in -lrt])
 552         ],[
 553                 AC_SEARCH_LIBS([timer_create], [rt], [
 554                         AC_MSG_RESULT(yes)
 555                         have_timer="yes"
 556                         REALTIME_LIBS="-lrt -lpthread"
 557                         AC_DEFINE_UNQUOTED([HAVE_TIMER_CREATE], [1], [Define if timer_create exist in -lrt -lpthread])
 558                 ],[], [-lpthread]
 559                 )
 560         ])]
 561 )
 562
 563 AC_SUBST([REALTIME_LIBS])
 564
 565 AS_IF([test x"$have_timer" = xno], [
 566        AC_CHECK_FUNCS([setitimer], [have_timer="yes"], [have_timer="no"])
 567 ])
 568
 569
 570 AC_CHECK_LIB([rtas], [rtas_get_sysparm], [
 571         RTAS_LIBS="-lrtas"
 572         AC_DEFINE_UNQUOTED([HAVE_LIBRTAS], [1], [Define if librtas exists]), [],
 573 ])
 574 AC_SUBST([RTAS_LIBS])
 575
 576
 577 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 578                 AC_DEFINE_UNQUOTED([HAVE_SA_LEN], [1], [Define if struct sockaddr contains sa_len]), [],
 579         [#include <sys/types.h>
 580          #include <sys/socket.h>])
 581
 582 SOCKET_LIBS=
 583 AC_SEARCH_LIBS([socket], [socket],
 584         [AS_IF([test x"$ac_cv_search_socket" != x"none required"],
 585                 [SOCKET_LIBS="$SOCKET_LIBS -lsocket"])
 586 ])
 587 AC_SUBST([SOCKET_LIBS])
 588
 589
 590 have_dirfd=no
 591 AC_CHECK_FUNCS([dirfd], [have_dirfd=yes], [have_dirfd=no])
 592 AS_IF([test x"$have_dirfd" = xno], [
 593         AC_CHECK_DECLS([dirfd],
 594                 [have_dirfd=yes], [have_dirfd=no],
 595                 [#include <sys/types.h>
 596                  #include <dirent.h>])
 597 ])
 598
 599 have_ddfd=no
 600 AS_IF([test x"$have_dirfd" = xno], [
 601         AC_CHECK_MEMBERS([DIR.dd_fd],
 602                 [have_ddfd=yes], [have_ddfd=no],
 603                 [#include <sys/types.h>
 604                  #include <dirent.h>])
 605 ])
 606
 607 AM_CONDITIONAL([HAVE_DIRFD], [test "x$have_dirfd" = xyes -o "x$have_ddfd" = xyes])
 608
 609
 610 AC_MSG_CHECKING([whether program_invocation_short_name is defined])
 611 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 612         #include <errno.h>
 613 ]], [[
 614         program_invocation_short_name = "test";
 615 ]])], [
 616         AC_MSG_RESULT([yes])
 617         AC_DEFINE([HAVE_PROGRAM_INVOCATION_SHORT_NAME], [1],
 618                 [Define if program_invocation_short_name is defined])
 619 ], [
 620         AC_MSG_RESULT([no])
 621 ])
 622
 623
 624 AC_MSG_CHECKING([whether __progname is defined])
 625 AC_LINK_IFELSE([AC_LANG_PROGRAM([extern char *__progname;],
 626            [if (*__progname == 0) return 1;])],
 627            AC_DEFINE([HAVE___PROGNAME], [1], [Define if __progname is defined])
 628            AC_MSG_RESULT([yes]),
 629            AC_MSG_RESULT([no]))
 630
 631 dnl Static compilation
 632 m4_define([UL_STATIC_PROGRAMS], [losetup, mount, umount, fdisk, sfdisk, blkid, nsenter, unshare])
 633
 634 AC_ARG_ENABLE([static-programs],
 635   [AS_HELP_STRING([--enable-static-programs=LIST],
 636       [link static the programs in LIST (comma-separated,
 637       supported for ]m4_defn([UL_STATIC_PROGRAMS])[)])])
 638
 639 AS_CASE([$enable_static_programs],
 640   [yes],
 641     [enable_static_programs=m4_quote(UL_STATIC_PROGRAMS)],
 642   [no],
 643     [enable_static_programs=]
 644 )
 645
 646 dnl Set all the individual AM_CONDITIONALs
 647 m4_foreach([UL_PRG], m4_defn([UL_STATIC_PROGRAMS]), [
 648   AS_CASE([,$enable_static_programs,],
 649    [*,UL_PRG,*], [static_[]UL_PRG=yes]
 650   )
 651   AS_IF([test "x$static_[]UL_PRG" = xyes], [AC_MSG_NOTICE([enable static build: UL_PRG.])])
 652   AM_CONDITIONAL([HAVE_STATIC_]m4_toupper(UL_PRG),
 653     [test "x$static_[]UL_PRG" = xyes])
 654 ])
 655
 656
 657 AC_ARG_ENABLE([all-programs],
 658   AS_HELP_STRING([--disable-all-programs], [disable everything, might be overridden by --enable-<name>]),
 659   [], [enable_all_programs=undefined]
 660 )
 661
 662 AS_CASE([$enable_all_programs],
 663   [yes], [AC_MSG_WARN([force to build all programs by default])
 664           ul_default_estate=check],
 665   [no],  [AC_MSG_WARN([disable all programs by default])
 666           ul_default_estate=no]
 667 )
 668
 669
 670 AX_CHECK_TLS
 671
 672 AC_DEFUN([UL_SCANF_TYPE_MODIFIER], [dnl
 673 # include <stdio.h>
 674 # include <stdlib.h>
 675 int main()
 676 {
 677         int i;
 678         int rc = 1;
 679         char *s;
 680         i = sscanf("x", $1, &s);
 681         if (i == 1  && *s == 'x')
 682                 rc = 0;
 683         free(s);
 684         return rc;
 685 }])
 686
 687 AC_CACHE_VAL([scanf_cv_alloc_modifier],
 688   AC_RUN_IFELSE([AC_LANG_SOURCE([UL_SCANF_TYPE_MODIFIER(["%ms"])])],
 689     [scanf_cv_alloc_modifier=ms],
 690     AC_RUN_IFELSE([AC_LANG_SOURCE([UL_SCANF_TYPE_MODIFIER(["%as"])])],
 691       [scanf_cv_alloc_modifier=as],
 692       [scanf_cv_alloc_modifier=no]
 693     )
 694     ,
 695
 696     [AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 697      #include <stdio.h>
 698      #include <unistd.h>
 699
 700      #if defined(__GLIBC__) && !defined(__UCLIBC__)
 701
 702      #if !(__GLIBC_PREREQ(2, 7))
 703      #error %m is not available
 704      #endif
 705
 706      #elif defined(_POSIX_VERSION)
 707
 708      #if _POSIX_VERSION < 200809L
 709      #error %m is not available
 710      #endif
 711
 712      #else
 713      #error Your C-library is not supported.
 714      #endif
 715      ])],
 716     [scanf_cv_alloc_modifier=ms],
 717     [scanf_cv_alloc_modifier=no])]
 718   )
 719 )
 720
 721 AC_MSG_CHECKING([scanf string alloc modifiers])
 722 AS_CASE([$scanf_cv_alloc_modifier],
 723   [ms],
 724     [AC_MSG_RESULT([(%ms) yes])
 725      AC_DEFINE([HAVE_SCANF_MS_MODIFIER], [1], [scanf %ms modifier])
 726      have_scanf_alloc_modifier=yes],
 727   [as],
 728     [AC_MSG_RESULT([(%as) yes])
 729      have_scanf_alloc_modifier=yes
 730      AC_DEFINE([HAVE_SCANF_AS_MODIFIER], [1], [scanf %as modifier])],
 731   [AC_MSG_RESULT([no])
 732    have_scanf_alloc_modifier=no]
 733 )
 734
 735
 736 AC_ARG_WITH([util], AS_HELP_STRING([--without-util], [compile without libutil]),
 737   [], [with_util=auto]
 738 )
 739 AS_IF([test "x$with_util" = xno], [
 740   AM_CONDITIONAL([HAVE_UTIL], [false])
 741   have_util=no
 742 ], [
 743   UL_CHECK_LIB([util], [openpty])
 744 ])
 745
 746
 747 AC_CHECK_TYPES([union semun], [], [], [[
 748 #include <sys/sem.h>
 749 ]])
 750 AC_CHECK_TYPES([loff_t])
 751
 752
 753 AC_ARG_ENABLE([widechar],
 754   AS_HELP_STRING([--disable-widechar], [do not compile wide character support]),
 755   [], [enable_widechar=check]
 756 )
 757 UL_BUILD_INIT([widechar])
 758 UL_REQUIRES_COMPILE([widechar], [[
 759   #include <wchar.h>
 760   #include <wctype.h>
 761   #include <stdio.h>
 762   #include <stdlib.h>
 763   ]], [[
 764     wchar_t wc;
 765     wint_t w;
 766     w = fgetwc(stdin);
 767     if (w == WEOF) exit(1);
 768     wc = w;
 769     fputwc(wc,stdout);
 770   ]],
 771   [wchar_t support])
 772
 773 AS_IF([test "x$build_widechar" = xyes ], [
 774   AC_DEFINE([HAVE_WIDECHAR], [1], [Do we have wide character support?])
 775 ])
 776
 777
 778 AC_CHECK_TYPES([cpu_set_t], [have_cpu_set_t=yes], [], [[
 779 #include <sched.h>
 780 ]])
 781
 782 AM_CONDITIONAL([HAVE_CPU_SET_T], [test "x$have_cpu_set_t" = xyes])
 783
 784 AC_CHECK_TYPES([sighandler_t], [], [], [[
 785 #include <signal.h>
 786 ]])
 787
 788 AC_CHECK_DECLS([CPU_ALLOC], [], [], [[
 789 #include <sched.h>
 790 ]])
 791
 792 # on Solaris, you can't mix and match standards, since we use c99
 793 # apparently at this stage, XOPEN_SOURCE will conflict.  As workaround,
 794 # check for crypt.h and use that without XOPEN_SOURCE.
 795 have_crypt=no
 796 AC_CHECK_HEADERS([crypt.h])
 797 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 798 #ifdef HAVE_CRYPT_H
 799 #include <crypt.h>
 800 #else
 801 #define _XOPEN_SOURCE
 802 #include <unistd.h>
 803 #endif
 804 ]], [[
 805 char *c = crypt("abc","pw");
 806 ]])],[
 807   have_libcrypt=no
 808   have_crypt=yes
 809 ],[
 810   LIBS="$LIBS -lcrypt"
 811   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 812   #ifdef HAVE_CRYPT_H
 813   #include <crypt.h>
 814   #else
 815   #define _XOPEN_SOURCE
 816   #include <unistd.h>
 817   #endif
 818   ]], [[
 819   char *c = crypt("abc","pw");
 820   ]])],[
 821   AC_DEFINE([HAVE_LIBCRYPT], [1], [Do we need -lcrypt?])
 822   have_libcrypt=yes
 823   have_crypt=yes
 824   ],[
 825   AC_MSG_WARN([crypt() is not available])
 826   ])
 827 ])
 828 AM_CONDITIONAL([HAVE_LIBCRYPT], [test "x$have_libcrypt" = xyes])
 829
 830
 831 AC_ARG_WITH([selinux],
 832   AS_HELP_STRING([--with-selinux], [compile with SELinux support]),
 833   [], [with_selinux=no]
 834 )
 835
 836 AS_IF([test "x$with_selinux" = xno], [
 837   AM_CONDITIONAL([HAVE_SELINUX], [false])
 838 ], [
 839   PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.0],
 840         [AC_DEFINE([HAVE_LIBSELINUX], [1], [Define if SELinux is available])
 841          UL_PKG_STATIC([SELINUX_LIBS_STATIC], [libselinux])
 842          AM_CONDITIONAL([HAVE_SELINUX], [true])
 843          have_selinux=yes],
 844         [have_selinux=no])
 845
 846   AS_CASE([$with_selinux:$have_selinux],
 847     [yes:no], [AC_MSG_ERROR([SELinux selected but libselinux not found or too old])]
 848   )
 849
 850   AS_IF([test "x$have_selinux" = xyes], [
 851     UL_SET_FLAGS([], [], [$SELINUX_LIBS])
 852     # This function is missing in old libselinux 1.xx versions
 853     AC_CHECK_FUNCS([security_get_initial_context])
 854     UL_RESTORE_FLAGS
 855   ])
 856 ])
 857 AC_SUBST([SELINUX_LIBS])
 858 AC_SUBST([SELINUX_LIBS_STATIC])
 859
 860
 861 AC_ARG_WITH([audit],
 862   AS_HELP_STRING([--with-audit], [compile with audit support]),
 863   [], [with_audit=no]
 864 )
 865
 866 AS_IF([test "x$with_audit" = xno], [
 867   AM_CONDITIONAL([HAVE_AUDIT], [false])
 868 ], [
 869   UL_CHECK_LIB([audit], [audit_log_user_message])
 870   AS_CASE([$with_audit:$have_audit],
 871     [yes:no],
 872       [AC_MSG_ERROR([Audit selected but libaudit not found (or does not support audit_log_user_message())])]
 873   )
 874 ])
 875
 876 AC_ARG_WITH([udev], AS_HELP_STRING([--without-udev], [compile without udev support]),
 877   [], [with_udev=auto]
 878 )
 879
 880 AS_IF([test "x$with_udev" = xno], [
 881   AM_CONDITIONAL([HAVE_UDEV], [false])
 882 ], [
 883   UL_CHECK_LIB([udev], [udev_new])
 884   AS_CASE([$with_udev:$have_udev],
 885     [yes:no],
 886       [AC_MSG_ERROR([udev selected but libudev not found])]
 887   )
 888 ])
 889
 890
 891 dnl wide-char ncurses
 892 AC_ARG_WITH([ncursesw],
 893   AS_HELP_STRING([--without-ncursesw], [do not build with wide-char ncurses]),
 894   [], [with_ncursesw=auto]
 895 )
 896 have_ncursesw=no
 897 have_ncursesw_header=no
 898 AS_IF([test "x$with_ncursesw" != xno], [
 899   UL_NCURSES_CHECK([ncursesw])
 900   AS_IF([test "x$have_ncursesw" = xyes], [
 901     AC_CHECK_HEADERS([ncursesw/ncurses.h], [have_ncursesw_header=yes])
 902     AC_CHECK_HEADERS([ncursesw/term.h])
 903
 904     # Define HAVE_NCURSES_H only if check for HAVE_NCURSESW_NCURSES_H is
 905     # unsuccessful to avoid too many *_H permitations in config.h
 906     AS_IF([test "x$have_ncursesw_header" = xno], [
 907            AC_CHECK_HEADERS([ncurses.h], [have_ncursesw_header=yes])
 908            AC_CHECK_HEADERS([term.h])
 909     ])
 910     AS_IF([test "x$have_ncursesw_header" = xno], [have_ncursesw=no])
 911   ])
 912   AS_IF([test "x$have_ncursesw" = xyes], [
 913     CURSES_LIB_NAME="ncursesw"
 914     AC_DEFINE([HAVE_LIBNCURSESW], [1], [Define if ncursesw library available])
 915   ])
 916 ])
 917 AS_CASE([$with_ncursesw:$have_ncursesw],
 918   [yes:no], [AC_MSG_ERROR([ncursesw selected, but library not found])])
 919
 920
 921 dnl non-wide ncurses
 922 AC_ARG_WITH([ncurses],
 923   AS_HELP_STRING([--with-ncurses], [build with non-wide ncurses]),
 924   [], [with_ncurses=auto]
 925 )
 926 have_ncurses=no
 927 have_ncurses_header=no
 928 AS_CASE([$with_ncurses:$build_widechar],
 929   [yes:yes], [AC_MSG_ERROR([wide-char support enabled, but non-wide ncurses selects])])
 930
 931 AS_IF([test "x$have_ncursesw" = xno -a "x$with_ncurses" != xno ], [
 932   UL_NCURSES_CHECK([ncurses])
 933   AS_IF([test "x$have_ncurses" = xyes], [
 934     AC_CHECK_HEADERS([ncurses/ncurses.h], [have_ncurses_header=yes])
 935     AC_CHECK_HEADERS([ncurses/term.h])
 936
 937     # Define HAVE_NCURSES_H only if check for HAVE_NCURSES_NCURSES_H is
 938     # unsuccessful to avoid too many *_H permitations in config.h
 939     AS_IF([test "x$have_ncurses_header" = xno], [
 940            AC_CHECK_HEADERS([ncurses.h], [have_ncurses_header=yes])
 941            AC_CHECK_HEADERS([term.h])
 942     ])
 943     AS_IF([test "x$have_ncurses_header" = xno], [have_ncurses=no])
 944   ])
 945   AS_IF([test "x$have_ncurses" = xyes], [
 946     CURSES_LIB_NAME="ncurses"
 947     AC_DEFINE([HAVE_LIBNCURSES], [1], [Define if ncurses library available])
 948   ])
 949 ])
 950 AS_CASE([$with_ncurses:$have_ncurses],
 951   [yes:no], [AC_MSG_ERROR([ncurses selected, but library not found])])
 952
 953 AC_SUBST([NCURSES_CFLAGS])
 954 AC_SUBST([NCURSES_LIBS])
 955 AM_CONDITIONAL([HAVE_NCURSES], [test "x$have_ncursesw" = xyes -o  "x$have_ncurses" = xyes])
 956
 957
 958 AC_ARG_WITH([slang],
 959   AS_HELP_STRING([--with-slang], [compile cfdisk with slang rather than ncurses]),
 960   [], [with_slang=no]
 961 )
 962 have_slang=no
 963 AS_IF([test "x$with_slang" = xyes], [
 964   AC_CHECK_HEADERS([slang.h slang/slang.h])
 965   AC_CHECK_HEADERS([slcurses.h slang/slcurses.h],
 966                    [have_slang=yes], [], [
 967 #ifdef HAVE_SLANG_H
 968 #include <slang.h>
 969 #elif defined(HAVE_SLANG_SLANG_H)
 970 #include <slang/slang.h>
 971 #endif
 972 ])
 973   AS_IF([test "x$have_slang" = xno], [
 974     AC_MSG_ERROR([slang selected but slcurses.h not found])],
 975     [CURSES_LIB_NAME=slang
 976   ])
 977 ])
 978 AM_CONDITIONAL([HAVE_SLANG], [test "x$have_slang" = xyes])
 979
 980
 981 AS_IF([test "x$have_slang" = xyes -o "x$have_ncursesw" = xyes -o "x$have_ncurses" = xyes], [
 982         AC_CHECK_LIB([$CURSES_LIB_NAME], use_default_colors, [
 983                      AC_DEFINE(HAVE_USE_DEFAULT_COLORS, 1,
 984                                [Define if curses library has the use_default_colors().])
 985         ])
 986         AC_CHECK_LIB([$CURSES_LIB_NAME], resizeterm, [
 987                      AC_DEFINE(HAVE_RESIZETERM, 1,
 988                                [Define if curses library has the resizeterm().])
 989         ])
 990 ])
 991
 992
 993 AC_ARG_WITH([tinfo], AS_HELP_STRING([--without-tinfo], [compile without libtinfo]),
 994   [], [with_tinfo=auto]
 995 )
 996 have_tinfo=no
 997 have_tinfow=no
 998 AS_IF([test "x$with_tinfo" != xno], [
 999   AS_IF([test "x$have_ncursesw" = xyes], [
1000     UL_TINFO_CHECK([tinfow])
1001   ])
1002   AS_IF([test "x$have_tinfow" = xno], [
1003     UL_TINFO_CHECK([tinfo])
1004   ])
1005 ])
1006 AC_SUBST([TINFO_LIBS])
1007 AC_SUBST([TINFO_LIBS_STATIC])
1008 AC_SUBST([TINFO_CFLAGS])
1009 AM_CONDITIONAL([HAVE_TINFO], [test "x$have_tinfo" = xyes -o "x$have_tinfow" = xyes])
1010 AS_IF([test "x$have_tinfo" = xyes -o "x$have_tinfow" = xyes], [
1011   AC_DEFINE(HAVE_LIBTINFO, 1, [Define if libtinfo or libtinfow available.])
1012 ])
1013
1014
1015 AC_ARG_WITH([readline],
1016   AS_HELP_STRING([--without-readline], [do not build with GNU Readline support]),
1017   [], [with_readline=auto]
1018 )
1019
1020 AS_IF([test "x$with_readline" = xno], [
1021   AM_CONDITIONAL([HAVE_READLINE], [false])
1022 ], [
1023   UL_CHECK_LIB([readline], [readline])
1024   AS_CASE([$with_readline:$have_readline],
1025     [yes:no],
1026       [AC_MSG_ERROR([readline selected but libreadline not found ])],
1027     [*:yes],
1028       [READLINE_LIBS="-lreadline"
1029        READLINE_LIBS_STATIC="-lreadline $TINFO_LIBS_STATIC"]
1030   )
1031 ])
1032 AC_SUBST([READLINE_LIBS])
1033 AC_SUBST([READLINE_LIBS_STATIC])
1034
1035
1036 AC_ARG_WITH([utempter],
1037   AS_HELP_STRING([--with-utempter], [compile script(1) with libutempter]),
1038   [], [with_utempter=no]
1039 )
1040
1041 AS_IF([test "x$with_utempter" = xyes], [
1042   UL_CHECK_LIB([utempter], [utempter_add_record])
1043   AS_IF([test "x$have_utempter" = xno], [
1044     AC_MSG_ERROR([utempter selected but libutempter not found])
1045   ])
1046 ], [
1047   AM_CONDITIONAL([HAVE_UTEMPTER], [false])
1048 ])
1049
1050
1051 dnl
1052 dnl libuuid
1053 dnl
1054 AC_ARG_ENABLE([libuuid],
1055   AS_HELP_STRING([--disable-libuuid], [do not build libuuid and uuid utilities]),
1056   [], [UL_DEFAULT_ENABLE([libuuid], [yes])]
1057 )
1058 UL_BUILD_INIT([libuuid])
1059 AC_SUBST([LIBUUID_VERSION])
1060 AC_SUBST([LIBUUID_VERSION_INFO])
1061 AM_CONDITIONAL(BUILD_LIBUUID, test "x$build_libuuid" = xyes)
1062
1063 AC_ARG_ENABLE([libuuid-force-uuidd],
1064   AS_HELP_STRING([--enable-libuuid-force-uuidd], [support uuidd even though the daemon is not built]),
1065   [], [enable_libuuid_force_uuidd=no]
1066 )
1067
1068 AS_IF([test "x$build_libuuid" = xyes], [
1069   AC_DEFINE(HAVE_LIBUUID, 1, [Define to 1 if you have the -luuid.])
1070 ])
1071
1072 dnl
1073 dnl libblkid
1074 dnl
1075 AC_ARG_ENABLE([libblkid],
1076   AS_HELP_STRING([--disable-libblkid], [do not build libblkid and many related utilities]),
1077   [], [UL_DEFAULT_ENABLE([libblkid], [check])]
1078 )
1079 UL_BUILD_INIT([libblkid])
1080 UL_REQUIRES_HAVE([libblkid], [openat], [openat functions])
1081 UL_REQUIRES_HAVE([libblkid], [dirfd,ddfd], [dirfd or ddfd function])
1082 AC_SUBST([LIBBLKID_DATE])
1083 AC_SUBST([LIBBLKID_VERSION])
1084 AC_SUBST([LIBBLKID_VERSION_INFO])
1085 AC_DEFINE_UNQUOTED([LIBBLKID_VERSION], ["$LIBBLKID_VERSION"], [libblkid version string])
1086 AC_DEFINE_UNQUOTED([LIBBLKID_DATE], ["$LIBBLKID_DATE"], [libblkid date string])
1087 AS_IF([test "x$build_libblkid" = xyes], [
1088   AC_DEFINE([HAVE_LIBBLKID], [1], [Define to 1 if you have the -lblkid.])
1089 ])
1090 AM_CONDITIONAL([BUILD_LIBBLKID], [test "x$build_libblkid" = xyes])
1091 AM_CONDITIONAL([BUILD_LIBBLKID_TESTS], [test "x$build_libblkid" = xyes -a "x$enable_static" = xyes])
1092
1093 dnl
1094 dnl libmount
1095 dnl
1096 AC_ARG_ENABLE([libmount],
1097   AS_HELP_STRING([--disable-libmount], [do not build libmount]),
1098   [], [UL_DEFAULT_ENABLE([libmount], [check])]
1099 )
1100 UL_BUILD_INIT([libmount])
1101 UL_REQUIRES_BUILD([libmount], [libblkid])
1102 UL_REQUIRES_HAVE([libmount], [scanf_alloc_modifier], [scanf string alloc modifier])
1103 UL_REQUIRES_HAVE([libmount], [dirfd,ddfd], [dirfd or ddfd function])
1104 AM_CONDITIONAL([BUILD_LIBMOUNT], [test "x$build_libmount" = xyes])
1105 AM_CONDITIONAL([BUILD_LIBMOUNT_TESTS], [test "x$build_libmount" = xyes -a "x$enable_static" = xyes])
1106 AS_IF([test "x$build_libmount" = xyes], [
1107   AC_DEFINE(HAVE_LIBMOUNT, 1, [Define if libmount available.])
1108   AS_IF([test "x$have_setns_syscall" = "xyes"], [
1109     AC_DEFINE([USE_LIBMOUNT_SUPPORT_NAMESPACES], [1], [Define to 1 if want to support namepaces.])
1110   ],[
1111     AC_MSG_WARN([libmount will be compiled without namespaces support])
1112   ])
1113 ])
1114
1115 AC_SUBST([LIBMOUNT_VERSION])
1116 AC_SUBST([LIBMOUNT_MAJOR_VERSION], $PACKAGE_VERSION_MAJOR)
1117 AC_SUBST([LIBMOUNT_MINOR_VERSION], $PACKAGE_VERSION_MINOR)
1118 AC_SUBST([LIBMOUNT_PATCH_VERSION], $PACKAGE_VERSION_RELEASE)
1119 AC_SUBST([LIBMOUNT_VERSION_INFO])
1120 AC_DEFINE_UNQUOTED([LIBMOUNT_VERSION], ["$LIBMOUNT_VERSION"], [libmount version string])
1121
1122 AC_ARG_ENABLE([libmount-support-mtab],
1123   AS_HELP_STRING([--enable-libmount-support-mtab], [support /etc/mtab (default is use /proc/self/mountinfo)]),
1124   [], [enable_libmount_support_mtab=no]
1125 )
1126
1127 AS_IF([test "x$enable_libmount_support_mtab" = xyes], [
1128   AC_DEFINE([USE_LIBMOUNT_SUPPORT_MTAB], [1], [Define to 1 if want to support mtab.])
1129 ])
1130
1131 dnl
1132 dnl libsmartcols
1133 dnl
1134 AC_ARG_ENABLE([libsmartcols],
1135   AS_HELP_STRING([--disable-libsmartcols], [do not build libsmartcols]),
1136   [], [UL_DEFAULT_ENABLE([libsmartcols], [yes])]
1137 )
1138 UL_BUILD_INIT([libsmartcols])
1139 AM_CONDITIONAL([BUILD_LIBSMARTCOLS], [test "x$build_libsmartcols" = xyes])
1140
1141 AC_SUBST([LIBSMARTCOLS_VERSION])
1142 AC_SUBST([LIBSMARTCOLS_VERSION_INFO])
1143 AC_DEFINE_UNQUOTED([LIBSMARTCOLS_VERSION], ["$LIBSMARTCOLS_VERSION"], [libsmartcols version string])
1144
1145
1146 dnl
1147 dnl libfdisk
1148 dnl
1149 AC_ARG_ENABLE([libfdisk],
1150   AS_HELP_STRING([--disable-libfdisk], [do not build libfdisk]),
1151   [], [UL_DEFAULT_ENABLE([libfdisk], [check])]
1152 )
1153 UL_BUILD_INIT([libfdisk])
1154 UL_REQUIRES_BUILD([libfdisk], [libuuid])
1155 AM_CONDITIONAL([BUILD_LIBFDISK], [test "x$build_libfdisk" = xyes])
1156 AM_CONDITIONAL([BUILD_LIBFDISK_TESTS], [test "x$build_libfdisk" = xyes -a "x$enable_static" = xyes])
1157
1158 AS_IF([test "x$build_libblkid" = xyes],
1159   [LIBFDISK_PC_REQUIRES="uuid blkid"],[LIBFDISK_PC_REQUIRES="uuid"])
1160 AC_SUBST([LIBFDISK_PC_REQUIRES])
1161
1162 AC_SUBST([LIBFDISK_VERSION])
1163 AC_SUBST([LIBFDISK_MAJOR_VERSION], $PACKAGE_VERSION_MAJOR)
1164 AC_SUBST([LIBFDISK_MINOR_VERSION], $PACKAGE_VERSION_MINOR)
1165 AC_SUBST([LIBFDISK_PATCH_VERSION], $PACKAGE_VERSION_RELEASE)
1166 AC_SUBST([LIBFDISK_VERSION_INFO])
1167 AC_DEFINE_UNQUOTED([LIBFDISK_VERSION], ["$LIBFDISK_VERSION"], [libfdisk version string])
1168
1169
1170 AC_ARG_ENABLE([fdisks],
1171   AS_HELP_STRING([--disable-fdisks], [do not build fdisk(8), sfdisk(8) and cfdisk(8)]),
1172   [], [UL_DEFAULT_ENABLE([fdisks], [check])]
1173 )
1174 enable_fdisk=$enable_fdisks
1175 enable_sfdisk=$enable_fdisks
1176 enable_cfdisk=$enable_fdisks
1177
1178 UL_BUILD_INIT([fdisk])
1179 UL_REQUIRES_HAVE([fdisk], [openat], [openat functions])
1180 UL_REQUIRES_HAVE([fdisk], [dirfd,ddfd], [dirfd or ddfd function])
1181 UL_REQUIRES_BUILD([fdisk], [libfdisk])
1182 UL_REQUIRES_BUILD([fdisk], [libsmartcols])
1183 AM_CONDITIONAL([BUILD_FDISK], [test "x$build_fdisk" = xyes])
1184
1185
1186 UL_BUILD_INIT([sfdisk])
1187 UL_REQUIRES_HAVE([sfdisk], [openat], [openat functions])
1188 UL_REQUIRES_HAVE([sfdisk], [dirfd,ddfd], [dirfd or ddfd function])
1189 UL_REQUIRES_BUILD([sfdisk], [libfdisk])
1190 UL_REQUIRES_BUILD([sfdisk], [libsmartcols])
1191 AM_CONDITIONAL([BUILD_SFDISK], [test "x$build_sfdisk" = xyes])
1192
1193
1194 UL_BUILD_INIT([cfdisk])
1195 UL_REQUIRES_BUILD([cfdisk], [libfdisk])
1196 UL_REQUIRES_BUILD([cfdisk], [libsmartcols])
1197 UL_REQUIRES_HAVE([cfdisk], [open_memstream], [open_memstream function])
1198 UL_REQUIRES_HAVE([cfdisk], [ncursesw,slang,ncurses], [ncursesw, ncurses or slang library])
1199 AM_CONDITIONAL([BUILD_CFDISK], [test "x$build_cfdisk" = xyes])
1200
1201
1202 AC_ARG_ENABLE([mount],
1203   AS_HELP_STRING([--disable-mount], [do not build mount(8) and umount(8)]),
1204   [], [UL_DEFAULT_ENABLE([mount], [check])]
1205 )
1206 UL_BUILD_INIT([mount])
1207 UL_REQUIRES_LINUX([mount])
1208 UL_REQUIRES_BUILD([mount], [libmount])
1209 AM_CONDITIONAL([BUILD_MOUNT], [test "x$build_mount" = xyes])
1210
1211
1212 AC_ARG_ENABLE([losetup],
1213   AS_HELP_STRING([--disable-losetup], [do not build losetup]),
1214   [], [UL_DEFAULT_ENABLE([losetup], [check])]
1215 )
1216 UL_BUILD_INIT([losetup])
1217 UL_REQUIRES_LINUX([losetup])
1218 UL_REQUIRES_BUILD([losetup], [libsmartcols])
1219 AM_CONDITIONAL([BUILD_LOSETUP], [test "x$build_losetup" = xyes])
1220
1221 AC_ARG_ENABLE([zramctl],
1222   AS_HELP_STRING([--disable-zramctl], [do not build zramctl]),
1223   [], [UL_DEFAULT_ENABLE([zramctl], [check])]
1224 )
1225 UL_BUILD_INIT([zramctl])
1226 UL_REQUIRES_LINUX([zramctl])
1227 UL_REQUIRES_BUILD([zramctl], [libsmartcols])
1228 AM_CONDITIONAL([BUILD_ZRAMCTL], [test "x$build_zramctl" = xyes])
1229
1230 AC_ARG_ENABLE([fsck],
1231   AS_HELP_STRING([--disable-fsck], [do not build fsck]),
1232   [], [UL_DEFAULT_ENABLE([fsck], [check])]
1233 )
1234 UL_BUILD_INIT([fsck])
1235 UL_REQUIRES_BUILD([fsck], [libmount])
1236 AM_CONDITIONAL([BUILD_FSCK], [test "x$build_fsck" = xyes])
1237
1238
1239 AC_ARG_ENABLE([partx],
1240   AS_HELP_STRING([--disable-partx], [do not build addpart, delpart, partx]),
1241   [], [UL_DEFAULT_ENABLE([partx], [check])]
1242 )
1243 UL_BUILD_INIT([partx])
1244 UL_REQUIRES_LINUX([partx])
1245 UL_REQUIRES_BUILD([partx], [libblkid])
1246 UL_REQUIRES_BUILD([partx], [libsmartcols])
1247 AM_CONDITIONAL([BUILD_PARTX], [test "x$build_partx" = xyes])
1248
1249
1250 AC_ARG_ENABLE([uuidd],
1251   AS_HELP_STRING([--disable-uuidd], [do not build the uuid daemon]),
1252   [], [UL_DEFAULT_ENABLE([uuidd], [check])]
1253 )
1254 UL_BUILD_INIT([uuidd])
1255 UL_REQUIRES_BUILD([uuidd], [libuuid])
1256 UL_REQUIRES_HAVE([uuidd], [timer], [timer_create function])
1257 UL_REQUIRES_HAVE([uuidd], [sys_signalfd_h], [sys/signalfd.h header])
1258 AS_IF([test "x$build_uuidd" = xyes || test "x$enable_libuuid_force_uuidd" = xyes], [
1259   AC_DEFINE([HAVE_UUIDD], [1], [Define to 1 if you want to use uuid daemon.])
1260 ])
1261 AM_CONDITIONAL([BUILD_UUIDD], [test "x$build_uuidd" = xyes])
1262
1263
1264 UL_BUILD_INIT([uuidgen], [check])
1265 UL_REQUIRES_BUILD([uuidgen], [libuuid])
1266 AM_CONDITIONAL([BUILD_UUIDGEN], [test "x$build_uuidgen" = xyes])
1267
1268 UL_BUILD_INIT([uuidparse], [check])
1269 UL_REQUIRES_BUILD([uuidparse], [libuuid])
1270 UL_REQUIRES_BUILD([uuidparse], [libsmartcols])
1271 AM_CONDITIONAL([BUILD_UUIDPARSE], [test "x$build_uuidparse" = xyes])
1272
1273 UL_BUILD_INIT([blkid], [check])
1274 UL_REQUIRES_BUILD([blkid], [libblkid])
1275 AM_CONDITIONAL([BUILD_BLKID], [test "x$build_blkid" = xyes])
1276
1277 UL_BUILD_INIT([findfs], [check])
1278 UL_REQUIRES_BUILD([findfs], [libblkid])
1279 AM_CONDITIONAL([BUILD_FINDFS], [test "x$build_findfs" = xyes])
1280
1281 UL_BUILD_INIT([wipefs], [check])
1282 UL_REQUIRES_BUILD([wipefs], [libblkid])
1283 UL_REQUIRES_BUILD([wipefs], [libsmartcols])
1284 AM_CONDITIONAL([BUILD_WIPEFS], [test "x$build_wipefs" = xyes])
1285
1286 UL_BUILD_INIT([findmnt], [check])
1287 UL_REQUIRES_BUILD([findmnt], [libmount])
1288 UL_REQUIRES_BUILD([findmnt], [libblkid])
1289 UL_REQUIRES_BUILD([findmnt], [libsmartcols])
1290 AM_CONDITIONAL([BUILD_FINDMNT], [test "x$build_findmnt" = xyes])
1291
1292
1293 AC_ARG_ENABLE([mountpoint],
1294   AS_HELP_STRING([--disable-mountpoint], [do not build mountpoint]),
1295   [], [UL_DEFAULT_ENABLE([mountpoint], [check])]
1296 )
1297 UL_BUILD_INIT([mountpoint])
1298 UL_REQUIRES_BUILD([mountpoint], [libmount])
1299 AM_CONDITIONAL([BUILD_MOUNTPOINT], [test "x$build_mountpoint" = xyes])
1300
1301
1302 AC_ARG_ENABLE([fallocate],
1303   AS_HELP_STRING([--disable-fallocate], [do not build fallocate]),
1304   [], [UL_DEFAULT_ENABLE([fallocate], [check])]
1305 )
1306 UL_BUILD_INIT([fallocate])
1307 UL_REQUIRES_LINUX([fallocate])
1308 UL_REQUIRES_SYSCALL_CHECK([fallocate], [UL_CHECK_SYSCALL([fallocate])])
1309 AM_CONDITIONAL([BUILD_FALLOCATE], [test "x$build_fallocate" = xyes])
1310
1311 AS_IF([test "x$build_fallocate" = xyes], [
1312   dnl check for valid fallocate() function
1313   dnl with 32 bits glibc 2.10, fallocate() exists but not fallocate64()
1314   dnl when _FILE_OFFSET_BITS==64, fallocate() is redirect to fallocate64()
1315   dnl and program can't be linked.
1316   dnl AC_CHECK_FUNC can't catch such errors since it's redefining
1317   dnl function prototype.
1318   AC_MSG_CHECKING([for valid fallocate() function])
1319   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1320 #ifdef HAVE_UNISTD_H
1321 # include <unistd.h>
1322 #endif
1323 #ifdef HAVE_SYS_TYPES_H
1324 # include <sys/types.h>
1325 #endif
1326 #ifdef HAVE_LINUX_FALLOC_H
1327 # include <linux/falloc.h>
1328 #endif
1329 #ifdef HAVE_FCNTL_H
1330 # include <fcntl.h>
1331 #endif
1332 ]],[[
1333    long ret;
1334    ret = fallocate(0, FALLOC_FL_KEEP_SIZE, 0xfffffffful, 0xfffffffful);
1335    if (ret != 0) {
1336       return 1;
1337    }
1338    ]])],[
1339   AC_MSG_RESULT([yes])
1340   AC_DEFINE([HAVE_FALLOCATE], [1], [Have valid fallocate() function])],[
1341   AC_MSG_RESULT([no])])
1342 ])
1343
1344 AS_IF([test "x$build_fallocate" = xyes], [
1345   dnl check for valid posix_fallocate() function
1346   AC_MSG_CHECKING([for valid posix_fallocate() function])
1347   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1348 #ifdef HAVE_UNISTD_H
1349 # include <unistd.h>
1350 #endif
1351 #ifdef HAVE_SYS_TYPES_H
1352 # include <sys/types.h>
1353 #endif
1354 #ifdef HAVE_LINUX_FALLOC_H
1355 # include <linux/falloc.h>
1356 #endif
1357 #ifdef HAVE_FCNTL_H
1358 # include <fcntl.h>
1359 #endif
1360 ]],[[
1361    long ret;
1362    ret = posix_fallocate(0, 0xfffffffful, 0xfffffffful);
1363    if (ret != 0) {
1364       return 1;
1365    }
1366    ]])],[
1367   AC_MSG_RESULT([yes])
1368   AC_DEFINE([HAVE_POSIX_FALLOCATE], [1], [Have valid posix_fallocate() function])],[
1369   AC_MSG_RESULT([no])])
1370 ])
1371
1372
1373 AC_ARG_ENABLE([unshare],
1374   AS_HELP_STRING([--disable-unshare], [do not build unshare]),
1375   [], [UL_DEFAULT_ENABLE([unshare], [check])]
1376 )
1377 UL_BUILD_INIT([unshare])
1378 UL_REQUIRES_LINUX([unshare])
1379 UL_REQUIRES_SYSCALL_CHECK([unshare], [UL_CHECK_SYSCALL([unshare])])
1380 UL_REQUIRES_HAVE([unshare], [linux_capability_h], [linux/capability.h header file])
1381 AM_CONDITIONAL([BUILD_UNSHARE], [test "x$build_unshare" = xyes])
1382 AC_CHECK_FUNCS([unshare])
1383
1384 AC_ARG_ENABLE([nsenter],
1385   AS_HELP_STRING([--disable-nsenter], [do not build nsenter]),
1386   [], [UL_DEFAULT_ENABLE([nsenter], [check])]
1387 )
1388 UL_BUILD_INIT([nsenter])
1389 UL_REQUIRES_LINUX([nsenter])
1390 UL_REQUIRES_HAVE([nsenter], [setns_syscall], [setns syscall])
1391 AM_CONDITIONAL([BUILD_NSENTER], [test "x$build_nsenter" = xyes])
1392 AC_CHECK_FUNCS([setns])
1393
1394
1395 AC_ARG_WITH([cap_ng],
1396   AS_HELP_STRING([--without-cap-ng], [compile without libcap-ng]),
1397   [], [with_cap_ng=auto]
1398 )
1399 AS_IF([test "x$with_cap_ng" = xno], [
1400   AM_CONDITIONAL([HAVE_CAP_NG], [false])
1401   have_cap_ng=no
1402 ],[
1403   UL_CHECK_LIB([cap-ng], [capng_apply], [cap_ng])
1404 ])
1405
1406
1407 AC_ARG_ENABLE([setpriv],
1408   AS_HELP_STRING([--disable-setpriv], [do not build setpriv]),
1409   [], [UL_DEFAULT_ENABLE([setpriv], [check])]
1410 )
1411 UL_BUILD_INIT([setpriv])
1412 UL_REQUIRES_LINUX([setpriv])
1413 UL_REQUIRES_HAVE([setpriv], [linux_securebits_h], [linux/securebits.h header file])
1414 UL_REQUIRES_HAVE([setpriv], [linux_capability_h], [linux/capability.h header file])
1415 UL_REQUIRES_HAVE([setpriv], [cap_ng], [libcap-ng library])
1416 AM_CONDITIONAL([BUILD_SETPRIV], [test "x$build_setpriv" = xyes])
1417
1418 PKG_CHECK_MODULES([PCRE], [libpcre2-8], [have_pcre=yes], [have_pcre=no])
1419 AS_IF([test "x$have_pcre" = xyes ], [
1420     AC_DEFINE([HAVE_PCRE], [1], [Define if libpcre2 is available])
1421 ])
1422 AM_CONDITIONAL([HAVE_PCRE], [test "x$have_pcre" = xyes])
1423
1424 AC_ARG_ENABLE([hardlink],
1425   AS_HELP_STRING([--disable-hardlink], [do not build hardlink]),
1426   [], [UL_DEFAULT_ENABLE([hardlink], [check])]
1427 )
1428 UL_BUILD_INIT([hardlink])
1429 AM_CONDITIONAL([BUILD_HARDLINK], [test "x$build_hardlink" = xyes])
1430
1431 AC_ARG_ENABLE([eject],
1432   AS_HELP_STRING([--disable-eject], [do not build eject]),
1433   [], [UL_DEFAULT_ENABLE([eject], [check])]
1434 )
1435 UL_BUILD_INIT([eject])
1436 UL_REQUIRES_LINUX([eject])
1437 UL_REQUIRES_BUILD([eject], [libmount])
1438 AM_CONDITIONAL([BUILD_EJECT], [test "x$build_eject" = xyes])
1439
1440
1441 AC_ARG_ENABLE([agetty],
1442   AS_HELP_STRING([--disable-agetty], [do not build agetty]),
1443   [], [UL_DEFAULT_ENABLE([agetty], [check])]
1444 )
1445 UL_BUILD_INIT([agetty])
1446 UL_REQUIRES_HAVE([agetty], [utmpx_h], [utmpx.h header])
1447 UL_REQUIRES_HAVE([agetty], [gnu_utmpx], [GNU utmpx functions])
1448 AM_CONDITIONAL([BUILD_AGETTY], [test "x$build_agetty" = xyes])
1449 AS_IF([test "x$have_futimens" = xyes -a "x$have_inotify_init1" = xyes ], [
1450   AC_DEFINE([AGETTY_RELOAD], [1], [Enable agetty --reload feature])
1451 ],[
1452   AC_MSG_WARN([futimens or inotify_init1 not found; agetty(8) will not provide ---reload functionality])
1453 ])
1454
1455
1456 AC_ARG_ENABLE([plymouth_support],
1457   AS_HELP_STRING([--disable-plymouth_support], [do not care about plymouth in sylogin(8) and agetty(8)]),
1458   [], [enable_plymouth_support=check]
1459 )
1460 UL_BUILD_INIT([plymouth_support])
1461 UL_REQUIRES_HAVE([plymouth_support], [tiocglcktrmios], [TIOCGLCKTRMIOS flag])
1462 UL_REQUIRES_HAVE([plymouth_support], [sock_cloexec], [SOCK_CLOEXEC flag])
1463 UL_REQUIRES_HAVE([plymouth_support], [sock_nonblock], [SOCK_NONBLOCK flag])
1464 UL_REQUIRES_HAVE([plymouth_support], [so_passcred], [SO_PASSCRED flag])
1465 AM_CONDITIONAL([USE_PLYMOUTH_SUPPORT], [test "x$build_plymouth_support" = xyes])
1466 AS_IF([test "x$build_plymouth_support" = xyes ], [
1467     AC_DEFINE([USE_PLYMOUTH_SUPPORT], [1], [Enable plymouth support feature for sulogin and aggety])
1468 ])
1469
1470
1471 AC_ARG_WITH([libz],
1472   AS_HELP_STRING([--without-libz], [compile without libz]),
1473   [], [with_libz=auto]
1474 )
1475 AS_IF([test "x$with_libz" = xno], [have_z=no], [
1476   AC_CHECK_LIB([z], [crc32], [have_z=yes], [have_z=no])
1477 ])
1478
1479
1480 AC_ARG_ENABLE([cramfs],
1481   AS_HELP_STRING([--disable-cramfs], [do not build fsck.cramfs, mkfs.cramfs]),
1482   [], [UL_DEFAULT_ENABLE([cramfs], [check])]
1483 )
1484 UL_BUILD_INIT([cramfs])
1485 UL_REQUIRES_HAVE([cramfs], [z], [z library])
1486 AM_CONDITIONAL([BUILD_CRAMFS], [test "x$build_cramfs" = xyes])
1487
1488
1489 AC_ARG_ENABLE([bfs],
1490   AS_HELP_STRING([--disable-bfs], [do not build mkfs.bfs]),
1491   [], [UL_DEFAULT_ENABLE([bfs], [yes])]
1492 )
1493 UL_BUILD_INIT([bfs])
1494 AM_CONDITIONAL([BUILD_BFS], [test "x$build_bfs" = xyes])
1495
1496
1497 AC_ARG_ENABLE([minix],
1498   AS_HELP_STRING([--disable-minix], [do not build fsck.minix, mkfs.minix]),
1499   [], [UL_DEFAULT_ENABLE([minix], [yes])]
1500 )
1501 UL_BUILD_INIT([minix])
1502 AM_CONDITIONAL([BUILD_MINIX], [test "x$build_minix" = xyes])
1503
1504
1505 AC_ARG_ENABLE([fdformat],
1506   AS_HELP_STRING([--disable-fdformat], [do not build fdformat]),
1507   [], [UL_DEFAULT_ENABLE([fdformat], [check])]
1508 )
1509 UL_BUILD_INIT([fdformat])
1510 UL_REQUIRES_LINUX([fdformat])
1511 AM_CONDITIONAL([BUILD_FDFORMAT], [test "x$build_fdformat" = xyes])
1512
1513
1514 AC_ARG_ENABLE([hwclock],
1515   AS_HELP_STRING([--disable-hwclock], [do not build hwclock]),
1516   [], [UL_DEFAULT_ENABLE([hwclock], [check])]
1517 )
1518 have_linuxdummy=$linux_os
1519
1520 UL_BUILD_INIT([hwclock])
1521 UL_REQUIRES_HAVE([hwclock], [io, linuxdummy], [ioperm iopl function or Linux])
1522 AM_CONDITIONAL([BUILD_HWCLOCK], [test "x$build_hwclock" = xyes])
1523
1524 AC_ARG_ENABLE([hwclock_cmos],
1525   AS_HELP_STRING([--disable-hwclock-cmos], [do not use CMOS clock]),
1526   [], [enable_hwclock_cmos=check]
1527 )
1528 UL_BUILD_INIT([hwclock_cmos])
1529 UL_REQUIRES_BUILD([hwclock_cmos], [hwclock])
1530 UL_REQUIRES_ARCH([hwclock_cmos], [i?86-*,x86_64*])
1531 AM_CONDITIONAL([USE_HWCLOCK_CMOS], [test "x$build_hwclock_cmos" = xyes])
1532 AS_IF([test "x$build_hwclock_cmos" = xyes ], [
1533     AC_DEFINE([USE_HWCLOCK_CMOS], [1], [Define to 1 if want to use CMOS clock.])
1534 ])
1535
1536
1537 UL_BUILD_INIT([mkfs], [yes])
1538 AM_CONDITIONAL([BUILD_MKFS], [test "x$build_mkfs" = xyes])
1539
1540 UL_BUILD_INIT([isosize], [yes])
1541 AM_CONDITIONAL([BUILD_ISOSIZE], [test "x$build_isosize" = xyes])
1542
1543
1544 UL_BUILD_INIT([fstrim], [check])
1545 UL_REQUIRES_LINUX([fstrim])
1546 UL_REQUIRES_BUILD([fstrim], [libmount])
1547 AM_CONDITIONAL([BUILD_FSTRIM], [test "x$build_fstrim" = xyes])
1548
1549
1550 UL_BUILD_INIT([swapon], [check])
1551 UL_REQUIRES_LINUX([swapon])
1552 UL_REQUIRES_SYSCALL_CHECK([swapon], [UL_CHECK_SYSCALL([swapon])], [swapon])
1553 UL_REQUIRES_SYSCALL_CHECK([swapon], [UL_CHECK_SYSCALL([swapoff])], [swapoff])
1554 UL_REQUIRES_BUILD([swapon], [libblkid])
1555 UL_REQUIRES_BUILD([swapon], [libmount])
1556 UL_REQUIRES_BUILD([swapon], [libsmartcols])
1557 AM_CONDITIONAL([BUILD_SWAPON], [test "x$build_swapon" = xyes])
1558 AC_CHECK_FUNCS([swapon])
1559 AC_CHECK_FUNCS([swapoff])
1560
1561
1562 UL_BUILD_INIT([lsblk], [check])
1563 UL_REQUIRES_LINUX([lsblk])
1564 UL_REQUIRES_BUILD([lsblk], [libblkid])
1565 UL_REQUIRES_BUILD([lsblk], [libmount])
1566 UL_REQUIRES_BUILD([lsblk], [libsmartcols])
1567 AM_CONDITIONAL([BUILD_LSBLK], [test "x$build_lsblk" = xyes])
1568
1569
1570 UL_BUILD_INIT([lscpu], [check])
1571 UL_REQUIRES_LINUX([lscpu])
1572 UL_REQUIRES_BUILD([lscpu], [libsmartcols])
1573 UL_REQUIRES_HAVE([lscpu], [cpu_set_t], [cpu_set_t type])
1574 AM_CONDITIONAL([BUILD_LSCPU], [test "x$build_lscpu" = xyes])
1575
1576
1577 AC_ARG_ENABLE([lslogins],
1578   AS_HELP_STRING([--disable-lslogins], [do not build lslogins]),
1579   [], [UL_DEFAULT_ENABLE([lslogins], [check])]
1580 )
1581 UL_BUILD_INIT([lslogins])
1582 UL_REQUIRES_BUILD([lslogins], [libsmartcols])
1583 UL_REQUIRES_HAVE([lslogins], [shadow_h], [shadow.h header])
1584 UL_REQUIRES_HAVE([lslogins], [utmpx_h], [utmpx.h header])
1585 UL_REQUIRES_HAVE([lslogins], [gnu_utmpx], [GNU utmpx functions])
1586 AM_CONDITIONAL([BUILD_LSLOGINS], [test "x$build_lslogins" = xyes])
1587
1588
1589 UL_BUILD_INIT([chcpu], [check])
1590 UL_REQUIRES_LINUX([chcpu])
1591 UL_REQUIRES_HAVE([chcpu], [cpu_set_t], [cpu_set_t type])
1592 AM_CONDITIONAL([BUILD_CHCPU], [test "x$build_chcpu" = xyes])
1593
1594
1595 AC_ARG_ENABLE([wdctl],
1596   AS_HELP_STRING([--disable-wdctl], [do not build wdctl]),
1597   [], [UL_DEFAULT_ENABLE([wdctl], [check])]
1598 )
1599 UL_BUILD_INIT([wdctl])
1600 UL_REQUIRES_LINUX([wdctl])
1601 UL_REQUIRES_BUILD([wdctl], [libsmartcols])
1602 UL_REQUIRES_HAVE([wdctl], [linux_watchdog_h], [linux/watchdog.h header file])
1603 AM_CONDITIONAL([BUILD_WDCTL], [test "x$build_wdctl" = xyes])
1604
1605
1606 UL_BUILD_INIT([swaplabel], [check])
1607 UL_REQUIRES_BUILD([swaplabel], [libblkid])
1608 AM_CONDITIONAL([BUILD_SWAPLABEL], [test "x$build_swaplabel" = xyes])
1609
1610
1611 UL_BUILD_INIT([mkswap], [yes])
1612 AM_CONDITIONAL([BUILD_MKSWAP], [test "x$build_mkswap" = xyes])
1613 AS_IF([test "x$build_mkswap" = xyes -a "x$build_libuuid" != xyes], [
1614   AC_MSG_WARN([uuid library is not found; mkswap(8) will not generate UUIDs])
1615 ])
1616
1617
1618 AC_ARG_ENABLE([cal],
1619   AS_HELP_STRING([--disable-cal], [do not build cal]),
1620   [], [UL_DEFAULT_ENABLE([cal], [check])]
1621 )
1622 UL_BUILD_INIT([cal])
1623 AM_CONDITIONAL([BUILD_CAL], [test "x$build_cal" = xyes])
1624
1625 AC_ARG_ENABLE([logger],
1626   AS_HELP_STRING([--disable-logger], [do not build logger]),
1627   [], [UL_DEFAULT_ENABLE([logger], [check])]
1628 )
1629 UL_BUILD_INIT([logger])
1630 AM_CONDITIONAL([BUILD_LOGGER], [test "x$build_logger" = xyes])
1631
1632 UL_BUILD_INIT([look], [yes])
1633 AM_CONDITIONAL([BUILD_LOOK], [test "x$build_look" = xyes])
1634
1635 UL_BUILD_INIT([mcookie], [yes])
1636 AM_CONDITIONAL([BUILD_MCOOKIE], [test "x$build_mcookie" = xyes])
1637
1638 UL_BUILD_INIT([namei], [yes])
1639 AM_CONDITIONAL([BUILD_NAMEI], [test "x$build_namei" = xyes])
1640
1641 matriplet="$($CC -print-multiarch 2>/dev/null || true)"
1642 if test "x$matriplet" != "x"; then
1643   AC_DEFINE_UNQUOTED([MULTIARCHTRIPLET], ["$matriplet"],
1644   ["Multi-arch triplet for whereis library search path"])
1645 fi
1646 UL_BUILD_INIT([whereis], [yes])
1647 AM_CONDITIONAL([BUILD_WHEREIS], [test "x$build_whereis" = xyes])
1648
1649 UL_BUILD_INIT([getopt], [yes])
1650 AM_CONDITIONAL([BUILD_GETOPT], [test "x$build_getopt" = xyes])
1651
1652
1653 UL_BUILD_INIT([blockdev], [check])
1654 UL_REQUIRES_LINUX([blockdev])
1655 AM_CONDITIONAL([BUILD_BLOCKDEV], [test "x$build_blockdev" = xyes])
1656
1657
1658 UL_BUILD_INIT([prlimit], [check])
1659 UL_REQUIRES_LINUX([prlimit])
1660 UL_REQUIRES_BUILD([prlimit], [libsmartcols])
1661 UL_REQUIRES_SYSCALL_CHECK([prlimit], [UL_CHECK_SYSCALL([prlimit64])], [prlimit64])
1662 AM_CONDITIONAL([BUILD_PRLIMIT], [test "x$build_prlimit" = xyes])
1663 AS_IF([test "x$build_prlimit" = xyes], [
1664   AC_CHECK_FUNCS([prlimit])
1665 ])
1666
1667
1668 UL_BUILD_INIT([lslocks], [check])
1669 UL_REQUIRES_LINUX([lslocks])
1670 UL_REQUIRES_BUILD([lslocks], [libmount])
1671 UL_REQUIRES_BUILD([lslocks], [libsmartcols])
1672 AM_CONDITIONAL([BUILD_LSLOCKS], [test "x$build_lslocks" = xyes])
1673
1674
1675 AC_ARG_ENABLE([switch_root],
1676   AS_HELP_STRING([--disable-switch_root], [do not build switch_root]),
1677   [], [UL_DEFAULT_ENABLE([switch_root], [check])]
1678 )
1679 UL_BUILD_INIT([switch_root])
1680 UL_REQUIRES_LINUX([switch_root])
1681 UL_REQUIRES_HAVE([switch_root], [openat], [openat function])
1682 UL_REQUIRES_HAVE([switch_root], [dirfd,ddfd], [dirfd or ddfd function])
1683 AM_CONDITIONAL([BUILD_SWITCH_ROOT], [test "x$build_switch_root" = xyes])
1684
1685
1686 AC_ARG_ENABLE([pivot_root],
1687   AS_HELP_STRING([--disable-pivot_root], [do not build pivot_root]),
1688   [], [UL_DEFAULT_ENABLE([pivot_root], [check])]
1689 )
1690 UL_BUILD_INIT([pivot_root])
1691 UL_REQUIRES_LINUX([pivot_root])
1692 UL_REQUIRES_SYSCALL_CHECK([pivot_root], [UL_CHECK_SYSCALL([pivot_root])])
1693 AM_CONDITIONAL([BUILD_PIVOT_ROOT], [test "x$build_pivot_root" = xyes])
1694
1695
1696 UL_BUILD_INIT([flock], [check])
1697 UL_REQUIRES_HAVE([flock], [timer], [timer_create/setitimer function])
1698 AM_CONDITIONAL([BUILD_FLOCK], [test "x$build_flock" = xyes])
1699
1700
1701 AC_ARG_ENABLE([lsmem],
1702   AS_HELP_STRING([--disable-lsmem], [do not build lsmem]),
1703   [], [UL_DEFAULT_ENABLE([lsmem], [check])]
1704 )
1705 UL_BUILD_INIT([lsmem])
1706 UL_REQUIRES_LINUX([lsmem])
1707 UL_REQUIRES_BUILD([lsmem], [libsmartcols])
1708 AM_CONDITIONAL([BUILD_LSMEM], [test "x$build_lsmem" = xyes])
1709
1710
1711 AC_ARG_ENABLE([chmem],
1712   AS_HELP_STRING([--disable-chmem], [do not build chmem]),
1713   [], [UL_DEFAULT_ENABLE([chmem], [check])]
1714 )
1715 UL_BUILD_INIT([chmem])
1716 UL_REQUIRES_LINUX([chmem])
1717 AM_CONDITIONAL([BUILD_CHMEM], [test "x$build_chmem" = xyes])
1718
1719 UL_BUILD_INIT([ipcmk], [yes])
1720 AM_CONDITIONAL([BUILD_IPCMK], [test "x$build_ipcmk" = xyes])
1721
1722
1723 AC_ARG_ENABLE([ipcrm],
1724   AS_HELP_STRING([--disable-ipcrm], [do not build ipcrm]),
1725   [], [UL_DEFAULT_ENABLE([ipcrm], [yes])]
1726 )
1727 UL_BUILD_INIT([ipcrm])
1728 AM_CONDITIONAL([BUILD_IPCRM], [test "x$build_ipcrm" = xyes])
1729
1730 AC_ARG_ENABLE([ipcs],
1731   AS_HELP_STRING([--disable-ipcs], [do not build ipcs]),
1732   [], [UL_DEFAULT_ENABLE([ipcs], [yes])]
1733 )
1734 UL_BUILD_INIT([ipcs])
1735 AM_CONDITIONAL([BUILD_IPCS], [test "x$build_ipcs" = xyes])
1736
1737 UL_BUILD_INIT([choom], [check])
1738 UL_REQUIRES_LINUX([choom])
1739 AM_CONDITIONAL([BUILD_CHOOM], [test "x$build_choom" = xyes])
1740
1741 UL_BUILD_INIT([lsipc], [check])
1742 UL_REQUIRES_LINUX([lsipc])
1743 UL_REQUIRES_BUILD([lsipc], [libsmartcols])
1744 AM_CONDITIONAL([BUILD_LSIPC], [test "x$build_lsipc" = xyes])
1745
1746 UL_BUILD_INIT([lsns], [check])
1747 UL_REQUIRES_LINUX([lsns])
1748 UL_REQUIRES_BUILD([lsns], [libsmartcols])
1749 UL_REQUIRES_BUILD([lsns], [libmount])
1750 AM_CONDITIONAL([BUILD_LSNS], [test "x$build_lsns" = xyes])
1751
1752 UL_BUILD_INIT([renice], [yes])
1753 AM_CONDITIONAL([BUILD_RENICE], [test "x$build_renice" = xyes])
1754
1755
1756 AC_ARG_ENABLE([rfkill],
1757   AS_HELP_STRING([--disable-rfkill], [do not build rfkill]),
1758   [], [UL_DEFAULT_ENABLE([rfkill], [check])]
1759 )
1760 UL_BUILD_INIT([rfkill])
1761 UL_REQUIRES_LINUX([rfkill])
1762 UL_REQUIRES_BUILD([rfkill], [libsmartcols])
1763 AM_CONDITIONAL([BUILD_RFKILL], [test "x$build_rfkill" = xyes])
1764
1765
1766 UL_BUILD_INIT([setsid], [yes])
1767 AM_CONDITIONAL([BUILD_SETSID], [test "x$build_setsid" = xyes])
1768
1769 UL_BUILD_INIT([readprofile], [check])
1770 UL_REQUIRES_LINUX([readprofile])
1771 AM_CONDITIONAL([BUILD_READPROFILE], [test "x$build_readprofile" = xyes])
1772
1773 UL_BUILD_INIT([dmesg], [check])
1774 UL_REQUIRES_LINUX([dmesg])
1775 AM_CONDITIONAL([BUILD_DMESG], [test "x$build_dmesg" = xyes])
1776
1777 UL_BUILD_INIT([ctrlaltdel], [check])
1778 UL_REQUIRES_LINUX([ctrlaltdel])
1779 dnl we assume reboot() to be the 1-argument variant, because even considering
1780 dnl widely used alternative C libraries like uclibc, dietlibc and musl,
1781 dnl reboot() with multiple arguments is yet only found in glibc versions
1782 dnl earlier than 2.x.
1783 UL_REQUIRES_HAVE([ctrlaltdel], [reboot], [reboot function])
1784 AM_CONDITIONAL([BUILD_CTRLALTDEL], [test "x$build_ctrlaltdel" = xyes])
1785
1786 UL_BUILD_INIT([fincore], [check])
1787 UL_REQUIRES_LINUX([fincore])
1788 UL_REQUIRES_BUILD([fincore], [libsmartcols])
1789 AM_CONDITIONAL([BUILD_FINCORE], [test "x$build_fincore" = xyes])
1790
1791 UL_BUILD_INIT([fsfreeze], [check])
1792 UL_REQUIRES_LINUX([fsfreeze])
1793 AM_CONDITIONAL([BUILD_FSFREEZE], [test "x$build_fsfreeze" = xyes])
1794
1795 UL_BUILD_INIT([blkdiscard], [check])
1796 UL_REQUIRES_LINUX([blkdiscard])
1797 AM_CONDITIONAL([BUILD_BLKDISCARD], [test "x$build_blkdiscard" = xyes])
1798
1799 UL_BUILD_INIT([blkzone], [check])
1800 UL_REQUIRES_LINUX([blkzone])
1801 UL_REQUIRES_HAVE([blkzone], [linux_blkzoned_h], [linux/blkzoned.h header])
1802 AM_CONDITIONAL([BUILD_BLKZONE], [test "x$build_blkzone" = xyes])
1803
1804 UL_BUILD_INIT([ldattach], [check])
1805 UL_REQUIRES_LINUX([ldattach])
1806 AM_CONDITIONAL([BUILD_LDATTACH], [test "x$build_ldattach" = xyes])
1807
1808 UL_BUILD_INIT([rtcwake], [check])
1809 UL_REQUIRES_LINUX([rtcwake])
1810 AM_CONDITIONAL([BUILD_RTCWAKE], [test "x$build_rtcwake" = xyes])
1811
1812 UL_BUILD_INIT([setarch], [check])
1813 UL_REQUIRES_LINUX([setarch])
1814 AM_CONDITIONAL([BUILD_SETARCH], [test "x$build_setarch" = xyes])
1815
1816 UL_BUILD_INIT([script], [check])
1817 UL_REQUIRES_HAVE([script], [sys_signalfd_h], [sys/signalfd.h header])
1818 AM_CONDITIONAL([BUILD_SCRIPT], [test "x$build_script" = xyes])
1819
1820 UL_BUILD_INIT([scriptreplay], [yes])
1821 AM_CONDITIONAL([BUILD_SCRIPTREPLAY], [test "x$build_scriptreplay" = xyes])
1822
1823 UL_BUILD_INIT([col], [yes])
1824 AM_CONDITIONAL([BUILD_COL], [test "x$build_col" = xyes])
1825
1826 UL_BUILD_INIT([colcrt], [yes])
1827 AM_CONDITIONAL([BUILD_COLCRT], [test "x$build_colcrt" = xyes])
1828
1829 UL_BUILD_INIT([colrm], [yes])
1830 AM_CONDITIONAL([BUILD_COLRM], [test "x$build_colrm" = xyes])
1831
1832 UL_BUILD_INIT([column], [check])
1833 UL_REQUIRES_BUILD([column], [libsmartcols])
1834 AM_CONDITIONAL([BUILD_COLUMN], [test "x$build_column" = xyes])
1835
1836 UL_BUILD_INIT([hexdump], [yes])
1837 AM_CONDITIONAL([BUILD_HEXDUMP], [test "x$build_hexdump" = xyes])
1838
1839 UL_BUILD_INIT([rev], [yes])
1840 AM_CONDITIONAL([BUILD_REV], [test "x$build_rev" = xyes])
1841
1842
1843 AC_ARG_ENABLE([tunelp],
1844   AS_HELP_STRING([--enable-tunelp], [build tunelp]),
1845   [], [UL_DEFAULT_ENABLE([tunelp], [no])]
1846 )
1847 UL_BUILD_INIT([tunelp])
1848 UL_REQUIRES_LINUX([tunelp])
1849 AM_CONDITIONAL([BUILD_TUNELP], [test "x$build_tunelp" = xyes])
1850
1851
1852 AC_ARG_ENABLE([kill],
1853   AS_HELP_STRING([--disable-kill], [do not build kill]),
1854   [], [UL_DEFAULT_ENABLE([kill], [check])]
1855 )
1856 UL_BUILD_INIT([kill])
1857 UL_REQUIRES_LINUX([kill])
1858 AM_CONDITIONAL([BUILD_KILL], [test "x$build_kill" = xyes])
1859
1860
1861 AC_ARG_ENABLE([last],
1862   AS_HELP_STRING([--disable-last], [do not build last]),
1863   [], [UL_DEFAULT_ENABLE([last], [check])]
1864 )
1865 UL_BUILD_INIT([last])
1866 UL_REQUIRES_HAVE([last], [utmpx_h], [utmpx.h header])
1867 UL_REQUIRES_HAVE([last], [gnu_utmpx], [GNU utmpx functions])
1868 AM_CONDITIONAL([BUILD_LAST], [test "x$build_last" = xyes])
1869
1870
1871 AC_ARG_ENABLE([utmpdump],
1872   AS_HELP_STRING([--disable-utmpdump], [do not build utmpdump]),
1873   [], [UL_DEFAULT_ENABLE([utmpdump], [check])]
1874 )
1875 UL_BUILD_INIT([utmpdump])
1876 UL_REQUIRES_HAVE([utmpdump], [utmpx_h], [utmpx.h header])
1877 UL_REQUIRES_HAVE([utmpdump], [gnu_utmpx], [GNU utmpx functions])
1878 AM_CONDITIONAL([BUILD_UTMPDUMP], [test "x$build_utmpdump" = xyes])
1879
1880
1881 AC_ARG_ENABLE([line],
1882   AS_HELP_STRING([--enable-line], [build line]),
1883   [], [UL_DEFAULT_ENABLE([line], [no])]
1884 )
1885 UL_BUILD_INIT([line])
1886 AM_CONDITIONAL([BUILD_LINE], [test "x$build_line" = xyes])
1887
1888
1889 AC_ARG_ENABLE([mesg],
1890   AS_HELP_STRING([--disable-mesg], [do not build mesg]),
1891   [], [UL_DEFAULT_ENABLE([mesg], [yes])]
1892 )
1893 UL_BUILD_INIT([mesg])
1894 AM_CONDITIONAL([BUILD_MESG], [test "x$build_mesg" = xyes])
1895
1896
1897 AC_ARG_ENABLE([raw],
1898   AS_HELP_STRING([--disable-raw], [do not build raw]),
1899   [], [UL_DEFAULT_ENABLE([raw], [check])]
1900 )
1901 UL_BUILD_INIT([raw])
1902 UL_REQUIRES_LINUX([raw])
1903 UL_REQUIRES_HAVE([raw], [linux_raw_h], [raw.h header file])
1904 AM_CONDITIONAL([BUILD_RAW], [test "x$build_raw" = xyes])
1905
1906
1907 AC_ARG_ENABLE([rename],
1908   AS_HELP_STRING([--disable-rename], [do not build rename]),
1909   [], [UL_DEFAULT_ENABLE([rename], [yes])]
1910 )
1911 UL_BUILD_INIT([rename])
1912 AM_CONDITIONAL([BUILD_RENAME], [test "x$build_rename" = xyes])
1913
1914
1915 AC_ARG_ENABLE([vipw],
1916   AS_HELP_STRING([--enable-vipw], [build vipw]),
1917   [], [UL_DEFAULT_ENABLE([vipw], [no])]
1918 )
1919 UL_BUILD_INIT([vipw])
1920 UL_REQUIRES_HAVE([vipw], [shadow_h], [shadow.h header])
1921 AM_CONDITIONAL([BUILD_VIPW], [test "x$build_vipw" = xyes])
1922
1923
1924 AC_ARG_ENABLE([newgrp],
1925   AS_HELP_STRING([--enable-newgrp], [build newgrp]),
1926   [], [UL_DEFAULT_ENABLE([newgrp], [no])]
1927 )
1928 UL_BUILD_INIT([newgrp])
1929 UL_REQUIRES_HAVE([newgrp], [crypt], [crypt function])
1930 AM_CONDITIONAL([BUILD_NEWGRP], [test "x$build_newgrp" = xyes])
1931
1932
1933 AC_ARG_WITH([user], AS_HELP_STRING([--without-user], [compile without libuser (remote chsh)]),
1934   [], [with_user=check]
1935 )
1936 have_user=no
1937 AS_IF([test "x$with_user" != xno], [
1938   PKG_CHECK_MODULES(LIBUSER,[libuser >= 0.58], [have_user=yes], [have_user=no])
1939   AS_CASE([$with_user:$have_user],
1940     [yes:no],
1941       [AC_MSG_ERROR([user selected but libuser not found])],
1942     [*:yes],
1943       [AC_DEFINE([HAVE_LIBUSER], [1], [Define if libuser is available])]
1944   )
1945   # temporary solution, libuser has stupid .pc where are exported all
1946   # private dependencies to Requires: instead of Requires.private:
1947   AS_IF([test "x$have_user" = xyes], [
1948     LIBUSER_LIBS=-luser
1949   ])
1950 ])
1951 AM_CONDITIONAL([HAVE_USER], [test "x$have_user" = xyes])
1952
1953 AC_ARG_ENABLE([chfn-chsh-password],
1954   AS_HELP_STRING([--disable-chfn-chsh-password], [do not require the user to enter the password in chfn and chsh]),
1955   [], [enable_chfn_chsh_password=yes]
1956 )
1957
1958 AC_ARG_ENABLE([chfn-chsh],
1959   AS_HELP_STRING([--enable-chfn-chsh], [build chfn and chsh]),
1960   [], [UL_DEFAULT_ENABLE([chfn_chsh], [check])]
1961 )
1962 UL_BUILD_INIT([chfn_chsh])
1963 UL_REQUIRES_HAVE([chfn_chsh], [shadow_h], [shadow.h header])
1964 UL_REQUIRES_HAVE([chfn_chsh], [getusershell], [getusershell function])
1965
1966 AS_IF([test "x$enable_chfn_chsh_password" = xyes -o "x$have_user" = xyes], [
1967   UL_REQUIRES_HAVE([chfn_chsh], [security_pam_appl_h], [PAM header file])
1968   AC_DEFINE([CHFN_CHSH_PASSWORD], [1], [Should chfn and chsh require the user to enter the password?])
1969 ])
1970 AM_CONDITIONAL([BUILD_CHFN_CHSH], [test "x$build_chfn_chsh" = xyes])
1971 AM_CONDITIONAL([CHFN_CHSH_PASSWORD], [test "x$enable_chfn_chsh_password" = xyes])
1972
1973 AC_ARG_ENABLE([chsh-only-listed],
1974   AS_HELP_STRING([--disable-chsh-only-listed], [chsh: allow shells not in /etc/shells]),
1975   [], enable_chsh_only_listed=yes
1976 )
1977
1978 AS_IF([test "x$enable_chsh_only_listed" = xyes], [
1979   AC_DEFINE([ONLY_LISTED_SHELLS], [1], [Should chsh allow only shells in /etc/shells?])
1980 ])
1981
1982
1983 AC_ARG_ENABLE([login],
1984   AS_HELP_STRING([--disable-login], [do not build login]),
1985   [], [UL_DEFAULT_ENABLE([login], [check])]
1986 )
1987 UL_BUILD_INIT([login])
1988 UL_REQUIRES_HAVE([login], [security_pam_appl_h], [PAM header file])
1989 UL_REQUIRES_HAVE([login], [security_pam_misc_h, security_openpam_h], [PAM conversation functions])
1990 UL_REQUIRES_HAVE([login], [utmpx_h], [utmpx.h header])
1991 UL_REQUIRES_HAVE([login], [gnu_utmpx], [GNU utmpx functions])
1992 AM_CONDITIONAL([BUILD_LOGIN], [test "x$build_login" = xyes])
1993
1994 AC_ARG_ENABLE([login-chown-vcs],
1995   AS_HELP_STRING([--enable-login-chown-vcs], [let login chown /dev/vcsN]),
1996   [], [enable_login_chown_vcs=no]
1997 )
1998
1999 AS_IF([test "x$enable_login_chown_vcs" = xyes], [
2000   AC_DEFINE([LOGIN_CHOWN_VCS], [1], [Should login chown /dev/vcsN?])
2001 ])
2002
2003 AC_ARG_ENABLE([login-stat-mail],
2004   AS_HELP_STRING([--enable-login-stat-mail], [let login stat() the mailbox]),
2005   [], [enable_login_stat_mail=no]
2006 )
2007
2008 AS_IF([test "x$enable_login_stat_mail" = xyes], [
2009   AC_DEFINE([LOGIN_STAT_MAIL], [1], [Should login stat() the mailbox?])
2010 ])
2011
2012
2013 AC_ARG_ENABLE([nologin],
2014   AS_HELP_STRING([--disable-nologin], [do not build nologin]),
2015   [], [UL_DEFAULT_ENABLE([nologin], [yes])]
2016 )
2017 UL_BUILD_INIT([nologin])
2018 AM_CONDITIONAL([BUILD_NOLOGIN], [test "x$build_nologin" = xyes])
2019
2020
2021 AC_ARG_ENABLE([sulogin],
2022   AS_HELP_STRING([--disable-sulogin], [do not build sulogin]),
2023   [], [UL_DEFAULT_ENABLE([sulogin], [check])]
2024 )
2025 UL_BUILD_INIT([sulogin])
2026 UL_REQUIRES_HAVE([sulogin], [crypt], [crypt function])
2027 UL_REQUIRES_HAVE([sulogin], [shadow_h], [shadow.h header])
2028 AM_CONDITIONAL([BUILD_SULOGIN], [test "x$build_sulogin" = xyes])
2029
2030
2031 AC_ARG_ENABLE([su],
2032   AS_HELP_STRING([--disable-su], [do not build su]),
2033   [], [UL_DEFAULT_ENABLE([su], [check])]
2034 )
2035 UL_BUILD_INIT([su])
2036 UL_REQUIRES_HAVE([su], [security_pam_appl_h], [PAM header file])
2037 UL_REQUIRES_HAVE([su], [utmpx_h], [utmpx.h header])
2038 UL_REQUIRES_HAVE([su], [gnu_utmpx], [GNU utmpx functions])
2039 AM_CONDITIONAL([BUILD_SU], [test "x$build_su" = xyes])
2040
2041
2042 AC_ARG_ENABLE([runuser],
2043   AS_HELP_STRING([--disable-runuser], [do not build runuser]),
2044   [], [UL_DEFAULT_ENABLE([runuser], [check])]
2045 )
2046 UL_BUILD_INIT([runuser])
2047 UL_REQUIRES_HAVE([runuser], [security_pam_appl_h], [PAM header file])
2048 UL_REQUIRES_HAVE([runuser], [utmpx_h], [utmpx.h header])
2049 UL_REQUIRES_HAVE([runuser], [gnu_utmpx], [GNU utmpx functions])
2050 AM_CONDITIONAL([BUILD_RUNUSER], [test "x$build_runuser" = xyes])
2051
2052
2053 AC_ARG_ENABLE([ul],
2054   AS_HELP_STRING([--disable-ul], [do not build ul]),
2055   [], [UL_DEFAULT_ENABLE([ul], [check])]
2056 )
2057 UL_BUILD_INIT([ul])
2058 UL_REQUIRES_HAVE([ul], [ncursesw, ncurses], [ncursesw or ncurses libraries])
2059 AM_CONDITIONAL([BUILD_UL], [test "x$build_ul" = xyes])
2060
2061
2062 AC_ARG_ENABLE([more],
2063   AS_HELP_STRING([--disable-more], [do not build more]),
2064   [], [UL_DEFAULT_ENABLE([more], [check])]
2065 )
2066 UL_BUILD_INIT([more])
2067 UL_REQUIRES_HAVE([more], [ncursesw, ncurses], [ncursesw or ncurses libraries])
2068 AM_CONDITIONAL([BUILD_MORE], [test "x$build_more" = xyes])
2069
2070
2071 AC_ARG_ENABLE([pg],
2072   AS_HELP_STRING([--enable-pg], [build pg]),
2073   [], [UL_DEFAULT_ENABLE([pg], [no])]
2074 )
2075 UL_BUILD_INIT([pg])
2076 UL_REQUIRES_HAVE([pg], [ncursesw, ncurses], [ncursesw or ncurses library])
2077 AM_CONDITIONAL([BUILD_PG], [test "x$build_pg" = xyes])
2078
2079
2080 AC_ARG_ENABLE([setterm],
2081   AS_HELP_STRING([--disable-setterm], [do not build setterm]),
2082   [], [UL_DEFAULT_ENABLE([setterm], [check])]
2083 )
2084 UL_BUILD_INIT([setterm])
2085 UL_REQUIRES_LINUX([setterm])
2086 UL_REQUIRES_HAVE([setterm], [ncursesw, ncurses], [ncursesw or ncurses library])
2087 AM_CONDITIONAL([BUILD_SETTERM], [test "x$build_setterm" = xyes])
2088
2089 # build_schedutils= is just configure-only variable to control
2090 # ionice, taskset and chrt
2091 AC_ARG_ENABLE([schedutils],
2092   AS_HELP_STRING([--disable-schedutils], [do not build chrt, ionice, taskset]),
2093   [], [UL_DEFAULT_ENABLE([schedutils], [check])]
2094 )
2095
2096
2097 UL_ENABLE_ALIAS([ionice], [schedutils])
2098 UL_BUILD_INIT([ionice])
2099 UL_REQUIRES_SYSCALL_CHECK([ionice],
2100         [UL_CHECK_SYSCALL([ioprio_set],
2101           [alpha],      [442],
2102           [i*86],       [289],
2103           [ia64*],      [1274],
2104           [powerpc*],   [273],
2105           [s390*],      [282],
2106           [sparc*],     [196],
2107           [sh*],        [288],
2108           [x86_64*],    [251])],
2109         [ioprio_set])
2110
2111 UL_REQUIRES_SYSCALL_CHECK([ionice],
2112         [UL_CHECK_SYSCALL([ioprio_get],
2113           [alpha],      [443],
2114           [i*86],       [290],
2115           [ia64*],      [1275],
2116           [powerpc*],   [274],
2117           [s390*],      [283],
2118           [sparc*],     [218],
2119           [sh*],        [289],
2120           [x86_64*],    [252])],
2121         [ioprio_get])
2122
2123 AM_CONDITIONAL([BUILD_IONICE], [test "x$build_ionice" = xyes])
2124
2125
2126 UL_ENABLE_ALIAS([taskset], [schedutils])
2127 UL_BUILD_INIT([taskset])
2128 UL_REQUIRES_HAVE([taskset], [cpu_set_t], [cpu_set_t type])
2129 UL_REQUIRES_SYSCALL_CHECK([taskset],
2130         [UL_CHECK_SYSCALL([sched_getaffinity])],
2131         [sched_getaffinity])
2132 AM_CONDITIONAL([BUILD_TASKSET], [test "x$build_taskset" = xyes])
2133
2134
2135 have_schedsetter=no
2136 AS_IF([test "x$ac_cv_func_sched_setscheduler" = xyes], [have_schedsetter=yes],
2137       [test "x$ac_cv_func_sched_setattr" = xyes], [have_schedsetter=yes])
2138
2139 UL_ENABLE_ALIAS([chrt], [schedutils])
2140 UL_BUILD_INIT([chrt])
2141 UL_REQUIRES_HAVE([chrt], [schedsetter], [sched_set functions])
2142 AM_CONDITIONAL([BUILD_CHRT], [test "x$build_chrt" = xyes])
2143
2144 AS_IF([test "x$build_chrt" = xyes], [
2145         UL_CHECK_SYSCALL([sched_setattr])
2146 ])
2147
2148
2149 AC_ARG_ENABLE([wall],
2150   AS_HELP_STRING([--disable-wall], [do not build wall]),
2151   [], [UL_DEFAULT_ENABLE([wall], [check])]
2152 )
2153 UL_BUILD_INIT([wall])
2154 UL_REQUIRES_HAVE([wall], [utmpx_h], [utmpx.h header])
2155 AM_CONDITIONAL([BUILD_WALL], [test "x$build_wall" = xyes])
2156
2157
2158 AC_ARG_ENABLE([write],
2159   AS_HELP_STRING([--enable-write], [build write]),
2160   [], [UL_DEFAULT_ENABLE([write], [no])]
2161 )
2162 UL_BUILD_INIT([write])
2163 UL_REQUIRES_HAVE([write], [utmpx_h], [utmpx.h header])
2164 UL_REQUIRES_HAVE([write], [gnu_utmpx], [GNU utmpx functions])
2165 AM_CONDITIONAL([BUILD_WRITE], [test "x$build_write" = xyes])
2166
2167
2168 AC_ARG_WITH([btrfs],
2169   AS_HELP_STRING([--without-btrfs], [do not build with btrfs support]),
2170   [], [with_btrfs=check]
2171 )
2172 have_btrfs=no
2173 AS_IF([test "x$with_btrfs" != xno], [
2174   AS_CASE([$with_btrfs:$have_linux_btrfs_h],
2175     [yes:no],
2176     [AC_MSG_ERROR([btrfs selected but linux/btrfs.h not found])],
2177     [check:no],
2178        [AC_MSG_WARN([linux/btrfs.h not found, do not build with btrfs support])],
2179     [*:yes],
2180        [have_btrfs=yes
2181         AC_DEFINE([HAVE_BTRFS_SUPPORT], [1], [Define if btrfs stuff is available])]
2182   )
2183 ])
2184 AM_CONDITIONAL([HAVE_BTRFS], [test "x$have_btrfs" = xyes])
2185
2186
2187 AC_ARG_WITH([systemd],
2188   AS_HELP_STRING([--without-systemd], [do not build with systemd support]),
2189   [], [with_systemd=check]
2190 )
2191
2192 have_systemd=no
2193 AS_IF([test "x$with_systemd" != xno], [
2194   # new version -- all libsystemd-* libs merged into libsystemd
2195   PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [have_systemd=yes], [have_systemd=no])
2196   # old versions
2197   AS_IF([test "x$have_systemd" != "xyes"], [
2198     PKG_CHECK_MODULES([SYSTEMD_DAEMON], [libsystemd-daemon],
2199                       [have_systemd_daemon=yes], [have_systemd_daemon=no])
2200     PKG_CHECK_MODULES([SYSTEMD_JOURNAL], [libsystemd-journal],
2201                       [have_systemd_journal=yes], [have_systemd_journal=no])
2202     AS_IF([test "x$have_systemd_daemon" = "xyes" -a "x$have_systemd_journal" = "xyes" ],[
2203            have_systemd=yes])
2204   ])
2205   AS_CASE([$with_systemd:$have_systemd],
2206     [yes:no],
2207       [AC_MSG_ERROR([systemd expected but libsystemd not found])],
2208     [*:yes],
2209        AC_DEFINE([HAVE_LIBSYSTEMD], [1], [Define if libsystemd is available])
2210   )
2211 ])
2212 AM_CONDITIONAL([HAVE_SYSTEMD], [test "x$have_systemd" = xyes])
2213
2214
2215 AC_ARG_WITH([systemdsystemunitdir],
2216   AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [directory for systemd unit files (requires systemd support)]),
2217   [], [with_systemdsystemunitdir=check]
2218 )
2219 AS_IF([test "x$with_systemdsystemunitdir" = xcheck], [
2220   AS_IF([test "x$have_systemd" = xyes], [
2221     with_systemdsystemunitdir=`$PKG_CONFIG --variable=systemdsystemunitdir systemd`
2222   ],[
2223     with_systemdsystemunitdir=no
2224   ])
2225 ])
2226 AS_IF([test "x$with_systemdsystemunitdir" != "xno"], [
2227   AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
2228 ])
2229
2230
2231 AC_ARG_WITH([smack],
2232   AS_HELP_STRING([--with-smack], [build with SMACK support]),
2233   [], [with_smack=no]
2234 )
2235 AS_IF([test "x$with_smack" = xyes], [
2236   AC_DEFINE([HAVE_SMACK], [1], [Add SMACK support])
2237 ])
2238
2239
2240 AC_ARG_WITH([bashcompletiondir],
2241   AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
2242   [],
2243   [AS_IF([`$PKG_CONFIG --exists bash-completion`], [
2244     with_bashcompletiondir=`$PKG_CONFIG --variable=completionsdir bash-completion`
2245   ], [
2246     with_bashcompletiondir=${datadir}/bash-completion/completions
2247   ])
2248 ])
2249 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
2250
2251 AC_ARG_ENABLE([bash-completion],
2252   AS_HELP_STRING([--disable-bash-completion], [do not install bash completion files]),
2253   [], [enable_bash_completion=yes]
2254 )
2255
2256 AM_CONDITIONAL([BUILD_BASH_COMPLETION], [test "x$enable_bash_completion" = xyes])
2257
2258
2259 AC_ARG_WITH([python],
2260   AS_HELP_STRING([--without-python], [do not build python bindings, use --with-python={2,3} to force version]),
2261   [], [with_python=check withval=check]
2262 )
2263
2264 have_python=no
2265 have_libpython=no
2266 AS_IF([test "x$with_python" != xno], [
2267   # We follow distributions default and look for PKG module name "python"
2268   # (minimal version is 2) but if major version is explicitly specified by
2269   # --with-python=2 or --with-python=3 then we look for PKG module "python2" or
2270   # "python3".
2271   AS_IF([test "x$withval" != xno -a "x$withval" != xyes -a "x$withval" != xcheck],
2272         [pymajor="$withval"; PYTHON=python${pymajor}], [pymajor="2"])
2273
2274   # check for python interpreter
2275   AM_PATH_PYTHON([$pymajor], [have_python=yes], [have_python=no])
2276   AS_CASE([$with_python:$have_python],
2277     [yes:no],
2278       [AC_MSG_ERROR([python selected but python interpreter not found])],
2279     [check:no],
2280        [AC_MSG_WARN([python interpreter not found, do not build python bindings])],
2281     [*:yes],
2282        # check for python development stuff
2283        [PKG_CHECK_MODULES([PYTHON], [python-$PYTHON_VERSION],
2284                           [have_libpython=yes], [have_libpython=no])]
2285   )
2286 ])
2287
2288
2289 AC_ARG_ENABLE([pylibmount],
2290   AS_HELP_STRING([--disable-pylibmount], [do not build pylibmount]),
2291   [], [UL_DEFAULT_ENABLE([pylibmount], [check])]
2292 )
2293 UL_BUILD_INIT([pylibmount])
2294 UL_REQUIRES_HAVE([pylibmount], [libpython], [libpython])
2295 UL_REQUIRES_BUILD([pylibmount], [libmount])
2296 AM_CONDITIONAL([BUILD_PYLIBMOUNT], [test "x$build_pylibmount" = "xyes"])
2297
2298 # We need to introduce a verbatim dependency into the Makefile, without automake
2299 # trying to interpret it, so push it as a AM_SUBST_NOTMAKE variable.
2300 verbatim_pylibmount_dependency='
2301
2302 # pylibmountexec module must be installed after usrlib_exec libraries,
2303 # otherwise the libtool relink step will fail to find libmount.la and
2304 # will try -lmount which is possibly not available.
2305 install-pylibmountexecLTLIBRARIES: install-usrlib_execLTLIBRARIES
2306
2307 '
2308 AC_SUBST([verbatim_pylibmount_dependency])
2309 AM_SUBST_NOTMAKE([verbatim_pylibmount_dependency])
2310
2311 AC_ARG_ENABLE([pg-bell],
2312   AS_HELP_STRING([--disable-pg-bell], [let pg not ring the bell on invalid keys]),
2313   [], [enable_pg_bell=yes]
2314 )
2315
2316 AS_IF([test "x$enable_pg_bell" = xyes], [
2317   AC_DEFINE([PG_BELL], [1], [Should pg ring the bell on invalid keys?])
2318 ])
2319
2320
2321 AC_DEFUN([FS_PATHS_DEFAULT], [/sbin:/sbin/fs.d:/sbin/fs])
2322 AC_ARG_ENABLE([fs-paths-default],
2323   AS_HELP_STRING([--enable-fs-paths-default=paths], [default search path for fs helpers @<:@FS_PATHS_DEFAULT@:>@]),
2324   [AS_CASE([$enableval],
2325     [yes], [fs_paths_defaults="FS_PATHS_DEFAULT"],
2326     [no],  [fs_paths_defaults=""],
2327     [fs_paths_defaults="$enableval"]
2328   )],
2329   [fs_paths_defaults="FS_PATHS_DEFAULT"]
2330 )
2331 AC_ARG_ENABLE([fs-paths-extra],
2332   AS_HELP_STRING([--enable-fs-paths-extra=paths], [additional search paths for fs helpers]),
2333   [AS_CASE([$enableval],
2334      [yes|no], [fs_paths_extra=""],
2335      [fs_paths_extra="$enableval"]
2336   )],
2337   [fs_paths_extra=""]
2338 )
2339 fs_paths="$fs_paths_defaults"
2340 AS_IF([test "x$fs_paths_extra" != "x"], [
2341   AS_IF([test "x$fs_paths" != "x"], [
2342     fs_paths="${fs_paths}:"
2343   ])
2344   fs_paths="${fs_paths}${fs_paths_extra}"
2345 ])
2346 AC_DEFINE_UNQUOTED([FS_SEARCH_PATH], "$fs_paths", [search path for fs helpers])
2347
2348
2349 AC_ARG_ENABLE([use-tty-group],
2350   AS_HELP_STRING([--disable-use-tty-group], [do not install wall and write setgid tty]),
2351   [], [enable_use_tty_group=yes]
2352 )
2353 AM_CONDITIONAL([USE_TTY_GROUP], [test "x$enable_use_tty_group" = xyes])
2354
2355 AS_IF([test "x$enable_use_tty_group" = xyes], [
2356   AC_DEFINE([USE_TTY_GROUP], [1], [Should wall and write be installed setgid tty?])
2357 ])
2358
2359
2360 AC_ARG_ENABLE([sulogin-emergency-mount],
2361   AS_HELP_STRING([--enable-sulogin-emergency-mount],
2362                  [use emergency mount of /dev and /proc for sulogin]),
2363   [], [enable_sulogin_emergency_mount=no]
2364 )
2365
2366 AS_IF([test "x$enable_sulogin_emergency_mount" = xyes], [
2367   AC_DEFINE([USE_SULOGIN_EMERGENCY_MOUNT], [1],
2368             [Should sulogin use a emergency mount of /dev and /proc?])
2369 ])
2370
2371
2372 AC_ARG_ENABLE([usrdir-path],
2373   AS_HELP_STRING([--enable-usrdir-path], [use only /usr paths in PATH env. variable (recommended on systems with /bin -> /usr/bin symlinks)]),
2374   [], [enable_usrdir_path=no]
2375 )
2376
2377 AS_IF([test "x$enable_usrdir_path" = xyes], [
2378   AC_DEFINE([USE_USRDIR_PATHS_ONLY], [1], [Define to 1 to remove /bin and /sbin from PATH env.variable])
2379 ])
2380
2381
2382 AC_ARG_ENABLE([makeinstall-chown],
2383   AS_HELP_STRING([--disable-makeinstall-chown], [do not do chown-like operations during "make install"]),
2384   [], [enable_makeinstall_chown=yes]
2385 )
2386 AM_CONDITIONAL([MAKEINSTALL_DO_CHOWN], [test "x$enable_makeinstall_chown" = xyes])
2387
2388
2389 AC_ARG_ENABLE([makeinstall-setuid],
2390   AS_HELP_STRING([--disable-makeinstall-setuid], [do not do setuid chmod operations during "make install"]),
2391   [], [enable_makeinstall_setuid=yes]
2392 )
2393 AM_CONDITIONAL([MAKEINSTALL_DO_SETUID], [test "x$enable_makeinstall_setuid" = xyes])
2394
2395
2396 AC_ARG_ENABLE([colors-default],
2397   AS_HELP_STRING([--disable-colors-default], [do not colorize output from utils by default]),
2398   [], [enable_colors_default=yes]
2399 )
2400 AS_IF([test "x$enable_colors_default" = xyes], [
2401   AC_DEFINE([USE_COLORS_BY_DEFAULT], [1], [Enables colorized output from utils by default])
2402 ])
2403
2404
2405 AC_ARG_VAR([SUID_CFLAGS],
2406            [CFLAGS used for binaries which are usually with the suid bit])
2407 AC_ARG_VAR([SUID_LDFLAGS],
2408            [LDFLAGS used for binaries which are usually with the suid bit])
2409
2410 AC_ARG_VAR([DAEMON_CFLAGS],
2411            [CFLAGS used for binaries which are usually executed as daemons])
2412 AC_ARG_VAR([DAEMON_LDFLAGS],
2413            [LDFLAGS used for binaries which are usually executed as daemons])
2414
2415 AC_ARG_VAR([SOLIB_CFLAGS],
2416            [CFLAGS used for shared libraries])
2417 AC_ARG_VAR([SOLIB_LDFLAGS],
2418            [LDFLAGS used for shared libraries])
2419
2420 AC_ARG_VAR([ADJTIME_PATH],
2421            [Path to hwclock adjtime file, default /etc/adjtime])
2422 AS_IF([test "x$ADJTIME_PATH" = x], [ADJTIME_PATH="/etc/adjtime"])
2423 AC_DEFINE_UNQUOTED([CONFIG_ADJTIME_PATH], "$ADJTIME_PATH", [Path to hwclock adjtime file])
2424
2425
2426 LIBS=""
2427
2428
2429 AC_CONFIG_HEADERS([config.h])
2430
2431 #
2432 # Don't use configure.ac to replace install paths! See Makefile PATHFILES for
2433 # more details.
2434 #
2435 AC_CONFIG_FILES([
2436 Makefile
2437 libblkid/docs/Makefile
2438 libblkid/docs/version.xml
2439 libblkid/src/blkid.h
2440 libfdisk/docs/Makefile
2441 libfdisk/docs/version.xml
2442 libfdisk/src/libfdisk.h
2443 libmount/docs/Makefile
2444 libmount/docs/version.xml
2445 libmount/src/libmount.h
2446 libsmartcols/docs/Makefile
2447 libsmartcols/docs/version.xml
2448 libsmartcols/src/libsmartcols.h
2449 po/Makefile.in
2450 ])
2451
2452 AC_OUTPUT
2453
2454 AC_MSG_RESULT([
2455         ${PACKAGE}  ${VERSION}
2456
2457         prefix:            ${prefix}
2458         exec prefix:       ${exec_prefix}
2459
2460         runstatedir:       ${runstatedir}
2461         bindir:            ${bindir}
2462         sbindir:           ${sbindir}
2463         libdir:            ${libdir}
2464         includedir:        ${includedir}
2465         usrbin_execdir:    ${usrbin_execdir}
2466         usrsbin_execdir:   ${usrsbin_execdir}
2467         usrlib_execdir:    ${usrlib_execdir}
2468
2469         compiler:          ${CC}
2470         cflags:            ${CFLAGS}
2471         suid cflags:       ${SUID_CFLAGS}
2472         ldflags:           ${LDFLAGS}
2473         suid ldflags:      ${SUID_LDFLAGS}
2474         ASAN enabled:      ${enable_asan}
2475
2476         Python:            ${PYTHON}
2477         Python version:    ${PYTHON_VERSION}
2478         Python libs:       ${pyexecdir}
2479
2480         Bash completions:  ${with_bashcompletiondir}
2481         Systemd support:   ${have_systemd}
2482         Systemd unitdir:   ${with_systemdsystemunitdir}
2483         Btrfs support:     ${have_btrfs}
2484         Wide-char support: ${build_widechar}
2485
2486         warnings:
2487
2488 ${WARN_CFLAGS}
2489
2490         Type 'make' or 'make <utilname>' to compile.
2491 ])