configure.ac

   1 AC_INIT([util-linux],
   2         m4_esyscmd([tools/git-version-gen .tarball-version]),
   3         [kzak@redhat.com],,
   4         [http://www.kernel.org/pub/linux/utils/util-linux/])
   5
   6
   7 AC_PREREQ([2.60])
   8
   9 AC_CONFIG_AUX_DIR([config])
  10 AC_CONFIG_MACRO_DIR([m4])
  11 dnl AC_USE_SYSTEM_EXTENSIONS must be called before any macros that run
  12 dnl the compiler (like AC_PROG_LIBTOOL) to avoid autoconf errors.
  13 AC_USE_SYSTEM_EXTENSIONS
  14 AM_INIT_AUTOMAKE([-Wall foreign 1.10 tar-pax no-dist-gzip dist-xz subdir-objects])
  15
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  17                             [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  18 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  19
  20 AC_CONFIG_SRCDIR([sys-utils/mount.c])
  21 AC_PREFIX_DEFAULT([/usr])
  22
  23 dnl version details from <major>.<minor>[-<suffix>]
  24 PACKAGE_VERSION_MAJOR=$(echo $PACKAGE_VERSION | awk -F. '{print $1}')
  25 PACKAGE_VERSION_MINOR=$(echo $PACKAGE_VERSION | awk -F. '{
  26                                                    sub("-.*","",$2); print $2}')
  27 PACKAGE_VERSION_RELEASE=$(echo $PACKAGE_VERSION | awk -F. '{
  28                      sub("-.*","",$3); print $3 ~ /^@<:@0-9@:>@+$/ ? $3 : 0}')
  29
  30 dnl libblkid version
  31 LIBBLKID_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  32 LIBBLKID_DATE="21-Mar-2018"
  33 LIBBLKID_LT_MAJOR=1
  34 LIBBLKID_LT_MINOR=1
  35 LIBBLKID_LT_MICRO=0
  36 LIBBLKID_VERSION_INFO=`expr $LIBBLKID_LT_MAJOR + $LIBBLKID_LT_MINOR`:$LIBBLKID_LT_MICRO:$LIBBLKID_LT_MINOR
  37
  38 dnl libuuid version
  39 LIBUUID_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  40 LIBUUID_LT_MAJOR=1
  41 LIBUUID_LT_MINOR=3
  42 LIBUUID_LT_MICRO=0
  43 LIBUUID_VERSION_INFO=`expr $LIBUUID_LT_MAJOR + $LIBUUID_LT_MINOR`:$LIBUUID_LT_MICRO:$LIBUUID_LT_MINOR
  44
  45 dnl libmount version
  46 LIBMOUNT_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  47 LIBMOUNT_LT_MAJOR=1
  48 LIBMOUNT_LT_MINOR=1
  49 LIBMOUNT_LT_MICRO=0
  50 LIBMOUNT_VERSION_INFO=`expr $LIBMOUNT_LT_MAJOR + $LIBMOUNT_LT_MINOR`:$LIBMOUNT_LT_MICRO:$LIBMOUNT_LT_MINOR
  51
  52 dnl libsmartcols version
  53 LIBSMARTCOLS_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  54 LIBSMARTCOLS_LT_MAJOR=1
  55 LIBSMARTCOLS_LT_MINOR=1
  56 LIBSMARTCOLS_LT_MICRO=0
  57 LIBSMARTCOLS_VERSION_INFO=`expr $LIBSMARTCOLS_LT_MAJOR + $LIBSMARTCOLS_LT_MINOR`:$LIBSMARTCOLS_LT_MICRO:$LIBSMARTCOLS_LT_MINOR
  58
  59 dnl libfdisk version
  60 LIBFDISK_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  61 LIBFDISK_LT_MAJOR=1
  62 LIBFDISK_LT_MINOR=1
  63 LIBFDISK_LT_MICRO=0
  64 LIBFDISK_VERSION_INFO=`expr $LIBFDISK_LT_MAJOR + $LIBFDISK_LT_MINOR`:$LIBFDISK_LT_MICRO:$LIBFDISK_LT_MINOR
  65
  66 # Check whether exec_prefix=/usr:
  67 AS_CASE([$exec_prefix:$prefix],
  68 [NONE:NONE | NONE:/usr | /usr:*],
  69   [AC_MSG_NOTICE([Default --exec-prefix detected.])
  70    AS_CASE([$bindir],  ['${exec_prefix}/bin'],  [bindir=/bin;   AC_MSG_NOTICE([  --bindir defaults to /bin])  ])
  71    AS_CASE([$sbindir], ['${exec_prefix}/sbin'], [sbindir=/sbin; AC_MSG_NOTICE([  --sbindir defaults to /sbin])])
  72    AS_CASE([$libdir],  ['${exec_prefix}/lib'],  [libdir=/lib;   AC_MSG_NOTICE([  --libdir defaults to /lib])  ])
  73   ]
  74 )
  75
  76
  77 # default for old versions without $runstatedir
  78 AS_IF([test x"$runstatedir" = x], [runstatedir='${localstatedir}/run'])
  79
  80 # our default if $localstatedir unchanged
  81 AS_CASE([$localstatedir:$runstatedir],
  82  [NONE:'${localstatedir}/run' | /var:'${localstatedir}/run' | NONE:'/run' ],
  83    [runstatedir=/run; AC_MSG_NOTICE([  --runstatedir defaults to /run])]
  84 )
  85
  86 AC_SUBST([runstatedir])
  87
  88
  89 # The original default values of {bin,sbin,lib}dir
  90 usrbin_execdir='${exec_prefix}/bin'
  91 AC_SUBST([usrbin_execdir])
  92
  93 usrsbin_execdir='${exec_prefix}/sbin'
  94 AC_SUBST([usrsbin_execdir])
  95
  96 AS_CASE([$libdir],
  97  ['${exec_prefix}/'* | '${prefix}/'* | /usr/* | "${prefix}"/* ],
  98    [usrlib_execdir=$libdir],
  99  [usrlib_execdir='${exec_prefix}'$libdir]
 100 )
 101 AC_SUBST([usrlib_execdir])
 102
 103
 104 AM_PROG_CC_C_O
 105 AC_PROG_MKDIR_P
 106 AC_PROG_CC_STDC
 107 AC_PROG_YACC
 108 AC_CANONICAL_HOST
 109 AC_C_CONST
 110 AC_C_VOLATILE
 111 AC_C_BIGENDIAN
 112
 113 dnl Compiler warnings
 114 UL_WARN_ADD([-fno-common])
 115 UL_WARN_ADD([-Wall])
 116 UL_WARN_ADD([-Werror=sequence-point])
 117 UL_WARN_ADD([-Wextra])
 118 UL_WARN_ADD([-Wextra-semi])
 119 UL_WARN_ADD([-Wembedded-directive])
 120 UL_WARN_ADD([-Wmissing-declarations])
 121 UL_WARN_ADD([-Wmissing-parameter-type])
 122 UL_WARN_ADD([-Wmissing-prototypes])
 123 UL_WARN_ADD([-Wno-missing-field-initializers])
 124 UL_WARN_ADD([-Wredundant-decls])
 125 UL_WARN_ADD([-Wsign-compare])
 126 UL_WARN_ADD([-Wtype-limits])
 127 UL_WARN_ADD([-Wuninitialized])
 128 UL_WARN_ADD([-Wunused-but-set-parameter])
 129 UL_WARN_ADD([-Wunused-but-set-variable])
 130 UL_WARN_ADD([-Wunused-parameter])
 131 UL_WARN_ADD([-Wunused-result])
 132 UL_WARN_ADD([-Wunused-variable])
 133 UL_WARN_ADD([-Wnested-externs])
 134 UL_WARN_ADD([-Wpointer-arith])
 135 UL_WARN_ADD([-Wstrict-prototypes])
 136 UL_WARN_ADD([-Wformat-security])
 137 UL_WARN_ADD([-Wimplicit-function-declaration])
 138 UL_WARN_ADD([-Wdiscarded-qualifiers])
 139 AC_SUBST([WARN_CFLAGS])
 140
 141 UL_WARN_ADD([-Wno-clobbered], [BSD_WARN_CFLAGS])
 142 AC_SUBST([BSD_WARN_CFLAGS])
 143
 144 UL_WARN_ADD([-Wno-cast-function-type], [PYTHON_WARN_CFLAGS])
 145 AC_SUBST([PYTHON_WARN_CFLAGS])
 146
 147 UL_WARN_ADD([-Wno-unused-parameter], [NO_UNUSED_WARN_CFLAGS])
 148 AC_SUBST([NO_UNUSED_WARN_CFLAGS])
 149
 150
 151 AC_ARG_ENABLE([asan],
 152   AS_HELP_STRING([--enable-asan], [compile with Address Sanitizer]),
 153   [], [enable_asan=no]
 154 )
 155 AS_IF([test "x$enable_asan" = xyes], [
 156   UL_WARN_ADD([-fsanitize=address])
 157 ])
 158
 159
 160
 161 dnl libtool-2
 162 LT_INIT
 163
 164 dnl check supported linker flags
 165 AX_CHECK_VSCRIPT
 166
 167 m4_ifndef([PKG_PROG_PKG_CONFIG],
 168   [m4_fatal([Could not locate the pkg-config autoconf
 169     macros. These are usually located in /usr/share/aclocal/pkg.m4.
 170     If your macros are in a different location, try setting the
 171     environment variable AL_OPTS="-I/other/macro/dir" before running
 172     ./autogen.sh or autoreconf again. Make sure pkg-config is installed.])])
 173 PKG_PROG_PKG_CONFIG
 174
 175 GTK_DOC_CHECK([1.10])
 176 AC_PATH_PROG([XSLTPROC], [xsltproc])
 177
 178 linux_os=no
 179 bsd_os=no
 180 AS_CASE([${host_os}],
 181   [*linux*],
 182      [linux_os=yes],
 183   [*darwin*],
 184      [darwin_os=yes],
 185   [*bsd*],
 186      [bsd_os=yes])
 187 AM_CONDITIONAL([LINUX], [test "x$linux_os" = xyes])
 188 AM_CONDITIONAL([DARWIN], [test "x$darwin_os" = xyes])
 189 AM_CONDITIONAL([BSD], [test "x$bsd_os" = xyes])
 190
 191 AS_IF([test  "x$darwin_os" = xyes], [
 192   AC_DEFINE([_DARWIN_C_SOURCE], [1], [Enable MAP_ANON in sys/mman.h on Mac OS X])
 193 ])
 194
 195 dnl define ARCH_<NAME> conditionals
 196 UL_SET_ARCH([I86], [i?86-*])
 197 UL_SET_ARCH([86_64], [x86_64*])
 198 UL_SET_ARCH([IA64], [ia64*])
 199 UL_SET_ARCH([S390], [s390*])
 200 UL_SET_ARCH([SPARC], [sparc*])
 201 UL_SET_ARCH([PPC], [ppc*|powerpc*])
 202 UL_SET_ARCH([M68K], [m68*])
 203 UL_SET_ARCH([MIPS], [mips*])
 204 UL_SET_ARCH([HPPA], [hppa*|parisc*])
 205
 206 AC_SYS_LARGEFILE
 207 AC_HEADER_ASSERT
 208 AC_STRUCT_TIMEZONE
 209
 210 dnl Don't forget to maintain alternatively allowed versions in autogen.sh!
 211 AM_GNU_GETTEXT_VERSION([0.18.3])
 212 AM_GNU_GETTEXT([external])
 213
 214 AS_IF([test -d "$srcdir/po"], [
 215   ALL_LINGUAS=`cd $srcdir/po > /dev/null && echo *.po | sed 's/\.po//g'`
 216 ], [
 217   ALL_LINGUAS="af am ar as be bg bn_IN bn ca cs cy da de el en_GB es et eu_ES fa fi fr gl gu he hi hr hu hy id is it ja ka kn ko ku lo lt lv mk ml mr ms my nb nl nn no nso or pa pl pt_BR pt ro ru si sk sl sq sr@Latn sr sv ta te th tr uk ur vi zh_CN zh_TW zu"
 218 ])
 219
 220 AC_CHECK_HEADERS([linux/compiler.h linux/blkpg.h linux/major.h], [], [], [
 221 #ifdef HAVE_LINUX_COMPILER_H
 222 #include <linux/compiler.h>
 223 #endif
 224 ])
 225 AC_CHECK_HEADERS([ \
 226         asm/io.h \
 227         err.h \
 228         errno.h \
 229         fcntl.h \
 230         getopt.h \
 231         inttypes.h \
 232         lastlog.h \
 233         libutil.h \
 234         linux/btrfs.h \
 235         linux/cdrom.h \
 236         linux/falloc.h \
 237         linux/watchdog.h \
 238         linux/fd.h \
 239         linux/raw.h \
 240         linux/tiocl.h \
 241         linux/version.h \
 242         linux/securebits.h \
 243         linux/net_namespace.h \
 244         locale.h \
 245         mntent.h \
 246         net/if.h \
 247         net/if_dl.h \
 248         netinet/in.h \
 249         paths.h \
 250         pty.h \
 251         security/pam_appl.h \
 252         stdint.h \
 253         stdio_ext.h \
 254         stdlib.h \
 255         endian.h \
 256         byteswap.h \
 257         sys/endian.h \
 258         sys/disk.h \
 259         sys/disklabel.h \
 260         sys/file.h \
 261         sys/io.h \
 262         sys/ioccom.h \
 263         sys/ioctl.h \
 264         sys/mkdev.h \
 265         sys/mount.h \
 266         sys/param.h \
 267         sys/prctl.h \
 268         sys/resource.h \
 269         sys/signalfd.h \
 270         sys/socket.h \
 271         sys/sockio.h \
 272         sys/stat.h \
 273         sys/sysmacros.h \
 274         sys/swap.h \
 275         sys/syscall.h \
 276         sys/time.h \
 277         sys/timex.h \
 278         sys/ttydefaults.h \
 279         sys/types.h \
 280         sys/ucred.h \
 281         sys/un.h \
 282         unistd.h \
 283         shadow.h \
 284         utmp.h \
 285         utmpx.h \
 286 ])
 287
 288 # There is a collision in old kernel-headers. The both files mount.h and fs.h
 289 # define MS_* macros. Fixed by kernel commit e462ec50cb5fad19f6003a3d8087f4a0945dd2b1.
 290 #
 291 AC_CHECK_HEADERS([linux/fs.h ], [], [],
 292  [#ifdef HAVE_SYS_MOUNT_H
 293    # include <linux/fs.h>
 294    # include <sys/mount.h>
 295   #endif
 296 ])
 297
 298 AC_CHECK_HEADERS([linux/gsmmux.h ], [], [],
 299  [#ifdef LINUX_GSMMUX_H
 300    # include <linux/gsmmux.h>
 301    #endif
 302 ])
 303
 304 AC_CHECK_HEADERS([security/pam_misc.h],
 305                 [AM_CONDITIONAL([HAVE_LINUXPAM], [true])],
 306                 [AM_CONDITIONAL([HAVE_LINUXPAM], [false])], [
 307 #ifdef HAVE_SECURITY_PAM_APPL_H
 308 #include <security/pam_appl.h>
 309 #endif
 310 ])
 311
 312 AC_CHECK_HEADERS([linux/blkzoned.h])
 313
 314 AC_CHECK_HEADERS([security/openpam.h], [], [], [
 315 #ifdef HAVE_SECURITY_PAM_APPL_H
 316 #include <security/pam_appl.h>
 317 #endif
 318 ])
 319
 320 AC_CHECK_HEADERS([langinfo.h],
 321                 [AM_CONDITIONAL([HAVE_LANGINFO], [true])],
 322                 [AM_CONDITIONAL([HAVE_LANGINFO], [false])])
 323
 324 AC_MSG_CHECKING([whether langinfo.h defines ALTMON_x constants])
 325 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 326         #include <langinfo.h>
 327 ]], [[
 328         char *str;
 329         str = nl_langinfo (ALTMON_1);
 330         str = nl_langinfo (ALTMON_2);
 331         str = nl_langinfo (ALTMON_3);
 332         str = nl_langinfo (ALTMON_4);
 333         str = nl_langinfo (ALTMON_5);
 334         str = nl_langinfo (ALTMON_6);
 335         str = nl_langinfo (ALTMON_7);
 336         str = nl_langinfo (ALTMON_8);
 337         str = nl_langinfo (ALTMON_9);
 338         str = nl_langinfo (ALTMON_10);
 339         str = nl_langinfo (ALTMON_11);
 340         str = nl_langinfo (ALTMON_12);
 341 ]])], [
 342         AC_MSG_RESULT([yes])
 343         AC_DEFINE([HAVE_LANGINFO_ALTMON], [1],
 344                 [Define if langinfo.h defines ALTMON_x constants])
 345 ], [
 346         AC_MSG_RESULT([no])
 347 ])
 348
 349
 350 AC_MSG_CHECKING([whether langinfo.h defines _NL_ABALTMON_x constants])
 351 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 352         #include <langinfo.h>
 353 ]], [[
 354         char *str;
 355         str = nl_langinfo (_NL_ABALTMON_1);
 356         str = nl_langinfo (_NL_ABALTMON_2);
 357         str = nl_langinfo (_NL_ABALTMON_3);
 358         str = nl_langinfo (_NL_ABALTMON_4);
 359         str = nl_langinfo (_NL_ABALTMON_5);
 360         str = nl_langinfo (_NL_ABALTMON_6);
 361         str = nl_langinfo (_NL_ABALTMON_7);
 362         str = nl_langinfo (_NL_ABALTMON_8);
 363         str = nl_langinfo (_NL_ABALTMON_9);
 364         str = nl_langinfo (_NL_ABALTMON_10);
 365         str = nl_langinfo (_NL_ABALTMON_11);
 366         str = nl_langinfo (_NL_ABALTMON_12);
 367 ]])], [
 368         AC_MSG_RESULT([yes])
 369         AC_DEFINE([HAVE_LANGINFO_NL_ABALTMON], [1],
 370                 [Define if langinfo.h defines _NL_ABALTMON_x constants])
 371 ], [
 372         AC_MSG_RESULT([no])
 373 ])
 374
 375
 376 dnl Convert some ac_cv_header_* variables to have_*
 377 dnl
 378 have_linux_version_h=$ac_cv_header_linux_version_h
 379 have_linux_blkzoned_h=$ac_cv_header_linux_blkzoned_h
 380 have_linux_btrfs_h=$ac_cv_header_linux_btrfs_h
 381 have_linux_raw_h=$ac_cv_header_linux_raw_h
 382 have_linux_securebits_h=$ac_cv_header_linux_securebits_h
 383 have_linux_watchdog_h=$ac_cv_header_linux_watchdog_h
 384 have_security_pam_appl_h=$ac_cv_header_security_pam_appl_h
 385 have_security_pam_misc_h=$ac_cv_header_security_pam_misc_h
 386 have_security_openpam_h=$ac_cv_header_security_openpam_h
 387 have_shadow_h=$ac_cv_header_shadow_h
 388 have_sys_signalfd_h=$ac_cv_header_sys_signalfd_h
 389 have_utmpx_h=$ac_cv_header_utmpx_h
 390
 391 AS_CASE([$linux_os:$have_linux_version_h],
 392   [yes:no],
 393     [AC_MSG_ERROR([kernel headers required on Linux])]
 394 )
 395
 396 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 397 #include <time.h>
 398 #include <unistd.h>
 399 ]], [[
 400     int a = 0;
 401     struct tm *tm = localtime(0);
 402     if (a == -1)  /* false */
 403         sleep(tm->tm_gmtoff);
 404 ]])],
 405 [AC_DEFINE([HAVE_TM_GMTOFF], [1], [Does struct tm have a field tm_gmtoff?])
 406 ])
 407
 408 AC_CHECK_MEMBERS([struct termios.c_line],,,
 409     [[#include <termios.h>]])
 410
 411 AC_CHECK_MEMBERS([struct stat.st_mtim.tv_nsec],,,
 412         [#include <sys/stat.h>])
 413
 414 AC_CHECK_DECLS([_NL_TIME_WEEK_1STDAY],[],[],[[#include <langinfo.h>]])
 415
 416 AC_CHECK_DECL([llseek],
 417         [AC_DEFINE([HAVE_LLSEEK_PROTOTYPE], [1],
 418                         [Define to 1 if have llseek prototype])],
 419         [],
 420         [#include <unistd.h>])
 421
 422 AC_CHECK_DECL([lseek64],
 423         [AC_DEFINE([HAVE_LSEEK64_PROTOTYPE], [1],
 424                         [Define to 1 if have lseek64 prototype])],
 425         [],
 426         [#define _LARGEFILE_SOURCE
 427          #define _LARGEFILE64_SOURCE
 428          #include <unistd.h>])
 429
 430 AC_CHECK_DECL([environ],
 431         [AC_DEFINE([HAVE_ENVIRON_DECL], [1],
 432                 [Define to 1 if have **environ prototype])],
 433 )
 434
 435 AC_CHECK_DECL([strsignal],
 436         [AC_DEFINE([HAVE_STRSIGNAL_DECL], [1],
 437                 [Define to 1 if have strsignal function prototype])],
 438 )
 439
 440 AC_CHECK_DECL([TIOCGLCKTRMIOS],
 441               [have_tiocglcktrmios=yes], [have_tiocglcktrmios=no],
 442               [#include <sys/ioctl.h>])
 443 AC_CHECK_DECL([SOCK_CLOEXEC],
 444               [have_sock_cloexec=yes], [have_sock_cloexec=no],
 445               [#include <sys/types.h>
 446                #include <sys/socket.h>])
 447 AC_CHECK_DECL([SOCK_NONBLOCK],
 448               [have_sock_nonblock=yes], [have_sock_nonblock=no],
 449               [#include <sys/types.h>
 450                #include <sys/socket.h>])
 451 AC_CHECK_DECL([SO_PASSCRED],
 452               [have_so_passcred=yes], [have_so_passcred=no],
 453               [#include <sys/types.h>
 454                #include <sys/socket.h>])
 455
 456 AC_CHECK_FUNCS([ \
 457         __fpurge \
 458         fpurge \
 459         __fpending \
 460         secure_getenv \
 461         __secure_getenv \
 462         eaccess \
 463         err \
 464         errx \
 465         explicit_bzero \
 466         fsync \
 467         utimensat \
 468         getdomainname \
 469         getdtablesize \
 470         getexecname \
 471         getmntinfo \
 472         getrandom \
 473         getrlimit \
 474         getsgnam \
 475         inotify_init \
 476         jrand48 \
 477         lchown \
 478         llseek \
 479         lseek64 \
 480         mempcpy \
 481         mkostemp \
 482         nanosleep \
 483         ntp_gettime \
 484         personality \
 485         posix_fadvise \
 486         prctl \
 487         qsort_r \
 488         rpmatch \
 489         scandirat \
 490         setprogname \
 491         setresgid \
 492         setresuid \
 493         sched_setattr \
 494         sched_setscheduler \
 495         sigqueue \
 496         srandom \
 497         strnchr \
 498         strndup \
 499         strnlen \
 500         sysconf \
 501         sysinfo \
 502         timegm \
 503         usleep \
 504         vwarnx \
 505         warn \
 506         warnx \
 507 ])
 508 AC_FUNC_FSEEKO
 509
 510 AC_CHECK_FUNCS([openat fstatat unlinkat], [have_openat=yes], [have_openat=no])
 511 AC_CHECK_FUNCS([ioperm iopl], [have_io=yes])
 512 AC_CHECK_FUNCS([futimens], [have_futimens=yes])
 513 AC_CHECK_FUNCS([inotify_init1], [have_inotify_init1=yes])
 514 AC_CHECK_FUNCS([open_memstream], [have_open_memstream=yes],[have_open_memstream=no])
 515 AC_CHECK_FUNCS([reboot], [have_reboot=yes],[have_reboot=no])
 516 AC_CHECK_FUNCS([updwtmpx updwtmpx], [have_gnu_utmpx=yes], [have_gnu_utmpx=no])
 517 AC_CHECK_FUNCS([getusershell], [have_getusershell=yes],[have_getusershell=no])
 518
 519 AM_CONDITIONAL([HAVE_OPENAT], [test "x$have_openat" = xyes])
 520
 521
 522 AC_CHECK_FUNCS([isnan], [],
 523         [AC_CHECK_LIB([m], [isnan], [MATH_LIBS="-lm"])]
 524         [AC_CHECK_LIB([m], [__isnan], [MATH_LIBS="-lm"])]
 525 )
 526 AC_SUBST([MATH_LIBS])
 527
 528
 529 dnl lib/mononotic.c may require -lrt
 530 AC_CHECK_FUNCS([clock_gettime], [],
 531         [AC_CHECK_LIB([rt], [clock_gettime], [REALTIME_LIBS="-lrt"])]
 532 )
 533
 534 have_timer="no"
 535 AC_CHECK_FUNCS([timer_create],
 536         [have_timer="yes"],
 537         [AC_CHECK_LIB([rt], [timer_create], [
 538                 have_timer="yes"
 539                 REALTIME_LIBS="-lrt"
 540         ],[
 541                 AC_SEARCH_LIBS([timer_create], [rt], [
 542                         AC_MSG_RESULT(yes)
 543                         have_timer="yes"
 544                         REALTIME_LIBS="-lrt -lpthread"
 545                 ],[], [-lpthread]
 546                 )
 547                 ])]
 548 )
 549
 550 AC_SUBST([REALTIME_LIBS])
 551
 552
 553 AC_CHECK_LIB([rtas], [rtas_get_sysparm], [
 554         RTAS_LIBS="-lrtas"
 555         AC_DEFINE_UNQUOTED([HAVE_LIBRTAS], [1], [Define if librtas exists]), [],
 556 ])
 557 AC_SUBST([RTAS_LIBS])
 558
 559
 560 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 561                 AC_DEFINE_UNQUOTED([HAVE_SA_LEN], [1], [Define if struct sockaddr contains sa_len]), [],
 562         [#include <sys/types.h>
 563          #include <sys/socket.h>])
 564
 565 SOCKET_LIBS=
 566 AC_SEARCH_LIBS([socket], [socket],
 567         [AS_IF([test x"$ac_cv_search_socket" != x"none required"],
 568                 [SOCKET_LIBS="$SOCKET_LIBS -lsocket"])
 569 ])
 570 AC_SUBST([SOCKET_LIBS])
 571
 572
 573 have_dirfd=no
 574 AC_CHECK_FUNCS([dirfd], [have_dirfd=yes], [have_dirfd=no])
 575 AS_IF([test x"$have_dirfd" = xno], [
 576         AC_CHECK_DECLS([dirfd],
 577                 [have_dirfd=yes], [have_dirfd=no],
 578                 [#include <sys/types.h>
 579                  #include <dirent.h>])
 580 ])
 581
 582 have_ddfd=no
 583 AS_IF([test x"$have_dirfd" = xno], [
 584         AC_CHECK_MEMBERS([DIR.dd_fd],
 585                 [have_ddfd=yes], [have_ddfd=no],
 586                 [#include <sys/types.h>
 587                  #include <dirent.h>])
 588 ])
 589
 590 AS_CASE([$have_dirfd:$have_ddfd],
 591   [no:no],
 592     [AC_MSG_ERROR([cannot find a method to get filedescriptor of directory])]
 593 )
 594
 595
 596 AC_MSG_CHECKING([whether program_invocation_short_name is defined])
 597 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 598         #include <errno.h>
 599 ]], [[
 600         program_invocation_short_name = "test";
 601 ]])], [
 602         AC_MSG_RESULT([yes])
 603         AC_DEFINE([HAVE_PROGRAM_INVOCATION_SHORT_NAME], [1],
 604                 [Define if program_invocation_short_name is defined])
 605 ], [
 606         AC_MSG_RESULT([no])
 607 ])
 608
 609
 610 AC_MSG_CHECKING([whether __progname is defined])
 611 AC_LINK_IFELSE([AC_LANG_PROGRAM([extern char *__progname;],
 612            [if (*__progname == 0) return 1;])],
 613            AC_DEFINE([HAVE___PROGNAME], [1], [Define if __progname is defined])
 614            AC_MSG_RESULT([yes]),
 615            AC_MSG_RESULT([no]))
 616
 617 dnl Static compilation
 618 m4_define([UL_STATIC_PROGRAMS], [losetup, mount, umount, fdisk, sfdisk, blkid, nsenter, unshare])
 619
 620 AC_ARG_ENABLE([static-programs],
 621   [AS_HELP_STRING([--enable-static-programs=LIST],
 622       [link static the programs in LIST (comma-separated,
 623       supported for ]m4_defn([UL_STATIC_PROGRAMS])[)])])
 624
 625 AS_CASE([$enable_static_programs],
 626   [yes],
 627     [enable_static_programs=m4_quote(UL_STATIC_PROGRAMS)],
 628   [no],
 629     [enable_static_programs=]
 630 )
 631
 632 dnl Set all the individual AM_CONDITIONALs
 633 m4_foreach([UL_PRG], m4_defn([UL_STATIC_PROGRAMS]), [
 634   AS_CASE([,$enable_static_programs,],
 635    [*,UL_PRG,*], [static_[]UL_PRG=yes]
 636   )
 637   AS_IF([test "x$static_[]UL_PRG" = xyes], [AC_MSG_NOTICE([enable static build: UL_PRG.])])
 638   AM_CONDITIONAL([HAVE_STATIC_]m4_toupper(UL_PRG),
 639     [test "x$static_[]UL_PRG" = xyes])
 640 ])
 641
 642
 643 AC_ARG_ENABLE([all-programs],
 644   AS_HELP_STRING([--disable-all-programs], [disable everything, might be overridden by --enable-<name>]),
 645   [], [enable_all_programs=undefined]
 646 )
 647
 648 AS_CASE([$enable_all_programs],
 649   [yes], [AC_MSG_WARN([force to build all programs by default])
 650           ul_default_estate=check],
 651   [no],  [AC_MSG_WARN([disable all programs by default])
 652           ul_default_estate=no]
 653 )
 654
 655
 656 AX_CHECK_TLS
 657
 658 AC_DEFUN([UL_SCANF_TYPE_MODIFIER], [dnl
 659 # include <stdio.h>
 660 # include <stdlib.h>
 661 int main()
 662 {
 663         int i;
 664         int rc = 1;
 665         char *s;
 666         i = sscanf("x", $1, &s);
 667         if (i == 1  && *s == 'x')
 668                 rc = 0;
 669         free(s);
 670         return rc;
 671 }])
 672
 673 AC_CACHE_VAL([scanf_cv_alloc_modifier],
 674   AC_RUN_IFELSE([AC_LANG_SOURCE([UL_SCANF_TYPE_MODIFIER(["%ms"])])],
 675     [scanf_cv_alloc_modifier=ms],
 676     AC_RUN_IFELSE([AC_LANG_SOURCE([UL_SCANF_TYPE_MODIFIER(["%as"])])],
 677       [scanf_cv_alloc_modifier=as],
 678       [scanf_cv_alloc_modifier=no]
 679     )
 680     ,
 681
 682     [AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 683      #include <stdio.h>
 684      #include <unistd.h>
 685
 686      #if defined(__GLIBC__) && !defined(__UCLIBC__)
 687
 688      #if !(__GLIBC_PREREQ(2, 7))
 689      #error %m is not available
 690      #endif
 691
 692      #elif defined(_POSIX_VERSION)
 693
 694      #if _POSIX_VERSION < 200809L
 695      #error %m is not available
 696      #endif
 697
 698      #else
 699      #error Your C-library is not supported.
 700      #endif
 701      ])],
 702     [scanf_cv_alloc_modifier=ms],
 703     [scanf_cv_alloc_modifier=no])]
 704   )
 705 )
 706
 707 AC_MSG_CHECKING([scanf string alloc modifiers])
 708 AS_CASE([$scanf_cv_alloc_modifier],
 709   [ms],
 710     [AC_MSG_RESULT([(%ms) yes])
 711      AC_DEFINE([HAVE_SCANF_MS_MODIFIER], [1], [scanf %ms modifier])
 712      have_scanf_alloc_modifier=yes],
 713   [as],
 714     [AC_MSG_RESULT([(%as) yes])
 715      have_scanf_alloc_modifier=yes
 716      AC_DEFINE([HAVE_SCANF_AS_MODIFIER], [1], [scanf %as modifier])],
 717   [AC_MSG_RESULT([no])
 718    have_scanf_alloc_modifier=no]
 719 )
 720
 721
 722 AC_ARG_WITH([util], AS_HELP_STRING([--without-util], [compile without libutil]),
 723   [], [with_util=auto]
 724 )
 725 AS_IF([test "x$with_util" = xno], [
 726   AM_CONDITIONAL([HAVE_UTIL], [false])
 727   have_util=no
 728 ], [
 729   UL_CHECK_LIB([util], [openpty])
 730 ])
 731
 732
 733 AC_CHECK_TYPES([union semun], [], [], [[
 734 #include <sys/sem.h>
 735 ]])
 736 AC_CHECK_TYPES([loff_t])
 737
 738
 739 AC_ARG_ENABLE([widechar],
 740   AS_HELP_STRING([--disable-widechar], [do not compile wide character support]),
 741   [], [enable_widechar=check]
 742 )
 743 UL_BUILD_INIT([widechar])
 744 UL_REQUIRES_COMPILE([widechar], [[
 745   #include <wchar.h>
 746   #include <wctype.h>
 747   #include <stdio.h>
 748   ]], [[
 749     wchar_t wc;
 750     wint_t w;
 751     w = fgetwc(stdin);
 752     if (w == WEOF) exit(1);
 753     wc = w;
 754     fputwc(wc,stdout);
 755   ]],
 756   [wchar_t support])
 757
 758 AS_IF([test "x$build_widechar" = xyes ], [
 759   AC_DEFINE([HAVE_WIDECHAR], [1], [Do we have wide character support?])
 760 ])
 761
 762
 763 AC_CHECK_TYPES([cpu_set_t], [have_cpu_set_t=yes], [], [[
 764 #include <sched.h>
 765 ]])
 766
 767 AM_CONDITIONAL([HAVE_CPU_SET_T], [test "x$have_cpu_set_t" = xyes])
 768
 769 AC_CHECK_TYPES([sighandler_t], [], [], [[
 770 #include <signal.h>
 771 ]])
 772
 773 AC_CHECK_DECLS([CPU_ALLOC], [], [], [[
 774 #include <sched.h>
 775 ]])
 776
 777 # on Solaris, you can't mix and match standards, since we use c99
 778 # aparently at this stage, XOPEN_SOURCE will conflict.  As workaround,
 779 # check for crypt.h and use that without XOPEN_SOURCE.
 780 AC_CHECK_HEADERS([crypt.h])
 781 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 782 #ifdef HAVE_CRYPT_H
 783 #include <crypt.h>
 784 #else
 785 #define _XOPEN_SOURCE
 786 #include <unistd.h>
 787 #endif
 788 ]], [[
 789 char *c = crypt("abc","pw");
 790 ]])],[],[
 791   LIBS="$LIBS -lcrypt"
 792   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 793   #ifdef HAVE_CRYPT_H
 794   #include <crypt.h>
 795   #else
 796   #define _XOPEN_SOURCE
 797   #include <unistd.h>
 798   #endif
 799   ]], [[
 800   char *c = crypt("abc","pw");
 801   ]])],[
 802   AC_DEFINE([HAVE_LIBCRYPT], [1], [Do we need -lcrypt?])
 803   have_libcrypt=yes
 804   ],[
 805   AC_MSG_ERROR([crypt() is not available])
 806   ])
 807 ])
 808 AM_CONDITIONAL([HAVE_LIBCRYPT], [test "x$have_libcrypt" = xyes])
 809
 810
 811 AC_ARG_WITH([selinux],
 812   AS_HELP_STRING([--with-selinux], [compile with SELinux support]),
 813   [], [with_selinux=no]
 814 )
 815
 816 AS_IF([test "x$with_selinux" = xno], [
 817   AM_CONDITIONAL([HAVE_SELINUX], [false])
 818 ], [
 819   PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.0],
 820         [AC_DEFINE([HAVE_LIBSELINUX], [1], [Define if SELinux is available])
 821          UL_PKG_STATIC([SELINUX_LIBS_STATIC], [libselinux])
 822          AM_CONDITIONAL([HAVE_SELINUX], [true])
 823          have_selinux=yes],
 824         [have_selinux=no])
 825
 826   AS_CASE([$with_selinux:$have_selinux],
 827     [yes:no], [AC_MSG_ERROR([SELinux selected but libselinux not found or too old])]
 828   )
 829
 830   AS_IF([test "x$have_selinux" = xyes], [
 831     UL_SET_FLAGS([], [], [$SELINUX_LIBS])
 832     # This function is missing in old libselinux 1.xx versions
 833     AC_CHECK_FUNCS([security_get_initial_context])
 834     UL_RESTORE_FLAGS
 835   ])
 836 ])
 837 AC_SUBST([SELINUX_LIBS])
 838 AC_SUBST([SELINUX_LIBS_STATIC])
 839
 840
 841 AC_ARG_WITH([audit],
 842   AS_HELP_STRING([--with-audit], [compile with audit support]),
 843   [], [with_audit=no]
 844 )
 845
 846 AS_IF([test "x$with_audit" = xno], [
 847   AM_CONDITIONAL([HAVE_AUDIT], [false])
 848 ], [
 849   UL_CHECK_LIB([audit], [audit_log_user_message])
 850   AS_CASE([$with_audit:$have_audit],
 851     [yes:no],
 852       [AC_MSG_ERROR([Audit selected but libaudit not found (or does not support audit_log_user_message())])]
 853   )
 854 ])
 855
 856 AC_ARG_WITH([udev], AS_HELP_STRING([--without-udev], [compile without udev support]),
 857   [], [with_udev=auto]
 858 )
 859
 860 AS_IF([test "x$with_udev" = xno], [
 861   AM_CONDITIONAL([HAVE_UDEV], [false])
 862 ], [
 863   UL_CHECK_LIB([udev], [udev_new])
 864   AS_CASE([$with_udev:$have_udev],
 865     [yes:no],
 866       [AC_MSG_ERROR([udev selected but libudev not found])]
 867   )
 868 ])
 869
 870
 871 dnl wide-char ncurses
 872 AC_ARG_WITH([ncursesw],
 873   AS_HELP_STRING([--without-ncursesw], [do not build with wide-char ncurses]),
 874   [], [with_ncursesw=auto]
 875 )
 876 have_ncursesw=no
 877 have_ncursesw_header=no
 878 AS_IF([test "x$with_ncursesw" != xno], [
 879   UL_NCURSES_CHECK([ncursesw])
 880   AS_IF([test "x$have_ncursesw" = xyes], [
 881     AC_CHECK_HEADERS([ncursesw/ncurses.h], [have_ncursesw_header=yes])
 882     AC_CHECK_HEADERS([ncursesw/term.h])
 883
 884     # Define HAVE_NCURSES_H only if check for HAVE_NCURSESW_NCURSES_H is
 885     # unsuccessful to avoid too many *_H permitations in config.h
 886     AS_IF([test "x$have_ncursesw_header" = xno], [
 887            AC_CHECK_HEADERS([ncurses.h], [have_ncursesw_header=yes])
 888            AC_CHECK_HEADERS([term.h])
 889     ])
 890     AS_IF([test "x$have_ncursesw_header" = xno], [have_ncursesw=no])
 891   ])
 892   AS_IF([test "x$have_ncursesw" = xyes], [
 893     CURSES_LIB_NAME="ncursesw"
 894     AC_DEFINE([HAVE_LIBNCURSESW], [1], [Define if ncursesw library available])
 895   ])
 896 ])
 897 AS_CASE([$with_ncursesw:$have_ncursesw],
 898   [yes:no], [AC_MSG_ERROR([ncursesw selected, but library not found])])
 899
 900
 901 dnl non-wide ncurses
 902 AC_ARG_WITH([ncurses],
 903   AS_HELP_STRING([--with-ncurses], [build with non-wide ncurses]),
 904   [], [with_ncurses=auto]
 905 )
 906 have_ncurses=no
 907 have_ncurses_header=no
 908 AS_CASE([$with_ncurses:$build_widechar],
 909   [yes:yes], [AC_MSG_ERROR([wide-char support enabled, but non-wide ncurses selects])])
 910
 911 AS_IF([test "x$have_ncursesw" = xno -a "x$with_ncurses" != xno ], [
 912   UL_NCURSES_CHECK([ncurses])
 913   AS_IF([test "x$have_ncurses" = xyes], [
 914     AC_CHECK_HEADERS([ncurses/ncurses.h], [have_ncurses_header=yes])
 915     AC_CHECK_HEADERS([ncurses/term.h])
 916
 917     # Define HAVE_NCURSES_H only if check for HAVE_NCURSES_NCURSES_H is
 918     # unsuccessful to avoid too many *_H permitations in config.h
 919     AS_IF([test "x$have_ncurses_header" = xno], [
 920            AC_CHECK_HEADERS([ncurses.h], [have_ncurses_header=yes])
 921            AC_CHECK_HEADERS([term.h])
 922     ])
 923     AS_IF([test "x$have_ncurses_header" = xno], [have_ncurses=no])
 924   ])
 925   AS_IF([test "x$have_ncurses" = xyes], [
 926     CURSES_LIB_NAME="ncurses"
 927     AC_DEFINE([HAVE_LIBNCURSES], [1], [Define if ncurses library available])
 928   ])
 929 ])
 930 AS_CASE([$with_ncurses:$have_ncurses],
 931   [yes:no], [AC_MSG_ERROR([ncurses selected, but library not found])])
 932
 933 AC_SUBST([NCURSES_CFLAGS])
 934 AC_SUBST([NCURSES_LIBS])
 935 AM_CONDITIONAL([HAVE_NCURSES], [test "x$have_ncursesw" = xyes -o  "x$have_ncurses" = xyes])
 936
 937
 938 AC_ARG_WITH([slang],
 939   AS_HELP_STRING([--with-slang], [compile cfdisk with slang rather than ncurses]),
 940   [], [with_slang=no]
 941 )
 942 have_slang=no
 943 AS_IF([test "x$with_slang" = xyes], [
 944   AC_CHECK_HEADERS([slang.h slang/slang.h])
 945   AC_CHECK_HEADERS([slcurses.h slang/slcurses.h],
 946                    [have_slang=yes], [], [
 947 #ifdef HAVE_SLANG_H
 948 #include <slang.h>
 949 #elif defined(HAVE_SLANG_SLANG_H)
 950 #include <slang/slang.h>
 951 #endif
 952 ])
 953   AS_IF([test "x$have_slang" = xno], [
 954     AC_MSG_ERROR([slang selected but slcurses.h not found])],
 955     [CURSES_LIB_NAME=slang
 956   ])
 957 ])
 958 AM_CONDITIONAL([HAVE_SLANG], [test "x$have_slang" = xyes])
 959
 960
 961 AS_IF([test "x$have_slang" = xyes -o "x$have_ncursesw" = xyes -o "x$have_ncurses" = xyes], [
 962         AC_CHECK_LIB([$CURSES_LIB_NAME], use_default_colors, [
 963                      AC_DEFINE(HAVE_USE_DEFAULT_COLORS, 1,
 964                                [Define if curses library has the use_default_colors().])
 965         ])
 966         AC_CHECK_LIB([$CURSES_LIB_NAME], resizeterm, [
 967                      AC_DEFINE(HAVE_RESIZETERM, 1,
 968                                [Define if curses library has the resizeterm().])
 969         ])
 970 ])
 971
 972
 973 AC_ARG_WITH([tinfo], AS_HELP_STRING([--without-tinfo], [compile without libtinfo]),
 974   [], [with_tinfo=auto]
 975 )
 976 have_tinfo=no
 977 have_tinfow=no
 978 AS_IF([test "x$with_tinfo" != xno], [
 979   AS_IF([test "x$have_ncursesw" = xyes], [
 980     UL_TINFO_CHECK([tinfow])
 981   ])
 982   AS_IF([test "x$have_tinfow" = xno], [
 983     UL_TINFO_CHECK([tinfo])
 984   ])
 985 ])
 986 AC_SUBST([TINFO_LIBS])
 987 AC_SUBST([TINFO_LIBS_STATIC])
 988 AC_SUBST([TINFO_CFLAGS])
 989 AM_CONDITIONAL([HAVE_TINFO], [test "x$have_tinfo" = xyes -o "x$have_tinfow" = xyes])
 990 AS_IF([test "x$have_tinfo" = xyes -o "x$have_tinfow" = xyes], [
 991   AC_DEFINE(HAVE_LIBTINFO, 1, [Define if libtinfo or libtinfow available.])
 992 ])
 993
 994
 995 AC_ARG_WITH([readline],
 996   AS_HELP_STRING([--without-readline], [do not build with GNU Readline support]),
 997   [], [with_readline=auto]
 998 )
 999
1000 AS_IF([test "x$with_readline" = xno], [
1001   AM_CONDITIONAL([HAVE_READLINE], [false])
1002 ], [
1003   UL_CHECK_LIB([readline], [readline])
1004   AS_CASE([$with_readline:$have_readline],
1005     [yes:no],
1006       [AC_MSG_ERROR([readline selected but libreadline not found ])],
1007     [*:yes],
1008       [READLINE_LIBS="-lreadline"
1009        READLINE_LIBS_STATIC="-lreadline $TINFO_LIBS_STATIC"]
1010   )
1011 ])
1012 AC_SUBST([READLINE_LIBS])
1013 AC_SUBST([READLINE_LIBS_STATIC])
1014
1015
1016 AC_ARG_WITH([utempter],
1017   AS_HELP_STRING([--with-utempter], [compile script(1) with libutempter]),
1018   [], [with_utempter=no]
1019 )
1020
1021 AS_IF([test "x$with_utempter" = xyes], [
1022   UL_CHECK_LIB([utempter], [utempter_add_record])
1023   AS_IF([test "x$have_utempter" = xno], [
1024     AC_MSG_ERROR([utempter selected but libutempter not found])
1025   ])
1026 ], [
1027   AM_CONDITIONAL([HAVE_UTEMPTER], [false])
1028 ])
1029
1030
1031 dnl
1032 dnl libuuid
1033 dnl
1034 AC_ARG_ENABLE([libuuid],
1035   AS_HELP_STRING([--disable-libuuid], [do not build libuuid and uuid utilities]),
1036   [], [UL_DEFAULT_ENABLE([libuuid], [yes])]
1037 )
1038 UL_BUILD_INIT([libuuid])
1039 AC_SUBST([LIBUUID_VERSION])
1040 AC_SUBST([LIBUUID_VERSION_INFO])
1041 AM_CONDITIONAL(BUILD_LIBUUID, test "x$build_libuuid" = xyes)
1042
1043 AC_ARG_ENABLE([libuuid-force-uuidd],
1044   AS_HELP_STRING([--enable-libuuid-force-uuidd], [support uuidd even though the daemon is not built]),
1045   [], [enable_libuuid_force_uuidd=no]
1046 )
1047
1048 AS_IF([test "x$build_libuuid" = xyes], [
1049   AC_DEFINE(HAVE_LIBUUID, 1, [Define to 1 if you have the -luuid.])
1050 ])
1051
1052 dnl
1053 dnl libblkid
1054 dnl
1055 AC_ARG_ENABLE([libblkid],
1056   AS_HELP_STRING([--disable-libblkid], [do not build libblkid and many related utilities]),
1057   [], [UL_DEFAULT_ENABLE([libblkid], [check])]
1058 )
1059 UL_BUILD_INIT([libblkid])
1060 UL_REQUIRES_HAVE([libblkid], [openat], [openat functions])
1061 AC_SUBST([LIBBLKID_DATE])
1062 AC_SUBST([LIBBLKID_VERSION])
1063 AC_SUBST([LIBBLKID_VERSION_INFO])
1064 AC_DEFINE_UNQUOTED([LIBBLKID_VERSION], ["$LIBBLKID_VERSION"], [libblkid version string])
1065 AC_DEFINE_UNQUOTED([LIBBLKID_DATE], ["$LIBBLKID_DATE"], [libblkid date string])
1066 AS_IF([test "x$build_libblkid" = xyes], [
1067   AC_DEFINE([HAVE_LIBBLKID], [1], [Define to 1 if you have the -lblkid.])
1068 ])
1069 AM_CONDITIONAL([BUILD_LIBBLKID], [test "x$build_libblkid" = xyes])
1070 AM_CONDITIONAL([BUILD_LIBBLKID_TESTS], [test "x$build_libblkid" = xyes -a "x$enable_static" = xyes])
1071
1072 dnl
1073 dnl libmount
1074 dnl
1075 AC_ARG_ENABLE([libmount],
1076   AS_HELP_STRING([--disable-libmount], [do not build libmount]),
1077   [], [UL_DEFAULT_ENABLE([libmount], [check])]
1078 )
1079 UL_BUILD_INIT([libmount])
1080 UL_REQUIRES_BUILD([libmount], [libblkid])
1081 UL_REQUIRES_HAVE([libmount], [scanf_alloc_modifier], [scanf string alloc modifier])
1082 AM_CONDITIONAL([BUILD_LIBMOUNT], [test "x$build_libmount" = xyes])
1083 AM_CONDITIONAL([BUILD_LIBMOUNT_TESTS], [test "x$build_libmount" = xyes -a "x$enable_static" = xyes])
1084 AS_IF([test "x$build_libmount" = xyes], [
1085         AC_DEFINE(HAVE_LIBMOUNT, 1, [Define if libmount available.])
1086 ])
1087
1088 AC_SUBST([LIBMOUNT_VERSION])
1089 AC_SUBST([LIBMOUNT_MAJOR_VERSION], $PACKAGE_VERSION_MAJOR)
1090 AC_SUBST([LIBMOUNT_MINOR_VERSION], $PACKAGE_VERSION_MINOR)
1091 AC_SUBST([LIBMOUNT_PATCH_VERSION], $PACKAGE_VERSION_RELEASE)
1092 AC_SUBST([LIBMOUNT_VERSION_INFO])
1093 AC_DEFINE_UNQUOTED([LIBMOUNT_VERSION], ["$LIBMOUNT_VERSION"], [libmount version string])
1094
1095 AC_ARG_ENABLE([libmount-support-mtab],
1096   AS_HELP_STRING([--enable-libmount-support-mtab], [support /etc/mtab (default is use /proc/self/mountinfo)]),
1097   [], [enable_libmount_support_mtab=no]
1098 )
1099
1100 AS_IF([test "x$enable_libmount_support_mtab" = xyes], [
1101   AC_DEFINE([USE_LIBMOUNT_SUPPORT_MTAB], [1], [Define to 1 if want to support mtab.])
1102 ])
1103
1104
1105 dnl
1106 dnl libsmartcols
1107 dnl
1108 AC_ARG_ENABLE([libsmartcols],
1109   AS_HELP_STRING([--disable-libsmartcols], [do not build libsmartcols]),
1110   [], [UL_DEFAULT_ENABLE([libsmartcols], [yes])]
1111 )
1112 UL_BUILD_INIT([libsmartcols])
1113 AM_CONDITIONAL([BUILD_LIBSMARTCOLS], [test "x$build_libsmartcols" = xyes])
1114
1115 AC_SUBST([LIBSMARTCOLS_VERSION])
1116 AC_SUBST([LIBSMARTCOLS_VERSION_INFO])
1117 AC_DEFINE_UNQUOTED([LIBSMARTCOLS_VERSION], ["$LIBSMARTCOLS_VERSION"], [libsmartcols version string])
1118
1119
1120 dnl
1121 dnl libfdisk
1122 dnl
1123 AC_ARG_ENABLE([libfdisk],
1124   AS_HELP_STRING([--disable-libfdisk], [do not build libfdisk]),
1125   [], [UL_DEFAULT_ENABLE([libfdisk], [check])]
1126 )
1127 UL_BUILD_INIT([libfdisk])
1128 UL_REQUIRES_BUILD([libfdisk], [libuuid])
1129 AM_CONDITIONAL([BUILD_LIBFDISK], [test "x$build_libfdisk" = xyes])
1130 AM_CONDITIONAL([BUILD_LIBFDISK_TESTS], [test "x$build_libfdisk" = xyes -a "x$enable_static" = xyes])
1131
1132 AS_IF([test "x$build_libblkid" = xyes],
1133   [LIBFDISK_PC_REQUIRES="uuid blkid"],[LIBFDISK_PC_REQUIRES="uuid"])
1134 AC_SUBST([LIBFDISK_PC_REQUIRES])
1135
1136 AC_SUBST([LIBFDISK_VERSION])
1137 AC_SUBST([LIBFDISK_MAJOR_VERSION], $PACKAGE_VERSION_MAJOR)
1138 AC_SUBST([LIBFDISK_MINOR_VERSION], $PACKAGE_VERSION_MINOR)
1139 AC_SUBST([LIBFDISK_PATCH_VERSION], $PACKAGE_VERSION_RELEASE)
1140 AC_SUBST([LIBFDISK_VERSION_INFO])
1141 AC_DEFINE_UNQUOTED([LIBFDISK_VERSION], ["$LIBFDISK_VERSION"], [libfdisk version string])
1142
1143
1144 UL_BUILD_INIT([fdisk], [check])
1145 UL_REQUIRES_HAVE([fdisk], [openat], [openat functions])
1146 UL_REQUIRES_BUILD([fdisk], [libfdisk])
1147 UL_REQUIRES_BUILD([fdisk], [libsmartcols])
1148 AM_CONDITIONAL([BUILD_FDISK], [test "x$build_fdisk" = xyes])
1149
1150
1151 UL_BUILD_INIT([sfdisk], [check])
1152 UL_REQUIRES_HAVE([sfdisk], [openat], [openat functions])
1153 UL_REQUIRES_BUILD([sfdisk], [libfdisk])
1154 UL_REQUIRES_BUILD([sfdisk], [libsmartcols])
1155 AM_CONDITIONAL([BUILD_SFDISK], [test "x$build_sfdisk" = xyes])
1156
1157
1158 UL_BUILD_INIT([cfdisk], [check])
1159 UL_REQUIRES_BUILD([cfdisk], [libfdisk])
1160 UL_REQUIRES_BUILD([cfdisk], [libsmartcols])
1161 UL_REQUIRES_HAVE([cfdisk], [open_memstream], [open_memstream function])
1162 UL_REQUIRES_HAVE([cfdisk], [ncursesw,slang,ncurses], [ncursesw, ncurses or slang library])
1163 AM_CONDITIONAL([BUILD_CFDISK], [test "x$build_cfdisk" = xyes])
1164
1165
1166 AC_ARG_ENABLE([mount],
1167   AS_HELP_STRING([--disable-mount], [do not build mount(8) and umount(8)]),
1168   [], [UL_DEFAULT_ENABLE([mount], [check])]
1169 )
1170 UL_BUILD_INIT([mount])
1171 UL_REQUIRES_LINUX([mount])
1172 UL_REQUIRES_BUILD([mount], [libmount])
1173 AM_CONDITIONAL([BUILD_MOUNT], [test "x$build_mount" = xyes])
1174
1175
1176 AC_ARG_ENABLE([losetup],
1177   AS_HELP_STRING([--disable-losetup], [do not build losetup]),
1178   [], [UL_DEFAULT_ENABLE([losetup], [check])]
1179 )
1180 UL_BUILD_INIT([losetup])
1181 UL_REQUIRES_LINUX([losetup])
1182 UL_REQUIRES_BUILD([losetup], [libsmartcols])
1183 AM_CONDITIONAL([BUILD_LOSETUP], [test "x$build_losetup" = xyes])
1184
1185 AC_ARG_ENABLE([zramctl],
1186   AS_HELP_STRING([--disable-zramctl], [do not build zramctl]),
1187   [], [UL_DEFAULT_ENABLE([zramctl], [check])]
1188 )
1189 UL_BUILD_INIT([zramctl])
1190 UL_REQUIRES_LINUX([zramctl])
1191 UL_REQUIRES_BUILD([zramctl], [libsmartcols])
1192 AM_CONDITIONAL([BUILD_ZRAMCTL], [test "x$build_zramctl" = xyes])
1193
1194 AC_ARG_ENABLE([fsck],
1195   AS_HELP_STRING([--disable-fsck], [do not build fsck]),
1196   [], [UL_DEFAULT_ENABLE([fsck], [check])]
1197 )
1198 UL_BUILD_INIT([fsck])
1199 UL_REQUIRES_BUILD([fsck], [libmount])
1200 AM_CONDITIONAL([BUILD_FSCK], [test "x$build_fsck" = xyes])
1201
1202
1203 AC_ARG_ENABLE([partx],
1204   AS_HELP_STRING([--disable-partx], [do not build addpart, delpart, partx]),
1205   [], [UL_DEFAULT_ENABLE([partx], [check])]
1206 )
1207 UL_BUILD_INIT([partx])
1208 UL_REQUIRES_LINUX([partx])
1209 UL_REQUIRES_BUILD([partx], [libblkid])
1210 UL_REQUIRES_BUILD([partx], [libsmartcols])
1211 AM_CONDITIONAL([BUILD_PARTX], [test "x$build_partx" = xyes])
1212
1213
1214 AC_ARG_ENABLE([uuidd],
1215   AS_HELP_STRING([--disable-uuidd], [do not build the uuid daemon]),
1216   [], [UL_DEFAULT_ENABLE([uuidd], [check])]
1217 )
1218 UL_BUILD_INIT([uuidd])
1219 UL_REQUIRES_BUILD([uuidd], [libuuid])
1220 UL_REQUIRES_HAVE([uuidd], [timer], [timer_create function])
1221 UL_REQUIRES_HAVE([uuidd], [sys_signalfd_h], [sys/signalfd.h header])
1222 AS_IF([test "x$build_uuidd" = xyes || test "x$enable_libuuid_force_uuidd" = xyes], [
1223   AC_DEFINE([HAVE_UUIDD], [1], [Define to 1 if you want to use uuid daemon.])
1224 ])
1225 AM_CONDITIONAL([BUILD_UUIDD], [test "x$build_uuidd" = xyes])
1226
1227
1228 UL_BUILD_INIT([uuidgen], [check])
1229 UL_REQUIRES_BUILD([uuidgen], [libuuid])
1230 AM_CONDITIONAL([BUILD_UUIDGEN], [test "x$build_uuidgen" = xyes])
1231
1232 UL_BUILD_INIT([uuidparse], [check])
1233 UL_REQUIRES_BUILD([uuidparse], [libuuid])
1234 UL_REQUIRES_BUILD([uuidparse], [libsmartcols])
1235 AM_CONDITIONAL([BUILD_UUIDPARSE], [test "x$build_uuidparse" = xyes])
1236
1237 UL_BUILD_INIT([blkid], [check])
1238 UL_REQUIRES_BUILD([blkid], [libblkid])
1239 AM_CONDITIONAL([BUILD_BLKID], [test "x$build_blkid" = xyes])
1240
1241 UL_BUILD_INIT([findfs], [check])
1242 UL_REQUIRES_BUILD([findfs], [libblkid])
1243 AM_CONDITIONAL([BUILD_FINDFS], [test "x$build_findfs" = xyes])
1244
1245 UL_BUILD_INIT([wipefs], [check])
1246 UL_REQUIRES_BUILD([wipefs], [libblkid])
1247 UL_REQUIRES_BUILD([wipefs], [libsmartcols])
1248 AM_CONDITIONAL([BUILD_WIPEFS], [test "x$build_wipefs" = xyes])
1249
1250 UL_BUILD_INIT([findmnt], [check])
1251 UL_REQUIRES_BUILD([findmnt], [libmount])
1252 UL_REQUIRES_BUILD([findmnt], [libblkid])
1253 UL_REQUIRES_BUILD([findmnt], [libsmartcols])
1254 AM_CONDITIONAL([BUILD_FINDMNT], [test "x$build_findmnt" = xyes])
1255
1256
1257 AC_ARG_ENABLE([mountpoint],
1258   AS_HELP_STRING([--disable-mountpoint], [do not build mountpoint]),
1259   [], [UL_DEFAULT_ENABLE([mountpoint], [check])]
1260 )
1261 UL_BUILD_INIT([mountpoint])
1262 UL_REQUIRES_BUILD([mountpoint], [libmount])
1263 AM_CONDITIONAL([BUILD_MOUNTPOINT], [test "x$build_mountpoint" = xyes])
1264
1265
1266 AC_ARG_ENABLE([fallocate],
1267   AS_HELP_STRING([--disable-fallocate], [do not build fallocate]),
1268   [], [UL_DEFAULT_ENABLE([fallocate], [check])]
1269 )
1270 UL_BUILD_INIT([fallocate])
1271 UL_REQUIRES_LINUX([fallocate])
1272 UL_REQUIRES_SYSCALL_CHECK([fallocate], [UL_CHECK_SYSCALL([fallocate])])
1273 AM_CONDITIONAL([BUILD_FALLOCATE], [test "x$build_fallocate" = xyes])
1274
1275 AS_IF([test "x$build_fallocate" = xyes], [
1276   dnl check for valid fallocate() function
1277   dnl with 32 bits glibc 2.10, fallocate() exists but not fallocate64()
1278   dnl when _FILE_OFFSET_BITS==64, fallocate() is redirect to fallocate64()
1279   dnl and program can't be linked.
1280   dnl AC_CHECK_FUNC can't catch such errors since it's redefining
1281   dnl function prototype.
1282   AC_MSG_CHECKING([for valid fallocate() function])
1283   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1284 #ifdef HAVE_UNISTD_H
1285 # include <unistd.h>
1286 #endif
1287 #ifdef HAVE_SYS_TYPES_H
1288 # include <sys/types.h>
1289 #endif
1290 #ifdef HAVE_LINUX_FALLOC_H
1291 # include <linux/falloc.h>
1292 #endif
1293 #ifdef HAVE_FCNTL_H
1294 # include <fcntl.h>
1295 #endif
1296 ]],[[
1297    long ret;
1298    ret = fallocate(0, FALLOC_FL_KEEP_SIZE, 0xfffffffful, 0xfffffffful);
1299    if (ret != 0) {
1300       return 1;
1301    }
1302    ]])],[
1303   AC_MSG_RESULT([yes])
1304   AC_DEFINE([HAVE_FALLOCATE], [1], [Have valid fallocate() function])],[
1305   AC_MSG_RESULT([no])])
1306 ])
1307
1308 AS_IF([test "x$build_fallocate" = xyes], [
1309   dnl check for valid posix_fallocate() function
1310   AC_MSG_CHECKING([for valid posix_fallocate() function])
1311   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1312 #ifdef HAVE_UNISTD_H
1313 # include <unistd.h>
1314 #endif
1315 #ifdef HAVE_SYS_TYPES_H
1316 # include <sys/types.h>
1317 #endif
1318 #ifdef HAVE_LINUX_FALLOC_H
1319 # include <linux/falloc.h>
1320 #endif
1321 #ifdef HAVE_FCNTL_H
1322 # include <fcntl.h>
1323 #endif
1324 ]],[[
1325    long ret;
1326    ret = posix_fallocate(0, 0xfffffffful, 0xfffffffful);
1327    if (ret != 0) {
1328       return 1;
1329    }
1330    ]])],[
1331   AC_MSG_RESULT([yes])
1332   AC_DEFINE([HAVE_POSIX_FALLOCATE], [1], [Have valid posix_fallocate() function])],[
1333   AC_MSG_RESULT([no])])
1334 ])
1335
1336
1337 AC_ARG_ENABLE([unshare],
1338   AS_HELP_STRING([--disable-unshare], [do not build unshare]),
1339   [], [UL_DEFAULT_ENABLE([unshare], [check])]
1340 )
1341 UL_BUILD_INIT([unshare])
1342 UL_REQUIRES_LINUX([unshare])
1343 UL_REQUIRES_SYSCALL_CHECK([unshare], [UL_CHECK_SYSCALL([unshare])])
1344 AM_CONDITIONAL([BUILD_UNSHARE], [test "x$build_unshare" = xyes])
1345 AC_CHECK_FUNCS([unshare])
1346
1347 AC_ARG_ENABLE([nsenter],
1348   AS_HELP_STRING([--disable-nsenter], [do not build nsenter]),
1349   [], [UL_DEFAULT_ENABLE([nsenter], [check])]
1350 )
1351 UL_BUILD_INIT([nsenter])
1352 UL_REQUIRES_LINUX([nsenter])
1353 UL_REQUIRES_SYSCALL_CHECK([nsenter], [UL_CHECK_SYSCALL([setns])], [setns])
1354 AM_CONDITIONAL([BUILD_NSENTER], [test "x$build_nsenter" = xyes])
1355 AC_CHECK_FUNCS([setns])
1356
1357
1358 AC_ARG_WITH([cap_ng],
1359   AS_HELP_STRING([--without-cap-ng], [compile without libcap-ng]),
1360   [], [with_cap_ng=auto]
1361 )
1362 AS_IF([test "x$with_cap_ng" = xno], [
1363   AM_CONDITIONAL([HAVE_CAP_NG], [false])
1364   have_cap_ng=no
1365 ],[
1366   UL_CHECK_LIB([cap-ng], [capng_apply], [cap_ng])
1367 ])
1368
1369
1370 AC_ARG_ENABLE([setpriv],
1371   AS_HELP_STRING([--disable-setpriv], [do not build setpriv]),
1372   [], [UL_DEFAULT_ENABLE([setpriv], [check])]
1373 )
1374 UL_BUILD_INIT([setpriv])
1375 UL_REQUIRES_LINUX([setpriv])
1376 UL_REQUIRES_HAVE([setpriv], [linux_securebits_h], [securebits.h header file])
1377 UL_REQUIRES_HAVE([setpriv], [cap_ng], [libcap-ng library])
1378 AM_CONDITIONAL([BUILD_SETPRIV], [test "x$build_setpriv" = xyes])
1379
1380
1381 AC_ARG_ENABLE([eject],
1382   AS_HELP_STRING([--disable-eject], [do not build eject]),
1383   [], [UL_DEFAULT_ENABLE([eject], [check])]
1384 )
1385 UL_BUILD_INIT([eject])
1386 UL_REQUIRES_LINUX([eject])
1387 UL_REQUIRES_BUILD([eject], [libmount])
1388 AM_CONDITIONAL([BUILD_EJECT], [test "x$build_eject" = xyes])
1389
1390
1391 AC_ARG_ENABLE([agetty],
1392   AS_HELP_STRING([--disable-agetty], [do not build agetty]),
1393   [], [UL_DEFAULT_ENABLE([agetty], [check])]
1394 )
1395 UL_BUILD_INIT([agetty])
1396 UL_REQUIRES_HAVE([agetty], [utmpx_h], [utmpx.h header])
1397 UL_REQUIRES_HAVE([agetty], [gnu_utmpx], [GNU utmpx functions])
1398 AM_CONDITIONAL([BUILD_AGETTY], [test "x$build_agetty" = xyes])
1399 AS_IF([test "x$have_futimens" = xyes -a "x$have_inotify_init1" = xyes ], [
1400   AC_DEFINE([AGETTY_RELOAD], [1], [Enable agetty --reload feature])
1401 ],[
1402   AC_MSG_WARN([futimens or inotify_init1 not found; agetty(8) will not provide ---reload functionality])
1403 ])
1404
1405
1406 AC_ARG_ENABLE([plymouth_support],
1407   AS_HELP_STRING([--disable-plymouth_support], [don not care about plymouth in sylogin(8) and agetty(8)]),
1408   [], [enable_plymouth_support=check]
1409 )
1410 UL_BUILD_INIT([plymouth_support])
1411 UL_REQUIRES_HAVE([plymouth_support], [tiocglcktrmios], [TIOCGLCKTRMIOS flag])
1412 UL_REQUIRES_HAVE([plymouth_support], [sock_cloexec], [SOCK_CLOEXEC flag])
1413 UL_REQUIRES_HAVE([plymouth_support], [sock_nonblock], [SOCK_NONBLOCK flag])
1414 UL_REQUIRES_HAVE([plymouth_support], [so_passcred], [SO_PASSCRED flag])
1415 AM_CONDITIONAL([USE_PLYMOUTH_SUPPORT], [test "x$build_plymouth_support" = xyes])
1416 AS_IF([test "x$build_plymouth_support" = xyes ], [
1417     AC_DEFINE([USE_PLYMOUTH_SUPPORT], [1], [Enable plymouth support feature for sulogin and aggety])
1418 ])
1419
1420
1421 AC_ARG_WITH([libz],
1422   AS_HELP_STRING([--without-libz], [compile without libz]),
1423   [], [with_libz=auto]
1424 )
1425 AS_IF([test "x$with_libz" = xno], [have_z=no], [
1426   AC_CHECK_LIB([z], [crc32], [have_z=yes], [have_z=no])
1427 ])
1428
1429
1430 AC_ARG_ENABLE([cramfs],
1431   AS_HELP_STRING([--disable-cramfs], [do not build fsck.cramfs, mkfs.cramfs]),
1432   [], [UL_DEFAULT_ENABLE([cramfs], [check])]
1433 )
1434 UL_BUILD_INIT([cramfs])
1435 UL_REQUIRES_HAVE([cramfs], [z], [z library])
1436 AM_CONDITIONAL([BUILD_CRAMFS], [test "x$build_cramfs" = xyes])
1437
1438
1439 AC_ARG_ENABLE([bfs],
1440   AS_HELP_STRING([--disable-bfs], [do not build mkfs.bfs]),
1441   [], [UL_DEFAULT_ENABLE([bfs], [yes])]
1442 )
1443 UL_BUILD_INIT([bfs])
1444 AM_CONDITIONAL([BUILD_BFS], [test "x$build_bfs" = xyes])
1445
1446
1447 AC_ARG_ENABLE([minix],
1448   AS_HELP_STRING([--disable-minix], [do not build fsck.minix, mkfs.minix]),
1449   [], [UL_DEFAULT_ENABLE([minix], [yes])]
1450 )
1451 UL_BUILD_INIT([minix])
1452 AM_CONDITIONAL([BUILD_MINIX], [test "x$build_minix" = xyes])
1453
1454
1455 AC_ARG_ENABLE([fdformat],
1456   AS_HELP_STRING([--disable-fdformat], [do not build fdformat]),
1457   [], [UL_DEFAULT_ENABLE([fdformat], [check])]
1458 )
1459 UL_BUILD_INIT([fdformat])
1460 UL_REQUIRES_LINUX([fdformat])
1461 AM_CONDITIONAL([BUILD_FDFORMAT], [test "x$build_fdformat" = xyes])
1462
1463
1464 AC_ARG_ENABLE([hwclock],
1465   AS_HELP_STRING([--disable-hwclock], [do not build hwclock]),
1466   [], [UL_DEFAULT_ENABLE([hwclock], [check])]
1467 )
1468 have_linuxdummy=$linux_os
1469
1470 UL_BUILD_INIT([hwclock])
1471 UL_REQUIRES_HAVE([hwclock], [io, linuxdummy], [ioperm iopl function or Linux])
1472 AM_CONDITIONAL([BUILD_HWCLOCK], [test "x$build_hwclock" = xyes])
1473
1474
1475 UL_BUILD_INIT([mkfs], [yes])
1476 AM_CONDITIONAL([BUILD_MKFS], [test "x$build_mkfs" = xyes])
1477
1478 UL_BUILD_INIT([isosize], [yes])
1479 AM_CONDITIONAL([BUILD_ISOSIZE], [test "x$build_isosize" = xyes])
1480
1481
1482 UL_BUILD_INIT([fstrim], [check])
1483 UL_REQUIRES_LINUX([fstrim])
1484 UL_REQUIRES_BUILD([fstrim], [libmount])
1485 AM_CONDITIONAL([BUILD_FSTRIM], [test "x$build_fstrim" = xyes])
1486
1487
1488 UL_BUILD_INIT([swapon], [check])
1489 UL_REQUIRES_LINUX([swapon])
1490 UL_REQUIRES_SYSCALL_CHECK([swapon], [UL_CHECK_SYSCALL([swapon])], [swapon])
1491 UL_REQUIRES_SYSCALL_CHECK([swapon], [UL_CHECK_SYSCALL([swapoff])], [swapoff])
1492 UL_REQUIRES_BUILD([swapon], [libblkid])
1493 UL_REQUIRES_BUILD([swapon], [libmount])
1494 UL_REQUIRES_BUILD([swapon], [libsmartcols])
1495 AM_CONDITIONAL([BUILD_SWAPON], [test "x$build_swapon" = xyes])
1496 AC_CHECK_FUNCS([swapon])
1497 AC_CHECK_FUNCS([swapoff])
1498
1499
1500 UL_BUILD_INIT([lsblk], [check])
1501 UL_REQUIRES_LINUX([lsblk])
1502 UL_REQUIRES_BUILD([lsblk], [libblkid])
1503 UL_REQUIRES_BUILD([lsblk], [libmount])
1504 UL_REQUIRES_BUILD([lsblk], [libsmartcols])
1505 AM_CONDITIONAL([BUILD_LSBLK], [test "x$build_lsblk" = xyes])
1506
1507
1508 UL_BUILD_INIT([lscpu], [check])
1509 UL_REQUIRES_LINUX([lscpu])
1510 UL_REQUIRES_BUILD([lscpu], [libsmartcols])
1511 UL_REQUIRES_HAVE([lscpu], [cpu_set_t], [cpu_set_t type])
1512 AM_CONDITIONAL([BUILD_LSCPU], [test "x$build_lscpu" = xyes])
1513
1514
1515 AC_ARG_ENABLE([lslogins],
1516   AS_HELP_STRING([--disable-lslogins], [do not build lslogins]),
1517   [], [UL_DEFAULT_ENABLE([lslogins], [check])]
1518 )
1519 UL_BUILD_INIT([lslogins])
1520 UL_REQUIRES_BUILD([lslogins], [libsmartcols])
1521 UL_REQUIRES_HAVE([lslogins], [shadow_h], [shadow.h header])
1522 UL_REQUIRES_HAVE([lslogins], [utmpx_h], [utmpx.h header])
1523 UL_REQUIRES_HAVE([lslogins], [gnu_utmpx], [GNU utmpx functions])
1524 AM_CONDITIONAL([BUILD_LSLOGINS], [test "x$build_lslogins" = xyes])
1525
1526
1527 UL_BUILD_INIT([chcpu], [check])
1528 UL_REQUIRES_LINUX([chcpu])
1529 UL_REQUIRES_HAVE([chcpu], [cpu_set_t], [cpu_set_t type])
1530 AM_CONDITIONAL([BUILD_CHCPU], [test "x$build_chcpu" = xyes])
1531
1532
1533 AC_ARG_ENABLE([wdctl],
1534   AS_HELP_STRING([--disable-wdctl], [do not build wdctl]),
1535   [], [UL_DEFAULT_ENABLE([wdctl], [check])]
1536 )
1537 UL_BUILD_INIT([wdctl])
1538 UL_REQUIRES_LINUX([wdctl])
1539 UL_REQUIRES_BUILD([wdctl], [libsmartcols])
1540 UL_REQUIRES_HAVE([wdctl], [linux_watchdog_h], [linux/watchdog.h header file])
1541 AM_CONDITIONAL([BUILD_WDCTL], [test "x$build_wdctl" = xyes])
1542
1543
1544 UL_BUILD_INIT([swaplabel], [check])
1545 UL_REQUIRES_BUILD([swaplabel], [libblkid])
1546 AM_CONDITIONAL([BUILD_SWAPLABEL], [test "x$build_swaplabel" = xyes])
1547
1548
1549 UL_BUILD_INIT([mkswap], [yes])
1550 AM_CONDITIONAL([BUILD_MKSWAP], [test "x$build_mkswap" = xyes])
1551 AS_IF([test "x$build_mkswap" = xyes -a "x$build_libuuid" != xyes], [
1552   AC_MSG_WARN([uuid library is not found; mkswap(8) will not generate UUIDs])
1553 ])
1554
1555
1556 AC_ARG_ENABLE([cal],
1557   AS_HELP_STRING([--disable-cal], [do not build cal]),
1558   [], [UL_DEFAULT_ENABLE([cal], [check])]
1559 )
1560 UL_BUILD_INIT([cal])
1561 AM_CONDITIONAL([BUILD_CAL], [test "x$build_cal" = xyes])
1562
1563 AC_ARG_ENABLE([logger],
1564   AS_HELP_STRING([--disable-logger], [do not build logger]),
1565   [], [UL_DEFAULT_ENABLE([logger], [check])]
1566 )
1567 UL_BUILD_INIT([logger])
1568 AM_CONDITIONAL([BUILD_LOGGER], [test "x$build_logger" = xyes])
1569
1570 UL_BUILD_INIT([look], [yes])
1571 AM_CONDITIONAL([BUILD_LOOK], [test "x$build_look" = xyes])
1572
1573 UL_BUILD_INIT([mcookie], [yes])
1574 AM_CONDITIONAL([BUILD_MCOOKIE], [test "x$build_mcookie" = xyes])
1575
1576 UL_BUILD_INIT([namei], [yes])
1577 AM_CONDITIONAL([BUILD_NAMEI], [test "x$build_namei" = xyes])
1578
1579 matriplet="$($CC -print-multiarch 2>/dev/null || true)"
1580 if test "x$matriplet" != "x"; then
1581   AC_DEFINE_UNQUOTED([MULTIARCHTRIPLET], ["$matriplet"],
1582   ["Multi-arch triplet for whereis library search path"])
1583 fi
1584 UL_BUILD_INIT([whereis], [yes])
1585 AM_CONDITIONAL([BUILD_WHEREIS], [test "x$build_whereis" = xyes])
1586
1587 UL_BUILD_INIT([getopt], [yes])
1588 AM_CONDITIONAL([BUILD_GETOPT], [test "x$build_getopt" = xyes])
1589
1590
1591 UL_BUILD_INIT([blockdev], [check])
1592 UL_REQUIRES_LINUX([blockdev])
1593 AM_CONDITIONAL([BUILD_BLOCKDEV], [test "x$build_blockdev" = xyes])
1594
1595
1596 UL_BUILD_INIT([prlimit], [check])
1597 UL_REQUIRES_LINUX([prlimit])
1598 UL_REQUIRES_BUILD([prlimit], [libsmartcols])
1599 UL_REQUIRES_SYSCALL_CHECK([prlimit], [UL_CHECK_SYSCALL([prlimit64])], [prlimit64])
1600 AM_CONDITIONAL([BUILD_PRLIMIT], [test "x$build_prlimit" = xyes])
1601 AS_IF([test "x$build_prlimit" = xyes], [
1602   AC_CHECK_FUNCS([prlimit])
1603 ])
1604
1605
1606 UL_BUILD_INIT([lslocks], [check])
1607 UL_REQUIRES_LINUX([lslocks])
1608 UL_REQUIRES_BUILD([lslocks], [libmount])
1609 UL_REQUIRES_BUILD([lslocks], [libsmartcols])
1610 AM_CONDITIONAL([BUILD_LSLOCKS], [test "x$build_lslocks" = xyes])
1611
1612
1613 AC_ARG_ENABLE([switch_root],
1614   AS_HELP_STRING([--disable-switch_root], [do not build switch_root]),
1615   [], [UL_DEFAULT_ENABLE([switch_root], [check])]
1616 )
1617 UL_BUILD_INIT([switch_root])
1618 UL_REQUIRES_LINUX([switch_root])
1619 UL_REQUIRES_HAVE([switch_root], [openat], [openat function])
1620 AM_CONDITIONAL([BUILD_SWITCH_ROOT], [test "x$build_switch_root" = xyes])
1621
1622
1623 AC_ARG_ENABLE([pivot_root],
1624   AS_HELP_STRING([--disable-pivot_root], [do not build pivot_root]),
1625   [], [UL_DEFAULT_ENABLE([pivot_root], [check])]
1626 )
1627 UL_BUILD_INIT([pivot_root])
1628 UL_REQUIRES_LINUX([pivot_root])
1629 UL_REQUIRES_SYSCALL_CHECK([pivot_root], [UL_CHECK_SYSCALL([pivot_root])])
1630 AM_CONDITIONAL([BUILD_PIVOT_ROOT], [test "x$build_pivot_root" = xyes])
1631
1632
1633 UL_BUILD_INIT([flock], [check])
1634 UL_REQUIRES_HAVE([flock], [timer], [timer_create function])
1635 AM_CONDITIONAL([BUILD_FLOCK], [test "x$build_flock" = xyes])
1636
1637
1638 AC_ARG_ENABLE([lsmem],
1639   AS_HELP_STRING([--disable-lsmem], [do not build lsmem]),
1640   [], [UL_DEFAULT_ENABLE([lsmem], [check])]
1641 )
1642 UL_BUILD_INIT([lsmem])
1643 UL_REQUIRES_LINUX([lsmem])
1644 UL_REQUIRES_BUILD([lsmem], [libsmartcols])
1645 AM_CONDITIONAL([BUILD_LSMEM], [test "x$build_lsmem" = xyes])
1646
1647
1648 AC_ARG_ENABLE([chmem],
1649   AS_HELP_STRING([--disable-chmem], [do not build chmem]),
1650   [], [UL_DEFAULT_ENABLE([chmem], [check])]
1651 )
1652 UL_BUILD_INIT([chmem])
1653 UL_REQUIRES_LINUX([chmem])
1654 AM_CONDITIONAL([BUILD_CHMEM], [test "x$build_chmem" = xyes])
1655
1656 UL_BUILD_INIT([ipcmk], [yes])
1657 AM_CONDITIONAL([BUILD_IPCMK], [test "x$build_ipcmk" = xyes])
1658
1659
1660 AC_ARG_ENABLE([ipcrm],
1661   AS_HELP_STRING([--disable-ipcrm], [do not build ipcrm]),
1662   [], [UL_DEFAULT_ENABLE([ipcrm], [yes])]
1663 )
1664 UL_BUILD_INIT([ipcrm])
1665 AM_CONDITIONAL([BUILD_IPCRM], [test "x$build_ipcrm" = xyes])
1666
1667 AC_ARG_ENABLE([ipcs],
1668   AS_HELP_STRING([--disable-ipcs], [do not build ipcs]),
1669   [], [UL_DEFAULT_ENABLE([ipcs], [yes])]
1670 )
1671 UL_BUILD_INIT([ipcs])
1672 AM_CONDITIONAL([BUILD_IPCS], [test "x$build_ipcs" = xyes])
1673
1674 UL_BUILD_INIT([choom], [check])
1675 UL_REQUIRES_LINUX([choom])
1676 AM_CONDITIONAL([BUILD_CHOOM], [test "x$build_choom" = xyes])
1677
1678 UL_BUILD_INIT([lsipc], [check])
1679 UL_REQUIRES_LINUX([lsipc])
1680 UL_REQUIRES_BUILD([lsipc], [libsmartcols])
1681 AM_CONDITIONAL([BUILD_LSIPC], [test "x$build_lsipc" = xyes])
1682
1683 UL_BUILD_INIT([lsns], [check])
1684 UL_REQUIRES_LINUX([lsns])
1685 UL_REQUIRES_BUILD([lsns], [libsmartcols])
1686 UL_REQUIRES_BUILD([lsns], [libmount])
1687 AM_CONDITIONAL([BUILD_LSNS], [test "x$build_lsns" = xyes])
1688
1689 UL_BUILD_INIT([renice], [yes])
1690 AM_CONDITIONAL([BUILD_RENICE], [test "x$build_renice" = xyes])
1691
1692
1693 AC_ARG_ENABLE([rfkill],
1694   AS_HELP_STRING([--disable-rfkill], [do not build rfkill]),
1695   [], [UL_DEFAULT_ENABLE([rfkill], [check])]
1696 )
1697 UL_BUILD_INIT([rfkill])
1698 UL_REQUIRES_LINUX([rfkill])
1699 UL_REQUIRES_BUILD([rfkill], [libsmartcols])
1700 AM_CONDITIONAL([BUILD_RFKILL], [test "x$build_rfkill" = xyes])
1701
1702
1703 UL_BUILD_INIT([setsid], [yes])
1704 AM_CONDITIONAL([BUILD_SETSID], [test "x$build_setsid" = xyes])
1705
1706 UL_BUILD_INIT([readprofile], [check])
1707 UL_REQUIRES_LINUX([readprofile])
1708 AM_CONDITIONAL([BUILD_READPROFILE], [test "x$build_readprofile" = xyes])
1709
1710 UL_BUILD_INIT([dmesg], [check])
1711 UL_REQUIRES_LINUX([dmesg])
1712 AM_CONDITIONAL([BUILD_DMESG], [test "x$build_dmesg" = xyes])
1713
1714 UL_BUILD_INIT([ctrlaltdel], [check])
1715 UL_REQUIRES_LINUX([ctrlaltdel])
1716 dnl we assume reboot() to be the 1-argument variant, because even considering
1717 dnl widely used alternative C libraries like uclibc, dietlibc and musl,
1718 dnl reboot() with multiple arguments is yet only found in glibc versions
1719 dnl earlier than 2.x.
1720 UL_REQUIRES_HAVE([ctrlaltdel], [reboot], [reboot function])
1721 AM_CONDITIONAL([BUILD_CTRLALTDEL], [test "x$build_ctrlaltdel" = xyes])
1722
1723 UL_BUILD_INIT([fincore], [check])
1724 UL_REQUIRES_LINUX([fincore])
1725 UL_REQUIRES_BUILD([fincore], [libsmartcols])
1726 AM_CONDITIONAL([BUILD_FINCORE], [test "x$build_fincore" = xyes])
1727
1728 UL_BUILD_INIT([fsfreeze], [check])
1729 UL_REQUIRES_LINUX([fsfreeze])
1730 AM_CONDITIONAL([BUILD_FSFREEZE], [test "x$build_fsfreeze" = xyes])
1731
1732 UL_BUILD_INIT([blkdiscard], [check])
1733 UL_REQUIRES_LINUX([blkdiscard])
1734 AM_CONDITIONAL([BUILD_BLKDISCARD], [test "x$build_blkdiscard" = xyes])
1735
1736 UL_BUILD_INIT([blkzone], [check])
1737 UL_REQUIRES_LINUX([blkzone])
1738 UL_REQUIRES_HAVE([blkzone], [linux_blkzoned_h], [linux/blkzoned.h header])
1739 AM_CONDITIONAL([BUILD_BLKZONE], [test "x$build_blkzone" = xyes])
1740
1741 UL_BUILD_INIT([ldattach], [check])
1742 UL_REQUIRES_LINUX([ldattach])
1743 AM_CONDITIONAL([BUILD_LDATTACH], [test "x$build_ldattach" = xyes])
1744
1745 UL_BUILD_INIT([rtcwake], [check])
1746 UL_REQUIRES_LINUX([rtcwake])
1747 AM_CONDITIONAL([BUILD_RTCWAKE], [test "x$build_rtcwake" = xyes])
1748
1749 UL_BUILD_INIT([setarch], [check])
1750 UL_REQUIRES_LINUX([setarch])
1751 AM_CONDITIONAL([BUILD_SETARCH], [test "x$build_setarch" = xyes])
1752
1753 UL_BUILD_INIT([script], [check])
1754 UL_REQUIRES_HAVE([script], [sys_signalfd_h], [sys/signalfd.h header])
1755 AM_CONDITIONAL([BUILD_SCRIPT], [test "x$build_script" = xyes])
1756
1757 UL_BUILD_INIT([scriptreplay], [yes])
1758 AM_CONDITIONAL([BUILD_SCRIPTREPLAY], [test "x$build_scriptreplay" = xyes])
1759
1760 UL_BUILD_INIT([col], [yes])
1761 AM_CONDITIONAL([BUILD_COL], [test "x$build_col" = xyes])
1762
1763 UL_BUILD_INIT([colcrt], [yes])
1764 AM_CONDITIONAL([BUILD_COLCRT], [test "x$build_colcrt" = xyes])
1765
1766 UL_BUILD_INIT([colrm], [yes])
1767 AM_CONDITIONAL([BUILD_COLRM], [test "x$build_colrm" = xyes])
1768
1769 UL_BUILD_INIT([column], [check])
1770 UL_REQUIRES_BUILD([column], [libsmartcols])
1771 AM_CONDITIONAL([BUILD_COLUMN], [test "x$build_column" = xyes])
1772
1773 UL_BUILD_INIT([hexdump], [yes])
1774 AM_CONDITIONAL([BUILD_HEXDUMP], [test "x$build_hexdump" = xyes])
1775
1776 UL_BUILD_INIT([rev], [yes])
1777 AM_CONDITIONAL([BUILD_REV], [test "x$build_rev" = xyes])
1778
1779
1780 AC_ARG_ENABLE([tunelp],
1781   AS_HELP_STRING([--enable-tunelp], [build tunelp]),
1782   [], [UL_DEFAULT_ENABLE([tunelp], [no])]
1783 )
1784 UL_BUILD_INIT([tunelp])
1785 UL_REQUIRES_LINUX([tunelp])
1786 AM_CONDITIONAL([BUILD_TUNELP], [test "x$build_tunelp" = xyes])
1787
1788
1789 AC_ARG_ENABLE([kill],
1790   AS_HELP_STRING([--disable-kill], [do not build kill]),
1791   [], [UL_DEFAULT_ENABLE([kill], [check])]
1792 )
1793 UL_BUILD_INIT([kill])
1794 UL_REQUIRES_LINUX([kill])
1795 AM_CONDITIONAL([BUILD_KILL], [test "x$build_kill" = xyes])
1796
1797
1798 AC_ARG_ENABLE([last],
1799   AS_HELP_STRING([--disable-last], [do not build last]),
1800   [], [UL_DEFAULT_ENABLE([last], [check])]
1801 )
1802 UL_BUILD_INIT([last])
1803 UL_REQUIRES_HAVE([last], [utmpx_h], [utmpx.h header])
1804 UL_REQUIRES_HAVE([last], [gnu_utmpx], [GNU utmpx functions])
1805 AM_CONDITIONAL([BUILD_LAST], [test "x$build_last" = xyes])
1806
1807
1808 AC_ARG_ENABLE([utmpdump],
1809   AS_HELP_STRING([--disable-utmpdump], [do not build utmpdump]),
1810   [], [UL_DEFAULT_ENABLE([utmpdump], [check])]
1811 )
1812 UL_BUILD_INIT([utmpdump])
1813 UL_REQUIRES_HAVE([utmpdump], [utmpx_h], [utmpx.h header])
1814 UL_REQUIRES_HAVE([utmpdump], [gnu_utmpx], [GNU utmpx functions])
1815 AM_CONDITIONAL([BUILD_UTMPDUMP], [test "x$build_utmpdump" = xyes])
1816
1817
1818 AC_ARG_ENABLE([line],
1819   AS_HELP_STRING([--enable-line], [build line]),
1820   [], [UL_DEFAULT_ENABLE([line], [no])]
1821 )
1822 UL_BUILD_INIT([line])
1823 AM_CONDITIONAL([BUILD_LINE], [test "x$build_line" = xyes])
1824
1825
1826 AC_ARG_ENABLE([mesg],
1827   AS_HELP_STRING([--disable-mesg], [do not build mesg]),
1828   [], [UL_DEFAULT_ENABLE([mesg], [yes])]
1829 )
1830 UL_BUILD_INIT([mesg])
1831 AM_CONDITIONAL([BUILD_MESG], [test "x$build_mesg" = xyes])
1832
1833
1834 AC_ARG_ENABLE([raw],
1835   AS_HELP_STRING([--disable-raw], [do not build raw]),
1836   [], [UL_DEFAULT_ENABLE([raw], [check])]
1837 )
1838 UL_BUILD_INIT([raw])
1839 UL_REQUIRES_LINUX([raw])
1840 UL_REQUIRES_HAVE([raw], [linux_raw_h], [raw.h header file])
1841 AM_CONDITIONAL([BUILD_RAW], [test "x$build_raw" = xyes])
1842
1843
1844 AC_ARG_ENABLE([rename],
1845   AS_HELP_STRING([--disable-rename], [do not build rename]),
1846   [], [UL_DEFAULT_ENABLE([rename], [yes])]
1847 )
1848 UL_BUILD_INIT([rename])
1849 AM_CONDITIONAL([BUILD_RENAME], [test "x$build_rename" = xyes])
1850
1851
1852 AC_ARG_ENABLE([vipw],
1853   AS_HELP_STRING([--enable-vipw], [build vipw]),
1854   [], [UL_DEFAULT_ENABLE([vipw], [no])]
1855 )
1856 UL_BUILD_INIT([vipw])
1857 UL_REQUIRES_HAVE([vipw], [shadow_h], [shadow.h header])
1858 AM_CONDITIONAL([BUILD_VIPW], [test "x$build_vipw" = xyes])
1859
1860
1861 AC_ARG_ENABLE([newgrp],
1862   AS_HELP_STRING([--enable-newgrp], [build newgrp]),
1863   [], [UL_DEFAULT_ENABLE([newgrp], [no])]
1864 )
1865 UL_BUILD_INIT([newgrp])
1866 AM_CONDITIONAL([BUILD_NEWGRP], [test "x$build_newgrp" = xyes])
1867
1868
1869 AC_ARG_WITH([user], AS_HELP_STRING([--without-user], [compile without libuser (remote chsh)]),
1870   [], [with_user=check]
1871 )
1872 have_user=no
1873 AS_IF([test "x$with_user" != xno], [
1874   PKG_CHECK_MODULES(LIBUSER,[libuser >= 0.58], [have_user=yes], [have_user=no])
1875   AS_CASE([$with_user:$have_user],
1876     [yes:no],
1877       [AC_MSG_ERROR([user selected but libuser not found])],
1878     [*:yes],
1879       [AC_DEFINE([HAVE_LIBUSER], [1], [Define if libuser is available])]
1880   )
1881   # temporary solution, libuser has stupid .pc where are exported all
1882   # private dependencies to Requires: instead of Requires.private:
1883   AS_IF([test "x$have_user" = xyes], [
1884     LIBUSER_LIBS=-luser
1885   ])
1886 ])
1887 AM_CONDITIONAL([HAVE_USER], [test "x$have_user" = xyes])
1888
1889 AC_ARG_ENABLE([chfn-chsh-password],
1890   AS_HELP_STRING([--disable-chfn-chsh-password], [do not require the user to enter the password in chfn and chsh]),
1891   [], [enable_chfn_chsh_password=yes]
1892 )
1893
1894 AC_ARG_ENABLE([chfn-chsh],
1895   AS_HELP_STRING([--enable-chfn-chsh], [build chfn and chsh]),
1896   [], [UL_DEFAULT_ENABLE([chfn_chsh], [check])]
1897 )
1898 UL_BUILD_INIT([chfn_chsh])
1899 UL_REQUIRES_HAVE([chfn_chsh], [shadow_h], [shadow.h header])
1900 UL_REQUIRES_HAVE([chfn_chsh], [getusershell], [getusershell function])
1901
1902 AS_IF([test "x$enable_chfn_chsh_password" = xyes -o "x$have_user" = xyes], [
1903   UL_REQUIRES_HAVE([chfn_chsh], [security_pam_appl_h], [PAM header file])
1904   AC_DEFINE([CHFN_CHSH_PASSWORD], [1], [Should chfn and chsh require the user to enter the password?])
1905 ])
1906 AM_CONDITIONAL([BUILD_CHFN_CHSH], [test "x$build_chfn_chsh" = xyes])
1907 AM_CONDITIONAL([CHFN_CHSH_PASSWORD], [test "x$enable_chfn_chsh_password" = xyes])
1908
1909 AC_ARG_ENABLE([chsh-only-listed],
1910   AS_HELP_STRING([--disable-chsh-only-listed], [chsh: allow shells not in /etc/shells]),
1911   [], enable_chsh_only_listed=yes
1912 )
1913
1914 AS_IF([test "x$enable_chsh_only_listed" = xyes], [
1915   AC_DEFINE([ONLY_LISTED_SHELLS], [1], [Should chsh allow only shells in /etc/shells?])
1916 ])
1917
1918
1919 AC_ARG_ENABLE([login],
1920   AS_HELP_STRING([--disable-login], [do not build login]),
1921   [], [UL_DEFAULT_ENABLE([login], [check])]
1922 )
1923 UL_BUILD_INIT([login])
1924 UL_REQUIRES_HAVE([login], [security_pam_appl_h], [PAM header file])
1925 UL_REQUIRES_HAVE([login], [security_pam_misc_h, security_openpam_h], [PAM conversation functions])
1926 UL_REQUIRES_HAVE([login], [utmpx_h], [utmpx.h header])
1927 UL_REQUIRES_HAVE([login], [gnu_utmpx], [GNU utmpx functions])
1928 AM_CONDITIONAL([BUILD_LOGIN], [test "x$build_login" = xyes])
1929
1930 AC_ARG_ENABLE([login-chown-vcs],
1931   AS_HELP_STRING([--enable-login-chown-vcs], [let login chown /dev/vcsN]),
1932   [], [enable_login_chown_vcs=no]
1933 )
1934
1935 AS_IF([test "x$enable_login_chown_vcs" = xyes], [
1936   AC_DEFINE([LOGIN_CHOWN_VCS], [1], [Should login chown /dev/vcsN?])
1937 ])
1938
1939 AC_ARG_ENABLE([login-stat-mail],
1940   AS_HELP_STRING([--enable-login-stat-mail], [let login stat() the mailbox]),
1941   [], [enable_login_stat_mail=no]
1942 )
1943
1944 AS_IF([test "x$enable_login_stat_mail" = xyes], [
1945   AC_DEFINE([LOGIN_STAT_MAIL], [1], [Should login stat() the mailbox?])
1946 ])
1947
1948
1949 AC_ARG_ENABLE([nologin],
1950   AS_HELP_STRING([--disable-nologin], [do not build nologin]),
1951   [], [UL_DEFAULT_ENABLE([nologin], [yes])]
1952 )
1953 UL_BUILD_INIT([nologin])
1954 AM_CONDITIONAL([BUILD_NOLOGIN], [test "x$build_nologin" = xyes])
1955
1956
1957 AC_ARG_ENABLE([sulogin],
1958   AS_HELP_STRING([--disable-sulogin], [do not build sulogin]),
1959   [], [UL_DEFAULT_ENABLE([sulogin], [check])]
1960 )
1961 UL_BUILD_INIT([sulogin])
1962 UL_REQUIRES_HAVE([sulogin], [shadow_h], [shadow.h header])
1963 AM_CONDITIONAL([BUILD_SULOGIN], [test "x$build_sulogin" = xyes])
1964
1965
1966 AC_ARG_ENABLE([su],
1967   AS_HELP_STRING([--disable-su], [do not build su]),
1968   [], [UL_DEFAULT_ENABLE([su], [check])]
1969 )
1970 UL_BUILD_INIT([su])
1971 UL_REQUIRES_HAVE([su], [security_pam_appl_h], [PAM header file])
1972 UL_REQUIRES_HAVE([su], [utmpx_h], [utmpx.h header])
1973 UL_REQUIRES_HAVE([su], [gnu_utmpx], [GNU utmpx functions])
1974 AM_CONDITIONAL([BUILD_SU], [test "x$build_su" = xyes])
1975
1976
1977 AC_ARG_ENABLE([runuser],
1978   AS_HELP_STRING([--disable-runuser], [do not build runuser]),
1979   [], [UL_DEFAULT_ENABLE([runuser], [check])]
1980 )
1981 UL_BUILD_INIT([runuser])
1982 UL_REQUIRES_HAVE([runuser], [security_pam_appl_h], [PAM header file])
1983 UL_REQUIRES_HAVE([runuser], [utmpx_h], [utmpx.h header])
1984 UL_REQUIRES_HAVE([runuser], [gnu_utmpx], [GNU utmpx functions])
1985 AM_CONDITIONAL([BUILD_RUNUSER], [test "x$build_runuser" = xyes])
1986
1987
1988 AC_ARG_ENABLE([ul],
1989   AS_HELP_STRING([--disable-ul], [do not build ul]),
1990   [], [UL_DEFAULT_ENABLE([ul], [check])]
1991 )
1992 UL_BUILD_INIT([ul])
1993 UL_REQUIRES_HAVE([ul], [ncursesw, ncurses], [ncursesw or ncurses libraries])
1994 AM_CONDITIONAL([BUILD_UL], [test "x$build_ul" = xyes])
1995
1996
1997 AC_ARG_ENABLE([more],
1998   AS_HELP_STRING([--disable-more], [do not build more]),
1999   [], [UL_DEFAULT_ENABLE([more], [check])]
2000 )
2001 UL_BUILD_INIT([more])
2002 UL_REQUIRES_HAVE([more], [ncursesw, ncurses], [ncursesw or ncurses libraries])
2003 AM_CONDITIONAL([BUILD_MORE], [test "x$build_more" = xyes])
2004
2005
2006 AC_ARG_ENABLE([pg],
2007   AS_HELP_STRING([--enable-pg], [build pg]),
2008   [], [UL_DEFAULT_ENABLE([pg], [no])]
2009 )
2010 UL_BUILD_INIT([pg])
2011 UL_REQUIRES_HAVE([pg], [ncursesw, ncurses], [ncursesw or ncurses library])
2012 AM_CONDITIONAL([BUILD_PG], [test "x$build_pg" = xyes])
2013
2014
2015 AC_ARG_ENABLE([setterm],
2016   AS_HELP_STRING([--disable-setterm], [do not build setterm]),
2017   [], [UL_DEFAULT_ENABLE([setterm], [check])]
2018 )
2019 UL_BUILD_INIT([setterm])
2020 UL_REQUIRES_LINUX([setterm])
2021 UL_REQUIRES_HAVE([setterm], [ncursesw, ncurses], [ncursesw or ncurses library])
2022 AM_CONDITIONAL([BUILD_SETTERM], [test "x$build_setterm" = xyes])
2023
2024 # build_schedutils= is just configure-only variable to control
2025 # ionice, taskset and chrt
2026 AC_ARG_ENABLE([schedutils],
2027   AS_HELP_STRING([--disable-schedutils], [do not build chrt, ionice, taskset]),
2028   [], [UL_DEFAULT_ENABLE([schedutils], [check])]
2029 )
2030
2031
2032 UL_ENABLE_ALIAS([ionice], [schedutils])
2033 UL_BUILD_INIT([ionice])
2034 UL_REQUIRES_SYSCALL_CHECK([ionice],
2035         [UL_CHECK_SYSCALL([ioprio_set],
2036           [alpha],      [442],
2037           [i*86],       [289],
2038           [ia64*],      [1274],
2039           [powerpc*],   [273],
2040           [s390*],      [282],
2041           [sparc*],     [196],
2042           [sh*],        [288],
2043           [x86_64*],    [251])],
2044         [ioprio_set])
2045
2046 UL_REQUIRES_SYSCALL_CHECK([ionice],
2047         [UL_CHECK_SYSCALL([ioprio_get],
2048           [alpha],      [443],
2049           [i*86],       [290],
2050           [ia64*],      [1275],
2051           [powerpc*],   [274],
2052           [s390*],      [283],
2053           [sparc*],     [218],
2054           [sh*],        [289],
2055           [x86_64*],    [252])],
2056         [ioprio_get])
2057
2058 AM_CONDITIONAL([BUILD_IONICE], [test "x$build_ionice" = xyes])
2059
2060
2061 UL_ENABLE_ALIAS([taskset], [schedutils])
2062 UL_BUILD_INIT([taskset])
2063 UL_REQUIRES_HAVE([taskset], [cpu_set_t], [cpu_set_t type])
2064 UL_REQUIRES_SYSCALL_CHECK([taskset],
2065         [UL_CHECK_SYSCALL([sched_getaffinity])],
2066         [sched_getaffinity])
2067 AM_CONDITIONAL([BUILD_TASKSET], [test "x$build_taskset" = xyes])
2068
2069
2070 have_schedsetter=no
2071 AS_IF([test "x$ac_cv_func_sched_setscheduler" = xyes], [have_schedsetter=yes],
2072       [test "x$ac_cv_func_sched_setattr" = xyes], [have_schedsetter=yes])
2073
2074 UL_ENABLE_ALIAS([chrt], [schedutils])
2075 UL_BUILD_INIT([chrt])
2076 UL_REQUIRES_HAVE([chrt], [schedsetter], [sched_set functions])
2077 AM_CONDITIONAL([BUILD_CHRT], [test "x$build_chrt" = xyes])
2078
2079 AS_IF([test "x$build_chrt" = xyes], [
2080         UL_CHECK_SYSCALL([sched_setattr])
2081 ])
2082
2083
2084 AC_ARG_ENABLE([wall],
2085   AS_HELP_STRING([--disable-wall], [do not build wall]),
2086   [], [UL_DEFAULT_ENABLE([wall], [check])]
2087 )
2088 UL_BUILD_INIT([wall])
2089 UL_REQUIRES_HAVE([wall], [utmpx_h], [utmpx.h header])
2090 AM_CONDITIONAL([BUILD_WALL], [test "x$build_wall" = xyes])
2091
2092
2093 AC_ARG_ENABLE([write],
2094   AS_HELP_STRING([--enable-write], [build write]),
2095   [], [UL_DEFAULT_ENABLE([write], [no])]
2096 )
2097 UL_BUILD_INIT([write])
2098 UL_REQUIRES_HAVE([write], [utmpx_h], [utmpx.h header])
2099 UL_REQUIRES_HAVE([write], [gnu_utmpx], [GNU utmpx functions])
2100 AM_CONDITIONAL([BUILD_WRITE], [test "x$build_write" = xyes])
2101
2102
2103 AC_ARG_WITH([btrfs],
2104   AS_HELP_STRING([--without-btrfs], [do not build with btrfs support]),
2105   [], [with_btrfs=check]
2106 )
2107 have_btrfs=no
2108 AS_IF([test "x$with_btrfs" != xno], [
2109   AS_CASE([$with_btrfs:$have_linux_btrfs_h],
2110     [yes:no],
2111     [AC_MSG_ERROR([btrfs selected but linux/btrfs.h not found])],
2112     [check:no],
2113        [AC_MSG_WARN([linux/btrfs.h not found, do not build with btrfs support])],
2114     [*:yes],
2115        [have_btrfs=yes
2116         AC_DEFINE([HAVE_BTRFS_SUPPORT], [1], [Define if btrfs stuff is available])]
2117   )
2118 ])
2119 AM_CONDITIONAL([HAVE_BTRFS], [test "x$have_btrfs" = xyes])
2120
2121
2122 AC_ARG_WITH([systemd],
2123   AS_HELP_STRING([--without-systemd], [do not build with systemd support]),
2124   [], [with_systemd=check]
2125 )
2126
2127 have_systemd=no
2128 AS_IF([test "x$with_systemd" != xno], [
2129   # new version -- all libsystemd-* libs merged into libsystemd
2130   PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [have_systemd=yes], [have_systemd=no])
2131   # old versions
2132   AS_IF([test "x$have_systemd" != "xyes"], [
2133     PKG_CHECK_MODULES([SYSTEMD_DAEMON], [libsystemd-daemon],
2134                       [have_systemd_daemon=yes], [have_systemd_daemon=no])
2135     PKG_CHECK_MODULES([SYSTEMD_JOURNAL], [libsystemd-journal],
2136                       [have_systemd_journal=yes], [have_systemd_journal=no])
2137     AS_IF([test "x$have_systemd_daemon" = "xyes" -a "x$have_systemd_journal" = "xyes" ],[
2138            have_systemd=yes])
2139   ])
2140   AS_CASE([$with_systemd:$have_systemd],
2141     [yes:no],
2142       [AC_MSG_ERROR([systemd expected but libsystemd not found])],
2143     [*:yes],
2144        AC_DEFINE([HAVE_LIBSYSTEMD], [1], [Define if libsystemd is available])
2145   )
2146 ])
2147 AM_CONDITIONAL([HAVE_SYSTEMD], [test "x$have_systemd" = xyes])
2148
2149
2150 AC_ARG_WITH([systemdsystemunitdir],
2151   AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [directory for systemd unit files (requires systemd support)]),
2152   [], [with_systemdsystemunitdir=check]
2153 )
2154 AS_IF([test "x$with_systemdsystemunitdir" = xcheck], [
2155   AS_IF([test "x$have_systemd" = xyes], [
2156     with_systemdsystemunitdir=`$PKG_CONFIG --variable=systemdsystemunitdir systemd`
2157   ],[
2158     with_systemdsystemunitdir=no
2159   ])
2160 ])
2161 AS_IF([test "x$with_systemdsystemunitdir" != "xno"], [
2162   AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
2163 ])
2164
2165
2166 AC_ARG_WITH([smack],
2167   AS_HELP_STRING([--with-smack], [build with SMACK support]),
2168   [], [with_smack=no]
2169 )
2170 AS_IF([test "x$with_smack" = xyes], [
2171   AC_DEFINE([HAVE_SMACK], [1], [Add SMACK support])
2172 ])
2173
2174
2175 AC_ARG_WITH([bashcompletiondir],
2176   AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
2177   [],
2178   [AS_IF([`$PKG_CONFIG --exists bash-completion`], [
2179     with_bashcompletiondir=`$PKG_CONFIG --variable=completionsdir bash-completion`
2180   ], [
2181     with_bashcompletiondir=${datadir}/bash-completion/completions
2182   ])
2183 ])
2184 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
2185
2186 AC_ARG_ENABLE([bash-completion],
2187   AS_HELP_STRING([--disable-bash-completion], [do not install bash completion files]),
2188   [], [enable_bash_completion=yes]
2189 )
2190
2191 AM_CONDITIONAL([BUILD_BASH_COMPLETION], [test "x$enable_bash_completion" = xyes])
2192
2193
2194 AC_ARG_WITH([python],
2195   AS_HELP_STRING([--without-python], [do not build python bindings, use --with-python={2,3} to force version]),
2196   [], [with_python=check withval=check]
2197 )
2198
2199 have_python=no
2200 have_libpython=no
2201 AS_IF([test "x$with_python" != xno], [
2202   # We follow distributions default and look for PKG module name "python"
2203   # (minimal version is 2) but if major version is explicitly specified by
2204   # --with-python=2 or --with-python=3 then we look for PKG module "python2" or
2205   # "python3".
2206   AS_IF([test "x$withval" != xno -a "x$withval" != xyes -a "x$withval" != xcheck],
2207         [pymajor="$withval"; PYTHON=python${pymajor}], [pymajor="2"])
2208
2209   # check for python interpreter
2210   AM_PATH_PYTHON([$pymajor], [have_python=yes], [have_python=no])
2211   AS_CASE([$with_python:$have_python],
2212     [yes:no],
2213       [AC_MSG_ERROR([python selected but python interpreter not found])],
2214     [check:no],
2215        [AC_MSG_WARN([python interpreter not found, do not build python bindings])],
2216     [*:yes],
2217        # check for python development stuff
2218        [PKG_CHECK_MODULES([PYTHON], [python-$PYTHON_VERSION],
2219                           [have_libpython=yes], [have_libpython=no])]
2220   )
2221 ])
2222
2223
2224 AC_ARG_ENABLE([pylibmount],
2225   AS_HELP_STRING([--disable-pylibmount], [do not build pylibmount]),
2226   [], [UL_DEFAULT_ENABLE([pylibmount], [check])]
2227 )
2228 UL_BUILD_INIT([pylibmount])
2229 UL_REQUIRES_HAVE([pylibmount], [libpython], [libpython])
2230 UL_REQUIRES_BUILD([pylibmount], [libmount])
2231 AM_CONDITIONAL([BUILD_PYLIBMOUNT], [test "x$build_pylibmount" = "xyes"])
2232
2233 # We need to introduce a verbatim dependency into the Makefile, without automake
2234 # trying to interpret it, so push it as a AM_SUBST_NOTMAKE variable.
2235 verbatim_pylibmount_dependency='
2236
2237 # pylibmountexec module must be installed after usrlib_exec libraries,
2238 # otherwise the libtool relink step will fail to find libmount.la and
2239 # will try -lmount which is possibly not available.
2240 install-pylibmountexecLTLIBRARIES: install-usrlib_execLTLIBRARIES
2241
2242 '
2243 AC_SUBST([verbatim_pylibmount_dependency])
2244 AM_SUBST_NOTMAKE([verbatim_pylibmount_dependency])
2245
2246 AC_ARG_ENABLE([pg-bell],
2247   AS_HELP_STRING([--disable-pg-bell], [let pg not ring the bell on invalid keys]),
2248   [], [enable_pg_bell=yes]
2249 )
2250
2251 AS_IF([test "x$enable_pg_bell" = xyes], [
2252   AC_DEFINE([PG_BELL], [1], [Should pg ring the bell on invalid keys?])
2253 ])
2254
2255
2256 AC_DEFUN([FS_PATHS_DEFAULT], [/sbin:/sbin/fs.d:/sbin/fs])
2257 AC_ARG_ENABLE([fs-paths-default],
2258   AS_HELP_STRING([--enable-fs-paths-default=paths], [default search path for fs helpers @<:@FS_PATHS_DEFAULT@:>@]),
2259   [AS_CASE([$enableval],
2260     [yes], [fs_paths_defaults="FS_PATHS_DEFAULT"],
2261     [no],  [fs_paths_defaults=""],
2262     [fs_paths_defaults="$enableval"]
2263   )],
2264   [fs_paths_defaults="FS_PATHS_DEFAULT"]
2265 )
2266 AC_ARG_ENABLE([fs-paths-extra],
2267   AS_HELP_STRING([--enable-fs-paths-extra=paths], [additional search paths for fs helpers]),
2268   [AS_CASE([$enableval],
2269      [yes|no], [fs_paths_extra=""],
2270      [fs_paths_extra="$enableval"]
2271   )],
2272   [fs_paths_extra=""]
2273 )
2274 fs_paths="$fs_paths_defaults"
2275 AS_IF([test "x$fs_paths_extra" != "x"], [
2276   AS_IF([test "x$fs_paths" != "x"], [
2277     fs_paths="${fs_paths}:"
2278   ])
2279   fs_paths="${fs_paths}${fs_paths_extra}"
2280 ])
2281 AC_DEFINE_UNQUOTED([FS_SEARCH_PATH], "$fs_paths", [search path for fs helpers])
2282
2283
2284 AC_ARG_ENABLE([use-tty-group],
2285   AS_HELP_STRING([--disable-use-tty-group], [do not install wall and write setgid tty]),
2286   [], [enable_use_tty_group=yes]
2287 )
2288 AM_CONDITIONAL([USE_TTY_GROUP], [test "x$enable_use_tty_group" = xyes])
2289
2290 AS_IF([test "x$enable_use_tty_group" = xyes], [
2291   AC_DEFINE([USE_TTY_GROUP], [1], [Should wall and write be installed setgid tty?])
2292 ])
2293
2294
2295 AC_ARG_ENABLE([sulogin-emergency-mount],
2296   AS_HELP_STRING([--enable-sulogin-emergency-mount],
2297                  [use emergency mount of /dev and /proc for sulogin]),
2298   [], [enable_sulogin_emergency_mount=no]
2299 )
2300
2301 AS_IF([test "x$enable_sulogin_emergency_mount" = xyes], [
2302   AC_DEFINE([USE_SULOGIN_EMERGENCY_MOUNT], [1],
2303             [Should sulogin use a emergency mount of /dev and /proc?])
2304 ])
2305
2306
2307 AC_ARG_ENABLE([usrdir-path],
2308   AS_HELP_STRING([--enable-usrdir-path], [use only /usr paths in PATH env. variable (recommended on systems with /bin -> /usr/bin symlinks)]),
2309   [], [enable_usrdir_path=no]
2310 )
2311
2312 AS_IF([test "x$enable_usrdir_path" = xyes], [
2313   AC_DEFINE([USE_USRDIR_PATHS_ONLY], [1], [Define to 1 to remove /bin and /sbin from PATH env.variable])
2314 ])
2315
2316
2317 AC_ARG_ENABLE([makeinstall-chown],
2318   AS_HELP_STRING([--disable-makeinstall-chown], [do not do chown-like operations during "make install"]),
2319   [], [enable_makeinstall_chown=yes]
2320 )
2321 AM_CONDITIONAL([MAKEINSTALL_DO_CHOWN], [test "x$enable_makeinstall_chown" = xyes])
2322
2323
2324 AC_ARG_ENABLE([makeinstall-setuid],
2325   AS_HELP_STRING([--disable-makeinstall-setuid], [do not do setuid chmod operations during "make install"]),
2326   [], [enable_makeinstall_setuid=yes]
2327 )
2328 AM_CONDITIONAL([MAKEINSTALL_DO_SETUID], [test "x$enable_makeinstall_setuid" = xyes])
2329
2330
2331 AC_ARG_ENABLE([colors-default],
2332   AS_HELP_STRING([--disable-colors-default], [do not colorize output from utils by default]),
2333   [], [enable_colors_default=yes]
2334 )
2335 AS_IF([test "x$enable_colors_default" = xyes], [
2336   AC_DEFINE([USE_COLORS_BY_DEFAULT], [1], [Enables colorized output from utils by default])
2337 ])
2338
2339
2340 AC_ARG_VAR([SUID_CFLAGS],
2341            [CFLAGS used for binaries which are usually with the suid bit])
2342 AC_ARG_VAR([SUID_LDFLAGS],
2343            [LDFLAGS used for binaries which are usually with the suid bit])
2344
2345 AC_ARG_VAR([DAEMON_CFLAGS],
2346            [CFLAGS used for binaries which are usually executed as daemons])
2347 AC_ARG_VAR([DAEMON_LDFLAGS],
2348            [LDFLAGS used for binaries which are usually executed as daemons])
2349
2350 AC_ARG_VAR([SOLIB_CFLAGS],
2351            [CFLAGS used for shared libraries])
2352 AC_ARG_VAR([SOLIB_LDFLAGS],
2353            [LDFLAGS used for shared libraries])
2354
2355 AC_ARG_VAR([ADJTIME_PATH],
2356            [Path to hwclock adjtime file, default /etc/adjtime])
2357 AS_IF([test "x$ADJTIME_PATH" = x], [ADJTIME_PATH="/etc/adjtime"])
2358 AC_DEFINE_UNQUOTED([CONFIG_ADJTIME_PATH], "$ADJTIME_PATH", [Path to hwclock adjtime file])
2359
2360
2361 LIBS=""
2362
2363
2364 AC_CONFIG_HEADERS([config.h])
2365
2366 #
2367 # Don't use configure.ac to replace install paths! See Makefile PATHFILES for
2368 # more details.
2369 #
2370 AC_CONFIG_FILES([
2371 Makefile
2372 libblkid/docs/Makefile
2373 libblkid/docs/version.xml
2374 libblkid/src/blkid.h
2375 libfdisk/docs/Makefile
2376 libfdisk/docs/version.xml
2377 libfdisk/src/libfdisk.h
2378 libmount/docs/Makefile
2379 libmount/docs/version.xml
2380 libmount/src/libmount.h
2381 libsmartcols/docs/Makefile
2382 libsmartcols/docs/version.xml
2383 libsmartcols/src/libsmartcols.h
2384 po/Makefile.in
2385 ])
2386
2387 AC_OUTPUT
2388
2389 AC_MSG_RESULT([
2390         ${PACKAGE}  ${VERSION}
2391
2392         prefix:            ${prefix}
2393         exec prefix:       ${exec_prefix}
2394
2395         runstatedir:       ${runstatedir}
2396         bindir:            ${bindir}
2397         sbindir:           ${sbindir}
2398         libdir:            ${libdir}
2399         includedir:        ${includedir}
2400         usrbin_execdir:    ${usrbin_execdir}
2401         usrsbin_execdir:   ${usrsbin_execdir}
2402         usrlib_execdir:    ${usrlib_execdir}
2403
2404         compiler:          ${CC}
2405         cflags:            ${CFLAGS}
2406         suid cflags:       ${SUID_CFLAGS}
2407         ldflags:           ${LDFLAGS}
2408         suid ldflags:      ${SUID_LDFLAGS}
2409
2410         Python:            ${PYTHON}
2411         Python version:    ${PYTHON_VERSION}
2412         Python libs:       ${pyexecdir}
2413
2414         Bash completions:  ${with_bashcompletiondir}
2415         Systemd support:   ${have_systemd}
2416         Systemd unitdir:   ${with_systemdsystemunitdir}
2417         Btrfs support:     ${have_btrfs}
2418         Wide-char support: ${build_widechar}
2419
2420         warnings:
2421
2422 ${WARN_CFLAGS}
2423
2424         Type 'make' or 'make <utilname>' to compile.
2425 ])