configure.ac

   1 AC_INIT([util-linux],
   2         m4_esyscmd([tools/git-version-gen .tarball-version]),
   3         [kzak@redhat.com],,
   4         [http://www.kernel.org/pub/linux/utils/util-linux/])
   5
   6
   7 AC_PREREQ([2.60])
   8
   9 AC_CONFIG_AUX_DIR([config])
  10 AC_CONFIG_MACRO_DIR([m4])
  11 dnl AC_USE_SYSTEM_EXTENSIONS must be called before any macros that run
  12 dnl the compiler (like AC_PROG_LIBTOOL) to avoid autoconf errors.
  13 AC_USE_SYSTEM_EXTENSIONS
  14 AM_INIT_AUTOMAKE([-Wall foreign 1.10 tar-pax no-dist-gzip dist-xz subdir-objects])
  15
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  17                             [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  18 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  19
  20 AC_CONFIG_SRCDIR([sys-utils/mount.c])
  21 AC_PREFIX_DEFAULT([/usr])
  22
  23 dnl version details from <major>.<minor>[-<suffix>]
  24 PACKAGE_VERSION_MAJOR=$(echo $PACKAGE_VERSION | awk -F. '{print $1}')
  25 PACKAGE_VERSION_MINOR=$(echo $PACKAGE_VERSION | awk -F. '{
  26                                                    sub("-.*","",$2); print $2}')
  27 PACKAGE_VERSION_RELEASE=$(echo $PACKAGE_VERSION | awk -F. '{
  28                      sub("-.*","",$3); print $3 ~ /^@<:@0-9@:>@+$/ ? $3 : 0}')
  29
  30 dnl libblkid version
  31 LIBBLKID_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  32 LIBBLKID_DATE="14-Jun-2019"
  33 LIBBLKID_LT_MAJOR=1
  34 LIBBLKID_LT_MINOR=1
  35 LIBBLKID_LT_MICRO=0
  36 LIBBLKID_VERSION_INFO=`expr $LIBBLKID_LT_MAJOR + $LIBBLKID_LT_MINOR`:$LIBBLKID_LT_MICRO:$LIBBLKID_LT_MINOR
  37
  38 dnl libuuid version
  39 LIBUUID_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  40 LIBUUID_LT_MAJOR=1
  41 LIBUUID_LT_MINOR=3
  42 LIBUUID_LT_MICRO=0
  43 LIBUUID_VERSION_INFO=`expr $LIBUUID_LT_MAJOR + $LIBUUID_LT_MINOR`:$LIBUUID_LT_MICRO:$LIBUUID_LT_MINOR
  44
  45 dnl libmount version
  46 LIBMOUNT_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  47 LIBMOUNT_LT_MAJOR=1
  48 LIBMOUNT_LT_MINOR=1
  49 LIBMOUNT_LT_MICRO=0
  50 LIBMOUNT_VERSION_INFO=`expr $LIBMOUNT_LT_MAJOR + $LIBMOUNT_LT_MINOR`:$LIBMOUNT_LT_MICRO:$LIBMOUNT_LT_MINOR
  51
  52 dnl libsmartcols version
  53 LIBSMARTCOLS_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  54 LIBSMARTCOLS_LT_MAJOR=1
  55 LIBSMARTCOLS_LT_MINOR=1
  56 LIBSMARTCOLS_LT_MICRO=0
  57 LIBSMARTCOLS_VERSION_INFO=`expr $LIBSMARTCOLS_LT_MAJOR + $LIBSMARTCOLS_LT_MINOR`:$LIBSMARTCOLS_LT_MICRO:$LIBSMARTCOLS_LT_MINOR
  58
  59 dnl libfdisk version
  60 LIBFDISK_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  61 LIBFDISK_LT_MAJOR=1
  62 LIBFDISK_LT_MINOR=1
  63 LIBFDISK_LT_MICRO=0
  64 LIBFDISK_VERSION_INFO=`expr $LIBFDISK_LT_MAJOR + $LIBFDISK_LT_MINOR`:$LIBFDISK_LT_MICRO:$LIBFDISK_LT_MINOR
  65
  66 # Check whether exec_prefix=/usr:
  67 AS_CASE([$exec_prefix:$prefix],
  68 [NONE:NONE | NONE:/usr | /usr:*],
  69   [AC_MSG_NOTICE([Default --exec-prefix detected.])
  70    AS_CASE([$bindir],  ['${exec_prefix}/bin'],  [bindir=/bin;   AC_MSG_NOTICE([  --bindir defaults to /bin])  ])
  71    AS_CASE([$sbindir], ['${exec_prefix}/sbin'], [sbindir=/sbin; AC_MSG_NOTICE([  --sbindir defaults to /sbin])])
  72    AS_CASE([$libdir],  ['${exec_prefix}/lib'],  [libdir=/lib;   AC_MSG_NOTICE([  --libdir defaults to /lib])  ])
  73    AS_CASE([$libdir],  ['${exec_prefix}/lib64'],[libdir=/lib64; AC_MSG_NOTICE([  --libdir defaults to /lib64])  ])
  74   ]
  75 )
  76
  77
  78 # default for old versions without $runstatedir
  79 AS_IF([test x"$runstatedir" = x], [runstatedir='${localstatedir}/run'])
  80
  81 # our default if $localstatedir unchanged
  82 AS_CASE([$localstatedir:$runstatedir],
  83  [NONE:'${localstatedir}/run' | /var:'${localstatedir}/run' | NONE:'/run' ],
  84    [runstatedir=/run; AC_MSG_NOTICE([  --runstatedir defaults to /run])]
  85 )
  86
  87 AC_SUBST([runstatedir])
  88
  89
  90 # The original default values of {bin,sbin,lib}dir
  91 usrbin_execdir='${exec_prefix}/bin'
  92 AC_SUBST([usrbin_execdir])
  93
  94 usrsbin_execdir='${exec_prefix}/sbin'
  95 AC_SUBST([usrsbin_execdir])
  96
  97 AS_CASE([$libdir],
  98  ['${exec_prefix}/'* | '${prefix}/'* | /usr/* | "${prefix}"/* ],
  99    [usrlib_execdir=$libdir],
 100  [usrlib_execdir='${exec_prefix}'$libdir]
 101 )
 102 AC_SUBST([usrlib_execdir])
 103
 104
 105 AM_PROG_CC_C_O
 106 AC_PROG_MKDIR_P
 107 AC_PROG_CC_STDC
 108 AC_PROG_YACC
 109 AC_CANONICAL_HOST
 110 AC_C_CONST
 111 AC_C_VOLATILE
 112 AC_C_BIGENDIAN
 113
 114 dnl Compiler warnings
 115 UL_WARN_ADD([-fno-common])
 116 UL_WARN_ADD([-Wall])
 117 UL_WARN_ADD([-Werror=sequence-point])
 118 UL_WARN_ADD([-Wextra])
 119 UL_WARN_ADD([-Wextra-semi])
 120 UL_WARN_ADD([-Wembedded-directive])
 121 UL_WARN_ADD([-Wmissing-declarations])
 122 UL_WARN_ADD([-Wmissing-parameter-type])
 123 UL_WARN_ADD([-Wmissing-prototypes])
 124 UL_WARN_ADD([-Wno-missing-field-initializers])
 125 UL_WARN_ADD([-Wredundant-decls])
 126 UL_WARN_ADD([-Wsign-compare])
 127 UL_WARN_ADD([-Wtype-limits])
 128 UL_WARN_ADD([-Wuninitialized])
 129 UL_WARN_ADD([-Wunused-but-set-parameter])
 130 UL_WARN_ADD([-Wunused-but-set-variable])
 131 UL_WARN_ADD([-Wunused-parameter])
 132 UL_WARN_ADD([-Wunused-result])
 133 UL_WARN_ADD([-Wunused-variable])
 134 UL_WARN_ADD([-Wnested-externs])
 135 UL_WARN_ADD([-Wpointer-arith])
 136 UL_WARN_ADD([-Wstrict-prototypes])
 137 UL_WARN_ADD([-Wformat-security])
 138 UL_WARN_ADD([-Wimplicit-function-declaration])
 139 UL_WARN_ADD([-Wdiscarded-qualifiers])
 140 AC_SUBST([WARN_CFLAGS])
 141
 142 UL_WARN_ADD([-Wno-clobbered], [BSD_WARN_CFLAGS])
 143 AC_SUBST([BSD_WARN_CFLAGS])
 144
 145 UL_WARN_ADD([-Wno-cast-function-type], [PYTHON_WARN_CFLAGS])
 146 AC_SUBST([PYTHON_WARN_CFLAGS])
 147
 148 UL_WARN_ADD([-Wno-unused-parameter], [NO_UNUSED_WARN_CFLAGS])
 149 AC_SUBST([NO_UNUSED_WARN_CFLAGS])
 150
 151
 152 AC_ARG_ENABLE([asan],
 153   AS_HELP_STRING([--enable-asan], [compile with Address Sanitizer]),
 154   [], [enable_asan=no]
 155 )
 156 AS_IF([test "x$enable_asan" = xyes], [
 157   UL_WARN_ADD([-fsanitize=address])
 158   ASAN_LDFLAGS="-fsanitize=address"
 159 ])
 160 AC_SUBST([ASAN_LDFLAGS])
 161
 162 dnl libtool-2
 163 LT_INIT
 164
 165 dnl check supported linker flags
 166 AX_CHECK_VSCRIPT
 167
 168 m4_ifndef([PKG_PROG_PKG_CONFIG],
 169   [m4_fatal([Could not locate the pkg-config autoconf
 170     macros. These are usually located in /usr/share/aclocal/pkg.m4.
 171     If your macros are in a different location, try setting the
 172     environment variable AL_OPTS="-I/other/macro/dir" before running
 173     ./autogen.sh or autoreconf again. Make sure pkg-config is installed.])])
 174 PKG_PROG_PKG_CONFIG
 175 PKG_INSTALLDIR(['${usrlib_execdir}/pkgconfig'])
 176
 177 GTK_DOC_CHECK([1.10])
 178 AC_PATH_PROG([XSLTPROC], [xsltproc])
 179
 180 linux_os=no
 181 bsd_os=no
 182 AS_CASE([${host_os}],
 183   [*linux*],
 184      [linux_os=yes],
 185   [*darwin*],
 186      [darwin_os=yes],
 187   [*bsd*],
 188      [bsd_os=yes])
 189 AM_CONDITIONAL([LINUX], [test "x$linux_os" = xyes])
 190 AM_CONDITIONAL([DARWIN], [test "x$darwin_os" = xyes])
 191 AM_CONDITIONAL([BSD], [test "x$bsd_os" = xyes])
 192
 193 AS_IF([test  "x$darwin_os" = xyes], [
 194   AC_DEFINE([_DARWIN_C_SOURCE], [1], [Enable MAP_ANON in sys/mman.h on Mac OS X])
 195 ])
 196
 197 dnl define ARCH_<NAME> conditionals
 198 UL_SET_ARCH([I86], [i?86-*])
 199 UL_SET_ARCH([86_64], [x86_64*])
 200 UL_SET_ARCH([IA64], [ia64*])
 201 UL_SET_ARCH([S390], [s390*])
 202 UL_SET_ARCH([SPARC], [sparc*])
 203 UL_SET_ARCH([PPC], [ppc*|powerpc*])
 204 UL_SET_ARCH([M68K], [m68*])
 205 UL_SET_ARCH([MIPS], [mips*])
 206 UL_SET_ARCH([HPPA], [hppa*|parisc*])
 207
 208 AC_SYS_LARGEFILE
 209 AC_HEADER_ASSERT
 210 AC_STRUCT_TIMEZONE
 211
 212 dnl Don't forget to maintain alternatively allowed versions in autogen.sh!
 213 AM_GNU_GETTEXT_VERSION([0.18.3])
 214 AM_GNU_GETTEXT([external])
 215
 216 AS_IF([test -d "$srcdir/po"], [
 217   ALL_LINGUAS=`cd $srcdir/po > /dev/null && echo *.po | sed 's/\.po//g'`
 218 ], [
 219   ALL_LINGUAS="af am ar as be bg bn_IN bn ca cs cy da de el en_GB es et eu_ES fa fi fr gl gu he hi hr hu hy id is it ja ka kn ko ku lo lt lv mk ml mr ms my nb nl nn no nso or pa pl pt_BR pt ro ru si sk sl sq sr@Latn sr sv ta te th tr uk ur vi zh_CN zh_TW zu"
 220 ])
 221
 222 AC_CHECK_HEADERS([linux/compiler.h linux/blkpg.h linux/major.h], [], [], [
 223 #ifdef HAVE_LINUX_COMPILER_H
 224 #include <linux/compiler.h>
 225 #endif
 226 ])
 227 AC_CHECK_HEADERS([ \
 228         asm/io.h \
 229         err.h \
 230         errno.h \
 231         fcntl.h \
 232         getopt.h \
 233         inttypes.h \
 234         lastlog.h \
 235         libutil.h \
 236         linux/btrfs.h \
 237         linux/cdrom.h \
 238         linux/falloc.h \
 239         linux/watchdog.h \
 240         linux/fd.h \
 241         linux/raw.h \
 242         linux/tiocl.h \
 243         linux/version.h \
 244         linux/securebits.h \
 245         linux/net_namespace.h \
 246         locale.h \
 247         mntent.h \
 248         net/if.h \
 249         net/if_dl.h \
 250         netinet/in.h \
 251         paths.h \
 252         pty.h \
 253         security/pam_appl.h \
 254         stdint.h \
 255         stdio_ext.h \
 256         stdlib.h \
 257         endian.h \
 258         byteswap.h \
 259         sys/endian.h \
 260         sys/disk.h \
 261         sys/disklabel.h \
 262         sys/file.h \
 263         sys/io.h \
 264         sys/ioccom.h \
 265         sys/ioctl.h \
 266         sys/mkdev.h \
 267         sys/mount.h \
 268         sys/param.h \
 269         sys/prctl.h \
 270         sys/resource.h \
 271         sys/signalfd.h \
 272         sys/socket.h \
 273         sys/sockio.h \
 274         sys/stat.h \
 275         sys/sysmacros.h \
 276         sys/swap.h \
 277         sys/syscall.h \
 278         sys/time.h \
 279         sys/timex.h \
 280         sys/ttydefaults.h \
 281         sys/types.h \
 282         sys/ucred.h \
 283         sys/un.h \
 284         unistd.h \
 285         shadow.h \
 286         utmp.h \
 287         utmpx.h \
 288 ])
 289
 290 # There is a collision in old kernel-headers. The both files mount.h and fs.h
 291 # define MS_* macros. Fixed by kernel commit e462ec50cb5fad19f6003a3d8087f4a0945dd2b1.
 292 #
 293 AC_CHECK_HEADERS([linux/fs.h ], [], [],
 294  [#ifdef HAVE_SYS_MOUNT_H
 295    # include <linux/fs.h>
 296    # include <sys/mount.h>
 297   #endif
 298 ])
 299
 300 AC_CHECK_HEADERS([linux/gsmmux.h ], [], [],
 301  [#ifdef LINUX_GSMMUX_H
 302    # include <linux/gsmmux.h>
 303    #endif
 304 ])
 305
 306 AC_CHECK_HEADERS([security/pam_misc.h],
 307                 [AM_CONDITIONAL([HAVE_LINUXPAM], [true])],
 308                 [AM_CONDITIONAL([HAVE_LINUXPAM], [false])], [
 309 #ifdef HAVE_SECURITY_PAM_APPL_H
 310 #include <security/pam_appl.h>
 311 #endif
 312 ])
 313
 314 AC_CHECK_HEADERS([linux/blkzoned.h])
 315
 316 AC_CHECK_HEADERS([security/openpam.h], [], [], [
 317 #ifdef HAVE_SECURITY_PAM_APPL_H
 318 #include <security/pam_appl.h>
 319 #endif
 320 ])
 321
 322 AC_CHECK_HEADERS([langinfo.h],
 323                 [AM_CONDITIONAL([HAVE_LANGINFO], [true])],
 324                 [AM_CONDITIONAL([HAVE_LANGINFO], [false])])
 325
 326 AC_MSG_CHECKING([whether langinfo.h defines ALTMON_x constants])
 327 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 328         #include <langinfo.h>
 329 ]], [[
 330         char *str;
 331         str = nl_langinfo (ALTMON_1);
 332         str = nl_langinfo (ALTMON_2);
 333         str = nl_langinfo (ALTMON_3);
 334         str = nl_langinfo (ALTMON_4);
 335         str = nl_langinfo (ALTMON_5);
 336         str = nl_langinfo (ALTMON_6);
 337         str = nl_langinfo (ALTMON_7);
 338         str = nl_langinfo (ALTMON_8);
 339         str = nl_langinfo (ALTMON_9);
 340         str = nl_langinfo (ALTMON_10);
 341         str = nl_langinfo (ALTMON_11);
 342         str = nl_langinfo (ALTMON_12);
 343 ]])], [
 344         AC_MSG_RESULT([yes])
 345         AC_DEFINE([HAVE_LANGINFO_ALTMON], [1],
 346                 [Define if langinfo.h defines ALTMON_x constants])
 347 ], [
 348         AC_MSG_RESULT([no])
 349 ])
 350
 351
 352 AC_MSG_CHECKING([whether langinfo.h defines _NL_ABALTMON_x constants])
 353 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 354         #include <langinfo.h>
 355 ]], [[
 356         char *str;
 357         str = nl_langinfo (_NL_ABALTMON_1);
 358         str = nl_langinfo (_NL_ABALTMON_2);
 359         str = nl_langinfo (_NL_ABALTMON_3);
 360         str = nl_langinfo (_NL_ABALTMON_4);
 361         str = nl_langinfo (_NL_ABALTMON_5);
 362         str = nl_langinfo (_NL_ABALTMON_6);
 363         str = nl_langinfo (_NL_ABALTMON_7);
 364         str = nl_langinfo (_NL_ABALTMON_8);
 365         str = nl_langinfo (_NL_ABALTMON_9);
 366         str = nl_langinfo (_NL_ABALTMON_10);
 367         str = nl_langinfo (_NL_ABALTMON_11);
 368         str = nl_langinfo (_NL_ABALTMON_12);
 369 ]])], [
 370         AC_MSG_RESULT([yes])
 371         AC_DEFINE([HAVE_LANGINFO_NL_ABALTMON], [1],
 372                 [Define if langinfo.h defines _NL_ABALTMON_x constants])
 373 ], [
 374         AC_MSG_RESULT([no])
 375 ])
 376
 377
 378 dnl Convert some ac_cv_header_* variables to have_*
 379 dnl
 380 have_linux_version_h=$ac_cv_header_linux_version_h
 381 have_linux_blkzoned_h=$ac_cv_header_linux_blkzoned_h
 382 have_linux_btrfs_h=$ac_cv_header_linux_btrfs_h
 383 have_linux_raw_h=$ac_cv_header_linux_raw_h
 384 have_linux_securebits_h=$ac_cv_header_linux_securebits_h
 385 have_linux_watchdog_h=$ac_cv_header_linux_watchdog_h
 386 have_security_pam_appl_h=$ac_cv_header_security_pam_appl_h
 387 have_security_pam_misc_h=$ac_cv_header_security_pam_misc_h
 388 have_security_openpam_h=$ac_cv_header_security_openpam_h
 389 have_shadow_h=$ac_cv_header_shadow_h
 390 have_sys_signalfd_h=$ac_cv_header_sys_signalfd_h
 391 have_utmpx_h=$ac_cv_header_utmpx_h
 392
 393 AS_CASE([$linux_os:$have_linux_version_h],
 394   [yes:no],
 395     [AC_MSG_ERROR([kernel headers required on Linux])]
 396 )
 397
 398 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 399 #include <time.h>
 400 #include <unistd.h>
 401 ]], [[
 402     int a = 0;
 403     struct tm *tm = localtime(0);
 404     if (a == -1)  /* false */
 405         sleep(tm->tm_gmtoff);
 406 ]])],
 407 [AC_DEFINE([HAVE_TM_GMTOFF], [1], [Does struct tm have a field tm_gmtoff?])
 408 ])
 409
 410 AC_CHECK_MEMBERS([struct termios.c_line],,,
 411     [[#include <termios.h>]])
 412
 413 AC_CHECK_MEMBERS([struct stat.st_mtim.tv_nsec],,,
 414         [#include <sys/stat.h>])
 415
 416 AC_CHECK_DECLS([_NL_TIME_WEEK_1STDAY],[],[],[[#include <langinfo.h>]])
 417
 418 AC_CHECK_DECL([llseek],
 419         [AC_DEFINE([HAVE_LLSEEK_PROTOTYPE], [1],
 420                         [Define to 1 if have llseek prototype])],
 421         [],
 422         [#include <unistd.h>])
 423
 424 AC_CHECK_DECL([lseek64],
 425         [AC_DEFINE([HAVE_LSEEK64_PROTOTYPE], [1],
 426                         [Define to 1 if have lseek64 prototype])],
 427         [],
 428         [#define _LARGEFILE_SOURCE
 429          #define _LARGEFILE64_SOURCE
 430          #include <unistd.h>])
 431
 432 AC_CHECK_DECL([environ],
 433         [AC_DEFINE([HAVE_ENVIRON_DECL], [1],
 434                 [Define to 1 if have **environ prototype])],
 435 )
 436
 437 AC_CHECK_DECL([strsignal],
 438         [AC_DEFINE([HAVE_STRSIGNAL_DECL], [1],
 439                 [Define to 1 if have strsignal function prototype])],
 440 )
 441
 442 AC_CHECK_DECL([TIOCGLCKTRMIOS],
 443               [have_tiocglcktrmios=yes], [have_tiocglcktrmios=no],
 444               [#include <sys/ioctl.h>])
 445 AC_CHECK_DECL([SOCK_CLOEXEC],
 446               [have_sock_cloexec=yes], [have_sock_cloexec=no],
 447               [#include <sys/types.h>
 448                #include <sys/socket.h>])
 449 AC_CHECK_DECL([SOCK_NONBLOCK],
 450               [have_sock_nonblock=yes], [have_sock_nonblock=no],
 451               [#include <sys/types.h>
 452                #include <sys/socket.h>])
 453 AC_CHECK_DECL([SO_PASSCRED],
 454               [have_so_passcred=yes], [have_so_passcred=no],
 455               [#include <sys/types.h>
 456                #include <sys/socket.h>])
 457
 458 AC_CHECK_FUNCS([ \
 459         clearenv \
 460         __fpurge \
 461         fpurge \
 462         __fpending \
 463         secure_getenv \
 464         __secure_getenv \
 465         eaccess \
 466         err \
 467         errx \
 468         explicit_bzero \
 469         fsync \
 470         utimensat \
 471         getdomainname \
 472         getdtablesize \
 473         getexecname \
 474         getmntinfo \
 475         getrandom \
 476         getrlimit \
 477         getsgnam \
 478         inotify_init \
 479         jrand48 \
 480         lchown \
 481         llseek \
 482         lseek64 \
 483         mempcpy \
 484         mkostemp \
 485         nanosleep \
 486         ntp_gettime \
 487         personality \
 488         posix_fadvise \
 489         prctl \
 490         qsort_r \
 491         rpmatch \
 492         scandirat \
 493         setprogname \
 494         setresgid \
 495         setresuid \
 496         sched_setattr \
 497         sched_setscheduler \
 498         sigqueue \
 499         srandom \
 500         strnchr \
 501         strndup \
 502         strnlen \
 503         sysconf \
 504         sysinfo \
 505         timegm \
 506         usleep \
 507         vwarnx \
 508         warn \
 509         warnx \
 510 ])
 511 AC_FUNC_FSEEKO
 512
 513 AC_CHECK_FUNCS([openat fstatat unlinkat], [have_openat=yes], [have_openat=no])
 514 AC_CHECK_FUNCS([ioperm iopl], [have_io=yes])
 515 AC_CHECK_FUNCS([futimens], [have_futimens=yes])
 516 AC_CHECK_FUNCS([inotify_init1], [have_inotify_init1=yes])
 517 AC_CHECK_FUNCS([open_memstream], [have_open_memstream=yes],[have_open_memstream=no])
 518 AC_CHECK_FUNCS([reboot], [have_reboot=yes],[have_reboot=no])
 519 AC_CHECK_FUNCS([updwtmpx updwtmpx], [have_gnu_utmpx=yes], [have_gnu_utmpx=no])
 520 AC_CHECK_FUNCS([getusershell], [have_getusershell=yes],[have_getusershell=no])
 521
 522 AM_CONDITIONAL([HAVE_OPENAT], [test "x$have_openat" = xyes])
 523
 524 have_setns_syscall="yes"
 525 UL_CHECK_SYSCALL([setns])
 526 AS_IF([test "x$ul_cv_syscall_setns" = xno], [
 527    have_setns_syscall="no"
 528 ])
 529
 530 AC_CHECK_FUNCS([isnan], [],
 531         [AC_CHECK_LIB([m], [isnan], [MATH_LIBS="-lm"])]
 532         [AC_CHECK_LIB([m], [__isnan], [MATH_LIBS="-lm"])]
 533 )
 534 AC_SUBST([MATH_LIBS])
 535
 536
 537 dnl lib/mononotic.c may require -lrt
 538 AC_CHECK_FUNCS([clock_gettime], [],
 539         [AC_CHECK_LIB([rt], [clock_gettime], [REALTIME_LIBS="-lrt"])]
 540 )
 541
 542 have_timer="no"
 543 AC_CHECK_FUNCS([timer_create],
 544         [have_timer="yes"],
 545         [AC_CHECK_LIB([rt], [timer_create], [
 546                 have_timer="yes"
 547                 REALTIME_LIBS="-lrt"
 548                 AC_DEFINE_UNQUOTED([HAVE_TIMER_CREATE], [1], [Define if timer_create exist in -lrt])
 549         ],[
 550                 AC_SEARCH_LIBS([timer_create], [rt], [
 551                         AC_MSG_RESULT(yes)
 552                         have_timer="yes"
 553                         REALTIME_LIBS="-lrt -lpthread"
 554                         AC_DEFINE_UNQUOTED([HAVE_TIMER_CREATE], [1], [Define if timer_create exist in -lrt -lpthread])
 555                 ],[], [-lpthread]
 556                 )
 557         ])]
 558 )
 559
 560 AC_SUBST([REALTIME_LIBS])
 561
 562 AS_IF([test x"$have_timer" = xno], [
 563        AC_CHECK_FUNCS([setitimer], [have_timer="yes"], [have_timer="no"])
 564 ])
 565
 566
 567 AC_CHECK_LIB([rtas], [rtas_get_sysparm], [
 568         RTAS_LIBS="-lrtas"
 569         AC_DEFINE_UNQUOTED([HAVE_LIBRTAS], [1], [Define if librtas exists]), [],
 570 ])
 571 AC_SUBST([RTAS_LIBS])
 572
 573
 574 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 575                 AC_DEFINE_UNQUOTED([HAVE_SA_LEN], [1], [Define if struct sockaddr contains sa_len]), [],
 576         [#include <sys/types.h>
 577          #include <sys/socket.h>])
 578
 579 SOCKET_LIBS=
 580 AC_SEARCH_LIBS([socket], [socket],
 581         [AS_IF([test x"$ac_cv_search_socket" != x"none required"],
 582                 [SOCKET_LIBS="$SOCKET_LIBS -lsocket"])
 583 ])
 584 AC_SUBST([SOCKET_LIBS])
 585
 586
 587 have_dirfd=no
 588 AC_CHECK_FUNCS([dirfd], [have_dirfd=yes], [have_dirfd=no])
 589 AS_IF([test x"$have_dirfd" = xno], [
 590         AC_CHECK_DECLS([dirfd],
 591                 [have_dirfd=yes], [have_dirfd=no],
 592                 [#include <sys/types.h>
 593                  #include <dirent.h>])
 594 ])
 595
 596 have_ddfd=no
 597 AS_IF([test x"$have_dirfd" = xno], [
 598         AC_CHECK_MEMBERS([DIR.dd_fd],
 599                 [have_ddfd=yes], [have_ddfd=no],
 600                 [#include <sys/types.h>
 601                  #include <dirent.h>])
 602 ])
 603
 604 AM_CONDITIONAL([HAVE_DIRFD], [test "x$have_dirfd" = xyes -o "x$have_ddfd" = xyes])
 605
 606
 607 AC_MSG_CHECKING([whether program_invocation_short_name is defined])
 608 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 609         #include <errno.h>
 610 ]], [[
 611         program_invocation_short_name = "test";
 612 ]])], [
 613         AC_MSG_RESULT([yes])
 614         AC_DEFINE([HAVE_PROGRAM_INVOCATION_SHORT_NAME], [1],
 615                 [Define if program_invocation_short_name is defined])
 616 ], [
 617         AC_MSG_RESULT([no])
 618 ])
 619
 620
 621 AC_MSG_CHECKING([whether __progname is defined])
 622 AC_LINK_IFELSE([AC_LANG_PROGRAM([extern char *__progname;],
 623            [if (*__progname == 0) return 1;])],
 624            AC_DEFINE([HAVE___PROGNAME], [1], [Define if __progname is defined])
 625            AC_MSG_RESULT([yes]),
 626            AC_MSG_RESULT([no]))
 627
 628 dnl Static compilation
 629 m4_define([UL_STATIC_PROGRAMS], [losetup, mount, umount, fdisk, sfdisk, blkid, nsenter, unshare])
 630
 631 AC_ARG_ENABLE([static-programs],
 632   [AS_HELP_STRING([--enable-static-programs=LIST],
 633       [link static the programs in LIST (comma-separated,
 634       supported for ]m4_defn([UL_STATIC_PROGRAMS])[)])])
 635
 636 AS_CASE([$enable_static_programs],
 637   [yes],
 638     [enable_static_programs=m4_quote(UL_STATIC_PROGRAMS)],
 639   [no],
 640     [enable_static_programs=]
 641 )
 642
 643 dnl Set all the individual AM_CONDITIONALs
 644 m4_foreach([UL_PRG], m4_defn([UL_STATIC_PROGRAMS]), [
 645   AS_CASE([,$enable_static_programs,],
 646    [*,UL_PRG,*], [static_[]UL_PRG=yes]
 647   )
 648   AS_IF([test "x$static_[]UL_PRG" = xyes], [AC_MSG_NOTICE([enable static build: UL_PRG.])])
 649   AM_CONDITIONAL([HAVE_STATIC_]m4_toupper(UL_PRG),
 650     [test "x$static_[]UL_PRG" = xyes])
 651 ])
 652
 653
 654 AC_ARG_ENABLE([all-programs],
 655   AS_HELP_STRING([--disable-all-programs], [disable everything, might be overridden by --enable-<name>]),
 656   [], [enable_all_programs=undefined]
 657 )
 658
 659 AS_CASE([$enable_all_programs],
 660   [yes], [AC_MSG_WARN([force to build all programs by default])
 661           ul_default_estate=check],
 662   [no],  [AC_MSG_WARN([disable all programs by default])
 663           ul_default_estate=no]
 664 )
 665
 666
 667 AX_CHECK_TLS
 668
 669 AC_DEFUN([UL_SCANF_TYPE_MODIFIER], [dnl
 670 # include <stdio.h>
 671 # include <stdlib.h>
 672 int main()
 673 {
 674         int i;
 675         int rc = 1;
 676         char *s;
 677         i = sscanf("x", $1, &s);
 678         if (i == 1  && *s == 'x')
 679                 rc = 0;
 680         free(s);
 681         return rc;
 682 }])
 683
 684 AC_CACHE_VAL([scanf_cv_alloc_modifier],
 685   AC_RUN_IFELSE([AC_LANG_SOURCE([UL_SCANF_TYPE_MODIFIER(["%ms"])])],
 686     [scanf_cv_alloc_modifier=ms],
 687     AC_RUN_IFELSE([AC_LANG_SOURCE([UL_SCANF_TYPE_MODIFIER(["%as"])])],
 688       [scanf_cv_alloc_modifier=as],
 689       [scanf_cv_alloc_modifier=no]
 690     )
 691     ,
 692
 693     [AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 694      #include <stdio.h>
 695      #include <unistd.h>
 696
 697      #if defined(__GLIBC__) && !defined(__UCLIBC__)
 698
 699      #if !(__GLIBC_PREREQ(2, 7))
 700      #error %m is not available
 701      #endif
 702
 703      #elif defined(_POSIX_VERSION)
 704
 705      #if _POSIX_VERSION < 200809L
 706      #error %m is not available
 707      #endif
 708
 709      #else
 710      #error Your C-library is not supported.
 711      #endif
 712      ])],
 713     [scanf_cv_alloc_modifier=ms],
 714     [scanf_cv_alloc_modifier=no])]
 715   )
 716 )
 717
 718 AC_MSG_CHECKING([scanf string alloc modifiers])
 719 AS_CASE([$scanf_cv_alloc_modifier],
 720   [ms],
 721     [AC_MSG_RESULT([(%ms) yes])
 722      AC_DEFINE([HAVE_SCANF_MS_MODIFIER], [1], [scanf %ms modifier])
 723      have_scanf_alloc_modifier=yes],
 724   [as],
 725     [AC_MSG_RESULT([(%as) yes])
 726      have_scanf_alloc_modifier=yes
 727      AC_DEFINE([HAVE_SCANF_AS_MODIFIER], [1], [scanf %as modifier])],
 728   [AC_MSG_RESULT([no])
 729    have_scanf_alloc_modifier=no]
 730 )
 731
 732
 733 AC_ARG_WITH([util], AS_HELP_STRING([--without-util], [compile without libutil]),
 734   [], [with_util=auto]
 735 )
 736 AS_IF([test "x$with_util" = xno], [
 737   AM_CONDITIONAL([HAVE_UTIL], [false])
 738   have_util=no
 739 ], [
 740   UL_CHECK_LIB([util], [openpty])
 741 ])
 742
 743
 744 AC_CHECK_TYPES([union semun], [], [], [[
 745 #include <sys/sem.h>
 746 ]])
 747 AC_CHECK_TYPES([loff_t])
 748
 749
 750 AC_ARG_ENABLE([widechar],
 751   AS_HELP_STRING([--disable-widechar], [do not compile wide character support]),
 752   [], [enable_widechar=check]
 753 )
 754 UL_BUILD_INIT([widechar])
 755 UL_REQUIRES_COMPILE([widechar], [[
 756   #include <wchar.h>
 757   #include <wctype.h>
 758   #include <stdio.h>
 759   ]], [[
 760     wchar_t wc;
 761     wint_t w;
 762     w = fgetwc(stdin);
 763     if (w == WEOF) exit(1);
 764     wc = w;
 765     fputwc(wc,stdout);
 766   ]],
 767   [wchar_t support])
 768
 769 AS_IF([test "x$build_widechar" = xyes ], [
 770   AC_DEFINE([HAVE_WIDECHAR], [1], [Do we have wide character support?])
 771 ])
 772
 773
 774 AC_CHECK_TYPES([cpu_set_t], [have_cpu_set_t=yes], [], [[
 775 #include <sched.h>
 776 ]])
 777
 778 AM_CONDITIONAL([HAVE_CPU_SET_T], [test "x$have_cpu_set_t" = xyes])
 779
 780 AC_CHECK_TYPES([sighandler_t], [], [], [[
 781 #include <signal.h>
 782 ]])
 783
 784 AC_CHECK_DECLS([CPU_ALLOC], [], [], [[
 785 #include <sched.h>
 786 ]])
 787
 788 # on Solaris, you can't mix and match standards, since we use c99
 789 # aparently at this stage, XOPEN_SOURCE will conflict.  As workaround,
 790 # check for crypt.h and use that without XOPEN_SOURCE.
 791 have_crypt=no
 792 AC_CHECK_HEADERS([crypt.h])
 793 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 794 #ifdef HAVE_CRYPT_H
 795 #include <crypt.h>
 796 #else
 797 #define _XOPEN_SOURCE
 798 #include <unistd.h>
 799 #endif
 800 ]], [[
 801 char *c = crypt("abc","pw");
 802 ]])],[
 803   have_libcrypt=no
 804   have_crypt=yes
 805 ],[
 806   LIBS="$LIBS -lcrypt"
 807   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 808   #ifdef HAVE_CRYPT_H
 809   #include <crypt.h>
 810   #else
 811   #define _XOPEN_SOURCE
 812   #include <unistd.h>
 813   #endif
 814   ]], [[
 815   char *c = crypt("abc","pw");
 816   ]])],[
 817   AC_DEFINE([HAVE_LIBCRYPT], [1], [Do we need -lcrypt?])
 818   have_libcrypt=yes
 819   have_crypt=yes
 820   ],[
 821   AC_MSG_WARN([crypt() is not available])
 822   ])
 823 ])
 824 AM_CONDITIONAL([HAVE_LIBCRYPT], [test "x$have_libcrypt" = xyes])
 825
 826
 827 AC_ARG_WITH([selinux],
 828   AS_HELP_STRING([--with-selinux], [compile with SELinux support]),
 829   [], [with_selinux=no]
 830 )
 831
 832 AS_IF([test "x$with_selinux" = xno], [
 833   AM_CONDITIONAL([HAVE_SELINUX], [false])
 834 ], [
 835   PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.0],
 836         [AC_DEFINE([HAVE_LIBSELINUX], [1], [Define if SELinux is available])
 837          UL_PKG_STATIC([SELINUX_LIBS_STATIC], [libselinux])
 838          AM_CONDITIONAL([HAVE_SELINUX], [true])
 839          have_selinux=yes],
 840         [have_selinux=no])
 841
 842   AS_CASE([$with_selinux:$have_selinux],
 843     [yes:no], [AC_MSG_ERROR([SELinux selected but libselinux not found or too old])]
 844   )
 845
 846   AS_IF([test "x$have_selinux" = xyes], [
 847     UL_SET_FLAGS([], [], [$SELINUX_LIBS])
 848     # This function is missing in old libselinux 1.xx versions
 849     AC_CHECK_FUNCS([security_get_initial_context])
 850     UL_RESTORE_FLAGS
 851   ])
 852 ])
 853 AC_SUBST([SELINUX_LIBS])
 854 AC_SUBST([SELINUX_LIBS_STATIC])
 855
 856
 857 AC_ARG_WITH([audit],
 858   AS_HELP_STRING([--with-audit], [compile with audit support]),
 859   [], [with_audit=no]
 860 )
 861
 862 AS_IF([test "x$with_audit" = xno], [
 863   AM_CONDITIONAL([HAVE_AUDIT], [false])
 864 ], [
 865   UL_CHECK_LIB([audit], [audit_log_user_message])
 866   AS_CASE([$with_audit:$have_audit],
 867     [yes:no],
 868       [AC_MSG_ERROR([Audit selected but libaudit not found (or does not support audit_log_user_message())])]
 869   )
 870 ])
 871
 872 AC_ARG_WITH([udev], AS_HELP_STRING([--without-udev], [compile without udev support]),
 873   [], [with_udev=auto]
 874 )
 875
 876 AS_IF([test "x$with_udev" = xno], [
 877   AM_CONDITIONAL([HAVE_UDEV], [false])
 878 ], [
 879   UL_CHECK_LIB([udev], [udev_new])
 880   AS_CASE([$with_udev:$have_udev],
 881     [yes:no],
 882       [AC_MSG_ERROR([udev selected but libudev not found])]
 883   )
 884 ])
 885
 886
 887 dnl wide-char ncurses
 888 AC_ARG_WITH([ncursesw],
 889   AS_HELP_STRING([--without-ncursesw], [do not build with wide-char ncurses]),
 890   [], [with_ncursesw=auto]
 891 )
 892 have_ncursesw=no
 893 have_ncursesw_header=no
 894 AS_IF([test "x$with_ncursesw" != xno], [
 895   UL_NCURSES_CHECK([ncursesw])
 896   AS_IF([test "x$have_ncursesw" = xyes], [
 897     AC_CHECK_HEADERS([ncursesw/ncurses.h], [have_ncursesw_header=yes])
 898     AC_CHECK_HEADERS([ncursesw/term.h])
 899
 900     # Define HAVE_NCURSES_H only if check for HAVE_NCURSESW_NCURSES_H is
 901     # unsuccessful to avoid too many *_H permitations in config.h
 902     AS_IF([test "x$have_ncursesw_header" = xno], [
 903            AC_CHECK_HEADERS([ncurses.h], [have_ncursesw_header=yes])
 904            AC_CHECK_HEADERS([term.h])
 905     ])
 906     AS_IF([test "x$have_ncursesw_header" = xno], [have_ncursesw=no])
 907   ])
 908   AS_IF([test "x$have_ncursesw" = xyes], [
 909     CURSES_LIB_NAME="ncursesw"
 910     AC_DEFINE([HAVE_LIBNCURSESW], [1], [Define if ncursesw library available])
 911   ])
 912 ])
 913 AS_CASE([$with_ncursesw:$have_ncursesw],
 914   [yes:no], [AC_MSG_ERROR([ncursesw selected, but library not found])])
 915
 916
 917 dnl non-wide ncurses
 918 AC_ARG_WITH([ncurses],
 919   AS_HELP_STRING([--with-ncurses], [build with non-wide ncurses]),
 920   [], [with_ncurses=auto]
 921 )
 922 have_ncurses=no
 923 have_ncurses_header=no
 924 AS_CASE([$with_ncurses:$build_widechar],
 925   [yes:yes], [AC_MSG_ERROR([wide-char support enabled, but non-wide ncurses selects])])
 926
 927 AS_IF([test "x$have_ncursesw" = xno -a "x$with_ncurses" != xno ], [
 928   UL_NCURSES_CHECK([ncurses])
 929   AS_IF([test "x$have_ncurses" = xyes], [
 930     AC_CHECK_HEADERS([ncurses/ncurses.h], [have_ncurses_header=yes])
 931     AC_CHECK_HEADERS([ncurses/term.h])
 932
 933     # Define HAVE_NCURSES_H only if check for HAVE_NCURSES_NCURSES_H is
 934     # unsuccessful to avoid too many *_H permitations in config.h
 935     AS_IF([test "x$have_ncurses_header" = xno], [
 936            AC_CHECK_HEADERS([ncurses.h], [have_ncurses_header=yes])
 937            AC_CHECK_HEADERS([term.h])
 938     ])
 939     AS_IF([test "x$have_ncurses_header" = xno], [have_ncurses=no])
 940   ])
 941   AS_IF([test "x$have_ncurses" = xyes], [
 942     CURSES_LIB_NAME="ncurses"
 943     AC_DEFINE([HAVE_LIBNCURSES], [1], [Define if ncurses library available])
 944   ])
 945 ])
 946 AS_CASE([$with_ncurses:$have_ncurses],
 947   [yes:no], [AC_MSG_ERROR([ncurses selected, but library not found])])
 948
 949 AC_SUBST([NCURSES_CFLAGS])
 950 AC_SUBST([NCURSES_LIBS])
 951 AM_CONDITIONAL([HAVE_NCURSES], [test "x$have_ncursesw" = xyes -o  "x$have_ncurses" = xyes])
 952
 953
 954 AC_ARG_WITH([slang],
 955   AS_HELP_STRING([--with-slang], [compile cfdisk with slang rather than ncurses]),
 956   [], [with_slang=no]
 957 )
 958 have_slang=no
 959 AS_IF([test "x$with_slang" = xyes], [
 960   AC_CHECK_HEADERS([slang.h slang/slang.h])
 961   AC_CHECK_HEADERS([slcurses.h slang/slcurses.h],
 962                    [have_slang=yes], [], [
 963 #ifdef HAVE_SLANG_H
 964 #include <slang.h>
 965 #elif defined(HAVE_SLANG_SLANG_H)
 966 #include <slang/slang.h>
 967 #endif
 968 ])
 969   AS_IF([test "x$have_slang" = xno], [
 970     AC_MSG_ERROR([slang selected but slcurses.h not found])],
 971     [CURSES_LIB_NAME=slang
 972   ])
 973 ])
 974 AM_CONDITIONAL([HAVE_SLANG], [test "x$have_slang" = xyes])
 975
 976
 977 AS_IF([test "x$have_slang" = xyes -o "x$have_ncursesw" = xyes -o "x$have_ncurses" = xyes], [
 978         AC_CHECK_LIB([$CURSES_LIB_NAME], use_default_colors, [
 979                      AC_DEFINE(HAVE_USE_DEFAULT_COLORS, 1,
 980                                [Define if curses library has the use_default_colors().])
 981         ])
 982         AC_CHECK_LIB([$CURSES_LIB_NAME], resizeterm, [
 983                      AC_DEFINE(HAVE_RESIZETERM, 1,
 984                                [Define if curses library has the resizeterm().])
 985         ])
 986 ])
 987
 988
 989 AC_ARG_WITH([tinfo], AS_HELP_STRING([--without-tinfo], [compile without libtinfo]),
 990   [], [with_tinfo=auto]
 991 )
 992 have_tinfo=no
 993 have_tinfow=no
 994 AS_IF([test "x$with_tinfo" != xno], [
 995   AS_IF([test "x$have_ncursesw" = xyes], [
 996     UL_TINFO_CHECK([tinfow])
 997   ])
 998   AS_IF([test "x$have_tinfow" = xno], [
 999     UL_TINFO_CHECK([tinfo])
1000   ])
1001 ])
1002 AC_SUBST([TINFO_LIBS])
1003 AC_SUBST([TINFO_LIBS_STATIC])
1004 AC_SUBST([TINFO_CFLAGS])
1005 AM_CONDITIONAL([HAVE_TINFO], [test "x$have_tinfo" = xyes -o "x$have_tinfow" = xyes])
1006 AS_IF([test "x$have_tinfo" = xyes -o "x$have_tinfow" = xyes], [
1007   AC_DEFINE(HAVE_LIBTINFO, 1, [Define if libtinfo or libtinfow available.])
1008 ])
1009
1010
1011 AC_ARG_WITH([readline],
1012   AS_HELP_STRING([--without-readline], [do not build with GNU Readline support]),
1013   [], [with_readline=auto]
1014 )
1015
1016 AS_IF([test "x$with_readline" = xno], [
1017   AM_CONDITIONAL([HAVE_READLINE], [false])
1018 ], [
1019   UL_CHECK_LIB([readline], [readline])
1020   AS_CASE([$with_readline:$have_readline],
1021     [yes:no],
1022       [AC_MSG_ERROR([readline selected but libreadline not found ])],
1023     [*:yes],
1024       [READLINE_LIBS="-lreadline"
1025        READLINE_LIBS_STATIC="-lreadline $TINFO_LIBS_STATIC"]
1026   )
1027 ])
1028 AC_SUBST([READLINE_LIBS])
1029 AC_SUBST([READLINE_LIBS_STATIC])
1030
1031
1032 AC_ARG_WITH([utempter],
1033   AS_HELP_STRING([--with-utempter], [compile script(1) with libutempter]),
1034   [], [with_utempter=no]
1035 )
1036
1037 AS_IF([test "x$with_utempter" = xyes], [
1038   UL_CHECK_LIB([utempter], [utempter_add_record])
1039   AS_IF([test "x$have_utempter" = xno], [
1040     AC_MSG_ERROR([utempter selected but libutempter not found])
1041   ])
1042 ], [
1043   AM_CONDITIONAL([HAVE_UTEMPTER], [false])
1044 ])
1045
1046
1047 dnl
1048 dnl libuuid
1049 dnl
1050 AC_ARG_ENABLE([libuuid],
1051   AS_HELP_STRING([--disable-libuuid], [do not build libuuid and uuid utilities]),
1052   [], [UL_DEFAULT_ENABLE([libuuid], [yes])]
1053 )
1054 UL_BUILD_INIT([libuuid])
1055 AC_SUBST([LIBUUID_VERSION])
1056 AC_SUBST([LIBUUID_VERSION_INFO])
1057 AM_CONDITIONAL(BUILD_LIBUUID, test "x$build_libuuid" = xyes)
1058
1059 AC_ARG_ENABLE([libuuid-force-uuidd],
1060   AS_HELP_STRING([--enable-libuuid-force-uuidd], [support uuidd even though the daemon is not built]),
1061   [], [enable_libuuid_force_uuidd=no]
1062 )
1063
1064 AS_IF([test "x$build_libuuid" = xyes], [
1065   AC_DEFINE(HAVE_LIBUUID, 1, [Define to 1 if you have the -luuid.])
1066 ])
1067
1068 dnl
1069 dnl libblkid
1070 dnl
1071 AC_ARG_ENABLE([libblkid],
1072   AS_HELP_STRING([--disable-libblkid], [do not build libblkid and many related utilities]),
1073   [], [UL_DEFAULT_ENABLE([libblkid], [check])]
1074 )
1075 UL_BUILD_INIT([libblkid])
1076 UL_REQUIRES_HAVE([libblkid], [openat], [openat functions])
1077 UL_REQUIRES_HAVE([libblkid], [dirfd,ddfd], [dirfd or ddfd function])
1078 AC_SUBST([LIBBLKID_DATE])
1079 AC_SUBST([LIBBLKID_VERSION])
1080 AC_SUBST([LIBBLKID_VERSION_INFO])
1081 AC_DEFINE_UNQUOTED([LIBBLKID_VERSION], ["$LIBBLKID_VERSION"], [libblkid version string])
1082 AC_DEFINE_UNQUOTED([LIBBLKID_DATE], ["$LIBBLKID_DATE"], [libblkid date string])
1083 AS_IF([test "x$build_libblkid" = xyes], [
1084   AC_DEFINE([HAVE_LIBBLKID], [1], [Define to 1 if you have the -lblkid.])
1085 ])
1086 AM_CONDITIONAL([BUILD_LIBBLKID], [test "x$build_libblkid" = xyes])
1087 AM_CONDITIONAL([BUILD_LIBBLKID_TESTS], [test "x$build_libblkid" = xyes -a "x$enable_static" = xyes])
1088
1089 dnl
1090 dnl libmount
1091 dnl
1092 AC_ARG_ENABLE([libmount],
1093   AS_HELP_STRING([--disable-libmount], [do not build libmount]),
1094   [], [UL_DEFAULT_ENABLE([libmount], [check])]
1095 )
1096 UL_BUILD_INIT([libmount])
1097 UL_REQUIRES_BUILD([libmount], [libblkid])
1098 UL_REQUIRES_HAVE([libmount], [scanf_alloc_modifier], [scanf string alloc modifier])
1099 UL_REQUIRES_HAVE([libmount], [dirfd,ddfd], [dirfd or ddfd function])
1100 AM_CONDITIONAL([BUILD_LIBMOUNT], [test "x$build_libmount" = xyes])
1101 AM_CONDITIONAL([BUILD_LIBMOUNT_TESTS], [test "x$build_libmount" = xyes -a "x$enable_static" = xyes])
1102 AS_IF([test "x$build_libmount" = xyes], [
1103   AC_DEFINE(HAVE_LIBMOUNT, 1, [Define if libmount available.])
1104   AS_IF([test "x$have_setns_syscall" = "xyes"], [
1105     AC_DEFINE([USE_LIBMOUNT_SUPPORT_NAMESPACES], [1], [Define to 1 if want to support namepaces.])
1106   ],[
1107     AC_MSG_WARN([libmount will be compiled without namespaces support])
1108   ])
1109 ])
1110
1111 AC_SUBST([LIBMOUNT_VERSION])
1112 AC_SUBST([LIBMOUNT_MAJOR_VERSION], $PACKAGE_VERSION_MAJOR)
1113 AC_SUBST([LIBMOUNT_MINOR_VERSION], $PACKAGE_VERSION_MINOR)
1114 AC_SUBST([LIBMOUNT_PATCH_VERSION], $PACKAGE_VERSION_RELEASE)
1115 AC_SUBST([LIBMOUNT_VERSION_INFO])
1116 AC_DEFINE_UNQUOTED([LIBMOUNT_VERSION], ["$LIBMOUNT_VERSION"], [libmount version string])
1117
1118 AC_ARG_ENABLE([libmount-support-mtab],
1119   AS_HELP_STRING([--enable-libmount-support-mtab], [support /etc/mtab (default is use /proc/self/mountinfo)]),
1120   [], [enable_libmount_support_mtab=no]
1121 )
1122
1123 AS_IF([test "x$enable_libmount_support_mtab" = xyes], [
1124   AC_DEFINE([USE_LIBMOUNT_SUPPORT_MTAB], [1], [Define to 1 if want to support mtab.])
1125 ])
1126
1127 dnl
1128 dnl libsmartcols
1129 dnl
1130 AC_ARG_ENABLE([libsmartcols],
1131   AS_HELP_STRING([--disable-libsmartcols], [do not build libsmartcols]),
1132   [], [UL_DEFAULT_ENABLE([libsmartcols], [yes])]
1133 )
1134 UL_BUILD_INIT([libsmartcols])
1135 AM_CONDITIONAL([BUILD_LIBSMARTCOLS], [test "x$build_libsmartcols" = xyes])
1136
1137 AC_SUBST([LIBSMARTCOLS_VERSION])
1138 AC_SUBST([LIBSMARTCOLS_VERSION_INFO])
1139 AC_DEFINE_UNQUOTED([LIBSMARTCOLS_VERSION], ["$LIBSMARTCOLS_VERSION"], [libsmartcols version string])
1140
1141
1142 dnl
1143 dnl libfdisk
1144 dnl
1145 AC_ARG_ENABLE([libfdisk],
1146   AS_HELP_STRING([--disable-libfdisk], [do not build libfdisk]),
1147   [], [UL_DEFAULT_ENABLE([libfdisk], [check])]
1148 )
1149 UL_BUILD_INIT([libfdisk])
1150 UL_REQUIRES_BUILD([libfdisk], [libuuid])
1151 AM_CONDITIONAL([BUILD_LIBFDISK], [test "x$build_libfdisk" = xyes])
1152 AM_CONDITIONAL([BUILD_LIBFDISK_TESTS], [test "x$build_libfdisk" = xyes -a "x$enable_static" = xyes])
1153
1154 AS_IF([test "x$build_libblkid" = xyes],
1155   [LIBFDISK_PC_REQUIRES="uuid blkid"],[LIBFDISK_PC_REQUIRES="uuid"])
1156 AC_SUBST([LIBFDISK_PC_REQUIRES])
1157
1158 AC_SUBST([LIBFDISK_VERSION])
1159 AC_SUBST([LIBFDISK_MAJOR_VERSION], $PACKAGE_VERSION_MAJOR)
1160 AC_SUBST([LIBFDISK_MINOR_VERSION], $PACKAGE_VERSION_MINOR)
1161 AC_SUBST([LIBFDISK_PATCH_VERSION], $PACKAGE_VERSION_RELEASE)
1162 AC_SUBST([LIBFDISK_VERSION_INFO])
1163 AC_DEFINE_UNQUOTED([LIBFDISK_VERSION], ["$LIBFDISK_VERSION"], [libfdisk version string])
1164
1165
1166 AC_ARG_ENABLE([fdisks],
1167   AS_HELP_STRING([--disable-fdisks], [do not build fdisk(8), sfdisk(8) and cfdisk(8)]),
1168   [], [UL_DEFAULT_ENABLE([fdisks], [check])]
1169 )
1170 enable_fdisk=$enable_fdisks
1171 enable_sfdisk=$enable_fdisks
1172 enable_cfdisk=$enable_fdisks
1173
1174 UL_BUILD_INIT([fdisk])
1175 UL_REQUIRES_HAVE([fdisk], [openat], [openat functions])
1176 UL_REQUIRES_HAVE([fdisk], [dirfd,ddfd], [dirfd or ddfd function])
1177 UL_REQUIRES_BUILD([fdisk], [libfdisk])
1178 UL_REQUIRES_BUILD([fdisk], [libsmartcols])
1179 AM_CONDITIONAL([BUILD_FDISK], [test "x$build_fdisk" = xyes])
1180
1181
1182 UL_BUILD_INIT([sfdisk])
1183 UL_REQUIRES_HAVE([sfdisk], [openat], [openat functions])
1184 UL_REQUIRES_HAVE([sfdisk], [dirfd,ddfd], [dirfd or ddfd function])
1185 UL_REQUIRES_BUILD([sfdisk], [libfdisk])
1186 UL_REQUIRES_BUILD([sfdisk], [libsmartcols])
1187 AM_CONDITIONAL([BUILD_SFDISK], [test "x$build_sfdisk" = xyes])
1188
1189
1190 UL_BUILD_INIT([cfdisk])
1191 UL_REQUIRES_BUILD([cfdisk], [libfdisk])
1192 UL_REQUIRES_BUILD([cfdisk], [libsmartcols])
1193 UL_REQUIRES_HAVE([cfdisk], [open_memstream], [open_memstream function])
1194 UL_REQUIRES_HAVE([cfdisk], [ncursesw,slang,ncurses], [ncursesw, ncurses or slang library])
1195 AM_CONDITIONAL([BUILD_CFDISK], [test "x$build_cfdisk" = xyes])
1196
1197
1198 AC_ARG_ENABLE([mount],
1199   AS_HELP_STRING([--disable-mount], [do not build mount(8) and umount(8)]),
1200   [], [UL_DEFAULT_ENABLE([mount], [check])]
1201 )
1202 UL_BUILD_INIT([mount])
1203 UL_REQUIRES_LINUX([mount])
1204 UL_REQUIRES_BUILD([mount], [libmount])
1205 AM_CONDITIONAL([BUILD_MOUNT], [test "x$build_mount" = xyes])
1206
1207
1208 AC_ARG_ENABLE([losetup],
1209   AS_HELP_STRING([--disable-losetup], [do not build losetup]),
1210   [], [UL_DEFAULT_ENABLE([losetup], [check])]
1211 )
1212 UL_BUILD_INIT([losetup])
1213 UL_REQUIRES_LINUX([losetup])
1214 UL_REQUIRES_BUILD([losetup], [libsmartcols])
1215 AM_CONDITIONAL([BUILD_LOSETUP], [test "x$build_losetup" = xyes])
1216
1217 AC_ARG_ENABLE([zramctl],
1218   AS_HELP_STRING([--disable-zramctl], [do not build zramctl]),
1219   [], [UL_DEFAULT_ENABLE([zramctl], [check])]
1220 )
1221 UL_BUILD_INIT([zramctl])
1222 UL_REQUIRES_LINUX([zramctl])
1223 UL_REQUIRES_BUILD([zramctl], [libsmartcols])
1224 AM_CONDITIONAL([BUILD_ZRAMCTL], [test "x$build_zramctl" = xyes])
1225
1226 AC_ARG_ENABLE([fsck],
1227   AS_HELP_STRING([--disable-fsck], [do not build fsck]),
1228   [], [UL_DEFAULT_ENABLE([fsck], [check])]
1229 )
1230 UL_BUILD_INIT([fsck])
1231 UL_REQUIRES_BUILD([fsck], [libmount])
1232 AM_CONDITIONAL([BUILD_FSCK], [test "x$build_fsck" = xyes])
1233
1234
1235 AC_ARG_ENABLE([partx],
1236   AS_HELP_STRING([--disable-partx], [do not build addpart, delpart, partx]),
1237   [], [UL_DEFAULT_ENABLE([partx], [check])]
1238 )
1239 UL_BUILD_INIT([partx])
1240 UL_REQUIRES_LINUX([partx])
1241 UL_REQUIRES_BUILD([partx], [libblkid])
1242 UL_REQUIRES_BUILD([partx], [libsmartcols])
1243 AM_CONDITIONAL([BUILD_PARTX], [test "x$build_partx" = xyes])
1244
1245
1246 AC_ARG_ENABLE([uuidd],
1247   AS_HELP_STRING([--disable-uuidd], [do not build the uuid daemon]),
1248   [], [UL_DEFAULT_ENABLE([uuidd], [check])]
1249 )
1250 UL_BUILD_INIT([uuidd])
1251 UL_REQUIRES_BUILD([uuidd], [libuuid])
1252 UL_REQUIRES_HAVE([uuidd], [timer], [timer_create function])
1253 UL_REQUIRES_HAVE([uuidd], [sys_signalfd_h], [sys/signalfd.h header])
1254 AS_IF([test "x$build_uuidd" = xyes || test "x$enable_libuuid_force_uuidd" = xyes], [
1255   AC_DEFINE([HAVE_UUIDD], [1], [Define to 1 if you want to use uuid daemon.])
1256 ])
1257 AM_CONDITIONAL([BUILD_UUIDD], [test "x$build_uuidd" = xyes])
1258
1259
1260 UL_BUILD_INIT([uuidgen], [check])
1261 UL_REQUIRES_BUILD([uuidgen], [libuuid])
1262 AM_CONDITIONAL([BUILD_UUIDGEN], [test "x$build_uuidgen" = xyes])
1263
1264 UL_BUILD_INIT([uuidparse], [check])
1265 UL_REQUIRES_BUILD([uuidparse], [libuuid])
1266 UL_REQUIRES_BUILD([uuidparse], [libsmartcols])
1267 AM_CONDITIONAL([BUILD_UUIDPARSE], [test "x$build_uuidparse" = xyes])
1268
1269 UL_BUILD_INIT([blkid], [check])
1270 UL_REQUIRES_BUILD([blkid], [libblkid])
1271 AM_CONDITIONAL([BUILD_BLKID], [test "x$build_blkid" = xyes])
1272
1273 UL_BUILD_INIT([findfs], [check])
1274 UL_REQUIRES_BUILD([findfs], [libblkid])
1275 AM_CONDITIONAL([BUILD_FINDFS], [test "x$build_findfs" = xyes])
1276
1277 UL_BUILD_INIT([wipefs], [check])
1278 UL_REQUIRES_BUILD([wipefs], [libblkid])
1279 UL_REQUIRES_BUILD([wipefs], [libsmartcols])
1280 AM_CONDITIONAL([BUILD_WIPEFS], [test "x$build_wipefs" = xyes])
1281
1282 UL_BUILD_INIT([findmnt], [check])
1283 UL_REQUIRES_BUILD([findmnt], [libmount])
1284 UL_REQUIRES_BUILD([findmnt], [libblkid])
1285 UL_REQUIRES_BUILD([findmnt], [libsmartcols])
1286 AM_CONDITIONAL([BUILD_FINDMNT], [test "x$build_findmnt" = xyes])
1287
1288
1289 AC_ARG_ENABLE([mountpoint],
1290   AS_HELP_STRING([--disable-mountpoint], [do not build mountpoint]),
1291   [], [UL_DEFAULT_ENABLE([mountpoint], [check])]
1292 )
1293 UL_BUILD_INIT([mountpoint])
1294 UL_REQUIRES_BUILD([mountpoint], [libmount])
1295 AM_CONDITIONAL([BUILD_MOUNTPOINT], [test "x$build_mountpoint" = xyes])
1296
1297
1298 AC_ARG_ENABLE([fallocate],
1299   AS_HELP_STRING([--disable-fallocate], [do not build fallocate]),
1300   [], [UL_DEFAULT_ENABLE([fallocate], [check])]
1301 )
1302 UL_BUILD_INIT([fallocate])
1303 UL_REQUIRES_LINUX([fallocate])
1304 UL_REQUIRES_SYSCALL_CHECK([fallocate], [UL_CHECK_SYSCALL([fallocate])])
1305 AM_CONDITIONAL([BUILD_FALLOCATE], [test "x$build_fallocate" = xyes])
1306
1307 AS_IF([test "x$build_fallocate" = xyes], [
1308   dnl check for valid fallocate() function
1309   dnl with 32 bits glibc 2.10, fallocate() exists but not fallocate64()
1310   dnl when _FILE_OFFSET_BITS==64, fallocate() is redirect to fallocate64()
1311   dnl and program can't be linked.
1312   dnl AC_CHECK_FUNC can't catch such errors since it's redefining
1313   dnl function prototype.
1314   AC_MSG_CHECKING([for valid fallocate() function])
1315   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1316 #ifdef HAVE_UNISTD_H
1317 # include <unistd.h>
1318 #endif
1319 #ifdef HAVE_SYS_TYPES_H
1320 # include <sys/types.h>
1321 #endif
1322 #ifdef HAVE_LINUX_FALLOC_H
1323 # include <linux/falloc.h>
1324 #endif
1325 #ifdef HAVE_FCNTL_H
1326 # include <fcntl.h>
1327 #endif
1328 ]],[[
1329    long ret;
1330    ret = fallocate(0, FALLOC_FL_KEEP_SIZE, 0xfffffffful, 0xfffffffful);
1331    if (ret != 0) {
1332       return 1;
1333    }
1334    ]])],[
1335   AC_MSG_RESULT([yes])
1336   AC_DEFINE([HAVE_FALLOCATE], [1], [Have valid fallocate() function])],[
1337   AC_MSG_RESULT([no])])
1338 ])
1339
1340 AS_IF([test "x$build_fallocate" = xyes], [
1341   dnl check for valid posix_fallocate() function
1342   AC_MSG_CHECKING([for valid posix_fallocate() function])
1343   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1344 #ifdef HAVE_UNISTD_H
1345 # include <unistd.h>
1346 #endif
1347 #ifdef HAVE_SYS_TYPES_H
1348 # include <sys/types.h>
1349 #endif
1350 #ifdef HAVE_LINUX_FALLOC_H
1351 # include <linux/falloc.h>
1352 #endif
1353 #ifdef HAVE_FCNTL_H
1354 # include <fcntl.h>
1355 #endif
1356 ]],[[
1357    long ret;
1358    ret = posix_fallocate(0, 0xfffffffful, 0xfffffffful);
1359    if (ret != 0) {
1360       return 1;
1361    }
1362    ]])],[
1363   AC_MSG_RESULT([yes])
1364   AC_DEFINE([HAVE_POSIX_FALLOCATE], [1], [Have valid posix_fallocate() function])],[
1365   AC_MSG_RESULT([no])])
1366 ])
1367
1368
1369 AC_ARG_ENABLE([unshare],
1370   AS_HELP_STRING([--disable-unshare], [do not build unshare]),
1371   [], [UL_DEFAULT_ENABLE([unshare], [check])]
1372 )
1373 UL_BUILD_INIT([unshare])
1374 UL_REQUIRES_LINUX([unshare])
1375 UL_REQUIRES_SYSCALL_CHECK([unshare], [UL_CHECK_SYSCALL([unshare])])
1376 AM_CONDITIONAL([BUILD_UNSHARE], [test "x$build_unshare" = xyes])
1377 AC_CHECK_FUNCS([unshare])
1378
1379 AC_ARG_ENABLE([nsenter],
1380   AS_HELP_STRING([--disable-nsenter], [do not build nsenter]),
1381   [], [UL_DEFAULT_ENABLE([nsenter], [check])]
1382 )
1383 UL_BUILD_INIT([nsenter])
1384 UL_REQUIRES_LINUX([nsenter])
1385 UL_REQUIRES_HAVE([nsenter], [setns_syscall], [setns syscall])
1386 AM_CONDITIONAL([BUILD_NSENTER], [test "x$build_nsenter" = xyes])
1387 AC_CHECK_FUNCS([setns])
1388
1389
1390 AC_ARG_WITH([cap_ng],
1391   AS_HELP_STRING([--without-cap-ng], [compile without libcap-ng]),
1392   [], [with_cap_ng=auto]
1393 )
1394 AS_IF([test "x$with_cap_ng" = xno], [
1395   AM_CONDITIONAL([HAVE_CAP_NG], [false])
1396   have_cap_ng=no
1397 ],[
1398   UL_CHECK_LIB([cap-ng], [capng_apply], [cap_ng])
1399 ])
1400
1401
1402 AC_ARG_ENABLE([setpriv],
1403   AS_HELP_STRING([--disable-setpriv], [do not build setpriv]),
1404   [], [UL_DEFAULT_ENABLE([setpriv], [check])]
1405 )
1406 UL_BUILD_INIT([setpriv])
1407 UL_REQUIRES_LINUX([setpriv])
1408 UL_REQUIRES_HAVE([setpriv], [linux_securebits_h], [securebits.h header file])
1409 UL_REQUIRES_HAVE([setpriv], [cap_ng], [libcap-ng library])
1410 AM_CONDITIONAL([BUILD_SETPRIV], [test "x$build_setpriv" = xyes])
1411
1412 PKG_CHECK_MODULES([PCRE], [libpcre2-8], [have_pcre=yes], [have_pcre=no])
1413 AS_IF([test "x$have_pcre" = xyes ], [
1414     AC_DEFINE([HAVE_PCRE], [1], [Define if libpcre2 is available])
1415 ])
1416 AM_CONDITIONAL([HAVE_PCRE], [test "x$have_pcre" = xyes])
1417
1418 AC_ARG_ENABLE([hardlink],
1419   AS_HELP_STRING([--disable-hardlink], [do not build hardlink]),
1420   [], [UL_DEFAULT_ENABLE([hardlink], [check])]
1421 )
1422 UL_BUILD_INIT([hardlink])
1423 AM_CONDITIONAL([BUILD_HARDLINK], [test "x$build_hardlink" = xyes])
1424
1425 AC_ARG_ENABLE([eject],
1426   AS_HELP_STRING([--disable-eject], [do not build eject]),
1427   [], [UL_DEFAULT_ENABLE([eject], [check])]
1428 )
1429 UL_BUILD_INIT([eject])
1430 UL_REQUIRES_LINUX([eject])
1431 UL_REQUIRES_BUILD([eject], [libmount])
1432 AM_CONDITIONAL([BUILD_EJECT], [test "x$build_eject" = xyes])
1433
1434
1435 AC_ARG_ENABLE([agetty],
1436   AS_HELP_STRING([--disable-agetty], [do not build agetty]),
1437   [], [UL_DEFAULT_ENABLE([agetty], [check])]
1438 )
1439 UL_BUILD_INIT([agetty])
1440 UL_REQUIRES_HAVE([agetty], [utmpx_h], [utmpx.h header])
1441 UL_REQUIRES_HAVE([agetty], [gnu_utmpx], [GNU utmpx functions])
1442 AM_CONDITIONAL([BUILD_AGETTY], [test "x$build_agetty" = xyes])
1443 AS_IF([test "x$have_futimens" = xyes -a "x$have_inotify_init1" = xyes ], [
1444   AC_DEFINE([AGETTY_RELOAD], [1], [Enable agetty --reload feature])
1445 ],[
1446   AC_MSG_WARN([futimens or inotify_init1 not found; agetty(8) will not provide ---reload functionality])
1447 ])
1448
1449
1450 AC_ARG_ENABLE([plymouth_support],
1451   AS_HELP_STRING([--disable-plymouth_support], [do not care about plymouth in sylogin(8) and agetty(8)]),
1452   [], [enable_plymouth_support=check]
1453 )
1454 UL_BUILD_INIT([plymouth_support])
1455 UL_REQUIRES_HAVE([plymouth_support], [tiocglcktrmios], [TIOCGLCKTRMIOS flag])
1456 UL_REQUIRES_HAVE([plymouth_support], [sock_cloexec], [SOCK_CLOEXEC flag])
1457 UL_REQUIRES_HAVE([plymouth_support], [sock_nonblock], [SOCK_NONBLOCK flag])
1458 UL_REQUIRES_HAVE([plymouth_support], [so_passcred], [SO_PASSCRED flag])
1459 AM_CONDITIONAL([USE_PLYMOUTH_SUPPORT], [test "x$build_plymouth_support" = xyes])
1460 AS_IF([test "x$build_plymouth_support" = xyes ], [
1461     AC_DEFINE([USE_PLYMOUTH_SUPPORT], [1], [Enable plymouth support feature for sulogin and aggety])
1462 ])
1463
1464
1465 AC_ARG_WITH([libz],
1466   AS_HELP_STRING([--without-libz], [compile without libz]),
1467   [], [with_libz=auto]
1468 )
1469 AS_IF([test "x$with_libz" = xno], [have_z=no], [
1470   AC_CHECK_LIB([z], [crc32], [have_z=yes], [have_z=no])
1471 ])
1472
1473
1474 AC_ARG_ENABLE([cramfs],
1475   AS_HELP_STRING([--disable-cramfs], [do not build fsck.cramfs, mkfs.cramfs]),
1476   [], [UL_DEFAULT_ENABLE([cramfs], [check])]
1477 )
1478 UL_BUILD_INIT([cramfs])
1479 UL_REQUIRES_HAVE([cramfs], [z], [z library])
1480 AM_CONDITIONAL([BUILD_CRAMFS], [test "x$build_cramfs" = xyes])
1481
1482
1483 AC_ARG_ENABLE([bfs],
1484   AS_HELP_STRING([--disable-bfs], [do not build mkfs.bfs]),
1485   [], [UL_DEFAULT_ENABLE([bfs], [yes])]
1486 )
1487 UL_BUILD_INIT([bfs])
1488 AM_CONDITIONAL([BUILD_BFS], [test "x$build_bfs" = xyes])
1489
1490
1491 AC_ARG_ENABLE([minix],
1492   AS_HELP_STRING([--disable-minix], [do not build fsck.minix, mkfs.minix]),
1493   [], [UL_DEFAULT_ENABLE([minix], [yes])]
1494 )
1495 UL_BUILD_INIT([minix])
1496 AM_CONDITIONAL([BUILD_MINIX], [test "x$build_minix" = xyes])
1497
1498
1499 AC_ARG_ENABLE([fdformat],
1500   AS_HELP_STRING([--disable-fdformat], [do not build fdformat]),
1501   [], [UL_DEFAULT_ENABLE([fdformat], [check])]
1502 )
1503 UL_BUILD_INIT([fdformat])
1504 UL_REQUIRES_LINUX([fdformat])
1505 AM_CONDITIONAL([BUILD_FDFORMAT], [test "x$build_fdformat" = xyes])
1506
1507
1508 AC_ARG_ENABLE([hwclock],
1509   AS_HELP_STRING([--disable-hwclock], [do not build hwclock]),
1510   [], [UL_DEFAULT_ENABLE([hwclock], [check])]
1511 )
1512 have_linuxdummy=$linux_os
1513
1514 UL_BUILD_INIT([hwclock])
1515 UL_REQUIRES_HAVE([hwclock], [io, linuxdummy], [ioperm iopl function or Linux])
1516 AM_CONDITIONAL([BUILD_HWCLOCK], [test "x$build_hwclock" = xyes])
1517
1518
1519 UL_BUILD_INIT([mkfs], [yes])
1520 AM_CONDITIONAL([BUILD_MKFS], [test "x$build_mkfs" = xyes])
1521
1522 UL_BUILD_INIT([isosize], [yes])
1523 AM_CONDITIONAL([BUILD_ISOSIZE], [test "x$build_isosize" = xyes])
1524
1525
1526 UL_BUILD_INIT([fstrim], [check])
1527 UL_REQUIRES_LINUX([fstrim])
1528 UL_REQUIRES_BUILD([fstrim], [libmount])
1529 AM_CONDITIONAL([BUILD_FSTRIM], [test "x$build_fstrim" = xyes])
1530
1531
1532 UL_BUILD_INIT([swapon], [check])
1533 UL_REQUIRES_LINUX([swapon])
1534 UL_REQUIRES_SYSCALL_CHECK([swapon], [UL_CHECK_SYSCALL([swapon])], [swapon])
1535 UL_REQUIRES_SYSCALL_CHECK([swapon], [UL_CHECK_SYSCALL([swapoff])], [swapoff])
1536 UL_REQUIRES_BUILD([swapon], [libblkid])
1537 UL_REQUIRES_BUILD([swapon], [libmount])
1538 UL_REQUIRES_BUILD([swapon], [libsmartcols])
1539 AM_CONDITIONAL([BUILD_SWAPON], [test "x$build_swapon" = xyes])
1540 AC_CHECK_FUNCS([swapon])
1541 AC_CHECK_FUNCS([swapoff])
1542
1543
1544 UL_BUILD_INIT([lsblk], [check])
1545 UL_REQUIRES_LINUX([lsblk])
1546 UL_REQUIRES_BUILD([lsblk], [libblkid])
1547 UL_REQUIRES_BUILD([lsblk], [libmount])
1548 UL_REQUIRES_BUILD([lsblk], [libsmartcols])
1549 AM_CONDITIONAL([BUILD_LSBLK], [test "x$build_lsblk" = xyes])
1550
1551
1552 UL_BUILD_INIT([lscpu], [check])
1553 UL_REQUIRES_LINUX([lscpu])
1554 UL_REQUIRES_BUILD([lscpu], [libsmartcols])
1555 UL_REQUIRES_HAVE([lscpu], [cpu_set_t], [cpu_set_t type])
1556 AM_CONDITIONAL([BUILD_LSCPU], [test "x$build_lscpu" = xyes])
1557
1558
1559 AC_ARG_ENABLE([lslogins],
1560   AS_HELP_STRING([--disable-lslogins], [do not build lslogins]),
1561   [], [UL_DEFAULT_ENABLE([lslogins], [check])]
1562 )
1563 UL_BUILD_INIT([lslogins])
1564 UL_REQUIRES_BUILD([lslogins], [libsmartcols])
1565 UL_REQUIRES_HAVE([lslogins], [shadow_h], [shadow.h header])
1566 UL_REQUIRES_HAVE([lslogins], [utmpx_h], [utmpx.h header])
1567 UL_REQUIRES_HAVE([lslogins], [gnu_utmpx], [GNU utmpx functions])
1568 AM_CONDITIONAL([BUILD_LSLOGINS], [test "x$build_lslogins" = xyes])
1569
1570
1571 UL_BUILD_INIT([chcpu], [check])
1572 UL_REQUIRES_LINUX([chcpu])
1573 UL_REQUIRES_HAVE([chcpu], [cpu_set_t], [cpu_set_t type])
1574 AM_CONDITIONAL([BUILD_CHCPU], [test "x$build_chcpu" = xyes])
1575
1576
1577 AC_ARG_ENABLE([wdctl],
1578   AS_HELP_STRING([--disable-wdctl], [do not build wdctl]),
1579   [], [UL_DEFAULT_ENABLE([wdctl], [check])]
1580 )
1581 UL_BUILD_INIT([wdctl])
1582 UL_REQUIRES_LINUX([wdctl])
1583 UL_REQUIRES_BUILD([wdctl], [libsmartcols])
1584 UL_REQUIRES_HAVE([wdctl], [linux_watchdog_h], [linux/watchdog.h header file])
1585 AM_CONDITIONAL([BUILD_WDCTL], [test "x$build_wdctl" = xyes])
1586
1587
1588 UL_BUILD_INIT([swaplabel], [check])
1589 UL_REQUIRES_BUILD([swaplabel], [libblkid])
1590 AM_CONDITIONAL([BUILD_SWAPLABEL], [test "x$build_swaplabel" = xyes])
1591
1592
1593 UL_BUILD_INIT([mkswap], [yes])
1594 AM_CONDITIONAL([BUILD_MKSWAP], [test "x$build_mkswap" = xyes])
1595 AS_IF([test "x$build_mkswap" = xyes -a "x$build_libuuid" != xyes], [
1596   AC_MSG_WARN([uuid library is not found; mkswap(8) will not generate UUIDs])
1597 ])
1598
1599
1600 AC_ARG_ENABLE([cal],
1601   AS_HELP_STRING([--disable-cal], [do not build cal]),
1602   [], [UL_DEFAULT_ENABLE([cal], [check])]
1603 )
1604 UL_BUILD_INIT([cal])
1605 AM_CONDITIONAL([BUILD_CAL], [test "x$build_cal" = xyes])
1606
1607 AC_ARG_ENABLE([logger],
1608   AS_HELP_STRING([--disable-logger], [do not build logger]),
1609   [], [UL_DEFAULT_ENABLE([logger], [check])]
1610 )
1611 UL_BUILD_INIT([logger])
1612 AM_CONDITIONAL([BUILD_LOGGER], [test "x$build_logger" = xyes])
1613
1614 UL_BUILD_INIT([look], [yes])
1615 AM_CONDITIONAL([BUILD_LOOK], [test "x$build_look" = xyes])
1616
1617 UL_BUILD_INIT([mcookie], [yes])
1618 AM_CONDITIONAL([BUILD_MCOOKIE], [test "x$build_mcookie" = xyes])
1619
1620 UL_BUILD_INIT([namei], [yes])
1621 AM_CONDITIONAL([BUILD_NAMEI], [test "x$build_namei" = xyes])
1622
1623 matriplet="$($CC -print-multiarch 2>/dev/null || true)"
1624 if test "x$matriplet" != "x"; then
1625   AC_DEFINE_UNQUOTED([MULTIARCHTRIPLET], ["$matriplet"],
1626   ["Multi-arch triplet for whereis library search path"])
1627 fi
1628 UL_BUILD_INIT([whereis], [yes])
1629 AM_CONDITIONAL([BUILD_WHEREIS], [test "x$build_whereis" = xyes])
1630
1631 UL_BUILD_INIT([getopt], [yes])
1632 AM_CONDITIONAL([BUILD_GETOPT], [test "x$build_getopt" = xyes])
1633
1634
1635 UL_BUILD_INIT([blockdev], [check])
1636 UL_REQUIRES_LINUX([blockdev])
1637 AM_CONDITIONAL([BUILD_BLOCKDEV], [test "x$build_blockdev" = xyes])
1638
1639
1640 UL_BUILD_INIT([prlimit], [check])
1641 UL_REQUIRES_LINUX([prlimit])
1642 UL_REQUIRES_BUILD([prlimit], [libsmartcols])
1643 UL_REQUIRES_SYSCALL_CHECK([prlimit], [UL_CHECK_SYSCALL([prlimit64])], [prlimit64])
1644 AM_CONDITIONAL([BUILD_PRLIMIT], [test "x$build_prlimit" = xyes])
1645 AS_IF([test "x$build_prlimit" = xyes], [
1646   AC_CHECK_FUNCS([prlimit])
1647 ])
1648
1649
1650 UL_BUILD_INIT([lslocks], [check])
1651 UL_REQUIRES_LINUX([lslocks])
1652 UL_REQUIRES_BUILD([lslocks], [libmount])
1653 UL_REQUIRES_BUILD([lslocks], [libsmartcols])
1654 AM_CONDITIONAL([BUILD_LSLOCKS], [test "x$build_lslocks" = xyes])
1655
1656
1657 AC_ARG_ENABLE([switch_root],
1658   AS_HELP_STRING([--disable-switch_root], [do not build switch_root]),
1659   [], [UL_DEFAULT_ENABLE([switch_root], [check])]
1660 )
1661 UL_BUILD_INIT([switch_root])
1662 UL_REQUIRES_LINUX([switch_root])
1663 UL_REQUIRES_HAVE([switch_root], [openat], [openat function])
1664 UL_REQUIRES_HAVE([switch_root], [dirfd,ddfd], [dirfd or ddfd function])
1665 AM_CONDITIONAL([BUILD_SWITCH_ROOT], [test "x$build_switch_root" = xyes])
1666
1667
1668 AC_ARG_ENABLE([pivot_root],
1669   AS_HELP_STRING([--disable-pivot_root], [do not build pivot_root]),
1670   [], [UL_DEFAULT_ENABLE([pivot_root], [check])]
1671 )
1672 UL_BUILD_INIT([pivot_root])
1673 UL_REQUIRES_LINUX([pivot_root])
1674 UL_REQUIRES_SYSCALL_CHECK([pivot_root], [UL_CHECK_SYSCALL([pivot_root])])
1675 AM_CONDITIONAL([BUILD_PIVOT_ROOT], [test "x$build_pivot_root" = xyes])
1676
1677
1678 UL_BUILD_INIT([flock], [check])
1679 UL_REQUIRES_HAVE([flock], [timer], [timer_create/setitimer function])
1680 AM_CONDITIONAL([BUILD_FLOCK], [test "x$build_flock" = xyes])
1681
1682
1683 AC_ARG_ENABLE([lsmem],
1684   AS_HELP_STRING([--disable-lsmem], [do not build lsmem]),
1685   [], [UL_DEFAULT_ENABLE([lsmem], [check])]
1686 )
1687 UL_BUILD_INIT([lsmem])
1688 UL_REQUIRES_LINUX([lsmem])
1689 UL_REQUIRES_BUILD([lsmem], [libsmartcols])
1690 AM_CONDITIONAL([BUILD_LSMEM], [test "x$build_lsmem" = xyes])
1691
1692
1693 AC_ARG_ENABLE([chmem],
1694   AS_HELP_STRING([--disable-chmem], [do not build chmem]),
1695   [], [UL_DEFAULT_ENABLE([chmem], [check])]
1696 )
1697 UL_BUILD_INIT([chmem])
1698 UL_REQUIRES_LINUX([chmem])
1699 AM_CONDITIONAL([BUILD_CHMEM], [test "x$build_chmem" = xyes])
1700
1701 UL_BUILD_INIT([ipcmk], [yes])
1702 AM_CONDITIONAL([BUILD_IPCMK], [test "x$build_ipcmk" = xyes])
1703
1704
1705 AC_ARG_ENABLE([ipcrm],
1706   AS_HELP_STRING([--disable-ipcrm], [do not build ipcrm]),
1707   [], [UL_DEFAULT_ENABLE([ipcrm], [yes])]
1708 )
1709 UL_BUILD_INIT([ipcrm])
1710 AM_CONDITIONAL([BUILD_IPCRM], [test "x$build_ipcrm" = xyes])
1711
1712 AC_ARG_ENABLE([ipcs],
1713   AS_HELP_STRING([--disable-ipcs], [do not build ipcs]),
1714   [], [UL_DEFAULT_ENABLE([ipcs], [yes])]
1715 )
1716 UL_BUILD_INIT([ipcs])
1717 AM_CONDITIONAL([BUILD_IPCS], [test "x$build_ipcs" = xyes])
1718
1719 UL_BUILD_INIT([choom], [check])
1720 UL_REQUIRES_LINUX([choom])
1721 AM_CONDITIONAL([BUILD_CHOOM], [test "x$build_choom" = xyes])
1722
1723 UL_BUILD_INIT([lsipc], [check])
1724 UL_REQUIRES_LINUX([lsipc])
1725 UL_REQUIRES_BUILD([lsipc], [libsmartcols])
1726 AM_CONDITIONAL([BUILD_LSIPC], [test "x$build_lsipc" = xyes])
1727
1728 UL_BUILD_INIT([lsns], [check])
1729 UL_REQUIRES_LINUX([lsns])
1730 UL_REQUIRES_BUILD([lsns], [libsmartcols])
1731 UL_REQUIRES_BUILD([lsns], [libmount])
1732 AM_CONDITIONAL([BUILD_LSNS], [test "x$build_lsns" = xyes])
1733
1734 UL_BUILD_INIT([renice], [yes])
1735 AM_CONDITIONAL([BUILD_RENICE], [test "x$build_renice" = xyes])
1736
1737
1738 AC_ARG_ENABLE([rfkill],
1739   AS_HELP_STRING([--disable-rfkill], [do not build rfkill]),
1740   [], [UL_DEFAULT_ENABLE([rfkill], [check])]
1741 )
1742 UL_BUILD_INIT([rfkill])
1743 UL_REQUIRES_LINUX([rfkill])
1744 UL_REQUIRES_BUILD([rfkill], [libsmartcols])
1745 AM_CONDITIONAL([BUILD_RFKILL], [test "x$build_rfkill" = xyes])
1746
1747
1748 UL_BUILD_INIT([setsid], [yes])
1749 AM_CONDITIONAL([BUILD_SETSID], [test "x$build_setsid" = xyes])
1750
1751 UL_BUILD_INIT([readprofile], [check])
1752 UL_REQUIRES_LINUX([readprofile])
1753 AM_CONDITIONAL([BUILD_READPROFILE], [test "x$build_readprofile" = xyes])
1754
1755 UL_BUILD_INIT([dmesg], [check])
1756 UL_REQUIRES_LINUX([dmesg])
1757 AM_CONDITIONAL([BUILD_DMESG], [test "x$build_dmesg" = xyes])
1758
1759 UL_BUILD_INIT([ctrlaltdel], [check])
1760 UL_REQUIRES_LINUX([ctrlaltdel])
1761 dnl we assume reboot() to be the 1-argument variant, because even considering
1762 dnl widely used alternative C libraries like uclibc, dietlibc and musl,
1763 dnl reboot() with multiple arguments is yet only found in glibc versions
1764 dnl earlier than 2.x.
1765 UL_REQUIRES_HAVE([ctrlaltdel], [reboot], [reboot function])
1766 AM_CONDITIONAL([BUILD_CTRLALTDEL], [test "x$build_ctrlaltdel" = xyes])
1767
1768 UL_BUILD_INIT([fincore], [check])
1769 UL_REQUIRES_LINUX([fincore])
1770 UL_REQUIRES_BUILD([fincore], [libsmartcols])
1771 AM_CONDITIONAL([BUILD_FINCORE], [test "x$build_fincore" = xyes])
1772
1773 UL_BUILD_INIT([fsfreeze], [check])
1774 UL_REQUIRES_LINUX([fsfreeze])
1775 AM_CONDITIONAL([BUILD_FSFREEZE], [test "x$build_fsfreeze" = xyes])
1776
1777 UL_BUILD_INIT([blkdiscard], [check])
1778 UL_REQUIRES_LINUX([blkdiscard])
1779 AM_CONDITIONAL([BUILD_BLKDISCARD], [test "x$build_blkdiscard" = xyes])
1780
1781 UL_BUILD_INIT([blkzone], [check])
1782 UL_REQUIRES_LINUX([blkzone])
1783 UL_REQUIRES_HAVE([blkzone], [linux_blkzoned_h], [linux/blkzoned.h header])
1784 AM_CONDITIONAL([BUILD_BLKZONE], [test "x$build_blkzone" = xyes])
1785
1786 UL_BUILD_INIT([ldattach], [check])
1787 UL_REQUIRES_LINUX([ldattach])
1788 AM_CONDITIONAL([BUILD_LDATTACH], [test "x$build_ldattach" = xyes])
1789
1790 UL_BUILD_INIT([rtcwake], [check])
1791 UL_REQUIRES_LINUX([rtcwake])
1792 AM_CONDITIONAL([BUILD_RTCWAKE], [test "x$build_rtcwake" = xyes])
1793
1794 UL_BUILD_INIT([setarch], [check])
1795 UL_REQUIRES_LINUX([setarch])
1796 AM_CONDITIONAL([BUILD_SETARCH], [test "x$build_setarch" = xyes])
1797
1798 UL_BUILD_INIT([script], [check])
1799 UL_REQUIRES_HAVE([script], [sys_signalfd_h], [sys/signalfd.h header])
1800 AM_CONDITIONAL([BUILD_SCRIPT], [test "x$build_script" = xyes])
1801
1802 UL_BUILD_INIT([scriptreplay], [yes])
1803 AM_CONDITIONAL([BUILD_SCRIPTREPLAY], [test "x$build_scriptreplay" = xyes])
1804
1805 UL_BUILD_INIT([col], [yes])
1806 AM_CONDITIONAL([BUILD_COL], [test "x$build_col" = xyes])
1807
1808 UL_BUILD_INIT([colcrt], [yes])
1809 AM_CONDITIONAL([BUILD_COLCRT], [test "x$build_colcrt" = xyes])
1810
1811 UL_BUILD_INIT([colrm], [yes])
1812 AM_CONDITIONAL([BUILD_COLRM], [test "x$build_colrm" = xyes])
1813
1814 UL_BUILD_INIT([column], [check])
1815 UL_REQUIRES_BUILD([column], [libsmartcols])
1816 AM_CONDITIONAL([BUILD_COLUMN], [test "x$build_column" = xyes])
1817
1818 UL_BUILD_INIT([hexdump], [yes])
1819 AM_CONDITIONAL([BUILD_HEXDUMP], [test "x$build_hexdump" = xyes])
1820
1821 UL_BUILD_INIT([rev], [yes])
1822 AM_CONDITIONAL([BUILD_REV], [test "x$build_rev" = xyes])
1823
1824
1825 AC_ARG_ENABLE([tunelp],
1826   AS_HELP_STRING([--enable-tunelp], [build tunelp]),
1827   [], [UL_DEFAULT_ENABLE([tunelp], [no])]
1828 )
1829 UL_BUILD_INIT([tunelp])
1830 UL_REQUIRES_LINUX([tunelp])
1831 AM_CONDITIONAL([BUILD_TUNELP], [test "x$build_tunelp" = xyes])
1832
1833
1834 AC_ARG_ENABLE([kill],
1835   AS_HELP_STRING([--disable-kill], [do not build kill]),
1836   [], [UL_DEFAULT_ENABLE([kill], [check])]
1837 )
1838 UL_BUILD_INIT([kill])
1839 UL_REQUIRES_LINUX([kill])
1840 AM_CONDITIONAL([BUILD_KILL], [test "x$build_kill" = xyes])
1841
1842
1843 AC_ARG_ENABLE([last],
1844   AS_HELP_STRING([--disable-last], [do not build last]),
1845   [], [UL_DEFAULT_ENABLE([last], [check])]
1846 )
1847 UL_BUILD_INIT([last])
1848 UL_REQUIRES_HAVE([last], [utmpx_h], [utmpx.h header])
1849 UL_REQUIRES_HAVE([last], [gnu_utmpx], [GNU utmpx functions])
1850 AM_CONDITIONAL([BUILD_LAST], [test "x$build_last" = xyes])
1851
1852
1853 AC_ARG_ENABLE([utmpdump],
1854   AS_HELP_STRING([--disable-utmpdump], [do not build utmpdump]),
1855   [], [UL_DEFAULT_ENABLE([utmpdump], [check])]
1856 )
1857 UL_BUILD_INIT([utmpdump])
1858 UL_REQUIRES_HAVE([utmpdump], [utmpx_h], [utmpx.h header])
1859 UL_REQUIRES_HAVE([utmpdump], [gnu_utmpx], [GNU utmpx functions])
1860 AM_CONDITIONAL([BUILD_UTMPDUMP], [test "x$build_utmpdump" = xyes])
1861
1862
1863 AC_ARG_ENABLE([line],
1864   AS_HELP_STRING([--enable-line], [build line]),
1865   [], [UL_DEFAULT_ENABLE([line], [no])]
1866 )
1867 UL_BUILD_INIT([line])
1868 AM_CONDITIONAL([BUILD_LINE], [test "x$build_line" = xyes])
1869
1870
1871 AC_ARG_ENABLE([mesg],
1872   AS_HELP_STRING([--disable-mesg], [do not build mesg]),
1873   [], [UL_DEFAULT_ENABLE([mesg], [yes])]
1874 )
1875 UL_BUILD_INIT([mesg])
1876 AM_CONDITIONAL([BUILD_MESG], [test "x$build_mesg" = xyes])
1877
1878
1879 AC_ARG_ENABLE([raw],
1880   AS_HELP_STRING([--disable-raw], [do not build raw]),
1881   [], [UL_DEFAULT_ENABLE([raw], [check])]
1882 )
1883 UL_BUILD_INIT([raw])
1884 UL_REQUIRES_LINUX([raw])
1885 UL_REQUIRES_HAVE([raw], [linux_raw_h], [raw.h header file])
1886 AM_CONDITIONAL([BUILD_RAW], [test "x$build_raw" = xyes])
1887
1888
1889 AC_ARG_ENABLE([rename],
1890   AS_HELP_STRING([--disable-rename], [do not build rename]),
1891   [], [UL_DEFAULT_ENABLE([rename], [yes])]
1892 )
1893 UL_BUILD_INIT([rename])
1894 AM_CONDITIONAL([BUILD_RENAME], [test "x$build_rename" = xyes])
1895
1896
1897 AC_ARG_ENABLE([vipw],
1898   AS_HELP_STRING([--enable-vipw], [build vipw]),
1899   [], [UL_DEFAULT_ENABLE([vipw], [no])]
1900 )
1901 UL_BUILD_INIT([vipw])
1902 UL_REQUIRES_HAVE([vipw], [shadow_h], [shadow.h header])
1903 AM_CONDITIONAL([BUILD_VIPW], [test "x$build_vipw" = xyes])
1904
1905
1906 AC_ARG_ENABLE([newgrp],
1907   AS_HELP_STRING([--enable-newgrp], [build newgrp]),
1908   [], [UL_DEFAULT_ENABLE([newgrp], [no])]
1909 )
1910 UL_BUILD_INIT([newgrp])
1911 UL_REQUIRES_HAVE([newgrp], [crypt], [crypt function])
1912 AM_CONDITIONAL([BUILD_NEWGRP], [test "x$build_newgrp" = xyes])
1913
1914
1915 AC_ARG_WITH([user], AS_HELP_STRING([--without-user], [compile without libuser (remote chsh)]),
1916   [], [with_user=check]
1917 )
1918 have_user=no
1919 AS_IF([test "x$with_user" != xno], [
1920   PKG_CHECK_MODULES(LIBUSER,[libuser >= 0.58], [have_user=yes], [have_user=no])
1921   AS_CASE([$with_user:$have_user],
1922     [yes:no],
1923       [AC_MSG_ERROR([user selected but libuser not found])],
1924     [*:yes],
1925       [AC_DEFINE([HAVE_LIBUSER], [1], [Define if libuser is available])]
1926   )
1927   # temporary solution, libuser has stupid .pc where are exported all
1928   # private dependencies to Requires: instead of Requires.private:
1929   AS_IF([test "x$have_user" = xyes], [
1930     LIBUSER_LIBS=-luser
1931   ])
1932 ])
1933 AM_CONDITIONAL([HAVE_USER], [test "x$have_user" = xyes])
1934
1935 AC_ARG_ENABLE([chfn-chsh-password],
1936   AS_HELP_STRING([--disable-chfn-chsh-password], [do not require the user to enter the password in chfn and chsh]),
1937   [], [enable_chfn_chsh_password=yes]
1938 )
1939
1940 AC_ARG_ENABLE([chfn-chsh],
1941   AS_HELP_STRING([--enable-chfn-chsh], [build chfn and chsh]),
1942   [], [UL_DEFAULT_ENABLE([chfn_chsh], [check])]
1943 )
1944 UL_BUILD_INIT([chfn_chsh])
1945 UL_REQUIRES_HAVE([chfn_chsh], [shadow_h], [shadow.h header])
1946 UL_REQUIRES_HAVE([chfn_chsh], [getusershell], [getusershell function])
1947
1948 AS_IF([test "x$enable_chfn_chsh_password" = xyes -o "x$have_user" = xyes], [
1949   UL_REQUIRES_HAVE([chfn_chsh], [security_pam_appl_h], [PAM header file])
1950   AC_DEFINE([CHFN_CHSH_PASSWORD], [1], [Should chfn and chsh require the user to enter the password?])
1951 ])
1952 AM_CONDITIONAL([BUILD_CHFN_CHSH], [test "x$build_chfn_chsh" = xyes])
1953 AM_CONDITIONAL([CHFN_CHSH_PASSWORD], [test "x$enable_chfn_chsh_password" = xyes])
1954
1955 AC_ARG_ENABLE([chsh-only-listed],
1956   AS_HELP_STRING([--disable-chsh-only-listed], [chsh: allow shells not in /etc/shells]),
1957   [], enable_chsh_only_listed=yes
1958 )
1959
1960 AS_IF([test "x$enable_chsh_only_listed" = xyes], [
1961   AC_DEFINE([ONLY_LISTED_SHELLS], [1], [Should chsh allow only shells in /etc/shells?])
1962 ])
1963
1964
1965 AC_ARG_ENABLE([login],
1966   AS_HELP_STRING([--disable-login], [do not build login]),
1967   [], [UL_DEFAULT_ENABLE([login], [check])]
1968 )
1969 UL_BUILD_INIT([login])
1970 UL_REQUIRES_HAVE([login], [security_pam_appl_h], [PAM header file])
1971 UL_REQUIRES_HAVE([login], [security_pam_misc_h, security_openpam_h], [PAM conversation functions])
1972 UL_REQUIRES_HAVE([login], [utmpx_h], [utmpx.h header])
1973 UL_REQUIRES_HAVE([login], [gnu_utmpx], [GNU utmpx functions])
1974 AM_CONDITIONAL([BUILD_LOGIN], [test "x$build_login" = xyes])
1975
1976 AC_ARG_ENABLE([login-chown-vcs],
1977   AS_HELP_STRING([--enable-login-chown-vcs], [let login chown /dev/vcsN]),
1978   [], [enable_login_chown_vcs=no]
1979 )
1980
1981 AS_IF([test "x$enable_login_chown_vcs" = xyes], [
1982   AC_DEFINE([LOGIN_CHOWN_VCS], [1], [Should login chown /dev/vcsN?])
1983 ])
1984
1985 AC_ARG_ENABLE([login-stat-mail],
1986   AS_HELP_STRING([--enable-login-stat-mail], [let login stat() the mailbox]),
1987   [], [enable_login_stat_mail=no]
1988 )
1989
1990 AS_IF([test "x$enable_login_stat_mail" = xyes], [
1991   AC_DEFINE([LOGIN_STAT_MAIL], [1], [Should login stat() the mailbox?])
1992 ])
1993
1994
1995 AC_ARG_ENABLE([nologin],
1996   AS_HELP_STRING([--disable-nologin], [do not build nologin]),
1997   [], [UL_DEFAULT_ENABLE([nologin], [yes])]
1998 )
1999 UL_BUILD_INIT([nologin])
2000 AM_CONDITIONAL([BUILD_NOLOGIN], [test "x$build_nologin" = xyes])
2001
2002
2003 AC_ARG_ENABLE([sulogin],
2004   AS_HELP_STRING([--disable-sulogin], [do not build sulogin]),
2005   [], [UL_DEFAULT_ENABLE([sulogin], [check])]
2006 )
2007 UL_BUILD_INIT([sulogin])
2008 UL_REQUIRES_HAVE([sulogin], [crypt], [crypt function])
2009 UL_REQUIRES_HAVE([sulogin], [shadow_h], [shadow.h header])
2010 AM_CONDITIONAL([BUILD_SULOGIN], [test "x$build_sulogin" = xyes])
2011
2012
2013 AC_ARG_ENABLE([su],
2014   AS_HELP_STRING([--disable-su], [do not build su]),
2015   [], [UL_DEFAULT_ENABLE([su], [check])]
2016 )
2017 UL_BUILD_INIT([su])
2018 UL_REQUIRES_HAVE([su], [security_pam_appl_h], [PAM header file])
2019 UL_REQUIRES_HAVE([su], [utmpx_h], [utmpx.h header])
2020 UL_REQUIRES_HAVE([su], [gnu_utmpx], [GNU utmpx functions])
2021 AM_CONDITIONAL([BUILD_SU], [test "x$build_su" = xyes])
2022
2023
2024 AC_ARG_ENABLE([runuser],
2025   AS_HELP_STRING([--disable-runuser], [do not build runuser]),
2026   [], [UL_DEFAULT_ENABLE([runuser], [check])]
2027 )
2028 UL_BUILD_INIT([runuser])
2029 UL_REQUIRES_HAVE([runuser], [security_pam_appl_h], [PAM header file])
2030 UL_REQUIRES_HAVE([runuser], [utmpx_h], [utmpx.h header])
2031 UL_REQUIRES_HAVE([runuser], [gnu_utmpx], [GNU utmpx functions])
2032 AM_CONDITIONAL([BUILD_RUNUSER], [test "x$build_runuser" = xyes])
2033
2034
2035 AC_ARG_ENABLE([ul],
2036   AS_HELP_STRING([--disable-ul], [do not build ul]),
2037   [], [UL_DEFAULT_ENABLE([ul], [check])]
2038 )
2039 UL_BUILD_INIT([ul])
2040 UL_REQUIRES_HAVE([ul], [ncursesw, ncurses], [ncursesw or ncurses libraries])
2041 AM_CONDITIONAL([BUILD_UL], [test "x$build_ul" = xyes])
2042
2043
2044 AC_ARG_ENABLE([more],
2045   AS_HELP_STRING([--disable-more], [do not build more]),
2046   [], [UL_DEFAULT_ENABLE([more], [check])]
2047 )
2048 UL_BUILD_INIT([more])
2049 UL_REQUIRES_HAVE([more], [ncursesw, ncurses], [ncursesw or ncurses libraries])
2050 AM_CONDITIONAL([BUILD_MORE], [test "x$build_more" = xyes])
2051
2052
2053 AC_ARG_ENABLE([pg],
2054   AS_HELP_STRING([--enable-pg], [build pg]),
2055   [], [UL_DEFAULT_ENABLE([pg], [no])]
2056 )
2057 UL_BUILD_INIT([pg])
2058 UL_REQUIRES_HAVE([pg], [ncursesw, ncurses], [ncursesw or ncurses library])
2059 AM_CONDITIONAL([BUILD_PG], [test "x$build_pg" = xyes])
2060
2061
2062 AC_ARG_ENABLE([setterm],
2063   AS_HELP_STRING([--disable-setterm], [do not build setterm]),
2064   [], [UL_DEFAULT_ENABLE([setterm], [check])]
2065 )
2066 UL_BUILD_INIT([setterm])
2067 UL_REQUIRES_LINUX([setterm])
2068 UL_REQUIRES_HAVE([setterm], [ncursesw, ncurses], [ncursesw or ncurses library])
2069 AM_CONDITIONAL([BUILD_SETTERM], [test "x$build_setterm" = xyes])
2070
2071 # build_schedutils= is just configure-only variable to control
2072 # ionice, taskset and chrt
2073 AC_ARG_ENABLE([schedutils],
2074   AS_HELP_STRING([--disable-schedutils], [do not build chrt, ionice, taskset]),
2075   [], [UL_DEFAULT_ENABLE([schedutils], [check])]
2076 )
2077
2078
2079 UL_ENABLE_ALIAS([ionice], [schedutils])
2080 UL_BUILD_INIT([ionice])
2081 UL_REQUIRES_SYSCALL_CHECK([ionice],
2082         [UL_CHECK_SYSCALL([ioprio_set],
2083           [alpha],      [442],
2084           [i*86],       [289],
2085           [ia64*],      [1274],
2086           [powerpc*],   [273],
2087           [s390*],      [282],
2088           [sparc*],     [196],
2089           [sh*],        [288],
2090           [x86_64*],    [251])],
2091         [ioprio_set])
2092
2093 UL_REQUIRES_SYSCALL_CHECK([ionice],
2094         [UL_CHECK_SYSCALL([ioprio_get],
2095           [alpha],      [443],
2096           [i*86],       [290],
2097           [ia64*],      [1275],
2098           [powerpc*],   [274],
2099           [s390*],      [283],
2100           [sparc*],     [218],
2101           [sh*],        [289],
2102           [x86_64*],    [252])],
2103         [ioprio_get])
2104
2105 AM_CONDITIONAL([BUILD_IONICE], [test "x$build_ionice" = xyes])
2106
2107
2108 UL_ENABLE_ALIAS([taskset], [schedutils])
2109 UL_BUILD_INIT([taskset])
2110 UL_REQUIRES_HAVE([taskset], [cpu_set_t], [cpu_set_t type])
2111 UL_REQUIRES_SYSCALL_CHECK([taskset],
2112         [UL_CHECK_SYSCALL([sched_getaffinity])],
2113         [sched_getaffinity])
2114 AM_CONDITIONAL([BUILD_TASKSET], [test "x$build_taskset" = xyes])
2115
2116
2117 have_schedsetter=no
2118 AS_IF([test "x$ac_cv_func_sched_setscheduler" = xyes], [have_schedsetter=yes],
2119       [test "x$ac_cv_func_sched_setattr" = xyes], [have_schedsetter=yes])
2120
2121 UL_ENABLE_ALIAS([chrt], [schedutils])
2122 UL_BUILD_INIT([chrt])
2123 UL_REQUIRES_HAVE([chrt], [schedsetter], [sched_set functions])
2124 AM_CONDITIONAL([BUILD_CHRT], [test "x$build_chrt" = xyes])
2125
2126 AS_IF([test "x$build_chrt" = xyes], [
2127         UL_CHECK_SYSCALL([sched_setattr])
2128 ])
2129
2130
2131 AC_ARG_ENABLE([wall],
2132   AS_HELP_STRING([--disable-wall], [do not build wall]),
2133   [], [UL_DEFAULT_ENABLE([wall], [check])]
2134 )
2135 UL_BUILD_INIT([wall])
2136 UL_REQUIRES_HAVE([wall], [utmpx_h], [utmpx.h header])
2137 AM_CONDITIONAL([BUILD_WALL], [test "x$build_wall" = xyes])
2138
2139
2140 AC_ARG_ENABLE([write],
2141   AS_HELP_STRING([--enable-write], [build write]),
2142   [], [UL_DEFAULT_ENABLE([write], [no])]
2143 )
2144 UL_BUILD_INIT([write])
2145 UL_REQUIRES_HAVE([write], [utmpx_h], [utmpx.h header])
2146 UL_REQUIRES_HAVE([write], [gnu_utmpx], [GNU utmpx functions])
2147 AM_CONDITIONAL([BUILD_WRITE], [test "x$build_write" = xyes])
2148
2149
2150 AC_ARG_WITH([btrfs],
2151   AS_HELP_STRING([--without-btrfs], [do not build with btrfs support]),
2152   [], [with_btrfs=check]
2153 )
2154 have_btrfs=no
2155 AS_IF([test "x$with_btrfs" != xno], [
2156   AS_CASE([$with_btrfs:$have_linux_btrfs_h],
2157     [yes:no],
2158     [AC_MSG_ERROR([btrfs selected but linux/btrfs.h not found])],
2159     [check:no],
2160        [AC_MSG_WARN([linux/btrfs.h not found, do not build with btrfs support])],
2161     [*:yes],
2162        [have_btrfs=yes
2163         AC_DEFINE([HAVE_BTRFS_SUPPORT], [1], [Define if btrfs stuff is available])]
2164   )
2165 ])
2166 AM_CONDITIONAL([HAVE_BTRFS], [test "x$have_btrfs" = xyes])
2167
2168
2169 AC_ARG_WITH([systemd],
2170   AS_HELP_STRING([--without-systemd], [do not build with systemd support]),
2171   [], [with_systemd=check]
2172 )
2173
2174 have_systemd=no
2175 AS_IF([test "x$with_systemd" != xno], [
2176   # new version -- all libsystemd-* libs merged into libsystemd
2177   PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [have_systemd=yes], [have_systemd=no])
2178   # old versions
2179   AS_IF([test "x$have_systemd" != "xyes"], [
2180     PKG_CHECK_MODULES([SYSTEMD_DAEMON], [libsystemd-daemon],
2181                       [have_systemd_daemon=yes], [have_systemd_daemon=no])
2182     PKG_CHECK_MODULES([SYSTEMD_JOURNAL], [libsystemd-journal],
2183                       [have_systemd_journal=yes], [have_systemd_journal=no])
2184     AS_IF([test "x$have_systemd_daemon" = "xyes" -a "x$have_systemd_journal" = "xyes" ],[
2185            have_systemd=yes])
2186   ])
2187   AS_CASE([$with_systemd:$have_systemd],
2188     [yes:no],
2189       [AC_MSG_ERROR([systemd expected but libsystemd not found])],
2190     [*:yes],
2191        AC_DEFINE([HAVE_LIBSYSTEMD], [1], [Define if libsystemd is available])
2192   )
2193 ])
2194 AM_CONDITIONAL([HAVE_SYSTEMD], [test "x$have_systemd" = xyes])
2195
2196
2197 AC_ARG_WITH([systemdsystemunitdir],
2198   AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [directory for systemd unit files (requires systemd support)]),
2199   [], [with_systemdsystemunitdir=check]
2200 )
2201 AS_IF([test "x$with_systemdsystemunitdir" = xcheck], [
2202   AS_IF([test "x$have_systemd" = xyes], [
2203     with_systemdsystemunitdir=`$PKG_CONFIG --variable=systemdsystemunitdir systemd`
2204   ],[
2205     with_systemdsystemunitdir=no
2206   ])
2207 ])
2208 AS_IF([test "x$with_systemdsystemunitdir" != "xno"], [
2209   AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
2210 ])
2211
2212
2213 AC_ARG_WITH([smack],
2214   AS_HELP_STRING([--with-smack], [build with SMACK support]),
2215   [], [with_smack=no]
2216 )
2217 AS_IF([test "x$with_smack" = xyes], [
2218   AC_DEFINE([HAVE_SMACK], [1], [Add SMACK support])
2219 ])
2220
2221
2222 AC_ARG_WITH([bashcompletiondir],
2223   AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
2224   [],
2225   [AS_IF([`$PKG_CONFIG --exists bash-completion`], [
2226     with_bashcompletiondir=`$PKG_CONFIG --variable=completionsdir bash-completion`
2227   ], [
2228     with_bashcompletiondir=${datadir}/bash-completion/completions
2229   ])
2230 ])
2231 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
2232
2233 AC_ARG_ENABLE([bash-completion],
2234   AS_HELP_STRING([--disable-bash-completion], [do not install bash completion files]),
2235   [], [enable_bash_completion=yes]
2236 )
2237
2238 AM_CONDITIONAL([BUILD_BASH_COMPLETION], [test "x$enable_bash_completion" = xyes])
2239
2240
2241 AC_ARG_WITH([python],
2242   AS_HELP_STRING([--without-python], [do not build python bindings, use --with-python={2,3} to force version]),
2243   [], [with_python=check withval=check]
2244 )
2245
2246 have_python=no
2247 have_libpython=no
2248 AS_IF([test "x$with_python" != xno], [
2249   # We follow distributions default and look for PKG module name "python"
2250   # (minimal version is 2) but if major version is explicitly specified by
2251   # --with-python=2 or --with-python=3 then we look for PKG module "python2" or
2252   # "python3".
2253   AS_IF([test "x$withval" != xno -a "x$withval" != xyes -a "x$withval" != xcheck],
2254         [pymajor="$withval"; PYTHON=python${pymajor}], [pymajor="2"])
2255
2256   # check for python interpreter
2257   AM_PATH_PYTHON([$pymajor], [have_python=yes], [have_python=no])
2258   AS_CASE([$with_python:$have_python],
2259     [yes:no],
2260       [AC_MSG_ERROR([python selected but python interpreter not found])],
2261     [check:no],
2262        [AC_MSG_WARN([python interpreter not found, do not build python bindings])],
2263     [*:yes],
2264        # check for python development stuff
2265        [PKG_CHECK_MODULES([PYTHON], [python-$PYTHON_VERSION],
2266                           [have_libpython=yes], [have_libpython=no])]
2267   )
2268 ])
2269
2270
2271 AC_ARG_ENABLE([pylibmount],
2272   AS_HELP_STRING([--disable-pylibmount], [do not build pylibmount]),
2273   [], [UL_DEFAULT_ENABLE([pylibmount], [check])]
2274 )
2275 UL_BUILD_INIT([pylibmount])
2276 UL_REQUIRES_HAVE([pylibmount], [libpython], [libpython])
2277 UL_REQUIRES_BUILD([pylibmount], [libmount])
2278 AM_CONDITIONAL([BUILD_PYLIBMOUNT], [test "x$build_pylibmount" = "xyes"])
2279
2280 # We need to introduce a verbatim dependency into the Makefile, without automake
2281 # trying to interpret it, so push it as a AM_SUBST_NOTMAKE variable.
2282 verbatim_pylibmount_dependency='
2283
2284 # pylibmountexec module must be installed after usrlib_exec libraries,
2285 # otherwise the libtool relink step will fail to find libmount.la and
2286 # will try -lmount which is possibly not available.
2287 install-pylibmountexecLTLIBRARIES: install-usrlib_execLTLIBRARIES
2288
2289 '
2290 AC_SUBST([verbatim_pylibmount_dependency])
2291 AM_SUBST_NOTMAKE([verbatim_pylibmount_dependency])
2292
2293 AC_ARG_ENABLE([pg-bell],
2294   AS_HELP_STRING([--disable-pg-bell], [let pg not ring the bell on invalid keys]),
2295   [], [enable_pg_bell=yes]
2296 )
2297
2298 AS_IF([test "x$enable_pg_bell" = xyes], [
2299   AC_DEFINE([PG_BELL], [1], [Should pg ring the bell on invalid keys?])
2300 ])
2301
2302
2303 AC_DEFUN([FS_PATHS_DEFAULT], [/sbin:/sbin/fs.d:/sbin/fs])
2304 AC_ARG_ENABLE([fs-paths-default],
2305   AS_HELP_STRING([--enable-fs-paths-default=paths], [default search path for fs helpers @<:@FS_PATHS_DEFAULT@:>@]),
2306   [AS_CASE([$enableval],
2307     [yes], [fs_paths_defaults="FS_PATHS_DEFAULT"],
2308     [no],  [fs_paths_defaults=""],
2309     [fs_paths_defaults="$enableval"]
2310   )],
2311   [fs_paths_defaults="FS_PATHS_DEFAULT"]
2312 )
2313 AC_ARG_ENABLE([fs-paths-extra],
2314   AS_HELP_STRING([--enable-fs-paths-extra=paths], [additional search paths for fs helpers]),
2315   [AS_CASE([$enableval],
2316      [yes|no], [fs_paths_extra=""],
2317      [fs_paths_extra="$enableval"]
2318   )],
2319   [fs_paths_extra=""]
2320 )
2321 fs_paths="$fs_paths_defaults"
2322 AS_IF([test "x$fs_paths_extra" != "x"], [
2323   AS_IF([test "x$fs_paths" != "x"], [
2324     fs_paths="${fs_paths}:"
2325   ])
2326   fs_paths="${fs_paths}${fs_paths_extra}"
2327 ])
2328 AC_DEFINE_UNQUOTED([FS_SEARCH_PATH], "$fs_paths", [search path for fs helpers])
2329
2330
2331 AC_ARG_ENABLE([use-tty-group],
2332   AS_HELP_STRING([--disable-use-tty-group], [do not install wall and write setgid tty]),
2333   [], [enable_use_tty_group=yes]
2334 )
2335 AM_CONDITIONAL([USE_TTY_GROUP], [test "x$enable_use_tty_group" = xyes])
2336
2337 AS_IF([test "x$enable_use_tty_group" = xyes], [
2338   AC_DEFINE([USE_TTY_GROUP], [1], [Should wall and write be installed setgid tty?])
2339 ])
2340
2341
2342 AC_ARG_ENABLE([sulogin-emergency-mount],
2343   AS_HELP_STRING([--enable-sulogin-emergency-mount],
2344                  [use emergency mount of /dev and /proc for sulogin]),
2345   [], [enable_sulogin_emergency_mount=no]
2346 )
2347
2348 AS_IF([test "x$enable_sulogin_emergency_mount" = xyes], [
2349   AC_DEFINE([USE_SULOGIN_EMERGENCY_MOUNT], [1],
2350             [Should sulogin use a emergency mount of /dev and /proc?])
2351 ])
2352
2353
2354 AC_ARG_ENABLE([usrdir-path],
2355   AS_HELP_STRING([--enable-usrdir-path], [use only /usr paths in PATH env. variable (recommended on systems with /bin -> /usr/bin symlinks)]),
2356   [], [enable_usrdir_path=no]
2357 )
2358
2359 AS_IF([test "x$enable_usrdir_path" = xyes], [
2360   AC_DEFINE([USE_USRDIR_PATHS_ONLY], [1], [Define to 1 to remove /bin and /sbin from PATH env.variable])
2361 ])
2362
2363
2364 AC_ARG_ENABLE([makeinstall-chown],
2365   AS_HELP_STRING([--disable-makeinstall-chown], [do not do chown-like operations during "make install"]),
2366   [], [enable_makeinstall_chown=yes]
2367 )
2368 AM_CONDITIONAL([MAKEINSTALL_DO_CHOWN], [test "x$enable_makeinstall_chown" = xyes])
2369
2370
2371 AC_ARG_ENABLE([makeinstall-setuid],
2372   AS_HELP_STRING([--disable-makeinstall-setuid], [do not do setuid chmod operations during "make install"]),
2373   [], [enable_makeinstall_setuid=yes]
2374 )
2375 AM_CONDITIONAL([MAKEINSTALL_DO_SETUID], [test "x$enable_makeinstall_setuid" = xyes])
2376
2377
2378 AC_ARG_ENABLE([colors-default],
2379   AS_HELP_STRING([--disable-colors-default], [do not colorize output from utils by default]),
2380   [], [enable_colors_default=yes]
2381 )
2382 AS_IF([test "x$enable_colors_default" = xyes], [
2383   AC_DEFINE([USE_COLORS_BY_DEFAULT], [1], [Enables colorized output from utils by default])
2384 ])
2385
2386
2387 AC_ARG_VAR([SUID_CFLAGS],
2388            [CFLAGS used for binaries which are usually with the suid bit])
2389 AC_ARG_VAR([SUID_LDFLAGS],
2390            [LDFLAGS used for binaries which are usually with the suid bit])
2391
2392 AC_ARG_VAR([DAEMON_CFLAGS],
2393            [CFLAGS used for binaries which are usually executed as daemons])
2394 AC_ARG_VAR([DAEMON_LDFLAGS],
2395            [LDFLAGS used for binaries which are usually executed as daemons])
2396
2397 AC_ARG_VAR([SOLIB_CFLAGS],
2398            [CFLAGS used for shared libraries])
2399 AC_ARG_VAR([SOLIB_LDFLAGS],
2400            [LDFLAGS used for shared libraries])
2401
2402 AC_ARG_VAR([ADJTIME_PATH],
2403            [Path to hwclock adjtime file, default /etc/adjtime])
2404 AS_IF([test "x$ADJTIME_PATH" = x], [ADJTIME_PATH="/etc/adjtime"])
2405 AC_DEFINE_UNQUOTED([CONFIG_ADJTIME_PATH], "$ADJTIME_PATH", [Path to hwclock adjtime file])
2406
2407
2408 LIBS=""
2409
2410
2411 AC_CONFIG_HEADERS([config.h])
2412
2413 #
2414 # Don't use configure.ac to replace install paths! See Makefile PATHFILES for
2415 # more details.
2416 #
2417 AC_CONFIG_FILES([
2418 Makefile
2419 libblkid/docs/Makefile
2420 libblkid/docs/version.xml
2421 libblkid/src/blkid.h
2422 libfdisk/docs/Makefile
2423 libfdisk/docs/version.xml
2424 libfdisk/src/libfdisk.h
2425 libmount/docs/Makefile
2426 libmount/docs/version.xml
2427 libmount/src/libmount.h
2428 libsmartcols/docs/Makefile
2429 libsmartcols/docs/version.xml
2430 libsmartcols/src/libsmartcols.h
2431 po/Makefile.in
2432 ])
2433
2434 AC_OUTPUT
2435
2436 AC_MSG_RESULT([
2437         ${PACKAGE}  ${VERSION}
2438
2439         prefix:            ${prefix}
2440         exec prefix:       ${exec_prefix}
2441
2442         runstatedir:       ${runstatedir}
2443         bindir:            ${bindir}
2444         sbindir:           ${sbindir}
2445         libdir:            ${libdir}
2446         includedir:        ${includedir}
2447         usrbin_execdir:    ${usrbin_execdir}
2448         usrsbin_execdir:   ${usrsbin_execdir}
2449         usrlib_execdir:    ${usrlib_execdir}
2450
2451         compiler:          ${CC}
2452         cflags:            ${CFLAGS}
2453         suid cflags:       ${SUID_CFLAGS}
2454         ldflags:           ${LDFLAGS}
2455         suid ldflags:      ${SUID_LDFLAGS}
2456         ASAN enabled:      ${enable_asan}
2457
2458         Python:            ${PYTHON}
2459         Python version:    ${PYTHON_VERSION}
2460         Python libs:       ${pyexecdir}
2461
2462         Bash completions:  ${with_bashcompletiondir}
2463         Systemd support:   ${have_systemd}
2464         Systemd unitdir:   ${with_systemdsystemunitdir}
2465         Btrfs support:     ${have_btrfs}
2466         Wide-char support: ${build_widechar}
2467
2468         warnings:
2469
2470 ${WARN_CFLAGS}
2471
2472         Type 'make' or 'make <utilname>' to compile.
2473 ])