configure.ac

   1 AC_INIT([util-linux],
   2         m4_esyscmd([tools/git-version-gen .tarball-version]),
   3         [kzak@redhat.com], [],
   4         [https://www.kernel.org/pub/linux/utils/util-linux/])
   5
   6
   7 AC_PREREQ([2.64])
   8
   9 AC_CONFIG_AUX_DIR([config])
  10 AC_CONFIG_MACRO_DIR([m4])
  11 dnl AC_USE_SYSTEM_EXTENSIONS must be called before any macros that run
  12 dnl the compiler (like LT_INIT) to avoid autoconf errors.
  13 AC_USE_SYSTEM_EXTENSIONS
  14 AM_INIT_AUTOMAKE([-Wall -Wno-portability foreign 1.10 tar-pax no-dist-gzip dist-xz subdir-objects])
  15
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  17                             [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  18 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  19
  20 AC_CONFIG_SRCDIR([sys-utils/mount.c])
  21 AC_PREFIX_DEFAULT([/usr])
  22
  23 dnl version details from <major>.<minor>[-<suffix>]
  24 PACKAGE_VERSION_MAJOR=$(echo $PACKAGE_VERSION | awk -F. '{print $1}')
  25 PACKAGE_VERSION_MINOR=$(echo $PACKAGE_VERSION | awk -F. '{
  26                                                    sub("-.*","",$2); print $2}')
  27 PACKAGE_VERSION_RELEASE=$(echo $PACKAGE_VERSION | awk -F. '{
  28                      sub("-.*","",$3); print $3 ~ /^@<:@0-9@:>@+$/ ? $3 : 0}')
  29
  30 dnl libblkid version
  31 LIBBLKID_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  32 LIBBLKID_DATE="24-Jan-2024"
  33 LIBBLKID_LT_MAJOR=1
  34 LIBBLKID_LT_MINOR=1
  35 LIBBLKID_LT_MICRO=0
  36 LIBBLKID_VERSION_INFO=`expr $LIBBLKID_LT_MAJOR + $LIBBLKID_LT_MINOR`:$LIBBLKID_LT_MICRO:$LIBBLKID_LT_MINOR
  37
  38 dnl libuuid version
  39 LIBUUID_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  40 LIBUUID_LT_MAJOR=1
  41 LIBUUID_LT_MINOR=3
  42 LIBUUID_LT_MICRO=0
  43 LIBUUID_VERSION_INFO=`expr $LIBUUID_LT_MAJOR + $LIBUUID_LT_MINOR`:$LIBUUID_LT_MICRO:$LIBUUID_LT_MINOR
  44
  45 dnl liblastlog2 version
  46 LIBLASTLOG2_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  47 LIBLASTLOG2_LT_MAJOR=2
  48 LIBLASTLOG2_LT_MINOR=0
  49 LIBLASTLOG2_LT_MICRO=0
  50 LIBLASTLOG2_VERSION_INFO=`expr $LIBLASTLOG2_LT_MAJOR + $LIBLASTLOG2_LT_MINOR`:$LIBLASTLOG2_LT_MICRO:$LIBLASTLOG2_LT_MINOR
  51
  52 dnl libmount version
  53 LIBMOUNT_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  54 LIBMOUNT_LT_MAJOR=1
  55 LIBMOUNT_LT_MINOR=1
  56 LIBMOUNT_LT_MICRO=0
  57 LIBMOUNT_VERSION_INFO=`expr $LIBMOUNT_LT_MAJOR + $LIBMOUNT_LT_MINOR`:$LIBMOUNT_LT_MICRO:$LIBMOUNT_LT_MINOR
  58
  59 dnl libsmartcols version
  60 LIBSMARTCOLS_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  61 LIBSMARTCOLS_LT_MAJOR=1
  62 LIBSMARTCOLS_LT_MINOR=1
  63 LIBSMARTCOLS_LT_MICRO=0
  64 LIBSMARTCOLS_VERSION_INFO=`expr $LIBSMARTCOLS_LT_MAJOR + $LIBSMARTCOLS_LT_MINOR`:$LIBSMARTCOLS_LT_MICRO:$LIBSMARTCOLS_LT_MINOR
  65
  66 dnl libfdisk version
  67 LIBFDISK_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  68 LIBFDISK_LT_MAJOR=1
  69 LIBFDISK_LT_MINOR=1
  70 LIBFDISK_LT_MICRO=0
  71 LIBFDISK_VERSION_INFO=`expr $LIBFDISK_LT_MAJOR + $LIBFDISK_LT_MINOR`:$LIBFDISK_LT_MICRO:$LIBFDISK_LT_MINOR
  72
  73 # Check whether exec_prefix=/usr:
  74 AS_CASE([$exec_prefix:$prefix],
  75 [NONE:NONE | NONE:/usr | /usr:*],
  76   [AC_MSG_NOTICE([Default --exec-prefix detected.])
  77    AS_CASE([$bindir],  ['${exec_prefix}/bin'],  [bindir=/bin;   AC_MSG_NOTICE([  --bindir defaults to /bin])  ])
  78    AS_CASE([$sbindir], ['${exec_prefix}/sbin'], [sbindir=/sbin; AC_MSG_NOTICE([  --sbindir defaults to /sbin])])
  79    AS_CASE([$libdir],  ['${exec_prefix}/lib'],  [libdir=/lib;   AC_MSG_NOTICE([  --libdir defaults to /lib])  ])
  80    AS_CASE([$libdir],  ['${exec_prefix}/lib64'],[libdir=/lib64; AC_MSG_NOTICE([  --libdir defaults to /lib64])  ])
  81   ]
  82 )
  83
  84 # Check whether prefix=/usr
  85 AS_CASE([$prefix],
  86 [NONE | /usr],
  87   [AC_MSG_NOTICE([Default --prefix detected.])
  88    AS_CASE([$localstatedir], [NONE | '${prefix}/var' | "${prefix}"/var ],
  89            [localstatedir=/var; AC_MSG_NOTICE([  --localstatedir defaults to /var])])
  90    AS_CASE([$sysconfdir], [NONE | '${prefix}/etc' | "${prefix}"/etc ],
  91            [sysconfdir=/etc; AC_MSG_NOTICE([  --sysconfdir defaults to /etc])])
  92
  93   ]
  94 )
  95
  96 # default for old versions without $runstatedir
  97 AS_IF([test x"$runstatedir" = x], [runstatedir='${localstatedir}/run'])
  98
  99 # our default if $localstatedir unchanged
 100 AS_CASE([$localstatedir:$runstatedir],
 101  [NONE:'${localstatedir}/run' | /var:'${localstatedir}/run' | NONE:'/run' ],
 102    [runstatedir=/run; AC_MSG_NOTICE([  --runstatedir defaults to /run])]
 103 )
 104
 105 AC_SUBST([runstatedir])
 106
 107
 108 # The original default values of {bin,sbin,lib}dir
 109 usrbin_execdir='${exec_prefix}/bin'
 110 AC_SUBST([usrbin_execdir])
 111
 112 usrsbin_execdir='${exec_prefix}/sbin'
 113 AC_SUBST([usrsbin_execdir])
 114
 115 AS_CASE([$libdir],
 116  ['${exec_prefix}/'* | '${prefix}/'* | /usr/* | "${prefix}"/* ],
 117    [usrlib_execdir=$libdir],
 118  [usrlib_execdir='${exec_prefix}'$libdir]
 119 )
 120 AC_SUBST([usrlib_execdir])
 121
 122 # static configuration maintaned by packages (e.g. /usr/lib)
 123 AC_ARG_VAR([SYSCONFSTATICDIR],
 124            [Path to static system configuration, default ${prefix}/lib])
 125 AS_IF([test "x$SYSCONFSTATICDIR" = x],
 126       [sysconfstaticdir='${prefix}/lib'],
 127       [sysconfstaticdir=$SYSCONFSTATICDIR])
 128 AC_SUBST([sysconfstaticdir])
 129
 130 AC_PROG_CC
 131 AM_PROG_CC_C_O
 132 AC_PROG_MKDIR_P
 133 AC_PROG_YACC
 134
 135 # Don't use autotools integrated LEX/YACC support for libsmartcols
 136 AC_PATH_PROG([FLEX], [flex])
 137 AC_PATH_PROG([BISON], [bison])
 138
 139 AC_CANONICAL_HOST
 140 AC_C_CONST
 141 AC_C_VOLATILE
 142
 143 dnl Compiler warnings
 144 UL_WARN_ADD([-fno-common])
 145 UL_WARN_ADD([-Wall])
 146 UL_WARN_ADD([-Wextra])
 147
 148 UL_WARN_ADD([-Waddress-of-packed-member])
 149 UL_WARN_ADD([-Wdiscarded-qualifiers])
 150 UL_WARN_ADD([-Wembedded-directive])
 151 UL_WARN_ADD([-Wextra-semi])
 152 UL_WARN_ADD([-Wformat-security])
 153 UL_WARN_ADD([-Wimplicit-function-declaration])
 154 UL_WARN_ADD([-Wmissing-declarations])
 155 UL_WARN_ADD([-Wmissing-parameter-type])
 156 UL_WARN_ADD([-Wmissing-prototypes])
 157 UL_WARN_ADD([-Wnested-externs])
 158 UL_WARN_ADD([-Wno-missing-field-initializers])
 159 UL_WARN_ADD([-Wold-style-definition])
 160 UL_WARN_ADD([-Wpointer-arith])
 161 UL_WARN_ADD([-Wredundant-decls])
 162 UL_WARN_ADD([-Wsign-compare])
 163 UL_WARN_ADD([-Wstrict-prototypes])
 164 UL_WARN_ADD([-Wtype-limits])
 165 UL_WARN_ADD([-Wuninitialized])
 166 UL_WARN_ADD([-Wunused-but-set-parameter])
 167 UL_WARN_ADD([-Wunused-but-set-variable])
 168 UL_WARN_ADD([-Wunused-parameter])
 169 UL_WARN_ADD([-Wunused-result])
 170 UL_WARN_ADD([-Wunused-variable])
 171 UL_WARN_ADD([-Wvla])
 172 UL_WARN_ADD([-Walloca])
 173
 174 AC_ARG_ENABLE([werror],
 175   AS_HELP_STRING([--enable-werror], [make all compiler warnings into errors]),
 176   [], [enable_werror=no]
 177 )
 178 AS_IF([test "x$enable_werror" = xyes], [
 179   UL_WARN_ADD([-Werror])
 180 ],[
 181   UL_WARN_ADD([-Werror=sequence-point])
 182 ])
 183
 184 AC_SUBST([WARN_CFLAGS])
 185
 186
 187 UL_WARN_ADD([-Wno-clobbered], [BSD_WARN_CFLAGS])
 188 AC_SUBST([BSD_WARN_CFLAGS])
 189
 190 UL_WARN_ADD([-Wno-cast-function-type], [PYTHON_WARN_CFLAGS])
 191 AC_SUBST([PYTHON_WARN_CFLAGS])
 192
 193
 194 AC_ARG_ENABLE([asan],
 195   AS_HELP_STRING([--enable-asan], [compile with Address Sanitizer]),
 196   [], [enable_asan=no]
 197 )
 198 AS_IF([test "x$enable_asan" = xyes], [
 199   UL_WARN_ADD([-fsanitize=address])
 200   ASAN_LDFLAGS="-fsanitize=address"
 201 ])
 202 AC_SUBST([ASAN_LDFLAGS])
 203
 204 AC_ARG_ENABLE([ubsan],
 205   AS_HELP_STRING([--enable-ubsan], [compile with UBsan]),
 206   [], [enable_ubsan=no]
 207 )
 208 AS_IF([test "x$enable_ubsan" = xyes], [
 209   UL_WARN_ADD([-fsanitize=undefined])
 210   UBSAN_LDFLAGS="-fsanitize=undefined"
 211 ])
 212 AC_SUBST([UBSAN_LDFLAGS])
 213
 214 AC_ARG_ENABLE([fuzzing-engine],
 215   AS_HELP_STRING([--enable-fuzzing-engine], [compile with fuzzing engine]),
 216   [], [enable_fuzzing_engine=no]
 217 )
 218 AS_IF([test "x$enable_fuzzing_engine" = xyes && test "x$LIB_FUZZING_ENGINE" = x], [
 219   UL_WARN_ADD([-fno-omit-frame-pointer])
 220   UL_WARN_ADD([-gline-tables-only])
 221   UL_WARN_ADD([-fsanitize=fuzzer-no-link])
 222   FUZZING_ENGINE_LDFLAGS="-fsanitize=fuzzer-no-link"
 223 ])
 224 AC_SUBST([FUZZING_ENGINE_LDFLAGS])
 225 AC_PROG_CXX
 226 AM_CONDITIONAL([FUZZING_ENGINE], [test "x$enable_fuzzing_engine" = xyes])
 227 AM_CONDITIONAL([OSS_FUZZ], [test "x$LIB_FUZZING_ENGINE" != x])
 228
 229 AC_ARG_ENABLE([coverage],
 230   AS_HELP_STRING([--enable-coverage], [compile with gcov]),
 231   [], [enable_coverage=no]
 232 )
 233 AS_IF([test "x$enable_coverage" = xyes], [
 234   UL_WARN_ADD([--coverage])
 235   COVERAGE_LDFLAGS="--coverage"
 236 ])
 237 AC_SUBST([COVERAGE_LDFLAGS])
 238 AM_CONDITIONAL([WITH_COVERAGE], [test "x$enable_coverage" = xyes])
 239
 240 dnl libtool-2
 241 LT_INIT
 242
 243 dnl check supported linker flags
 244 AX_CHECK_VSCRIPT
 245
 246 m4_ifndef([PKG_PROG_PKG_CONFIG],
 247   [m4_fatal([Could not locate the pkg-config autoconf
 248     macros. These are usually located in /usr/share/aclocal/pkg.m4.
 249     If your macros are in a different location, try setting the
 250     environment variable AL_OPTS="-I/other/macro/dir" before running
 251     ./autogen.sh or autoreconf again. Make sure pkg-config is installed.])])
 252 PKG_PROG_PKG_CONFIG
 253 PKG_INSTALLDIR(['${usrlib_execdir}/pkgconfig'])
 254
 255 GTK_DOC_CHECK([1.10])
 256 AC_PATH_PROG([XSLTPROC], [xsltproc])
 257
 258
 259 linux_os=no
 260 bsd_os=no
 261 AS_CASE([${host_os}],
 262   [*linux*],
 263      [linux_os=yes],
 264   [*darwin*],
 265      [darwin_os=yes],
 266   [*bsd*],
 267      [bsd_os=yes])
 268 AM_CONDITIONAL([LINUX], [test "x$linux_os" = xyes])
 269 AM_CONDITIONAL([DARWIN], [test "x$darwin_os" = xyes])
 270 AM_CONDITIONAL([BSD], [test "x$bsd_os" = xyes])
 271
 272 AS_IF([test  "x$darwin_os" = xyes], [
 273   AC_DEFINE([_DARWIN_C_SOURCE], [1], [Enable MAP_ANON in sys/mman.h on Mac OS X])
 274 ])
 275
 276 dnl define ARCH_<NAME> conditionals
 277 UL_SET_ARCH([I86], [i?86-*])
 278 UL_SET_ARCH([86_64], [x86_64*])
 279 UL_SET_ARCH([IA64], [ia64*])
 280 UL_SET_ARCH([S390], [s390*])
 281 UL_SET_ARCH([SPARC], [sparc*])
 282 UL_SET_ARCH([PPC], [ppc*|powerpc*])
 283 UL_SET_ARCH([M68K], [m68*])
 284 UL_SET_ARCH([MIPS], [mips*])
 285 UL_SET_ARCH([HPPA], [hppa*|parisc*])
 286
 287 AC_SYS_LARGEFILE
 288 AC_HEADER_ASSERT
 289 AC_STRUCT_TIMEZONE
 290 UL_YEAR2038_INIT
 291 AC_SYS_YEAR2038_RECOMMENDED
 292
 293 dnl Don't forget to maintain alternatively allowed versions in autogen.sh!
 294 AM_GNU_GETTEXT_VERSION([0.18.3])
 295 AM_GNU_GETTEXT([external])
 296
 297 AS_IF([test -d "$srcdir/po"], [
 298   ALL_LINGUAS=`cd $srcdir/po > /dev/null && echo *.po | sed 's/\.po//g'`
 299 ], [dnl echo $ALL_LINGUAS | sed 's/ /\n/g' | sort -u | column -xc 72 -o ' ' | sed 's/^/\t/'
 300   ALL_LINGUAS="
 301         af      am      ar      as      be      bg      bn      bn_IN   ca
 302         cs      cy      da      de      el      en_GB   es      et      eu_ES
 303         fa      fi      fr      gl      gu      he      hi      hr      hu
 304         hy      id      is      it      ja      ka      kn      ko      ku
 305         lo      lt      lv      mk      ml      mr      ms      my      nb
 306         nl      nn      no      nso     or      pa      pl      pt      pt_BR
 307         ro      ru      si      sk      sl      sq      sr      sr@Latn sv
 308         ta      te      th      tr      uk      ur      vi      zh_CN   zh_TW
 309         zu
 310 "])
 311
 312 AC_CHECK_HEADERS([linux/compiler.h linux/blkpg.h linux/major.h], [], [], [
 313 #ifdef HAVE_LINUX_COMPILER_H
 314 #include <linux/compiler.h>
 315 #endif
 316 ])
 317 AC_CHECK_HEADERS([ \
 318         asm-generic/fcntl.h \
 319         asm/fcntl.h \
 320         asm/io.h \
 321         byteswap.h \
 322         endian.h \
 323         err.h \
 324         errno.h \
 325         fcntl.h \
 326         getopt.h \
 327         inttypes.h \
 328         lastlog.h \
 329         libutil.h \
 330         linux/blkzoned.h \
 331         linux/btrfs.h \
 332         linux/capability.h \
 333         linux/cdrom.h \
 334         linux/falloc.h \
 335         linux/fd.h \
 336         linux/fiemap.h \
 337         linux/landlock.h \
 338         linux/kcmp.h \
 339         linux/net_namespace.h \
 340         linux/nsfs.h \
 341         linux/pr.h \
 342         linux/raw.h \
 343         linux/securebits.h \
 344         linux/tiocl.h \
 345         linux/version.h \
 346         linux/watchdog.h \
 347         linux/if_alg.h \
 348         locale.h \
 349         mntent.h \
 350         net/if_dl.h \
 351         net/if.h \
 352         netinet/in.h \
 353         paths.h \
 354         pty.h \
 355         security/pam_appl.h \
 356         security/pam_modules.h \
 357         shadow.h \
 358         stdint.h \
 359         stdio_ext.h \
 360         stdlib.h \
 361         sys/disk.h \
 362         sys/disklabel.h \
 363         sys/endian.h \
 364         sys/file.h \
 365         sys/ioccom.h \
 366         sys/ioctl.h \
 367         sys/io.h \
 368         sys/mkdev.h \
 369         sys/mount.h \
 370         sys/param.h \
 371         sys/pidfd.h \
 372         sys/prctl.h \
 373         sys/resource.h \
 374         sys/sendfile.h \
 375         sys/signalfd.h \
 376         sys/socket.h \
 377         sys/sockio.h \
 378         sys/stat.h \
 379         sys/statfs.h \
 380         sys/swap.h \
 381         sys/syscall.h \
 382         sys/sysmacros.h \
 383         sys/time.h \
 384         sys/timex.h \
 385         sys/ttydefaults.h \
 386         sys/types.h \
 387         sys/ucred.h \
 388         sys/un.h \
 389         sys/vfs.h \
 390         sys/xattr.h \
 391         unistd.h \
 392         utmp.h \
 393         utmpx.h \
 394 ])
 395
 396 # There is a collision in old kernel-headers. The both files mount.h and fs.h
 397 # define MS_* macros. Fixed by kernel commit e462ec50cb5fad19f6003a3d8087f4a0945dd2b1.
 398 #
 399 AC_CHECK_HEADERS([linux/fs.h ], [], [],
 400  [#ifdef HAVE_SYS_MOUNT_H
 401    # include <linux/fs.h>
 402    # include <sys/mount.h>
 403   #endif
 404 ])
 405
 406 AC_CHECK_HEADERS([linux/mount.h ], [], [],
 407  [#ifdef HAVE_LINUX_MOUNT_H
 408    # include <linux/mount.h>
 409    #endif
 410 ])
 411
 412 AC_CHECK_HEADERS([linux/gsmmux.h ], [], [],
 413  [#ifdef LINUX_GSMMUX_H
 414    # include <linux/gsmmux.h>
 415    #endif
 416 ])
 417
 418 AC_CHECK_HEADERS([security/pam_misc.h],
 419                 [AM_CONDITIONAL([HAVE_LINUXPAM], [true])],
 420                 [AM_CONDITIONAL([HAVE_LINUXPAM], [false])], [
 421 #ifdef HAVE_SECURITY_PAM_APPL_H
 422 #include <security/pam_appl.h>
 423 #endif
 424 ])
 425
 426 AC_CHECK_DECLS([BLK_ZONE_REP_CAPACITY], [], [], [
 427         #include <linux/blkzoned.h>
 428 ])
 429
 430 AC_CHECK_DECLS([PR_REP_CAPACITY], [], [], [
 431         #include <linux/pr.h>
 432 ])
 433
 434 AC_CHECK_HEADERS([security/openpam.h], [], [], [
 435 #ifdef HAVE_SECURITY_PAM_APPL_H
 436 #include <security/pam_appl.h>
 437 #endif
 438 ])
 439
 440 AC_CHECK_HEADERS([langinfo.h],
 441                 [AM_CONDITIONAL([HAVE_LANGINFO_H], [true])],
 442                 [AM_CONDITIONAL([HAVE_LANGINFO_H], [false])])
 443
 444 AC_MSG_CHECKING([whether langinfo.h defines ALTMON_x constants])
 445 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 446         #include <langinfo.h>
 447 ]], [[
 448         char *str;
 449         str = nl_langinfo (ALTMON_1);
 450         str = nl_langinfo (ALTMON_2);
 451         str = nl_langinfo (ALTMON_3);
 452         str = nl_langinfo (ALTMON_4);
 453         str = nl_langinfo (ALTMON_5);
 454         str = nl_langinfo (ALTMON_6);
 455         str = nl_langinfo (ALTMON_7);
 456         str = nl_langinfo (ALTMON_8);
 457         str = nl_langinfo (ALTMON_9);
 458         str = nl_langinfo (ALTMON_10);
 459         str = nl_langinfo (ALTMON_11);
 460         str = nl_langinfo (ALTMON_12);
 461 ]])], [
 462         AC_MSG_RESULT([yes])
 463         AC_DEFINE([HAVE_LANGINFO_ALTMON], [1],
 464                 [Define if langinfo.h defines ALTMON_x constants])
 465 ], [
 466         AC_MSG_RESULT([no])
 467 ])
 468
 469
 470 AC_MSG_CHECKING([whether langinfo.h defines _NL_ABALTMON_x constants])
 471 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 472         #include <langinfo.h>
 473 ]], [[
 474         char *str;
 475         str = nl_langinfo (_NL_ABALTMON_1);
 476         str = nl_langinfo (_NL_ABALTMON_2);
 477         str = nl_langinfo (_NL_ABALTMON_3);
 478         str = nl_langinfo (_NL_ABALTMON_4);
 479         str = nl_langinfo (_NL_ABALTMON_5);
 480         str = nl_langinfo (_NL_ABALTMON_6);
 481         str = nl_langinfo (_NL_ABALTMON_7);
 482         str = nl_langinfo (_NL_ABALTMON_8);
 483         str = nl_langinfo (_NL_ABALTMON_9);
 484         str = nl_langinfo (_NL_ABALTMON_10);
 485         str = nl_langinfo (_NL_ABALTMON_11);
 486         str = nl_langinfo (_NL_ABALTMON_12);
 487 ]])], [
 488         AC_MSG_RESULT([yes])
 489         AC_DEFINE([HAVE_LANGINFO_NL_ABALTMON], [1],
 490                 [Define if langinfo.h defines _NL_ABALTMON_x constants])
 491 ], [
 492         AC_MSG_RESULT([no])
 493 ])
 494
 495
 496 dnl Convert some ac_cv_header_* variables to have_*
 497 dnl
 498 have_linux_blkzoned_h=$ac_cv_header_linux_blkzoned_h
 499 have_linux_btrfs_h=$ac_cv_header_linux_btrfs_h
 500 have_linux_capability_h=$ac_cv_header_linux_capability_h
 501 have_linux_kcmp_h=$ac_cv_header_linux_kcmp_h
 502 have_linux_mount_h=$ac_cv_header_linux_mount_h
 503 have_linux_pr_h=$ac_cv_header_linux_pr_h
 504 have_linux_raw_h=$ac_cv_header_linux_raw_h
 505 have_linux_securebits_h=$ac_cv_header_linux_securebits_h
 506 have_linux_version_h=$ac_cv_header_linux_version_h
 507 have_linux_watchdog_h=$ac_cv_header_linux_watchdog_h
 508 have_pty_h=$ac_cv_header_pty_h
 509 have_security_openpam_h=$ac_cv_header_security_openpam_h
 510 have_security_pam_appl_h=$ac_cv_header_security_pam_appl_h
 511 have_security_pam_misc_h=$ac_cv_header_security_pam_misc_h
 512 have_security_pam_modules_h=$ac_cv_header_security_pam_modules_h
 513 have_shadow_h=$ac_cv_header_shadow_h
 514 have_sys_signalfd_h=$ac_cv_header_sys_signalfd_h
 515 have_utmpx_h=$ac_cv_header_utmpx_h
 516 have_mntent_h=$ac_cv_header_mntent_h
 517
 518 AS_CASE([$linux_os:$have_linux_version_h],
 519   [yes:no],
 520     [AC_MSG_ERROR([kernel headers required on Linux])]
 521 )
 522
 523 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 524 #include <time.h>
 525 #include <unistd.h>
 526 ]], [[
 527     int a = 0;
 528     struct tm *tm = localtime(0);
 529     if (a == -1)  /* false */
 530         sleep(tm->tm_gmtoff);
 531 ]])],
 532 [AC_DEFINE([HAVE_TM_GMTOFF], [1], [Does struct tm have a field tm_gmtoff?])
 533 ])
 534
 535 AC_CHECK_TYPES([struct mount_attr], [], [], [[#include <linux/mount.h>]])
 536 AC_CHECK_TYPES([enum fsconfig_command], [], [], [[#include <linux/mount.h>]])
 537
 538 AC_CHECK_MEMBERS([struct termios.c_line],,,
 539     [[#include <termios.h>]])
 540
 541 AC_CHECK_MEMBERS([struct stat.st_mtim.tv_nsec],,,
 542     [[#include <sys/stat.h>]])
 543
 544 AC_CHECK_TYPES([struct statx], [], [], [[#include <sys/stat.h>]])
 545 AC_CHECK_MEMBERS([struct statx.stx_mnt_id],,,
 546     [[#include <sys/stat.h>]])
 547
 548 AC_CHECK_DECLS([_NL_TIME_WEEK_1STDAY],[],[],[[#include <langinfo.h>]])
 549
 550 AC_CHECK_DECL([environ],
 551         [AC_DEFINE([HAVE_ENVIRON_DECL], [1],
 552                 [Define to 1 if have **environ prototype])],
 553 )
 554
 555 AC_CHECK_DECL([strsignal],
 556         [AC_DEFINE([HAVE_STRSIGNAL_DECL], [1],
 557                 [Define to 1 if have strsignal function prototype])],
 558 )
 559
 560 AC_CHECK_DECL([TIOCGLCKTRMIOS],
 561               [have_tiocglcktrmios=yes], [have_tiocglcktrmios=no],
 562               [#include <sys/ioctl.h>])
 563 AC_CHECK_DECL([SOCK_CLOEXEC],
 564               [have_sock_cloexec=yes], [have_sock_cloexec=no],
 565               [#include <sys/types.h>
 566                #include <sys/socket.h>])
 567 AC_CHECK_DECL([SOCK_NONBLOCK],
 568               [have_sock_nonblock=yes], [have_sock_nonblock=no],
 569               [#include <sys/types.h>
 570                #include <sys/socket.h>])
 571 AC_CHECK_DECL([SO_PASSCRED],
 572               [have_so_passcred=yes], [have_so_passcred=no],
 573               [#include <sys/types.h>
 574                #include <sys/socket.h>])
 575
 576 AC_CHECK_FUNCS([ \
 577         cachestat \
 578         clearenv \
 579         close_range \
 580         eaccess \
 581         err \
 582         errx \
 583         explicit_bzero \
 584         __fpending \
 585         __fpurge \
 586         fpurge \
 587         fnmatch \
 588         fsconfig \
 589         fsmount \
 590         fsopen \
 591         fspick \
 592         fsync \
 593         getdomainname \
 594         getdtablesize \
 595         getexecname \
 596         getmntinfo \
 597         getrandom \
 598         getrlimit \
 599         getsgnam \
 600         getttynam \
 601         inotify_init \
 602         jrand48 \
 603         landlock_create_ruleset \
 604         landlock_add_rule \
 605         landlock_restrict_self \
 606         lchown \
 607         lgetxattr \
 608         llistxattr \
 609         llseek \
 610         newlocale \
 611         mempcpy \
 612         mkostemp \
 613         move_mount \
 614         mount_setattr \
 615         nanosleep \
 616         ntp_gettime \
 617         open_tree \
 618         personality \
 619         pidfd_open \
 620         pidfd_send_signal \
 621         posix_fadvise \
 622         prctl \
 623         qsort_r \
 624         reallocarray \
 625         renameat2 \
 626         rpmatch \
 627         scandirat \
 628         sched_setattr \
 629         sched_setscheduler \
 630         __secure_getenv \
 631         secure_getenv \
 632         sendfile \
 633         setprogname \
 634         setresgid \
 635         setresuid \
 636         sigqueue \
 637         srandom \
 638         statx \
 639         strnchr \
 640         strndup \
 641         strnlen \
 642         strtod_l \
 643         sysconf \
 644         sysinfo \
 645         timegm \
 646         usleep \
 647         uselocale \
 648         utimensat \
 649         vwarnx \
 650         warn \
 651         warnx \
 652 ])
 653 AC_FUNC_FSEEKO
 654
 655 AC_CHECK_FUNCS([futimens], [have_futimens=yes])
 656 AC_CHECK_FUNCS([getusershell], [have_getusershell=yes],[have_getusershell=no])
 657 AC_CHECK_FUNCS([inotify_init1], [have_inotify_init1=yes])
 658 AC_CHECK_FUNCS([ioperm iopl], [have_io=yes])
 659 AC_CHECK_FUNCS([openat fstatat unlinkat], [have_openat=yes], [have_openat=no])
 660 AC_CHECK_FUNCS([open_memstream], [have_open_memstream=yes],[have_open_memstream=no])
 661 AC_CHECK_FUNCS([reboot], [have_reboot=yes],[have_reboot=no])
 662 AC_CHECK_FUNCS([updwtmpx updwtmpx], [have_gnu_utmpx=yes], [have_gnu_utmpx=no])
 663
 664 AM_CONDITIONAL([HAVE_OPENAT], [test "x$have_openat" = xyes])
 665 AM_CONDITIONAL([HAVE_LINUX_LANDLOCK_H], [test "x$ac_cv_header_linux_landlock_h" = xyes])
 666
 667 have_setns_syscall="yes"
 668 UL_CHECK_SYSCALL([setns])
 669 AS_IF([test "x$ul_cv_syscall_setns" = xno], [
 670    have_setns_syscall="no"
 671 ])
 672
 673 UL_CHECK_SYSCALL([pidfd_open])
 674 UL_CHECK_SYSCALL([pidfd_send_signal])
 675 UL_CHECK_SYSCALL([close_range])
 676 UL_CHECK_SYSCALL([fsconfig])
 677 UL_CHECK_SYSCALL([fsmount])
 678 UL_CHECK_SYSCALL([fsopen])
 679 UL_CHECK_SYSCALL([fspick])
 680 UL_CHECK_SYSCALL([mount_setattr])
 681 UL_CHECK_SYSCALL([move_mount])
 682 UL_CHECK_SYSCALL([open_tree])
 683
 684 AS_IF([test "x$ul_cv_syscall_fsconfig" = xno ||
 685        test "x$ul_cv_syscall_fsmount" = xno ||
 686        test "x$ul_cv_syscall_fsopen" = xno ||
 687        test "x$ul_cv_syscall_fspick" = xno ||
 688        test "x$ul_cv_syscall_mount_setattr" = xno ||
 689        test "x$ul_cv_syscall_move_mount" = xno ||
 690        test "x$ul_cv_syscall_open_tree" = xno],
 691    [
 692         have_mountfd_api="no"
 693    ],[
 694         have_mountfd_api="yes"
 695         AC_DEFINE([HAVE_MOUNTFD_API], [1], [Define to 1 if you want mount API based on FDs.])
 696    ])
 697
 698
 699 AC_CHECK_FUNCS([isnan], [],
 700         [AC_CHECK_LIB([m], [isnan], [MATH_LIBS="-lm"])]
 701         [AC_CHECK_LIB([m], [__isnan], [MATH_LIBS="-lm"])]
 702 )
 703 AC_SUBST([MATH_LIBS])
 704
 705
 706 dnl lib/mononotic.c may require -lrt
 707 AC_CHECK_FUNCS([clock_gettime], [],
 708         [AC_CHECK_LIB([rt], [clock_gettime], [REALTIME_LIBS="-lrt"])]
 709 )
 710
 711 have_timer="no"
 712 AC_CHECK_FUNCS([timer_create],
 713         [have_timer="yes"],
 714         [AC_CHECK_LIB([rt], [timer_create], [
 715                 have_timer="yes"
 716                 REALTIME_LIBS="-lrt"
 717                 AC_DEFINE([HAVE_TIMER_CREATE], [1], [Define if timer_create exist in -lrt])
 718         ],[
 719                 AC_SEARCH_LIBS([timer_create], [rt], [
 720                         AC_MSG_RESULT(yes)
 721                         have_timer="yes"
 722                         REALTIME_LIBS="-lrt -lpthread"
 723                         AC_DEFINE([HAVE_TIMER_CREATE], [1], [Define if timer_create exist in -lrt -lpthread])
 724                 ],[], [-lpthread]
 725                 )
 726         ])]
 727 )
 728
 729 AC_SUBST([REALTIME_LIBS])
 730
 731 AS_IF([test x"$have_timer" = xno], [
 732        AC_CHECK_FUNCS([setitimer], [have_timer="yes"], [have_timer="no"])
 733 ])
 734
 735
 736 AC_CHECK_LIB([rtas], [rtas_get_sysparm], [
 737         RTAS_LIBS="-lrtas"
 738         AC_DEFINE([HAVE_LIBRTAS], [1], [Define if librtas exists])
 739 ])
 740 AC_SUBST([RTAS_LIBS])
 741
 742
 743 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 744                 AC_DEFINE([HAVE_SA_LEN], [1], [Define if struct sockaddr contains sa_len]), [],
 745         [#include <sys/types.h>
 746          #include <sys/socket.h>])
 747
 748 SOCKET_LIBS=
 749 AC_SEARCH_LIBS([socket], [socket],
 750         [AS_IF([test x"$ac_cv_search_socket" != x"none required"],
 751                 [SOCKET_LIBS="$SOCKET_LIBS -lsocket"])
 752 ])
 753 AC_SUBST([SOCKET_LIBS])
 754
 755
 756 have_dirfd=no
 757 AC_CHECK_FUNCS([dirfd], [have_dirfd=yes], [have_dirfd=no])
 758 AS_IF([test x"$have_dirfd" = xno], [
 759         AC_CHECK_DECLS([dirfd],
 760                 [have_dirfd=yes], [have_dirfd=no],
 761                 [#include <sys/types.h>
 762                  #include <dirent.h>])
 763 ])
 764
 765 have_ddfd=no
 766 AS_IF([test x"$have_dirfd" = xno], [
 767         AC_CHECK_MEMBERS([DIR.dd_fd],
 768                 [have_ddfd=yes], [have_ddfd=no],
 769                 [#include <sys/types.h>
 770                  #include <dirent.h>])
 771 ])
 772
 773 AM_CONDITIONAL([HAVE_DIRFD], [test "x$have_dirfd" = xyes || test "x$have_ddfd" = xyes])
 774
 775 MQ_LIBS=
 776 AC_CHECK_LIB([rt], [mq_open], [MQ_LIBS="-lrt"])
 777 AC_SUBST([MQ_LIBS])
 778
 779 AC_MSG_CHECKING([whether program_invocation_short_name is defined])
 780 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 781         #include <errno.h>
 782 ]], [[
 783         program_invocation_short_name = "test";
 784 ]])], [
 785         AC_MSG_RESULT([yes])
 786         AC_DEFINE([HAVE_PROGRAM_INVOCATION_SHORT_NAME], [1],
 787                 [Define if program_invocation_short_name is defined])
 788 ], [
 789         AC_MSG_RESULT([no])
 790 ])
 791
 792
 793 AC_MSG_CHECKING([whether __progname is defined])
 794 AC_LINK_IFELSE([AC_LANG_PROGRAM([extern char *__progname;],
 795            [if (*__progname == 0) return 1;])],
 796            AC_DEFINE([HAVE___PROGNAME], [1], [Define if __progname is defined])
 797            AC_MSG_RESULT([yes]),
 798            AC_MSG_RESULT([no]))
 799
 800 AC_CHECK_DECL([IOC_OPAL_GET_STATUS],
 801         [AC_DEFINE([HAVE_OPAL_GET_STATUS], [1],
 802                 [Define to 1 if OPAL status ioctl is defined])],,
 803               [#include <linux/sed-opal.h>])
 804
 805 dnl Static compilation
 806 m4_define([UL_STATIC_PROGRAMS], [blkid, fdisk, losetup, mount, nsenter, sfdisk, umount, unshare])
 807
 808 AC_ARG_ENABLE([static-programs],
 809   [AS_HELP_STRING([--enable-static-programs=LIST],
 810       [link static the programs in LIST (comma-separated,
 811       supported for ]m4_defn([UL_STATIC_PROGRAMS])[)])])
 812
 813 AS_CASE([$enable_static_programs],
 814   [yes],
 815     [enable_static_programs=m4_quote(UL_STATIC_PROGRAMS)],
 816   [no],
 817     [enable_static_programs=]
 818 )
 819
 820 dnl Set all the individual AM_CONDITIONALs
 821 m4_foreach([UL_PRG], m4_defn([UL_STATIC_PROGRAMS]), [
 822   AS_CASE([,$enable_static_programs,],
 823    [*,UL_PRG,*], [static_[]UL_PRG=yes]
 824   )
 825   AS_IF([test "x$static_[]UL_PRG" = xyes], [AC_MSG_NOTICE([enable static build: UL_PRG.])])
 826   AM_CONDITIONAL([HAVE_STATIC_]m4_toupper(UL_PRG),
 827     [test "x$static_[]UL_PRG" = xyes])
 828 ])
 829
 830
 831 AC_ARG_ENABLE([all-programs],
 832   AS_HELP_STRING([--disable-all-programs], [disable everything, might be overridden by --enable-<name>]),
 833   [], [enable_all_programs=undefined]
 834 )
 835
 836 AS_CASE([$enable_all_programs],
 837   [yes], [AC_MSG_WARN([force to build all programs by default])
 838           ul_default_estate=check],
 839   [no],  [AC_MSG_WARN([disable all programs and man pages by default])
 840           ul_default_estate=no]
 841 )
 842
 843
 844 AC_ARG_ENABLE([asciidoc],
 845   AS_HELP_STRING([--disable-asciidoc], [do not generate man pages from asciidoc]),
 846   [], [UL_DEFAULT_ENABLE([asciidoc], [check])]
 847 )
 848 UL_BUILD_INIT([asciidoc])
 849 UL_REQUIRES_PROGRAM([asciidoc], [ASCIIDOCTOR], [asciidoctor], [man pages])
 850 AM_CONDITIONAL([ENABLE_ASCIIDOC], [test "x$build_asciidoc" = xyes])
 851 have_asciidoctor_failure_level=no
 852 AS_IF([test "x$build_asciidoc" = xyes], [
 853        AC_MSG_CHECKING([whether ${ASCIIDOCTOR} supports --failure-level])
 854        AS_IF([${ASCIIDOCTOR} --help | grep failure-level >/dev/null 2>&1 ], [
 855          AC_MSG_RESULT([yes])
 856          have_asciidoctor_failure_level=yes
 857        ], [
 858          AC_MSG_RESULT([no])
 859        ])
 860 ])
 861 AM_CONDITIONAL([HAVE_ASCIIDOCTOR_FAILURE_LEVEL], [test "x$have_asciidoctor_failure_level" = xyes])
 862
 863 have_manpages=no
 864 AS_IF([test -f "$srcdir/sys-utils/mount.8"], [
 865    AC_MSG_NOTICE([re-use already generated man-pages.])
 866    have_manpages=yes]
 867 )
 868 AM_CONDITIONAL([HAVE_MANPAGES], [test "x$have_manpages" = xyes])
 869
 870
 871 AC_ARG_ENABLE([poman],
 872   AS_HELP_STRING([--disable-poman], [generate translated man pages]),
 873   [], [UL_DEFAULT_ENABLE([poman], [check])]
 874 )
 875 UL_BUILD_INIT([poman])
 876 UL_REQUIRES_PROGRAM([poman], [PO4A], [po4a], [translated man pages])
 877 AM_CONDITIONAL([ENABLE_POMAN], [test "x$build_poman" = xyes])
 878
 879
 880 AX_CHECK_TLS
 881
 882 have_pty=no
 883 AC_ARG_WITH([util], AS_HELP_STRING([--without-util], [compile without libutil]),
 884   [], [with_util=auto]
 885 )
 886 AS_IF([test "x$with_util" = xno], [
 887   AM_CONDITIONAL([HAVE_UTIL], [false])
 888   have_util=no
 889 ], [
 890   UL_CHECK_LIB([util], [openpty])
 891 ])
 892
 893 AS_IF([test "x$have_pty_h" = xyes && test "x$have_sys_signalfd_h" = xyes && test "x$have_util" = xyes], [
 894    AM_CONDITIONAL([HAVE_PTY], [true])
 895    AC_DEFINE([HAVE_PTY], [1], [have PTY support])
 896    have_pty=yes
 897 ], [
 898    AM_CONDITIONAL([HAVE_PTY], [false])
 899 ])
 900
 901 AC_CHECK_TYPES([union semun], [], [], [[
 902 #include <sys/sem.h>
 903 ]])
 904 AC_CHECK_TYPES([loff_t])
 905
 906
 907 AC_ARG_ENABLE([widechar],
 908   AS_HELP_STRING([--disable-widechar], [do not compile wide character support]),
 909   [], [enable_widechar=check]
 910 )
 911 UL_BUILD_INIT([widechar])
 912 UL_REQUIRES_COMPILE([widechar], [[
 913   #include <wchar.h>
 914   #include <wctype.h>
 915   #include <stdio.h>
 916   #include <stdlib.h>
 917   ]], [[
 918     wchar_t wc;
 919     wint_t w;
 920     w = fgetwc(stdin);
 921     if (w == WEOF) exit(1);
 922     wc = w;
 923     fputwc(wc,stdout);
 924   ]],
 925   [wchar_t support])
 926
 927 AS_IF([test "x$build_widechar" = xyes ], [
 928   AC_DEFINE([HAVE_WIDECHAR], [1], [Do we have wide character support?])
 929 ])
 930
 931
 932 AC_CHECK_TYPES([cpu_set_t], [have_cpu_set_t=yes], [], [[
 933 #include <sched.h>
 934 ]])
 935
 936 AM_CONDITIONAL([HAVE_CPU_SET_T], [test "x$have_cpu_set_t" = xyes])
 937
 938 AC_CHECK_TYPES([sighandler_t], [], [], [[
 939 #include <signal.h>
 940 ]])
 941
 942 AC_CHECK_DECLS([CPU_ALLOC], [], [], [[
 943 #include <sched.h>
 944 ]])
 945
 946 # on Solaris, you can't mix and match standards, since we use c99
 947 # apparently at this stage, XOPEN_SOURCE will conflict.  As workaround,
 948 # check for crypt.h and use that without XOPEN_SOURCE.
 949 have_crypt=no
 950 AC_CHECK_HEADERS([crypt.h])
 951 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 952 #ifdef HAVE_CRYPT_H
 953 #include <crypt.h>
 954 #else
 955 #define _XOPEN_SOURCE
 956 #include <unistd.h>
 957 #endif
 958 ]], [[
 959 char *c = crypt("abc","pw");
 960 ]])],[
 961   have_libcrypt=no
 962   have_crypt=yes
 963 ],[
 964   UL_SET_LIBS([-lcrypt])
 965   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 966   #ifdef HAVE_CRYPT_H
 967   #include <crypt.h>
 968   #else
 969   #define _XOPEN_SOURCE
 970   #include <unistd.h>
 971   #endif
 972   ]], [[
 973   char *c = crypt("abc","pw");
 974   ]])],[
 975   have_libcrypt=yes
 976   have_crypt=yes
 977   ],[
 978   AC_MSG_WARN([crypt() is not available])
 979   ])
 980   UL_RESTORE_LIBS
 981 ])
 982 AM_CONDITIONAL([HAVE_LIBCRYPT], [test "x$have_libcrypt" = xyes])
 983
 984
 985 AC_ARG_WITH([selinux],
 986   AS_HELP_STRING([--with-selinux], [compile with SELinux support]),
 987   [], [with_selinux=no]
 988 )
 989
 990 AS_IF([test "x$with_selinux" = xno], [
 991   AM_CONDITIONAL([HAVE_SELINUX], [false])
 992 ], [
 993   PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.5], [have_selinux=yes], [have_selinux=no])
 994   AS_CASE([$with_selinux:$have_selinux],
 995     [yes:no], [AC_MSG_ERROR([SELinux selected but libselinux not found or too old])]
 996   )
 997   AS_IF([test "x$have_selinux" = xyes], [
 998     AC_DEFINE([HAVE_LIBSELINUX], [1], [Define if SELinux is available])
 999     UL_PKG_STATIC([SELINUX_LIBS_STATIC], [libselinux])
1000     AM_CONDITIONAL([HAVE_SELINUX], [true])
1001
1002     UL_SET_LIBS([$SELINUX_LIBS])
1003     # This function is missing in old libselinux 1.xx versions
1004     AC_CHECK_FUNCS([security_get_initial_context])
1005     UL_RESTORE_LIBS
1006   ])
1007 ])
1008 AC_SUBST([SELINUX_LIBS])
1009 AC_SUBST([SELINUX_LIBS_STATIC])
1010
1011
1012 AC_ARG_WITH([audit],
1013   AS_HELP_STRING([--with-audit], [compile with audit support]),
1014   [], [with_audit=no]
1015 )
1016
1017 AS_IF([test "x$with_audit" = xno], [
1018   AM_CONDITIONAL([HAVE_AUDIT], [false])
1019 ], [
1020   UL_CHECK_LIB([audit], [audit_log_user_message])
1021   AS_CASE([$with_audit:$have_audit],
1022     [yes:no],
1023       [AC_MSG_ERROR([Audit selected but libaudit not found (or does not support audit_log_user_message())])]
1024   )
1025 ])
1026
1027 AC_ARG_WITH([udev], AS_HELP_STRING([--without-udev], [compile without udev support]),
1028   [], [with_udev=auto]
1029 )
1030
1031 AS_IF([test "x$with_udev" = xno], [
1032   AM_CONDITIONAL([HAVE_UDEV], [false])
1033 ], [
1034   UL_CHECK_LIB([udev], [udev_new])
1035   AS_CASE([$with_udev:$have_udev],
1036     [yes:no],
1037       [AC_MSG_ERROR([udev selected but libudev not found])]
1038   )
1039 ])
1040
1041
1042 dnl wide-char ncurses
1043 AC_ARG_WITH([ncursesw],
1044   AS_HELP_STRING([--without-ncursesw], [do not build with wide-char ncurses]),
1045   [], [with_ncursesw=auto]
1046 )
1047 have_ncursesw=no
1048 have_ncursesw_header=no
1049 AS_IF([test "x$with_ncursesw" != xno], [
1050   UL_NCURSES_CHECK([ncursesw])
1051   AS_IF([test "x$have_ncursesw" = xyes], [
1052     AC_CHECK_HEADERS([ncursesw/ncurses.h], [have_ncursesw_header=yes])
1053     AC_CHECK_HEADERS([ncursesw/term.h])
1054
1055     # Define HAVE_NCURSES_H only if check for HAVE_NCURSESW_NCURSES_H is
1056     # unsuccessful to avoid too many *_H permitations in config.h
1057     AS_IF([test "x$have_ncursesw_header" = xno], [
1058            AC_CHECK_HEADERS([ncurses.h], [have_ncursesw_header=yes])
1059            AC_CHECK_HEADERS([term.h])
1060     ])
1061     AS_IF([test "x$have_ncursesw_header" = xno], [have_ncursesw=no])
1062   ])
1063   AS_IF([test "x$have_ncursesw" = xyes], [
1064     CURSES_LIB_NAME="ncursesw"
1065     AC_DEFINE([HAVE_LIBNCURSESW], [1], [Define if ncursesw library available])
1066   ])
1067 ])
1068 AS_CASE([$with_ncursesw:$have_ncursesw],
1069   [yes:no], [AC_MSG_ERROR([ncursesw selected, but library not found])])
1070
1071
1072 dnl non-wide ncurses
1073 AC_ARG_WITH([ncurses],
1074   AS_HELP_STRING([--with-ncurses], [build with non-wide ncurses]),
1075   [], [with_ncurses=auto]
1076 )
1077 have_ncurses=no
1078 have_ncurses_header=no
1079 AS_CASE([$with_ncurses:$build_widechar],
1080   [yes:yes], [AC_MSG_ERROR([wide-char support enabled, but non-wide ncurses selects])])
1081
1082 AS_IF([test "x$have_ncursesw" = xno && test "x$with_ncurses" != xno ], [
1083   UL_NCURSES_CHECK([ncurses])
1084   AS_IF([test "x$have_ncurses" = xyes], [
1085     AC_CHECK_HEADERS([ncurses/ncurses.h], [have_ncurses_header=yes])
1086     AC_CHECK_HEADERS([ncurses/term.h])
1087
1088     # Define HAVE_NCURSES_H only if check for HAVE_NCURSES_NCURSES_H is
1089     # unsuccessful to avoid too many *_H permitations in config.h
1090     AS_IF([test "x$have_ncurses_header" = xno], [
1091            AC_CHECK_HEADERS([ncurses.h], [have_ncurses_header=yes])
1092            AC_CHECK_HEADERS([term.h])
1093     ])
1094     AS_IF([test "x$have_ncurses_header" = xno], [have_ncurses=no])
1095   ])
1096   AS_IF([test "x$have_ncurses" = xyes], [
1097     CURSES_LIB_NAME="ncurses"
1098     AC_DEFINE([HAVE_LIBNCURSES], [1], [Define if ncurses library available])
1099   ])
1100 ])
1101 AS_CASE([$with_ncurses:$have_ncurses],
1102   [yes:no], [AC_MSG_ERROR([ncurses selected, but library not found])])
1103
1104 AC_SUBST([NCURSES_CFLAGS])
1105 AC_SUBST([NCURSES_LIBS])
1106 AM_CONDITIONAL([HAVE_NCURSES], [test "x$have_ncursesw" = xyes || test "x$have_ncurses" = xyes])
1107
1108
1109 AC_ARG_WITH([slang],
1110   AS_HELP_STRING([--with-slang], [compile cfdisk with slang rather than ncurses]),
1111   [], [with_slang=no]
1112 )
1113 have_slang=no
1114 AS_IF([test "x$with_slang" = xyes], [
1115   AC_CHECK_HEADERS([slang.h slang/slang.h])
1116   AC_CHECK_HEADERS([slcurses.h slang/slcurses.h],
1117                    [have_slang=yes], [], [
1118 #ifdef HAVE_SLANG_H
1119 #include <slang.h>
1120 #elif defined(HAVE_SLANG_SLANG_H)
1121 #include <slang/slang.h>
1122 #endif
1123 ])
1124   AS_IF([test "x$have_slang" = xno], [
1125     AC_MSG_ERROR([slang selected but slcurses.h not found])],
1126     [CURSES_LIB_NAME=slang
1127   ])
1128 ])
1129 AM_CONDITIONAL([HAVE_SLANG], [test "x$have_slang" = xyes])
1130
1131
1132 AS_IF([test "x$have_slang" = xyes || test "x$have_ncursesw" = xyes || test "x$have_ncurses" = xyes], [
1133         AC_CHECK_LIB([$CURSES_LIB_NAME], use_default_colors, [
1134                      AC_DEFINE(HAVE_USE_DEFAULT_COLORS, 1,
1135                                [Define if curses library has the use_default_colors().])
1136         ])
1137         AC_CHECK_LIB([$CURSES_LIB_NAME], resizeterm, [
1138                      AC_DEFINE(HAVE_RESIZETERM, 1,
1139                                [Define if curses library has the resizeterm().])
1140         ])
1141 ])
1142
1143
1144 AC_ARG_WITH([tinfo], AS_HELP_STRING([--without-tinfo], [compile without libtinfo]),
1145   [], [with_tinfo=auto]
1146 )
1147 have_tinfo=no
1148 have_tinfow=no
1149 AS_IF([test "x$with_tinfo" != xno], [
1150   AS_IF([test "x$have_ncursesw" = xyes], [
1151     UL_TINFO_CHECK([tinfow])
1152   ])
1153   AS_IF([test "x$have_tinfow" = xno], [
1154     UL_TINFO_CHECK([tinfo])
1155   ])
1156 ])
1157 AC_SUBST([TINFO_LIBS])
1158 AC_SUBST([TINFO_LIBS_STATIC])
1159 AC_SUBST([TINFO_CFLAGS])
1160 AM_CONDITIONAL([HAVE_TINFO], [test "x$have_tinfo" = xyes || test "x$have_tinfow" = xyes])
1161 AS_IF([test "x$have_tinfo" = xyes || test "x$have_tinfow" = xyes], [
1162   AC_DEFINE(HAVE_LIBTINFO, 1, [Define if libtinfo or libtinfow available.])
1163 ])
1164
1165
1166 AC_ARG_WITH([readline],
1167   AS_HELP_STRING([--without-readline], [do not build with GNU Readline support]),
1168   [], [with_readline=auto]
1169 )
1170
1171 AS_IF([test "x$with_readline" = xno], [
1172   AM_CONDITIONAL([HAVE_READLINE], [false])
1173 ], [
1174   UL_CHECK_LIB([readline], [readline])
1175   AS_CASE([$with_readline:$have_readline],
1176     [yes:no],
1177       [AC_MSG_ERROR([readline selected but libreadline not found ])],
1178     [*:yes],
1179       [READLINE_LIBS="-lreadline"
1180        READLINE_LIBS_STATIC="-lreadline $TINFO_LIBS_STATIC"]
1181   )
1182 ])
1183 AC_SUBST([READLINE_LIBS])
1184 AC_SUBST([READLINE_LIBS_STATIC])
1185
1186
1187 AC_ARG_WITH([utempter],
1188   AS_HELP_STRING([--with-utempter], [compile script(1) with libutempter]),
1189   [], [with_utempter=no]
1190 )
1191
1192 AS_IF([test "x$with_utempter" = xyes], [
1193   UL_CHECK_LIB([utempter], [utempter_add_record])
1194   AS_IF([test "x$have_utempter" = xno], [
1195     AC_MSG_ERROR([utempter selected but libutempter not found])
1196   ])
1197 ], [
1198   AM_CONDITIONAL([HAVE_UTEMPTER], [false])
1199 ])
1200
1201
1202 dnl
1203 dnl libuuid
1204 dnl
1205 AC_ARG_ENABLE([libuuid],
1206   AS_HELP_STRING([--disable-libuuid], [do not build libuuid and uuid utilities]),
1207   [], [UL_DEFAULT_ENABLE([libuuid], [yes])]
1208 )
1209 UL_BUILD_INIT([libuuid])
1210 AC_SUBST([LIBUUID_VERSION])
1211 AC_SUBST([LIBUUID_VERSION_INFO])
1212 AM_CONDITIONAL(BUILD_LIBUUID, test "x$build_libuuid" = xyes)
1213
1214 AC_ARG_ENABLE([libuuid-force-uuidd],
1215   AS_HELP_STRING([--enable-libuuid-force-uuidd], [support uuidd even though the daemon is not built]),
1216   [], [enable_libuuid_force_uuidd=no]
1217 )
1218
1219 AS_IF([test "x$build_libuuid" = xyes], [
1220   AC_DEFINE(HAVE_LIBUUID, 1, [Define to 1 if you have the -luuid.])
1221 ])
1222
1223 dnl
1224 dnl liblastlog2
1225 dnl
1226 AC_ARG_ENABLE([liblastlog2],
1227   AS_HELP_STRING([--disable-liblastlog2], [do not build liblastlog2 and lastlog2 utilities]),
1228   [], [UL_DEFAULT_ENABLE([liblastlog2], [yes])]
1229 )
1230 UL_BUILD_INIT([liblastlog2])
1231
1232 have_sqlite3=no
1233 AS_IF([test "x$build_liblastlog2" = xyes], [
1234   PKG_CHECK_MODULES([SQLITE3], [sqlite3], [have_sqlite3=yes], [have_sqlite3=no])
1235 ])
1236 UL_REQUIRES_HAVE([liblastlog2], [sqlite3], [sqlite3 library])
1237 AC_SUBST([SQLITE3_LIBS])
1238
1239 AC_SUBST([LIBLASTLOG2_VERSION])
1240 AC_SUBST([LIBLASTLOG2_VERSION_INFO])
1241 AC_DEFINE_UNQUOTED([LIBLASTLOG2_VERSION], ["$LIBLASTLOG2_VERSION"], [liblastlog2 version string])
1242 AM_CONDITIONAL([BUILD_LIBLASTLOG2], [test "x$build_liblastlog2" = xyes])
1243 AM_CONDITIONAL([BUILD_LIBLASTLOG2_TESTS], [test "x$build_liblastlog2" = xyes && test "x$enable_static" = xyes])
1244
1245
1246 AC_ARG_ENABLE([pam_lastlog2],
1247   AS_HELP_STRING([--disable-pam-lastlog2], [do not build PAM lastlog2 module]),
1248   [], [UL_DEFAULT_ENABLE([pam_lastlog2], [check])]
1249 )
1250 UL_BUILD_INIT([pam_lastlog2])
1251 UL_REQUIRES_BUILD([pam_lastlog2], [liblastlog2])
1252 UL_REQUIRES_HAVE([pam_lastlog2], [security_pam_modules_h], [pam_modules.h header file])
1253 AM_CONDITIONAL([BUILD_PAM_LASTLOG2], [test "x$build_pam_lastlog2" = xyes])
1254
1255
1256 dnl
1257 dnl libblkid
1258 dnl
1259 AC_ARG_ENABLE([libblkid],
1260   AS_HELP_STRING([--disable-libblkid], [do not build libblkid and many related utilities]),
1261   [], [UL_DEFAULT_ENABLE([libblkid], [check])]
1262 )
1263 UL_BUILD_INIT([libblkid])
1264 UL_REQUIRES_HAVE([libblkid], [openat], [openat functions])
1265 UL_REQUIRES_HAVE([libblkid], [dirfd,ddfd], [dirfd or ddfd function])
1266 AC_SUBST([LIBBLKID_DATE])
1267 AC_SUBST([LIBBLKID_VERSION])
1268 AC_SUBST([LIBBLKID_VERSION_INFO])
1269 AC_DEFINE_UNQUOTED([LIBBLKID_VERSION], ["$LIBBLKID_VERSION"], [libblkid version string])
1270 AC_DEFINE_UNQUOTED([LIBBLKID_DATE], ["$LIBBLKID_DATE"], [libblkid date string])
1271 AS_IF([test "x$build_libblkid" = xyes], [
1272   AC_DEFINE([HAVE_LIBBLKID], [1], [Define to 1 if you have the -lblkid.])
1273 ])
1274 AM_CONDITIONAL([BUILD_LIBBLKID], [test "x$build_libblkid" = xyes])
1275 AM_CONDITIONAL([BUILD_LIBBLKID_TESTS], [test "x$build_libblkid" = xyes && test "x$enable_static" = xyes])
1276
1277 dnl
1278 dnl libmount
1279 dnl
1280 AC_ARG_ENABLE([libmount],
1281   AS_HELP_STRING([--disable-libmount], [do not build libmount]),
1282   [], [UL_DEFAULT_ENABLE([libmount], [check])]
1283 )
1284 UL_BUILD_INIT([libmount])
1285 UL_REQUIRES_BUILD([libmount], [libblkid])
1286 UL_REQUIRES_HAVE([libmount], [dirfd,ddfd], [dirfd or ddfd function])
1287 UL_REQUIRES_HAVE([libmount], [mntent_h], [mntent.h header file])
1288 AM_CONDITIONAL([BUILD_LIBMOUNT], [test "x$build_libmount" = xyes])
1289 AM_CONDITIONAL([BUILD_LIBMOUNT_TESTS], [test "x$build_libmount" = xyes && test "x$enable_static" = xyes])
1290 AS_IF([test "x$build_libmount" = xyes], [
1291   AC_DEFINE(HAVE_LIBMOUNT, 1, [Define if libmount available.])
1292   AS_IF([test "x$have_setns_syscall" = "xyes"], [
1293     AC_DEFINE([USE_LIBMOUNT_SUPPORT_NAMESPACES], [1], [Define to 1 if want to support namepaces.])
1294   ],[
1295     AC_MSG_WARN([libmount will be compiled without namespaces support])
1296   ])
1297 ])
1298
1299 AC_SUBST([LIBMOUNT_VERSION])
1300 AC_SUBST([LIBMOUNT_MAJOR_VERSION], $PACKAGE_VERSION_MAJOR)
1301 AC_SUBST([LIBMOUNT_MINOR_VERSION], $PACKAGE_VERSION_MINOR)
1302 AC_SUBST([LIBMOUNT_PATCH_VERSION], $PACKAGE_VERSION_RELEASE)
1303 AC_SUBST([LIBMOUNT_VERSION_INFO])
1304 AC_DEFINE_UNQUOTED([LIBMOUNT_VERSION], ["$LIBMOUNT_VERSION"], [libmount version string])
1305
1306 AC_ARG_ENABLE([libmount-mountfd-support],
1307   AS_HELP_STRING([--disable-libmount-mountfd-support], [do not use new mount API based on FDs]),
1308   [], [enable_libmount_mountfd_support=check]
1309 )
1310 UL_BUILD_INIT([libmount_mountfd_support])
1311 UL_REQUIRES_BUILD([libmount_mountfd_support], [libmount])
1312 UL_REQUIRES_LINUX([libmount_mountfd_support])
1313 UL_REQUIRES_HAVE([libmount_mountfd_support], [mountfd_api], [mount FDs based API])
1314 UL_REQUIRES_HAVE([libmount_mountfd_support], [linux_mount_h], [linux/mount.h])
1315 AS_IF([test "x$build_libmount_mountfd_support" = xyes ], [
1316   AC_DEFINE([USE_LIBMOUNT_MOUNTFD_SUPPORT], [1], [Enable support for new mount FD based kernel API])
1317 ])
1318
1319
1320 dnl
1321 dnl libsmartcols
1322 dnl
1323 AC_ARG_ENABLE([libsmartcols],
1324   AS_HELP_STRING([--disable-libsmartcols], [do not build libsmartcols]),
1325   [], [UL_DEFAULT_ENABLE([libsmartcols], [yes])]
1326 )
1327 UL_BUILD_INIT([libsmartcols])
1328 AM_CONDITIONAL([BUILD_LIBSMARTCOLS], [test "x$build_libsmartcols" = xyes])
1329
1330 AC_SUBST([LIBSMARTCOLS_VERSION])
1331 AC_SUBST([LIBSMARTCOLS_VERSION_INFO])
1332 AC_DEFINE_UNQUOTED([LIBSMARTCOLS_VERSION], ["$LIBSMARTCOLS_VERSION"], [libsmartcols version string])
1333
1334
1335 dnl
1336 dnl libfdisk
1337 dnl
1338 AC_ARG_ENABLE([libfdisk],
1339   AS_HELP_STRING([--disable-libfdisk], [do not build libfdisk]),
1340   [], [UL_DEFAULT_ENABLE([libfdisk], [check])]
1341 )
1342 UL_BUILD_INIT([libfdisk])
1343 UL_REQUIRES_BUILD([libfdisk], [libuuid])
1344 AM_CONDITIONAL([BUILD_LIBFDISK], [test "x$build_libfdisk" = xyes])
1345 AM_CONDITIONAL([BUILD_LIBFDISK_TESTS], [test "x$build_libfdisk" = xyes && test "x$enable_static" = xyes])
1346
1347 AS_IF([test "x$build_libblkid" = xyes],
1348   [LIBFDISK_PC_REQUIRES="uuid blkid"],[LIBFDISK_PC_REQUIRES="uuid"])
1349 AC_SUBST([LIBFDISK_PC_REQUIRES])
1350
1351 AC_SUBST([LIBFDISK_VERSION])
1352 AC_SUBST([LIBFDISK_MAJOR_VERSION], $PACKAGE_VERSION_MAJOR)
1353 AC_SUBST([LIBFDISK_MINOR_VERSION], $PACKAGE_VERSION_MINOR)
1354 AC_SUBST([LIBFDISK_PATCH_VERSION], $PACKAGE_VERSION_RELEASE)
1355 AC_SUBST([LIBFDISK_VERSION_INFO])
1356 AC_DEFINE_UNQUOTED([LIBFDISK_VERSION], ["$LIBFDISK_VERSION"], [libfdisk version string])
1357
1358
1359 AC_ARG_ENABLE([fdisks],
1360   AS_HELP_STRING([--disable-fdisks], [do not build fdisk(8), sfdisk(8) and cfdisk(8)]),
1361   [], [UL_DEFAULT_ENABLE([fdisks], [check])]
1362 )
1363 enable_fdisk=$enable_fdisks
1364 enable_sfdisk=$enable_fdisks
1365 enable_cfdisk=$enable_fdisks
1366
1367 UL_BUILD_INIT([fdisk])
1368 UL_REQUIRES_HAVE([fdisk], [openat], [openat functions])
1369 UL_REQUIRES_HAVE([fdisk], [dirfd,ddfd], [dirfd or ddfd function])
1370 UL_REQUIRES_BUILD([fdisk], [libfdisk])
1371 UL_REQUIRES_BUILD([fdisk], [libsmartcols])
1372 AM_CONDITIONAL([BUILD_FDISK], [test "x$build_fdisk" = xyes])
1373
1374
1375 UL_BUILD_INIT([sfdisk])
1376 UL_REQUIRES_HAVE([sfdisk], [openat], [openat functions])
1377 UL_REQUIRES_HAVE([sfdisk], [dirfd,ddfd], [dirfd or ddfd function])
1378 UL_REQUIRES_BUILD([sfdisk], [libfdisk])
1379 UL_REQUIRES_BUILD([sfdisk], [libsmartcols])
1380 AM_CONDITIONAL([BUILD_SFDISK], [test "x$build_sfdisk" = xyes])
1381
1382
1383 UL_BUILD_INIT([cfdisk])
1384 UL_REQUIRES_BUILD([cfdisk], [libfdisk])
1385 UL_REQUIRES_BUILD([cfdisk], [libsmartcols])
1386 UL_REQUIRES_HAVE([cfdisk], [open_memstream], [open_memstream function])
1387 UL_REQUIRES_HAVE([cfdisk], [ncursesw,slang,ncurses], [ncursesw, ncurses or slang library])
1388 AM_CONDITIONAL([BUILD_CFDISK], [test "x$build_cfdisk" = xyes])
1389
1390
1391 AC_ARG_ENABLE([mount],
1392   AS_HELP_STRING([--disable-mount], [do not build mount(8) and umount(8)]),
1393   [], [UL_DEFAULT_ENABLE([mount], [check])]
1394 )
1395 UL_BUILD_INIT([mount])
1396 UL_REQUIRES_LINUX([mount])
1397 UL_REQUIRES_BUILD([mount], [libmount])
1398 AM_CONDITIONAL([BUILD_MOUNT], [test "x$build_mount" = xyes])
1399
1400
1401 AC_ARG_ENABLE([losetup],
1402   AS_HELP_STRING([--disable-losetup], [do not build losetup]),
1403   [], [UL_DEFAULT_ENABLE([losetup], [check])]
1404 )
1405 UL_BUILD_INIT([losetup])
1406 UL_REQUIRES_LINUX([losetup])
1407 UL_REQUIRES_BUILD([losetup], [libsmartcols])
1408 AM_CONDITIONAL([BUILD_LOSETUP], [test "x$build_losetup" = xyes])
1409
1410 AC_ARG_ENABLE([zramctl],
1411   AS_HELP_STRING([--disable-zramctl], [do not build zramctl]),
1412   [], [UL_DEFAULT_ENABLE([zramctl], [check])]
1413 )
1414 UL_BUILD_INIT([zramctl])
1415 UL_REQUIRES_LINUX([zramctl])
1416 UL_REQUIRES_BUILD([zramctl], [libsmartcols])
1417 AM_CONDITIONAL([BUILD_ZRAMCTL], [test "x$build_zramctl" = xyes])
1418
1419 AC_ARG_ENABLE([fsck],
1420   AS_HELP_STRING([--disable-fsck], [do not build fsck]),
1421   [], [UL_DEFAULT_ENABLE([fsck], [check])]
1422 )
1423 UL_BUILD_INIT([fsck])
1424 UL_REQUIRES_BUILD([fsck], [libmount])
1425 AM_CONDITIONAL([BUILD_FSCK], [test "x$build_fsck" = xyes])
1426
1427
1428 AC_ARG_ENABLE([partx],
1429   AS_HELP_STRING([--disable-partx], [do not build addpart, delpart, partx]),
1430   [], [UL_DEFAULT_ENABLE([partx], [check])]
1431 )
1432 UL_BUILD_INIT([partx])
1433 UL_REQUIRES_LINUX([partx])
1434 UL_REQUIRES_BUILD([partx], [libblkid])
1435 UL_REQUIRES_BUILD([partx], [libsmartcols])
1436 AM_CONDITIONAL([BUILD_PARTX], [test "x$build_partx" = xyes])
1437
1438
1439 AC_ARG_ENABLE([uuidd],
1440   AS_HELP_STRING([--disable-uuidd], [do not build the uuid daemon]),
1441   [], [UL_DEFAULT_ENABLE([uuidd], [check])]
1442 )
1443 UL_BUILD_INIT([uuidd])
1444 UL_REQUIRES_BUILD([uuidd], [libuuid])
1445 UL_REQUIRES_HAVE([uuidd], [timer], [timer_create function])
1446 UL_REQUIRES_HAVE([uuidd], [sys_signalfd_h], [sys/signalfd.h header])
1447 AS_IF([test "x$build_uuidd" = xyes || test "x$enable_libuuid_force_uuidd" = xyes], [
1448   AC_DEFINE([HAVE_UUIDD], [1], [Define to 1 if you want to use uuid daemon.])
1449 ])
1450 AM_CONDITIONAL([BUILD_UUIDD], [test "x$build_uuidd" = xyes])
1451
1452
1453 AC_ARG_ENABLE([uuidgen],
1454   AS_HELP_STRING([--disable-uuidgen], [do not build uuidgen]),
1455   [], [UL_DEFAULT_ENABLE([uuidgen], [check])]
1456 )
1457 UL_BUILD_INIT([uuidgen])
1458 UL_REQUIRES_BUILD([uuidgen], [libuuid])
1459 AM_CONDITIONAL([BUILD_UUIDGEN], [test "x$build_uuidgen" = xyes])
1460
1461 UL_BUILD_INIT([uuidparse], [check])
1462 UL_REQUIRES_BUILD([uuidparse], [libuuid])
1463 UL_REQUIRES_BUILD([uuidparse], [libsmartcols])
1464 AM_CONDITIONAL([BUILD_UUIDPARSE], [test "x$build_uuidparse" = xyes])
1465
1466 AC_ARG_ENABLE([blkid],
1467   AS_HELP_STRING([--disable-blkid], [do not build blkid(8)]),
1468   [], [UL_DEFAULT_ENABLE([blkid], [check])]
1469 )
1470 UL_BUILD_INIT([blkid])
1471 UL_REQUIRES_BUILD([blkid], [libblkid])
1472 AM_CONDITIONAL([BUILD_BLKID], [test "x$build_blkid" = xyes])
1473
1474 UL_BUILD_INIT([findfs], [check])
1475 UL_REQUIRES_BUILD([findfs], [libblkid])
1476 AM_CONDITIONAL([BUILD_FINDFS], [test "x$build_findfs" = xyes])
1477
1478 AC_ARG_ENABLE([wipefs],
1479   AS_HELP_STRING([--disable-wipefs], [do not build wipefs]),
1480   [], [UL_DEFAULT_ENABLE([wipefs], [check])]
1481 )
1482 UL_BUILD_INIT([wipefs])
1483 UL_REQUIRES_BUILD([wipefs], [libblkid])
1484 UL_REQUIRES_BUILD([wipefs], [libsmartcols])
1485 AM_CONDITIONAL([BUILD_WIPEFS], [test "x$build_wipefs" = xyes])
1486
1487 UL_BUILD_INIT([findmnt], [check])
1488 UL_REQUIRES_BUILD([findmnt], [libmount])
1489 UL_REQUIRES_BUILD([findmnt], [libblkid])
1490 UL_REQUIRES_BUILD([findmnt], [libsmartcols])
1491 AM_CONDITIONAL([BUILD_FINDMNT], [test "x$build_findmnt" = xyes])
1492
1493
1494 AC_ARG_ENABLE([mountpoint],
1495   AS_HELP_STRING([--disable-mountpoint], [do not build mountpoint]),
1496   [], [UL_DEFAULT_ENABLE([mountpoint], [check])]
1497 )
1498 UL_BUILD_INIT([mountpoint])
1499 UL_REQUIRES_BUILD([mountpoint], [libmount])
1500 AM_CONDITIONAL([BUILD_MOUNTPOINT], [test "x$build_mountpoint" = xyes])
1501
1502
1503 AC_ARG_ENABLE([fallocate],
1504   AS_HELP_STRING([--disable-fallocate], [do not build fallocate]),
1505   [], [UL_DEFAULT_ENABLE([fallocate], [check])]
1506 )
1507 UL_BUILD_INIT([fallocate])
1508 UL_REQUIRES_LINUX([fallocate])
1509 UL_REQUIRES_SYSCALL_CHECK([fallocate], [UL_CHECK_SYSCALL([fallocate])])
1510 AM_CONDITIONAL([BUILD_FALLOCATE], [test "x$build_fallocate" = xyes])
1511
1512 AS_IF([test "x$build_fallocate" = xyes], [
1513   dnl check for valid fallocate() function
1514   dnl with 32 bits glibc 2.10, fallocate() exists but not fallocate64()
1515   dnl when _FILE_OFFSET_BITS==64, fallocate() is redirect to fallocate64()
1516   dnl and program can't be linked.
1517   dnl AC_CHECK_FUNC can't catch such errors since it's redefining
1518   dnl function prototype.
1519   AC_MSG_CHECKING([for valid fallocate() function])
1520   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1521 #ifdef HAVE_UNISTD_H
1522 # include <unistd.h>
1523 #endif
1524 #ifdef HAVE_SYS_TYPES_H
1525 # include <sys/types.h>
1526 #endif
1527 #ifdef HAVE_LINUX_FALLOC_H
1528 # include <linux/falloc.h>
1529 #endif
1530 #ifdef HAVE_FCNTL_H
1531 # include <fcntl.h>
1532 #endif
1533 ]],[[
1534    long ret;
1535    ret = fallocate(0, FALLOC_FL_KEEP_SIZE, 0xfffffffful, 0xfffffffful);
1536    if (ret != 0) {
1537       return 1;
1538    }
1539    ]])],[
1540   AC_MSG_RESULT([yes])
1541   AC_DEFINE([HAVE_FALLOCATE], [1], [Have valid fallocate() function])],[
1542   AC_MSG_RESULT([no])])
1543 ])
1544
1545 AS_IF([test "x$build_fallocate" = xyes], [
1546   dnl check for valid posix_fallocate() function
1547   AC_MSG_CHECKING([for valid posix_fallocate() function])
1548   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1549 #ifdef HAVE_UNISTD_H
1550 # include <unistd.h>
1551 #endif
1552 #ifdef HAVE_SYS_TYPES_H
1553 # include <sys/types.h>
1554 #endif
1555 #ifdef HAVE_LINUX_FALLOC_H
1556 # include <linux/falloc.h>
1557 #endif
1558 #ifdef HAVE_FCNTL_H
1559 # include <fcntl.h>
1560 #endif
1561 ]],[[
1562    long ret;
1563    ret = posix_fallocate(0, 0xfffffffful, 0xfffffffful);
1564    if (ret != 0) {
1565       return 1;
1566    }
1567    ]])],[
1568   AC_MSG_RESULT([yes])
1569   AC_DEFINE([HAVE_POSIX_FALLOCATE], [1], [Have valid posix_fallocate() function])],[
1570   AC_MSG_RESULT([no])])
1571 ])
1572
1573
1574 AC_ARG_ENABLE([unshare],
1575   AS_HELP_STRING([--disable-unshare], [do not build unshare]),
1576   [], [UL_DEFAULT_ENABLE([unshare], [check])]
1577 )
1578 UL_BUILD_INIT([unshare])
1579 UL_REQUIRES_LINUX([unshare])
1580 UL_REQUIRES_SYSCALL_CHECK([unshare], [UL_CHECK_SYSCALL([unshare])])
1581 UL_REQUIRES_HAVE([unshare], [linux_capability_h], [linux/capability.h header file])
1582 AM_CONDITIONAL([BUILD_UNSHARE], [test "x$build_unshare" = xyes])
1583
1584 AC_MSG_CHECKING([for valid unshare() function])
1585 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1586 #include <sched.h>
1587 ]],[[
1588    int ret;
1589    ret = unshare(0);
1590    if (ret != 0) {
1591       return 1;
1592    }
1593    ]])],[
1594   AC_MSG_RESULT([yes])
1595   AC_DEFINE([HAVE_UNSHARE], [1], [Have valid unshare() function])],
1596 [
1597   AC_MSG_RESULT([no])
1598 ])
1599
1600
1601 AC_ARG_ENABLE([nsenter],
1602   AS_HELP_STRING([--disable-nsenter], [do not build nsenter]),
1603   [], [UL_DEFAULT_ENABLE([nsenter], [check])]
1604 )
1605 UL_BUILD_INIT([nsenter])
1606 UL_REQUIRES_LINUX([nsenter])
1607 UL_REQUIRES_HAVE([nsenter], [setns_syscall], [setns syscall])
1608 AM_CONDITIONAL([BUILD_NSENTER], [test "x$build_nsenter" = xyes])
1609
1610 AC_MSG_CHECKING([for valid setns() function])
1611 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1612 #include <sched.h>
1613 #include <errno.h>
1614 ]],[[
1615    int ret;
1616    ret = setns(0, 0);
1617    if (ret != EINVAL && ret != EBADF && ret != EPERM) {
1618       return 1;
1619    }
1620    ]])],[
1621   AC_MSG_RESULT([yes])
1622   AC_DEFINE([HAVE_SETNS], [1], [Have valid setns() function])],
1623 [
1624   AC_MSG_RESULT([no])
1625 ])
1626
1627
1628 AC_ARG_WITH([cap_ng],
1629   AS_HELP_STRING([--without-cap-ng], [compile without libcap-ng]),
1630   [], [with_cap_ng=auto]
1631 )
1632 AS_IF([test "x$with_cap_ng" = xno], [
1633   AM_CONDITIONAL([HAVE_CAP_NG], [false])
1634   have_cap_ng=no
1635 ],[
1636   UL_CHECK_LIB([cap-ng], [capng_apply], [cap_ng])
1637 ])
1638
1639
1640 AC_ARG_ENABLE([setpriv],
1641   AS_HELP_STRING([--disable-setpriv], [do not build setpriv]),
1642   [], [UL_DEFAULT_ENABLE([setpriv], [check])]
1643 )
1644 UL_BUILD_INIT([setpriv])
1645 UL_REQUIRES_LINUX([setpriv])
1646 UL_REQUIRES_HAVE([setpriv], [linux_securebits_h], [linux/securebits.h header file])
1647 UL_REQUIRES_HAVE([setpriv], [linux_capability_h], [linux/capability.h header file])
1648 UL_REQUIRES_HAVE([setpriv], [cap_ng], [libcap-ng library])
1649 AM_CONDITIONAL([BUILD_SETPRIV], [test "x$build_setpriv" = xyes])
1650
1651 AC_ARG_ENABLE([hardlink],
1652   AS_HELP_STRING([--disable-hardlink], [do not build hardlink]),
1653   [], [UL_DEFAULT_ENABLE([hardlink], [check])]
1654 )
1655 UL_BUILD_INIT([hardlink])
1656 AM_CONDITIONAL([BUILD_HARDLINK], [test "x$build_hardlink" = xyes])
1657
1658
1659 AC_ARG_ENABLE([eject],
1660   AS_HELP_STRING([--disable-eject], [do not build eject]),
1661   [], [UL_DEFAULT_ENABLE([eject], [check])]
1662 )
1663 UL_BUILD_INIT([eject])
1664 UL_REQUIRES_LINUX([eject])
1665 UL_REQUIRES_BUILD([eject], [libmount])
1666 AM_CONDITIONAL([BUILD_EJECT], [test "x$build_eject" = xyes])
1667
1668
1669 AC_ARG_ENABLE([agetty],
1670   AS_HELP_STRING([--disable-agetty], [do not build agetty]),
1671   [], [UL_DEFAULT_ENABLE([agetty], [check])]
1672 )
1673 UL_BUILD_INIT([agetty])
1674 UL_REQUIRES_HAVE([agetty], [utmpx_h], [utmpx.h header])
1675 UL_REQUIRES_HAVE([agetty], [gnu_utmpx], [GNU utmpx functions])
1676 AM_CONDITIONAL([BUILD_AGETTY], [test "x$build_agetty" = xyes])
1677 AS_IF([test "x$have_futimens" = xyes && test "x$have_inotify_init1" = xyes ], [
1678   AC_DEFINE([AGETTY_RELOAD], [1], [Enable agetty --reload feature])
1679 ],[
1680   AC_MSG_WARN([futimens or inotify_init1 not found; agetty(8) will not provide ---reload functionality])
1681 ])
1682
1683
1684 AC_ARG_ENABLE([plymouth_support],
1685   AS_HELP_STRING([--disable-plymouth_support], [do not care about plymouth in sulogin(8) and agetty(8)]),
1686   [], [enable_plymouth_support=check]
1687 )
1688 UL_BUILD_INIT([plymouth_support])
1689 UL_REQUIRES_HAVE([plymouth_support], [tiocglcktrmios], [TIOCGLCKTRMIOS flag])
1690 UL_REQUIRES_HAVE([plymouth_support], [sock_cloexec], [SOCK_CLOEXEC flag])
1691 UL_REQUIRES_HAVE([plymouth_support], [sock_nonblock], [SOCK_NONBLOCK flag])
1692 UL_REQUIRES_HAVE([plymouth_support], [so_passcred], [SO_PASSCRED flag])
1693 AM_CONDITIONAL([USE_PLYMOUTH_SUPPORT], [test "x$build_plymouth_support" = xyes])
1694 AS_IF([test "x$build_plymouth_support" = xyes ], [
1695     AC_DEFINE([USE_PLYMOUTH_SUPPORT], [1], [Enable plymouth support feature for sulogin and agetty])
1696 ])
1697
1698
1699 AC_ARG_WITH([libz],
1700   AS_HELP_STRING([--without-libz], [compile without libz]),
1701   [], [with_libz=auto]
1702 )
1703 AS_IF([test "x$with_libz" = xno], [have_z=no], [
1704   AC_CHECK_LIB([z], [crc32], [have_z=yes], [have_z=no])
1705 ])
1706
1707 AC_ARG_WITH([libmagic],
1708   AS_HELP_STRING([--without-libmagic], [compile without libmagic]),
1709   [], [with_libmagic=auto]
1710 )
1711 AS_IF([test "x$with_libmagic" = xno], [have_magic=no], [
1712   AC_CHECK_LIB([magic], [magic_open], [
1713     AC_CHECK_HEADER(magic.h, [
1714       AC_DEFINE([HAVE_MAGIC], [1], [Define to 1 if you have the libmagic present.])
1715       MAGIC_LIBS="-lmagic"
1716     ])
1717   ])
1718 ])
1719 AC_SUBST([MAGIC_LIBS])
1720
1721
1722 AC_ARG_ENABLE([cramfs],
1723   AS_HELP_STRING([--disable-cramfs], [do not build fsck.cramfs, mkfs.cramfs]),
1724   [], [UL_DEFAULT_ENABLE([cramfs], [check])]
1725 )
1726 UL_BUILD_INIT([cramfs])
1727 UL_REQUIRES_HAVE([cramfs], [z], [z library])
1728 AM_CONDITIONAL([BUILD_CRAMFS], [test "x$build_cramfs" = xyes])
1729
1730
1731 AC_ARG_ENABLE([bfs],
1732   AS_HELP_STRING([--disable-bfs], [do not build mkfs.bfs]),
1733   [], [UL_DEFAULT_ENABLE([bfs], [yes])]
1734 )
1735 UL_BUILD_INIT([bfs])
1736 AM_CONDITIONAL([BUILD_BFS], [test "x$build_bfs" = xyes])
1737
1738
1739 AC_ARG_ENABLE([minix],
1740   AS_HELP_STRING([--disable-minix], [do not build fsck.minix, mkfs.minix]),
1741   [], [UL_DEFAULT_ENABLE([minix], [yes])]
1742 )
1743 UL_BUILD_INIT([minix])
1744 AM_CONDITIONAL([BUILD_MINIX], [test "x$build_minix" = xyes])
1745
1746
1747 AC_ARG_ENABLE([fdformat],
1748   AS_HELP_STRING([--enable-fdformat], [build fdformat]),
1749   [], [UL_DEFAULT_ENABLE([fdformat], [no])]
1750 )
1751 UL_BUILD_INIT([fdformat])
1752 UL_REQUIRES_LINUX([fdformat])
1753 AM_CONDITIONAL([BUILD_FDFORMAT], [test "x$build_fdformat" = xyes])
1754
1755
1756 AC_ARG_ENABLE([hwclock],
1757   AS_HELP_STRING([--disable-hwclock], [do not build hwclock]),
1758   [], [UL_DEFAULT_ENABLE([hwclock], [check])]
1759 )
1760 have_linuxdummy=$linux_os
1761
1762 UL_BUILD_INIT([hwclock])
1763 UL_REQUIRES_HAVE([hwclock], [io, linuxdummy], [ioperm iopl function or Linux])
1764 AM_CONDITIONAL([BUILD_HWCLOCK], [test "x$build_hwclock" = xyes])
1765
1766 AC_ARG_ENABLE([hwclock_cmos],
1767   AS_HELP_STRING([--disable-hwclock-cmos], [do not use CMOS clock]),
1768   [], [enable_hwclock_cmos=check]
1769 )
1770 UL_BUILD_INIT([hwclock_cmos])
1771 UL_REQUIRES_BUILD([hwclock_cmos], [hwclock])
1772 UL_REQUIRES_ARCH([hwclock_cmos], [i?86-*,x86_64*])
1773 AM_CONDITIONAL([USE_HWCLOCK_CMOS], [test "x$build_hwclock_cmos" = xyes])
1774 AS_IF([test "x$build_hwclock_cmos" = xyes ], [
1775     AC_DEFINE([USE_HWCLOCK_CMOS], [1], [Define to 1 if want to use CMOS clock.])
1776 ])
1777
1778 AC_ARG_ENABLE([hwclock_gplv3],
1779   AS_HELP_STRING([--disable-hwclock-gplv3], [do not use datetime parsing GPLv3 code]),
1780   [], [enable_hwclock_gplv3=yes]
1781 )
1782 AM_CONDITIONAL([USE_HWCLOCK_GPLv3_DATETIME], [test "x$enable_hwclock_gplv3" = xyes])
1783 AS_IF([test "x$enable_hwclock_gplv3" = xyes ], [
1784     AC_DEFINE([USE_HWCLOCK_GPLv3_DATETIME], [1], [use datetime parsing GPLv3 code to hwclock])
1785 ])
1786
1787
1788 AC_ARG_ENABLE([mkfs],
1789   AS_HELP_STRING([--disable-mkfs], [do not build mkfs(8)]),
1790   [], [UL_DEFAULT_ENABLE([mkfs], [check])]
1791 )
1792 UL_BUILD_INIT([mkfs])
1793 AM_CONDITIONAL([BUILD_MKFS], [test "x$build_mkfs" = xyes])
1794
1795 UL_BUILD_INIT([isosize], [yes])
1796 AM_CONDITIONAL([BUILD_ISOSIZE], [test "x$build_isosize" = xyes])
1797
1798
1799 AC_ARG_ENABLE([fstrim],
1800   AS_HELP_STRING([--disable-fstrim], [do not build fstrim(8)]),
1801   [], [UL_DEFAULT_ENABLE([fstrim], [check])]
1802 )
1803 UL_BUILD_INIT([fstrim])
1804 UL_REQUIRES_LINUX([fstrim])
1805 UL_REQUIRES_BUILD([fstrim], [libmount])
1806 AM_CONDITIONAL([BUILD_FSTRIM], [test "x$build_fstrim" = xyes])
1807
1808
1809 AC_ARG_ENABLE([swapon],
1810   AS_HELP_STRING([--disable-swapon], [do not build swapon(8) and swapoff(8)]),
1811   [], [UL_DEFAULT_ENABLE([swapon], [check])]
1812 )
1813 UL_BUILD_INIT([swapon])
1814 UL_REQUIRES_LINUX([swapon])
1815 UL_REQUIRES_SYSCALL_CHECK([swapon], [UL_CHECK_SYSCALL([swapon])], [swapon])
1816 UL_REQUIRES_SYSCALL_CHECK([swapon], [UL_CHECK_SYSCALL([swapoff])], [swapoff])
1817 UL_REQUIRES_BUILD([swapon], [libblkid])
1818 UL_REQUIRES_BUILD([swapon], [libmount])
1819 UL_REQUIRES_BUILD([swapon], [libsmartcols])
1820 AM_CONDITIONAL([BUILD_SWAPON], [test "x$build_swapon" = xyes])
1821 AC_CHECK_FUNCS([swapon])
1822 AC_CHECK_FUNCS([swapoff])
1823
1824
1825 UL_BUILD_INIT([lsblk], [check])
1826 UL_REQUIRES_LINUX([lsblk])
1827 UL_REQUIRES_BUILD([lsblk], [libblkid])
1828 UL_REQUIRES_BUILD([lsblk], [libmount])
1829 UL_REQUIRES_BUILD([lsblk], [libsmartcols])
1830 AM_CONDITIONAL([BUILD_LSBLK], [test "x$build_lsblk" = xyes])
1831
1832
1833 AC_ARG_ENABLE([lscpu],
1834   AS_HELP_STRING([--disable-lscpu], [do not build lscpu]),
1835   [], [UL_DEFAULT_ENABLE([lscpu], [check])]
1836 )
1837 UL_BUILD_INIT([lscpu])
1838 UL_REQUIRES_LINUX([lscpu])
1839 UL_REQUIRES_BUILD([lscpu], [libsmartcols])
1840 UL_REQUIRES_HAVE([lscpu], [cpu_set_t], [cpu_set_t type])
1841 AM_CONDITIONAL([BUILD_LSCPU], [test "x$build_lscpu" = xyes])
1842
1843 AC_ARG_ENABLE([lsfd],
1844   AS_HELP_STRING([--disable-lsfd], [do not build lsfd]),
1845   [], [UL_DEFAULT_ENABLE([lsfd], [check])]
1846 )
1847 UL_BUILD_INIT([lsfd])
1848 UL_REQUIRES_LINUX([lsfd])
1849 UL_REQUIRES_BUILD([lsfd], [libsmartcols])
1850 AM_CONDITIONAL([BUILD_LSFD], [test "x$build_lsfd" = xyes])
1851
1852 AC_ARG_ENABLE([lslogins],
1853   AS_HELP_STRING([--disable-lslogins], [do not build lslogins]),
1854   [], [UL_DEFAULT_ENABLE([lslogins], [check])]
1855 )
1856 UL_BUILD_INIT([lslogins])
1857 UL_REQUIRES_BUILD([lslogins], [libsmartcols])
1858 UL_REQUIRES_HAVE([lslogins], [shadow_h], [shadow.h header])
1859 UL_REQUIRES_HAVE([lslogins], [utmpx_h], [utmpx.h header])
1860 UL_REQUIRES_HAVE([lslogins], [gnu_utmpx], [GNU utmpx functions])
1861 AM_CONDITIONAL([BUILD_LSLOGINS], [test "x$build_lslogins" = xyes])
1862
1863
1864 UL_BUILD_INIT([chcpu], [check])
1865 UL_REQUIRES_LINUX([chcpu])
1866 UL_REQUIRES_HAVE([chcpu], [cpu_set_t], [cpu_set_t type])
1867 AM_CONDITIONAL([BUILD_CHCPU], [test "x$build_chcpu" = xyes])
1868
1869
1870 AC_ARG_ENABLE([wdctl],
1871   AS_HELP_STRING([--disable-wdctl], [do not build wdctl]),
1872   [], [UL_DEFAULT_ENABLE([wdctl], [check])]
1873 )
1874 UL_BUILD_INIT([wdctl])
1875 UL_REQUIRES_LINUX([wdctl])
1876 UL_REQUIRES_BUILD([wdctl], [libsmartcols])
1877 UL_REQUIRES_HAVE([wdctl], [linux_watchdog_h], [linux/watchdog.h header file])
1878 AM_CONDITIONAL([BUILD_WDCTL], [test "x$build_wdctl" = xyes])
1879
1880
1881 UL_BUILD_INIT([swaplabel], [check])
1882 UL_REQUIRES_BUILD([swaplabel], [libblkid])
1883 AM_CONDITIONAL([BUILD_SWAPLABEL], [test "x$build_swaplabel" = xyes])
1884
1885
1886 UL_BUILD_INIT([mkswap], [yes])
1887 AM_CONDITIONAL([BUILD_MKSWAP], [test "x$build_mkswap" = xyes])
1888 AS_IF([test "x$build_mkswap" = xyes && test "x$build_libuuid" != xyes], [
1889   AC_MSG_WARN([uuid library is not found; mkswap(8) will not generate UUIDs])
1890 ])
1891
1892
1893 AC_ARG_ENABLE([cal],
1894   AS_HELP_STRING([--disable-cal], [do not build cal]),
1895   [], [UL_DEFAULT_ENABLE([cal], [check])]
1896 )
1897 UL_BUILD_INIT([cal])
1898 AM_CONDITIONAL([BUILD_CAL], [test "x$build_cal" = xyes])
1899
1900 AC_ARG_ENABLE([logger],
1901   AS_HELP_STRING([--disable-logger], [do not build logger]),
1902   [], [UL_DEFAULT_ENABLE([logger], [check])]
1903 )
1904 UL_BUILD_INIT([logger])
1905 AM_CONDITIONAL([BUILD_LOGGER], [test "x$build_logger" = xyes])
1906
1907 UL_BUILD_INIT([look], [yes])
1908 AM_CONDITIONAL([BUILD_LOOK], [test "x$build_look" = xyes])
1909
1910 UL_BUILD_INIT([mcookie], [yes])
1911 AM_CONDITIONAL([BUILD_MCOOKIE], [test "x$build_mcookie" = xyes])
1912
1913 UL_BUILD_INIT([namei], [yes])
1914 AM_CONDITIONAL([BUILD_NAMEI], [test "x$build_namei" = xyes])
1915
1916 matriplet="$($CC -print-multiarch 2>/dev/null || true)"
1917 if test "x$matriplet" != "x"; then
1918   AC_DEFINE_UNQUOTED([MULTIARCHTRIPLET], ["$matriplet"],
1919   ["Multi-arch triplet for whereis library search path"])
1920 fi
1921 AC_ARG_ENABLE([whereis],
1922   AS_HELP_STRING([--disable-whereis], [do not build whereis]),
1923   [], [UL_DEFAULT_ENABLE([whereis], [check])]
1924 )
1925 UL_BUILD_INIT([whereis])
1926 AM_CONDITIONAL([BUILD_WHEREIS], [test "x$build_whereis" = xyes])
1927
1928 AC_ARG_ENABLE([pipesz],
1929   AS_HELP_STRING([--disable-pipesz], [do not build pipesz]),
1930   [], [UL_DEFAULT_ENABLE([pipesz], [check])]
1931 )
1932 UL_BUILD_INIT([pipesz])
1933 UL_REQUIRES_LINUX([pipesz])
1934 AM_CONDITIONAL([BUILD_PIPESZ], [test "x$build_pipesz" = xyes])
1935
1936 UL_BUILD_INIT([fadvise], [check])
1937 UL_REQUIRES_LINUX([fadvise])
1938 AM_CONDITIONAL([BUILD_FADVISE], [test "x$build_fadvise" = xyes])
1939
1940 AC_ARG_ENABLE([waitpid],
1941   AS_HELP_STRING([--disable-waitpid], [do not build waitpid]),
1942   [], [UL_DEFAULT_ENABLE([waitpid], [check])]
1943 )
1944 UL_BUILD_INIT([waitpid])
1945 UL_REQUIRES_LINUX([waitpid])
1946 UL_REQUIRES_SYSCALL_CHECK([waitpid], [UL_CHECK_SYSCALL([pidfd_open])], [pidfd_open])
1947 AM_CONDITIONAL([BUILD_WAITPID], [test "x$build_waitpid" = xyes])
1948
1949 UL_BUILD_INIT([enosys], [check])
1950 UL_REQUIRES_LINUX([enosys])
1951 AS_IF([test "x$build_enosys" = xyes], [
1952   AC_MSG_CHECKING([for valid audit arch])
1953   AC_COMPILE_IFELSE(
1954     [AC_LANG_PROGRAM([[#include "${srcdir}/include/audit-arch.h"]])],
1955     [AC_MSG_RESULT([yes])],
1956     [AC_MSG_RESULT([no])
1957      build_enosys=no
1958     ])
1959 ])
1960 AM_CONDITIONAL([BUILD_ENOSYS], [test "x$build_enosys" = xyes])
1961
1962 UL_BUILD_INIT([lsclocks], [check])
1963 UL_REQUIRES_LINUX([lsclocks])
1964 AM_CONDITIONAL([BUILD_LSCLOCKS], [test "x$build_lsclocks" = xyes])
1965
1966 UL_BUILD_INIT([getopt], [yes])
1967 AM_CONDITIONAL([BUILD_GETOPT], [test "x$build_getopt" = xyes])
1968
1969
1970 UL_BUILD_INIT([blockdev], [check])
1971 UL_REQUIRES_LINUX([blockdev])
1972 AM_CONDITIONAL([BUILD_BLOCKDEV], [test "x$build_blockdev" = xyes])
1973
1974
1975 UL_BUILD_INIT([prlimit], [check])
1976 UL_REQUIRES_LINUX([prlimit])
1977 UL_REQUIRES_BUILD([prlimit], [libsmartcols])
1978 UL_REQUIRES_SYSCALL_CHECK([prlimit], [UL_CHECK_SYSCALL([prlimit64])], [prlimit64])
1979 AM_CONDITIONAL([BUILD_PRLIMIT], [test "x$build_prlimit" = xyes])
1980 AS_IF([test "x$build_prlimit" = xyes], [
1981   dnl check for valid prlimit() function
1982   AC_MSG_CHECKING([for valid prlimit() function])
1983   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1984 #include <sys/types.h>
1985 #include <sys/time.h>
1986 #include <sys/resource.h>
1987 #include <stddef.h>
1988 ]],[[
1989    int ret;
1990    ret = prlimit(0, RLIMIT_AS, NULL, NULL);
1991    if (ret != 0) {
1992       return 1;
1993    }
1994    ]])],[
1995   AC_MSG_RESULT([yes])
1996   AC_DEFINE([HAVE_PRLIMIT], [1], [Have valid prlimit() function])],[
1997   AC_MSG_RESULT([no])])
1998 ])
1999
2000
2001
2002 UL_BUILD_INIT([lslocks], [check])
2003 UL_REQUIRES_LINUX([lslocks])
2004 UL_REQUIRES_BUILD([lslocks], [libmount])
2005 UL_REQUIRES_BUILD([lslocks], [libsmartcols])
2006 AM_CONDITIONAL([BUILD_LSLOCKS], [test "x$build_lslocks" = xyes])
2007
2008
2009 AC_ARG_ENABLE([switch_root],
2010   AS_HELP_STRING([--disable-switch_root], [do not build switch_root]),
2011   [], [UL_DEFAULT_ENABLE([switch_root], [check])]
2012 )
2013 UL_BUILD_INIT([switch_root])
2014 UL_REQUIRES_LINUX([switch_root])
2015 UL_REQUIRES_HAVE([switch_root], [openat], [openat function])
2016 UL_REQUIRES_HAVE([switch_root], [dirfd,ddfd], [dirfd or ddfd function])
2017 AM_CONDITIONAL([BUILD_SWITCH_ROOT], [test "x$build_switch_root" = xyes])
2018
2019
2020 AC_ARG_ENABLE([pivot_root],
2021   AS_HELP_STRING([--disable-pivot_root], [do not build pivot_root]),
2022   [], [UL_DEFAULT_ENABLE([pivot_root], [check])]
2023 )
2024 UL_BUILD_INIT([pivot_root])
2025 UL_REQUIRES_LINUX([pivot_root])
2026 UL_REQUIRES_SYSCALL_CHECK([pivot_root], [UL_CHECK_SYSCALL([pivot_root])])
2027 AM_CONDITIONAL([BUILD_PIVOT_ROOT], [test "x$build_pivot_root" = xyes])
2028
2029
2030 UL_BUILD_INIT([flock], [check])
2031 UL_REQUIRES_HAVE([flock], [timer], [timer_create/setitimer function])
2032 AM_CONDITIONAL([BUILD_FLOCK], [test "x$build_flock" = xyes])
2033
2034
2035 AC_ARG_ENABLE([lsmem],
2036   AS_HELP_STRING([--disable-lsmem], [do not build lsmem]),
2037   [], [UL_DEFAULT_ENABLE([lsmem], [check])]
2038 )
2039 UL_BUILD_INIT([lsmem])
2040 UL_REQUIRES_LINUX([lsmem])
2041 UL_REQUIRES_BUILD([lsmem], [libsmartcols])
2042 AM_CONDITIONAL([BUILD_LSMEM], [test "x$build_lsmem" = xyes])
2043
2044
2045 AC_ARG_ENABLE([chmem],
2046   AS_HELP_STRING([--disable-chmem], [do not build chmem]),
2047   [], [UL_DEFAULT_ENABLE([chmem], [check])]
2048 )
2049 UL_BUILD_INIT([chmem])
2050 UL_REQUIRES_LINUX([chmem])
2051 AM_CONDITIONAL([BUILD_CHMEM], [test "x$build_chmem" = xyes])
2052
2053
2054 AC_ARG_ENABLE([ipcmk],
2055   AS_HELP_STRING([--disable-ipcmk], [do not build ipcmk]),
2056   [], [UL_DEFAULT_ENABLE([ipcmk], [check])]
2057 )
2058 UL_BUILD_INIT([ipcmk])
2059 UL_EXCLUDE_ARCH([ipcmk], [*darwin*])
2060 AM_CONDITIONAL([BUILD_IPCMK], [test "x$build_ipcmk" = xyes])
2061
2062 AC_ARG_ENABLE([ipcrm],
2063   AS_HELP_STRING([--disable-ipcrm], [do not build ipcrm]),
2064   [], [UL_DEFAULT_ENABLE([ipcrm], [check])]
2065 )
2066 UL_BUILD_INIT([ipcrm])
2067 UL_EXCLUDE_ARCH([ipcrm], [*darwin*])
2068 AM_CONDITIONAL([BUILD_IPCRM], [test "x$build_ipcrm" = xyes])
2069
2070 AC_ARG_ENABLE([ipcs],
2071   AS_HELP_STRING([--disable-ipcs], [do not build ipcs]),
2072   [], [UL_DEFAULT_ENABLE([ipcs], [check])]
2073 )
2074 UL_BUILD_INIT([ipcs])
2075 UL_EXCLUDE_ARCH([ipcs], [*darwin*])
2076 AM_CONDITIONAL([BUILD_IPCS], [test "x$build_ipcs" = xyes])
2077
2078
2079 AC_ARG_ENABLE([irqtop],
2080   AS_HELP_STRING([--disable-irqtop], [do not build irqtop]),
2081   [], [UL_DEFAULT_ENABLE([irqtop], [check])]
2082 )
2083 UL_BUILD_INIT([irqtop])
2084 UL_REQUIRES_LINUX([irqtop])
2085 UL_REQUIRES_BUILD([irqtop], [libsmartcols])
2086 UL_REQUIRES_HAVE([irqtop], [open_memstream], [open_memstream function])
2087 UL_REQUIRES_HAVE([irqtop], [ncursesw,slang,ncurses], [ncursesw, ncurses or slang library])
2088 AM_CONDITIONAL([BUILD_IRQTOP], [test "x$build_irqtop" = xyes])
2089
2090 AC_ARG_ENABLE([lsirq],
2091   AS_HELP_STRING([--disable-lsirq], [do not build lsirq]),
2092   [], [UL_DEFAULT_ENABLE([lsirq], [check])]
2093 )
2094 UL_BUILD_INIT([lsirq])
2095 UL_REQUIRES_LINUX([lsirq])
2096 UL_REQUIRES_BUILD([lsirq], [libsmartcols])
2097 AM_CONDITIONAL([BUILD_LSIRQ], [test "x$build_lsirq" = xyes])
2098
2099
2100 UL_BUILD_INIT([choom], [check])
2101 UL_REQUIRES_LINUX([choom])
2102 AM_CONDITIONAL([BUILD_CHOOM], [test "x$build_choom" = xyes])
2103
2104 UL_BUILD_INIT([lsipc], [check])
2105 UL_REQUIRES_LINUX([lsipc])
2106 UL_REQUIRES_BUILD([lsipc], [libsmartcols])
2107 AM_CONDITIONAL([BUILD_LSIPC], [test "x$build_lsipc" = xyes])
2108
2109 AC_ARG_ENABLE([lsns],
2110   AS_HELP_STRING([--disable-lsns], [do not build lsns]),
2111   [], [UL_DEFAULT_ENABLE([lsns], [check])]
2112 )
2113 UL_BUILD_INIT([lsns])
2114 UL_REQUIRES_LINUX([lsns])
2115 UL_REQUIRES_BUILD([lsns], [libsmartcols])
2116 UL_REQUIRES_BUILD([lsns], [libmount])
2117 AM_CONDITIONAL([BUILD_LSNS], [test "x$build_lsns" = xyes])
2118
2119 UL_BUILD_INIT([renice], [yes])
2120 AM_CONDITIONAL([BUILD_RENICE], [test "x$build_renice" = xyes])
2121
2122
2123 AC_ARG_ENABLE([rfkill],
2124   AS_HELP_STRING([--disable-rfkill], [do not build rfkill]),
2125   [], [UL_DEFAULT_ENABLE([rfkill], [check])]
2126 )
2127 UL_BUILD_INIT([rfkill])
2128 UL_REQUIRES_LINUX([rfkill])
2129 UL_REQUIRES_BUILD([rfkill], [libsmartcols])
2130 AM_CONDITIONAL([BUILD_RFKILL], [test "x$build_rfkill" = xyes])
2131
2132
2133 UL_BUILD_INIT([setpgid], [yes])
2134 AM_CONDITIONAL([BUILD_SETPGID], [test "x$build_setpgid" = xyes])
2135
2136 UL_BUILD_INIT([setsid], [yes])
2137 AM_CONDITIONAL([BUILD_SETSID], [test "x$build_setsid" = xyes])
2138
2139 UL_BUILD_INIT([readprofile], [check])
2140 UL_REQUIRES_LINUX([readprofile])
2141 AM_CONDITIONAL([BUILD_READPROFILE], [test "x$build_readprofile" = xyes])
2142
2143 UL_BUILD_INIT([dmesg], [check])
2144 UL_REQUIRES_LINUX([dmesg])
2145 AM_CONDITIONAL([BUILD_DMESG], [test "x$build_dmesg" = xyes])
2146
2147 UL_BUILD_INIT([ctrlaltdel], [check])
2148 UL_REQUIRES_LINUX([ctrlaltdel])
2149 dnl we assume reboot() to be the 1-argument variant, because even considering
2150 dnl widely used alternative C libraries like uclibc, dietlibc and musl,
2151 dnl reboot() with multiple arguments is yet only found in glibc versions
2152 dnl earlier than 2.x.
2153 UL_REQUIRES_HAVE([ctrlaltdel], [reboot], [reboot function])
2154 AM_CONDITIONAL([BUILD_CTRLALTDEL], [test "x$build_ctrlaltdel" = xyes])
2155
2156 AC_ARG_ENABLE([exch],
2157   AS_HELP_STRING([--disable-exch], [do not build exch]),
2158   [], [UL_DEFAULT_ENABLE([exch], [check])]
2159 )
2160 UL_BUILD_INIT([exch])
2161 UL_REQUIRES_LINUX([exch])
2162 UL_REQUIRES_SYSCALL_CHECK([exch], [UL_CHECK_SYSCALL([renameat2])])
2163 AM_CONDITIONAL([BUILD_EXCH], [test "x$build_exch" = xyes])
2164
2165 UL_BUILD_INIT([fincore], [check])
2166 UL_REQUIRES_LINUX([fincore])
2167 UL_REQUIRES_BUILD([fincore], [libsmartcols])
2168 AM_CONDITIONAL([BUILD_FINCORE], [test "x$build_fincore" = xyes])
2169
2170 UL_BUILD_INIT([fsfreeze], [check])
2171 UL_REQUIRES_LINUX([fsfreeze])
2172 AM_CONDITIONAL([BUILD_FSFREEZE], [test "x$build_fsfreeze" = xyes])
2173
2174 UL_BUILD_INIT([blkdiscard], [check])
2175 UL_REQUIRES_LINUX([blkdiscard])
2176 AM_CONDITIONAL([BUILD_BLKDISCARD], [test "x$build_blkdiscard" = xyes])
2177
2178 UL_BUILD_INIT([blkzone], [check])
2179 UL_REQUIRES_LINUX([blkzone])
2180 UL_REQUIRES_HAVE([blkzone], [linux_blkzoned_h], [linux/blkzoned.h header])
2181 AM_CONDITIONAL([BUILD_BLKZONE], [test "x$build_blkzone" = xyes])
2182
2183 UL_BUILD_INIT([blkpr], [check])
2184 UL_REQUIRES_LINUX([blkpr])
2185 UL_REQUIRES_HAVE([blkpr], [linux_pr_h], [linux/pr.h header])
2186 AM_CONDITIONAL([BUILD_BLKPR], [test "x$build_blkpr" = xyes])
2187
2188 UL_BUILD_INIT([ldattach], [check])
2189 UL_REQUIRES_LINUX([ldattach])
2190 AM_CONDITIONAL([BUILD_LDATTACH], [test "x$build_ldattach" = xyes])
2191
2192 UL_BUILD_INIT([rtcwake], [check])
2193 UL_REQUIRES_LINUX([rtcwake])
2194 AM_CONDITIONAL([BUILD_RTCWAKE], [test "x$build_rtcwake" = xyes])
2195
2196 UL_BUILD_INIT([setarch], [check])
2197 UL_REQUIRES_LINUX([setarch])
2198 AM_CONDITIONAL([BUILD_SETARCH], [test "x$build_setarch" = xyes])
2199
2200
2201 # build_scriptutils= is just configure-only variable to control
2202 # script, scriptreplay and scriptlive
2203 AC_ARG_ENABLE([scriptutils],
2204   AS_HELP_STRING([--disable-scriptutils], [do not build script, scriptreplay and scriptlive]),
2205   [], [UL_DEFAULT_ENABLE([scriptutils], [check])]
2206 )
2207
2208 UL_ENABLE_ALIAS([script], [scriptutils])
2209 UL_BUILD_INIT([script])
2210 UL_REQUIRES_HAVE([script], [pty], [openpty function (libutil)])
2211 AM_CONDITIONAL([BUILD_SCRIPT], [test "x$build_script" = xyes])
2212
2213 UL_ENABLE_ALIAS([scriptreplay], [scriptutils])
2214 UL_BUILD_INIT([scriptreplay])
2215 AM_CONDITIONAL([BUILD_SCRIPTREPLAY], [test "x$build_scriptreplay" = xyes])
2216
2217 UL_ENABLE_ALIAS([scriptlive], [scriptutils])
2218 UL_BUILD_INIT([scriptlive])
2219 UL_REQUIRES_HAVE([scriptlive], [pty], [openpty function (libutil)])
2220 AM_CONDITIONAL([BUILD_SCRIPTLIVE], [test "x$build_scriptlive" = xyes])
2221
2222
2223 UL_BUILD_INIT([col], [check])
2224 UL_REQUIRES_COMPILE([col], [#include <limits.h>], [__GLIBC__], [building for glibc])
2225 AM_CONDITIONAL([BUILD_COL], [test "x$build_col" = xyes])
2226
2227 UL_BUILD_INIT([colcrt], [yes])
2228 AM_CONDITIONAL([BUILD_COLCRT], [test "x$build_colcrt" = xyes])
2229
2230 UL_BUILD_INIT([colrm], [yes])
2231 AM_CONDITIONAL([BUILD_COLRM], [test "x$build_colrm" = xyes])
2232
2233 UL_BUILD_INIT([column], [check])
2234 UL_REQUIRES_BUILD([column], [libsmartcols])
2235 AM_CONDITIONAL([BUILD_COLUMN], [test "x$build_column" = xyes])
2236
2237 UL_BUILD_INIT([hexdump], [yes])
2238 AM_CONDITIONAL([BUILD_HEXDUMP], [test "x$build_hexdump" = xyes])
2239
2240 UL_BUILD_INIT([rev], [yes])
2241 AM_CONDITIONAL([BUILD_REV], [test "x$build_rev" = xyes])
2242
2243
2244 AC_ARG_ENABLE([tunelp],
2245   AS_HELP_STRING([--enable-tunelp], [build tunelp]),
2246   [], [UL_DEFAULT_ENABLE([tunelp], [no])]
2247 )
2248 UL_BUILD_INIT([tunelp])
2249 UL_REQUIRES_LINUX([tunelp])
2250 AM_CONDITIONAL([BUILD_TUNELP], [test "x$build_tunelp" = xyes])
2251
2252
2253 AC_ARG_ENABLE([kill],
2254   AS_HELP_STRING([--disable-kill], [do not build kill]),
2255   [], [UL_DEFAULT_ENABLE([kill], [check])]
2256 )
2257 UL_BUILD_INIT([kill])
2258 UL_REQUIRES_LINUX([kill])
2259 AM_CONDITIONAL([BUILD_KILL], [test "x$build_kill" = xyes])
2260
2261
2262 AC_ARG_ENABLE([last],
2263   AS_HELP_STRING([--disable-last], [do not build last]),
2264   [], [UL_DEFAULT_ENABLE([last], [check])]
2265 )
2266 UL_BUILD_INIT([last])
2267 UL_REQUIRES_HAVE([last], [utmpx_h], [utmpx.h header])
2268 UL_REQUIRES_HAVE([last], [gnu_utmpx], [GNU utmpx functions])
2269 AM_CONDITIONAL([BUILD_LAST], [test "x$build_last" = xyes])
2270
2271
2272 AC_ARG_ENABLE([utmpdump],
2273   AS_HELP_STRING([--disable-utmpdump], [do not build utmpdump]),
2274   [], [UL_DEFAULT_ENABLE([utmpdump], [check])]
2275 )
2276 UL_BUILD_INIT([utmpdump])
2277 UL_REQUIRES_HAVE([utmpdump], [utmpx_h], [utmpx.h header])
2278 UL_REQUIRES_HAVE([utmpdump], [gnu_utmpx], [GNU utmpx functions])
2279 AM_CONDITIONAL([BUILD_UTMPDUMP], [test "x$build_utmpdump" = xyes])
2280
2281
2282 AC_ARG_ENABLE([line],
2283   AS_HELP_STRING([--enable-line], [build line]),
2284   [], [UL_DEFAULT_ENABLE([line], [no])]
2285 )
2286 UL_BUILD_INIT([line])
2287 AM_CONDITIONAL([BUILD_LINE], [test "x$build_line" = xyes])
2288
2289
2290 AC_ARG_ENABLE([mesg],
2291   AS_HELP_STRING([--disable-mesg], [do not build mesg]),
2292   [], [UL_DEFAULT_ENABLE([mesg], [yes])]
2293 )
2294 UL_BUILD_INIT([mesg])
2295 AM_CONDITIONAL([BUILD_MESG], [test "x$build_mesg" = xyes])
2296
2297
2298 AC_ARG_ENABLE([raw],
2299   AS_HELP_STRING([--disable-raw], [do not build raw]),
2300   [], [UL_DEFAULT_ENABLE([raw], [check])]
2301 )
2302 UL_BUILD_INIT([raw])
2303 UL_REQUIRES_LINUX([raw])
2304 UL_REQUIRES_HAVE([raw], [linux_raw_h], [raw.h header file])
2305 AM_CONDITIONAL([BUILD_RAW], [test "x$build_raw" = xyes])
2306
2307
2308 AC_ARG_ENABLE([rename],
2309   AS_HELP_STRING([--disable-rename], [do not build rename]),
2310   [], [UL_DEFAULT_ENABLE([rename], [yes])]
2311 )
2312 UL_BUILD_INIT([rename])
2313 AM_CONDITIONAL([BUILD_RENAME], [test "x$build_rename" = xyes])
2314
2315
2316 AC_ARG_ENABLE([vipw],
2317   AS_HELP_STRING([--enable-vipw], [build vipw]),
2318   [], [UL_DEFAULT_ENABLE([vipw], [no])]
2319 )
2320 UL_BUILD_INIT([vipw])
2321 UL_REQUIRES_HAVE([vipw], [shadow_h], [shadow.h header])
2322 AM_CONDITIONAL([BUILD_VIPW], [test "x$build_vipw" = xyes])
2323
2324
2325 AC_ARG_ENABLE([newgrp],
2326   AS_HELP_STRING([--enable-newgrp], [build newgrp]),
2327   [], [UL_DEFAULT_ENABLE([newgrp], [no])]
2328 )
2329 UL_BUILD_INIT([newgrp])
2330 UL_REQUIRES_HAVE([newgrp], [crypt], [crypt function])
2331 AM_CONDITIONAL([BUILD_NEWGRP], [test "x$build_newgrp" = xyes])
2332
2333
2334 AC_ARG_WITH([user], AS_HELP_STRING([--without-user], [compile without libuser (remote chsh)]),
2335   [], [with_user=check]
2336 )
2337 have_user=no
2338 AS_IF([test "x$with_user" != xno], [
2339   PKG_CHECK_MODULES(LIBUSER,[libuser >= 0.58], [have_user=yes], [have_user=no])
2340   AS_CASE([$with_user:$have_user],
2341     [yes:no],
2342       [AC_MSG_ERROR([user selected but libuser not found])],
2343     [*:yes],
2344       [AC_DEFINE([HAVE_LIBUSER], [1], [Define if libuser is available])]
2345   )
2346   # temporary solution, libuser has stupid .pc where are exported all
2347   # private dependencies to Requires: instead of Requires.private:
2348   AS_IF([test "x$have_user" = xyes], [
2349     LIBUSER_LIBS=-luser
2350   ])
2351 ])
2352 AM_CONDITIONAL([HAVE_USER], [test "x$have_user" = xyes])
2353
2354 AC_ARG_ENABLE([chfn-chsh-password],
2355   AS_HELP_STRING([--disable-chfn-chsh-password], [do not require the user to enter the password in chfn and chsh]),
2356   [], [enable_chfn_chsh_password=yes]
2357 )
2358
2359 AC_ARG_ENABLE([chfn-chsh],
2360   AS_HELP_STRING([--disable-chfn-chsh], [do not build chfn and chsh]),
2361   [], [UL_DEFAULT_ENABLE([chfn_chsh], [check])]
2362 )
2363 UL_BUILD_INIT([chfn_chsh])
2364 UL_REQUIRES_HAVE([chfn_chsh], [shadow_h], [shadow.h header])
2365 UL_REQUIRES_HAVE([chfn_chsh], [getusershell], [getusershell function])
2366
2367 AS_IF([test "x$enable_chfn_chsh_password" = xyes || test "x$have_user" = xyes], [
2368   UL_REQUIRES_HAVE([chfn_chsh], [security_pam_appl_h], [PAM header file])
2369   AC_DEFINE([CHFN_CHSH_PASSWORD], [1], [Should chfn and chsh require the user to enter the password?])
2370 ])
2371 AM_CONDITIONAL([BUILD_CHFN_CHSH], [test "x$build_chfn_chsh" = xyes])
2372 AM_CONDITIONAL([CHFN_CHSH_PASSWORD], [test "x$enable_chfn_chsh_password" = xyes])
2373
2374 AC_ARG_ENABLE([chsh-only-listed],
2375   AS_HELP_STRING([--disable-chsh-only-listed], [chsh: allow shells not in /etc/shells]),
2376   [], enable_chsh_only_listed=yes
2377 )
2378
2379 AS_IF([test "x$enable_chsh_only_listed" = xyes], [
2380   AC_DEFINE([ONLY_LISTED_SHELLS], [1], [Should chsh allow only shells in /etc/shells?])
2381 ])
2382
2383
2384 AC_ARG_ENABLE([login],
2385   AS_HELP_STRING([--disable-login], [do not build login]),
2386   [], [UL_DEFAULT_ENABLE([login], [check])]
2387 )
2388 UL_BUILD_INIT([login])
2389 UL_REQUIRES_HAVE([login], [security_pam_appl_h], [PAM header file])
2390 UL_REQUIRES_HAVE([login], [security_pam_misc_h, security_openpam_h], [PAM conversation functions])
2391 UL_REQUIRES_HAVE([login], [utmpx_h], [utmpx.h header])
2392 UL_REQUIRES_HAVE([login], [gnu_utmpx], [GNU utmpx functions])
2393 AM_CONDITIONAL([BUILD_LOGIN], [test "x$build_login" = xyes])
2394
2395 AC_ARG_ENABLE([login-chown-vcs],
2396   AS_HELP_STRING([--enable-login-chown-vcs], [let login chown /dev/vcsN]),
2397   [], [enable_login_chown_vcs=no]
2398 )
2399
2400 AS_IF([test "x$enable_login_chown_vcs" = xyes], [
2401   AC_DEFINE([LOGIN_CHOWN_VCS], [1], [Should login chown /dev/vcsN?])
2402 ])
2403
2404 AC_ARG_ENABLE([login-stat-mail],
2405   AS_HELP_STRING([--enable-login-stat-mail], [let login stat() the mailbox]),
2406   [], [enable_login_stat_mail=no]
2407 )
2408
2409 AS_IF([test "x$enable_login_stat_mail" = xyes], [
2410   AC_DEFINE([LOGIN_STAT_MAIL], [1], [Should login stat() the mailbox?])
2411 ])
2412
2413 AC_ARG_ENABLE([login-lastlog],
2414   AS_HELP_STRING([--enable-login-lastlog], [program login writes lastlog entries]),
2415   [], [enable_login_lastlogin=no]
2416 )
2417
2418 AS_IF([test "x$enable_login_lastlogin" != xno], [
2419   AC_DEFINE([USE_LOGIN_LASTLOG],
2420             [1],
2421             [Define if program login writes lastlog entries])
2422 ])
2423
2424 AC_ARG_ENABLE([nologin],
2425   AS_HELP_STRING([--disable-nologin], [do not build nologin]),
2426   [], [UL_DEFAULT_ENABLE([nologin], [yes])]
2427 )
2428 UL_BUILD_INIT([nologin])
2429 AM_CONDITIONAL([BUILD_NOLOGIN], [test "x$build_nologin" = xyes])
2430
2431
2432 AC_ARG_ENABLE([sulogin],
2433   AS_HELP_STRING([--disable-sulogin], [do not build sulogin]),
2434   [], [UL_DEFAULT_ENABLE([sulogin], [check])]
2435 )
2436 UL_BUILD_INIT([sulogin])
2437 UL_REQUIRES_HAVE([sulogin], [crypt], [crypt function])
2438 UL_REQUIRES_HAVE([sulogin], [shadow_h], [shadow.h header])
2439 AM_CONDITIONAL([BUILD_SULOGIN], [test "x$build_sulogin" = xyes])
2440
2441
2442 AC_ARG_ENABLE([su],
2443   AS_HELP_STRING([--disable-su], [do not build su]),
2444   [], [UL_DEFAULT_ENABLE([su], [check])]
2445 )
2446 UL_BUILD_INIT([su])
2447 UL_REQUIRES_HAVE([su], [security_pam_appl_h], [PAM header file])
2448 UL_REQUIRES_HAVE([su], [utmpx_h], [utmpx.h header])
2449 UL_REQUIRES_HAVE([su], [gnu_utmpx], [GNU utmpx functions])
2450 AM_CONDITIONAL([BUILD_SU], [test "x$build_su" = xyes])
2451
2452
2453 AC_ARG_ENABLE([runuser],
2454   AS_HELP_STRING([--disable-runuser], [do not build runuser]),
2455   [], [UL_DEFAULT_ENABLE([runuser], [check])]
2456 )
2457 UL_BUILD_INIT([runuser])
2458 UL_REQUIRES_HAVE([runuser], [security_pam_appl_h], [PAM header file])
2459 UL_REQUIRES_HAVE([runuser], [utmpx_h], [utmpx.h header])
2460 UL_REQUIRES_HAVE([runuser], [gnu_utmpx], [GNU utmpx functions])
2461 AM_CONDITIONAL([BUILD_RUNUSER], [test "x$build_runuser" = xyes])
2462
2463
2464 AC_ARG_ENABLE([ul],
2465   AS_HELP_STRING([--disable-ul], [do not build ul]),
2466   [], [UL_DEFAULT_ENABLE([ul], [check])]
2467 )
2468 UL_BUILD_INIT([ul])
2469 UL_REQUIRES_HAVE([ul], [ncursesw, ncurses], [ncursesw or ncurses libraries])
2470 AM_CONDITIONAL([BUILD_UL], [test "x$build_ul" = xyes])
2471
2472
2473 AC_ARG_ENABLE([more],
2474   AS_HELP_STRING([--disable-more], [do not build more]),
2475   [], [UL_DEFAULT_ENABLE([more], [check])]
2476 )
2477 UL_BUILD_INIT([more])
2478 UL_REQUIRES_HAVE([more], [ncursesw, ncurses], [ncursesw or ncurses libraries])
2479 UL_REQUIRES_LINUX([more])
2480 AM_CONDITIONAL([BUILD_MORE], [test "x$build_more" = xyes])
2481
2482
2483 AC_ARG_ENABLE([pg],
2484   AS_HELP_STRING([--enable-pg], [build pg]),
2485   [], [UL_DEFAULT_ENABLE([pg], [no])]
2486 )
2487 UL_BUILD_INIT([pg])
2488 UL_REQUIRES_HAVE([pg], [ncursesw, ncurses], [ncursesw or ncurses library])
2489 AM_CONDITIONAL([BUILD_PG], [test "x$build_pg" = xyes])
2490
2491
2492 AC_ARG_ENABLE([setterm],
2493   AS_HELP_STRING([--disable-setterm], [do not build setterm]),
2494   [], [UL_DEFAULT_ENABLE([setterm], [check])]
2495 )
2496 UL_BUILD_INIT([setterm])
2497 UL_REQUIRES_LINUX([setterm])
2498 UL_REQUIRES_HAVE([setterm], [ncursesw, ncurses], [ncursesw or ncurses library])
2499 AM_CONDITIONAL([BUILD_SETTERM], [test "x$build_setterm" = xyes])
2500
2501 # build_schedutils= is just configure-only variable to control
2502 # ionice, taskset and chrt
2503 AC_ARG_ENABLE([schedutils],
2504   AS_HELP_STRING([--disable-schedutils], [do not build chrt, ionice, taskset]),
2505   [], [UL_DEFAULT_ENABLE([schedutils], [check])]
2506 )
2507
2508
2509 UL_ENABLE_ALIAS([ionice], [schedutils])
2510 UL_BUILD_INIT([ionice])
2511 UL_REQUIRES_SYSCALL_CHECK([ionice],
2512         [UL_CHECK_SYSCALL([ioprio_set],
2513           [alpha],      [442],
2514           [i*86],       [289],
2515           [ia64*],      [1274],
2516           [powerpc*],   [273],
2517           [s390*],      [282],
2518           [sparc*],     [196],
2519           [sh*],        [288],
2520           [x86_64*],    [251])],
2521         [ioprio_set])
2522
2523 UL_REQUIRES_SYSCALL_CHECK([ionice],
2524         [UL_CHECK_SYSCALL([ioprio_get],
2525           [alpha],      [443],
2526           [i*86],       [290],
2527           [ia64*],      [1275],
2528           [powerpc*],   [274],
2529           [s390*],      [283],
2530           [sparc*],     [218],
2531           [sh*],        [289],
2532           [x86_64*],    [252])],
2533         [ioprio_get])
2534
2535 AM_CONDITIONAL([BUILD_IONICE], [test "x$build_ionice" = xyes])
2536
2537
2538 UL_ENABLE_ALIAS([taskset], [schedutils])
2539 UL_BUILD_INIT([taskset])
2540 UL_REQUIRES_HAVE([taskset], [cpu_set_t], [cpu_set_t type])
2541 UL_REQUIRES_SYSCALL_CHECK([taskset],
2542         [UL_CHECK_SYSCALL([sched_getaffinity])],
2543         [sched_getaffinity])
2544 AM_CONDITIONAL([BUILD_TASKSET], [test "x$build_taskset" = xyes])
2545
2546
2547 have_schedsetter=no
2548 AS_IF([test "x$ac_cv_func_sched_setscheduler" = xyes], [have_schedsetter=yes],
2549       [test "x$ac_cv_func_sched_setattr" = xyes], [have_schedsetter=yes])
2550
2551 UL_ENABLE_ALIAS([chrt], [schedutils])
2552 UL_BUILD_INIT([chrt])
2553 UL_REQUIRES_HAVE([chrt], [schedsetter], [sched_set functions])
2554 AM_CONDITIONAL([BUILD_CHRT], [test "x$build_chrt" = xyes])
2555
2556 AS_IF([test "x$build_chrt" = xyes], [
2557         UL_CHECK_SYSCALL([sched_setattr])
2558 ])
2559
2560 UL_ENABLE_ALIAS([uclampset], [schedutils])
2561 UL_BUILD_INIT([uclampset])
2562 UL_REQUIRES_SYSCALL_CHECK([uclampset],
2563         [UL_CHECK_SYSCALL([sched_setattr])], [sched_setattr])
2564 AM_CONDITIONAL([BUILD_UCLAMPSET], [test "x$build_uclampset" = xyes])
2565
2566
2567 AC_ARG_ENABLE([wall],
2568   AS_HELP_STRING([--disable-wall], [do not build wall]),
2569   [], [UL_DEFAULT_ENABLE([wall], [check])]
2570 )
2571 UL_BUILD_INIT([wall])
2572 UL_REQUIRES_HAVE([wall], [utmpx_h], [utmpx.h header])
2573 AM_CONDITIONAL([BUILD_WALL], [test "x$build_wall" = xyes])
2574
2575
2576 AC_ARG_ENABLE([write],
2577   AS_HELP_STRING([--enable-write], [build write]),
2578   [], [UL_DEFAULT_ENABLE([write], [no])]
2579 )
2580 UL_BUILD_INIT([write])
2581 UL_REQUIRES_HAVE([write], [utmpx_h], [utmpx.h header])
2582 UL_REQUIRES_HAVE([write], [gnu_utmpx], [GNU utmpx functions])
2583 AM_CONDITIONAL([BUILD_WRITE], [test "x$build_write" = xyes])
2584
2585
2586 AC_ARG_WITH([btrfs],
2587   AS_HELP_STRING([--without-btrfs], [do not build with btrfs support]),
2588   [], [with_btrfs=check]
2589 )
2590 have_btrfs=no
2591 AS_IF([test "x$with_btrfs" != xno], [
2592   AS_CASE([$with_btrfs:$have_linux_btrfs_h],
2593     [yes:no],
2594     [AC_MSG_ERROR([btrfs selected but linux/btrfs.h not found])],
2595     [check:no],
2596        [AC_MSG_WARN([linux/btrfs.h not found, do not build with btrfs support])],
2597     [*:yes],
2598        [have_btrfs=yes
2599         AC_DEFINE([HAVE_BTRFS_SUPPORT], [1], [Define if btrfs stuff is available])]
2600   )
2601 ])
2602 AM_CONDITIONAL([HAVE_BTRFS], [test "x$have_btrfs" = xyes])
2603
2604
2605 AC_ARG_WITH([systemd],
2606   AS_HELP_STRING([--without-systemd], [do not build with systemd support]),
2607   [], [with_systemd=check]
2608 )
2609
2610 have_systemd=no
2611 AS_IF([test "x$with_systemd" != xno], [
2612   # new version -- all libsystemd-* libs merged into libsystemd
2613   PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [have_systemd=yes], [have_systemd=no])
2614   # old versions
2615   AS_IF([test "x$have_systemd" != "xyes"], [
2616     PKG_CHECK_MODULES([SYSTEMD_DAEMON], [libsystemd-daemon],
2617                       [have_systemd_daemon=yes], [have_systemd_daemon=no])
2618     PKG_CHECK_MODULES([SYSTEMD_JOURNAL], [libsystemd-journal],
2619                       [have_systemd_journal=yes], [have_systemd_journal=no])
2620     AS_IF([test "x$have_systemd_daemon" = "xyes" && test "x$have_systemd_journal" = "xyes" ],[
2621            have_systemd=yes])
2622   ])
2623   AS_CASE([$with_systemd:$have_systemd],
2624     [yes:no],
2625       [AC_MSG_ERROR([systemd expected but libsystemd not found])],
2626     [*:yes],
2627        AC_DEFINE([HAVE_LIBSYSTEMD], [1], [Define if libsystemd is available])
2628        AC_DEFINE([USE_SYSTEMD], [1], [Define if systemd support is wanted ])
2629        AC_CHECK_DECLS([sd_session_get_username], [], [], [#include <systemd/sd-login.h>])
2630   )
2631 ])
2632 AM_CONDITIONAL([HAVE_SYSTEMD], [test "x$have_systemd" = xyes])
2633
2634
2635 AC_ARG_WITH([systemdsystemunitdir],
2636   AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [directory for systemd unit files (requires systemd support)]),
2637   [], [
2638   AS_IF([test "x$have_systemd" = xyes], [
2639     PKG_CHECK_VAR([with_systemdsystemunitdir], [systemd], [systemdsystemunitdir],
2640       [],
2641       [with_systemdsystemunitdir=no])
2642   ])
2643 ])
2644 AS_IF([test "x$with_systemdsystemunitdir" != "xno"], [
2645   AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
2646 ])
2647
2648 AC_ARG_WITH([tmpfilesdir],
2649   AS_HELP_STRING([--with-tmpfilesdir=DIR], [directory for tmpfiles. See tmpfiles.d(5) for details]),
2650   [], [
2651   AS_IF([test "x$have_systemd" = xyes], [
2652     PKG_CHECK_VAR([with_tmpfilesdir], [systemd], [tmpfilesdir],
2653       [],
2654       [with_tmpfilesdir=no])
2655   ])
2656 ])
2657 AS_IF([test "x$with_tmpfilesdir" != "xno"], [
2658   AC_SUBST([tmpfilesdir], [$with_tmpfilesdir])
2659 ])
2660
2661 AC_ARG_WITH([smack],
2662   AS_HELP_STRING([--with-smack], [build with SMACK support]),
2663   [], [with_smack=no]
2664 )
2665 AS_IF([test "x$with_smack" = xyes], [
2666   AC_DEFINE([HAVE_SMACK], [1], [Add SMACK support])
2667 ])
2668
2669 AC_ARG_WITH([econf],
2670   AS_HELP_STRING([--without-econf], [do not use libeconf]),
2671   [], [with_econf=check]
2672 )
2673
2674 have_econf=no
2675 AS_IF([test "x$with_econf" != xno], [
2676   PKG_CHECK_MODULES([ECONF], [libeconf], [have_econf=yes], [have_econf=no])
2677     AS_CASE([$with_econf:$have_econf],
2678     [yes:no],
2679       [AC_MSG_ERROR([libeconf expected but libeconf not found])],
2680     [*:yes],
2681        AC_DEFINE([HAVE_LIBECONF], [1], [Define if libeconf is available])
2682   )
2683 ])
2684 AM_CONDITIONAL([HAVE_ECONF], [test "x$have_econf" = xyes])
2685
2686 AC_ARG_WITH([vendordir],
2687   AS_HELP_STRING([--with-vendordir=DIR], [Directory for distribution provided configuration files]),
2688   [], []
2689 )
2690 AC_SUBST([vendordir], [$with_vendordir])
2691 AM_CONDITIONAL([USE_VENDORDIR], [test "x$with_vendordir" != x])
2692 AS_IF([test "x$with_vendordir" != x], [
2693   AC_DEFINE([USE_VENDORDIR], [1], [Define to 1 to use vendordir])
2694 ])
2695
2696
2697 AC_ARG_ENABLE([bash-completion],
2698   AS_HELP_STRING([--disable-bash-completion], [do not install bash completion files]),
2699   [], [enable_bash_completion=yes]
2700 )
2701
2702 AM_CONDITIONAL([BUILD_BASH_COMPLETION], [test "x$enable_bash_completion" = xyes])
2703
2704 AC_ARG_WITH([bashcompletiondir],
2705   AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
2706   [], [
2707   AS_IF([test "x$enable_bash_completion" = xyes], [
2708     PKG_CHECK_VAR([with_bashcompletiondir], [bash-completion], [completionsdir],
2709       [],
2710       [with_bashcompletiondir=${datadir}/bash-completion/completions])
2711   ])
2712 ])
2713 AS_IF([test "x$enable_bash_completion" = xyes], [
2714   AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
2715 ])
2716
2717
2718 AC_ARG_WITH([python],
2719   AS_HELP_STRING([--without-python], [do not build python bindings, use --with-python={2,3} to force version]),
2720   [], [with_python=check withval=check]
2721 )
2722
2723 have_python=no
2724 have_libpython=no
2725 AS_IF([test "x$with_python" != xno], [
2726   # We follow distributions default and look for PKG module name "python"
2727   # (minimal version is 2) but if major version is explicitly specified by
2728   # --with-python=2 or --with-python=3 then we look for PKG module "python2" or
2729   # "python3".
2730   AS_IF([test "x$withval" != xno && test "x$withval" != xyes && test "x$withval" != xcheck],
2731         [pymajor="$withval"; PYTHON=python${pymajor}], [pymajor="2"])
2732
2733   # check for python interpreter
2734   AM_PATH_PYTHON([$pymajor], [have_python=yes], [have_python=no])
2735   AS_CASE([$with_python:$have_python],
2736     [yes:no],
2737       [AC_MSG_ERROR([python selected but python interpreter not found])],
2738     [check:no],
2739        [AC_MSG_WARN([python interpreter not found, do not build python bindings])],
2740     [*:yes],
2741        # check for python development stuff
2742        [
2743          PKG_CHECK_MODULES([PYTHON], [python-$PYTHON_VERSION], [have_libpython=yes], [have_libpython=no])
2744
2745          # https://github.com/util-linux/util-linux/issues/2366
2746          AX_COMPARE_VERSION([$PYTHON_VERSION], [ge], [3.12], [
2747            UL_WARN_ADD([-Wno-error=redundant-decls], [PYTHON_CFLAGS])
2748          ])
2749        ]
2750   )
2751 ])
2752
2753
2754 AC_ARG_ENABLE([pylibmount],
2755   AS_HELP_STRING([--disable-pylibmount], [do not build pylibmount]),
2756   [], [UL_DEFAULT_ENABLE([pylibmount], [check])]
2757 )
2758 UL_BUILD_INIT([pylibmount])
2759 UL_REQUIRES_HAVE([pylibmount], [libpython], [libpython])
2760 UL_REQUIRES_BUILD([pylibmount], [libmount])
2761 AM_CONDITIONAL([BUILD_PYLIBMOUNT], [test "x$build_pylibmount" = "xyes"])
2762
2763 # We need to introduce a verbatim dependency into the Makefile, without automake
2764 # trying to interpret it, so push it as a AM_SUBST_NOTMAKE variable.
2765 verbatim_pylibmount_dependency='
2766
2767 # pylibmountexec module must be installed after usrlib_exec libraries,
2768 # otherwise the libtool relink step will fail to find libmount.la and
2769 # will try -lmount which is possibly not available.
2770 install-pylibmountexecLTLIBRARIES: install-usrlib_execLTLIBRARIES
2771
2772 '
2773 AC_SUBST([verbatim_pylibmount_dependency])
2774 AM_SUBST_NOTMAKE([verbatim_pylibmount_dependency])
2775
2776 AC_ARG_ENABLE([pg-bell],
2777   AS_HELP_STRING([--disable-pg-bell], [let pg not ring the bell on invalid keys]),
2778   [], [enable_pg_bell=yes]
2779 )
2780
2781 AS_IF([test "x$enable_pg_bell" = xyes], [
2782   AC_DEFINE([PG_BELL], [1], [Should pg ring the bell on invalid keys?])
2783 ])
2784
2785
2786 AC_DEFUN([FS_PATHS_DEFAULT], [/sbin:/sbin/fs.d:/sbin/fs])
2787 AC_ARG_ENABLE([fs-paths-default],
2788   AS_HELP_STRING([--enable-fs-paths-default=paths], [default search path for fs helpers @<:@FS_PATHS_DEFAULT@:>@]),
2789   [AS_CASE([$enableval],
2790     [yes], [fs_paths_defaults="FS_PATHS_DEFAULT"],
2791     [no],  [fs_paths_defaults=""],
2792     [fs_paths_defaults="$enableval"]
2793   )],
2794   [fs_paths_defaults="FS_PATHS_DEFAULT"]
2795 )
2796 AC_ARG_ENABLE([fs-paths-extra],
2797   AS_HELP_STRING([--enable-fs-paths-extra=paths], [additional search paths for fs helpers]),
2798   [AS_CASE([$enableval],
2799      [yes|no], [fs_paths_extra=""],
2800      [fs_paths_extra="$enableval"]
2801   )],
2802   [fs_paths_extra=""]
2803 )
2804 fs_paths="$fs_paths_defaults"
2805 AS_IF([test "x$fs_paths_extra" != "x"], [
2806   AS_IF([test "x$fs_paths" != "x"], [
2807     fs_paths="${fs_paths}:"
2808   ])
2809   fs_paths="${fs_paths}${fs_paths_extra}"
2810 ])
2811 AC_DEFINE_UNQUOTED([FS_SEARCH_PATH], "$fs_paths", [search path for fs helpers])
2812
2813
2814 AC_ARG_ENABLE([use-tty-group],
2815   AS_HELP_STRING([--disable-use-tty-group], [do not install wall and write setgid tty]),
2816   [], [enable_use_tty_group=yes]
2817 )
2818 AM_CONDITIONAL([USE_TTY_GROUP], [test "x$enable_use_tty_group" = xyes])
2819
2820 AS_IF([test "x$enable_use_tty_group" = xyes], [
2821   AC_DEFINE([USE_TTY_GROUP], [1], [Should wall and write be installed setgid tty?])
2822 ])
2823
2824
2825 AC_ARG_ENABLE([sulogin-emergency-mount],
2826   AS_HELP_STRING([--enable-sulogin-emergency-mount],
2827                  [use emergency mount of /dev and /proc for sulogin]),
2828   [], [enable_sulogin_emergency_mount=no]
2829 )
2830
2831 AS_IF([test "x$enable_sulogin_emergency_mount" = xyes], [
2832   AS_IF([test "x$linux_os" = xyes], [ ],
2833         [AC_MSG_ERROR([--enable-sulogin-emergency-mount selected for non-linux system])])
2834   AC_DEFINE([USE_SULOGIN_EMERGENCY_MOUNT], [1],
2835             [Should sulogin use an emergency mount of /dev and /proc?])
2836 ])
2837
2838
2839 AC_ARG_ENABLE([usrdir-path],
2840   AS_HELP_STRING([--enable-usrdir-path], [use only /usr paths in PATH env. variable (recommended on systems with /bin -> /usr/bin symlinks)]),
2841   [], [enable_usrdir_path=no]
2842 )
2843
2844 AS_IF([test "x$enable_usrdir_path" = xyes], [
2845   AC_DEFINE([USE_USRDIR_PATHS_ONLY], [1], [Define to 1 to remove /bin and /sbin from PATH env.variable])
2846 ])
2847
2848
2849 AC_ARG_ENABLE([makeinstall-chown],
2850   AS_HELP_STRING([--disable-makeinstall-chown], [do not do chown-like operations during "make install"]),
2851   [], [enable_makeinstall_chown=yes]
2852 )
2853 AM_CONDITIONAL([MAKEINSTALL_DO_CHOWN], [test "x$enable_makeinstall_chown" = xyes])
2854
2855
2856 AC_ARG_ENABLE([makeinstall-setuid],
2857   AS_HELP_STRING([--disable-makeinstall-setuid], [do not do setuid chmod operations during "make install"]),
2858   [], [enable_makeinstall_setuid=yes]
2859 )
2860 AM_CONDITIONAL([MAKEINSTALL_DO_SETUID], [test "x$enable_makeinstall_setuid" = xyes])
2861
2862
2863 AC_ARG_ENABLE([colors-default],
2864   AS_HELP_STRING([--disable-colors-default], [do not colorize output from utils by default]),
2865   [], [enable_colors_default=yes]
2866 )
2867 AS_IF([test "x$enable_colors_default" = xyes], [
2868   AC_DEFINE([USE_COLORS_BY_DEFAULT], [1], [Enables colorized output from utils by default])
2869 ])
2870
2871
2872 AC_ARG_WITH([cryptsetup],
2873   AS_HELP_STRING([--with-cryptsetup], [compile with cryptsetup support]),
2874   [], [with_cryptsetup=no]
2875 )
2876
2877 AS_IF([test "x$with_cryptsetup" = xno], [
2878   AM_CONDITIONAL([HAVE_CRYPTSETUP], [false])
2879   AM_CONDITIONAL([CRYPTSETUP_VIA_DLOPEN], [false])
2880 ], [
2881   PKG_CHECK_MODULES([CRYPTSETUP], [libcryptsetup],
2882         [AC_DEFINE([HAVE_CRYPTSETUP], [1], [Define if cryptsetup is available])
2883          UL_PKG_STATIC([CRYPTSETUP_LIBS_STATIC], [libcryptsetup])
2884          AM_CONDITIONAL([HAVE_CRYPTSETUP], [true])
2885          SAVE_CFLAGS="$CFLAGS"
2886          CFLAGS="$CRYPTSETUP_CFLAGS $CFLAGS"
2887          SAVE_LIBS="$LIBS"
2888          LIBS="$CRYPTSETUP_LIBS $LIBS"
2889          AC_CHECK_LIB([cryptsetup], [crypt_activate_by_signed_key], [
2890           AC_DEFINE([HAVE_CRYPT_ACTIVATE_BY_SIGNED_KEY], [1], [Define if crypt_activate_by_signed_key exist in -lcryptsetup])
2891          ])
2892          AS_IF([test "x$with_cryptsetup" = xdlopen], [
2893           LIBS="-ldl $LIBS"
2894           AC_CHECK_LIB([dl], [dlsym], [
2895             AC_DEFINE([CRYPTSETUP_VIA_DLOPEN], [1], [Define if cryptsetup is to be loaded via dlopen])
2896             AM_CONDITIONAL([CRYPTSETUP_VIA_DLOPEN], [true])
2897            ], [AC_MSG_ERROR([libdl required to build with cryptsetup support])])
2898          ], [
2899           AM_CONDITIONAL([CRYPTSETUP_VIA_DLOPEN], [false])
2900          ])
2901          CFLAGS="$SAVE_CFLAGS"
2902          LIBS="$SAVE_LIBS"
2903          have_cryptsetup=yes],
2904         [have_cryptsetup=no
2905    AM_CONDITIONAL([HAVE_CRYPTSETUP], [false])
2906    AM_CONDITIONAL([CRYPTSETUP_VIA_DLOPEN], [false])
2907   ])
2908
2909   AS_CASE([$with_cryptsetup:$have_cryptsetup],
2910     [yes:no], [AC_MSG_WARN([cryptsetup selected but libcryptsetup not found])]
2911   )
2912 ])
2913 AC_SUBST([CRYPTSETUP_LIBS])
2914 AC_SUBST([CRYPTSETUP_LIBS_STATIC])
2915
2916
2917 AC_ARG_VAR([SUID_CFLAGS],
2918            [CFLAGS used for binaries which are usually with the suid bit])
2919 AC_ARG_VAR([SUID_LDFLAGS],
2920            [LDFLAGS used for binaries which are usually with the suid bit])
2921
2922 AC_ARG_VAR([DAEMON_CFLAGS],
2923            [CFLAGS used for binaries which are usually executed as daemons])
2924 AC_ARG_VAR([DAEMON_LDFLAGS],
2925            [LDFLAGS used for binaries which are usually executed as daemons])
2926
2927 AC_ARG_VAR([SOLIB_CFLAGS],
2928            [CFLAGS used for shared libraries])
2929 AC_ARG_VAR([SOLIB_LDFLAGS],
2930            [LDFLAGS used for shared libraries])
2931
2932 AC_ARG_VAR([ADJTIME_PATH],
2933            [Path to hwclock adjtime file, default /etc/adjtime])
2934 AS_IF([test "x$ADJTIME_PATH" = x], [ADJTIME_PATH="/etc/adjtime"])
2935 AC_DEFINE_UNQUOTED([CONFIG_ADJTIME_PATH], "$ADJTIME_PATH", [Path to hwclock adjtime file])
2936
2937 if test "x${build_alias}" != "x${host_alias}"; then
2938   AC_MSG_NOTICE([setting link_all_deplibs=unknown for libtool])
2939   # work around Debian patch to libtool breaking cross-compiles
2940   # https://bugs.debian.org/cgi-bin/bugreport.cgi?bug=702737
2941   # https://bugs.debian.org/cgi-bin/bugreport.cgi?bug=297726
2942   link_all_deplibs=unknown
2943 fi
2944
2945
2946 LIBS=""
2947
2948
2949 AC_CONFIG_HEADERS([config.h])
2950
2951 #
2952 # Don't use configure.ac to replace install paths! See Makefile PATHFILES for
2953 # more details.
2954 #
2955 AC_CONFIG_FILES([
2956 Makefile
2957 libblkid/docs/Makefile
2958 libblkid/docs/version.xml
2959 libblkid/src/blkid.h
2960 libfdisk/docs/Makefile
2961 libfdisk/docs/version.xml
2962 libfdisk/src/libfdisk.h
2963 libmount/docs/Makefile
2964 libmount/docs/version.xml
2965 libmount/src/libmount.h
2966 libsmartcols/docs/Makefile
2967 libsmartcols/docs/version.xml
2968 libsmartcols/src/libsmartcols.h
2969 po/Makefile.in
2970 po-man/Makefile
2971 ])
2972
2973 AC_OUTPUT
2974
2975 AC_MSG_RESULT([
2976         ${PACKAGE}  ${VERSION}
2977
2978         prefix:                    ${prefix}
2979         exec prefix:               ${exec_prefix}
2980
2981         bindir:                    ${bindir}
2982         sbindir:                   ${sbindir}
2983         libdir:                    ${libdir}
2984         usrbin_execdir:            ${usrbin_execdir}
2985         usrsbin_execdir:           ${usrsbin_execdir}
2986         usrlib_execdir:            ${usrlib_execdir}
2987
2988         localstatedir:             ${localstatedir}
2989         runstatedir:               ${runstatedir}
2990         includedir:                ${includedir}
2991         sysconfdir:                ${sysconfdir}
2992         sysconfstaticdir:          ${sysconfstaticdir}
2993
2994         vendordir:                 ${with_vendordir}
2995
2996         Python:                    ${PYTHON}
2997         Python version:            ${PYTHON_VERSION}
2998         Python libs:               ${pyexecdir}
2999
3000         Bash completions:          ${with_bashcompletiondir}
3001         Systemd support:           ${have_systemd}
3002         Systemd unitdir:           ${with_systemdsystemunitdir}
3003         tmpfilesdir:               ${with_tmpfilesdir}
3004         libeconf support:          ${have_econf}
3005         Btrfs support:             ${have_btrfs}
3006         lastlog2 support:          ${build_liblastlog2}
3007         Wide-char support:         ${build_widechar}
3008         libcryptsetup support:     ${have_cryptsetup}
3009
3010         Manual pages:              ${build_asciidoc}
3011         Manual pages translated:   ${build_poman}
3012
3013         compiler:                  ${CC} / ${CXX}
3014         suid cflags:               ${SUID_CFLAGS}
3015         ldflags:                   ${LDFLAGS}
3016         suid ldflags:              ${SUID_LDFLAGS}
3017         ASAN enabled:              ${enable_asan}
3018         Fuzzing enabled:           ${enable_fuzzing_engine}
3019         Coverage enabled           ${enable_coverage}
3020
3021         cflags:                    ${CFLAGS}
3022
3023         warnings:
3024
3025 ${WARN_CFLAGS}
3026
3027  Type 'make' or 'make <utilname>' to compile.
3028 ])