configure.ac

   1 AC_INIT([util-linux],
   2         m4_esyscmd([tools/git-version-gen .tarball-version]),
   3         [kzak@redhat.com], [],
   4         [https://www.kernel.org/pub/linux/utils/util-linux/])
   5
   6
   7 AC_PREREQ([2.64])
   8
   9 AC_CONFIG_AUX_DIR([config])
  10 AC_CONFIG_MACRO_DIR([m4])
  11 dnl AC_USE_SYSTEM_EXTENSIONS must be called before any macros that run
  12 dnl the compiler (like LT_INIT) to avoid autoconf errors.
  13 AC_USE_SYSTEM_EXTENSIONS
  14 AM_INIT_AUTOMAKE([-Wall -Wno-portability foreign 1.10 tar-pax no-dist-gzip dist-xz subdir-objects])
  15
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  17                             [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  18 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  19
  20 AC_CONFIG_SRCDIR([sys-utils/mount.c])
  21 AC_PREFIX_DEFAULT([/usr])
  22
  23 dnl version details from <major>.<minor>[-<suffix>]
  24 PACKAGE_VERSION_MAJOR=$(echo $PACKAGE_VERSION | awk -F. '{print $1}')
  25 PACKAGE_VERSION_MINOR=$(echo $PACKAGE_VERSION | awk -F. '{
  26                                                    sub("-.*","",$2); print $2}')
  27 PACKAGE_VERSION_RELEASE=$(echo $PACKAGE_VERSION | awk -F. '{
  28                      sub("-.*","",$3); print $3 ~ /^@<:@0-9@:>@+$/ ? $3 : 0}')
  29
  30 dnl libblkid version
  31 LIBBLKID_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  32 LIBBLKID_DATE="17-May-2023"
  33 LIBBLKID_LT_MAJOR=1
  34 LIBBLKID_LT_MINOR=1
  35 LIBBLKID_LT_MICRO=0
  36 LIBBLKID_VERSION_INFO=`expr $LIBBLKID_LT_MAJOR + $LIBBLKID_LT_MINOR`:$LIBBLKID_LT_MICRO:$LIBBLKID_LT_MINOR
  37
  38 dnl libuuid version
  39 LIBUUID_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  40 LIBUUID_LT_MAJOR=1
  41 LIBUUID_LT_MINOR=3
  42 LIBUUID_LT_MICRO=0
  43 LIBUUID_VERSION_INFO=`expr $LIBUUID_LT_MAJOR + $LIBUUID_LT_MINOR`:$LIBUUID_LT_MICRO:$LIBUUID_LT_MINOR
  44
  45 dnl libmount version
  46 LIBMOUNT_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  47 LIBMOUNT_LT_MAJOR=1
  48 LIBMOUNT_LT_MINOR=1
  49 LIBMOUNT_LT_MICRO=0
  50 LIBMOUNT_VERSION_INFO=`expr $LIBMOUNT_LT_MAJOR + $LIBMOUNT_LT_MINOR`:$LIBMOUNT_LT_MICRO:$LIBMOUNT_LT_MINOR
  51
  52 dnl libsmartcols version
  53 LIBSMARTCOLS_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  54 LIBSMARTCOLS_LT_MAJOR=1
  55 LIBSMARTCOLS_LT_MINOR=1
  56 LIBSMARTCOLS_LT_MICRO=0
  57 LIBSMARTCOLS_VERSION_INFO=`expr $LIBSMARTCOLS_LT_MAJOR + $LIBSMARTCOLS_LT_MINOR`:$LIBSMARTCOLS_LT_MICRO:$LIBSMARTCOLS_LT_MINOR
  58
  59 dnl libfdisk version
  60 LIBFDISK_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  61 LIBFDISK_LT_MAJOR=1
  62 LIBFDISK_LT_MINOR=1
  63 LIBFDISK_LT_MICRO=0
  64 LIBFDISK_VERSION_INFO=`expr $LIBFDISK_LT_MAJOR + $LIBFDISK_LT_MINOR`:$LIBFDISK_LT_MICRO:$LIBFDISK_LT_MINOR
  65
  66 # Check whether exec_prefix=/usr:
  67 AS_CASE([$exec_prefix:$prefix],
  68 [NONE:NONE | NONE:/usr | /usr:*],
  69   [AC_MSG_NOTICE([Default --exec-prefix detected.])
  70    AS_CASE([$bindir],  ['${exec_prefix}/bin'],  [bindir=/bin;   AC_MSG_NOTICE([  --bindir defaults to /bin])  ])
  71    AS_CASE([$sbindir], ['${exec_prefix}/sbin'], [sbindir=/sbin; AC_MSG_NOTICE([  --sbindir defaults to /sbin])])
  72    AS_CASE([$libdir],  ['${exec_prefix}/lib'],  [libdir=/lib;   AC_MSG_NOTICE([  --libdir defaults to /lib])  ])
  73    AS_CASE([$libdir],  ['${exec_prefix}/lib64'],[libdir=/lib64; AC_MSG_NOTICE([  --libdir defaults to /lib64])  ])
  74   ]
  75 )
  76
  77 # Check whether prefix=/usr
  78 AS_CASE([$prefix],
  79 [NONE | /usr],
  80   [AC_MSG_NOTICE([Default --prefix detected.])
  81    AS_CASE([$localstatedir], [NONE | '${prefix}/var' | "${prefix}"/var ],
  82            [localstatedir=/var; AC_MSG_NOTICE([  --localstatedir defaults to /var])])
  83    AS_CASE([$sysconfdir], [NONE | '${prefix}/etc' | "${prefix}"/etc ],
  84            [sysconfdir=/etc; AC_MSG_NOTICE([  --sysconfdir defaults to /etc])])
  85
  86   ]
  87 )
  88
  89 # default for old versions without $runstatedir
  90 AS_IF([test x"$runstatedir" = x], [runstatedir='${localstatedir}/run'])
  91
  92 # our default if $localstatedir unchanged
  93 AS_CASE([$localstatedir:$runstatedir],
  94  [NONE:'${localstatedir}/run' | /var:'${localstatedir}/run' | NONE:'/run' ],
  95    [runstatedir=/run; AC_MSG_NOTICE([  --runstatedir defaults to /run])]
  96 )
  97
  98 AC_SUBST([runstatedir])
  99
 100
 101 # The original default values of {bin,sbin,lib}dir
 102 usrbin_execdir='${exec_prefix}/bin'
 103 AC_SUBST([usrbin_execdir])
 104
 105 usrsbin_execdir='${exec_prefix}/sbin'
 106 AC_SUBST([usrsbin_execdir])
 107
 108 AS_CASE([$libdir],
 109  ['${exec_prefix}/'* | '${prefix}/'* | /usr/* | "${prefix}"/* ],
 110    [usrlib_execdir=$libdir],
 111  [usrlib_execdir='${exec_prefix}'$libdir]
 112 )
 113 AC_SUBST([usrlib_execdir])
 114
 115 # static configuration maintaned by packages (e.g. /usr/lib)
 116 AC_ARG_VAR([SYSCONFSTATICDIR],
 117            [Path to static system configuration, default ${prefix}/lib])
 118 AS_IF([test "x$SYSCONFSTATICDIR" = x],
 119       [sysconfstaticdir='${prefix}/lib'],
 120       [sysconfstaticdir=$SYSCONFSTATICDIR])
 121 AC_SUBST([sysconfstaticdir])
 122
 123 AC_PROG_CC
 124 AM_PROG_CC_C_O
 125 AC_PROG_MKDIR_P
 126 AC_PROG_YACC
 127
 128 # Don't use autotools integrated LEX/YACC support for libsmartcols
 129 AC_PATH_PROG([FLEX], [flex])
 130 AC_PATH_PROG([BISON], [bison])
 131
 132 AC_CANONICAL_HOST
 133 AC_C_CONST
 134 AC_C_VOLATILE
 135
 136 dnl Compiler warnings
 137 UL_WARN_ADD([-fno-common])
 138 UL_WARN_ADD([-Wall])
 139 UL_WARN_ADD([-Wextra])
 140
 141 UL_WARN_ADD([-Waddress-of-packed-member])
 142 UL_WARN_ADD([-Wdiscarded-qualifiers])
 143 UL_WARN_ADD([-Wembedded-directive])
 144 UL_WARN_ADD([-Wextra-semi])
 145 UL_WARN_ADD([-Wformat-security])
 146 UL_WARN_ADD([-Wimplicit-function-declaration])
 147 UL_WARN_ADD([-Wmissing-declarations])
 148 UL_WARN_ADD([-Wmissing-parameter-type])
 149 UL_WARN_ADD([-Wmissing-prototypes])
 150 UL_WARN_ADD([-Wnested-externs])
 151 UL_WARN_ADD([-Wno-missing-field-initializers])
 152 UL_WARN_ADD([-Wold-style-definition])
 153 UL_WARN_ADD([-Wpointer-arith])
 154 UL_WARN_ADD([-Wredundant-decls])
 155 UL_WARN_ADD([-Wsign-compare])
 156 UL_WARN_ADD([-Wstrict-prototypes])
 157 UL_WARN_ADD([-Wtype-limits])
 158 UL_WARN_ADD([-Wuninitialized])
 159 UL_WARN_ADD([-Wunused-but-set-parameter])
 160 UL_WARN_ADD([-Wunused-but-set-variable])
 161 UL_WARN_ADD([-Wunused-parameter])
 162 UL_WARN_ADD([-Wunused-result])
 163 UL_WARN_ADD([-Wunused-variable])
 164 UL_WARN_ADD([-Wvla])
 165 UL_WARN_ADD([-Walloca])
 166
 167 AC_ARG_ENABLE([werror],
 168   AS_HELP_STRING([--enable-werror], [make all compiler warnings into errors]),
 169   [], [enable_werror=no]
 170 )
 171 AS_IF([test "x$enable_werror" = xyes], [
 172   UL_WARN_ADD([-Werror])
 173 ],[
 174   UL_WARN_ADD([-Werror=sequence-point])
 175 ])
 176
 177 AC_SUBST([WARN_CFLAGS])
 178
 179
 180 UL_WARN_ADD([-Wno-clobbered], [BSD_WARN_CFLAGS])
 181 AC_SUBST([BSD_WARN_CFLAGS])
 182
 183 UL_WARN_ADD([-Wno-cast-function-type], [PYTHON_WARN_CFLAGS])
 184 AC_SUBST([PYTHON_WARN_CFLAGS])
 185
 186
 187 AC_ARG_ENABLE([asan],
 188   AS_HELP_STRING([--enable-asan], [compile with Address Sanitizer]),
 189   [], [enable_asan=no]
 190 )
 191 AS_IF([test "x$enable_asan" = xyes], [
 192   UL_WARN_ADD([-fsanitize=address])
 193   ASAN_LDFLAGS="-fsanitize=address"
 194 ])
 195 AC_SUBST([ASAN_LDFLAGS])
 196
 197 AC_ARG_ENABLE([ubsan],
 198   AS_HELP_STRING([--enable-ubsan], [compile with UBsan]),
 199   [], [enable_ubsan=no]
 200 )
 201 AS_IF([test "x$enable_ubsan" = xyes], [
 202   UL_WARN_ADD([-fsanitize=undefined])
 203   UBSAN_LDFLAGS="-fsanitize=undefined"
 204 ])
 205 AC_SUBST([UBSAN_LDFLAGS])
 206
 207 AC_ARG_ENABLE([fuzzing-engine],
 208   AS_HELP_STRING([--enable-fuzzing-engine], [compile with fuzzing engine]),
 209   [], [enable_fuzzing_engine=no]
 210 )
 211 AS_IF([test "x$enable_fuzzing_engine" = xyes && test "x$LIB_FUZZING_ENGINE" = x], [
 212   UL_WARN_ADD([-fno-omit-frame-pointer])
 213   UL_WARN_ADD([-gline-tables-only])
 214   UL_WARN_ADD([-fsanitize=fuzzer-no-link])
 215   FUZZING_ENGINE_LDFLAGS="-fsanitize=fuzzer-no-link"
 216 ])
 217 AC_SUBST([FUZZING_ENGINE_LDFLAGS])
 218 AC_PROG_CXX
 219 AM_CONDITIONAL([FUZZING_ENGINE], [test "x$enable_fuzzing_engine" = xyes])
 220 AM_CONDITIONAL([OSS_FUZZ], [test "x$LIB_FUZZING_ENGINE" != x])
 221
 222 AC_ARG_ENABLE([coverage],
 223   AS_HELP_STRING([--enable-coverage], [compile with gcov]),
 224   [], [enable_coverage=no]
 225 )
 226 AS_IF([test "x$enable_coverage" = xyes], [
 227   UL_WARN_ADD([--coverage])
 228   COVERAGE_LDFLAGS="--coverage"
 229 ])
 230 AC_SUBST([COVERAGE_LDFLAGS])
 231 AM_CONDITIONAL([WITH_COVERAGE], [test "x$enable_coverage" = xyes])
 232
 233 dnl libtool-2
 234 LT_INIT
 235
 236 dnl check supported linker flags
 237 AX_CHECK_VSCRIPT
 238
 239 m4_ifndef([PKG_PROG_PKG_CONFIG],
 240   [m4_fatal([Could not locate the pkg-config autoconf
 241     macros. These are usually located in /usr/share/aclocal/pkg.m4.
 242     If your macros are in a different location, try setting the
 243     environment variable AL_OPTS="-I/other/macro/dir" before running
 244     ./autogen.sh or autoreconf again. Make sure pkg-config is installed.])])
 245 PKG_PROG_PKG_CONFIG
 246 PKG_INSTALLDIR(['${usrlib_execdir}/pkgconfig'])
 247
 248 GTK_DOC_CHECK([1.10])
 249 AC_PATH_PROG([XSLTPROC], [xsltproc])
 250
 251
 252 linux_os=no
 253 bsd_os=no
 254 AS_CASE([${host_os}],
 255   [*linux*],
 256      [linux_os=yes],
 257   [*darwin*],
 258      [darwin_os=yes],
 259   [*bsd*],
 260      [bsd_os=yes])
 261 AM_CONDITIONAL([LINUX], [test "x$linux_os" = xyes])
 262 AM_CONDITIONAL([DARWIN], [test "x$darwin_os" = xyes])
 263 AM_CONDITIONAL([BSD], [test "x$bsd_os" = xyes])
 264
 265 AS_IF([test  "x$darwin_os" = xyes], [
 266   AC_DEFINE([_DARWIN_C_SOURCE], [1], [Enable MAP_ANON in sys/mman.h on Mac OS X])
 267 ])
 268
 269 dnl define ARCH_<NAME> conditionals
 270 UL_SET_ARCH([I86], [i?86-*])
 271 UL_SET_ARCH([86_64], [x86_64*])
 272 UL_SET_ARCH([IA64], [ia64*])
 273 UL_SET_ARCH([S390], [s390*])
 274 UL_SET_ARCH([SPARC], [sparc*])
 275 UL_SET_ARCH([PPC], [ppc*|powerpc*])
 276 UL_SET_ARCH([M68K], [m68*])
 277 UL_SET_ARCH([MIPS], [mips*])
 278 UL_SET_ARCH([HPPA], [hppa*|parisc*])
 279
 280 AC_SYS_LARGEFILE
 281 AC_HEADER_ASSERT
 282 AC_STRUCT_TIMEZONE
 283
 284 dnl Don't forget to maintain alternatively allowed versions in autogen.sh!
 285 AM_GNU_GETTEXT_VERSION([0.18.3])
 286 AM_GNU_GETTEXT([external])
 287
 288 AS_IF([test -d "$srcdir/po"], [
 289   ALL_LINGUAS=`cd $srcdir/po > /dev/null && echo *.po | sed 's/\.po//g'`
 290 ], [dnl echo $ALL_LINGUAS | sed 's/ /\n/g' | sort -u | column -xc 72 -o ' ' | sed 's/^/\t/'
 291   ALL_LINGUAS="
 292         af      am      ar      as      be      bg      bn      bn_IN   ca
 293         cs      cy      da      de      el      en_GB   es      et      eu_ES
 294         fa      fi      fr      gl      gu      he      hi      hr      hu
 295         hy      id      is      it      ja      ka      kn      ko      ku
 296         lo      lt      lv      mk      ml      mr      ms      my      nb
 297         nl      nn      no      nso     or      pa      pl      pt      pt_BR
 298         ro      ru      si      sk      sl      sq      sr      sr@Latn sv
 299         ta      te      th      tr      uk      ur      vi      zh_CN   zh_TW
 300         zu
 301 "])
 302
 303 AC_CHECK_HEADERS([linux/compiler.h linux/blkpg.h linux/major.h], [], [], [
 304 #ifdef HAVE_LINUX_COMPILER_H
 305 #include <linux/compiler.h>
 306 #endif
 307 ])
 308 AC_CHECK_HEADERS([ \
 309         asm-generic/fcntl.h \
 310         asm/fcntl.h \
 311         asm/io.h \
 312         byteswap.h \
 313         endian.h \
 314         err.h \
 315         errno.h \
 316         fcntl.h \
 317         getopt.h \
 318         inttypes.h \
 319         lastlog.h \
 320         libutil.h \
 321         linux/blkzoned.h \
 322         linux/btrfs.h \
 323         linux/capability.h \
 324         linux/cdrom.h \
 325         linux/falloc.h \
 326         linux/fd.h \
 327         linux/fiemap.h \
 328         linux/landlock.h \
 329         linux/kcmp.h \
 330         linux/net_namespace.h \
 331         linux/nsfs.h \
 332         linux/pr.h \
 333         linux/raw.h \
 334         linux/securebits.h \
 335         linux/tiocl.h \
 336         linux/version.h \
 337         linux/watchdog.h \
 338         linux/if_alg.h \
 339         locale.h \
 340         mntent.h \
 341         net/if_dl.h \
 342         net/if.h \
 343         netinet/in.h \
 344         paths.h \
 345         pty.h \
 346         security/pam_appl.h \
 347         shadow.h \
 348         stdint.h \
 349         stdio_ext.h \
 350         stdlib.h \
 351         sys/disk.h \
 352         sys/disklabel.h \
 353         sys/endian.h \
 354         sys/file.h \
 355         sys/ioccom.h \
 356         sys/ioctl.h \
 357         sys/io.h \
 358         sys/mkdev.h \
 359         sys/mount.h \
 360         sys/param.h \
 361         sys/pidfd.h \
 362         sys/prctl.h \
 363         sys/resource.h \
 364         sys/sendfile.h \
 365         sys/signalfd.h \
 366         sys/socket.h \
 367         sys/sockio.h \
 368         sys/stat.h \
 369         sys/statfs.h \
 370         sys/swap.h \
 371         sys/syscall.h \
 372         sys/sysmacros.h \
 373         sys/time.h \
 374         sys/timex.h \
 375         sys/ttydefaults.h \
 376         sys/types.h \
 377         sys/ucred.h \
 378         sys/un.h \
 379         sys/vfs.h \
 380         sys/xattr.h \
 381         unistd.h \
 382         utmp.h \
 383         utmpx.h \
 384 ])
 385
 386 # There is a collision in old kernel-headers. The both files mount.h and fs.h
 387 # define MS_* macros. Fixed by kernel commit e462ec50cb5fad19f6003a3d8087f4a0945dd2b1.
 388 #
 389 AC_CHECK_HEADERS([linux/fs.h ], [], [],
 390  [#ifdef HAVE_SYS_MOUNT_H
 391    # include <linux/fs.h>
 392    # include <sys/mount.h>
 393   #endif
 394 ])
 395
 396 AC_CHECK_HEADERS([linux/mount.h ], [], [],
 397  [#ifdef HAVE_LINUX_MOUNT_H
 398    # include <linux/mount.h>
 399    #endif
 400 ])
 401
 402 AC_CHECK_HEADERS([linux/gsmmux.h ], [], [],
 403  [#ifdef LINUX_GSMMUX_H
 404    # include <linux/gsmmux.h>
 405    #endif
 406 ])
 407
 408 AC_CHECK_HEADERS([security/pam_misc.h],
 409                 [AM_CONDITIONAL([HAVE_LINUXPAM], [true])],
 410                 [AM_CONDITIONAL([HAVE_LINUXPAM], [false])], [
 411 #ifdef HAVE_SECURITY_PAM_APPL_H
 412 #include <security/pam_appl.h>
 413 #endif
 414 ])
 415
 416 AC_CHECK_DECLS([BLK_ZONE_REP_CAPACITY], [], [], [
 417         #include <linux/blkzoned.h>
 418 ])
 419
 420 AC_CHECK_DECLS([PR_REP_CAPACITY], [], [], [
 421         #include <linux/pr.h>
 422 ])
 423
 424 AC_CHECK_HEADERS([security/openpam.h], [], [], [
 425 #ifdef HAVE_SECURITY_PAM_APPL_H
 426 #include <security/pam_appl.h>
 427 #endif
 428 ])
 429
 430 AC_CHECK_HEADERS([langinfo.h],
 431                 [AM_CONDITIONAL([HAVE_LANGINFO_H], [true])],
 432                 [AM_CONDITIONAL([HAVE_LANGINFO_H], [false])])
 433
 434 AC_MSG_CHECKING([whether langinfo.h defines ALTMON_x constants])
 435 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 436         #include <langinfo.h>
 437 ]], [[
 438         char *str;
 439         str = nl_langinfo (ALTMON_1);
 440         str = nl_langinfo (ALTMON_2);
 441         str = nl_langinfo (ALTMON_3);
 442         str = nl_langinfo (ALTMON_4);
 443         str = nl_langinfo (ALTMON_5);
 444         str = nl_langinfo (ALTMON_6);
 445         str = nl_langinfo (ALTMON_7);
 446         str = nl_langinfo (ALTMON_8);
 447         str = nl_langinfo (ALTMON_9);
 448         str = nl_langinfo (ALTMON_10);
 449         str = nl_langinfo (ALTMON_11);
 450         str = nl_langinfo (ALTMON_12);
 451 ]])], [
 452         AC_MSG_RESULT([yes])
 453         AC_DEFINE([HAVE_LANGINFO_ALTMON], [1],
 454                 [Define if langinfo.h defines ALTMON_x constants])
 455 ], [
 456         AC_MSG_RESULT([no])
 457 ])
 458
 459
 460 AC_MSG_CHECKING([whether langinfo.h defines _NL_ABALTMON_x constants])
 461 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 462         #include <langinfo.h>
 463 ]], [[
 464         char *str;
 465         str = nl_langinfo (_NL_ABALTMON_1);
 466         str = nl_langinfo (_NL_ABALTMON_2);
 467         str = nl_langinfo (_NL_ABALTMON_3);
 468         str = nl_langinfo (_NL_ABALTMON_4);
 469         str = nl_langinfo (_NL_ABALTMON_5);
 470         str = nl_langinfo (_NL_ABALTMON_6);
 471         str = nl_langinfo (_NL_ABALTMON_7);
 472         str = nl_langinfo (_NL_ABALTMON_8);
 473         str = nl_langinfo (_NL_ABALTMON_9);
 474         str = nl_langinfo (_NL_ABALTMON_10);
 475         str = nl_langinfo (_NL_ABALTMON_11);
 476         str = nl_langinfo (_NL_ABALTMON_12);
 477 ]])], [
 478         AC_MSG_RESULT([yes])
 479         AC_DEFINE([HAVE_LANGINFO_NL_ABALTMON], [1],
 480                 [Define if langinfo.h defines _NL_ABALTMON_x constants])
 481 ], [
 482         AC_MSG_RESULT([no])
 483 ])
 484
 485
 486 dnl Convert some ac_cv_header_* variables to have_*
 487 dnl
 488 have_linux_blkzoned_h=$ac_cv_header_linux_blkzoned_h
 489 have_linux_btrfs_h=$ac_cv_header_linux_btrfs_h
 490 have_linux_capability_h=$ac_cv_header_linux_capability_h
 491 have_linux_kcmp_h=$ac_cv_header_linux_kcmp_h
 492 have_linux_mount_h=$ac_cv_header_linux_mount_h
 493 have_linux_pr_h=$ac_cv_header_linux_pr_h
 494 have_linux_raw_h=$ac_cv_header_linux_raw_h
 495 have_linux_securebits_h=$ac_cv_header_linux_securebits_h
 496 have_linux_version_h=$ac_cv_header_linux_version_h
 497 have_linux_watchdog_h=$ac_cv_header_linux_watchdog_h
 498 have_pty_h=$ac_cv_header_pty_h
 499 have_security_openpam_h=$ac_cv_header_security_openpam_h
 500 have_security_pam_appl_h=$ac_cv_header_security_pam_appl_h
 501 have_security_pam_misc_h=$ac_cv_header_security_pam_misc_h
 502 have_shadow_h=$ac_cv_header_shadow_h
 503 have_sys_signalfd_h=$ac_cv_header_sys_signalfd_h
 504 have_utmpx_h=$ac_cv_header_utmpx_h
 505 have_mntent_h=$ac_cv_header_mntent_h
 506
 507 AS_CASE([$linux_os:$have_linux_version_h],
 508   [yes:no],
 509     [AC_MSG_ERROR([kernel headers required on Linux])]
 510 )
 511
 512 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 513 #include <time.h>
 514 #include <unistd.h>
 515 ]], [[
 516     int a = 0;
 517     struct tm *tm = localtime(0);
 518     if (a == -1)  /* false */
 519         sleep(tm->tm_gmtoff);
 520 ]])],
 521 [AC_DEFINE([HAVE_TM_GMTOFF], [1], [Does struct tm have a field tm_gmtoff?])
 522 ])
 523
 524 AC_CHECK_TYPES([struct mount_attr], [], [], [[#include <linux/mount.h>]])
 525 AC_CHECK_TYPES([enum fsconfig_command], [], [], [[#include <linux/mount.h>]])
 526
 527 AC_CHECK_MEMBERS([struct termios.c_line],,,
 528     [[#include <termios.h>]])
 529
 530 AC_CHECK_MEMBERS([struct stat.st_mtim.tv_nsec],,,
 531     [[#include <sys/stat.h>]])
 532
 533 AC_CHECK_TYPES([struct statx], [], [], [[#include <sys/stat.h>]])
 534 AC_CHECK_MEMBERS([struct statx.stx_mnt_id],,,
 535     [[#include <sys/stat.h>]])
 536
 537 AC_CHECK_DECLS([_NL_TIME_WEEK_1STDAY],[],[],[[#include <langinfo.h>]])
 538
 539 AC_CHECK_DECL([environ],
 540         [AC_DEFINE([HAVE_ENVIRON_DECL], [1],
 541                 [Define to 1 if have **environ prototype])],
 542 )
 543
 544 AC_CHECK_DECL([strsignal],
 545         [AC_DEFINE([HAVE_STRSIGNAL_DECL], [1],
 546                 [Define to 1 if have strsignal function prototype])],
 547 )
 548
 549 AC_CHECK_DECL([TIOCGLCKTRMIOS],
 550               [have_tiocglcktrmios=yes], [have_tiocglcktrmios=no],
 551               [#include <sys/ioctl.h>])
 552 AC_CHECK_DECL([SOCK_CLOEXEC],
 553               [have_sock_cloexec=yes], [have_sock_cloexec=no],
 554               [#include <sys/types.h>
 555                #include <sys/socket.h>])
 556 AC_CHECK_DECL([SOCK_NONBLOCK],
 557               [have_sock_nonblock=yes], [have_sock_nonblock=no],
 558               [#include <sys/types.h>
 559                #include <sys/socket.h>])
 560 AC_CHECK_DECL([SO_PASSCRED],
 561               [have_so_passcred=yes], [have_so_passcred=no],
 562               [#include <sys/types.h>
 563                #include <sys/socket.h>])
 564
 565 AC_CHECK_FUNCS([ \
 566         cachestat \
 567         clearenv \
 568         close_range \
 569         eaccess \
 570         err \
 571         errx \
 572         explicit_bzero \
 573         __fpending \
 574         __fpurge \
 575         fpurge \
 576         fnmatch \
 577         fsconfig \
 578         fsmount \
 579         fsopen \
 580         fspick \
 581         fsync \
 582         getdomainname \
 583         getdtablesize \
 584         getexecname \
 585         getmntinfo \
 586         getrandom \
 587         getrlimit \
 588         getsgnam \
 589         getttynam \
 590         inotify_init \
 591         jrand48 \
 592         landlock_create_ruleset \
 593         landlock_add_rule \
 594         landlock_restrict_self \
 595         lchown \
 596         lgetxattr \
 597         llistxattr \
 598         llseek \
 599         newlocale \
 600         mempcpy \
 601         mkostemp \
 602         move_mount \
 603         mount_setattr \
 604         nanosleep \
 605         ntp_gettime \
 606         open_tree \
 607         personality \
 608         pidfd_open \
 609         pidfd_send_signal \
 610         posix_fadvise \
 611         prctl \
 612         qsort_r \
 613         reallocarray \
 614         renameat2 \
 615         rpmatch \
 616         scandirat \
 617         sched_setattr \
 618         sched_setscheduler \
 619         __secure_getenv \
 620         secure_getenv \
 621         sendfile \
 622         setprogname \
 623         setresgid \
 624         setresuid \
 625         sigqueue \
 626         srandom \
 627         statx \
 628         strnchr \
 629         strndup \
 630         strnlen \
 631         strtod_l \
 632         sysconf \
 633         sysinfo \
 634         timegm \
 635         usleep \
 636         uselocale \
 637         utimensat \
 638         vwarnx \
 639         warn \
 640         warnx \
 641 ])
 642 AC_FUNC_FSEEKO
 643
 644 AC_CHECK_FUNCS([futimens], [have_futimens=yes])
 645 AC_CHECK_FUNCS([getusershell], [have_getusershell=yes],[have_getusershell=no])
 646 AC_CHECK_FUNCS([inotify_init1], [have_inotify_init1=yes])
 647 AC_CHECK_FUNCS([ioperm iopl], [have_io=yes])
 648 AC_CHECK_FUNCS([openat fstatat unlinkat], [have_openat=yes], [have_openat=no])
 649 AC_CHECK_FUNCS([open_memstream], [have_open_memstream=yes],[have_open_memstream=no])
 650 AC_CHECK_FUNCS([reboot], [have_reboot=yes],[have_reboot=no])
 651 AC_CHECK_FUNCS([updwtmpx updwtmpx], [have_gnu_utmpx=yes], [have_gnu_utmpx=no])
 652
 653 AM_CONDITIONAL([HAVE_OPENAT], [test "x$have_openat" = xyes])
 654 AM_CONDITIONAL([HAVE_LINUX_LANDLOCK_H], [test "x$ac_cv_header_linux_landlock_h" = xyes])
 655
 656 have_setns_syscall="yes"
 657 UL_CHECK_SYSCALL([setns])
 658 AS_IF([test "x$ul_cv_syscall_setns" = xno], [
 659    have_setns_syscall="no"
 660 ])
 661
 662 UL_CHECK_SYSCALL([pidfd_open])
 663 UL_CHECK_SYSCALL([pidfd_send_signal])
 664 UL_CHECK_SYSCALL([close_range])
 665 UL_CHECK_SYSCALL([fsconfig])
 666 UL_CHECK_SYSCALL([fsmount])
 667 UL_CHECK_SYSCALL([fsopen])
 668 UL_CHECK_SYSCALL([fspick])
 669 UL_CHECK_SYSCALL([mount_setattr])
 670 UL_CHECK_SYSCALL([move_mount])
 671 UL_CHECK_SYSCALL([open_tree])
 672
 673 AS_IF([test "x$ul_cv_syscall_fsconfig" = xno ||
 674        test "x$ul_cv_syscall_fsmount" = xno ||
 675        test "x$ul_cv_syscall_fsopen" = xno ||
 676        test "x$ul_cv_syscall_fspick" = xno ||
 677        test "x$ul_cv_syscall_mount_setattr" = xno ||
 678        test "x$ul_cv_syscall_move_mount" = xno ||
 679        test "x$ul_cv_syscall_open_tree" = xno],
 680    [
 681         have_mountfd_api="no"
 682    ],[
 683         have_mountfd_api="yes"
 684         AC_DEFINE([HAVE_MOUNTFD_API], [1], [Define to 1 if you want mount API based on FDs.])
 685    ])
 686
 687
 688 AC_CHECK_FUNCS([isnan], [],
 689         [AC_CHECK_LIB([m], [isnan], [MATH_LIBS="-lm"])]
 690         [AC_CHECK_LIB([m], [__isnan], [MATH_LIBS="-lm"])]
 691 )
 692 AC_SUBST([MATH_LIBS])
 693
 694
 695 dnl lib/mononotic.c may require -lrt
 696 AC_CHECK_FUNCS([clock_gettime], [],
 697         [AC_CHECK_LIB([rt], [clock_gettime], [REALTIME_LIBS="-lrt"])]
 698 )
 699
 700 have_timer="no"
 701 AC_CHECK_FUNCS([timer_create],
 702         [have_timer="yes"],
 703         [AC_CHECK_LIB([rt], [timer_create], [
 704                 have_timer="yes"
 705                 REALTIME_LIBS="-lrt"
 706                 AC_DEFINE([HAVE_TIMER_CREATE], [1], [Define if timer_create exist in -lrt])
 707         ],[
 708                 AC_SEARCH_LIBS([timer_create], [rt], [
 709                         AC_MSG_RESULT(yes)
 710                         have_timer="yes"
 711                         REALTIME_LIBS="-lrt -lpthread"
 712                         AC_DEFINE([HAVE_TIMER_CREATE], [1], [Define if timer_create exist in -lrt -lpthread])
 713                 ],[], [-lpthread]
 714                 )
 715         ])]
 716 )
 717
 718 AC_SUBST([REALTIME_LIBS])
 719
 720 AS_IF([test x"$have_timer" = xno], [
 721        AC_CHECK_FUNCS([setitimer], [have_timer="yes"], [have_timer="no"])
 722 ])
 723
 724
 725 AC_CHECK_LIB([rtas], [rtas_get_sysparm], [
 726         RTAS_LIBS="-lrtas"
 727         AC_DEFINE([HAVE_LIBRTAS], [1], [Define if librtas exists])
 728 ])
 729 AC_SUBST([RTAS_LIBS])
 730
 731
 732 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 733                 AC_DEFINE([HAVE_SA_LEN], [1], [Define if struct sockaddr contains sa_len]), [],
 734         [#include <sys/types.h>
 735          #include <sys/socket.h>])
 736
 737 SOCKET_LIBS=
 738 AC_SEARCH_LIBS([socket], [socket],
 739         [AS_IF([test x"$ac_cv_search_socket" != x"none required"],
 740                 [SOCKET_LIBS="$SOCKET_LIBS -lsocket"])
 741 ])
 742 AC_SUBST([SOCKET_LIBS])
 743
 744
 745 have_dirfd=no
 746 AC_CHECK_FUNCS([dirfd], [have_dirfd=yes], [have_dirfd=no])
 747 AS_IF([test x"$have_dirfd" = xno], [
 748         AC_CHECK_DECLS([dirfd],
 749                 [have_dirfd=yes], [have_dirfd=no],
 750                 [#include <sys/types.h>
 751                  #include <dirent.h>])
 752 ])
 753
 754 have_ddfd=no
 755 AS_IF([test x"$have_dirfd" = xno], [
 756         AC_CHECK_MEMBERS([DIR.dd_fd],
 757                 [have_ddfd=yes], [have_ddfd=no],
 758                 [#include <sys/types.h>
 759                  #include <dirent.h>])
 760 ])
 761
 762 AM_CONDITIONAL([HAVE_DIRFD], [test "x$have_dirfd" = xyes || test "x$have_ddfd" = xyes])
 763
 764 MQ_LIBS=
 765 AC_CHECK_LIB([rt], [mq_open], [MQ_LIBS="-lrt"])
 766 AC_SUBST([MQ_LIBS])
 767
 768 AC_MSG_CHECKING([whether program_invocation_short_name is defined])
 769 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 770         #include <errno.h>
 771 ]], [[
 772         program_invocation_short_name = "test";
 773 ]])], [
 774         AC_MSG_RESULT([yes])
 775         AC_DEFINE([HAVE_PROGRAM_INVOCATION_SHORT_NAME], [1],
 776                 [Define if program_invocation_short_name is defined])
 777 ], [
 778         AC_MSG_RESULT([no])
 779 ])
 780
 781
 782 AC_MSG_CHECKING([whether __progname is defined])
 783 AC_LINK_IFELSE([AC_LANG_PROGRAM([extern char *__progname;],
 784            [if (*__progname == 0) return 1;])],
 785            AC_DEFINE([HAVE___PROGNAME], [1], [Define if __progname is defined])
 786            AC_MSG_RESULT([yes]),
 787            AC_MSG_RESULT([no]))
 788
 789 AC_CHECK_DECL([IOC_OPAL_GET_STATUS],
 790         [AC_DEFINE([HAVE_OPAL_GET_STATUS], [1],
 791                 [Define to 1 if OPAL status ioctl is defined])],,
 792               [#include <linux/sed-opal.h>])
 793
 794 dnl Static compilation
 795 m4_define([UL_STATIC_PROGRAMS], [blkid, fdisk, losetup, mount, nsenter, sfdisk, umount, unshare])
 796
 797 AC_ARG_ENABLE([static-programs],
 798   [AS_HELP_STRING([--enable-static-programs=LIST],
 799       [link static the programs in LIST (comma-separated,
 800       supported for ]m4_defn([UL_STATIC_PROGRAMS])[)])])
 801
 802 AS_CASE([$enable_static_programs],
 803   [yes],
 804     [enable_static_programs=m4_quote(UL_STATIC_PROGRAMS)],
 805   [no],
 806     [enable_static_programs=]
 807 )
 808
 809 dnl Set all the individual AM_CONDITIONALs
 810 m4_foreach([UL_PRG], m4_defn([UL_STATIC_PROGRAMS]), [
 811   AS_CASE([,$enable_static_programs,],
 812    [*,UL_PRG,*], [static_[]UL_PRG=yes]
 813   )
 814   AS_IF([test "x$static_[]UL_PRG" = xyes], [AC_MSG_NOTICE([enable static build: UL_PRG.])])
 815   AM_CONDITIONAL([HAVE_STATIC_]m4_toupper(UL_PRG),
 816     [test "x$static_[]UL_PRG" = xyes])
 817 ])
 818
 819
 820 AC_ARG_ENABLE([all-programs],
 821   AS_HELP_STRING([--disable-all-programs], [disable everything, might be overridden by --enable-<name>]),
 822   [], [enable_all_programs=undefined]
 823 )
 824
 825 AS_CASE([$enable_all_programs],
 826   [yes], [AC_MSG_WARN([force to build all programs by default])
 827           ul_default_estate=check],
 828   [no],  [AC_MSG_WARN([disable all programs and man pages by default])
 829           ul_default_estate=no]
 830 )
 831
 832
 833 AC_ARG_ENABLE([asciidoc],
 834   AS_HELP_STRING([--disable-asciidoc], [do not generate man pages from asciidoc]),
 835   [], [UL_DEFAULT_ENABLE([asciidoc], [check])]
 836 )
 837 UL_BUILD_INIT([asciidoc])
 838 UL_REQUIRES_PROGRAM([asciidoc], [ASCIIDOCTOR], [asciidoctor], [man pages])
 839 AM_CONDITIONAL([ENABLE_ASCIIDOC], [test "x$build_asciidoc" = xyes])
 840 have_asciidoctor_failure_level=no
 841 AS_IF([test "x$build_asciidoc" = xyes], [
 842        AC_MSG_CHECKING([whether ${ASCIIDOCTOR} supports --failure-level])
 843        AS_IF([${ASCIIDOCTOR} --help | grep failure-level >/dev/null 2>&1 ], [
 844          AC_MSG_RESULT([yes])
 845          have_asciidoctor_failure_level=yes
 846        ], [
 847          AC_MSG_RESULT([no])
 848        ])
 849 ])
 850 AM_CONDITIONAL([HAVE_ASCIIDOCTOR_FAILURE_LEVEL], [test "x$have_asciidoctor_failure_level" = xyes])
 851
 852 have_manpages=no
 853 AS_IF([test -f "$srcdir/sys-utils/mount.8"], [
 854    AC_MSG_NOTICE([re-use already generated man-pages.])
 855    have_manpages=yes]
 856 )
 857 AM_CONDITIONAL([HAVE_MANPAGES], [test "x$have_manpages" = xyes])
 858
 859
 860 AC_ARG_ENABLE([poman],
 861   AS_HELP_STRING([--disable-poman], [generate translated man pages]),
 862   [], [UL_DEFAULT_ENABLE([poman], [check])]
 863 )
 864 UL_BUILD_INIT([poman])
 865 UL_REQUIRES_PROGRAM([poman], [PO4A], [po4a], [translated man pages])
 866 AM_CONDITIONAL([ENABLE_POMAN], [test "x$build_poman" = xyes])
 867
 868
 869 AX_CHECK_TLS
 870
 871 have_pty=no
 872 AC_ARG_WITH([util], AS_HELP_STRING([--without-util], [compile without libutil]),
 873   [], [with_util=auto]
 874 )
 875 AS_IF([test "x$with_util" = xno], [
 876   AM_CONDITIONAL([HAVE_UTIL], [false])
 877   have_util=no
 878 ], [
 879   UL_CHECK_LIB([util], [openpty])
 880 ])
 881
 882 AS_IF([test "x$have_pty_h" = xyes && test "x$have_sys_signalfd_h" = xyes && test "x$have_util" = xyes], [
 883    AM_CONDITIONAL([HAVE_PTY], [true])
 884    AC_DEFINE([HAVE_PTY], [1], [have PTY support])
 885    have_pty=yes
 886 ], [
 887    AM_CONDITIONAL([HAVE_PTY], [false])
 888 ])
 889
 890 AC_CHECK_TYPES([union semun], [], [], [[
 891 #include <sys/sem.h>
 892 ]])
 893 AC_CHECK_TYPES([loff_t])
 894
 895
 896 AC_ARG_ENABLE([widechar],
 897   AS_HELP_STRING([--disable-widechar], [do not compile wide character support]),
 898   [], [enable_widechar=check]
 899 )
 900 UL_BUILD_INIT([widechar])
 901 UL_REQUIRES_COMPILE([widechar], [[
 902   #include <wchar.h>
 903   #include <wctype.h>
 904   #include <stdio.h>
 905   #include <stdlib.h>
 906   ]], [[
 907     wchar_t wc;
 908     wint_t w;
 909     w = fgetwc(stdin);
 910     if (w == WEOF) exit(1);
 911     wc = w;
 912     fputwc(wc,stdout);
 913   ]],
 914   [wchar_t support])
 915
 916 AS_IF([test "x$build_widechar" = xyes ], [
 917   AC_DEFINE([HAVE_WIDECHAR], [1], [Do we have wide character support?])
 918 ])
 919
 920
 921 AC_CHECK_TYPES([cpu_set_t], [have_cpu_set_t=yes], [], [[
 922 #include <sched.h>
 923 ]])
 924
 925 AM_CONDITIONAL([HAVE_CPU_SET_T], [test "x$have_cpu_set_t" = xyes])
 926
 927 AC_CHECK_TYPES([sighandler_t], [], [], [[
 928 #include <signal.h>
 929 ]])
 930
 931 AC_CHECK_DECLS([CPU_ALLOC], [], [], [[
 932 #include <sched.h>
 933 ]])
 934
 935 # on Solaris, you can't mix and match standards, since we use c99
 936 # apparently at this stage, XOPEN_SOURCE will conflict.  As workaround,
 937 # check for crypt.h and use that without XOPEN_SOURCE.
 938 have_crypt=no
 939 AC_CHECK_HEADERS([crypt.h])
 940 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 941 #ifdef HAVE_CRYPT_H
 942 #include <crypt.h>
 943 #else
 944 #define _XOPEN_SOURCE
 945 #include <unistd.h>
 946 #endif
 947 ]], [[
 948 char *c = crypt("abc","pw");
 949 ]])],[
 950   have_libcrypt=no
 951   have_crypt=yes
 952 ],[
 953   UL_SET_LIBS([-lcrypt])
 954   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 955   #ifdef HAVE_CRYPT_H
 956   #include <crypt.h>
 957   #else
 958   #define _XOPEN_SOURCE
 959   #include <unistd.h>
 960   #endif
 961   ]], [[
 962   char *c = crypt("abc","pw");
 963   ]])],[
 964   have_libcrypt=yes
 965   have_crypt=yes
 966   ],[
 967   AC_MSG_WARN([crypt() is not available])
 968   ])
 969   UL_RESTORE_LIBS
 970 ])
 971 AM_CONDITIONAL([HAVE_LIBCRYPT], [test "x$have_libcrypt" = xyes])
 972
 973
 974 AC_ARG_WITH([selinux],
 975   AS_HELP_STRING([--with-selinux], [compile with SELinux support]),
 976   [], [with_selinux=no]
 977 )
 978
 979 AS_IF([test "x$with_selinux" = xno], [
 980   AM_CONDITIONAL([HAVE_SELINUX], [false])
 981 ], [
 982   PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.5], [have_selinux=yes], [have_selinux=no])
 983   AS_CASE([$with_selinux:$have_selinux],
 984     [yes:no], [AC_MSG_ERROR([SELinux selected but libselinux not found or too old])]
 985   )
 986   AS_IF([test "x$have_selinux" = xyes], [
 987     AC_DEFINE([HAVE_LIBSELINUX], [1], [Define if SELinux is available])
 988     UL_PKG_STATIC([SELINUX_LIBS_STATIC], [libselinux])
 989     AM_CONDITIONAL([HAVE_SELINUX], [true])
 990
 991     UL_SET_LIBS([$SELINUX_LIBS])
 992     # This function is missing in old libselinux 1.xx versions
 993     AC_CHECK_FUNCS([security_get_initial_context])
 994     UL_RESTORE_LIBS
 995   ])
 996 ])
 997 AC_SUBST([SELINUX_LIBS])
 998 AC_SUBST([SELINUX_LIBS_STATIC])
 999
1000
1001 AC_ARG_WITH([audit],
1002   AS_HELP_STRING([--with-audit], [compile with audit support]),
1003   [], [with_audit=no]
1004 )
1005
1006 AS_IF([test "x$with_audit" = xno], [
1007   AM_CONDITIONAL([HAVE_AUDIT], [false])
1008 ], [
1009   UL_CHECK_LIB([audit], [audit_log_user_message])
1010   AS_CASE([$with_audit:$have_audit],
1011     [yes:no],
1012       [AC_MSG_ERROR([Audit selected but libaudit not found (or does not support audit_log_user_message())])]
1013   )
1014 ])
1015
1016 AC_ARG_WITH([udev], AS_HELP_STRING([--without-udev], [compile without udev support]),
1017   [], [with_udev=auto]
1018 )
1019
1020 AS_IF([test "x$with_udev" = xno], [
1021   AM_CONDITIONAL([HAVE_UDEV], [false])
1022 ], [
1023   UL_CHECK_LIB([udev], [udev_new])
1024   AS_CASE([$with_udev:$have_udev],
1025     [yes:no],
1026       [AC_MSG_ERROR([udev selected but libudev not found])]
1027   )
1028 ])
1029
1030
1031 dnl wide-char ncurses
1032 AC_ARG_WITH([ncursesw],
1033   AS_HELP_STRING([--without-ncursesw], [do not build with wide-char ncurses]),
1034   [], [with_ncursesw=auto]
1035 )
1036 have_ncursesw=no
1037 have_ncursesw_header=no
1038 AS_IF([test "x$with_ncursesw" != xno], [
1039   UL_NCURSES_CHECK([ncursesw])
1040   AS_IF([test "x$have_ncursesw" = xyes], [
1041     AC_CHECK_HEADERS([ncursesw/ncurses.h], [have_ncursesw_header=yes])
1042     AC_CHECK_HEADERS([ncursesw/term.h])
1043
1044     # Define HAVE_NCURSES_H only if check for HAVE_NCURSESW_NCURSES_H is
1045     # unsuccessful to avoid too many *_H permitations in config.h
1046     AS_IF([test "x$have_ncursesw_header" = xno], [
1047            AC_CHECK_HEADERS([ncurses.h], [have_ncursesw_header=yes])
1048            AC_CHECK_HEADERS([term.h])
1049     ])
1050     AS_IF([test "x$have_ncursesw_header" = xno], [have_ncursesw=no])
1051   ])
1052   AS_IF([test "x$have_ncursesw" = xyes], [
1053     CURSES_LIB_NAME="ncursesw"
1054     AC_DEFINE([HAVE_LIBNCURSESW], [1], [Define if ncursesw library available])
1055   ])
1056 ])
1057 AS_CASE([$with_ncursesw:$have_ncursesw],
1058   [yes:no], [AC_MSG_ERROR([ncursesw selected, but library not found])])
1059
1060
1061 dnl non-wide ncurses
1062 AC_ARG_WITH([ncurses],
1063   AS_HELP_STRING([--with-ncurses], [build with non-wide ncurses]),
1064   [], [with_ncurses=auto]
1065 )
1066 have_ncurses=no
1067 have_ncurses_header=no
1068 AS_CASE([$with_ncurses:$build_widechar],
1069   [yes:yes], [AC_MSG_ERROR([wide-char support enabled, but non-wide ncurses selects])])
1070
1071 AS_IF([test "x$have_ncursesw" = xno && test "x$with_ncurses" != xno ], [
1072   UL_NCURSES_CHECK([ncurses])
1073   AS_IF([test "x$have_ncurses" = xyes], [
1074     AC_CHECK_HEADERS([ncurses/ncurses.h], [have_ncurses_header=yes])
1075     AC_CHECK_HEADERS([ncurses/term.h])
1076
1077     # Define HAVE_NCURSES_H only if check for HAVE_NCURSES_NCURSES_H is
1078     # unsuccessful to avoid too many *_H permitations in config.h
1079     AS_IF([test "x$have_ncurses_header" = xno], [
1080            AC_CHECK_HEADERS([ncurses.h], [have_ncurses_header=yes])
1081            AC_CHECK_HEADERS([term.h])
1082     ])
1083     AS_IF([test "x$have_ncurses_header" = xno], [have_ncurses=no])
1084   ])
1085   AS_IF([test "x$have_ncurses" = xyes], [
1086     CURSES_LIB_NAME="ncurses"
1087     AC_DEFINE([HAVE_LIBNCURSES], [1], [Define if ncurses library available])
1088   ])
1089 ])
1090 AS_CASE([$with_ncurses:$have_ncurses],
1091   [yes:no], [AC_MSG_ERROR([ncurses selected, but library not found])])
1092
1093 AC_SUBST([NCURSES_CFLAGS])
1094 AC_SUBST([NCURSES_LIBS])
1095 AM_CONDITIONAL([HAVE_NCURSES], [test "x$have_ncursesw" = xyes || test "x$have_ncurses" = xyes])
1096
1097
1098 AC_ARG_WITH([slang],
1099   AS_HELP_STRING([--with-slang], [compile cfdisk with slang rather than ncurses]),
1100   [], [with_slang=no]
1101 )
1102 have_slang=no
1103 AS_IF([test "x$with_slang" = xyes], [
1104   AC_CHECK_HEADERS([slang.h slang/slang.h])
1105   AC_CHECK_HEADERS([slcurses.h slang/slcurses.h],
1106                    [have_slang=yes], [], [
1107 #ifdef HAVE_SLANG_H
1108 #include <slang.h>
1109 #elif defined(HAVE_SLANG_SLANG_H)
1110 #include <slang/slang.h>
1111 #endif
1112 ])
1113   AS_IF([test "x$have_slang" = xno], [
1114     AC_MSG_ERROR([slang selected but slcurses.h not found])],
1115     [CURSES_LIB_NAME=slang
1116   ])
1117 ])
1118 AM_CONDITIONAL([HAVE_SLANG], [test "x$have_slang" = xyes])
1119
1120
1121 AS_IF([test "x$have_slang" = xyes || test "x$have_ncursesw" = xyes || test "x$have_ncurses" = xyes], [
1122         AC_CHECK_LIB([$CURSES_LIB_NAME], use_default_colors, [
1123                      AC_DEFINE(HAVE_USE_DEFAULT_COLORS, 1,
1124                                [Define if curses library has the use_default_colors().])
1125         ])
1126         AC_CHECK_LIB([$CURSES_LIB_NAME], resizeterm, [
1127                      AC_DEFINE(HAVE_RESIZETERM, 1,
1128                                [Define if curses library has the resizeterm().])
1129         ])
1130 ])
1131
1132
1133 AC_ARG_WITH([tinfo], AS_HELP_STRING([--without-tinfo], [compile without libtinfo]),
1134   [], [with_tinfo=auto]
1135 )
1136 have_tinfo=no
1137 have_tinfow=no
1138 AS_IF([test "x$with_tinfo" != xno], [
1139   AS_IF([test "x$have_ncursesw" = xyes], [
1140     UL_TINFO_CHECK([tinfow])
1141   ])
1142   AS_IF([test "x$have_tinfow" = xno], [
1143     UL_TINFO_CHECK([tinfo])
1144   ])
1145 ])
1146 AC_SUBST([TINFO_LIBS])
1147 AC_SUBST([TINFO_LIBS_STATIC])
1148 AC_SUBST([TINFO_CFLAGS])
1149 AM_CONDITIONAL([HAVE_TINFO], [test "x$have_tinfo" = xyes || test "x$have_tinfow" = xyes])
1150 AS_IF([test "x$have_tinfo" = xyes || test "x$have_tinfow" = xyes], [
1151   AC_DEFINE(HAVE_LIBTINFO, 1, [Define if libtinfo or libtinfow available.])
1152 ])
1153
1154
1155 AC_ARG_WITH([readline],
1156   AS_HELP_STRING([--without-readline], [do not build with GNU Readline support]),
1157   [], [with_readline=auto]
1158 )
1159
1160 AS_IF([test "x$with_readline" = xno], [
1161   AM_CONDITIONAL([HAVE_READLINE], [false])
1162 ], [
1163   UL_CHECK_LIB([readline], [readline])
1164   AS_CASE([$with_readline:$have_readline],
1165     [yes:no],
1166       [AC_MSG_ERROR([readline selected but libreadline not found ])],
1167     [*:yes],
1168       [READLINE_LIBS="-lreadline"
1169        READLINE_LIBS_STATIC="-lreadline $TINFO_LIBS_STATIC"]
1170   )
1171 ])
1172 AC_SUBST([READLINE_LIBS])
1173 AC_SUBST([READLINE_LIBS_STATIC])
1174
1175
1176 AC_ARG_WITH([utempter],
1177   AS_HELP_STRING([--with-utempter], [compile script(1) with libutempter]),
1178   [], [with_utempter=no]
1179 )
1180
1181 AS_IF([test "x$with_utempter" = xyes], [
1182   UL_CHECK_LIB([utempter], [utempter_add_record])
1183   AS_IF([test "x$have_utempter" = xno], [
1184     AC_MSG_ERROR([utempter selected but libutempter not found])
1185   ])
1186 ], [
1187   AM_CONDITIONAL([HAVE_UTEMPTER], [false])
1188 ])
1189
1190
1191 dnl
1192 dnl libuuid
1193 dnl
1194 AC_ARG_ENABLE([libuuid],
1195   AS_HELP_STRING([--disable-libuuid], [do not build libuuid and uuid utilities]),
1196   [], [UL_DEFAULT_ENABLE([libuuid], [yes])]
1197 )
1198 UL_BUILD_INIT([libuuid])
1199 AC_SUBST([LIBUUID_VERSION])
1200 AC_SUBST([LIBUUID_VERSION_INFO])
1201 AM_CONDITIONAL(BUILD_LIBUUID, test "x$build_libuuid" = xyes)
1202
1203 AC_ARG_ENABLE([libuuid-force-uuidd],
1204   AS_HELP_STRING([--enable-libuuid-force-uuidd], [support uuidd even though the daemon is not built]),
1205   [], [enable_libuuid_force_uuidd=no]
1206 )
1207
1208 AS_IF([test "x$build_libuuid" = xyes], [
1209   AC_DEFINE(HAVE_LIBUUID, 1, [Define to 1 if you have the -luuid.])
1210 ])
1211
1212 dnl
1213 dnl libblkid
1214 dnl
1215 AC_ARG_ENABLE([libblkid],
1216   AS_HELP_STRING([--disable-libblkid], [do not build libblkid and many related utilities]),
1217   [], [UL_DEFAULT_ENABLE([libblkid], [check])]
1218 )
1219 UL_BUILD_INIT([libblkid])
1220 UL_REQUIRES_HAVE([libblkid], [openat], [openat functions])
1221 UL_REQUIRES_HAVE([libblkid], [dirfd,ddfd], [dirfd or ddfd function])
1222 AC_SUBST([LIBBLKID_DATE])
1223 AC_SUBST([LIBBLKID_VERSION])
1224 AC_SUBST([LIBBLKID_VERSION_INFO])
1225 AC_DEFINE_UNQUOTED([LIBBLKID_VERSION], ["$LIBBLKID_VERSION"], [libblkid version string])
1226 AC_DEFINE_UNQUOTED([LIBBLKID_DATE], ["$LIBBLKID_DATE"], [libblkid date string])
1227 AS_IF([test "x$build_libblkid" = xyes], [
1228   AC_DEFINE([HAVE_LIBBLKID], [1], [Define to 1 if you have the -lblkid.])
1229 ])
1230 AM_CONDITIONAL([BUILD_LIBBLKID], [test "x$build_libblkid" = xyes])
1231 AM_CONDITIONAL([BUILD_LIBBLKID_TESTS], [test "x$build_libblkid" = xyes && test "x$enable_static" = xyes])
1232
1233 dnl
1234 dnl libmount
1235 dnl
1236 AC_ARG_ENABLE([libmount],
1237   AS_HELP_STRING([--disable-libmount], [do not build libmount]),
1238   [], [UL_DEFAULT_ENABLE([libmount], [check])]
1239 )
1240 UL_BUILD_INIT([libmount])
1241 UL_REQUIRES_BUILD([libmount], [libblkid])
1242 UL_REQUIRES_HAVE([libmount], [dirfd,ddfd], [dirfd or ddfd function])
1243 UL_REQUIRES_HAVE([libmount], [mntent_h], [mntent.h header file])
1244 AM_CONDITIONAL([BUILD_LIBMOUNT], [test "x$build_libmount" = xyes])
1245 AM_CONDITIONAL([BUILD_LIBMOUNT_TESTS], [test "x$build_libmount" = xyes && test "x$enable_static" = xyes])
1246 AS_IF([test "x$build_libmount" = xyes], [
1247   AC_DEFINE(HAVE_LIBMOUNT, 1, [Define if libmount available.])
1248   AS_IF([test "x$have_setns_syscall" = "xyes"], [
1249     AC_DEFINE([USE_LIBMOUNT_SUPPORT_NAMESPACES], [1], [Define to 1 if want to support namepaces.])
1250   ],[
1251     AC_MSG_WARN([libmount will be compiled without namespaces support])
1252   ])
1253 ])
1254
1255 AC_SUBST([LIBMOUNT_VERSION])
1256 AC_SUBST([LIBMOUNT_MAJOR_VERSION], $PACKAGE_VERSION_MAJOR)
1257 AC_SUBST([LIBMOUNT_MINOR_VERSION], $PACKAGE_VERSION_MINOR)
1258 AC_SUBST([LIBMOUNT_PATCH_VERSION], $PACKAGE_VERSION_RELEASE)
1259 AC_SUBST([LIBMOUNT_VERSION_INFO])
1260 AC_DEFINE_UNQUOTED([LIBMOUNT_VERSION], ["$LIBMOUNT_VERSION"], [libmount version string])
1261
1262 AC_ARG_ENABLE([libmount-mountfd-support],
1263   AS_HELP_STRING([--disable-libmount-mountfd-support], [do not use new mount API based on FDs]),
1264   [], [enable_libmount_mountfd_support=check]
1265 )
1266 UL_BUILD_INIT([libmount_mountfd_support])
1267 UL_REQUIRES_BUILD([libmount_mountfd_support], [libmount])
1268 UL_REQUIRES_LINUX([libmount_mountfd_support])
1269 UL_REQUIRES_HAVE([libmount_mountfd_support], [mountfd_api], [mount FDs based API])
1270 UL_REQUIRES_HAVE([libmount_mountfd_support], [linux_mount_h], [linux/mount.h])
1271 AS_IF([test "x$build_libmount_mountfd_support" = xyes ], [
1272   AC_DEFINE([USE_LIBMOUNT_MOUNTFD_SUPPORT], [1], [Enable support for new mount FD based kernel API])
1273 ])
1274
1275
1276 dnl
1277 dnl libsmartcols
1278 dnl
1279 AC_ARG_ENABLE([libsmartcols],
1280   AS_HELP_STRING([--disable-libsmartcols], [do not build libsmartcols]),
1281   [], [UL_DEFAULT_ENABLE([libsmartcols], [yes])]
1282 )
1283 UL_BUILD_INIT([libsmartcols])
1284 AM_CONDITIONAL([BUILD_LIBSMARTCOLS], [test "x$build_libsmartcols" = xyes])
1285
1286 AC_SUBST([LIBSMARTCOLS_VERSION])
1287 AC_SUBST([LIBSMARTCOLS_VERSION_INFO])
1288 AC_DEFINE_UNQUOTED([LIBSMARTCOLS_VERSION], ["$LIBSMARTCOLS_VERSION"], [libsmartcols version string])
1289
1290
1291 dnl
1292 dnl libfdisk
1293 dnl
1294 AC_ARG_ENABLE([libfdisk],
1295   AS_HELP_STRING([--disable-libfdisk], [do not build libfdisk]),
1296   [], [UL_DEFAULT_ENABLE([libfdisk], [check])]
1297 )
1298 UL_BUILD_INIT([libfdisk])
1299 UL_REQUIRES_BUILD([libfdisk], [libuuid])
1300 AM_CONDITIONAL([BUILD_LIBFDISK], [test "x$build_libfdisk" = xyes])
1301 AM_CONDITIONAL([BUILD_LIBFDISK_TESTS], [test "x$build_libfdisk" = xyes && test "x$enable_static" = xyes])
1302
1303 AS_IF([test "x$build_libblkid" = xyes],
1304   [LIBFDISK_PC_REQUIRES="uuid blkid"],[LIBFDISK_PC_REQUIRES="uuid"])
1305 AC_SUBST([LIBFDISK_PC_REQUIRES])
1306
1307 AC_SUBST([LIBFDISK_VERSION])
1308 AC_SUBST([LIBFDISK_MAJOR_VERSION], $PACKAGE_VERSION_MAJOR)
1309 AC_SUBST([LIBFDISK_MINOR_VERSION], $PACKAGE_VERSION_MINOR)
1310 AC_SUBST([LIBFDISK_PATCH_VERSION], $PACKAGE_VERSION_RELEASE)
1311 AC_SUBST([LIBFDISK_VERSION_INFO])
1312 AC_DEFINE_UNQUOTED([LIBFDISK_VERSION], ["$LIBFDISK_VERSION"], [libfdisk version string])
1313
1314
1315 AC_ARG_ENABLE([fdisks],
1316   AS_HELP_STRING([--disable-fdisks], [do not build fdisk(8), sfdisk(8) and cfdisk(8)]),
1317   [], [UL_DEFAULT_ENABLE([fdisks], [check])]
1318 )
1319 enable_fdisk=$enable_fdisks
1320 enable_sfdisk=$enable_fdisks
1321 enable_cfdisk=$enable_fdisks
1322
1323 UL_BUILD_INIT([fdisk])
1324 UL_REQUIRES_HAVE([fdisk], [openat], [openat functions])
1325 UL_REQUIRES_HAVE([fdisk], [dirfd,ddfd], [dirfd or ddfd function])
1326 UL_REQUIRES_BUILD([fdisk], [libfdisk])
1327 UL_REQUIRES_BUILD([fdisk], [libsmartcols])
1328 AM_CONDITIONAL([BUILD_FDISK], [test "x$build_fdisk" = xyes])
1329
1330
1331 UL_BUILD_INIT([sfdisk])
1332 UL_REQUIRES_HAVE([sfdisk], [openat], [openat functions])
1333 UL_REQUIRES_HAVE([sfdisk], [dirfd,ddfd], [dirfd or ddfd function])
1334 UL_REQUIRES_BUILD([sfdisk], [libfdisk])
1335 UL_REQUIRES_BUILD([sfdisk], [libsmartcols])
1336 AM_CONDITIONAL([BUILD_SFDISK], [test "x$build_sfdisk" = xyes])
1337
1338
1339 UL_BUILD_INIT([cfdisk])
1340 UL_REQUIRES_BUILD([cfdisk], [libfdisk])
1341 UL_REQUIRES_BUILD([cfdisk], [libsmartcols])
1342 UL_REQUIRES_HAVE([cfdisk], [open_memstream], [open_memstream function])
1343 UL_REQUIRES_HAVE([cfdisk], [ncursesw,slang,ncurses], [ncursesw, ncurses or slang library])
1344 AM_CONDITIONAL([BUILD_CFDISK], [test "x$build_cfdisk" = xyes])
1345
1346
1347 AC_ARG_ENABLE([mount],
1348   AS_HELP_STRING([--disable-mount], [do not build mount(8) and umount(8)]),
1349   [], [UL_DEFAULT_ENABLE([mount], [check])]
1350 )
1351 UL_BUILD_INIT([mount])
1352 UL_REQUIRES_LINUX([mount])
1353 UL_REQUIRES_BUILD([mount], [libmount])
1354 AM_CONDITIONAL([BUILD_MOUNT], [test "x$build_mount" = xyes])
1355
1356
1357 AC_ARG_ENABLE([losetup],
1358   AS_HELP_STRING([--disable-losetup], [do not build losetup]),
1359   [], [UL_DEFAULT_ENABLE([losetup], [check])]
1360 )
1361 UL_BUILD_INIT([losetup])
1362 UL_REQUIRES_LINUX([losetup])
1363 UL_REQUIRES_BUILD([losetup], [libsmartcols])
1364 AM_CONDITIONAL([BUILD_LOSETUP], [test "x$build_losetup" = xyes])
1365
1366 AC_ARG_ENABLE([zramctl],
1367   AS_HELP_STRING([--disable-zramctl], [do not build zramctl]),
1368   [], [UL_DEFAULT_ENABLE([zramctl], [check])]
1369 )
1370 UL_BUILD_INIT([zramctl])
1371 UL_REQUIRES_LINUX([zramctl])
1372 UL_REQUIRES_BUILD([zramctl], [libsmartcols])
1373 AM_CONDITIONAL([BUILD_ZRAMCTL], [test "x$build_zramctl" = xyes])
1374
1375 AC_ARG_ENABLE([fsck],
1376   AS_HELP_STRING([--disable-fsck], [do not build fsck]),
1377   [], [UL_DEFAULT_ENABLE([fsck], [check])]
1378 )
1379 UL_BUILD_INIT([fsck])
1380 UL_REQUIRES_BUILD([fsck], [libmount])
1381 AM_CONDITIONAL([BUILD_FSCK], [test "x$build_fsck" = xyes])
1382
1383
1384 AC_ARG_ENABLE([partx],
1385   AS_HELP_STRING([--disable-partx], [do not build addpart, delpart, partx]),
1386   [], [UL_DEFAULT_ENABLE([partx], [check])]
1387 )
1388 UL_BUILD_INIT([partx])
1389 UL_REQUIRES_LINUX([partx])
1390 UL_REQUIRES_BUILD([partx], [libblkid])
1391 UL_REQUIRES_BUILD([partx], [libsmartcols])
1392 AM_CONDITIONAL([BUILD_PARTX], [test "x$build_partx" = xyes])
1393
1394
1395 AC_ARG_ENABLE([uuidd],
1396   AS_HELP_STRING([--disable-uuidd], [do not build the uuid daemon]),
1397   [], [UL_DEFAULT_ENABLE([uuidd], [check])]
1398 )
1399 UL_BUILD_INIT([uuidd])
1400 UL_REQUIRES_BUILD([uuidd], [libuuid])
1401 UL_REQUIRES_HAVE([uuidd], [timer], [timer_create function])
1402 UL_REQUIRES_HAVE([uuidd], [sys_signalfd_h], [sys/signalfd.h header])
1403 AS_IF([test "x$build_uuidd" = xyes || test "x$enable_libuuid_force_uuidd" = xyes], [
1404   AC_DEFINE([HAVE_UUIDD], [1], [Define to 1 if you want to use uuid daemon.])
1405 ])
1406 AM_CONDITIONAL([BUILD_UUIDD], [test "x$build_uuidd" = xyes])
1407
1408
1409 AC_ARG_ENABLE([uuidgen],
1410   AS_HELP_STRING([--disable-uuidgen], [do not build uuidgen]),
1411   [], [UL_DEFAULT_ENABLE([uuidgen], [check])]
1412 )
1413 UL_BUILD_INIT([uuidgen])
1414 UL_REQUIRES_BUILD([uuidgen], [libuuid])
1415 AM_CONDITIONAL([BUILD_UUIDGEN], [test "x$build_uuidgen" = xyes])
1416
1417 UL_BUILD_INIT([uuidparse], [check])
1418 UL_REQUIRES_BUILD([uuidparse], [libuuid])
1419 UL_REQUIRES_BUILD([uuidparse], [libsmartcols])
1420 AM_CONDITIONAL([BUILD_UUIDPARSE], [test "x$build_uuidparse" = xyes])
1421
1422 AC_ARG_ENABLE([blkid],
1423   AS_HELP_STRING([--disable-blkid], [do not build blkid(8)]),
1424   [], [UL_DEFAULT_ENABLE([blkid], [check])]
1425 )
1426 UL_BUILD_INIT([blkid])
1427 UL_REQUIRES_BUILD([blkid], [libblkid])
1428 AM_CONDITIONAL([BUILD_BLKID], [test "x$build_blkid" = xyes])
1429
1430 UL_BUILD_INIT([findfs], [check])
1431 UL_REQUIRES_BUILD([findfs], [libblkid])
1432 AM_CONDITIONAL([BUILD_FINDFS], [test "x$build_findfs" = xyes])
1433
1434 AC_ARG_ENABLE([wipefs],
1435   AS_HELP_STRING([--disable-wipefs], [do not build wipefs]),
1436   [], [UL_DEFAULT_ENABLE([wipefs], [check])]
1437 )
1438 UL_BUILD_INIT([wipefs])
1439 UL_REQUIRES_BUILD([wipefs], [libblkid])
1440 UL_REQUIRES_BUILD([wipefs], [libsmartcols])
1441 AM_CONDITIONAL([BUILD_WIPEFS], [test "x$build_wipefs" = xyes])
1442
1443 UL_BUILD_INIT([findmnt], [check])
1444 UL_REQUIRES_BUILD([findmnt], [libmount])
1445 UL_REQUIRES_BUILD([findmnt], [libblkid])
1446 UL_REQUIRES_BUILD([findmnt], [libsmartcols])
1447 AM_CONDITIONAL([BUILD_FINDMNT], [test "x$build_findmnt" = xyes])
1448
1449
1450 AC_ARG_ENABLE([mountpoint],
1451   AS_HELP_STRING([--disable-mountpoint], [do not build mountpoint]),
1452   [], [UL_DEFAULT_ENABLE([mountpoint], [check])]
1453 )
1454 UL_BUILD_INIT([mountpoint])
1455 UL_REQUIRES_BUILD([mountpoint], [libmount])
1456 AM_CONDITIONAL([BUILD_MOUNTPOINT], [test "x$build_mountpoint" = xyes])
1457
1458
1459 AC_ARG_ENABLE([fallocate],
1460   AS_HELP_STRING([--disable-fallocate], [do not build fallocate]),
1461   [], [UL_DEFAULT_ENABLE([fallocate], [check])]
1462 )
1463 UL_BUILD_INIT([fallocate])
1464 UL_REQUIRES_LINUX([fallocate])
1465 UL_REQUIRES_SYSCALL_CHECK([fallocate], [UL_CHECK_SYSCALL([fallocate])])
1466 AM_CONDITIONAL([BUILD_FALLOCATE], [test "x$build_fallocate" = xyes])
1467
1468 AS_IF([test "x$build_fallocate" = xyes], [
1469   dnl check for valid fallocate() function
1470   dnl with 32 bits glibc 2.10, fallocate() exists but not fallocate64()
1471   dnl when _FILE_OFFSET_BITS==64, fallocate() is redirect to fallocate64()
1472   dnl and program can't be linked.
1473   dnl AC_CHECK_FUNC can't catch such errors since it's redefining
1474   dnl function prototype.
1475   AC_MSG_CHECKING([for valid fallocate() function])
1476   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1477 #ifdef HAVE_UNISTD_H
1478 # include <unistd.h>
1479 #endif
1480 #ifdef HAVE_SYS_TYPES_H
1481 # include <sys/types.h>
1482 #endif
1483 #ifdef HAVE_LINUX_FALLOC_H
1484 # include <linux/falloc.h>
1485 #endif
1486 #ifdef HAVE_FCNTL_H
1487 # include <fcntl.h>
1488 #endif
1489 ]],[[
1490    long ret;
1491    ret = fallocate(0, FALLOC_FL_KEEP_SIZE, 0xfffffffful, 0xfffffffful);
1492    if (ret != 0) {
1493       return 1;
1494    }
1495    ]])],[
1496   AC_MSG_RESULT([yes])
1497   AC_DEFINE([HAVE_FALLOCATE], [1], [Have valid fallocate() function])],[
1498   AC_MSG_RESULT([no])])
1499 ])
1500
1501 AS_IF([test "x$build_fallocate" = xyes], [
1502   dnl check for valid posix_fallocate() function
1503   AC_MSG_CHECKING([for valid posix_fallocate() function])
1504   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1505 #ifdef HAVE_UNISTD_H
1506 # include <unistd.h>
1507 #endif
1508 #ifdef HAVE_SYS_TYPES_H
1509 # include <sys/types.h>
1510 #endif
1511 #ifdef HAVE_LINUX_FALLOC_H
1512 # include <linux/falloc.h>
1513 #endif
1514 #ifdef HAVE_FCNTL_H
1515 # include <fcntl.h>
1516 #endif
1517 ]],[[
1518    long ret;
1519    ret = posix_fallocate(0, 0xfffffffful, 0xfffffffful);
1520    if (ret != 0) {
1521       return 1;
1522    }
1523    ]])],[
1524   AC_MSG_RESULT([yes])
1525   AC_DEFINE([HAVE_POSIX_FALLOCATE], [1], [Have valid posix_fallocate() function])],[
1526   AC_MSG_RESULT([no])])
1527 ])
1528
1529
1530 AC_ARG_ENABLE([unshare],
1531   AS_HELP_STRING([--disable-unshare], [do not build unshare]),
1532   [], [UL_DEFAULT_ENABLE([unshare], [check])]
1533 )
1534 UL_BUILD_INIT([unshare])
1535 UL_REQUIRES_LINUX([unshare])
1536 UL_REQUIRES_SYSCALL_CHECK([unshare], [UL_CHECK_SYSCALL([unshare])])
1537 UL_REQUIRES_HAVE([unshare], [linux_capability_h], [linux/capability.h header file])
1538 AM_CONDITIONAL([BUILD_UNSHARE], [test "x$build_unshare" = xyes])
1539
1540 AC_MSG_CHECKING([for valid unshare() function])
1541 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1542 #include <sched.h>
1543 ]],[[
1544    int ret;
1545    ret = unshare(0);
1546    if (ret != 0) {
1547       return 1;
1548    }
1549    ]])],[
1550   AC_MSG_RESULT([yes])
1551   AC_DEFINE([HAVE_UNSHARE], [1], [Have valid unshare() function])],
1552 [
1553   AC_MSG_RESULT([no])
1554 ])
1555
1556
1557 AC_ARG_ENABLE([nsenter],
1558   AS_HELP_STRING([--disable-nsenter], [do not build nsenter]),
1559   [], [UL_DEFAULT_ENABLE([nsenter], [check])]
1560 )
1561 UL_BUILD_INIT([nsenter])
1562 UL_REQUIRES_LINUX([nsenter])
1563 UL_REQUIRES_HAVE([nsenter], [setns_syscall], [setns syscall])
1564 AM_CONDITIONAL([BUILD_NSENTER], [test "x$build_nsenter" = xyes])
1565
1566 AC_MSG_CHECKING([for valid setns() function])
1567 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1568 #include <sched.h>
1569 #include <errno.h>
1570 ]],[[
1571    int ret;
1572    ret = setns(0, 0);
1573    if (ret != EINVAL && ret != EBADF && ret != EPERM) {
1574       return 1;
1575    }
1576    ]])],[
1577   AC_MSG_RESULT([yes])
1578   AC_DEFINE([HAVE_SETNS], [1], [Have valid setns() function])],
1579 [
1580   AC_MSG_RESULT([no])
1581 ])
1582
1583
1584 AC_ARG_WITH([cap_ng],
1585   AS_HELP_STRING([--without-cap-ng], [compile without libcap-ng]),
1586   [], [with_cap_ng=auto]
1587 )
1588 AS_IF([test "x$with_cap_ng" = xno], [
1589   AM_CONDITIONAL([HAVE_CAP_NG], [false])
1590   have_cap_ng=no
1591 ],[
1592   UL_CHECK_LIB([cap-ng], [capng_apply], [cap_ng])
1593 ])
1594
1595
1596 AC_ARG_ENABLE([setpriv],
1597   AS_HELP_STRING([--disable-setpriv], [do not build setpriv]),
1598   [], [UL_DEFAULT_ENABLE([setpriv], [check])]
1599 )
1600 UL_BUILD_INIT([setpriv])
1601 UL_REQUIRES_LINUX([setpriv])
1602 UL_REQUIRES_HAVE([setpriv], [linux_securebits_h], [linux/securebits.h header file])
1603 UL_REQUIRES_HAVE([setpriv], [linux_capability_h], [linux/capability.h header file])
1604 UL_REQUIRES_HAVE([setpriv], [cap_ng], [libcap-ng library])
1605 AM_CONDITIONAL([BUILD_SETPRIV], [test "x$build_setpriv" = xyes])
1606
1607 AC_ARG_ENABLE([hardlink],
1608   AS_HELP_STRING([--disable-hardlink], [do not build hardlink]),
1609   [], [UL_DEFAULT_ENABLE([hardlink], [check])]
1610 )
1611 UL_BUILD_INIT([hardlink])
1612 AM_CONDITIONAL([BUILD_HARDLINK], [test "x$build_hardlink" = xyes])
1613
1614
1615 AC_ARG_ENABLE([eject],
1616   AS_HELP_STRING([--disable-eject], [do not build eject]),
1617   [], [UL_DEFAULT_ENABLE([eject], [check])]
1618 )
1619 UL_BUILD_INIT([eject])
1620 UL_REQUIRES_LINUX([eject])
1621 UL_REQUIRES_BUILD([eject], [libmount])
1622 AM_CONDITIONAL([BUILD_EJECT], [test "x$build_eject" = xyes])
1623
1624
1625 AC_ARG_ENABLE([agetty],
1626   AS_HELP_STRING([--disable-agetty], [do not build agetty]),
1627   [], [UL_DEFAULT_ENABLE([agetty], [check])]
1628 )
1629 UL_BUILD_INIT([agetty])
1630 UL_REQUIRES_HAVE([agetty], [utmpx_h], [utmpx.h header])
1631 UL_REQUIRES_HAVE([agetty], [gnu_utmpx], [GNU utmpx functions])
1632 AM_CONDITIONAL([BUILD_AGETTY], [test "x$build_agetty" = xyes])
1633 AS_IF([test "x$have_futimens" = xyes && test "x$have_inotify_init1" = xyes ], [
1634   AC_DEFINE([AGETTY_RELOAD], [1], [Enable agetty --reload feature])
1635 ],[
1636   AC_MSG_WARN([futimens or inotify_init1 not found; agetty(8) will not provide ---reload functionality])
1637 ])
1638
1639
1640 AC_ARG_ENABLE([plymouth_support],
1641   AS_HELP_STRING([--disable-plymouth_support], [do not care about plymouth in sulogin(8) and agetty(8)]),
1642   [], [enable_plymouth_support=check]
1643 )
1644 UL_BUILD_INIT([plymouth_support])
1645 UL_REQUIRES_HAVE([plymouth_support], [tiocglcktrmios], [TIOCGLCKTRMIOS flag])
1646 UL_REQUIRES_HAVE([plymouth_support], [sock_cloexec], [SOCK_CLOEXEC flag])
1647 UL_REQUIRES_HAVE([plymouth_support], [sock_nonblock], [SOCK_NONBLOCK flag])
1648 UL_REQUIRES_HAVE([plymouth_support], [so_passcred], [SO_PASSCRED flag])
1649 AM_CONDITIONAL([USE_PLYMOUTH_SUPPORT], [test "x$build_plymouth_support" = xyes])
1650 AS_IF([test "x$build_plymouth_support" = xyes ], [
1651     AC_DEFINE([USE_PLYMOUTH_SUPPORT], [1], [Enable plymouth support feature for sulogin and agetty])
1652 ])
1653
1654
1655 AC_ARG_WITH([libz],
1656   AS_HELP_STRING([--without-libz], [compile without libz]),
1657   [], [with_libz=auto]
1658 )
1659 AS_IF([test "x$with_libz" = xno], [have_z=no], [
1660   AC_CHECK_LIB([z], [crc32], [have_z=yes], [have_z=no])
1661 ])
1662
1663 AC_ARG_WITH([libmagic],
1664   AS_HELP_STRING([--without-libmagic], [compile without libmagic]),
1665   [], [with_libmagic=auto]
1666 )
1667 AS_IF([test "x$with_libmagic" = xno], [have_magic=no], [
1668   AC_CHECK_LIB([magic], [magic_open], [
1669     AC_CHECK_HEADER(magic.h, [
1670       AC_DEFINE([HAVE_MAGIC], [1], [Define to 1 if you have the libmagic present.])
1671       MAGIC_LIBS="-lmagic"
1672     ])
1673   ])
1674 ])
1675 AC_SUBST([MAGIC_LIBS])
1676
1677
1678 AC_ARG_ENABLE([cramfs],
1679   AS_HELP_STRING([--disable-cramfs], [do not build fsck.cramfs, mkfs.cramfs]),
1680   [], [UL_DEFAULT_ENABLE([cramfs], [check])]
1681 )
1682 UL_BUILD_INIT([cramfs])
1683 UL_REQUIRES_HAVE([cramfs], [z], [z library])
1684 AM_CONDITIONAL([BUILD_CRAMFS], [test "x$build_cramfs" = xyes])
1685
1686
1687 AC_ARG_ENABLE([bfs],
1688   AS_HELP_STRING([--disable-bfs], [do not build mkfs.bfs]),
1689   [], [UL_DEFAULT_ENABLE([bfs], [yes])]
1690 )
1691 UL_BUILD_INIT([bfs])
1692 AM_CONDITIONAL([BUILD_BFS], [test "x$build_bfs" = xyes])
1693
1694
1695 AC_ARG_ENABLE([minix],
1696   AS_HELP_STRING([--disable-minix], [do not build fsck.minix, mkfs.minix]),
1697   [], [UL_DEFAULT_ENABLE([minix], [yes])]
1698 )
1699 UL_BUILD_INIT([minix])
1700 AM_CONDITIONAL([BUILD_MINIX], [test "x$build_minix" = xyes])
1701
1702
1703 AC_ARG_ENABLE([fdformat],
1704   AS_HELP_STRING([--enable-fdformat], [build fdformat]),
1705   [], [UL_DEFAULT_ENABLE([fdformat], [no])]
1706 )
1707 UL_BUILD_INIT([fdformat])
1708 UL_REQUIRES_LINUX([fdformat])
1709 AM_CONDITIONAL([BUILD_FDFORMAT], [test "x$build_fdformat" = xyes])
1710
1711
1712 AC_ARG_ENABLE([hwclock],
1713   AS_HELP_STRING([--disable-hwclock], [do not build hwclock]),
1714   [], [UL_DEFAULT_ENABLE([hwclock], [check])]
1715 )
1716 have_linuxdummy=$linux_os
1717
1718 UL_BUILD_INIT([hwclock])
1719 UL_REQUIRES_HAVE([hwclock], [io, linuxdummy], [ioperm iopl function or Linux])
1720 AM_CONDITIONAL([BUILD_HWCLOCK], [test "x$build_hwclock" = xyes])
1721
1722 AC_ARG_ENABLE([hwclock_cmos],
1723   AS_HELP_STRING([--disable-hwclock-cmos], [do not use CMOS clock]),
1724   [], [enable_hwclock_cmos=check]
1725 )
1726 UL_BUILD_INIT([hwclock_cmos])
1727 UL_REQUIRES_BUILD([hwclock_cmos], [hwclock])
1728 UL_REQUIRES_ARCH([hwclock_cmos], [i?86-*,x86_64*])
1729 AM_CONDITIONAL([USE_HWCLOCK_CMOS], [test "x$build_hwclock_cmos" = xyes])
1730 AS_IF([test "x$build_hwclock_cmos" = xyes ], [
1731     AC_DEFINE([USE_HWCLOCK_CMOS], [1], [Define to 1 if want to use CMOS clock.])
1732 ])
1733
1734 AC_ARG_ENABLE([hwclock_gplv3],
1735   AS_HELP_STRING([--disable-hwclock-gplv3], [do not use datetime parsing GPLv3 code]),
1736   [], [enable_hwclock_gplv3=yes]
1737 )
1738 AM_CONDITIONAL([USE_HWCLOCK_GPLv3_DATETIME], [test "x$enable_hwclock_gplv3" = xyes])
1739 AS_IF([test "x$enable_hwclock_gplv3" = xyes ], [
1740     AC_DEFINE([USE_HWCLOCK_GPLv3_DATETIME], [1], [use datetime parsing GPLv3 code to hwclock])
1741 ])
1742
1743
1744 AC_ARG_ENABLE([mkfs],
1745   AS_HELP_STRING([--disable-mkfs], [do not build mkfs(8)]),
1746   [], [UL_DEFAULT_ENABLE([mkfs], [check])]
1747 )
1748 UL_BUILD_INIT([mkfs])
1749 AM_CONDITIONAL([BUILD_MKFS], [test "x$build_mkfs" = xyes])
1750
1751 UL_BUILD_INIT([isosize], [yes])
1752 AM_CONDITIONAL([BUILD_ISOSIZE], [test "x$build_isosize" = xyes])
1753
1754
1755 AC_ARG_ENABLE([fstrim],
1756   AS_HELP_STRING([--disable-fstrim], [do not build fstrim(8)]),
1757   [], [UL_DEFAULT_ENABLE([fstrim], [check])]
1758 )
1759 UL_BUILD_INIT([fstrim])
1760 UL_REQUIRES_LINUX([fstrim])
1761 UL_REQUIRES_BUILD([fstrim], [libmount])
1762 AM_CONDITIONAL([BUILD_FSTRIM], [test "x$build_fstrim" = xyes])
1763
1764
1765 AC_ARG_ENABLE([swapon],
1766   AS_HELP_STRING([--disable-swapon], [do not build swapon(8) and swapoff(8)]),
1767   [], [UL_DEFAULT_ENABLE([swapon], [check])]
1768 )
1769 UL_BUILD_INIT([swapon])
1770 UL_REQUIRES_LINUX([swapon])
1771 UL_REQUIRES_SYSCALL_CHECK([swapon], [UL_CHECK_SYSCALL([swapon])], [swapon])
1772 UL_REQUIRES_SYSCALL_CHECK([swapon], [UL_CHECK_SYSCALL([swapoff])], [swapoff])
1773 UL_REQUIRES_BUILD([swapon], [libblkid])
1774 UL_REQUIRES_BUILD([swapon], [libmount])
1775 UL_REQUIRES_BUILD([swapon], [libsmartcols])
1776 AM_CONDITIONAL([BUILD_SWAPON], [test "x$build_swapon" = xyes])
1777 AC_CHECK_FUNCS([swapon])
1778 AC_CHECK_FUNCS([swapoff])
1779
1780
1781 UL_BUILD_INIT([lsblk], [check])
1782 UL_REQUIRES_LINUX([lsblk])
1783 UL_REQUIRES_BUILD([lsblk], [libblkid])
1784 UL_REQUIRES_BUILD([lsblk], [libmount])
1785 UL_REQUIRES_BUILD([lsblk], [libsmartcols])
1786 AM_CONDITIONAL([BUILD_LSBLK], [test "x$build_lsblk" = xyes])
1787
1788
1789 AC_ARG_ENABLE([lscpu],
1790   AS_HELP_STRING([--disable-lscpu], [do not build lscpu]),
1791   [], [UL_DEFAULT_ENABLE([lscpu], [check])]
1792 )
1793 UL_BUILD_INIT([lscpu])
1794 UL_REQUIRES_LINUX([lscpu])
1795 UL_REQUIRES_BUILD([lscpu], [libsmartcols])
1796 UL_REQUIRES_HAVE([lscpu], [cpu_set_t], [cpu_set_t type])
1797 AM_CONDITIONAL([BUILD_LSCPU], [test "x$build_lscpu" = xyes])
1798
1799 AC_ARG_ENABLE([lsfd],
1800   AS_HELP_STRING([--disable-lsfd], [do not build lsfd]),
1801   [], [UL_DEFAULT_ENABLE([lsfd], [check])]
1802 )
1803 UL_BUILD_INIT([lsfd])
1804 UL_REQUIRES_LINUX([lsfd])
1805 UL_REQUIRES_BUILD([lsfd], [libsmartcols])
1806 UL_REQUIRES_HAVE([lsfd], [linux_kcmp_h], [linux/kcmp.h header file])
1807 AM_CONDITIONAL([BUILD_LSFD], [test "x$build_lsfd" = xyes])
1808
1809 AC_ARG_ENABLE([lslogins],
1810   AS_HELP_STRING([--disable-lslogins], [do not build lslogins]),
1811   [], [UL_DEFAULT_ENABLE([lslogins], [check])]
1812 )
1813 UL_BUILD_INIT([lslogins])
1814 UL_REQUIRES_BUILD([lslogins], [libsmartcols])
1815 UL_REQUIRES_HAVE([lslogins], [shadow_h], [shadow.h header])
1816 UL_REQUIRES_HAVE([lslogins], [utmpx_h], [utmpx.h header])
1817 UL_REQUIRES_HAVE([lslogins], [gnu_utmpx], [GNU utmpx functions])
1818 AM_CONDITIONAL([BUILD_LSLOGINS], [test "x$build_lslogins" = xyes])
1819
1820
1821 UL_BUILD_INIT([chcpu], [check])
1822 UL_REQUIRES_LINUX([chcpu])
1823 UL_REQUIRES_HAVE([chcpu], [cpu_set_t], [cpu_set_t type])
1824 AM_CONDITIONAL([BUILD_CHCPU], [test "x$build_chcpu" = xyes])
1825
1826
1827 AC_ARG_ENABLE([wdctl],
1828   AS_HELP_STRING([--disable-wdctl], [do not build wdctl]),
1829   [], [UL_DEFAULT_ENABLE([wdctl], [check])]
1830 )
1831 UL_BUILD_INIT([wdctl])
1832 UL_REQUIRES_LINUX([wdctl])
1833 UL_REQUIRES_BUILD([wdctl], [libsmartcols])
1834 UL_REQUIRES_HAVE([wdctl], [linux_watchdog_h], [linux/watchdog.h header file])
1835 AM_CONDITIONAL([BUILD_WDCTL], [test "x$build_wdctl" = xyes])
1836
1837
1838 UL_BUILD_INIT([swaplabel], [check])
1839 UL_REQUIRES_BUILD([swaplabel], [libblkid])
1840 AM_CONDITIONAL([BUILD_SWAPLABEL], [test "x$build_swaplabel" = xyes])
1841
1842
1843 UL_BUILD_INIT([mkswap], [yes])
1844 AM_CONDITIONAL([BUILD_MKSWAP], [test "x$build_mkswap" = xyes])
1845 AS_IF([test "x$build_mkswap" = xyes && test "x$build_libuuid" != xyes], [
1846   AC_MSG_WARN([uuid library is not found; mkswap(8) will not generate UUIDs])
1847 ])
1848
1849
1850 AC_ARG_ENABLE([cal],
1851   AS_HELP_STRING([--disable-cal], [do not build cal]),
1852   [], [UL_DEFAULT_ENABLE([cal], [check])]
1853 )
1854 UL_BUILD_INIT([cal])
1855 AM_CONDITIONAL([BUILD_CAL], [test "x$build_cal" = xyes])
1856
1857 AC_ARG_ENABLE([logger],
1858   AS_HELP_STRING([--disable-logger], [do not build logger]),
1859   [], [UL_DEFAULT_ENABLE([logger], [check])]
1860 )
1861 UL_BUILD_INIT([logger])
1862 AM_CONDITIONAL([BUILD_LOGGER], [test "x$build_logger" = xyes])
1863
1864 UL_BUILD_INIT([look], [yes])
1865 AM_CONDITIONAL([BUILD_LOOK], [test "x$build_look" = xyes])
1866
1867 UL_BUILD_INIT([mcookie], [yes])
1868 AM_CONDITIONAL([BUILD_MCOOKIE], [test "x$build_mcookie" = xyes])
1869
1870 UL_BUILD_INIT([namei], [yes])
1871 AM_CONDITIONAL([BUILD_NAMEI], [test "x$build_namei" = xyes])
1872
1873 matriplet="$($CC -print-multiarch 2>/dev/null || true)"
1874 if test "x$matriplet" != "x"; then
1875   AC_DEFINE_UNQUOTED([MULTIARCHTRIPLET], ["$matriplet"],
1876   ["Multi-arch triplet for whereis library search path"])
1877 fi
1878 AC_ARG_ENABLE([whereis],
1879   AS_HELP_STRING([--disable-whereis], [do not build whereis]),
1880   [], [UL_DEFAULT_ENABLE([whereis], [check])]
1881 )
1882 UL_BUILD_INIT([whereis])
1883 AM_CONDITIONAL([BUILD_WHEREIS], [test "x$build_whereis" = xyes])
1884
1885 AC_ARG_ENABLE([pipesz],
1886   AS_HELP_STRING([--disable-pipesz], [do not build pipesz]),
1887   [], [UL_DEFAULT_ENABLE([pipesz], [check])]
1888 )
1889 UL_BUILD_INIT([pipesz])
1890 UL_REQUIRES_LINUX([pipesz])
1891 AM_CONDITIONAL([BUILD_PIPESZ], [test "x$build_pipesz" = xyes])
1892
1893 UL_BUILD_INIT([fadvise], [check])
1894 UL_REQUIRES_LINUX([fadvise])
1895 AM_CONDITIONAL([BUILD_FADVISE], [test "x$build_fadvise" = xyes])
1896
1897 AC_ARG_ENABLE([waitpid],
1898   AS_HELP_STRING([--disable-waitpid], [do not build waitpid]),
1899   [], [UL_DEFAULT_ENABLE([waitpid], [check])]
1900 )
1901 UL_BUILD_INIT([waitpid])
1902 UL_REQUIRES_LINUX([waitpid])
1903 UL_REQUIRES_SYSCALL_CHECK([waitpid], [UL_CHECK_SYSCALL([pidfd_open])], [pidfd_open])
1904 AM_CONDITIONAL([BUILD_WAITPID], [test "x$build_waitpid" = xyes])
1905
1906 UL_BUILD_INIT([enosys], [check])
1907 UL_REQUIRES_LINUX([enosys])
1908 AS_IF([test "x$build_enosys" = xyes], [
1909   AC_MSG_CHECKING([for valid audit arch])
1910   AC_COMPILE_IFELSE(
1911     [AC_LANG_PROGRAM([[#include "${srcdir}/include/audit-arch.h"]])],
1912     [AC_MSG_RESULT([yes])],
1913     [AC_MSG_RESULT([no])
1914      build_enosys=no
1915     ])
1916 ])
1917 AM_CONDITIONAL([BUILD_ENOSYS], [test "x$build_enosys" = xyes])
1918
1919 UL_BUILD_INIT([lsclocks], [check])
1920 UL_REQUIRES_LINUX([lsclocks])
1921 AM_CONDITIONAL([BUILD_LSCLOCKS], [test "x$build_lsclocks" = xyes])
1922
1923 UL_BUILD_INIT([getopt], [yes])
1924 AM_CONDITIONAL([BUILD_GETOPT], [test "x$build_getopt" = xyes])
1925
1926
1927 UL_BUILD_INIT([blockdev], [check])
1928 UL_REQUIRES_LINUX([blockdev])
1929 AM_CONDITIONAL([BUILD_BLOCKDEV], [test "x$build_blockdev" = xyes])
1930
1931
1932 UL_BUILD_INIT([prlimit], [check])
1933 UL_REQUIRES_LINUX([prlimit])
1934 UL_REQUIRES_BUILD([prlimit], [libsmartcols])
1935 UL_REQUIRES_SYSCALL_CHECK([prlimit], [UL_CHECK_SYSCALL([prlimit64])], [prlimit64])
1936 AM_CONDITIONAL([BUILD_PRLIMIT], [test "x$build_prlimit" = xyes])
1937 AS_IF([test "x$build_prlimit" = xyes], [
1938   dnl check for valid prlimit() function
1939   AC_MSG_CHECKING([for valid prlimit() function])
1940   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1941 #include <sys/types.h>
1942 #include <sys/time.h>
1943 #include <sys/resource.h>
1944 #include <stddef.h>
1945 ]],[[
1946    int ret;
1947    ret = prlimit(0, RLIMIT_AS, NULL, NULL);
1948    if (ret != 0) {
1949       return 1;
1950    }
1951    ]])],[
1952   AC_MSG_RESULT([yes])
1953   AC_DEFINE([HAVE_PRLIMIT], [1], [Have valid prlimit() function])],[
1954   AC_MSG_RESULT([no])])
1955 ])
1956
1957
1958
1959 UL_BUILD_INIT([lslocks], [check])
1960 UL_REQUIRES_LINUX([lslocks])
1961 UL_REQUIRES_BUILD([lslocks], [libmount])
1962 UL_REQUIRES_BUILD([lslocks], [libsmartcols])
1963 AM_CONDITIONAL([BUILD_LSLOCKS], [test "x$build_lslocks" = xyes])
1964
1965
1966 AC_ARG_ENABLE([switch_root],
1967   AS_HELP_STRING([--disable-switch_root], [do not build switch_root]),
1968   [], [UL_DEFAULT_ENABLE([switch_root], [check])]
1969 )
1970 UL_BUILD_INIT([switch_root])
1971 UL_REQUIRES_LINUX([switch_root])
1972 UL_REQUIRES_HAVE([switch_root], [openat], [openat function])
1973 UL_REQUIRES_HAVE([switch_root], [dirfd,ddfd], [dirfd or ddfd function])
1974 AM_CONDITIONAL([BUILD_SWITCH_ROOT], [test "x$build_switch_root" = xyes])
1975
1976
1977 AC_ARG_ENABLE([pivot_root],
1978   AS_HELP_STRING([--disable-pivot_root], [do not build pivot_root]),
1979   [], [UL_DEFAULT_ENABLE([pivot_root], [check])]
1980 )
1981 UL_BUILD_INIT([pivot_root])
1982 UL_REQUIRES_LINUX([pivot_root])
1983 UL_REQUIRES_SYSCALL_CHECK([pivot_root], [UL_CHECK_SYSCALL([pivot_root])])
1984 AM_CONDITIONAL([BUILD_PIVOT_ROOT], [test "x$build_pivot_root" = xyes])
1985
1986
1987 UL_BUILD_INIT([flock], [check])
1988 UL_REQUIRES_HAVE([flock], [timer], [timer_create/setitimer function])
1989 AM_CONDITIONAL([BUILD_FLOCK], [test "x$build_flock" = xyes])
1990
1991
1992 AC_ARG_ENABLE([lsmem],
1993   AS_HELP_STRING([--disable-lsmem], [do not build lsmem]),
1994   [], [UL_DEFAULT_ENABLE([lsmem], [check])]
1995 )
1996 UL_BUILD_INIT([lsmem])
1997 UL_REQUIRES_LINUX([lsmem])
1998 UL_REQUIRES_BUILD([lsmem], [libsmartcols])
1999 AM_CONDITIONAL([BUILD_LSMEM], [test "x$build_lsmem" = xyes])
2000
2001
2002 AC_ARG_ENABLE([chmem],
2003   AS_HELP_STRING([--disable-chmem], [do not build chmem]),
2004   [], [UL_DEFAULT_ENABLE([chmem], [check])]
2005 )
2006 UL_BUILD_INIT([chmem])
2007 UL_REQUIRES_LINUX([chmem])
2008 AM_CONDITIONAL([BUILD_CHMEM], [test "x$build_chmem" = xyes])
2009
2010
2011 AC_ARG_ENABLE([ipcmk],
2012   AS_HELP_STRING([--disable-ipcmk], [do not build ipcmk]),
2013   [], [UL_DEFAULT_ENABLE([ipcmk], [check])]
2014 )
2015 UL_BUILD_INIT([ipcmk])
2016 UL_EXCLUDE_ARCH([ipcmk], [*darwin*])
2017 AM_CONDITIONAL([BUILD_IPCMK], [test "x$build_ipcmk" = xyes])
2018
2019 AC_ARG_ENABLE([ipcrm],
2020   AS_HELP_STRING([--disable-ipcrm], [do not build ipcrm]),
2021   [], [UL_DEFAULT_ENABLE([ipcrm], [check])]
2022 )
2023 UL_BUILD_INIT([ipcrm])
2024 UL_EXCLUDE_ARCH([ipcrm], [*darwin*])
2025 AM_CONDITIONAL([BUILD_IPCRM], [test "x$build_ipcrm" = xyes])
2026
2027 AC_ARG_ENABLE([ipcs],
2028   AS_HELP_STRING([--disable-ipcs], [do not build ipcs]),
2029   [], [UL_DEFAULT_ENABLE([ipcs], [check])]
2030 )
2031 UL_BUILD_INIT([ipcs])
2032 UL_EXCLUDE_ARCH([ipcs], [*darwin*])
2033 AM_CONDITIONAL([BUILD_IPCS], [test "x$build_ipcs" = xyes])
2034
2035
2036 AC_ARG_ENABLE([irqtop],
2037   AS_HELP_STRING([--disable-irqtop], [do not build irqtop]),
2038   [], [UL_DEFAULT_ENABLE([irqtop], [check])]
2039 )
2040 UL_BUILD_INIT([irqtop])
2041 UL_REQUIRES_LINUX([irqtop])
2042 UL_REQUIRES_BUILD([irqtop], [libsmartcols])
2043 UL_REQUIRES_HAVE([irqtop], [open_memstream], [open_memstream function])
2044 UL_REQUIRES_HAVE([irqtop], [ncursesw,slang,ncurses], [ncursesw, ncurses or slang library])
2045 AM_CONDITIONAL([BUILD_IRQTOP], [test "x$build_irqtop" = xyes])
2046
2047 AC_ARG_ENABLE([lsirq],
2048   AS_HELP_STRING([--disable-lsirq], [do not build lsirq]),
2049   [], [UL_DEFAULT_ENABLE([lsirq], [check])]
2050 )
2051 UL_BUILD_INIT([lsirq])
2052 UL_REQUIRES_LINUX([lsirq])
2053 UL_REQUIRES_BUILD([lsirq], [libsmartcols])
2054 AM_CONDITIONAL([BUILD_LSIRQ], [test "x$build_lsirq" = xyes])
2055
2056
2057 UL_BUILD_INIT([choom], [check])
2058 UL_REQUIRES_LINUX([choom])
2059 AM_CONDITIONAL([BUILD_CHOOM], [test "x$build_choom" = xyes])
2060
2061 UL_BUILD_INIT([lsipc], [check])
2062 UL_REQUIRES_LINUX([lsipc])
2063 UL_REQUIRES_BUILD([lsipc], [libsmartcols])
2064 AM_CONDITIONAL([BUILD_LSIPC], [test "x$build_lsipc" = xyes])
2065
2066 AC_ARG_ENABLE([lsns],
2067   AS_HELP_STRING([--disable-lsns], [do not build lsns]),
2068   [], [UL_DEFAULT_ENABLE([lsns], [check])]
2069 )
2070 UL_BUILD_INIT([lsns])
2071 UL_REQUIRES_LINUX([lsns])
2072 UL_REQUIRES_BUILD([lsns], [libsmartcols])
2073 UL_REQUIRES_BUILD([lsns], [libmount])
2074 AM_CONDITIONAL([BUILD_LSNS], [test "x$build_lsns" = xyes])
2075
2076 UL_BUILD_INIT([renice], [yes])
2077 AM_CONDITIONAL([BUILD_RENICE], [test "x$build_renice" = xyes])
2078
2079
2080 AC_ARG_ENABLE([rfkill],
2081   AS_HELP_STRING([--disable-rfkill], [do not build rfkill]),
2082   [], [UL_DEFAULT_ENABLE([rfkill], [check])]
2083 )
2084 UL_BUILD_INIT([rfkill])
2085 UL_REQUIRES_LINUX([rfkill])
2086 UL_REQUIRES_BUILD([rfkill], [libsmartcols])
2087 AM_CONDITIONAL([BUILD_RFKILL], [test "x$build_rfkill" = xyes])
2088
2089
2090 UL_BUILD_INIT([setpgid], [yes])
2091 AM_CONDITIONAL([BUILD_SETPGID], [test "x$build_setpgid" = xyes])
2092
2093 UL_BUILD_INIT([setsid], [yes])
2094 AM_CONDITIONAL([BUILD_SETSID], [test "x$build_setsid" = xyes])
2095
2096 UL_BUILD_INIT([readprofile], [check])
2097 UL_REQUIRES_LINUX([readprofile])
2098 AM_CONDITIONAL([BUILD_READPROFILE], [test "x$build_readprofile" = xyes])
2099
2100 UL_BUILD_INIT([dmesg], [check])
2101 UL_REQUIRES_LINUX([dmesg])
2102 AM_CONDITIONAL([BUILD_DMESG], [test "x$build_dmesg" = xyes])
2103
2104 UL_BUILD_INIT([ctrlaltdel], [check])
2105 UL_REQUIRES_LINUX([ctrlaltdel])
2106 dnl we assume reboot() to be the 1-argument variant, because even considering
2107 dnl widely used alternative C libraries like uclibc, dietlibc and musl,
2108 dnl reboot() with multiple arguments is yet only found in glibc versions
2109 dnl earlier than 2.x.
2110 UL_REQUIRES_HAVE([ctrlaltdel], [reboot], [reboot function])
2111 AM_CONDITIONAL([BUILD_CTRLALTDEL], [test "x$build_ctrlaltdel" = xyes])
2112
2113 AC_ARG_ENABLE([exch],
2114   AS_HELP_STRING([--disable-exch], [do not build exch]),
2115   [], [UL_DEFAULT_ENABLE([exch], [check])]
2116 )
2117 UL_BUILD_INIT([exch])
2118 UL_REQUIRES_LINUX([exch])
2119 UL_REQUIRES_SYSCALL_CHECK([exch], [UL_CHECK_SYSCALL([renameat2])])
2120 AM_CONDITIONAL([BUILD_EXCH], [test "x$build_exch" = xyes])
2121
2122 UL_BUILD_INIT([fincore], [check])
2123 UL_REQUIRES_LINUX([fincore])
2124 UL_REQUIRES_BUILD([fincore], [libsmartcols])
2125 AM_CONDITIONAL([BUILD_FINCORE], [test "x$build_fincore" = xyes])
2126
2127 UL_BUILD_INIT([fsfreeze], [check])
2128 UL_REQUIRES_LINUX([fsfreeze])
2129 AM_CONDITIONAL([BUILD_FSFREEZE], [test "x$build_fsfreeze" = xyes])
2130
2131 UL_BUILD_INIT([blkdiscard], [check])
2132 UL_REQUIRES_LINUX([blkdiscard])
2133 AM_CONDITIONAL([BUILD_BLKDISCARD], [test "x$build_blkdiscard" = xyes])
2134
2135 UL_BUILD_INIT([blkzone], [check])
2136 UL_REQUIRES_LINUX([blkzone])
2137 UL_REQUIRES_HAVE([blkzone], [linux_blkzoned_h], [linux/blkzoned.h header])
2138 AM_CONDITIONAL([BUILD_BLKZONE], [test "x$build_blkzone" = xyes])
2139
2140 UL_BUILD_INIT([blkpr], [check])
2141 UL_REQUIRES_LINUX([blkpr])
2142 UL_REQUIRES_HAVE([blkpr], [linux_pr_h], [linux/pr.h header])
2143 AM_CONDITIONAL([BUILD_BLKPR], [test "x$build_blkpr" = xyes])
2144
2145 UL_BUILD_INIT([ldattach], [check])
2146 UL_REQUIRES_LINUX([ldattach])
2147 AM_CONDITIONAL([BUILD_LDATTACH], [test "x$build_ldattach" = xyes])
2148
2149 UL_BUILD_INIT([rtcwake], [check])
2150 UL_REQUIRES_LINUX([rtcwake])
2151 AM_CONDITIONAL([BUILD_RTCWAKE], [test "x$build_rtcwake" = xyes])
2152
2153 UL_BUILD_INIT([setarch], [check])
2154 UL_REQUIRES_LINUX([setarch])
2155 AM_CONDITIONAL([BUILD_SETARCH], [test "x$build_setarch" = xyes])
2156
2157
2158 # build_scriptutils= is just configure-only variable to control
2159 # script, scriptreplay and scriptlive
2160 AC_ARG_ENABLE([scriptutils],
2161   AS_HELP_STRING([--disable-scriptutils], [do not build script, scriptreplay and scriptlive]),
2162   [], [UL_DEFAULT_ENABLE([scriptutils], [check])]
2163 )
2164
2165 UL_ENABLE_ALIAS([script], [scriptutils])
2166 UL_BUILD_INIT([script])
2167 UL_REQUIRES_HAVE([script], [pty], [openpty function (libutil)])
2168 AM_CONDITIONAL([BUILD_SCRIPT], [test "x$build_script" = xyes])
2169
2170 UL_ENABLE_ALIAS([scriptreplay], [scriptutils])
2171 UL_BUILD_INIT([scriptreplay])
2172 AM_CONDITIONAL([BUILD_SCRIPTREPLAY], [test "x$build_scriptreplay" = xyes])
2173
2174 UL_ENABLE_ALIAS([scriptlive], [scriptutils])
2175 UL_BUILD_INIT([scriptlive])
2176 UL_REQUIRES_HAVE([scriptlive], [pty], [openpty function (libutil)])
2177 AM_CONDITIONAL([BUILD_SCRIPTLIVE], [test "x$build_scriptlive" = xyes])
2178
2179
2180 UL_BUILD_INIT([col], [check])
2181 UL_REQUIRES_COMPILE([col], [#include <limits.h>], [__GLIBC__], [building for glibc])
2182 AM_CONDITIONAL([BUILD_COL], [test "x$build_col" = xyes])
2183
2184 UL_BUILD_INIT([colcrt], [yes])
2185 AM_CONDITIONAL([BUILD_COLCRT], [test "x$build_colcrt" = xyes])
2186
2187 UL_BUILD_INIT([colrm], [yes])
2188 AM_CONDITIONAL([BUILD_COLRM], [test "x$build_colrm" = xyes])
2189
2190 UL_BUILD_INIT([column], [check])
2191 UL_REQUIRES_BUILD([column], [libsmartcols])
2192 AM_CONDITIONAL([BUILD_COLUMN], [test "x$build_column" = xyes])
2193
2194 UL_BUILD_INIT([hexdump], [yes])
2195 AM_CONDITIONAL([BUILD_HEXDUMP], [test "x$build_hexdump" = xyes])
2196
2197 UL_BUILD_INIT([rev], [yes])
2198 AM_CONDITIONAL([BUILD_REV], [test "x$build_rev" = xyes])
2199
2200
2201 AC_ARG_ENABLE([tunelp],
2202   AS_HELP_STRING([--enable-tunelp], [build tunelp]),
2203   [], [UL_DEFAULT_ENABLE([tunelp], [no])]
2204 )
2205 UL_BUILD_INIT([tunelp])
2206 UL_REQUIRES_LINUX([tunelp])
2207 AM_CONDITIONAL([BUILD_TUNELP], [test "x$build_tunelp" = xyes])
2208
2209
2210 AC_ARG_ENABLE([kill],
2211   AS_HELP_STRING([--disable-kill], [do not build kill]),
2212   [], [UL_DEFAULT_ENABLE([kill], [check])]
2213 )
2214 UL_BUILD_INIT([kill])
2215 UL_REQUIRES_LINUX([kill])
2216 AM_CONDITIONAL([BUILD_KILL], [test "x$build_kill" = xyes])
2217
2218
2219 AC_ARG_ENABLE([last],
2220   AS_HELP_STRING([--disable-last], [do not build last]),
2221   [], [UL_DEFAULT_ENABLE([last], [check])]
2222 )
2223 UL_BUILD_INIT([last])
2224 UL_REQUIRES_HAVE([last], [utmpx_h], [utmpx.h header])
2225 UL_REQUIRES_HAVE([last], [gnu_utmpx], [GNU utmpx functions])
2226 AM_CONDITIONAL([BUILD_LAST], [test "x$build_last" = xyes])
2227
2228
2229 AC_ARG_ENABLE([utmpdump],
2230   AS_HELP_STRING([--disable-utmpdump], [do not build utmpdump]),
2231   [], [UL_DEFAULT_ENABLE([utmpdump], [check])]
2232 )
2233 UL_BUILD_INIT([utmpdump])
2234 UL_REQUIRES_HAVE([utmpdump], [utmpx_h], [utmpx.h header])
2235 UL_REQUIRES_HAVE([utmpdump], [gnu_utmpx], [GNU utmpx functions])
2236 AM_CONDITIONAL([BUILD_UTMPDUMP], [test "x$build_utmpdump" = xyes])
2237
2238
2239 AC_ARG_ENABLE([line],
2240   AS_HELP_STRING([--enable-line], [build line]),
2241   [], [UL_DEFAULT_ENABLE([line], [no])]
2242 )
2243 UL_BUILD_INIT([line])
2244 AM_CONDITIONAL([BUILD_LINE], [test "x$build_line" = xyes])
2245
2246
2247 AC_ARG_ENABLE([mesg],
2248   AS_HELP_STRING([--disable-mesg], [do not build mesg]),
2249   [], [UL_DEFAULT_ENABLE([mesg], [yes])]
2250 )
2251 UL_BUILD_INIT([mesg])
2252 AM_CONDITIONAL([BUILD_MESG], [test "x$build_mesg" = xyes])
2253
2254
2255 AC_ARG_ENABLE([raw],
2256   AS_HELP_STRING([--disable-raw], [do not build raw]),
2257   [], [UL_DEFAULT_ENABLE([raw], [check])]
2258 )
2259 UL_BUILD_INIT([raw])
2260 UL_REQUIRES_LINUX([raw])
2261 UL_REQUIRES_HAVE([raw], [linux_raw_h], [raw.h header file])
2262 AM_CONDITIONAL([BUILD_RAW], [test "x$build_raw" = xyes])
2263
2264
2265 AC_ARG_ENABLE([rename],
2266   AS_HELP_STRING([--disable-rename], [do not build rename]),
2267   [], [UL_DEFAULT_ENABLE([rename], [yes])]
2268 )
2269 UL_BUILD_INIT([rename])
2270 AM_CONDITIONAL([BUILD_RENAME], [test "x$build_rename" = xyes])
2271
2272
2273 AC_ARG_ENABLE([vipw],
2274   AS_HELP_STRING([--enable-vipw], [build vipw]),
2275   [], [UL_DEFAULT_ENABLE([vipw], [no])]
2276 )
2277 UL_BUILD_INIT([vipw])
2278 UL_REQUIRES_HAVE([vipw], [shadow_h], [shadow.h header])
2279 AM_CONDITIONAL([BUILD_VIPW], [test "x$build_vipw" = xyes])
2280
2281
2282 AC_ARG_ENABLE([newgrp],
2283   AS_HELP_STRING([--enable-newgrp], [build newgrp]),
2284   [], [UL_DEFAULT_ENABLE([newgrp], [no])]
2285 )
2286 UL_BUILD_INIT([newgrp])
2287 UL_REQUIRES_HAVE([newgrp], [crypt], [crypt function])
2288 AM_CONDITIONAL([BUILD_NEWGRP], [test "x$build_newgrp" = xyes])
2289
2290
2291 AC_ARG_WITH([user], AS_HELP_STRING([--without-user], [compile without libuser (remote chsh)]),
2292   [], [with_user=check]
2293 )
2294 have_user=no
2295 AS_IF([test "x$with_user" != xno], [
2296   PKG_CHECK_MODULES(LIBUSER,[libuser >= 0.58], [have_user=yes], [have_user=no])
2297   AS_CASE([$with_user:$have_user],
2298     [yes:no],
2299       [AC_MSG_ERROR([user selected but libuser not found])],
2300     [*:yes],
2301       [AC_DEFINE([HAVE_LIBUSER], [1], [Define if libuser is available])]
2302   )
2303   # temporary solution, libuser has stupid .pc where are exported all
2304   # private dependencies to Requires: instead of Requires.private:
2305   AS_IF([test "x$have_user" = xyes], [
2306     LIBUSER_LIBS=-luser
2307   ])
2308 ])
2309 AM_CONDITIONAL([HAVE_USER], [test "x$have_user" = xyes])
2310
2311 AC_ARG_ENABLE([chfn-chsh-password],
2312   AS_HELP_STRING([--disable-chfn-chsh-password], [do not require the user to enter the password in chfn and chsh]),
2313   [], [enable_chfn_chsh_password=yes]
2314 )
2315
2316 AC_ARG_ENABLE([chfn-chsh],
2317   AS_HELP_STRING([--disable-chfn-chsh], [do not build chfn and chsh]),
2318   [], [UL_DEFAULT_ENABLE([chfn_chsh], [check])]
2319 )
2320 UL_BUILD_INIT([chfn_chsh])
2321 UL_REQUIRES_HAVE([chfn_chsh], [shadow_h], [shadow.h header])
2322 UL_REQUIRES_HAVE([chfn_chsh], [getusershell], [getusershell function])
2323
2324 AS_IF([test "x$enable_chfn_chsh_password" = xyes || test "x$have_user" = xyes], [
2325   UL_REQUIRES_HAVE([chfn_chsh], [security_pam_appl_h], [PAM header file])
2326   AC_DEFINE([CHFN_CHSH_PASSWORD], [1], [Should chfn and chsh require the user to enter the password?])
2327 ])
2328 AM_CONDITIONAL([BUILD_CHFN_CHSH], [test "x$build_chfn_chsh" = xyes])
2329 AM_CONDITIONAL([CHFN_CHSH_PASSWORD], [test "x$enable_chfn_chsh_password" = xyes])
2330
2331 AC_ARG_ENABLE([chsh-only-listed],
2332   AS_HELP_STRING([--disable-chsh-only-listed], [chsh: allow shells not in /etc/shells]),
2333   [], enable_chsh_only_listed=yes
2334 )
2335
2336 AS_IF([test "x$enable_chsh_only_listed" = xyes], [
2337   AC_DEFINE([ONLY_LISTED_SHELLS], [1], [Should chsh allow only shells in /etc/shells?])
2338 ])
2339
2340
2341 AC_ARG_ENABLE([login],
2342   AS_HELP_STRING([--disable-login], [do not build login]),
2343   [], [UL_DEFAULT_ENABLE([login], [check])]
2344 )
2345 UL_BUILD_INIT([login])
2346 UL_REQUIRES_HAVE([login], [security_pam_appl_h], [PAM header file])
2347 UL_REQUIRES_HAVE([login], [security_pam_misc_h, security_openpam_h], [PAM conversation functions])
2348 UL_REQUIRES_HAVE([login], [utmpx_h], [utmpx.h header])
2349 UL_REQUIRES_HAVE([login], [gnu_utmpx], [GNU utmpx functions])
2350 AM_CONDITIONAL([BUILD_LOGIN], [test "x$build_login" = xyes])
2351
2352 AC_ARG_ENABLE([login-chown-vcs],
2353   AS_HELP_STRING([--enable-login-chown-vcs], [let login chown /dev/vcsN]),
2354   [], [enable_login_chown_vcs=no]
2355 )
2356
2357 AS_IF([test "x$enable_login_chown_vcs" = xyes], [
2358   AC_DEFINE([LOGIN_CHOWN_VCS], [1], [Should login chown /dev/vcsN?])
2359 ])
2360
2361 AC_ARG_ENABLE([login-stat-mail],
2362   AS_HELP_STRING([--enable-login-stat-mail], [let login stat() the mailbox]),
2363   [], [enable_login_stat_mail=no]
2364 )
2365
2366 AS_IF([test "x$enable_login_stat_mail" = xyes], [
2367   AC_DEFINE([LOGIN_STAT_MAIL], [1], [Should login stat() the mailbox?])
2368 ])
2369
2370
2371 AC_ARG_ENABLE([nologin],
2372   AS_HELP_STRING([--disable-nologin], [do not build nologin]),
2373   [], [UL_DEFAULT_ENABLE([nologin], [yes])]
2374 )
2375 UL_BUILD_INIT([nologin])
2376 AM_CONDITIONAL([BUILD_NOLOGIN], [test "x$build_nologin" = xyes])
2377
2378
2379 AC_ARG_ENABLE([sulogin],
2380   AS_HELP_STRING([--disable-sulogin], [do not build sulogin]),
2381   [], [UL_DEFAULT_ENABLE([sulogin], [check])]
2382 )
2383 UL_BUILD_INIT([sulogin])
2384 UL_REQUIRES_HAVE([sulogin], [crypt], [crypt function])
2385 UL_REQUIRES_HAVE([sulogin], [shadow_h], [shadow.h header])
2386 AM_CONDITIONAL([BUILD_SULOGIN], [test "x$build_sulogin" = xyes])
2387
2388
2389 AC_ARG_ENABLE([su],
2390   AS_HELP_STRING([--disable-su], [do not build su]),
2391   [], [UL_DEFAULT_ENABLE([su], [check])]
2392 )
2393 UL_BUILD_INIT([su])
2394 UL_REQUIRES_HAVE([su], [security_pam_appl_h], [PAM header file])
2395 UL_REQUIRES_HAVE([su], [utmpx_h], [utmpx.h header])
2396 UL_REQUIRES_HAVE([su], [gnu_utmpx], [GNU utmpx functions])
2397 AM_CONDITIONAL([BUILD_SU], [test "x$build_su" = xyes])
2398
2399
2400 AC_ARG_ENABLE([runuser],
2401   AS_HELP_STRING([--disable-runuser], [do not build runuser]),
2402   [], [UL_DEFAULT_ENABLE([runuser], [check])]
2403 )
2404 UL_BUILD_INIT([runuser])
2405 UL_REQUIRES_HAVE([runuser], [security_pam_appl_h], [PAM header file])
2406 UL_REQUIRES_HAVE([runuser], [utmpx_h], [utmpx.h header])
2407 UL_REQUIRES_HAVE([runuser], [gnu_utmpx], [GNU utmpx functions])
2408 AM_CONDITIONAL([BUILD_RUNUSER], [test "x$build_runuser" = xyes])
2409
2410
2411 AC_ARG_ENABLE([ul],
2412   AS_HELP_STRING([--disable-ul], [do not build ul]),
2413   [], [UL_DEFAULT_ENABLE([ul], [check])]
2414 )
2415 UL_BUILD_INIT([ul])
2416 UL_REQUIRES_HAVE([ul], [ncursesw, ncurses], [ncursesw or ncurses libraries])
2417 AM_CONDITIONAL([BUILD_UL], [test "x$build_ul" = xyes])
2418
2419
2420 AC_ARG_ENABLE([more],
2421   AS_HELP_STRING([--disable-more], [do not build more]),
2422   [], [UL_DEFAULT_ENABLE([more], [check])]
2423 )
2424 UL_BUILD_INIT([more])
2425 UL_REQUIRES_HAVE([more], [ncursesw, ncurses], [ncursesw or ncurses libraries])
2426 UL_REQUIRES_LINUX([more])
2427 AM_CONDITIONAL([BUILD_MORE], [test "x$build_more" = xyes])
2428
2429
2430 AC_ARG_ENABLE([pg],
2431   AS_HELP_STRING([--enable-pg], [build pg]),
2432   [], [UL_DEFAULT_ENABLE([pg], [no])]
2433 )
2434 UL_BUILD_INIT([pg])
2435 UL_REQUIRES_HAVE([pg], [ncursesw, ncurses], [ncursesw or ncurses library])
2436 AM_CONDITIONAL([BUILD_PG], [test "x$build_pg" = xyes])
2437
2438
2439 AC_ARG_ENABLE([setterm],
2440   AS_HELP_STRING([--disable-setterm], [do not build setterm]),
2441   [], [UL_DEFAULT_ENABLE([setterm], [check])]
2442 )
2443 UL_BUILD_INIT([setterm])
2444 UL_REQUIRES_LINUX([setterm])
2445 UL_REQUIRES_HAVE([setterm], [ncursesw, ncurses], [ncursesw or ncurses library])
2446 AM_CONDITIONAL([BUILD_SETTERM], [test "x$build_setterm" = xyes])
2447
2448 # build_schedutils= is just configure-only variable to control
2449 # ionice, taskset and chrt
2450 AC_ARG_ENABLE([schedutils],
2451   AS_HELP_STRING([--disable-schedutils], [do not build chrt, ionice, taskset]),
2452   [], [UL_DEFAULT_ENABLE([schedutils], [check])]
2453 )
2454
2455
2456 UL_ENABLE_ALIAS([ionice], [schedutils])
2457 UL_BUILD_INIT([ionice])
2458 UL_REQUIRES_SYSCALL_CHECK([ionice],
2459         [UL_CHECK_SYSCALL([ioprio_set],
2460           [alpha],      [442],
2461           [i*86],       [289],
2462           [ia64*],      [1274],
2463           [powerpc*],   [273],
2464           [s390*],      [282],
2465           [sparc*],     [196],
2466           [sh*],        [288],
2467           [x86_64*],    [251])],
2468         [ioprio_set])
2469
2470 UL_REQUIRES_SYSCALL_CHECK([ionice],
2471         [UL_CHECK_SYSCALL([ioprio_get],
2472           [alpha],      [443],
2473           [i*86],       [290],
2474           [ia64*],      [1275],
2475           [powerpc*],   [274],
2476           [s390*],      [283],
2477           [sparc*],     [218],
2478           [sh*],        [289],
2479           [x86_64*],    [252])],
2480         [ioprio_get])
2481
2482 AM_CONDITIONAL([BUILD_IONICE], [test "x$build_ionice" = xyes])
2483
2484
2485 UL_ENABLE_ALIAS([taskset], [schedutils])
2486 UL_BUILD_INIT([taskset])
2487 UL_REQUIRES_HAVE([taskset], [cpu_set_t], [cpu_set_t type])
2488 UL_REQUIRES_SYSCALL_CHECK([taskset],
2489         [UL_CHECK_SYSCALL([sched_getaffinity])],
2490         [sched_getaffinity])
2491 AM_CONDITIONAL([BUILD_TASKSET], [test "x$build_taskset" = xyes])
2492
2493
2494 have_schedsetter=no
2495 AS_IF([test "x$ac_cv_func_sched_setscheduler" = xyes], [have_schedsetter=yes],
2496       [test "x$ac_cv_func_sched_setattr" = xyes], [have_schedsetter=yes])
2497
2498 UL_ENABLE_ALIAS([chrt], [schedutils])
2499 UL_BUILD_INIT([chrt])
2500 UL_REQUIRES_HAVE([chrt], [schedsetter], [sched_set functions])
2501 AM_CONDITIONAL([BUILD_CHRT], [test "x$build_chrt" = xyes])
2502
2503 AS_IF([test "x$build_chrt" = xyes], [
2504         UL_CHECK_SYSCALL([sched_setattr])
2505 ])
2506
2507 UL_ENABLE_ALIAS([uclampset], [schedutils])
2508 UL_BUILD_INIT([uclampset])
2509 UL_REQUIRES_SYSCALL_CHECK([uclampset],
2510         [UL_CHECK_SYSCALL([sched_setattr])], [sched_setattr])
2511 AM_CONDITIONAL([BUILD_UCLAMPSET], [test "x$build_uclampset" = xyes])
2512
2513
2514 AC_ARG_ENABLE([wall],
2515   AS_HELP_STRING([--disable-wall], [do not build wall]),
2516   [], [UL_DEFAULT_ENABLE([wall], [check])]
2517 )
2518 UL_BUILD_INIT([wall])
2519 UL_REQUIRES_HAVE([wall], [utmpx_h], [utmpx.h header])
2520 AM_CONDITIONAL([BUILD_WALL], [test "x$build_wall" = xyes])
2521
2522
2523 AC_ARG_ENABLE([write],
2524   AS_HELP_STRING([--enable-write], [build write]),
2525   [], [UL_DEFAULT_ENABLE([write], [no])]
2526 )
2527 UL_BUILD_INIT([write])
2528 UL_REQUIRES_HAVE([write], [utmpx_h], [utmpx.h header])
2529 UL_REQUIRES_HAVE([write], [gnu_utmpx], [GNU utmpx functions])
2530 AM_CONDITIONAL([BUILD_WRITE], [test "x$build_write" = xyes])
2531
2532
2533 AC_ARG_WITH([btrfs],
2534   AS_HELP_STRING([--without-btrfs], [do not build with btrfs support]),
2535   [], [with_btrfs=check]
2536 )
2537 have_btrfs=no
2538 AS_IF([test "x$with_btrfs" != xno], [
2539   AS_CASE([$with_btrfs:$have_linux_btrfs_h],
2540     [yes:no],
2541     [AC_MSG_ERROR([btrfs selected but linux/btrfs.h not found])],
2542     [check:no],
2543        [AC_MSG_WARN([linux/btrfs.h not found, do not build with btrfs support])],
2544     [*:yes],
2545        [have_btrfs=yes
2546         AC_DEFINE([HAVE_BTRFS_SUPPORT], [1], [Define if btrfs stuff is available])]
2547   )
2548 ])
2549 AM_CONDITIONAL([HAVE_BTRFS], [test "x$have_btrfs" = xyes])
2550
2551
2552 AC_ARG_WITH([systemd],
2553   AS_HELP_STRING([--without-systemd], [do not build with systemd support]),
2554   [], [with_systemd=check]
2555 )
2556
2557 have_systemd=no
2558 AS_IF([test "x$with_systemd" != xno], [
2559   # new version -- all libsystemd-* libs merged into libsystemd
2560   PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [have_systemd=yes], [have_systemd=no])
2561   # old versions
2562   AS_IF([test "x$have_systemd" != "xyes"], [
2563     PKG_CHECK_MODULES([SYSTEMD_DAEMON], [libsystemd-daemon],
2564                       [have_systemd_daemon=yes], [have_systemd_daemon=no])
2565     PKG_CHECK_MODULES([SYSTEMD_JOURNAL], [libsystemd-journal],
2566                       [have_systemd_journal=yes], [have_systemd_journal=no])
2567     AS_IF([test "x$have_systemd_daemon" = "xyes" && test "x$have_systemd_journal" = "xyes" ],[
2568            have_systemd=yes])
2569   ])
2570   AS_CASE([$with_systemd:$have_systemd],
2571     [yes:no],
2572       [AC_MSG_ERROR([systemd expected but libsystemd not found])],
2573     [*:yes],
2574        AC_DEFINE([HAVE_LIBSYSTEMD], [1], [Define if libsystemd is available])
2575        AC_DEFINE([USE_SYSTEMD], [1], [Define if systemd support is wanted ])
2576        AC_CHECK_DECLS([sd_session_get_username], [], [], [#include <systemd/sd-login.h>])
2577   )
2578 ])
2579 AM_CONDITIONAL([HAVE_SYSTEMD], [test "x$have_systemd" = xyes])
2580
2581
2582 AC_ARG_WITH([systemdsystemunitdir],
2583   AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [directory for systemd unit files (requires systemd support)]),
2584   [], [
2585   AS_IF([test "x$have_systemd" = xyes], [
2586     PKG_CHECK_VAR([with_systemdsystemunitdir], [systemd], [systemdsystemunitdir],
2587       [],
2588       [with_systemdsystemunitdir=no])
2589   ])
2590 ])
2591 AS_IF([test "x$with_systemdsystemunitdir" != "xno"], [
2592   AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
2593 ])
2594
2595
2596 AC_ARG_WITH([smack],
2597   AS_HELP_STRING([--with-smack], [build with SMACK support]),
2598   [], [with_smack=no]
2599 )
2600 AS_IF([test "x$with_smack" = xyes], [
2601   AC_DEFINE([HAVE_SMACK], [1], [Add SMACK support])
2602 ])
2603
2604 AC_ARG_WITH([econf],
2605   AS_HELP_STRING([--without-econf], [do not use libeconf]),
2606   [], [with_econf=check]
2607 )
2608
2609 have_econf=no
2610 AS_IF([test "x$with_econf" != xno], [
2611   PKG_CHECK_MODULES([ECONF], [libeconf], [have_econf=yes], [have_econf=no])
2612     AS_CASE([$with_econf:$have_econf],
2613     [yes:no],
2614       [AC_MSG_ERROR([libeconf expected but libeconf not found])],
2615     [*:yes],
2616        AC_DEFINE([HAVE_LIBECONF], [1], [Define if libeconf is available])
2617   )
2618 ])
2619 AM_CONDITIONAL([HAVE_ECONF], [test "x$have_econf" = xyes])
2620
2621 AC_ARG_WITH([vendordir],
2622   AS_HELP_STRING([--with-vendordir=DIR], [Directory for distribution provided configuration files]),
2623   [], []
2624 )
2625 AC_SUBST([vendordir], [$with_vendordir])
2626 AM_CONDITIONAL([USE_VENDORDIR], [test "x$with_vendordir" != x])
2627 AS_IF([test "x$with_vendordir" != x], [
2628   AC_DEFINE([USE_VENDORDIR], [1], [Define to 1 to use vendordir])
2629 ])
2630
2631
2632 AC_ARG_ENABLE([bash-completion],
2633   AS_HELP_STRING([--disable-bash-completion], [do not install bash completion files]),
2634   [], [enable_bash_completion=yes]
2635 )
2636
2637 AM_CONDITIONAL([BUILD_BASH_COMPLETION], [test "x$enable_bash_completion" = xyes])
2638
2639 AC_ARG_WITH([bashcompletiondir],
2640   AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
2641   [], [
2642   AS_IF([test "x$enable_bash_completion" = xyes], [
2643     PKG_CHECK_VAR([with_bashcompletiondir], [bash-completion], [completionsdir],
2644       [],
2645       [with_bashcompletiondir=${datadir}/bash-completion/completions])
2646   ])
2647 ])
2648 AS_IF([test "x$enable_bash_completion" = xyes], [
2649   AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
2650 ])
2651
2652
2653 AC_ARG_WITH([python],
2654   AS_HELP_STRING([--without-python], [do not build python bindings, use --with-python={2,3} to force version]),
2655   [], [with_python=check withval=check]
2656 )
2657
2658 have_python=no
2659 have_libpython=no
2660 AS_IF([test "x$with_python" != xno], [
2661   # We follow distributions default and look for PKG module name "python"
2662   # (minimal version is 2) but if major version is explicitly specified by
2663   # --with-python=2 or --with-python=3 then we look for PKG module "python2" or
2664   # "python3".
2665   AS_IF([test "x$withval" != xno && test "x$withval" != xyes && test "x$withval" != xcheck],
2666         [pymajor="$withval"; PYTHON=python${pymajor}], [pymajor="2"])
2667
2668   # check for python interpreter
2669   AM_PATH_PYTHON([$pymajor], [have_python=yes], [have_python=no])
2670   AS_CASE([$with_python:$have_python],
2671     [yes:no],
2672       [AC_MSG_ERROR([python selected but python interpreter not found])],
2673     [check:no],
2674        [AC_MSG_WARN([python interpreter not found, do not build python bindings])],
2675     [*:yes],
2676        # check for python development stuff
2677        [
2678          PKG_CHECK_MODULES([PYTHON], [python-$PYTHON_VERSION], [have_libpython=yes], [have_libpython=no])
2679
2680          # https://github.com/util-linux/util-linux/issues/2366
2681          AX_COMPARE_VERSION([$PYTHON_VERSION], [ge], [3.12], [
2682            UL_WARN_ADD([-Wno-error=redundant-decls], [PYTHON_CFLAGS])
2683          ])
2684        ]
2685   )
2686 ])
2687
2688
2689 AC_ARG_ENABLE([pylibmount],
2690   AS_HELP_STRING([--disable-pylibmount], [do not build pylibmount]),
2691   [], [UL_DEFAULT_ENABLE([pylibmount], [check])]
2692 )
2693 UL_BUILD_INIT([pylibmount])
2694 UL_REQUIRES_HAVE([pylibmount], [libpython], [libpython])
2695 UL_REQUIRES_BUILD([pylibmount], [libmount])
2696 AM_CONDITIONAL([BUILD_PYLIBMOUNT], [test "x$build_pylibmount" = "xyes"])
2697
2698 # We need to introduce a verbatim dependency into the Makefile, without automake
2699 # trying to interpret it, so push it as a AM_SUBST_NOTMAKE variable.
2700 verbatim_pylibmount_dependency='
2701
2702 # pylibmountexec module must be installed after usrlib_exec libraries,
2703 # otherwise the libtool relink step will fail to find libmount.la and
2704 # will try -lmount which is possibly not available.
2705 install-pylibmountexecLTLIBRARIES: install-usrlib_execLTLIBRARIES
2706
2707 '
2708 AC_SUBST([verbatim_pylibmount_dependency])
2709 AM_SUBST_NOTMAKE([verbatim_pylibmount_dependency])
2710
2711 AC_ARG_ENABLE([pg-bell],
2712   AS_HELP_STRING([--disable-pg-bell], [let pg not ring the bell on invalid keys]),
2713   [], [enable_pg_bell=yes]
2714 )
2715
2716 AS_IF([test "x$enable_pg_bell" = xyes], [
2717   AC_DEFINE([PG_BELL], [1], [Should pg ring the bell on invalid keys?])
2718 ])
2719
2720
2721 AC_DEFUN([FS_PATHS_DEFAULT], [/sbin:/sbin/fs.d:/sbin/fs])
2722 AC_ARG_ENABLE([fs-paths-default],
2723   AS_HELP_STRING([--enable-fs-paths-default=paths], [default search path for fs helpers @<:@FS_PATHS_DEFAULT@:>@]),
2724   [AS_CASE([$enableval],
2725     [yes], [fs_paths_defaults="FS_PATHS_DEFAULT"],
2726     [no],  [fs_paths_defaults=""],
2727     [fs_paths_defaults="$enableval"]
2728   )],
2729   [fs_paths_defaults="FS_PATHS_DEFAULT"]
2730 )
2731 AC_ARG_ENABLE([fs-paths-extra],
2732   AS_HELP_STRING([--enable-fs-paths-extra=paths], [additional search paths for fs helpers]),
2733   [AS_CASE([$enableval],
2734      [yes|no], [fs_paths_extra=""],
2735      [fs_paths_extra="$enableval"]
2736   )],
2737   [fs_paths_extra=""]
2738 )
2739 fs_paths="$fs_paths_defaults"
2740 AS_IF([test "x$fs_paths_extra" != "x"], [
2741   AS_IF([test "x$fs_paths" != "x"], [
2742     fs_paths="${fs_paths}:"
2743   ])
2744   fs_paths="${fs_paths}${fs_paths_extra}"
2745 ])
2746 AC_DEFINE_UNQUOTED([FS_SEARCH_PATH], "$fs_paths", [search path for fs helpers])
2747
2748
2749 AC_ARG_ENABLE([use-tty-group],
2750   AS_HELP_STRING([--disable-use-tty-group], [do not install wall and write setgid tty]),
2751   [], [enable_use_tty_group=yes]
2752 )
2753 AM_CONDITIONAL([USE_TTY_GROUP], [test "x$enable_use_tty_group" = xyes])
2754
2755 AS_IF([test "x$enable_use_tty_group" = xyes], [
2756   AC_DEFINE([USE_TTY_GROUP], [1], [Should wall and write be installed setgid tty?])
2757 ])
2758
2759
2760 AC_ARG_ENABLE([sulogin-emergency-mount],
2761   AS_HELP_STRING([--enable-sulogin-emergency-mount],
2762                  [use emergency mount of /dev and /proc for sulogin]),
2763   [], [enable_sulogin_emergency_mount=no]
2764 )
2765
2766 AS_IF([test "x$enable_sulogin_emergency_mount" = xyes], [
2767   AS_IF([test "x$linux_os" = xyes], [ ],
2768         [AC_MSG_ERROR([--enable-sulogin-emergency-mount selected for non-linux system])])
2769   AC_DEFINE([USE_SULOGIN_EMERGENCY_MOUNT], [1],
2770             [Should sulogin use an emergency mount of /dev and /proc?])
2771 ])
2772
2773
2774 AC_ARG_ENABLE([usrdir-path],
2775   AS_HELP_STRING([--enable-usrdir-path], [use only /usr paths in PATH env. variable (recommended on systems with /bin -> /usr/bin symlinks)]),
2776   [], [enable_usrdir_path=no]
2777 )
2778
2779 AS_IF([test "x$enable_usrdir_path" = xyes], [
2780   AC_DEFINE([USE_USRDIR_PATHS_ONLY], [1], [Define to 1 to remove /bin and /sbin from PATH env.variable])
2781 ])
2782
2783
2784 AC_ARG_ENABLE([makeinstall-chown],
2785   AS_HELP_STRING([--disable-makeinstall-chown], [do not do chown-like operations during "make install"]),
2786   [], [enable_makeinstall_chown=yes]
2787 )
2788 AM_CONDITIONAL([MAKEINSTALL_DO_CHOWN], [test "x$enable_makeinstall_chown" = xyes])
2789
2790
2791 AC_ARG_ENABLE([makeinstall-setuid],
2792   AS_HELP_STRING([--disable-makeinstall-setuid], [do not do setuid chmod operations during "make install"]),
2793   [], [enable_makeinstall_setuid=yes]
2794 )
2795 AM_CONDITIONAL([MAKEINSTALL_DO_SETUID], [test "x$enable_makeinstall_setuid" = xyes])
2796
2797
2798 AC_ARG_ENABLE([colors-default],
2799   AS_HELP_STRING([--disable-colors-default], [do not colorize output from utils by default]),
2800   [], [enable_colors_default=yes]
2801 )
2802 AS_IF([test "x$enable_colors_default" = xyes], [
2803   AC_DEFINE([USE_COLORS_BY_DEFAULT], [1], [Enables colorized output from utils by default])
2804 ])
2805
2806
2807 AC_ARG_WITH([cryptsetup],
2808   AS_HELP_STRING([--with-cryptsetup], [compile with cryptsetup support]),
2809   [], [with_cryptsetup=no]
2810 )
2811
2812 AS_IF([test "x$with_cryptsetup" = xno], [
2813   AM_CONDITIONAL([HAVE_CRYPTSETUP], [false])
2814   AM_CONDITIONAL([CRYPTSETUP_VIA_DLOPEN], [false])
2815 ], [
2816   PKG_CHECK_MODULES([CRYPTSETUP], [libcryptsetup],
2817         [AC_DEFINE([HAVE_CRYPTSETUP], [1], [Define if cryptsetup is available])
2818          UL_PKG_STATIC([CRYPTSETUP_LIBS_STATIC], [libcryptsetup])
2819          AM_CONDITIONAL([HAVE_CRYPTSETUP], [true])
2820          SAVE_CFLAGS="$CFLAGS"
2821          CFLAGS="$CRYPTSETUP_CFLAGS $CFLAGS"
2822          SAVE_LIBS="$LIBS"
2823          LIBS="$CRYPTSETUP_LIBS $LIBS"
2824          AC_CHECK_LIB([cryptsetup], [crypt_activate_by_signed_key], [
2825           AC_DEFINE([HAVE_CRYPT_ACTIVATE_BY_SIGNED_KEY], [1], [Define if crypt_activate_by_signed_key exist in -lcryptsetup])
2826          ])
2827          AS_IF([test "x$with_cryptsetup" = xdlopen], [
2828           LIBS="-ldl $LIBS"
2829           AC_CHECK_LIB([dl], [dlsym], [
2830             AC_DEFINE([CRYPTSETUP_VIA_DLOPEN], [1], [Define if cryptsetup is to be loaded via dlopen])
2831             AM_CONDITIONAL([CRYPTSETUP_VIA_DLOPEN], [true])
2832            ], [AC_MSG_ERROR([libdl required to build with cryptsetup support])])
2833          ], [
2834           AM_CONDITIONAL([CRYPTSETUP_VIA_DLOPEN], [false])
2835          ])
2836          CFLAGS="$SAVE_CFLAGS"
2837          LIBS="$SAVE_LIBS"
2838          have_cryptsetup=yes],
2839         [have_cryptsetup=no
2840    AM_CONDITIONAL([HAVE_CRYPTSETUP], [false])
2841    AM_CONDITIONAL([CRYPTSETUP_VIA_DLOPEN], [false])
2842   ])
2843
2844   AS_CASE([$with_cryptsetup:$have_cryptsetup],
2845     [yes:no], [AC_MSG_WARN([cryptsetup selected but libcryptsetup not found])]
2846   )
2847 ])
2848 AC_SUBST([CRYPTSETUP_LIBS])
2849 AC_SUBST([CRYPTSETUP_LIBS_STATIC])
2850
2851
2852 AC_ARG_VAR([SUID_CFLAGS],
2853            [CFLAGS used for binaries which are usually with the suid bit])
2854 AC_ARG_VAR([SUID_LDFLAGS],
2855            [LDFLAGS used for binaries which are usually with the suid bit])
2856
2857 AC_ARG_VAR([DAEMON_CFLAGS],
2858            [CFLAGS used for binaries which are usually executed as daemons])
2859 AC_ARG_VAR([DAEMON_LDFLAGS],
2860            [LDFLAGS used for binaries which are usually executed as daemons])
2861
2862 AC_ARG_VAR([SOLIB_CFLAGS],
2863            [CFLAGS used for shared libraries])
2864 AC_ARG_VAR([SOLIB_LDFLAGS],
2865            [LDFLAGS used for shared libraries])
2866
2867 AC_ARG_VAR([ADJTIME_PATH],
2868            [Path to hwclock adjtime file, default /etc/adjtime])
2869 AS_IF([test "x$ADJTIME_PATH" = x], [ADJTIME_PATH="/etc/adjtime"])
2870 AC_DEFINE_UNQUOTED([CONFIG_ADJTIME_PATH], "$ADJTIME_PATH", [Path to hwclock adjtime file])
2871
2872 if test "x${build_alias}" != "x${host_alias}"; then
2873   AC_MSG_NOTICE([setting link_all_deplibs=unknown for libtool])
2874   # work around Debian patch to libtool breaking cross-compiles
2875   # https://bugs.debian.org/cgi-bin/bugreport.cgi?bug=702737
2876   # https://bugs.debian.org/cgi-bin/bugreport.cgi?bug=297726
2877   link_all_deplibs=unknown
2878 fi
2879
2880
2881 LIBS=""
2882
2883
2884 AC_CONFIG_HEADERS([config.h])
2885
2886 #
2887 # Don't use configure.ac to replace install paths! See Makefile PATHFILES for
2888 # more details.
2889 #
2890 AC_CONFIG_FILES([
2891 Makefile
2892 libblkid/docs/Makefile
2893 libblkid/docs/version.xml
2894 libblkid/src/blkid.h
2895 libfdisk/docs/Makefile
2896 libfdisk/docs/version.xml
2897 libfdisk/src/libfdisk.h
2898 libmount/docs/Makefile
2899 libmount/docs/version.xml
2900 libmount/src/libmount.h
2901 libsmartcols/docs/Makefile
2902 libsmartcols/docs/version.xml
2903 libsmartcols/src/libsmartcols.h
2904 po/Makefile.in
2905 po-man/Makefile
2906 ])
2907
2908 AC_OUTPUT
2909
2910 AC_MSG_RESULT([
2911         ${PACKAGE}  ${VERSION}
2912
2913         prefix:                    ${prefix}
2914         exec prefix:               ${exec_prefix}
2915
2916         bindir:                    ${bindir}
2917         sbindir:                   ${sbindir}
2918         libdir:                    ${libdir}
2919         usrbin_execdir:            ${usrbin_execdir}
2920         usrsbin_execdir:           ${usrsbin_execdir}
2921         usrlib_execdir:            ${usrlib_execdir}
2922
2923         localstatedir:             ${localstatedir}
2924         runstatedir:               ${runstatedir}
2925         includedir:                ${includedir}
2926         sysconfdir:                ${sysconfdir}
2927         sysconfstaticdir:          ${sysconfstaticdir}
2928
2929         vendordir:                 ${with_vendordir}
2930
2931         Python:                    ${PYTHON}
2932         Python version:            ${PYTHON_VERSION}
2933         Python libs:               ${pyexecdir}
2934
2935         Bash completions:          ${with_bashcompletiondir}
2936         Systemd support:           ${have_systemd}
2937         Systemd unitdir:           ${with_systemdsystemunitdir}
2938         libeconf support:          ${have_econf}
2939         Btrfs support:             ${have_btrfs}
2940         Wide-char support:         ${build_widechar}
2941         libcryptsetup support:     ${have_cryptsetup}
2942
2943         Manual pages:              ${build_asciidoc}
2944         Manual pages translated:   ${build_poman}
2945
2946         compiler:                  ${CC} / ${CXX}
2947         suid cflags:               ${SUID_CFLAGS}
2948         ldflags:                   ${LDFLAGS}
2949         suid ldflags:              ${SUID_LDFLAGS}
2950         ASAN enabled:              ${enable_asan}
2951         Fuzzing enabled:           ${enable_fuzzing_engine}
2952         Coverage enabled           ${enable_coverage}
2953
2954         cflags:                    ${CFLAGS}
2955
2956         warnings:
2957
2958 ${WARN_CFLAGS}
2959
2960  Type 'make' or 'make <utilname>' to compile.
2961 ])