configure.ac

   1 AC_INIT([util-linux],
   2         m4_esyscmd([tools/git-version-gen .tarball-version]),
   3         [kzak@redhat.com],,
   4         [http://www.kernel.org/pub/linux/utils/util-linux/])
   5
   6
   7 AC_PREREQ([2.60])
   8
   9 AC_CONFIG_AUX_DIR([config])
  10 AC_CONFIG_MACRO_DIR([m4])
  11 dnl AC_USE_SYSTEM_EXTENSIONS must be called before any macros that run
  12 dnl the compiler (like AC_PROG_LIBTOOL) to avoid autoconf errors.
  13 AC_USE_SYSTEM_EXTENSIONS
  14 AM_INIT_AUTOMAKE([-Wall foreign 1.10 tar-pax no-dist-gzip dist-xz subdir-objects])
  15
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  17                             [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  18 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  19
  20 AC_CONFIG_SRCDIR([sys-utils/mount.c])
  21 AC_PREFIX_DEFAULT([/usr])
  22
  23 dnl version details from <major>.<minor>[-<suffix>]
  24 PACKAGE_VERSION_MAJOR=$(echo $PACKAGE_VERSION | awk -F. '{print $1}')
  25 PACKAGE_VERSION_MINOR=$(echo $PACKAGE_VERSION | awk -F. '{
  26                                                    sub("-.*","",$2); print $2}')
  27 PACKAGE_VERSION_RELEASE=$(echo $PACKAGE_VERSION | awk -F. '{
  28                      sub("-.*","",$3); print $3 ~ /^@<:@0-9@:>@+$/ ? $3 : 0}')
  29
  30 dnl libblkid version
  31 LIBBLKID_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  32 LIBBLKID_DATE="14-Jun-2019"
  33 LIBBLKID_LT_MAJOR=1
  34 LIBBLKID_LT_MINOR=1
  35 LIBBLKID_LT_MICRO=0
  36 LIBBLKID_VERSION_INFO=`expr $LIBBLKID_LT_MAJOR + $LIBBLKID_LT_MINOR`:$LIBBLKID_LT_MICRO:$LIBBLKID_LT_MINOR
  37
  38 dnl libuuid version
  39 LIBUUID_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  40 LIBUUID_LT_MAJOR=1
  41 LIBUUID_LT_MINOR=3
  42 LIBUUID_LT_MICRO=0
  43 LIBUUID_VERSION_INFO=`expr $LIBUUID_LT_MAJOR + $LIBUUID_LT_MINOR`:$LIBUUID_LT_MICRO:$LIBUUID_LT_MINOR
  44
  45 dnl libmount version
  46 LIBMOUNT_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  47 LIBMOUNT_LT_MAJOR=1
  48 LIBMOUNT_LT_MINOR=1
  49 LIBMOUNT_LT_MICRO=0
  50 LIBMOUNT_VERSION_INFO=`expr $LIBMOUNT_LT_MAJOR + $LIBMOUNT_LT_MINOR`:$LIBMOUNT_LT_MICRO:$LIBMOUNT_LT_MINOR
  51
  52 dnl libsmartcols version
  53 LIBSMARTCOLS_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  54 LIBSMARTCOLS_LT_MAJOR=1
  55 LIBSMARTCOLS_LT_MINOR=1
  56 LIBSMARTCOLS_LT_MICRO=0
  57 LIBSMARTCOLS_VERSION_INFO=`expr $LIBSMARTCOLS_LT_MAJOR + $LIBSMARTCOLS_LT_MINOR`:$LIBSMARTCOLS_LT_MICRO:$LIBSMARTCOLS_LT_MINOR
  58
  59 dnl libfdisk version
  60 LIBFDISK_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  61 LIBFDISK_LT_MAJOR=1
  62 LIBFDISK_LT_MINOR=1
  63 LIBFDISK_LT_MICRO=0
  64 LIBFDISK_VERSION_INFO=`expr $LIBFDISK_LT_MAJOR + $LIBFDISK_LT_MINOR`:$LIBFDISK_LT_MICRO:$LIBFDISK_LT_MINOR
  65
  66 # Check whether exec_prefix=/usr:
  67 AS_CASE([$exec_prefix:$prefix],
  68 [NONE:NONE | NONE:/usr | /usr:*],
  69   [AC_MSG_NOTICE([Default --exec-prefix detected.])
  70    AS_CASE([$bindir],  ['${exec_prefix}/bin'],  [bindir=/bin;   AC_MSG_NOTICE([  --bindir defaults to /bin])  ])
  71    AS_CASE([$sbindir], ['${exec_prefix}/sbin'], [sbindir=/sbin; AC_MSG_NOTICE([  --sbindir defaults to /sbin])])
  72    AS_CASE([$libdir],  ['${exec_prefix}/lib'],  [libdir=/lib;   AC_MSG_NOTICE([  --libdir defaults to /lib])  ])
  73    AS_CASE([$libdir],  ['${exec_prefix}/lib64'],[libdir=/lib64; AC_MSG_NOTICE([  --libdir defaults to /lib64])  ])
  74   ]
  75 )
  76
  77
  78 # default for old versions without $runstatedir
  79 AS_IF([test x"$runstatedir" = x], [runstatedir='${localstatedir}/run'])
  80
  81 # our default if $localstatedir unchanged
  82 AS_CASE([$localstatedir:$runstatedir],
  83  [NONE:'${localstatedir}/run' | /var:'${localstatedir}/run' | NONE:'/run' ],
  84    [runstatedir=/run; AC_MSG_NOTICE([  --runstatedir defaults to /run])]
  85 )
  86
  87 AC_SUBST([runstatedir])
  88
  89
  90 # The original default values of {bin,sbin,lib}dir
  91 usrbin_execdir='${exec_prefix}/bin'
  92 AC_SUBST([usrbin_execdir])
  93
  94 usrsbin_execdir='${exec_prefix}/sbin'
  95 AC_SUBST([usrsbin_execdir])
  96
  97 AS_CASE([$libdir],
  98  ['${exec_prefix}/'* | '${prefix}/'* | /usr/* | "${prefix}"/* ],
  99    [usrlib_execdir=$libdir],
 100  [usrlib_execdir='${exec_prefix}'$libdir]
 101 )
 102 AC_SUBST([usrlib_execdir])
 103
 104
 105 AM_PROG_CC_C_O
 106 AC_PROG_MKDIR_P
 107 AC_PROG_CC_STDC
 108 AC_PROG_YACC
 109 AC_CANONICAL_HOST
 110 AC_C_CONST
 111 AC_C_VOLATILE
 112 AC_C_BIGENDIAN
 113
 114 dnl Compiler warnings
 115 UL_WARN_ADD([-fno-common])
 116 UL_WARN_ADD([-Wall])
 117 UL_WARN_ADD([-Werror=sequence-point])
 118 UL_WARN_ADD([-Wextra])
 119 UL_WARN_ADD([-Wextra-semi])
 120 UL_WARN_ADD([-Wembedded-directive])
 121 UL_WARN_ADD([-Wmissing-declarations])
 122 UL_WARN_ADD([-Wmissing-parameter-type])
 123 UL_WARN_ADD([-Wmissing-prototypes])
 124 UL_WARN_ADD([-Wno-missing-field-initializers])
 125 UL_WARN_ADD([-Wredundant-decls])
 126 UL_WARN_ADD([-Wsign-compare])
 127 UL_WARN_ADD([-Wtype-limits])
 128 UL_WARN_ADD([-Wuninitialized])
 129 UL_WARN_ADD([-Wunused-but-set-parameter])
 130 UL_WARN_ADD([-Wunused-but-set-variable])
 131 UL_WARN_ADD([-Wunused-parameter])
 132 UL_WARN_ADD([-Wunused-result])
 133 UL_WARN_ADD([-Wunused-variable])
 134 UL_WARN_ADD([-Wnested-externs])
 135 UL_WARN_ADD([-Wpointer-arith])
 136 UL_WARN_ADD([-Wstrict-prototypes])
 137 UL_WARN_ADD([-Wformat-security])
 138 UL_WARN_ADD([-Wimplicit-function-declaration])
 139 UL_WARN_ADD([-Wdiscarded-qualifiers])
 140 AC_SUBST([WARN_CFLAGS])
 141
 142 UL_WARN_ADD([-Wno-clobbered], [BSD_WARN_CFLAGS])
 143 AC_SUBST([BSD_WARN_CFLAGS])
 144
 145 UL_WARN_ADD([-Wno-cast-function-type], [PYTHON_WARN_CFLAGS])
 146 AC_SUBST([PYTHON_WARN_CFLAGS])
 147
 148 UL_WARN_ADD([-Wno-unused-parameter], [NO_UNUSED_WARN_CFLAGS])
 149 AC_SUBST([NO_UNUSED_WARN_CFLAGS])
 150
 151
 152 AC_ARG_ENABLE([asan],
 153   AS_HELP_STRING([--enable-asan], [compile with Address Sanitizer]),
 154   [], [enable_asan=no]
 155 )
 156 AS_IF([test "x$enable_asan" = xyes], [
 157   UL_WARN_ADD([-fsanitize=address])
 158   ASAN_LDFLAGS="-fsanitize=address"
 159 ])
 160 AC_SUBST([ASAN_LDFLAGS])
 161
 162 dnl libtool-2
 163 LT_INIT
 164
 165 dnl check supported linker flags
 166 AX_CHECK_VSCRIPT
 167
 168 m4_ifndef([PKG_PROG_PKG_CONFIG],
 169   [m4_fatal([Could not locate the pkg-config autoconf
 170     macros. These are usually located in /usr/share/aclocal/pkg.m4.
 171     If your macros are in a different location, try setting the
 172     environment variable AL_OPTS="-I/other/macro/dir" before running
 173     ./autogen.sh or autoreconf again. Make sure pkg-config is installed.])])
 174 PKG_PROG_PKG_CONFIG
 175 PKG_INSTALLDIR(['${usrlib_execdir}/pkgconfig'])
 176
 177 GTK_DOC_CHECK([1.10])
 178 AC_PATH_PROG([XSLTPROC], [xsltproc])
 179
 180 linux_os=no
 181 bsd_os=no
 182 AS_CASE([${host_os}],
 183   [*linux*],
 184      [linux_os=yes],
 185   [*darwin*],
 186      [darwin_os=yes],
 187   [*bsd*],
 188      [bsd_os=yes])
 189 AM_CONDITIONAL([LINUX], [test "x$linux_os" = xyes])
 190 AM_CONDITIONAL([DARWIN], [test "x$darwin_os" = xyes])
 191 AM_CONDITIONAL([BSD], [test "x$bsd_os" = xyes])
 192
 193 AS_IF([test  "x$darwin_os" = xyes], [
 194   AC_DEFINE([_DARWIN_C_SOURCE], [1], [Enable MAP_ANON in sys/mman.h on Mac OS X])
 195 ])
 196
 197 dnl define ARCH_<NAME> conditionals
 198 UL_SET_ARCH([I86], [i?86-*])
 199 UL_SET_ARCH([86_64], [x86_64*])
 200 UL_SET_ARCH([IA64], [ia64*])
 201 UL_SET_ARCH([S390], [s390*])
 202 UL_SET_ARCH([SPARC], [sparc*])
 203 UL_SET_ARCH([PPC], [ppc*|powerpc*])
 204 UL_SET_ARCH([M68K], [m68*])
 205 UL_SET_ARCH([MIPS], [mips*])
 206 UL_SET_ARCH([HPPA], [hppa*|parisc*])
 207
 208 AC_SYS_LARGEFILE
 209 AC_HEADER_ASSERT
 210 AC_STRUCT_TIMEZONE
 211
 212 dnl Don't forget to maintain alternatively allowed versions in autogen.sh!
 213 AM_GNU_GETTEXT_VERSION([0.18.3])
 214 AM_GNU_GETTEXT([external])
 215
 216 AS_IF([test -d "$srcdir/po"], [
 217   ALL_LINGUAS=`cd $srcdir/po > /dev/null && echo *.po | sed 's/\.po//g'`
 218 ], [
 219   ALL_LINGUAS="af am ar as be bg bn_IN bn ca cs cy da de el en_GB es et eu_ES fa fi fr gl gu he hi hr hu hy id is it ja ka kn ko ku lo lt lv mk ml mr ms my nb nl nn no nso or pa pl pt_BR pt ro ru si sk sl sq sr@Latn sr sv ta te th tr uk ur vi zh_CN zh_TW zu"
 220 ])
 221
 222 AC_CHECK_HEADERS([linux/compiler.h linux/blkpg.h linux/major.h], [], [], [
 223 #ifdef HAVE_LINUX_COMPILER_H
 224 #include <linux/compiler.h>
 225 #endif
 226 ])
 227 AC_CHECK_HEADERS([ \
 228         asm/io.h \
 229         err.h \
 230         errno.h \
 231         fcntl.h \
 232         getopt.h \
 233         inttypes.h \
 234         lastlog.h \
 235         libutil.h \
 236         linux/btrfs.h \
 237         linux/cdrom.h \
 238         linux/falloc.h \
 239         linux/watchdog.h \
 240         linux/fd.h \
 241         linux/raw.h \
 242         linux/tiocl.h \
 243         linux/version.h \
 244         linux/securebits.h \
 245         linux/net_namespace.h \
 246         linux/capability.h \
 247         locale.h \
 248         mntent.h \
 249         net/if.h \
 250         net/if_dl.h \
 251         netinet/in.h \
 252         paths.h \
 253         pty.h \
 254         security/pam_appl.h \
 255         stdint.h \
 256         stdio_ext.h \
 257         stdlib.h \
 258         endian.h \
 259         byteswap.h \
 260         sys/endian.h \
 261         sys/disk.h \
 262         sys/disklabel.h \
 263         sys/file.h \
 264         sys/io.h \
 265         sys/ioccom.h \
 266         sys/ioctl.h \
 267         sys/mkdev.h \
 268         sys/mount.h \
 269         sys/param.h \
 270         sys/prctl.h \
 271         sys/resource.h \
 272         sys/signalfd.h \
 273         sys/socket.h \
 274         sys/sockio.h \
 275         sys/stat.h \
 276         sys/sysmacros.h \
 277         sys/swap.h \
 278         sys/syscall.h \
 279         sys/time.h \
 280         sys/timex.h \
 281         sys/ttydefaults.h \
 282         sys/types.h \
 283         sys/ucred.h \
 284         sys/un.h \
 285         unistd.h \
 286         shadow.h \
 287         utmp.h \
 288         utmpx.h \
 289 ])
 290
 291 # There is a collision in old kernel-headers. The both files mount.h and fs.h
 292 # define MS_* macros. Fixed by kernel commit e462ec50cb5fad19f6003a3d8087f4a0945dd2b1.
 293 #
 294 AC_CHECK_HEADERS([linux/fs.h ], [], [],
 295  [#ifdef HAVE_SYS_MOUNT_H
 296    # include <linux/fs.h>
 297    # include <sys/mount.h>
 298   #endif
 299 ])
 300
 301 AC_CHECK_HEADERS([linux/gsmmux.h ], [], [],
 302  [#ifdef LINUX_GSMMUX_H
 303    # include <linux/gsmmux.h>
 304    #endif
 305 ])
 306
 307 AC_CHECK_HEADERS([security/pam_misc.h],
 308                 [AM_CONDITIONAL([HAVE_LINUXPAM], [true])],
 309                 [AM_CONDITIONAL([HAVE_LINUXPAM], [false])], [
 310 #ifdef HAVE_SECURITY_PAM_APPL_H
 311 #include <security/pam_appl.h>
 312 #endif
 313 ])
 314
 315 AC_CHECK_HEADERS([linux/blkzoned.h])
 316
 317 AC_CHECK_HEADERS([security/openpam.h], [], [], [
 318 #ifdef HAVE_SECURITY_PAM_APPL_H
 319 #include <security/pam_appl.h>
 320 #endif
 321 ])
 322
 323 AC_CHECK_HEADERS([langinfo.h],
 324                 [AM_CONDITIONAL([HAVE_LANGINFO], [true])],
 325                 [AM_CONDITIONAL([HAVE_LANGINFO], [false])])
 326
 327 AC_MSG_CHECKING([whether langinfo.h defines ALTMON_x constants])
 328 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 329         #include <langinfo.h>
 330 ]], [[
 331         char *str;
 332         str = nl_langinfo (ALTMON_1);
 333         str = nl_langinfo (ALTMON_2);
 334         str = nl_langinfo (ALTMON_3);
 335         str = nl_langinfo (ALTMON_4);
 336         str = nl_langinfo (ALTMON_5);
 337         str = nl_langinfo (ALTMON_6);
 338         str = nl_langinfo (ALTMON_7);
 339         str = nl_langinfo (ALTMON_8);
 340         str = nl_langinfo (ALTMON_9);
 341         str = nl_langinfo (ALTMON_10);
 342         str = nl_langinfo (ALTMON_11);
 343         str = nl_langinfo (ALTMON_12);
 344 ]])], [
 345         AC_MSG_RESULT([yes])
 346         AC_DEFINE([HAVE_LANGINFO_ALTMON], [1],
 347                 [Define if langinfo.h defines ALTMON_x constants])
 348 ], [
 349         AC_MSG_RESULT([no])
 350 ])
 351
 352
 353 AC_MSG_CHECKING([whether langinfo.h defines _NL_ABALTMON_x constants])
 354 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 355         #include <langinfo.h>
 356 ]], [[
 357         char *str;
 358         str = nl_langinfo (_NL_ABALTMON_1);
 359         str = nl_langinfo (_NL_ABALTMON_2);
 360         str = nl_langinfo (_NL_ABALTMON_3);
 361         str = nl_langinfo (_NL_ABALTMON_4);
 362         str = nl_langinfo (_NL_ABALTMON_5);
 363         str = nl_langinfo (_NL_ABALTMON_6);
 364         str = nl_langinfo (_NL_ABALTMON_7);
 365         str = nl_langinfo (_NL_ABALTMON_8);
 366         str = nl_langinfo (_NL_ABALTMON_9);
 367         str = nl_langinfo (_NL_ABALTMON_10);
 368         str = nl_langinfo (_NL_ABALTMON_11);
 369         str = nl_langinfo (_NL_ABALTMON_12);
 370 ]])], [
 371         AC_MSG_RESULT([yes])
 372         AC_DEFINE([HAVE_LANGINFO_NL_ABALTMON], [1],
 373                 [Define if langinfo.h defines _NL_ABALTMON_x constants])
 374 ], [
 375         AC_MSG_RESULT([no])
 376 ])
 377
 378
 379 dnl Convert some ac_cv_header_* variables to have_*
 380 dnl
 381 have_linux_version_h=$ac_cv_header_linux_version_h
 382 have_linux_blkzoned_h=$ac_cv_header_linux_blkzoned_h
 383 have_linux_btrfs_h=$ac_cv_header_linux_btrfs_h
 384 have_linux_raw_h=$ac_cv_header_linux_raw_h
 385 have_linux_securebits_h=$ac_cv_header_linux_securebits_h
 386 have_linux_capability_h=$ac_cv_header_linux_capability_h
 387 have_linux_watchdog_h=$ac_cv_header_linux_watchdog_h
 388 have_security_pam_appl_h=$ac_cv_header_security_pam_appl_h
 389 have_security_pam_misc_h=$ac_cv_header_security_pam_misc_h
 390 have_security_openpam_h=$ac_cv_header_security_openpam_h
 391 have_shadow_h=$ac_cv_header_shadow_h
 392 have_sys_signalfd_h=$ac_cv_header_sys_signalfd_h
 393 have_utmpx_h=$ac_cv_header_utmpx_h
 394 have_pty_h=$ac_cv_header_pty_h
 395
 396 AS_CASE([$linux_os:$have_linux_version_h],
 397   [yes:no],
 398     [AC_MSG_ERROR([kernel headers required on Linux])]
 399 )
 400
 401 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 402 #include <time.h>
 403 #include <unistd.h>
 404 ]], [[
 405     int a = 0;
 406     struct tm *tm = localtime(0);
 407     if (a == -1)  /* false */
 408         sleep(tm->tm_gmtoff);
 409 ]])],
 410 [AC_DEFINE([HAVE_TM_GMTOFF], [1], [Does struct tm have a field tm_gmtoff?])
 411 ])
 412
 413 AC_CHECK_MEMBERS([struct termios.c_line],,,
 414     [[#include <termios.h>]])
 415
 416 AC_CHECK_MEMBERS([struct stat.st_mtim.tv_nsec],,,
 417         [#include <sys/stat.h>])
 418
 419 AC_CHECK_DECLS([_NL_TIME_WEEK_1STDAY],[],[],[[#include <langinfo.h>]])
 420
 421 AC_CHECK_DECL([llseek],
 422         [AC_DEFINE([HAVE_LLSEEK_PROTOTYPE], [1],
 423                         [Define to 1 if have llseek prototype])],
 424         [],
 425         [#include <unistd.h>])
 426
 427 AC_CHECK_DECL([lseek64],
 428         [AC_DEFINE([HAVE_LSEEK64_PROTOTYPE], [1],
 429                         [Define to 1 if have lseek64 prototype])],
 430         [],
 431         [#define _LARGEFILE_SOURCE
 432          #define _LARGEFILE64_SOURCE
 433          #include <unistd.h>])
 434
 435 AC_CHECK_DECL([environ],
 436         [AC_DEFINE([HAVE_ENVIRON_DECL], [1],
 437                 [Define to 1 if have **environ prototype])],
 438 )
 439
 440 AC_CHECK_DECL([strsignal],
 441         [AC_DEFINE([HAVE_STRSIGNAL_DECL], [1],
 442                 [Define to 1 if have strsignal function prototype])],
 443 )
 444
 445 AC_CHECK_DECL([TIOCGLCKTRMIOS],
 446               [have_tiocglcktrmios=yes], [have_tiocglcktrmios=no],
 447               [#include <sys/ioctl.h>])
 448 AC_CHECK_DECL([SOCK_CLOEXEC],
 449               [have_sock_cloexec=yes], [have_sock_cloexec=no],
 450               [#include <sys/types.h>
 451                #include <sys/socket.h>])
 452 AC_CHECK_DECL([SOCK_NONBLOCK],
 453               [have_sock_nonblock=yes], [have_sock_nonblock=no],
 454               [#include <sys/types.h>
 455                #include <sys/socket.h>])
 456 AC_CHECK_DECL([SO_PASSCRED],
 457               [have_so_passcred=yes], [have_so_passcred=no],
 458               [#include <sys/types.h>
 459                #include <sys/socket.h>])
 460
 461 AC_CHECK_FUNCS([ \
 462         clearenv \
 463         __fpurge \
 464         fpurge \
 465         __fpending \
 466         secure_getenv \
 467         __secure_getenv \
 468         eaccess \
 469         err \
 470         errx \
 471         explicit_bzero \
 472         fmemopen \
 473         fsync \
 474         utimensat \
 475         getdomainname \
 476         getdtablesize \
 477         getexecname \
 478         getmntinfo \
 479         getrandom \
 480         getrlimit \
 481         getsgnam \
 482         inotify_init \
 483         jrand48 \
 484         lchown \
 485         llseek \
 486         lseek64 \
 487         mempcpy \
 488         mkostemp \
 489         nanosleep \
 490         ntp_gettime \
 491         personality \
 492         posix_fadvise \
 493         prctl \
 494         qsort_r \
 495         rpmatch \
 496         scandirat \
 497         setprogname \
 498         setresgid \
 499         setresuid \
 500         sched_setattr \
 501         sched_setscheduler \
 502         sigqueue \
 503         srandom \
 504         strnchr \
 505         strndup \
 506         strnlen \
 507         sysconf \
 508         sysinfo \
 509         timegm \
 510         usleep \
 511         vwarnx \
 512         warn \
 513         warnx \
 514 ])
 515 AC_FUNC_FSEEKO
 516
 517 AC_CHECK_FUNCS([openat fstatat unlinkat], [have_openat=yes], [have_openat=no])
 518 AC_CHECK_FUNCS([ioperm iopl], [have_io=yes])
 519 AC_CHECK_FUNCS([futimens], [have_futimens=yes])
 520 AC_CHECK_FUNCS([inotify_init1], [have_inotify_init1=yes])
 521 AC_CHECK_FUNCS([open_memstream], [have_open_memstream=yes],[have_open_memstream=no])
 522 AC_CHECK_FUNCS([reboot], [have_reboot=yes],[have_reboot=no])
 523 AC_CHECK_FUNCS([updwtmpx updwtmpx], [have_gnu_utmpx=yes], [have_gnu_utmpx=no])
 524 AC_CHECK_FUNCS([getusershell], [have_getusershell=yes],[have_getusershell=no])
 525
 526 AM_CONDITIONAL([HAVE_OPENAT], [test "x$have_openat" = xyes])
 527
 528 have_setns_syscall="yes"
 529 UL_CHECK_SYSCALL([setns])
 530 AS_IF([test "x$ul_cv_syscall_setns" = xno], [
 531    have_setns_syscall="no"
 532 ])
 533
 534 AC_CHECK_FUNCS([isnan], [],
 535         [AC_CHECK_LIB([m], [isnan], [MATH_LIBS="-lm"])]
 536         [AC_CHECK_LIB([m], [__isnan], [MATH_LIBS="-lm"])]
 537 )
 538 AC_SUBST([MATH_LIBS])
 539
 540
 541 dnl lib/mononotic.c may require -lrt
 542 AC_CHECK_FUNCS([clock_gettime], [],
 543         [AC_CHECK_LIB([rt], [clock_gettime], [REALTIME_LIBS="-lrt"])]
 544 )
 545
 546 have_timer="no"
 547 AC_CHECK_FUNCS([timer_create],
 548         [have_timer="yes"],
 549         [AC_CHECK_LIB([rt], [timer_create], [
 550                 have_timer="yes"
 551                 REALTIME_LIBS="-lrt"
 552                 AC_DEFINE_UNQUOTED([HAVE_TIMER_CREATE], [1], [Define if timer_create exist in -lrt])
 553         ],[
 554                 AC_SEARCH_LIBS([timer_create], [rt], [
 555                         AC_MSG_RESULT(yes)
 556                         have_timer="yes"
 557                         REALTIME_LIBS="-lrt -lpthread"
 558                         AC_DEFINE_UNQUOTED([HAVE_TIMER_CREATE], [1], [Define if timer_create exist in -lrt -lpthread])
 559                 ],[], [-lpthread]
 560                 )
 561         ])]
 562 )
 563
 564 AC_SUBST([REALTIME_LIBS])
 565
 566 AS_IF([test x"$have_timer" = xno], [
 567        AC_CHECK_FUNCS([setitimer], [have_timer="yes"], [have_timer="no"])
 568 ])
 569
 570
 571 AC_CHECK_LIB([rtas], [rtas_get_sysparm], [
 572         RTAS_LIBS="-lrtas"
 573         AC_DEFINE_UNQUOTED([HAVE_LIBRTAS], [1], [Define if librtas exists]), [],
 574 ])
 575 AC_SUBST([RTAS_LIBS])
 576
 577
 578 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 579                 AC_DEFINE_UNQUOTED([HAVE_SA_LEN], [1], [Define if struct sockaddr contains sa_len]), [],
 580         [#include <sys/types.h>
 581          #include <sys/socket.h>])
 582
 583 SOCKET_LIBS=
 584 AC_SEARCH_LIBS([socket], [socket],
 585         [AS_IF([test x"$ac_cv_search_socket" != x"none required"],
 586                 [SOCKET_LIBS="$SOCKET_LIBS -lsocket"])
 587 ])
 588 AC_SUBST([SOCKET_LIBS])
 589
 590
 591 have_dirfd=no
 592 AC_CHECK_FUNCS([dirfd], [have_dirfd=yes], [have_dirfd=no])
 593 AS_IF([test x"$have_dirfd" = xno], [
 594         AC_CHECK_DECLS([dirfd],
 595                 [have_dirfd=yes], [have_dirfd=no],
 596                 [#include <sys/types.h>
 597                  #include <dirent.h>])
 598 ])
 599
 600 have_ddfd=no
 601 AS_IF([test x"$have_dirfd" = xno], [
 602         AC_CHECK_MEMBERS([DIR.dd_fd],
 603                 [have_ddfd=yes], [have_ddfd=no],
 604                 [#include <sys/types.h>
 605                  #include <dirent.h>])
 606 ])
 607
 608 AM_CONDITIONAL([HAVE_DIRFD], [test "x$have_dirfd" = xyes -o "x$have_ddfd" = xyes])
 609
 610
 611 AC_MSG_CHECKING([whether program_invocation_short_name is defined])
 612 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 613         #include <errno.h>
 614 ]], [[
 615         program_invocation_short_name = "test";
 616 ]])], [
 617         AC_MSG_RESULT([yes])
 618         AC_DEFINE([HAVE_PROGRAM_INVOCATION_SHORT_NAME], [1],
 619                 [Define if program_invocation_short_name is defined])
 620 ], [
 621         AC_MSG_RESULT([no])
 622 ])
 623
 624
 625 AC_MSG_CHECKING([whether __progname is defined])
 626 AC_LINK_IFELSE([AC_LANG_PROGRAM([extern char *__progname;],
 627            [if (*__progname == 0) return 1;])],
 628            AC_DEFINE([HAVE___PROGNAME], [1], [Define if __progname is defined])
 629            AC_MSG_RESULT([yes]),
 630            AC_MSG_RESULT([no]))
 631
 632 dnl Static compilation
 633 m4_define([UL_STATIC_PROGRAMS], [losetup, mount, umount, fdisk, sfdisk, blkid, nsenter, unshare])
 634
 635 AC_ARG_ENABLE([static-programs],
 636   [AS_HELP_STRING([--enable-static-programs=LIST],
 637       [link static the programs in LIST (comma-separated,
 638       supported for ]m4_defn([UL_STATIC_PROGRAMS])[)])])
 639
 640 AS_CASE([$enable_static_programs],
 641   [yes],
 642     [enable_static_programs=m4_quote(UL_STATIC_PROGRAMS)],
 643   [no],
 644     [enable_static_programs=]
 645 )
 646
 647 dnl Set all the individual AM_CONDITIONALs
 648 m4_foreach([UL_PRG], m4_defn([UL_STATIC_PROGRAMS]), [
 649   AS_CASE([,$enable_static_programs,],
 650    [*,UL_PRG,*], [static_[]UL_PRG=yes]
 651   )
 652   AS_IF([test "x$static_[]UL_PRG" = xyes], [AC_MSG_NOTICE([enable static build: UL_PRG.])])
 653   AM_CONDITIONAL([HAVE_STATIC_]m4_toupper(UL_PRG),
 654     [test "x$static_[]UL_PRG" = xyes])
 655 ])
 656
 657
 658 AC_ARG_ENABLE([all-programs],
 659   AS_HELP_STRING([--disable-all-programs], [disable everything, might be overridden by --enable-<name>]),
 660   [], [enable_all_programs=undefined]
 661 )
 662
 663 AS_CASE([$enable_all_programs],
 664   [yes], [AC_MSG_WARN([force to build all programs by default])
 665           ul_default_estate=check],
 666   [no],  [AC_MSG_WARN([disable all programs by default])
 667           ul_default_estate=no]
 668 )
 669
 670
 671 AX_CHECK_TLS
 672
 673 AC_DEFUN([UL_SCANF_TYPE_MODIFIER], [dnl
 674 # include <stdio.h>
 675 # include <stdlib.h>
 676 int main()
 677 {
 678         int i;
 679         int rc = 1;
 680         char *s;
 681         i = sscanf("x", $1, &s);
 682         if (i == 1  && *s == 'x')
 683                 rc = 0;
 684         free(s);
 685         return rc;
 686 }])
 687
 688 AC_CACHE_VAL([scanf_cv_alloc_modifier],
 689   AC_RUN_IFELSE([AC_LANG_SOURCE([UL_SCANF_TYPE_MODIFIER(["%ms"])])],
 690     [scanf_cv_alloc_modifier=ms],
 691     AC_RUN_IFELSE([AC_LANG_SOURCE([UL_SCANF_TYPE_MODIFIER(["%as"])])],
 692       [scanf_cv_alloc_modifier=as],
 693       [scanf_cv_alloc_modifier=no]
 694     )
 695     ,
 696
 697     [AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 698      #include <stdio.h>
 699      #include <unistd.h>
 700
 701      #if defined(__GLIBC__) && !defined(__UCLIBC__)
 702
 703      #if !(__GLIBC_PREREQ(2, 7))
 704      #error %m is not available
 705      #endif
 706
 707      #elif defined(_POSIX_VERSION)
 708
 709      #if _POSIX_VERSION < 200809L
 710      #error %m is not available
 711      #endif
 712
 713      #else
 714      #error Your C-library is not supported.
 715      #endif
 716      ])],
 717     [scanf_cv_alloc_modifier=ms],
 718     [scanf_cv_alloc_modifier=no])]
 719   )
 720 )
 721
 722 AC_MSG_CHECKING([scanf string alloc modifiers])
 723 AS_CASE([$scanf_cv_alloc_modifier],
 724   [ms],
 725     [AC_MSG_RESULT([(%ms) yes])
 726      AC_DEFINE([HAVE_SCANF_MS_MODIFIER], [1], [scanf %ms modifier])
 727      have_scanf_alloc_modifier=yes],
 728   [as],
 729     [AC_MSG_RESULT([(%as) yes])
 730      have_scanf_alloc_modifier=yes
 731      AC_DEFINE([HAVE_SCANF_AS_MODIFIER], [1], [scanf %as modifier])],
 732   [AC_MSG_RESULT([no])
 733    have_scanf_alloc_modifier=no]
 734 )
 735
 736
 737 AC_ARG_WITH([util], AS_HELP_STRING([--without-util], [compile without libutil]),
 738   [], [with_util=auto]
 739 )
 740 AS_IF([test "x$with_util" = xno], [
 741   AM_CONDITIONAL([HAVE_UTIL], [false])
 742   have_util=no
 743 ], [
 744   UL_CHECK_LIB([util], [openpty])
 745 ])
 746
 747 AS_IF([test "x$have_pty_h" = xyes -a "x$have_sys_signalfd_h" = xyes -a "x$have_util" = xyes], [
 748    AM_CONDITIONAL([HAVE_PTY], [true])
 749    AC_DEFINE([HAVE_PTY], [1], [have PTY support])
 750 ], [
 751    AM_CONDITIONAL([HAVE_PTY], [false])
 752 ])
 753
 754 AC_CHECK_TYPES([union semun], [], [], [[
 755 #include <sys/sem.h>
 756 ]])
 757 AC_CHECK_TYPES([loff_t])
 758
 759
 760 AC_ARG_ENABLE([widechar],
 761   AS_HELP_STRING([--disable-widechar], [do not compile wide character support]),
 762   [], [enable_widechar=check]
 763 )
 764 UL_BUILD_INIT([widechar])
 765 UL_REQUIRES_COMPILE([widechar], [[
 766   #include <wchar.h>
 767   #include <wctype.h>
 768   #include <stdio.h>
 769   #include <stdlib.h>
 770   ]], [[
 771     wchar_t wc;
 772     wint_t w;
 773     w = fgetwc(stdin);
 774     if (w == WEOF) exit(1);
 775     wc = w;
 776     fputwc(wc,stdout);
 777   ]],
 778   [wchar_t support])
 779
 780 AS_IF([test "x$build_widechar" = xyes ], [
 781   AC_DEFINE([HAVE_WIDECHAR], [1], [Do we have wide character support?])
 782 ])
 783
 784
 785 AC_CHECK_TYPES([cpu_set_t], [have_cpu_set_t=yes], [], [[
 786 #include <sched.h>
 787 ]])
 788
 789 AM_CONDITIONAL([HAVE_CPU_SET_T], [test "x$have_cpu_set_t" = xyes])
 790
 791 AC_CHECK_TYPES([sighandler_t], [], [], [[
 792 #include <signal.h>
 793 ]])
 794
 795 AC_CHECK_DECLS([CPU_ALLOC], [], [], [[
 796 #include <sched.h>
 797 ]])
 798
 799 # on Solaris, you can't mix and match standards, since we use c99
 800 # apparently at this stage, XOPEN_SOURCE will conflict.  As workaround,
 801 # check for crypt.h and use that without XOPEN_SOURCE.
 802 have_crypt=no
 803 AC_CHECK_HEADERS([crypt.h])
 804 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 805 #ifdef HAVE_CRYPT_H
 806 #include <crypt.h>
 807 #else
 808 #define _XOPEN_SOURCE
 809 #include <unistd.h>
 810 #endif
 811 ]], [[
 812 char *c = crypt("abc","pw");
 813 ]])],[
 814   have_libcrypt=no
 815   have_crypt=yes
 816 ],[
 817   LIBS="$LIBS -lcrypt"
 818   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 819   #ifdef HAVE_CRYPT_H
 820   #include <crypt.h>
 821   #else
 822   #define _XOPEN_SOURCE
 823   #include <unistd.h>
 824   #endif
 825   ]], [[
 826   char *c = crypt("abc","pw");
 827   ]])],[
 828   AC_DEFINE([HAVE_LIBCRYPT], [1], [Do we need -lcrypt?])
 829   have_libcrypt=yes
 830   have_crypt=yes
 831   ],[
 832   AC_MSG_WARN([crypt() is not available])
 833   ])
 834 ])
 835 AM_CONDITIONAL([HAVE_LIBCRYPT], [test "x$have_libcrypt" = xyes])
 836
 837
 838 AC_ARG_WITH([selinux],
 839   AS_HELP_STRING([--with-selinux], [compile with SELinux support]),
 840   [], [with_selinux=no]
 841 )
 842
 843 AS_IF([test "x$with_selinux" = xno], [
 844   AM_CONDITIONAL([HAVE_SELINUX], [false])
 845 ], [
 846   PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.0],
 847         [AC_DEFINE([HAVE_LIBSELINUX], [1], [Define if SELinux is available])
 848          UL_PKG_STATIC([SELINUX_LIBS_STATIC], [libselinux])
 849          AM_CONDITIONAL([HAVE_SELINUX], [true])
 850          have_selinux=yes],
 851         [have_selinux=no])
 852
 853   AS_CASE([$with_selinux:$have_selinux],
 854     [yes:no], [AC_MSG_ERROR([SELinux selected but libselinux not found or too old])]
 855   )
 856
 857   AS_IF([test "x$have_selinux" = xyes], [
 858     UL_SET_FLAGS([], [], [$SELINUX_LIBS])
 859     # This function is missing in old libselinux 1.xx versions
 860     AC_CHECK_FUNCS([security_get_initial_context])
 861     UL_RESTORE_FLAGS
 862   ])
 863 ])
 864 AC_SUBST([SELINUX_LIBS])
 865 AC_SUBST([SELINUX_LIBS_STATIC])
 866
 867
 868 AC_ARG_WITH([audit],
 869   AS_HELP_STRING([--with-audit], [compile with audit support]),
 870   [], [with_audit=no]
 871 )
 872
 873 AS_IF([test "x$with_audit" = xno], [
 874   AM_CONDITIONAL([HAVE_AUDIT], [false])
 875 ], [
 876   UL_CHECK_LIB([audit], [audit_log_user_message])
 877   AS_CASE([$with_audit:$have_audit],
 878     [yes:no],
 879       [AC_MSG_ERROR([Audit selected but libaudit not found (or does not support audit_log_user_message())])]
 880   )
 881 ])
 882
 883 AC_ARG_WITH([udev], AS_HELP_STRING([--without-udev], [compile without udev support]),
 884   [], [with_udev=auto]
 885 )
 886
 887 AS_IF([test "x$with_udev" = xno], [
 888   AM_CONDITIONAL([HAVE_UDEV], [false])
 889 ], [
 890   UL_CHECK_LIB([udev], [udev_new])
 891   AS_CASE([$with_udev:$have_udev],
 892     [yes:no],
 893       [AC_MSG_ERROR([udev selected but libudev not found])]
 894   )
 895 ])
 896
 897
 898 dnl wide-char ncurses
 899 AC_ARG_WITH([ncursesw],
 900   AS_HELP_STRING([--without-ncursesw], [do not build with wide-char ncurses]),
 901   [], [with_ncursesw=auto]
 902 )
 903 have_ncursesw=no
 904 have_ncursesw_header=no
 905 AS_IF([test "x$with_ncursesw" != xno], [
 906   UL_NCURSES_CHECK([ncursesw])
 907   AS_IF([test "x$have_ncursesw" = xyes], [
 908     AC_CHECK_HEADERS([ncursesw/ncurses.h], [have_ncursesw_header=yes])
 909     AC_CHECK_HEADERS([ncursesw/term.h])
 910
 911     # Define HAVE_NCURSES_H only if check for HAVE_NCURSESW_NCURSES_H is
 912     # unsuccessful to avoid too many *_H permitations in config.h
 913     AS_IF([test "x$have_ncursesw_header" = xno], [
 914            AC_CHECK_HEADERS([ncurses.h], [have_ncursesw_header=yes])
 915            AC_CHECK_HEADERS([term.h])
 916     ])
 917     AS_IF([test "x$have_ncursesw_header" = xno], [have_ncursesw=no])
 918   ])
 919   AS_IF([test "x$have_ncursesw" = xyes], [
 920     CURSES_LIB_NAME="ncursesw"
 921     AC_DEFINE([HAVE_LIBNCURSESW], [1], [Define if ncursesw library available])
 922   ])
 923 ])
 924 AS_CASE([$with_ncursesw:$have_ncursesw],
 925   [yes:no], [AC_MSG_ERROR([ncursesw selected, but library not found])])
 926
 927
 928 dnl non-wide ncurses
 929 AC_ARG_WITH([ncurses],
 930   AS_HELP_STRING([--with-ncurses], [build with non-wide ncurses]),
 931   [], [with_ncurses=auto]
 932 )
 933 have_ncurses=no
 934 have_ncurses_header=no
 935 AS_CASE([$with_ncurses:$build_widechar],
 936   [yes:yes], [AC_MSG_ERROR([wide-char support enabled, but non-wide ncurses selects])])
 937
 938 AS_IF([test "x$have_ncursesw" = xno -a "x$with_ncurses" != xno ], [
 939   UL_NCURSES_CHECK([ncurses])
 940   AS_IF([test "x$have_ncurses" = xyes], [
 941     AC_CHECK_HEADERS([ncurses/ncurses.h], [have_ncurses_header=yes])
 942     AC_CHECK_HEADERS([ncurses/term.h])
 943
 944     # Define HAVE_NCURSES_H only if check for HAVE_NCURSES_NCURSES_H is
 945     # unsuccessful to avoid too many *_H permitations in config.h
 946     AS_IF([test "x$have_ncurses_header" = xno], [
 947            AC_CHECK_HEADERS([ncurses.h], [have_ncurses_header=yes])
 948            AC_CHECK_HEADERS([term.h])
 949     ])
 950     AS_IF([test "x$have_ncurses_header" = xno], [have_ncurses=no])
 951   ])
 952   AS_IF([test "x$have_ncurses" = xyes], [
 953     CURSES_LIB_NAME="ncurses"
 954     AC_DEFINE([HAVE_LIBNCURSES], [1], [Define if ncurses library available])
 955   ])
 956 ])
 957 AS_CASE([$with_ncurses:$have_ncurses],
 958   [yes:no], [AC_MSG_ERROR([ncurses selected, but library not found])])
 959
 960 AC_SUBST([NCURSES_CFLAGS])
 961 AC_SUBST([NCURSES_LIBS])
 962 AM_CONDITIONAL([HAVE_NCURSES], [test "x$have_ncursesw" = xyes -o  "x$have_ncurses" = xyes])
 963
 964
 965 AC_ARG_WITH([slang],
 966   AS_HELP_STRING([--with-slang], [compile cfdisk with slang rather than ncurses]),
 967   [], [with_slang=no]
 968 )
 969 have_slang=no
 970 AS_IF([test "x$with_slang" = xyes], [
 971   AC_CHECK_HEADERS([slang.h slang/slang.h])
 972   AC_CHECK_HEADERS([slcurses.h slang/slcurses.h],
 973                    [have_slang=yes], [], [
 974 #ifdef HAVE_SLANG_H
 975 #include <slang.h>
 976 #elif defined(HAVE_SLANG_SLANG_H)
 977 #include <slang/slang.h>
 978 #endif
 979 ])
 980   AS_IF([test "x$have_slang" = xno], [
 981     AC_MSG_ERROR([slang selected but slcurses.h not found])],
 982     [CURSES_LIB_NAME=slang
 983   ])
 984 ])
 985 AM_CONDITIONAL([HAVE_SLANG], [test "x$have_slang" = xyes])
 986
 987
 988 AS_IF([test "x$have_slang" = xyes -o "x$have_ncursesw" = xyes -o "x$have_ncurses" = xyes], [
 989         AC_CHECK_LIB([$CURSES_LIB_NAME], use_default_colors, [
 990                      AC_DEFINE(HAVE_USE_DEFAULT_COLORS, 1,
 991                                [Define if curses library has the use_default_colors().])
 992         ])
 993         AC_CHECK_LIB([$CURSES_LIB_NAME], resizeterm, [
 994                      AC_DEFINE(HAVE_RESIZETERM, 1,
 995                                [Define if curses library has the resizeterm().])
 996         ])
 997 ])
 998
 999
1000 AC_ARG_WITH([tinfo], AS_HELP_STRING([--without-tinfo], [compile without libtinfo]),
1001   [], [with_tinfo=auto]
1002 )
1003 have_tinfo=no
1004 have_tinfow=no
1005 AS_IF([test "x$with_tinfo" != xno], [
1006   AS_IF([test "x$have_ncursesw" = xyes], [
1007     UL_TINFO_CHECK([tinfow])
1008   ])
1009   AS_IF([test "x$have_tinfow" = xno], [
1010     UL_TINFO_CHECK([tinfo])
1011   ])
1012 ])
1013 AC_SUBST([TINFO_LIBS])
1014 AC_SUBST([TINFO_LIBS_STATIC])
1015 AC_SUBST([TINFO_CFLAGS])
1016 AM_CONDITIONAL([HAVE_TINFO], [test "x$have_tinfo" = xyes -o "x$have_tinfow" = xyes])
1017 AS_IF([test "x$have_tinfo" = xyes -o "x$have_tinfow" = xyes], [
1018   AC_DEFINE(HAVE_LIBTINFO, 1, [Define if libtinfo or libtinfow available.])
1019 ])
1020
1021
1022 AC_ARG_WITH([readline],
1023   AS_HELP_STRING([--without-readline], [do not build with GNU Readline support]),
1024   [], [with_readline=auto]
1025 )
1026
1027 AS_IF([test "x$with_readline" = xno], [
1028   AM_CONDITIONAL([HAVE_READLINE], [false])
1029 ], [
1030   UL_CHECK_LIB([readline], [readline])
1031   AS_CASE([$with_readline:$have_readline],
1032     [yes:no],
1033       [AC_MSG_ERROR([readline selected but libreadline not found ])],
1034     [*:yes],
1035       [READLINE_LIBS="-lreadline"
1036        READLINE_LIBS_STATIC="-lreadline $TINFO_LIBS_STATIC"]
1037   )
1038 ])
1039 AC_SUBST([READLINE_LIBS])
1040 AC_SUBST([READLINE_LIBS_STATIC])
1041
1042
1043 AC_ARG_WITH([utempter],
1044   AS_HELP_STRING([--with-utempter], [compile script(1) with libutempter]),
1045   [], [with_utempter=no]
1046 )
1047
1048 AS_IF([test "x$with_utempter" = xyes], [
1049   UL_CHECK_LIB([utempter], [utempter_add_record])
1050   AS_IF([test "x$have_utempter" = xno], [
1051     AC_MSG_ERROR([utempter selected but libutempter not found])
1052   ])
1053 ], [
1054   AM_CONDITIONAL([HAVE_UTEMPTER], [false])
1055 ])
1056
1057
1058 dnl
1059 dnl libuuid
1060 dnl
1061 AC_ARG_ENABLE([libuuid],
1062   AS_HELP_STRING([--disable-libuuid], [do not build libuuid and uuid utilities]),
1063   [], [UL_DEFAULT_ENABLE([libuuid], [yes])]
1064 )
1065 UL_BUILD_INIT([libuuid])
1066 AC_SUBST([LIBUUID_VERSION])
1067 AC_SUBST([LIBUUID_VERSION_INFO])
1068 AM_CONDITIONAL(BUILD_LIBUUID, test "x$build_libuuid" = xyes)
1069
1070 AC_ARG_ENABLE([libuuid-force-uuidd],
1071   AS_HELP_STRING([--enable-libuuid-force-uuidd], [support uuidd even though the daemon is not built]),
1072   [], [enable_libuuid_force_uuidd=no]
1073 )
1074
1075 AS_IF([test "x$build_libuuid" = xyes], [
1076   AC_DEFINE(HAVE_LIBUUID, 1, [Define to 1 if you have the -luuid.])
1077 ])
1078
1079 dnl
1080 dnl libblkid
1081 dnl
1082 AC_ARG_ENABLE([libblkid],
1083   AS_HELP_STRING([--disable-libblkid], [do not build libblkid and many related utilities]),
1084   [], [UL_DEFAULT_ENABLE([libblkid], [check])]
1085 )
1086 UL_BUILD_INIT([libblkid])
1087 UL_REQUIRES_HAVE([libblkid], [openat], [openat functions])
1088 UL_REQUIRES_HAVE([libblkid], [dirfd,ddfd], [dirfd or ddfd function])
1089 AC_SUBST([LIBBLKID_DATE])
1090 AC_SUBST([LIBBLKID_VERSION])
1091 AC_SUBST([LIBBLKID_VERSION_INFO])
1092 AC_DEFINE_UNQUOTED([LIBBLKID_VERSION], ["$LIBBLKID_VERSION"], [libblkid version string])
1093 AC_DEFINE_UNQUOTED([LIBBLKID_DATE], ["$LIBBLKID_DATE"], [libblkid date string])
1094 AS_IF([test "x$build_libblkid" = xyes], [
1095   AC_DEFINE([HAVE_LIBBLKID], [1], [Define to 1 if you have the -lblkid.])
1096 ])
1097 AM_CONDITIONAL([BUILD_LIBBLKID], [test "x$build_libblkid" = xyes])
1098 AM_CONDITIONAL([BUILD_LIBBLKID_TESTS], [test "x$build_libblkid" = xyes -a "x$enable_static" = xyes])
1099
1100 dnl
1101 dnl libmount
1102 dnl
1103 AC_ARG_ENABLE([libmount],
1104   AS_HELP_STRING([--disable-libmount], [do not build libmount]),
1105   [], [UL_DEFAULT_ENABLE([libmount], [check])]
1106 )
1107 UL_BUILD_INIT([libmount])
1108 UL_REQUIRES_BUILD([libmount], [libblkid])
1109 UL_REQUIRES_HAVE([libmount], [scanf_alloc_modifier], [scanf string alloc modifier])
1110 UL_REQUIRES_HAVE([libmount], [dirfd,ddfd], [dirfd or ddfd function])
1111 AM_CONDITIONAL([BUILD_LIBMOUNT], [test "x$build_libmount" = xyes])
1112 AM_CONDITIONAL([BUILD_LIBMOUNT_TESTS], [test "x$build_libmount" = xyes -a "x$enable_static" = xyes])
1113 AS_IF([test "x$build_libmount" = xyes], [
1114   AC_DEFINE(HAVE_LIBMOUNT, 1, [Define if libmount available.])
1115   AS_IF([test "x$have_setns_syscall" = "xyes"], [
1116     AC_DEFINE([USE_LIBMOUNT_SUPPORT_NAMESPACES], [1], [Define to 1 if want to support namepaces.])
1117   ],[
1118     AC_MSG_WARN([libmount will be compiled without namespaces support])
1119   ])
1120 ])
1121
1122 AC_SUBST([LIBMOUNT_VERSION])
1123 AC_SUBST([LIBMOUNT_MAJOR_VERSION], $PACKAGE_VERSION_MAJOR)
1124 AC_SUBST([LIBMOUNT_MINOR_VERSION], $PACKAGE_VERSION_MINOR)
1125 AC_SUBST([LIBMOUNT_PATCH_VERSION], $PACKAGE_VERSION_RELEASE)
1126 AC_SUBST([LIBMOUNT_VERSION_INFO])
1127 AC_DEFINE_UNQUOTED([LIBMOUNT_VERSION], ["$LIBMOUNT_VERSION"], [libmount version string])
1128
1129 AC_ARG_ENABLE([libmount-support-mtab],
1130   AS_HELP_STRING([--enable-libmount-support-mtab], [support /etc/mtab (default is use /proc/self/mountinfo)]),
1131   [], [enable_libmount_support_mtab=no]
1132 )
1133
1134 AS_IF([test "x$enable_libmount_support_mtab" = xyes], [
1135   AC_DEFINE([USE_LIBMOUNT_SUPPORT_MTAB], [1], [Define to 1 if want to support mtab.])
1136 ])
1137
1138 dnl
1139 dnl libsmartcols
1140 dnl
1141 AC_ARG_ENABLE([libsmartcols],
1142   AS_HELP_STRING([--disable-libsmartcols], [do not build libsmartcols]),
1143   [], [UL_DEFAULT_ENABLE([libsmartcols], [yes])]
1144 )
1145 UL_BUILD_INIT([libsmartcols])
1146 AM_CONDITIONAL([BUILD_LIBSMARTCOLS], [test "x$build_libsmartcols" = xyes])
1147
1148 AC_SUBST([LIBSMARTCOLS_VERSION])
1149 AC_SUBST([LIBSMARTCOLS_VERSION_INFO])
1150 AC_DEFINE_UNQUOTED([LIBSMARTCOLS_VERSION], ["$LIBSMARTCOLS_VERSION"], [libsmartcols version string])
1151
1152
1153 dnl
1154 dnl libfdisk
1155 dnl
1156 AC_ARG_ENABLE([libfdisk],
1157   AS_HELP_STRING([--disable-libfdisk], [do not build libfdisk]),
1158   [], [UL_DEFAULT_ENABLE([libfdisk], [check])]
1159 )
1160 UL_BUILD_INIT([libfdisk])
1161 UL_REQUIRES_BUILD([libfdisk], [libuuid])
1162 AM_CONDITIONAL([BUILD_LIBFDISK], [test "x$build_libfdisk" = xyes])
1163 AM_CONDITIONAL([BUILD_LIBFDISK_TESTS], [test "x$build_libfdisk" = xyes -a "x$enable_static" = xyes])
1164
1165 AS_IF([test "x$build_libblkid" = xyes],
1166   [LIBFDISK_PC_REQUIRES="uuid blkid"],[LIBFDISK_PC_REQUIRES="uuid"])
1167 AC_SUBST([LIBFDISK_PC_REQUIRES])
1168
1169 AC_SUBST([LIBFDISK_VERSION])
1170 AC_SUBST([LIBFDISK_MAJOR_VERSION], $PACKAGE_VERSION_MAJOR)
1171 AC_SUBST([LIBFDISK_MINOR_VERSION], $PACKAGE_VERSION_MINOR)
1172 AC_SUBST([LIBFDISK_PATCH_VERSION], $PACKAGE_VERSION_RELEASE)
1173 AC_SUBST([LIBFDISK_VERSION_INFO])
1174 AC_DEFINE_UNQUOTED([LIBFDISK_VERSION], ["$LIBFDISK_VERSION"], [libfdisk version string])
1175
1176
1177 AC_ARG_ENABLE([fdisks],
1178   AS_HELP_STRING([--disable-fdisks], [do not build fdisk(8), sfdisk(8) and cfdisk(8)]),
1179   [], [UL_DEFAULT_ENABLE([fdisks], [check])]
1180 )
1181 enable_fdisk=$enable_fdisks
1182 enable_sfdisk=$enable_fdisks
1183 enable_cfdisk=$enable_fdisks
1184
1185 UL_BUILD_INIT([fdisk])
1186 UL_REQUIRES_HAVE([fdisk], [openat], [openat functions])
1187 UL_REQUIRES_HAVE([fdisk], [dirfd,ddfd], [dirfd or ddfd function])
1188 UL_REQUIRES_BUILD([fdisk], [libfdisk])
1189 UL_REQUIRES_BUILD([fdisk], [libsmartcols])
1190 AM_CONDITIONAL([BUILD_FDISK], [test "x$build_fdisk" = xyes])
1191
1192
1193 UL_BUILD_INIT([sfdisk])
1194 UL_REQUIRES_HAVE([sfdisk], [openat], [openat functions])
1195 UL_REQUIRES_HAVE([sfdisk], [dirfd,ddfd], [dirfd or ddfd function])
1196 UL_REQUIRES_BUILD([sfdisk], [libfdisk])
1197 UL_REQUIRES_BUILD([sfdisk], [libsmartcols])
1198 AM_CONDITIONAL([BUILD_SFDISK], [test "x$build_sfdisk" = xyes])
1199
1200
1201 UL_BUILD_INIT([cfdisk])
1202 UL_REQUIRES_BUILD([cfdisk], [libfdisk])
1203 UL_REQUIRES_BUILD([cfdisk], [libsmartcols])
1204 UL_REQUIRES_HAVE([cfdisk], [open_memstream], [open_memstream function])
1205 UL_REQUIRES_HAVE([cfdisk], [ncursesw,slang,ncurses], [ncursesw, ncurses or slang library])
1206 AM_CONDITIONAL([BUILD_CFDISK], [test "x$build_cfdisk" = xyes])
1207
1208
1209 AC_ARG_ENABLE([mount],
1210   AS_HELP_STRING([--disable-mount], [do not build mount(8) and umount(8)]),
1211   [], [UL_DEFAULT_ENABLE([mount], [check])]
1212 )
1213 UL_BUILD_INIT([mount])
1214 UL_REQUIRES_LINUX([mount])
1215 UL_REQUIRES_BUILD([mount], [libmount])
1216 AM_CONDITIONAL([BUILD_MOUNT], [test "x$build_mount" = xyes])
1217
1218
1219 AC_ARG_ENABLE([losetup],
1220   AS_HELP_STRING([--disable-losetup], [do not build losetup]),
1221   [], [UL_DEFAULT_ENABLE([losetup], [check])]
1222 )
1223 UL_BUILD_INIT([losetup])
1224 UL_REQUIRES_LINUX([losetup])
1225 UL_REQUIRES_BUILD([losetup], [libsmartcols])
1226 AM_CONDITIONAL([BUILD_LOSETUP], [test "x$build_losetup" = xyes])
1227
1228 AC_ARG_ENABLE([zramctl],
1229   AS_HELP_STRING([--disable-zramctl], [do not build zramctl]),
1230   [], [UL_DEFAULT_ENABLE([zramctl], [check])]
1231 )
1232 UL_BUILD_INIT([zramctl])
1233 UL_REQUIRES_LINUX([zramctl])
1234 UL_REQUIRES_BUILD([zramctl], [libsmartcols])
1235 AM_CONDITIONAL([BUILD_ZRAMCTL], [test "x$build_zramctl" = xyes])
1236
1237 AC_ARG_ENABLE([fsck],
1238   AS_HELP_STRING([--disable-fsck], [do not build fsck]),
1239   [], [UL_DEFAULT_ENABLE([fsck], [check])]
1240 )
1241 UL_BUILD_INIT([fsck])
1242 UL_REQUIRES_BUILD([fsck], [libmount])
1243 AM_CONDITIONAL([BUILD_FSCK], [test "x$build_fsck" = xyes])
1244
1245
1246 AC_ARG_ENABLE([partx],
1247   AS_HELP_STRING([--disable-partx], [do not build addpart, delpart, partx]),
1248   [], [UL_DEFAULT_ENABLE([partx], [check])]
1249 )
1250 UL_BUILD_INIT([partx])
1251 UL_REQUIRES_LINUX([partx])
1252 UL_REQUIRES_BUILD([partx], [libblkid])
1253 UL_REQUIRES_BUILD([partx], [libsmartcols])
1254 AM_CONDITIONAL([BUILD_PARTX], [test "x$build_partx" = xyes])
1255
1256
1257 AC_ARG_ENABLE([uuidd],
1258   AS_HELP_STRING([--disable-uuidd], [do not build the uuid daemon]),
1259   [], [UL_DEFAULT_ENABLE([uuidd], [check])]
1260 )
1261 UL_BUILD_INIT([uuidd])
1262 UL_REQUIRES_BUILD([uuidd], [libuuid])
1263 UL_REQUIRES_HAVE([uuidd], [timer], [timer_create function])
1264 UL_REQUIRES_HAVE([uuidd], [sys_signalfd_h], [sys/signalfd.h header])
1265 AS_IF([test "x$build_uuidd" = xyes || test "x$enable_libuuid_force_uuidd" = xyes], [
1266   AC_DEFINE([HAVE_UUIDD], [1], [Define to 1 if you want to use uuid daemon.])
1267 ])
1268 AM_CONDITIONAL([BUILD_UUIDD], [test "x$build_uuidd" = xyes])
1269
1270
1271 UL_BUILD_INIT([uuidgen], [check])
1272 UL_REQUIRES_BUILD([uuidgen], [libuuid])
1273 AM_CONDITIONAL([BUILD_UUIDGEN], [test "x$build_uuidgen" = xyes])
1274
1275 UL_BUILD_INIT([uuidparse], [check])
1276 UL_REQUIRES_BUILD([uuidparse], [libuuid])
1277 UL_REQUIRES_BUILD([uuidparse], [libsmartcols])
1278 AM_CONDITIONAL([BUILD_UUIDPARSE], [test "x$build_uuidparse" = xyes])
1279
1280 UL_BUILD_INIT([blkid], [check])
1281 UL_REQUIRES_BUILD([blkid], [libblkid])
1282 AM_CONDITIONAL([BUILD_BLKID], [test "x$build_blkid" = xyes])
1283
1284 UL_BUILD_INIT([findfs], [check])
1285 UL_REQUIRES_BUILD([findfs], [libblkid])
1286 AM_CONDITIONAL([BUILD_FINDFS], [test "x$build_findfs" = xyes])
1287
1288 UL_BUILD_INIT([wipefs], [check])
1289 UL_REQUIRES_BUILD([wipefs], [libblkid])
1290 UL_REQUIRES_BUILD([wipefs], [libsmartcols])
1291 AM_CONDITIONAL([BUILD_WIPEFS], [test "x$build_wipefs" = xyes])
1292
1293 UL_BUILD_INIT([findmnt], [check])
1294 UL_REQUIRES_BUILD([findmnt], [libmount])
1295 UL_REQUIRES_BUILD([findmnt], [libblkid])
1296 UL_REQUIRES_BUILD([findmnt], [libsmartcols])
1297 AM_CONDITIONAL([BUILD_FINDMNT], [test "x$build_findmnt" = xyes])
1298
1299
1300 AC_ARG_ENABLE([mountpoint],
1301   AS_HELP_STRING([--disable-mountpoint], [do not build mountpoint]),
1302   [], [UL_DEFAULT_ENABLE([mountpoint], [check])]
1303 )
1304 UL_BUILD_INIT([mountpoint])
1305 UL_REQUIRES_BUILD([mountpoint], [libmount])
1306 AM_CONDITIONAL([BUILD_MOUNTPOINT], [test "x$build_mountpoint" = xyes])
1307
1308
1309 AC_ARG_ENABLE([fallocate],
1310   AS_HELP_STRING([--disable-fallocate], [do not build fallocate]),
1311   [], [UL_DEFAULT_ENABLE([fallocate], [check])]
1312 )
1313 UL_BUILD_INIT([fallocate])
1314 UL_REQUIRES_LINUX([fallocate])
1315 UL_REQUIRES_SYSCALL_CHECK([fallocate], [UL_CHECK_SYSCALL([fallocate])])
1316 AM_CONDITIONAL([BUILD_FALLOCATE], [test "x$build_fallocate" = xyes])
1317
1318 AS_IF([test "x$build_fallocate" = xyes], [
1319   dnl check for valid fallocate() function
1320   dnl with 32 bits glibc 2.10, fallocate() exists but not fallocate64()
1321   dnl when _FILE_OFFSET_BITS==64, fallocate() is redirect to fallocate64()
1322   dnl and program can't be linked.
1323   dnl AC_CHECK_FUNC can't catch such errors since it's redefining
1324   dnl function prototype.
1325   AC_MSG_CHECKING([for valid fallocate() function])
1326   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1327 #ifdef HAVE_UNISTD_H
1328 # include <unistd.h>
1329 #endif
1330 #ifdef HAVE_SYS_TYPES_H
1331 # include <sys/types.h>
1332 #endif
1333 #ifdef HAVE_LINUX_FALLOC_H
1334 # include <linux/falloc.h>
1335 #endif
1336 #ifdef HAVE_FCNTL_H
1337 # include <fcntl.h>
1338 #endif
1339 ]],[[
1340    long ret;
1341    ret = fallocate(0, FALLOC_FL_KEEP_SIZE, 0xfffffffful, 0xfffffffful);
1342    if (ret != 0) {
1343       return 1;
1344    }
1345    ]])],[
1346   AC_MSG_RESULT([yes])
1347   AC_DEFINE([HAVE_FALLOCATE], [1], [Have valid fallocate() function])],[
1348   AC_MSG_RESULT([no])])
1349 ])
1350
1351 AS_IF([test "x$build_fallocate" = xyes], [
1352   dnl check for valid posix_fallocate() function
1353   AC_MSG_CHECKING([for valid posix_fallocate() function])
1354   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1355 #ifdef HAVE_UNISTD_H
1356 # include <unistd.h>
1357 #endif
1358 #ifdef HAVE_SYS_TYPES_H
1359 # include <sys/types.h>
1360 #endif
1361 #ifdef HAVE_LINUX_FALLOC_H
1362 # include <linux/falloc.h>
1363 #endif
1364 #ifdef HAVE_FCNTL_H
1365 # include <fcntl.h>
1366 #endif
1367 ]],[[
1368    long ret;
1369    ret = posix_fallocate(0, 0xfffffffful, 0xfffffffful);
1370    if (ret != 0) {
1371       return 1;
1372    }
1373    ]])],[
1374   AC_MSG_RESULT([yes])
1375   AC_DEFINE([HAVE_POSIX_FALLOCATE], [1], [Have valid posix_fallocate() function])],[
1376   AC_MSG_RESULT([no])])
1377 ])
1378
1379
1380 AC_ARG_ENABLE([unshare],
1381   AS_HELP_STRING([--disable-unshare], [do not build unshare]),
1382   [], [UL_DEFAULT_ENABLE([unshare], [check])]
1383 )
1384 UL_BUILD_INIT([unshare])
1385 UL_REQUIRES_LINUX([unshare])
1386 UL_REQUIRES_SYSCALL_CHECK([unshare], [UL_CHECK_SYSCALL([unshare])])
1387 UL_REQUIRES_HAVE([unshare], [linux_capability_h], [linux/capability.h header file])
1388 AM_CONDITIONAL([BUILD_UNSHARE], [test "x$build_unshare" = xyes])
1389 AC_CHECK_FUNCS([unshare])
1390
1391 AC_ARG_ENABLE([nsenter],
1392   AS_HELP_STRING([--disable-nsenter], [do not build nsenter]),
1393   [], [UL_DEFAULT_ENABLE([nsenter], [check])]
1394 )
1395 UL_BUILD_INIT([nsenter])
1396 UL_REQUIRES_LINUX([nsenter])
1397 UL_REQUIRES_HAVE([nsenter], [setns_syscall], [setns syscall])
1398 AM_CONDITIONAL([BUILD_NSENTER], [test "x$build_nsenter" = xyes])
1399 AC_CHECK_FUNCS([setns])
1400
1401
1402 AC_ARG_WITH([cap_ng],
1403   AS_HELP_STRING([--without-cap-ng], [compile without libcap-ng]),
1404   [], [with_cap_ng=auto]
1405 )
1406 AS_IF([test "x$with_cap_ng" = xno], [
1407   AM_CONDITIONAL([HAVE_CAP_NG], [false])
1408   have_cap_ng=no
1409 ],[
1410   UL_CHECK_LIB([cap-ng], [capng_apply], [cap_ng])
1411 ])
1412
1413
1414 AC_ARG_ENABLE([setpriv],
1415   AS_HELP_STRING([--disable-setpriv], [do not build setpriv]),
1416   [], [UL_DEFAULT_ENABLE([setpriv], [check])]
1417 )
1418 UL_BUILD_INIT([setpriv])
1419 UL_REQUIRES_LINUX([setpriv])
1420 UL_REQUIRES_HAVE([setpriv], [linux_securebits_h], [linux/securebits.h header file])
1421 UL_REQUIRES_HAVE([setpriv], [linux_capability_h], [linux/capability.h header file])
1422 UL_REQUIRES_HAVE([setpriv], [cap_ng], [libcap-ng library])
1423 AM_CONDITIONAL([BUILD_SETPRIV], [test "x$build_setpriv" = xyes])
1424
1425 PKG_CHECK_MODULES([PCRE], [libpcre2-8], [have_pcre=yes], [have_pcre=no])
1426 AS_IF([test "x$have_pcre" = xyes ], [
1427     AC_DEFINE([HAVE_PCRE], [1], [Define if libpcre2 is available])
1428 ])
1429 AM_CONDITIONAL([HAVE_PCRE], [test "x$have_pcre" = xyes])
1430
1431 AC_ARG_ENABLE([hardlink],
1432   AS_HELP_STRING([--disable-hardlink], [do not build hardlink]),
1433   [], [UL_DEFAULT_ENABLE([hardlink], [check])]
1434 )
1435 UL_BUILD_INIT([hardlink])
1436 AM_CONDITIONAL([BUILD_HARDLINK], [test "x$build_hardlink" = xyes])
1437
1438 AC_ARG_ENABLE([eject],
1439   AS_HELP_STRING([--disable-eject], [do not build eject]),
1440   [], [UL_DEFAULT_ENABLE([eject], [check])]
1441 )
1442 UL_BUILD_INIT([eject])
1443 UL_REQUIRES_LINUX([eject])
1444 UL_REQUIRES_BUILD([eject], [libmount])
1445 AM_CONDITIONAL([BUILD_EJECT], [test "x$build_eject" = xyes])
1446
1447
1448 AC_ARG_ENABLE([agetty],
1449   AS_HELP_STRING([--disable-agetty], [do not build agetty]),
1450   [], [UL_DEFAULT_ENABLE([agetty], [check])]
1451 )
1452 UL_BUILD_INIT([agetty])
1453 UL_REQUIRES_HAVE([agetty], [utmpx_h], [utmpx.h header])
1454 UL_REQUIRES_HAVE([agetty], [gnu_utmpx], [GNU utmpx functions])
1455 AM_CONDITIONAL([BUILD_AGETTY], [test "x$build_agetty" = xyes])
1456 AS_IF([test "x$have_futimens" = xyes -a "x$have_inotify_init1" = xyes ], [
1457   AC_DEFINE([AGETTY_RELOAD], [1], [Enable agetty --reload feature])
1458 ],[
1459   AC_MSG_WARN([futimens or inotify_init1 not found; agetty(8) will not provide ---reload functionality])
1460 ])
1461
1462
1463 AC_ARG_ENABLE([plymouth_support],
1464   AS_HELP_STRING([--disable-plymouth_support], [do not care about plymouth in sylogin(8) and agetty(8)]),
1465   [], [enable_plymouth_support=check]
1466 )
1467 UL_BUILD_INIT([plymouth_support])
1468 UL_REQUIRES_HAVE([plymouth_support], [tiocglcktrmios], [TIOCGLCKTRMIOS flag])
1469 UL_REQUIRES_HAVE([plymouth_support], [sock_cloexec], [SOCK_CLOEXEC flag])
1470 UL_REQUIRES_HAVE([plymouth_support], [sock_nonblock], [SOCK_NONBLOCK flag])
1471 UL_REQUIRES_HAVE([plymouth_support], [so_passcred], [SO_PASSCRED flag])
1472 AM_CONDITIONAL([USE_PLYMOUTH_SUPPORT], [test "x$build_plymouth_support" = xyes])
1473 AS_IF([test "x$build_plymouth_support" = xyes ], [
1474     AC_DEFINE([USE_PLYMOUTH_SUPPORT], [1], [Enable plymouth support feature for sulogin and aggety])
1475 ])
1476
1477
1478 AC_ARG_WITH([libz],
1479   AS_HELP_STRING([--without-libz], [compile without libz]),
1480   [], [with_libz=auto]
1481 )
1482 AS_IF([test "x$with_libz" = xno], [have_z=no], [
1483   AC_CHECK_LIB([z], [crc32], [have_z=yes], [have_z=no])
1484 ])
1485
1486
1487 AC_ARG_ENABLE([cramfs],
1488   AS_HELP_STRING([--disable-cramfs], [do not build fsck.cramfs, mkfs.cramfs]),
1489   [], [UL_DEFAULT_ENABLE([cramfs], [check])]
1490 )
1491 UL_BUILD_INIT([cramfs])
1492 UL_REQUIRES_HAVE([cramfs], [z], [z library])
1493 AM_CONDITIONAL([BUILD_CRAMFS], [test "x$build_cramfs" = xyes])
1494
1495
1496 AC_ARG_ENABLE([bfs],
1497   AS_HELP_STRING([--disable-bfs], [do not build mkfs.bfs]),
1498   [], [UL_DEFAULT_ENABLE([bfs], [yes])]
1499 )
1500 UL_BUILD_INIT([bfs])
1501 AM_CONDITIONAL([BUILD_BFS], [test "x$build_bfs" = xyes])
1502
1503
1504 AC_ARG_ENABLE([minix],
1505   AS_HELP_STRING([--disable-minix], [do not build fsck.minix, mkfs.minix]),
1506   [], [UL_DEFAULT_ENABLE([minix], [yes])]
1507 )
1508 UL_BUILD_INIT([minix])
1509 AM_CONDITIONAL([BUILD_MINIX], [test "x$build_minix" = xyes])
1510
1511
1512 AC_ARG_ENABLE([fdformat],
1513   AS_HELP_STRING([--disable-fdformat], [do not build fdformat]),
1514   [], [UL_DEFAULT_ENABLE([fdformat], [check])]
1515 )
1516 UL_BUILD_INIT([fdformat])
1517 UL_REQUIRES_LINUX([fdformat])
1518 AM_CONDITIONAL([BUILD_FDFORMAT], [test "x$build_fdformat" = xyes])
1519
1520
1521 AC_ARG_ENABLE([hwclock],
1522   AS_HELP_STRING([--disable-hwclock], [do not build hwclock]),
1523   [], [UL_DEFAULT_ENABLE([hwclock], [check])]
1524 )
1525 have_linuxdummy=$linux_os
1526
1527 UL_BUILD_INIT([hwclock])
1528 UL_REQUIRES_HAVE([hwclock], [io, linuxdummy], [ioperm iopl function or Linux])
1529 AM_CONDITIONAL([BUILD_HWCLOCK], [test "x$build_hwclock" = xyes])
1530
1531 AC_ARG_ENABLE([hwclock_cmos],
1532   AS_HELP_STRING([--disable-hwclock-cmos], [do not use CMOS clock]),
1533   [], [enable_hwclock_cmos=check]
1534 )
1535 UL_BUILD_INIT([hwclock_cmos])
1536 UL_REQUIRES_BUILD([hwclock_cmos], [hwclock])
1537 UL_REQUIRES_ARCH([hwclock_cmos], [i?86-*,x86_64*])
1538 AM_CONDITIONAL([USE_HWCLOCK_CMOS], [test "x$build_hwclock_cmos" = xyes])
1539 AS_IF([test "x$build_hwclock_cmos" = xyes ], [
1540     AC_DEFINE([USE_HWCLOCK_CMOS], [1], [Define to 1 if want to use CMOS clock.])
1541 ])
1542
1543
1544 UL_BUILD_INIT([mkfs], [yes])
1545 AM_CONDITIONAL([BUILD_MKFS], [test "x$build_mkfs" = xyes])
1546
1547 UL_BUILD_INIT([isosize], [yes])
1548 AM_CONDITIONAL([BUILD_ISOSIZE], [test "x$build_isosize" = xyes])
1549
1550
1551 UL_BUILD_INIT([fstrim], [check])
1552 UL_REQUIRES_LINUX([fstrim])
1553 UL_REQUIRES_BUILD([fstrim], [libmount])
1554 AM_CONDITIONAL([BUILD_FSTRIM], [test "x$build_fstrim" = xyes])
1555
1556
1557 UL_BUILD_INIT([swapon], [check])
1558 UL_REQUIRES_LINUX([swapon])
1559 UL_REQUIRES_SYSCALL_CHECK([swapon], [UL_CHECK_SYSCALL([swapon])], [swapon])
1560 UL_REQUIRES_SYSCALL_CHECK([swapon], [UL_CHECK_SYSCALL([swapoff])], [swapoff])
1561 UL_REQUIRES_BUILD([swapon], [libblkid])
1562 UL_REQUIRES_BUILD([swapon], [libmount])
1563 UL_REQUIRES_BUILD([swapon], [libsmartcols])
1564 AM_CONDITIONAL([BUILD_SWAPON], [test "x$build_swapon" = xyes])
1565 AC_CHECK_FUNCS([swapon])
1566 AC_CHECK_FUNCS([swapoff])
1567
1568
1569 UL_BUILD_INIT([lsblk], [check])
1570 UL_REQUIRES_LINUX([lsblk])
1571 UL_REQUIRES_BUILD([lsblk], [libblkid])
1572 UL_REQUIRES_BUILD([lsblk], [libmount])
1573 UL_REQUIRES_BUILD([lsblk], [libsmartcols])
1574 AM_CONDITIONAL([BUILD_LSBLK], [test "x$build_lsblk" = xyes])
1575
1576
1577 UL_BUILD_INIT([lscpu], [check])
1578 UL_REQUIRES_LINUX([lscpu])
1579 UL_REQUIRES_BUILD([lscpu], [libsmartcols])
1580 UL_REQUIRES_HAVE([lscpu], [cpu_set_t], [cpu_set_t type])
1581 AM_CONDITIONAL([BUILD_LSCPU], [test "x$build_lscpu" = xyes])
1582
1583
1584 AC_ARG_ENABLE([lslogins],
1585   AS_HELP_STRING([--disable-lslogins], [do not build lslogins]),
1586   [], [UL_DEFAULT_ENABLE([lslogins], [check])]
1587 )
1588 UL_BUILD_INIT([lslogins])
1589 UL_REQUIRES_BUILD([lslogins], [libsmartcols])
1590 UL_REQUIRES_HAVE([lslogins], [shadow_h], [shadow.h header])
1591 UL_REQUIRES_HAVE([lslogins], [utmpx_h], [utmpx.h header])
1592 UL_REQUIRES_HAVE([lslogins], [gnu_utmpx], [GNU utmpx functions])
1593 AM_CONDITIONAL([BUILD_LSLOGINS], [test "x$build_lslogins" = xyes])
1594
1595
1596 UL_BUILD_INIT([chcpu], [check])
1597 UL_REQUIRES_LINUX([chcpu])
1598 UL_REQUIRES_HAVE([chcpu], [cpu_set_t], [cpu_set_t type])
1599 AM_CONDITIONAL([BUILD_CHCPU], [test "x$build_chcpu" = xyes])
1600
1601
1602 AC_ARG_ENABLE([wdctl],
1603   AS_HELP_STRING([--disable-wdctl], [do not build wdctl]),
1604   [], [UL_DEFAULT_ENABLE([wdctl], [check])]
1605 )
1606 UL_BUILD_INIT([wdctl])
1607 UL_REQUIRES_LINUX([wdctl])
1608 UL_REQUIRES_BUILD([wdctl], [libsmartcols])
1609 UL_REQUIRES_HAVE([wdctl], [linux_watchdog_h], [linux/watchdog.h header file])
1610 AM_CONDITIONAL([BUILD_WDCTL], [test "x$build_wdctl" = xyes])
1611
1612
1613 UL_BUILD_INIT([swaplabel], [check])
1614 UL_REQUIRES_BUILD([swaplabel], [libblkid])
1615 AM_CONDITIONAL([BUILD_SWAPLABEL], [test "x$build_swaplabel" = xyes])
1616
1617
1618 UL_BUILD_INIT([mkswap], [yes])
1619 AM_CONDITIONAL([BUILD_MKSWAP], [test "x$build_mkswap" = xyes])
1620 AS_IF([test "x$build_mkswap" = xyes -a "x$build_libuuid" != xyes], [
1621   AC_MSG_WARN([uuid library is not found; mkswap(8) will not generate UUIDs])
1622 ])
1623
1624
1625 AC_ARG_ENABLE([cal],
1626   AS_HELP_STRING([--disable-cal], [do not build cal]),
1627   [], [UL_DEFAULT_ENABLE([cal], [check])]
1628 )
1629 UL_BUILD_INIT([cal])
1630 AM_CONDITIONAL([BUILD_CAL], [test "x$build_cal" = xyes])
1631
1632 AC_ARG_ENABLE([logger],
1633   AS_HELP_STRING([--disable-logger], [do not build logger]),
1634   [], [UL_DEFAULT_ENABLE([logger], [check])]
1635 )
1636 UL_BUILD_INIT([logger])
1637 AM_CONDITIONAL([BUILD_LOGGER], [test "x$build_logger" = xyes])
1638
1639 UL_BUILD_INIT([look], [yes])
1640 AM_CONDITIONAL([BUILD_LOOK], [test "x$build_look" = xyes])
1641
1642 UL_BUILD_INIT([mcookie], [yes])
1643 AM_CONDITIONAL([BUILD_MCOOKIE], [test "x$build_mcookie" = xyes])
1644
1645 UL_BUILD_INIT([namei], [yes])
1646 AM_CONDITIONAL([BUILD_NAMEI], [test "x$build_namei" = xyes])
1647
1648 matriplet="$($CC -print-multiarch 2>/dev/null || true)"
1649 if test "x$matriplet" != "x"; then
1650   AC_DEFINE_UNQUOTED([MULTIARCHTRIPLET], ["$matriplet"],
1651   ["Multi-arch triplet for whereis library search path"])
1652 fi
1653 UL_BUILD_INIT([whereis], [yes])
1654 AM_CONDITIONAL([BUILD_WHEREIS], [test "x$build_whereis" = xyes])
1655
1656 UL_BUILD_INIT([getopt], [yes])
1657 AM_CONDITIONAL([BUILD_GETOPT], [test "x$build_getopt" = xyes])
1658
1659
1660 UL_BUILD_INIT([blockdev], [check])
1661 UL_REQUIRES_LINUX([blockdev])
1662 AM_CONDITIONAL([BUILD_BLOCKDEV], [test "x$build_blockdev" = xyes])
1663
1664
1665 UL_BUILD_INIT([prlimit], [check])
1666 UL_REQUIRES_LINUX([prlimit])
1667 UL_REQUIRES_BUILD([prlimit], [libsmartcols])
1668 UL_REQUIRES_SYSCALL_CHECK([prlimit], [UL_CHECK_SYSCALL([prlimit64])], [prlimit64])
1669 AM_CONDITIONAL([BUILD_PRLIMIT], [test "x$build_prlimit" = xyes])
1670 AS_IF([test "x$build_prlimit" = xyes], [
1671   AC_CHECK_FUNCS([prlimit])
1672 ])
1673
1674
1675 UL_BUILD_INIT([lslocks], [check])
1676 UL_REQUIRES_LINUX([lslocks])
1677 UL_REQUIRES_BUILD([lslocks], [libmount])
1678 UL_REQUIRES_BUILD([lslocks], [libsmartcols])
1679 AM_CONDITIONAL([BUILD_LSLOCKS], [test "x$build_lslocks" = xyes])
1680
1681
1682 AC_ARG_ENABLE([switch_root],
1683   AS_HELP_STRING([--disable-switch_root], [do not build switch_root]),
1684   [], [UL_DEFAULT_ENABLE([switch_root], [check])]
1685 )
1686 UL_BUILD_INIT([switch_root])
1687 UL_REQUIRES_LINUX([switch_root])
1688 UL_REQUIRES_HAVE([switch_root], [openat], [openat function])
1689 UL_REQUIRES_HAVE([switch_root], [dirfd,ddfd], [dirfd or ddfd function])
1690 AM_CONDITIONAL([BUILD_SWITCH_ROOT], [test "x$build_switch_root" = xyes])
1691
1692
1693 AC_ARG_ENABLE([pivot_root],
1694   AS_HELP_STRING([--disable-pivot_root], [do not build pivot_root]),
1695   [], [UL_DEFAULT_ENABLE([pivot_root], [check])]
1696 )
1697 UL_BUILD_INIT([pivot_root])
1698 UL_REQUIRES_LINUX([pivot_root])
1699 UL_REQUIRES_SYSCALL_CHECK([pivot_root], [UL_CHECK_SYSCALL([pivot_root])])
1700 AM_CONDITIONAL([BUILD_PIVOT_ROOT], [test "x$build_pivot_root" = xyes])
1701
1702
1703 UL_BUILD_INIT([flock], [check])
1704 UL_REQUIRES_HAVE([flock], [timer], [timer_create/setitimer function])
1705 AM_CONDITIONAL([BUILD_FLOCK], [test "x$build_flock" = xyes])
1706
1707
1708 AC_ARG_ENABLE([lsmem],
1709   AS_HELP_STRING([--disable-lsmem], [do not build lsmem]),
1710   [], [UL_DEFAULT_ENABLE([lsmem], [check])]
1711 )
1712 UL_BUILD_INIT([lsmem])
1713 UL_REQUIRES_LINUX([lsmem])
1714 UL_REQUIRES_BUILD([lsmem], [libsmartcols])
1715 AM_CONDITIONAL([BUILD_LSMEM], [test "x$build_lsmem" = xyes])
1716
1717
1718 AC_ARG_ENABLE([chmem],
1719   AS_HELP_STRING([--disable-chmem], [do not build chmem]),
1720   [], [UL_DEFAULT_ENABLE([chmem], [check])]
1721 )
1722 UL_BUILD_INIT([chmem])
1723 UL_REQUIRES_LINUX([chmem])
1724 AM_CONDITIONAL([BUILD_CHMEM], [test "x$build_chmem" = xyes])
1725
1726 UL_BUILD_INIT([ipcmk], [yes])
1727 AM_CONDITIONAL([BUILD_IPCMK], [test "x$build_ipcmk" = xyes])
1728
1729
1730 AC_ARG_ENABLE([ipcrm],
1731   AS_HELP_STRING([--disable-ipcrm], [do not build ipcrm]),
1732   [], [UL_DEFAULT_ENABLE([ipcrm], [yes])]
1733 )
1734 UL_BUILD_INIT([ipcrm])
1735 AM_CONDITIONAL([BUILD_IPCRM], [test "x$build_ipcrm" = xyes])
1736
1737 AC_ARG_ENABLE([ipcs],
1738   AS_HELP_STRING([--disable-ipcs], [do not build ipcs]),
1739   [], [UL_DEFAULT_ENABLE([ipcs], [yes])]
1740 )
1741 UL_BUILD_INIT([ipcs])
1742 AM_CONDITIONAL([BUILD_IPCS], [test "x$build_ipcs" = xyes])
1743
1744 UL_BUILD_INIT([choom], [check])
1745 UL_REQUIRES_LINUX([choom])
1746 AM_CONDITIONAL([BUILD_CHOOM], [test "x$build_choom" = xyes])
1747
1748 UL_BUILD_INIT([lsipc], [check])
1749 UL_REQUIRES_LINUX([lsipc])
1750 UL_REQUIRES_BUILD([lsipc], [libsmartcols])
1751 AM_CONDITIONAL([BUILD_LSIPC], [test "x$build_lsipc" = xyes])
1752
1753 UL_BUILD_INIT([lsns], [check])
1754 UL_REQUIRES_LINUX([lsns])
1755 UL_REQUIRES_BUILD([lsns], [libsmartcols])
1756 UL_REQUIRES_BUILD([lsns], [libmount])
1757 AM_CONDITIONAL([BUILD_LSNS], [test "x$build_lsns" = xyes])
1758
1759 UL_BUILD_INIT([renice], [yes])
1760 AM_CONDITIONAL([BUILD_RENICE], [test "x$build_renice" = xyes])
1761
1762
1763 AC_ARG_ENABLE([rfkill],
1764   AS_HELP_STRING([--disable-rfkill], [do not build rfkill]),
1765   [], [UL_DEFAULT_ENABLE([rfkill], [check])]
1766 )
1767 UL_BUILD_INIT([rfkill])
1768 UL_REQUIRES_LINUX([rfkill])
1769 UL_REQUIRES_BUILD([rfkill], [libsmartcols])
1770 AM_CONDITIONAL([BUILD_RFKILL], [test "x$build_rfkill" = xyes])
1771
1772
1773 UL_BUILD_INIT([setsid], [yes])
1774 AM_CONDITIONAL([BUILD_SETSID], [test "x$build_setsid" = xyes])
1775
1776 UL_BUILD_INIT([readprofile], [check])
1777 UL_REQUIRES_LINUX([readprofile])
1778 AM_CONDITIONAL([BUILD_READPROFILE], [test "x$build_readprofile" = xyes])
1779
1780 UL_BUILD_INIT([dmesg], [check])
1781 UL_REQUIRES_LINUX([dmesg])
1782 AM_CONDITIONAL([BUILD_DMESG], [test "x$build_dmesg" = xyes])
1783
1784 UL_BUILD_INIT([ctrlaltdel], [check])
1785 UL_REQUIRES_LINUX([ctrlaltdel])
1786 dnl we assume reboot() to be the 1-argument variant, because even considering
1787 dnl widely used alternative C libraries like uclibc, dietlibc and musl,
1788 dnl reboot() with multiple arguments is yet only found in glibc versions
1789 dnl earlier than 2.x.
1790 UL_REQUIRES_HAVE([ctrlaltdel], [reboot], [reboot function])
1791 AM_CONDITIONAL([BUILD_CTRLALTDEL], [test "x$build_ctrlaltdel" = xyes])
1792
1793 UL_BUILD_INIT([fincore], [check])
1794 UL_REQUIRES_LINUX([fincore])
1795 UL_REQUIRES_BUILD([fincore], [libsmartcols])
1796 AM_CONDITIONAL([BUILD_FINCORE], [test "x$build_fincore" = xyes])
1797
1798 UL_BUILD_INIT([fsfreeze], [check])
1799 UL_REQUIRES_LINUX([fsfreeze])
1800 AM_CONDITIONAL([BUILD_FSFREEZE], [test "x$build_fsfreeze" = xyes])
1801
1802 UL_BUILD_INIT([blkdiscard], [check])
1803 UL_REQUIRES_LINUX([blkdiscard])
1804 AM_CONDITIONAL([BUILD_BLKDISCARD], [test "x$build_blkdiscard" = xyes])
1805
1806 UL_BUILD_INIT([blkzone], [check])
1807 UL_REQUIRES_LINUX([blkzone])
1808 UL_REQUIRES_HAVE([blkzone], [linux_blkzoned_h], [linux/blkzoned.h header])
1809 AM_CONDITIONAL([BUILD_BLKZONE], [test "x$build_blkzone" = xyes])
1810
1811 UL_BUILD_INIT([ldattach], [check])
1812 UL_REQUIRES_LINUX([ldattach])
1813 AM_CONDITIONAL([BUILD_LDATTACH], [test "x$build_ldattach" = xyes])
1814
1815 UL_BUILD_INIT([rtcwake], [check])
1816 UL_REQUIRES_LINUX([rtcwake])
1817 AM_CONDITIONAL([BUILD_RTCWAKE], [test "x$build_rtcwake" = xyes])
1818
1819 UL_BUILD_INIT([setarch], [check])
1820 UL_REQUIRES_LINUX([setarch])
1821 AM_CONDITIONAL([BUILD_SETARCH], [test "x$build_setarch" = xyes])
1822
1823 UL_BUILD_INIT([script], [check])
1824 UL_REQUIRES_HAVE([script], [sys_signalfd_h], [sys/signalfd.h header])
1825 AM_CONDITIONAL([BUILD_SCRIPT], [test "x$build_script" = xyes])
1826
1827 UL_BUILD_INIT([scriptreplay], [yes])
1828 AM_CONDITIONAL([BUILD_SCRIPTREPLAY], [test "x$build_scriptreplay" = xyes])
1829
1830 UL_BUILD_INIT([scriptlive], [yes])
1831 AM_CONDITIONAL([BUILD_SCRIPTLIVE], [test "x$build_scriptlive" = xyes])
1832
1833 UL_BUILD_INIT([col], [yes])
1834 AM_CONDITIONAL([BUILD_COL], [test "x$build_col" = xyes])
1835
1836 UL_BUILD_INIT([colcrt], [yes])
1837 AM_CONDITIONAL([BUILD_COLCRT], [test "x$build_colcrt" = xyes])
1838
1839 UL_BUILD_INIT([colrm], [yes])
1840 AM_CONDITIONAL([BUILD_COLRM], [test "x$build_colrm" = xyes])
1841
1842 UL_BUILD_INIT([column], [check])
1843 UL_REQUIRES_BUILD([column], [libsmartcols])
1844 AM_CONDITIONAL([BUILD_COLUMN], [test "x$build_column" = xyes])
1845
1846 UL_BUILD_INIT([hexdump], [yes])
1847 AM_CONDITIONAL([BUILD_HEXDUMP], [test "x$build_hexdump" = xyes])
1848
1849 UL_BUILD_INIT([rev], [yes])
1850 AM_CONDITIONAL([BUILD_REV], [test "x$build_rev" = xyes])
1851
1852
1853 AC_ARG_ENABLE([tunelp],
1854   AS_HELP_STRING([--enable-tunelp], [build tunelp]),
1855   [], [UL_DEFAULT_ENABLE([tunelp], [no])]
1856 )
1857 UL_BUILD_INIT([tunelp])
1858 UL_REQUIRES_LINUX([tunelp])
1859 AM_CONDITIONAL([BUILD_TUNELP], [test "x$build_tunelp" = xyes])
1860
1861
1862 AC_ARG_ENABLE([kill],
1863   AS_HELP_STRING([--disable-kill], [do not build kill]),
1864   [], [UL_DEFAULT_ENABLE([kill], [check])]
1865 )
1866 UL_BUILD_INIT([kill])
1867 UL_REQUIRES_LINUX([kill])
1868 AM_CONDITIONAL([BUILD_KILL], [test "x$build_kill" = xyes])
1869
1870
1871 AC_ARG_ENABLE([last],
1872   AS_HELP_STRING([--disable-last], [do not build last]),
1873   [], [UL_DEFAULT_ENABLE([last], [check])]
1874 )
1875 UL_BUILD_INIT([last])
1876 UL_REQUIRES_HAVE([last], [utmpx_h], [utmpx.h header])
1877 UL_REQUIRES_HAVE([last], [gnu_utmpx], [GNU utmpx functions])
1878 AM_CONDITIONAL([BUILD_LAST], [test "x$build_last" = xyes])
1879
1880
1881 AC_ARG_ENABLE([utmpdump],
1882   AS_HELP_STRING([--disable-utmpdump], [do not build utmpdump]),
1883   [], [UL_DEFAULT_ENABLE([utmpdump], [check])]
1884 )
1885 UL_BUILD_INIT([utmpdump])
1886 UL_REQUIRES_HAVE([utmpdump], [utmpx_h], [utmpx.h header])
1887 UL_REQUIRES_HAVE([utmpdump], [gnu_utmpx], [GNU utmpx functions])
1888 AM_CONDITIONAL([BUILD_UTMPDUMP], [test "x$build_utmpdump" = xyes])
1889
1890
1891 AC_ARG_ENABLE([line],
1892   AS_HELP_STRING([--enable-line], [build line]),
1893   [], [UL_DEFAULT_ENABLE([line], [no])]
1894 )
1895 UL_BUILD_INIT([line])
1896 AM_CONDITIONAL([BUILD_LINE], [test "x$build_line" = xyes])
1897
1898
1899 AC_ARG_ENABLE([mesg],
1900   AS_HELP_STRING([--disable-mesg], [do not build mesg]),
1901   [], [UL_DEFAULT_ENABLE([mesg], [yes])]
1902 )
1903 UL_BUILD_INIT([mesg])
1904 AM_CONDITIONAL([BUILD_MESG], [test "x$build_mesg" = xyes])
1905
1906
1907 AC_ARG_ENABLE([raw],
1908   AS_HELP_STRING([--disable-raw], [do not build raw]),
1909   [], [UL_DEFAULT_ENABLE([raw], [check])]
1910 )
1911 UL_BUILD_INIT([raw])
1912 UL_REQUIRES_LINUX([raw])
1913 UL_REQUIRES_HAVE([raw], [linux_raw_h], [raw.h header file])
1914 AM_CONDITIONAL([BUILD_RAW], [test "x$build_raw" = xyes])
1915
1916
1917 AC_ARG_ENABLE([rename],
1918   AS_HELP_STRING([--disable-rename], [do not build rename]),
1919   [], [UL_DEFAULT_ENABLE([rename], [yes])]
1920 )
1921 UL_BUILD_INIT([rename])
1922 AM_CONDITIONAL([BUILD_RENAME], [test "x$build_rename" = xyes])
1923
1924
1925 AC_ARG_ENABLE([vipw],
1926   AS_HELP_STRING([--enable-vipw], [build vipw]),
1927   [], [UL_DEFAULT_ENABLE([vipw], [no])]
1928 )
1929 UL_BUILD_INIT([vipw])
1930 UL_REQUIRES_HAVE([vipw], [shadow_h], [shadow.h header])
1931 AM_CONDITIONAL([BUILD_VIPW], [test "x$build_vipw" = xyes])
1932
1933
1934 AC_ARG_ENABLE([newgrp],
1935   AS_HELP_STRING([--enable-newgrp], [build newgrp]),
1936   [], [UL_DEFAULT_ENABLE([newgrp], [no])]
1937 )
1938 UL_BUILD_INIT([newgrp])
1939 UL_REQUIRES_HAVE([newgrp], [crypt], [crypt function])
1940 AM_CONDITIONAL([BUILD_NEWGRP], [test "x$build_newgrp" = xyes])
1941
1942
1943 AC_ARG_WITH([user], AS_HELP_STRING([--without-user], [compile without libuser (remote chsh)]),
1944   [], [with_user=check]
1945 )
1946 have_user=no
1947 AS_IF([test "x$with_user" != xno], [
1948   PKG_CHECK_MODULES(LIBUSER,[libuser >= 0.58], [have_user=yes], [have_user=no])
1949   AS_CASE([$with_user:$have_user],
1950     [yes:no],
1951       [AC_MSG_ERROR([user selected but libuser not found])],
1952     [*:yes],
1953       [AC_DEFINE([HAVE_LIBUSER], [1], [Define if libuser is available])]
1954   )
1955   # temporary solution, libuser has stupid .pc where are exported all
1956   # private dependencies to Requires: instead of Requires.private:
1957   AS_IF([test "x$have_user" = xyes], [
1958     LIBUSER_LIBS=-luser
1959   ])
1960 ])
1961 AM_CONDITIONAL([HAVE_USER], [test "x$have_user" = xyes])
1962
1963 AC_ARG_ENABLE([chfn-chsh-password],
1964   AS_HELP_STRING([--disable-chfn-chsh-password], [do not require the user to enter the password in chfn and chsh]),
1965   [], [enable_chfn_chsh_password=yes]
1966 )
1967
1968 AC_ARG_ENABLE([chfn-chsh],
1969   AS_HELP_STRING([--enable-chfn-chsh], [build chfn and chsh]),
1970   [], [UL_DEFAULT_ENABLE([chfn_chsh], [check])]
1971 )
1972 UL_BUILD_INIT([chfn_chsh])
1973 UL_REQUIRES_HAVE([chfn_chsh], [shadow_h], [shadow.h header])
1974 UL_REQUIRES_HAVE([chfn_chsh], [getusershell], [getusershell function])
1975
1976 AS_IF([test "x$enable_chfn_chsh_password" = xyes -o "x$have_user" = xyes], [
1977   UL_REQUIRES_HAVE([chfn_chsh], [security_pam_appl_h], [PAM header file])
1978   AC_DEFINE([CHFN_CHSH_PASSWORD], [1], [Should chfn and chsh require the user to enter the password?])
1979 ])
1980 AM_CONDITIONAL([BUILD_CHFN_CHSH], [test "x$build_chfn_chsh" = xyes])
1981 AM_CONDITIONAL([CHFN_CHSH_PASSWORD], [test "x$enable_chfn_chsh_password" = xyes])
1982
1983 AC_ARG_ENABLE([chsh-only-listed],
1984   AS_HELP_STRING([--disable-chsh-only-listed], [chsh: allow shells not in /etc/shells]),
1985   [], enable_chsh_only_listed=yes
1986 )
1987
1988 AS_IF([test "x$enable_chsh_only_listed" = xyes], [
1989   AC_DEFINE([ONLY_LISTED_SHELLS], [1], [Should chsh allow only shells in /etc/shells?])
1990 ])
1991
1992
1993 AC_ARG_ENABLE([login],
1994   AS_HELP_STRING([--disable-login], [do not build login]),
1995   [], [UL_DEFAULT_ENABLE([login], [check])]
1996 )
1997 UL_BUILD_INIT([login])
1998 UL_REQUIRES_HAVE([login], [security_pam_appl_h], [PAM header file])
1999 UL_REQUIRES_HAVE([login], [security_pam_misc_h, security_openpam_h], [PAM conversation functions])
2000 UL_REQUIRES_HAVE([login], [utmpx_h], [utmpx.h header])
2001 UL_REQUIRES_HAVE([login], [gnu_utmpx], [GNU utmpx functions])
2002 AM_CONDITIONAL([BUILD_LOGIN], [test "x$build_login" = xyes])
2003
2004 AC_ARG_ENABLE([login-chown-vcs],
2005   AS_HELP_STRING([--enable-login-chown-vcs], [let login chown /dev/vcsN]),
2006   [], [enable_login_chown_vcs=no]
2007 )
2008
2009 AS_IF([test "x$enable_login_chown_vcs" = xyes], [
2010   AC_DEFINE([LOGIN_CHOWN_VCS], [1], [Should login chown /dev/vcsN?])
2011 ])
2012
2013 AC_ARG_ENABLE([login-stat-mail],
2014   AS_HELP_STRING([--enable-login-stat-mail], [let login stat() the mailbox]),
2015   [], [enable_login_stat_mail=no]
2016 )
2017
2018 AS_IF([test "x$enable_login_stat_mail" = xyes], [
2019   AC_DEFINE([LOGIN_STAT_MAIL], [1], [Should login stat() the mailbox?])
2020 ])
2021
2022
2023 AC_ARG_ENABLE([nologin],
2024   AS_HELP_STRING([--disable-nologin], [do not build nologin]),
2025   [], [UL_DEFAULT_ENABLE([nologin], [yes])]
2026 )
2027 UL_BUILD_INIT([nologin])
2028 AM_CONDITIONAL([BUILD_NOLOGIN], [test "x$build_nologin" = xyes])
2029
2030
2031 AC_ARG_ENABLE([sulogin],
2032   AS_HELP_STRING([--disable-sulogin], [do not build sulogin]),
2033   [], [UL_DEFAULT_ENABLE([sulogin], [check])]
2034 )
2035 UL_BUILD_INIT([sulogin])
2036 UL_REQUIRES_HAVE([sulogin], [crypt], [crypt function])
2037 UL_REQUIRES_HAVE([sulogin], [shadow_h], [shadow.h header])
2038 AM_CONDITIONAL([BUILD_SULOGIN], [test "x$build_sulogin" = xyes])
2039
2040
2041 AC_ARG_ENABLE([su],
2042   AS_HELP_STRING([--disable-su], [do not build su]),
2043   [], [UL_DEFAULT_ENABLE([su], [check])]
2044 )
2045 UL_BUILD_INIT([su])
2046 UL_REQUIRES_HAVE([su], [security_pam_appl_h], [PAM header file])
2047 UL_REQUIRES_HAVE([su], [utmpx_h], [utmpx.h header])
2048 UL_REQUIRES_HAVE([su], [gnu_utmpx], [GNU utmpx functions])
2049 AM_CONDITIONAL([BUILD_SU], [test "x$build_su" = xyes])
2050
2051
2052 AC_ARG_ENABLE([runuser],
2053   AS_HELP_STRING([--disable-runuser], [do not build runuser]),
2054   [], [UL_DEFAULT_ENABLE([runuser], [check])]
2055 )
2056 UL_BUILD_INIT([runuser])
2057 UL_REQUIRES_HAVE([runuser], [security_pam_appl_h], [PAM header file])
2058 UL_REQUIRES_HAVE([runuser], [utmpx_h], [utmpx.h header])
2059 UL_REQUIRES_HAVE([runuser], [gnu_utmpx], [GNU utmpx functions])
2060 AM_CONDITIONAL([BUILD_RUNUSER], [test "x$build_runuser" = xyes])
2061
2062
2063 AC_ARG_ENABLE([ul],
2064   AS_HELP_STRING([--disable-ul], [do not build ul]),
2065   [], [UL_DEFAULT_ENABLE([ul], [check])]
2066 )
2067 UL_BUILD_INIT([ul])
2068 UL_REQUIRES_HAVE([ul], [ncursesw, ncurses], [ncursesw or ncurses libraries])
2069 AM_CONDITIONAL([BUILD_UL], [test "x$build_ul" = xyes])
2070
2071
2072 AC_ARG_ENABLE([more],
2073   AS_HELP_STRING([--disable-more], [do not build more]),
2074   [], [UL_DEFAULT_ENABLE([more], [check])]
2075 )
2076 UL_BUILD_INIT([more])
2077 UL_REQUIRES_HAVE([more], [ncursesw, ncurses], [ncursesw or ncurses libraries])
2078 AM_CONDITIONAL([BUILD_MORE], [test "x$build_more" = xyes])
2079
2080
2081 AC_ARG_ENABLE([pg],
2082   AS_HELP_STRING([--enable-pg], [build pg]),
2083   [], [UL_DEFAULT_ENABLE([pg], [no])]
2084 )
2085 UL_BUILD_INIT([pg])
2086 UL_REQUIRES_HAVE([pg], [ncursesw, ncurses], [ncursesw or ncurses library])
2087 AM_CONDITIONAL([BUILD_PG], [test "x$build_pg" = xyes])
2088
2089
2090 AC_ARG_ENABLE([setterm],
2091   AS_HELP_STRING([--disable-setterm], [do not build setterm]),
2092   [], [UL_DEFAULT_ENABLE([setterm], [check])]
2093 )
2094 UL_BUILD_INIT([setterm])
2095 UL_REQUIRES_LINUX([setterm])
2096 UL_REQUIRES_HAVE([setterm], [ncursesw, ncurses], [ncursesw or ncurses library])
2097 AM_CONDITIONAL([BUILD_SETTERM], [test "x$build_setterm" = xyes])
2098
2099 # build_schedutils= is just configure-only variable to control
2100 # ionice, taskset and chrt
2101 AC_ARG_ENABLE([schedutils],
2102   AS_HELP_STRING([--disable-schedutils], [do not build chrt, ionice, taskset]),
2103   [], [UL_DEFAULT_ENABLE([schedutils], [check])]
2104 )
2105
2106
2107 UL_ENABLE_ALIAS([ionice], [schedutils])
2108 UL_BUILD_INIT([ionice])
2109 UL_REQUIRES_SYSCALL_CHECK([ionice],
2110         [UL_CHECK_SYSCALL([ioprio_set],
2111           [alpha],      [442],
2112           [i*86],       [289],
2113           [ia64*],      [1274],
2114           [powerpc*],   [273],
2115           [s390*],      [282],
2116           [sparc*],     [196],
2117           [sh*],        [288],
2118           [x86_64*],    [251])],
2119         [ioprio_set])
2120
2121 UL_REQUIRES_SYSCALL_CHECK([ionice],
2122         [UL_CHECK_SYSCALL([ioprio_get],
2123           [alpha],      [443],
2124           [i*86],       [290],
2125           [ia64*],      [1275],
2126           [powerpc*],   [274],
2127           [s390*],      [283],
2128           [sparc*],     [218],
2129           [sh*],        [289],
2130           [x86_64*],    [252])],
2131         [ioprio_get])
2132
2133 AM_CONDITIONAL([BUILD_IONICE], [test "x$build_ionice" = xyes])
2134
2135
2136 UL_ENABLE_ALIAS([taskset], [schedutils])
2137 UL_BUILD_INIT([taskset])
2138 UL_REQUIRES_HAVE([taskset], [cpu_set_t], [cpu_set_t type])
2139 UL_REQUIRES_SYSCALL_CHECK([taskset],
2140         [UL_CHECK_SYSCALL([sched_getaffinity])],
2141         [sched_getaffinity])
2142 AM_CONDITIONAL([BUILD_TASKSET], [test "x$build_taskset" = xyes])
2143
2144
2145 have_schedsetter=no
2146 AS_IF([test "x$ac_cv_func_sched_setscheduler" = xyes], [have_schedsetter=yes],
2147       [test "x$ac_cv_func_sched_setattr" = xyes], [have_schedsetter=yes])
2148
2149 UL_ENABLE_ALIAS([chrt], [schedutils])
2150 UL_BUILD_INIT([chrt])
2151 UL_REQUIRES_HAVE([chrt], [schedsetter], [sched_set functions])
2152 AM_CONDITIONAL([BUILD_CHRT], [test "x$build_chrt" = xyes])
2153
2154 AS_IF([test "x$build_chrt" = xyes], [
2155         UL_CHECK_SYSCALL([sched_setattr])
2156 ])
2157
2158
2159 AC_ARG_ENABLE([wall],
2160   AS_HELP_STRING([--disable-wall], [do not build wall]),
2161   [], [UL_DEFAULT_ENABLE([wall], [check])]
2162 )
2163 UL_BUILD_INIT([wall])
2164 UL_REQUIRES_HAVE([wall], [utmpx_h], [utmpx.h header])
2165 AM_CONDITIONAL([BUILD_WALL], [test "x$build_wall" = xyes])
2166
2167
2168 AC_ARG_ENABLE([write],
2169   AS_HELP_STRING([--enable-write], [build write]),
2170   [], [UL_DEFAULT_ENABLE([write], [no])]
2171 )
2172 UL_BUILD_INIT([write])
2173 UL_REQUIRES_HAVE([write], [utmpx_h], [utmpx.h header])
2174 UL_REQUIRES_HAVE([write], [gnu_utmpx], [GNU utmpx functions])
2175 AM_CONDITIONAL([BUILD_WRITE], [test "x$build_write" = xyes])
2176
2177
2178 AC_ARG_WITH([btrfs],
2179   AS_HELP_STRING([--without-btrfs], [do not build with btrfs support]),
2180   [], [with_btrfs=check]
2181 )
2182 have_btrfs=no
2183 AS_IF([test "x$with_btrfs" != xno], [
2184   AS_CASE([$with_btrfs:$have_linux_btrfs_h],
2185     [yes:no],
2186     [AC_MSG_ERROR([btrfs selected but linux/btrfs.h not found])],
2187     [check:no],
2188        [AC_MSG_WARN([linux/btrfs.h not found, do not build with btrfs support])],
2189     [*:yes],
2190        [have_btrfs=yes
2191         AC_DEFINE([HAVE_BTRFS_SUPPORT], [1], [Define if btrfs stuff is available])]
2192   )
2193 ])
2194 AM_CONDITIONAL([HAVE_BTRFS], [test "x$have_btrfs" = xyes])
2195
2196
2197 AC_ARG_WITH([systemd],
2198   AS_HELP_STRING([--without-systemd], [do not build with systemd support]),
2199   [], [with_systemd=check]
2200 )
2201
2202 have_systemd=no
2203 AS_IF([test "x$with_systemd" != xno], [
2204   # new version -- all libsystemd-* libs merged into libsystemd
2205   PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [have_systemd=yes], [have_systemd=no])
2206   # old versions
2207   AS_IF([test "x$have_systemd" != "xyes"], [
2208     PKG_CHECK_MODULES([SYSTEMD_DAEMON], [libsystemd-daemon],
2209                       [have_systemd_daemon=yes], [have_systemd_daemon=no])
2210     PKG_CHECK_MODULES([SYSTEMD_JOURNAL], [libsystemd-journal],
2211                       [have_systemd_journal=yes], [have_systemd_journal=no])
2212     AS_IF([test "x$have_systemd_daemon" = "xyes" -a "x$have_systemd_journal" = "xyes" ],[
2213            have_systemd=yes])
2214   ])
2215   AS_CASE([$with_systemd:$have_systemd],
2216     [yes:no],
2217       [AC_MSG_ERROR([systemd expected but libsystemd not found])],
2218     [*:yes],
2219        AC_DEFINE([HAVE_LIBSYSTEMD], [1], [Define if libsystemd is available])
2220   )
2221 ])
2222 AM_CONDITIONAL([HAVE_SYSTEMD], [test "x$have_systemd" = xyes])
2223
2224
2225 AC_ARG_WITH([systemdsystemunitdir],
2226   AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [directory for systemd unit files (requires systemd support)]),
2227   [], [with_systemdsystemunitdir=check]
2228 )
2229 AS_IF([test "x$with_systemdsystemunitdir" = xcheck], [
2230   AS_IF([test "x$have_systemd" = xyes], [
2231     with_systemdsystemunitdir=`$PKG_CONFIG --variable=systemdsystemunitdir systemd`
2232   ],[
2233     with_systemdsystemunitdir=no
2234   ])
2235 ])
2236 AS_IF([test "x$with_systemdsystemunitdir" != "xno"], [
2237   AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
2238 ])
2239
2240
2241 AC_ARG_WITH([smack],
2242   AS_HELP_STRING([--with-smack], [build with SMACK support]),
2243   [], [with_smack=no]
2244 )
2245 AS_IF([test "x$with_smack" = xyes], [
2246   AC_DEFINE([HAVE_SMACK], [1], [Add SMACK support])
2247 ])
2248
2249
2250 AC_ARG_WITH([bashcompletiondir],
2251   AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
2252   [],
2253   [AS_IF([`$PKG_CONFIG --exists bash-completion`], [
2254     with_bashcompletiondir=`$PKG_CONFIG --variable=completionsdir bash-completion`
2255   ], [
2256     with_bashcompletiondir=${datadir}/bash-completion/completions
2257   ])
2258 ])
2259 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
2260
2261 AC_ARG_ENABLE([bash-completion],
2262   AS_HELP_STRING([--disable-bash-completion], [do not install bash completion files]),
2263   [], [enable_bash_completion=yes]
2264 )
2265
2266 AM_CONDITIONAL([BUILD_BASH_COMPLETION], [test "x$enable_bash_completion" = xyes])
2267
2268
2269 AC_ARG_WITH([python],
2270   AS_HELP_STRING([--without-python], [do not build python bindings, use --with-python={2,3} to force version]),
2271   [], [with_python=check withval=check]
2272 )
2273
2274 have_python=no
2275 have_libpython=no
2276 AS_IF([test "x$with_python" != xno], [
2277   # We follow distributions default and look for PKG module name "python"
2278   # (minimal version is 2) but if major version is explicitly specified by
2279   # --with-python=2 or --with-python=3 then we look for PKG module "python2" or
2280   # "python3".
2281   AS_IF([test "x$withval" != xno -a "x$withval" != xyes -a "x$withval" != xcheck],
2282         [pymajor="$withval"; PYTHON=python${pymajor}], [pymajor="2"])
2283
2284   # check for python interpreter
2285   AM_PATH_PYTHON([$pymajor], [have_python=yes], [have_python=no])
2286   AS_CASE([$with_python:$have_python],
2287     [yes:no],
2288       [AC_MSG_ERROR([python selected but python interpreter not found])],
2289     [check:no],
2290        [AC_MSG_WARN([python interpreter not found, do not build python bindings])],
2291     [*:yes],
2292        # check for python development stuff
2293        [PKG_CHECK_MODULES([PYTHON], [python-$PYTHON_VERSION],
2294                           [have_libpython=yes], [have_libpython=no])]
2295   )
2296 ])
2297
2298
2299 AC_ARG_ENABLE([pylibmount],
2300   AS_HELP_STRING([--disable-pylibmount], [do not build pylibmount]),
2301   [], [UL_DEFAULT_ENABLE([pylibmount], [check])]
2302 )
2303 UL_BUILD_INIT([pylibmount])
2304 UL_REQUIRES_HAVE([pylibmount], [libpython], [libpython])
2305 UL_REQUIRES_BUILD([pylibmount], [libmount])
2306 AM_CONDITIONAL([BUILD_PYLIBMOUNT], [test "x$build_pylibmount" = "xyes"])
2307
2308 # We need to introduce a verbatim dependency into the Makefile, without automake
2309 # trying to interpret it, so push it as a AM_SUBST_NOTMAKE variable.
2310 verbatim_pylibmount_dependency='
2311
2312 # pylibmountexec module must be installed after usrlib_exec libraries,
2313 # otherwise the libtool relink step will fail to find libmount.la and
2314 # will try -lmount which is possibly not available.
2315 install-pylibmountexecLTLIBRARIES: install-usrlib_execLTLIBRARIES
2316
2317 '
2318 AC_SUBST([verbatim_pylibmount_dependency])
2319 AM_SUBST_NOTMAKE([verbatim_pylibmount_dependency])
2320
2321 AC_ARG_ENABLE([pg-bell],
2322   AS_HELP_STRING([--disable-pg-bell], [let pg not ring the bell on invalid keys]),
2323   [], [enable_pg_bell=yes]
2324 )
2325
2326 AS_IF([test "x$enable_pg_bell" = xyes], [
2327   AC_DEFINE([PG_BELL], [1], [Should pg ring the bell on invalid keys?])
2328 ])
2329
2330
2331 AC_DEFUN([FS_PATHS_DEFAULT], [/sbin:/sbin/fs.d:/sbin/fs])
2332 AC_ARG_ENABLE([fs-paths-default],
2333   AS_HELP_STRING([--enable-fs-paths-default=paths], [default search path for fs helpers @<:@FS_PATHS_DEFAULT@:>@]),
2334   [AS_CASE([$enableval],
2335     [yes], [fs_paths_defaults="FS_PATHS_DEFAULT"],
2336     [no],  [fs_paths_defaults=""],
2337     [fs_paths_defaults="$enableval"]
2338   )],
2339   [fs_paths_defaults="FS_PATHS_DEFAULT"]
2340 )
2341 AC_ARG_ENABLE([fs-paths-extra],
2342   AS_HELP_STRING([--enable-fs-paths-extra=paths], [additional search paths for fs helpers]),
2343   [AS_CASE([$enableval],
2344      [yes|no], [fs_paths_extra=""],
2345      [fs_paths_extra="$enableval"]
2346   )],
2347   [fs_paths_extra=""]
2348 )
2349 fs_paths="$fs_paths_defaults"
2350 AS_IF([test "x$fs_paths_extra" != "x"], [
2351   AS_IF([test "x$fs_paths" != "x"], [
2352     fs_paths="${fs_paths}:"
2353   ])
2354   fs_paths="${fs_paths}${fs_paths_extra}"
2355 ])
2356 AC_DEFINE_UNQUOTED([FS_SEARCH_PATH], "$fs_paths", [search path for fs helpers])
2357
2358
2359 AC_ARG_ENABLE([use-tty-group],
2360   AS_HELP_STRING([--disable-use-tty-group], [do not install wall and write setgid tty]),
2361   [], [enable_use_tty_group=yes]
2362 )
2363 AM_CONDITIONAL([USE_TTY_GROUP], [test "x$enable_use_tty_group" = xyes])
2364
2365 AS_IF([test "x$enable_use_tty_group" = xyes], [
2366   AC_DEFINE([USE_TTY_GROUP], [1], [Should wall and write be installed setgid tty?])
2367 ])
2368
2369
2370 AC_ARG_ENABLE([sulogin-emergency-mount],
2371   AS_HELP_STRING([--enable-sulogin-emergency-mount],
2372                  [use emergency mount of /dev and /proc for sulogin]),
2373   [], [enable_sulogin_emergency_mount=no]
2374 )
2375
2376 AS_IF([test "x$enable_sulogin_emergency_mount" = xyes], [
2377   AC_DEFINE([USE_SULOGIN_EMERGENCY_MOUNT], [1],
2378             [Should sulogin use a emergency mount of /dev and /proc?])
2379 ])
2380
2381
2382 AC_ARG_ENABLE([usrdir-path],
2383   AS_HELP_STRING([--enable-usrdir-path], [use only /usr paths in PATH env. variable (recommended on systems with /bin -> /usr/bin symlinks)]),
2384   [], [enable_usrdir_path=no]
2385 )
2386
2387 AS_IF([test "x$enable_usrdir_path" = xyes], [
2388   AC_DEFINE([USE_USRDIR_PATHS_ONLY], [1], [Define to 1 to remove /bin and /sbin from PATH env.variable])
2389 ])
2390
2391
2392 AC_ARG_ENABLE([makeinstall-chown],
2393   AS_HELP_STRING([--disable-makeinstall-chown], [do not do chown-like operations during "make install"]),
2394   [], [enable_makeinstall_chown=yes]
2395 )
2396 AM_CONDITIONAL([MAKEINSTALL_DO_CHOWN], [test "x$enable_makeinstall_chown" = xyes])
2397
2398
2399 AC_ARG_ENABLE([makeinstall-setuid],
2400   AS_HELP_STRING([--disable-makeinstall-setuid], [do not do setuid chmod operations during "make install"]),
2401   [], [enable_makeinstall_setuid=yes]
2402 )
2403 AM_CONDITIONAL([MAKEINSTALL_DO_SETUID], [test "x$enable_makeinstall_setuid" = xyes])
2404
2405
2406 AC_ARG_ENABLE([colors-default],
2407   AS_HELP_STRING([--disable-colors-default], [do not colorize output from utils by default]),
2408   [], [enable_colors_default=yes]
2409 )
2410 AS_IF([test "x$enable_colors_default" = xyes], [
2411   AC_DEFINE([USE_COLORS_BY_DEFAULT], [1], [Enables colorized output from utils by default])
2412 ])
2413
2414
2415 AC_ARG_VAR([SUID_CFLAGS],
2416            [CFLAGS used for binaries which are usually with the suid bit])
2417 AC_ARG_VAR([SUID_LDFLAGS],
2418            [LDFLAGS used for binaries which are usually with the suid bit])
2419
2420 AC_ARG_VAR([DAEMON_CFLAGS],
2421            [CFLAGS used for binaries which are usually executed as daemons])
2422 AC_ARG_VAR([DAEMON_LDFLAGS],
2423            [LDFLAGS used for binaries which are usually executed as daemons])
2424
2425 AC_ARG_VAR([SOLIB_CFLAGS],
2426            [CFLAGS used for shared libraries])
2427 AC_ARG_VAR([SOLIB_LDFLAGS],
2428            [LDFLAGS used for shared libraries])
2429
2430 AC_ARG_VAR([ADJTIME_PATH],
2431            [Path to hwclock adjtime file, default /etc/adjtime])
2432 AS_IF([test "x$ADJTIME_PATH" = x], [ADJTIME_PATH="/etc/adjtime"])
2433 AC_DEFINE_UNQUOTED([CONFIG_ADJTIME_PATH], "$ADJTIME_PATH", [Path to hwclock adjtime file])
2434
2435
2436 LIBS=""
2437
2438
2439 AC_CONFIG_HEADERS([config.h])
2440
2441 #
2442 # Don't use configure.ac to replace install paths! See Makefile PATHFILES for
2443 # more details.
2444 #
2445 AC_CONFIG_FILES([
2446 Makefile
2447 libblkid/docs/Makefile
2448 libblkid/docs/version.xml
2449 libblkid/src/blkid.h
2450 libfdisk/docs/Makefile
2451 libfdisk/docs/version.xml
2452 libfdisk/src/libfdisk.h
2453 libmount/docs/Makefile
2454 libmount/docs/version.xml
2455 libmount/src/libmount.h
2456 libsmartcols/docs/Makefile
2457 libsmartcols/docs/version.xml
2458 libsmartcols/src/libsmartcols.h
2459 po/Makefile.in
2460 ])
2461
2462 AC_OUTPUT
2463
2464 AC_MSG_RESULT([
2465         ${PACKAGE}  ${VERSION}
2466
2467         prefix:            ${prefix}
2468         exec prefix:       ${exec_prefix}
2469
2470         runstatedir:       ${runstatedir}
2471         bindir:            ${bindir}
2472         sbindir:           ${sbindir}
2473         libdir:            ${libdir}
2474         includedir:        ${includedir}
2475         usrbin_execdir:    ${usrbin_execdir}
2476         usrsbin_execdir:   ${usrsbin_execdir}
2477         usrlib_execdir:    ${usrlib_execdir}
2478
2479         compiler:          ${CC}
2480         cflags:            ${CFLAGS}
2481         suid cflags:       ${SUID_CFLAGS}
2482         ldflags:           ${LDFLAGS}
2483         suid ldflags:      ${SUID_LDFLAGS}
2484         ASAN enabled:      ${enable_asan}
2485
2486         Python:            ${PYTHON}
2487         Python version:    ${PYTHON_VERSION}
2488         Python libs:       ${pyexecdir}
2489
2490         Bash completions:  ${with_bashcompletiondir}
2491         Systemd support:   ${have_systemd}
2492         Systemd unitdir:   ${with_systemdsystemunitdir}
2493         Btrfs support:     ${have_btrfs}
2494         Wide-char support: ${build_widechar}
2495
2496         warnings:
2497
2498 ${WARN_CFLAGS}
2499
2500         Type 'make' or 'make <utilname>' to compile.
2501 ])