configure.ac

   1 AC_INIT([util-linux],
   2         m4_esyscmd([tools/git-version-gen .tarball-version]),
   3         [kzak@redhat.com],,
   4         [http://www.kernel.org/pub/linux/utils/util-linux/])
   5
   6
   7 AC_PREREQ([2.60])
   8
   9 AC_CONFIG_AUX_DIR([config])
  10 AC_CONFIG_MACRO_DIR([m4])
  11 dnl AC_USE_SYSTEM_EXTENSIONS must be called before any macros that run
  12 dnl the compiler (like AC_PROG_LIBTOOL) to avoid autoconf errors.
  13 AC_USE_SYSTEM_EXTENSIONS
  14 AM_INIT_AUTOMAKE([-Wall foreign 1.10 tar-pax no-dist-gzip dist-xz subdir-objects])
  15
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  17                             [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  18 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  19
  20 AC_CONFIG_SRCDIR([sys-utils/mount.c])
  21 AC_PREFIX_DEFAULT([/usr])
  22
  23 dnl version details from <major>.<minor>[-<suffix>]
  24 PACKAGE_VERSION_MAJOR=$(echo $PACKAGE_VERSION | awk -F. '{print $1}')
  25 PACKAGE_VERSION_MINOR=$(echo $PACKAGE_VERSION | awk -F. '{
  26                                                    sub("-.*","",$2); print $2}')
  27 PACKAGE_VERSION_RELEASE=$(echo $PACKAGE_VERSION | awk -F. '{
  28                      sub("-.*","",$3); print $3 ~ /^@<:@0-9@:>@+$/ ? $3 : 0}')
  29
  30 dnl libblkid version
  31 LIBBLKID_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  32 LIBBLKID_DATE="21-Mar-2018"
  33 LIBBLKID_LT_MAJOR=1
  34 LIBBLKID_LT_MINOR=1
  35 LIBBLKID_LT_MICRO=0
  36 LIBBLKID_VERSION_INFO=`expr $LIBBLKID_LT_MAJOR + $LIBBLKID_LT_MINOR`:$LIBBLKID_LT_MICRO:$LIBBLKID_LT_MINOR
  37
  38 dnl libuuid version
  39 LIBUUID_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  40 LIBUUID_LT_MAJOR=1
  41 LIBUUID_LT_MINOR=3
  42 LIBUUID_LT_MICRO=0
  43 LIBUUID_VERSION_INFO=`expr $LIBUUID_LT_MAJOR + $LIBUUID_LT_MINOR`:$LIBUUID_LT_MICRO:$LIBUUID_LT_MINOR
  44
  45 dnl libmount version
  46 LIBMOUNT_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  47 LIBMOUNT_LT_MAJOR=1
  48 LIBMOUNT_LT_MINOR=1
  49 LIBMOUNT_LT_MICRO=0
  50 LIBMOUNT_VERSION_INFO=`expr $LIBMOUNT_LT_MAJOR + $LIBMOUNT_LT_MINOR`:$LIBMOUNT_LT_MICRO:$LIBMOUNT_LT_MINOR
  51
  52 dnl libsmartcols version
  53 LIBSMARTCOLS_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  54 LIBSMARTCOLS_LT_MAJOR=1
  55 LIBSMARTCOLS_LT_MINOR=1
  56 LIBSMARTCOLS_LT_MICRO=0
  57 LIBSMARTCOLS_VERSION_INFO=`expr $LIBSMARTCOLS_LT_MAJOR + $LIBSMARTCOLS_LT_MINOR`:$LIBSMARTCOLS_LT_MICRO:$LIBSMARTCOLS_LT_MINOR
  58
  59 dnl libfdisk version
  60 LIBFDISK_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  61 LIBFDISK_LT_MAJOR=1
  62 LIBFDISK_LT_MINOR=1
  63 LIBFDISK_LT_MICRO=0
  64 LIBFDISK_VERSION_INFO=`expr $LIBFDISK_LT_MAJOR + $LIBFDISK_LT_MINOR`:$LIBFDISK_LT_MICRO:$LIBFDISK_LT_MINOR
  65
  66 # Check whether exec_prefix=/usr:
  67 AS_CASE([$exec_prefix:$prefix],
  68 [NONE:NONE | NONE:/usr | /usr:*],
  69   [AC_MSG_NOTICE([Default --exec-prefix detected.])
  70    AS_CASE([$bindir],  ['${exec_prefix}/bin'],  [bindir=/bin;   AC_MSG_NOTICE([  --bindir defaults to /bin])  ])
  71    AS_CASE([$sbindir], ['${exec_prefix}/sbin'], [sbindir=/sbin; AC_MSG_NOTICE([  --sbindir defaults to /sbin])])
  72    AS_CASE([$libdir],  ['${exec_prefix}/lib'],  [libdir=/lib;   AC_MSG_NOTICE([  --libdir defaults to /lib])  ])
  73   ]
  74 )
  75
  76
  77 # default for old versions without $runstatedir
  78 AS_IF([test x"$runstatedir" = x], [runstatedir='${localstatedir}/run'])
  79
  80 # our default if $localstatedir unchanged
  81 AS_CASE([$localstatedir:$runstatedir],
  82  [NONE:'${localstatedir}/run' | /var:'${localstatedir}/run' | NONE:'/run' ],
  83    [runstatedir=/run; AC_MSG_NOTICE([  --runstatedir defaults to /run])]
  84 )
  85
  86 AC_SUBST([runstatedir])
  87
  88
  89 # The original default values of {bin,sbin,lib}dir
  90 usrbin_execdir='${exec_prefix}/bin'
  91 AC_SUBST([usrbin_execdir])
  92
  93 usrsbin_execdir='${exec_prefix}/sbin'
  94 AC_SUBST([usrsbin_execdir])
  95
  96 AS_CASE([$libdir],
  97  ['${exec_prefix}/'* | '${prefix}/'* | /usr/* | "${prefix}"/* ],
  98    [usrlib_execdir=$libdir],
  99  [usrlib_execdir='${exec_prefix}'$libdir]
 100 )
 101 AC_SUBST([usrlib_execdir])
 102
 103
 104 AM_PROG_CC_C_O
 105 AC_PROG_MKDIR_P
 106 AC_PROG_CC_STDC
 107 AC_PROG_YACC
 108 AC_CANONICAL_HOST
 109 AC_C_CONST
 110 AC_C_VOLATILE
 111 AC_C_BIGENDIAN
 112
 113 dnl Compiler warnings
 114 UL_WARN_ADD([-fno-common])
 115 UL_WARN_ADD([-Wall])
 116 UL_WARN_ADD([-Werror=sequence-point])
 117 UL_WARN_ADD([-Wextra])
 118 UL_WARN_ADD([-Wextra-semi])
 119 UL_WARN_ADD([-Wembedded-directive])
 120 UL_WARN_ADD([-Wmissing-declarations])
 121 UL_WARN_ADD([-Wmissing-parameter-type])
 122 UL_WARN_ADD([-Wmissing-prototypes])
 123 UL_WARN_ADD([-Wno-missing-field-initializers])
 124 UL_WARN_ADD([-Wredundant-decls])
 125 UL_WARN_ADD([-Wsign-compare])
 126 UL_WARN_ADD([-Wtype-limits])
 127 UL_WARN_ADD([-Wuninitialized])
 128 UL_WARN_ADD([-Wunused-but-set-parameter])
 129 UL_WARN_ADD([-Wunused-but-set-variable])
 130 UL_WARN_ADD([-Wunused-parameter])
 131 UL_WARN_ADD([-Wunused-result])
 132 UL_WARN_ADD([-Wunused-variable])
 133 UL_WARN_ADD([-Wnested-externs])
 134 UL_WARN_ADD([-Wpointer-arith])
 135 UL_WARN_ADD([-Wstrict-prototypes])
 136 UL_WARN_ADD([-Wformat-security])
 137 UL_WARN_ADD([-Wimplicit-function-declaration])
 138 AC_SUBST([WARN_CFLAGS])
 139
 140 UL_WARN_ADD([-Wno-clobbered], [BSD_WARN_CFLAGS])
 141 AC_SUBST([BSD_WARN_CFLAGS])
 142
 143 UL_WARN_ADD([-Wno-cast-function-type], [PYTHON_WARN_CFLAGS])
 144 AC_SUBST([PYTHON_WARN_CFLAGS])
 145
 146 UL_WARN_ADD([-Wno-unused-parameter], [NO_UNUSED_WARN_CFLAGS])
 147 AC_SUBST([NO_UNUSED_WARN_CFLAGS])
 148
 149
 150 AC_ARG_ENABLE([asan],
 151   AS_HELP_STRING([--enable-asan], [compile with Address Sanitizer]),
 152   [], [enable_asan=no]
 153 )
 154 AS_IF([test "x$enable_asan" = xyes], [
 155   UL_WARN_ADD([-fsanitize=address])
 156 ])
 157
 158
 159
 160 dnl libtool-2
 161 LT_INIT
 162
 163 dnl check supported linker flags
 164 AX_CHECK_VSCRIPT
 165
 166 m4_ifndef([PKG_PROG_PKG_CONFIG],
 167   [m4_fatal([Could not locate the pkg-config autoconf
 168     macros. These are usually located in /usr/share/aclocal/pkg.m4.
 169     If your macros are in a different location, try setting the
 170     environment variable AL_OPTS="-I/other/macro/dir" before running
 171     ./autogen.sh or autoreconf again. Make sure pkg-config is installed.])])
 172 PKG_PROG_PKG_CONFIG
 173
 174 GTK_DOC_CHECK([1.10])
 175 AC_PATH_PROG([XSLTPROC], [xsltproc])
 176
 177 linux_os=no
 178 bsd_os=no
 179 AS_CASE([${host_os}],
 180   [*linux*],
 181      [linux_os=yes],
 182   [*darwin*],
 183      [darwin_os=yes],
 184   [*bsd*],
 185      [bsd_os=yes])
 186 AM_CONDITIONAL([LINUX], [test "x$linux_os" = xyes])
 187 AM_CONDITIONAL([DARWIN], [test "x$darwin_os" = xyes])
 188 AM_CONDITIONAL([BSD], [test "x$bsd_os" = xyes])
 189
 190 AS_IF([test  "x$darwin_os" = xyes], [
 191   AC_DEFINE([_DARWIN_C_SOURCE], [1], [Enable MAP_ANON in sys/mman.h on Mac OS X])
 192 ])
 193
 194 dnl define ARCH_<NAME> conditionals
 195 UL_SET_ARCH([I86], [i?86-*])
 196 UL_SET_ARCH([86_64], [x86_64*])
 197 UL_SET_ARCH([IA64], [ia64*])
 198 UL_SET_ARCH([S390], [s390*])
 199 UL_SET_ARCH([SPARC], [sparc*])
 200 UL_SET_ARCH([PPC], [ppc*|powerpc*])
 201 UL_SET_ARCH([M68K], [m68*])
 202 UL_SET_ARCH([MIPS], [mips*])
 203 UL_SET_ARCH([HPPA], [hppa*|parisc*])
 204
 205 AC_SYS_LARGEFILE
 206 AC_HEADER_ASSERT
 207 AC_STRUCT_TIMEZONE
 208
 209 dnl Don't forget to maintain alternatively allowed versions in autogen.sh!
 210 AM_GNU_GETTEXT_VERSION([0.18.3])
 211 AM_GNU_GETTEXT([external])
 212
 213 AS_IF([test -d "$srcdir/po"], [
 214   ALL_LINGUAS=`cd $srcdir/po > /dev/null && echo *.po | sed 's/\.po//g'`
 215 ], [
 216   ALL_LINGUAS="af am ar as be bg bn_IN bn ca cs cy da de el en_GB es et eu_ES fa fi fr gl gu he hi hr hu hy id is it ja ka kn ko ku lo lt lv mk ml mr ms my nb nl nn no nso or pa pl pt_BR pt ro ru si sk sl sq sr@Latn sr sv ta te th tr uk ur vi zh_CN zh_TW zu"
 217 ])
 218
 219 AC_CHECK_HEADERS([linux/compiler.h linux/blkpg.h linux/major.h], [], [], [
 220 #ifdef HAVE_LINUX_COMPILER_H
 221 #include <linux/compiler.h>
 222 #endif
 223 ])
 224 AC_CHECK_HEADERS([ \
 225         asm/io.h \
 226         err.h \
 227         errno.h \
 228         fcntl.h \
 229         getopt.h \
 230         inttypes.h \
 231         lastlog.h \
 232         libutil.h \
 233         linux/btrfs.h \
 234         linux/cdrom.h \
 235         linux/falloc.h \
 236         linux/watchdog.h \
 237         linux/fd.h \
 238         linux/raw.h \
 239         linux/tiocl.h \
 240         linux/version.h \
 241         linux/securebits.h \
 242         linux/net_namespace.h \
 243         locale.h \
 244         mntent.h \
 245         net/if.h \
 246         net/if_dl.h \
 247         netinet/in.h \
 248         paths.h \
 249         pty.h \
 250         security/pam_appl.h \
 251         stdint.h \
 252         stdio_ext.h \
 253         stdlib.h \
 254         endian.h \
 255         byteswap.h \
 256         sys/endian.h \
 257         sys/disk.h \
 258         sys/disklabel.h \
 259         sys/file.h \
 260         sys/io.h \
 261         sys/ioccom.h \
 262         sys/ioctl.h \
 263         sys/mkdev.h \
 264         sys/mount.h \
 265         sys/param.h \
 266         sys/prctl.h \
 267         sys/resource.h \
 268         sys/signalfd.h \
 269         sys/socket.h \
 270         sys/sockio.h \
 271         sys/stat.h \
 272         sys/sysmacros.h \
 273         sys/swap.h \
 274         sys/syscall.h \
 275         sys/time.h \
 276         sys/timex.h \
 277         sys/ttydefaults.h \
 278         sys/types.h \
 279         sys/ucred.h \
 280         sys/un.h \
 281         unistd.h \
 282         shadow.h \
 283         utmp.h \
 284         utmpx.h \
 285 ])
 286
 287 # There is a collision in old kernel-headers. The both files mount.h and fs.h
 288 # define MS_* macros. Fixed by kernel commit e462ec50cb5fad19f6003a3d8087f4a0945dd2b1.
 289 #
 290 AC_CHECK_HEADERS([linux/fs.h ], [], [],
 291  [#ifdef HAVE_SYS_MOUNT_H
 292    # include <linux/fs.h>
 293    # include <sys/mount.h>
 294   #endif
 295 ])
 296
 297 AC_CHECK_HEADERS([linux/gsmmux.h ], [], [],
 298  [#ifdef LINUX_GSMMUX_H
 299    # include <linux/gsmmux.h>
 300    #endif
 301 ])
 302
 303 AC_CHECK_HEADERS([security/pam_misc.h],
 304                 [AM_CONDITIONAL([HAVE_LINUXPAM], [true])],
 305                 [AM_CONDITIONAL([HAVE_LINUXPAM], [false])], [
 306 #ifdef HAVE_SECURITY_PAM_APPL_H
 307 #include <security/pam_appl.h>
 308 #endif
 309 ])
 310
 311 AC_CHECK_HEADERS([linux/blkzoned.h])
 312
 313 AC_CHECK_HEADERS([security/openpam.h], [], [], [
 314 #ifdef HAVE_SECURITY_PAM_APPL_H
 315 #include <security/pam_appl.h>
 316 #endif
 317 ])
 318
 319 AC_CHECK_HEADERS([langinfo.h],
 320                 [AM_CONDITIONAL([HAVE_LANGINFO], [true])],
 321                 [AM_CONDITIONAL([HAVE_LANGINFO], [false])])
 322
 323 AC_MSG_CHECKING([whether langinfo.h defines ALTMON_x constants])
 324 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 325         #include <langinfo.h>
 326 ]], [[
 327         char *str;
 328         str = nl_langinfo (ALTMON_1);
 329         str = nl_langinfo (ALTMON_2);
 330         str = nl_langinfo (ALTMON_3);
 331         str = nl_langinfo (ALTMON_4);
 332         str = nl_langinfo (ALTMON_5);
 333         str = nl_langinfo (ALTMON_6);
 334         str = nl_langinfo (ALTMON_7);
 335         str = nl_langinfo (ALTMON_8);
 336         str = nl_langinfo (ALTMON_9);
 337         str = nl_langinfo (ALTMON_10);
 338         str = nl_langinfo (ALTMON_11);
 339         str = nl_langinfo (ALTMON_12);
 340 ]])], [
 341         AC_MSG_RESULT([yes])
 342         AC_DEFINE([HAVE_LANGINFO_ALTMON], [1],
 343                 [Define if langinfo.h defines ALTMON_x constants])
 344 ], [
 345         AC_MSG_RESULT([no])
 346 ])
 347
 348
 349 AC_MSG_CHECKING([whether langinfo.h defines _NL_ABALTMON_x constants])
 350 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 351         #include <langinfo.h>
 352 ]], [[
 353         char *str;
 354         str = nl_langinfo (_NL_ABALTMON_1);
 355         str = nl_langinfo (_NL_ABALTMON_2);
 356         str = nl_langinfo (_NL_ABALTMON_3);
 357         str = nl_langinfo (_NL_ABALTMON_4);
 358         str = nl_langinfo (_NL_ABALTMON_5);
 359         str = nl_langinfo (_NL_ABALTMON_6);
 360         str = nl_langinfo (_NL_ABALTMON_7);
 361         str = nl_langinfo (_NL_ABALTMON_8);
 362         str = nl_langinfo (_NL_ABALTMON_9);
 363         str = nl_langinfo (_NL_ABALTMON_10);
 364         str = nl_langinfo (_NL_ABALTMON_11);
 365         str = nl_langinfo (_NL_ABALTMON_12);
 366 ]])], [
 367         AC_MSG_RESULT([yes])
 368         AC_DEFINE([HAVE_LANGINFO_NL_ABALTMON], [1],
 369                 [Define if langinfo.h defines _NL_ABALTMON_x constants])
 370 ], [
 371         AC_MSG_RESULT([no])
 372 ])
 373
 374
 375 dnl Convert some ac_cv_header_* variables to have_*
 376 dnl
 377 have_linux_version_h=$ac_cv_header_linux_version_h
 378 have_linux_blkzoned_h=$ac_cv_header_linux_blkzoned_h
 379 have_linux_btrfs_h=$ac_cv_header_linux_btrfs_h
 380 have_linux_raw_h=$ac_cv_header_linux_raw_h
 381 have_linux_securebits_h=$ac_cv_header_linux_securebits_h
 382 have_linux_watchdog_h=$ac_cv_header_linux_watchdog_h
 383 have_security_pam_appl_h=$ac_cv_header_security_pam_appl_h
 384 have_security_pam_misc_h=$ac_cv_header_security_pam_misc_h
 385 have_security_openpam_h=$ac_cv_header_security_openpam_h
 386 have_shadow_h=$ac_cv_header_shadow_h
 387 have_sys_signalfd_h=$ac_cv_header_sys_signalfd_h
 388 have_utmpx_h=$ac_cv_header_utmpx_h
 389
 390 AS_CASE([$linux_os:$have_linux_version_h],
 391   [yes:no],
 392     [AC_MSG_ERROR([kernel headers required on Linux])]
 393 )
 394
 395 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 396 #include <time.h>
 397 #include <unistd.h>
 398 ]], [[
 399     int a = 0;
 400     struct tm *tm = localtime(0);
 401     if (a == -1)  /* false */
 402         sleep(tm->tm_gmtoff);
 403 ]])],
 404 [AC_DEFINE([HAVE_TM_GMTOFF], [1], [Does struct tm have a field tm_gmtoff?])
 405 ])
 406
 407 AC_CHECK_MEMBERS([struct termios.c_line],,,
 408     [[#include <termios.h>]])
 409
 410 AC_CHECK_MEMBERS([struct stat.st_mtim.tv_nsec],,,
 411         [#include <sys/stat.h>])
 412
 413 AC_CHECK_DECLS([_NL_TIME_WEEK_1STDAY],[],[],[[#include <langinfo.h>]])
 414
 415 AC_CHECK_DECL([llseek],
 416         [AC_DEFINE([HAVE_LLSEEK_PROTOTYPE], [1],
 417                         [Define to 1 if have llseek prototype])],
 418         [],
 419         [#include <unistd.h>])
 420
 421 AC_CHECK_DECL([lseek64],
 422         [AC_DEFINE([HAVE_LSEEK64_PROTOTYPE], [1],
 423                         [Define to 1 if have lseek64 prototype])],
 424         [],
 425         [#define _LARGEFILE_SOURCE
 426          #define _LARGEFILE64_SOURCE
 427          #include <unistd.h>])
 428
 429 AC_CHECK_DECL([environ],
 430         [AC_DEFINE([HAVE_ENVIRON_DECL], [1],
 431                 [Define to 1 if have **environ prototype])],
 432 )
 433
 434 AC_CHECK_DECL([strsignal],
 435         [AC_DEFINE([HAVE_STRSIGNAL_DECL], [1],
 436                 [Define to 1 if have strsignal function prototype])],
 437 )
 438
 439 AC_CHECK_DECL([TIOCGLCKTRMIOS],
 440               [have_tiocglcktrmios=yes], [have_tiocglcktrmios=no],
 441               [#include <sys/ioctl.h>])
 442 AC_CHECK_DECL([SOCK_CLOEXEC],
 443               [have_sock_cloexec=yes], [have_sock_cloexec=no],
 444               [#include <sys/types.h>
 445                #include <sys/socket.h>])
 446 AC_CHECK_DECL([SOCK_NONBLOCK],
 447               [have_sock_nonblock=yes], [have_sock_nonblock=no],
 448               [#include <sys/types.h>
 449                #include <sys/socket.h>])
 450 AC_CHECK_DECL([SO_PASSCRED],
 451               [have_so_passcred=yes], [have_so_passcred=no],
 452               [#include <sys/types.h>
 453                #include <sys/socket.h>])
 454
 455 AC_CHECK_FUNCS([ \
 456         __fpurge \
 457         fpurge \
 458         __fpending \
 459         secure_getenv \
 460         __secure_getenv \
 461         eaccess \
 462         err \
 463         errx \
 464         explicit_bzero \
 465         fsync \
 466         utimensat \
 467         getdomainname \
 468         getdtablesize \
 469         getexecname \
 470         getmntinfo \
 471         getrandom \
 472         getrlimit \
 473         getsgnam \
 474         inotify_init \
 475         jrand48 \
 476         lchown \
 477         llseek \
 478         lseek64 \
 479         mempcpy \
 480         mkostemp \
 481         nanosleep \
 482         ntp_gettime \
 483         personality \
 484         posix_fadvise \
 485         prctl \
 486         qsort_r \
 487         rpmatch \
 488         scandirat \
 489         setprogname \
 490         setresgid \
 491         setresuid \
 492         sched_setattr \
 493         sched_setscheduler \
 494         sigqueue \
 495         srandom \
 496         strnchr \
 497         strndup \
 498         strnlen \
 499         sysconf \
 500         sysinfo \
 501         timegm \
 502         usleep \
 503         vwarnx \
 504         warn \
 505         warnx \
 506 ])
 507 AC_FUNC_FSEEKO
 508
 509 AC_CHECK_FUNCS([openat fstatat unlinkat], [have_openat=yes], [have_openat=no])
 510 AC_CHECK_FUNCS([ioperm iopl], [have_io=yes])
 511 AC_CHECK_FUNCS([futimens], [have_futimens=yes])
 512 AC_CHECK_FUNCS([inotify_init1], [have_inotify_init1=yes])
 513 AC_CHECK_FUNCS([open_memstream], [have_open_memstream=yes],[have_open_memstream=no])
 514 AC_CHECK_FUNCS([reboot], [have_reboot=yes],[have_reboot=no])
 515 AC_CHECK_FUNCS([updwtmpx updwtmpx], [have_gnu_utmpx=yes], [have_gnu_utmpx=no])
 516 AC_CHECK_FUNCS([getusershell], [have_getusershell=yes],[have_getusershell=no])
 517
 518 AM_CONDITIONAL([HAVE_OPENAT], [test "x$have_openat" = xyes])
 519
 520
 521 AC_CHECK_FUNCS([isnan], [],
 522         [AC_CHECK_LIB([m], [isnan], [MATH_LIBS="-lm"])]
 523         [AC_CHECK_LIB([m], [__isnan], [MATH_LIBS="-lm"])]
 524 )
 525 AC_SUBST([MATH_LIBS])
 526
 527
 528 dnl lib/mononotic.c may require -lrt
 529 AC_CHECK_FUNCS([clock_gettime], [],
 530         [AC_CHECK_LIB([rt], [clock_gettime], [REALTIME_LIBS="-lrt"])]
 531 )
 532
 533 have_timer="no"
 534 AC_CHECK_FUNCS([timer_create],
 535         [have_timer="yes"],
 536         [AC_CHECK_LIB([rt], [timer_create], [
 537                 have_timer="yes"
 538                 REALTIME_LIBS="-lrt"
 539         ],[
 540                 AC_SEARCH_LIBS([timer_create], [rt], [
 541                         AC_MSG_RESULT(yes)
 542                         have_timer="yes"
 543                         REALTIME_LIBS="-lrt -lpthread"
 544                 ],[], [-lpthread]
 545                 )
 546                 ])]
 547 )
 548
 549 AC_SUBST([REALTIME_LIBS])
 550
 551
 552 AC_CHECK_LIB([rtas], [rtas_get_sysparm], [
 553         RTAS_LIBS="-lrtas"
 554         AC_DEFINE_UNQUOTED([HAVE_LIBRTAS], [1], [Define if librtas exists]), [],
 555 ])
 556 AC_SUBST([RTAS_LIBS])
 557
 558
 559 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 560                 AC_DEFINE_UNQUOTED([HAVE_SA_LEN], [1], [Define if struct sockaddr contains sa_len]), [],
 561         [#include <sys/types.h>
 562          #include <sys/socket.h>])
 563
 564 SOCKET_LIBS=
 565 AC_SEARCH_LIBS([socket], [socket],
 566         [AS_IF([test x"$ac_cv_search_socket" != x"none required"],
 567                 [SOCKET_LIBS="$SOCKET_LIBS -lsocket"])
 568 ])
 569 AC_SUBST([SOCKET_LIBS])
 570
 571
 572 have_dirfd=no
 573 AC_CHECK_FUNCS([dirfd], [have_dirfd=yes], [have_dirfd=no])
 574 AS_IF([test x"$have_dirfd" = xno], [
 575         AC_CHECK_DECLS([dirfd],
 576                 [have_dirfd=yes], [have_dirfd=no],
 577                 [#include <sys/types.h>
 578                  #include <dirent.h>])
 579 ])
 580
 581 have_ddfd=no
 582 AS_IF([test x"$have_dirfd" = xno], [
 583         AC_CHECK_MEMBERS([DIR.dd_fd],
 584                 [have_ddfd=yes], [have_ddfd=no],
 585                 [#include <sys/types.h>
 586                  #include <dirent.h>])
 587 ])
 588
 589 AS_CASE([$have_dirfd:$have_ddfd],
 590   [no:no],
 591     [AC_MSG_ERROR([cannot find a method to get filedescriptor of directory])]
 592 )
 593
 594
 595 AC_MSG_CHECKING([whether program_invocation_short_name is defined])
 596 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 597         #include <errno.h>
 598 ]], [[
 599         program_invocation_short_name = "test";
 600 ]])], [
 601         AC_MSG_RESULT([yes])
 602         AC_DEFINE([HAVE_PROGRAM_INVOCATION_SHORT_NAME], [1],
 603                 [Define if program_invocation_short_name is defined])
 604 ], [
 605         AC_MSG_RESULT([no])
 606 ])
 607
 608
 609 AC_MSG_CHECKING([whether __progname is defined])
 610 AC_LINK_IFELSE([AC_LANG_PROGRAM([extern char *__progname;],
 611            [if (*__progname == 0) return 1;])],
 612            AC_DEFINE([HAVE___PROGNAME], [1], [Define if __progname is defined])
 613            AC_MSG_RESULT([yes]),
 614            AC_MSG_RESULT([no]))
 615
 616 dnl Static compilation
 617 m4_define([UL_STATIC_PROGRAMS], [losetup, mount, umount, fdisk, sfdisk, blkid, nsenter, unshare])
 618
 619 AC_ARG_ENABLE([static-programs],
 620   [AS_HELP_STRING([--enable-static-programs=LIST],
 621       [link static the programs in LIST (comma-separated,
 622       supported for ]m4_defn([UL_STATIC_PROGRAMS])[)])])
 623
 624 AS_CASE([$enable_static_programs],
 625   [yes],
 626     [enable_static_programs=m4_quote(UL_STATIC_PROGRAMS)],
 627   [no],
 628     [enable_static_programs=]
 629 )
 630
 631 dnl Set all the individual AM_CONDITIONALs
 632 m4_foreach([UL_PRG], m4_defn([UL_STATIC_PROGRAMS]), [
 633   AS_CASE([,$enable_static_programs,],
 634    [*,UL_PRG,*], [static_[]UL_PRG=yes]
 635   )
 636   AS_IF([test "x$static_[]UL_PRG" = xyes], [AC_MSG_NOTICE([enable static build: UL_PRG.])])
 637   AM_CONDITIONAL([HAVE_STATIC_]m4_toupper(UL_PRG),
 638     [test "x$static_[]UL_PRG" = xyes])
 639 ])
 640
 641
 642 AC_ARG_ENABLE([all-programs],
 643   AS_HELP_STRING([--disable-all-programs], [disable everything, might be overridden by --enable-<name>]),
 644   [], [enable_all_programs=undefined]
 645 )
 646
 647 AS_CASE([$enable_all_programs],
 648   [yes], [AC_MSG_WARN([force to build all programs by default])
 649           ul_default_estate=check],
 650   [no],  [AC_MSG_WARN([disable all programs by default])
 651           ul_default_estate=no]
 652 )
 653
 654
 655 AX_CHECK_TLS
 656
 657 AC_DEFUN([UL_SCANF_TYPE_MODIFIER], [dnl
 658 # include <stdio.h>
 659 # include <stdlib.h>
 660 int main()
 661 {
 662         int i;
 663         int rc = 1;
 664         char *s;
 665         i = sscanf("x", $1, &s);
 666         if (i == 1  && *s == 'x')
 667                 rc = 0;
 668         free(s);
 669         return rc;
 670 }])
 671
 672 AC_CACHE_VAL([scanf_cv_alloc_modifier],
 673   AC_RUN_IFELSE([AC_LANG_SOURCE([UL_SCANF_TYPE_MODIFIER(["%ms"])])],
 674     [scanf_cv_alloc_modifier=ms],
 675     AC_RUN_IFELSE([AC_LANG_SOURCE([UL_SCANF_TYPE_MODIFIER(["%as"])])],
 676       [scanf_cv_alloc_modifier=as],
 677       [scanf_cv_alloc_modifier=no]
 678     )
 679     ,
 680
 681     [AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 682      #include <stdio.h>
 683      #include <unistd.h>
 684
 685      #if defined(__GLIBC__) && !defined(__UCLIBC__)
 686
 687      #if !(__GLIBC_PREREQ(2, 7))
 688      #error %m is not available
 689      #endif
 690
 691      #elif defined(_POSIX_VERSION)
 692
 693      #if _POSIX_VERSION < 200809L
 694      #error %m is not available
 695      #endif
 696
 697      #else
 698      #error Your C-library is not supported.
 699      #endif
 700      ])],
 701     [scanf_cv_alloc_modifier=ms],
 702     [scanf_cv_alloc_modifier=no])]
 703   )
 704 )
 705
 706 AC_MSG_CHECKING([scanf string alloc modifiers])
 707 AS_CASE([$scanf_cv_alloc_modifier],
 708   [ms],
 709     [AC_MSG_RESULT([(%ms) yes])
 710      AC_DEFINE([HAVE_SCANF_MS_MODIFIER], [1], [scanf %ms modifier])
 711      have_scanf_alloc_modifier=yes],
 712   [as],
 713     [AC_MSG_RESULT([(%as) yes])
 714      have_scanf_alloc_modifier=yes
 715      AC_DEFINE([HAVE_SCANF_AS_MODIFIER], [1], [scanf %as modifier])],
 716   [AC_MSG_RESULT([no])
 717    have_scanf_alloc_modifier=no]
 718 )
 719
 720
 721 AC_ARG_WITH([util], AS_HELP_STRING([--without-util], [compile without libutil]),
 722   [], [with_util=auto]
 723 )
 724 AS_IF([test "x$with_util" = xno], [
 725   AM_CONDITIONAL([HAVE_UTIL], [false])
 726   have_util=no
 727 ], [
 728   UL_CHECK_LIB([util], [openpty])
 729 ])
 730
 731
 732 AC_CHECK_TYPES([union semun], [], [], [[
 733 #include <sys/sem.h>
 734 ]])
 735 AC_CHECK_TYPES([loff_t])
 736
 737
 738 AC_ARG_ENABLE([widechar],
 739   AS_HELP_STRING([--disable-widechar], [do not compile wide character support]),
 740   [], [enable_widechar=check]
 741 )
 742 UL_BUILD_INIT([widechar])
 743 UL_REQUIRES_COMPILE([widechar], [[
 744   #include <wchar.h>
 745   #include <wctype.h>
 746   #include <stdio.h>
 747   ]], [[
 748     wchar_t wc;
 749     wint_t w;
 750     w = fgetwc(stdin);
 751     if (w == WEOF) exit(1);
 752     wc = w;
 753     fputwc(wc,stdout);
 754   ]],
 755   [wchar_t support])
 756
 757 AS_IF([test "x$build_widechar" = xyes ], [
 758   AC_DEFINE([HAVE_WIDECHAR], [1], [Do we have wide character support?])
 759 ])
 760
 761
 762 AC_CHECK_TYPES([cpu_set_t], [have_cpu_set_t=yes], [], [[
 763 #include <sched.h>
 764 ]])
 765
 766 AM_CONDITIONAL([HAVE_CPU_SET_T], [test "x$have_cpu_set_t" = xyes])
 767
 768 AC_CHECK_TYPES([sighandler_t], [], [], [[
 769 #include <signal.h>
 770 ]])
 771
 772 AC_CHECK_DECLS([CPU_ALLOC], [], [], [[
 773 #include <sched.h>
 774 ]])
 775
 776 # on Solaris, you can't mix and match standards, since we use c99
 777 # aparently at this stage, XOPEN_SOURCE will conflict.  As workaround,
 778 # check for crypt.h and use that without XOPEN_SOURCE.
 779 AC_CHECK_HEADERS([crypt.h])
 780 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 781 #ifdef HAVE_CRYPT_H
 782 #include <crypt.h>
 783 #else
 784 #define _XOPEN_SOURCE
 785 #include <unistd.h>
 786 #endif
 787 ]], [[
 788 char *c = crypt("abc","pw");
 789 ]])],[],[
 790   LIBS="$LIBS -lcrypt"
 791   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 792   #ifdef HAVE_CRYPT_H
 793   #include <crypt.h>
 794   #else
 795   #define _XOPEN_SOURCE
 796   #include <unistd.h>
 797   #endif
 798   ]], [[
 799   char *c = crypt("abc","pw");
 800   ]])],[
 801   AC_DEFINE([HAVE_LIBCRYPT], [1], [Do we need -lcrypt?])
 802   have_libcrypt=yes
 803   ],[
 804   AC_MSG_ERROR([crypt() is not available])
 805   ])
 806 ])
 807 AM_CONDITIONAL([HAVE_LIBCRYPT], [test "x$have_libcrypt" = xyes])
 808
 809
 810 AC_ARG_WITH([selinux],
 811   AS_HELP_STRING([--with-selinux], [compile with SELinux support]),
 812   [], [with_selinux=no]
 813 )
 814
 815 AS_IF([test "x$with_selinux" = xno], [
 816   AM_CONDITIONAL([HAVE_SELINUX], [false])
 817 ], [
 818   PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.0],
 819         [AC_DEFINE([HAVE_LIBSELINUX], [1], [Define if SELinux is available])
 820          UL_PKG_STATIC([SELINUX_LIBS_STATIC], [libselinux])
 821          AM_CONDITIONAL([HAVE_SELINUX], [true])
 822          have_selinux=yes],
 823         [have_selinux=no])
 824
 825   AS_CASE([$with_selinux:$have_selinux],
 826     [yes:no], [AC_MSG_ERROR([SELinux selected but libselinux not found or too old])]
 827   )
 828
 829   AS_IF([test "x$have_selinux" = xyes], [
 830     UL_SET_FLAGS([], [], [$SELINUX_LIBS])
 831     # This function is missing in old libselinux 1.xx versions
 832     AC_CHECK_FUNCS([security_get_initial_context])
 833     UL_RESTORE_FLAGS
 834   ])
 835 ])
 836 AC_SUBST([SELINUX_LIBS])
 837 AC_SUBST([SELINUX_LIBS_STATIC])
 838
 839
 840 AC_ARG_WITH([audit],
 841   AS_HELP_STRING([--with-audit], [compile with audit support]),
 842   [], [with_audit=no]
 843 )
 844
 845 AS_IF([test "x$with_audit" = xno], [
 846   AM_CONDITIONAL([HAVE_AUDIT], [false])
 847 ], [
 848   UL_CHECK_LIB([audit], [audit_log_user_message])
 849   AS_CASE([$with_audit:$have_audit],
 850     [yes:no],
 851       [AC_MSG_ERROR([Audit selected but libaudit not found (or does not support audit_log_user_message())])]
 852   )
 853 ])
 854
 855 AC_ARG_WITH([udev], AS_HELP_STRING([--without-udev], [compile without udev support]),
 856   [], [with_udev=auto]
 857 )
 858
 859 AS_IF([test "x$with_udev" = xno], [
 860   AM_CONDITIONAL([HAVE_UDEV], [false])
 861 ], [
 862   UL_CHECK_LIB([udev], [udev_new])
 863   AS_CASE([$with_udev:$have_udev],
 864     [yes:no],
 865       [AC_MSG_ERROR([udev selected but libudev not found])]
 866   )
 867 ])
 868
 869
 870 dnl wide-char ncurses
 871 AC_ARG_WITH([ncursesw],
 872   AS_HELP_STRING([--without-ncursesw], [do not build with wide-char ncurses]),
 873   [], [with_ncursesw=auto]
 874 )
 875 have_ncursesw=no
 876 have_ncursesw_header=no
 877 AS_IF([test "x$with_ncursesw" != xno], [
 878   UL_NCURSES_CHECK([ncursesw])
 879   AS_IF([test "x$have_ncursesw" = xyes], [
 880     AC_CHECK_HEADERS([ncursesw/ncurses.h], [have_ncursesw_header=yes])
 881     AC_CHECK_HEADERS([ncursesw/term.h])
 882
 883     # Define HAVE_NCURSES_H only if check for HAVE_NCURSESW_NCURSES_H is
 884     # unsuccessful to avoid too many *_H permitations in config.h
 885     AS_IF([test "x$have_ncursesw_header" = xno], [
 886            AC_CHECK_HEADERS([ncurses.h], [have_ncursesw_header=yes])
 887            AC_CHECK_HEADERS([term.h])
 888     ])
 889     AS_IF([test "x$have_ncursesw_header" = xno], [have_ncursesw=no])
 890   ])
 891   AS_IF([test "x$have_ncursesw" = xyes], [
 892     CURSES_LIB_NAME="ncursesw"
 893     AC_DEFINE([HAVE_LIBNCURSESW], [1], [Define if ncursesw library available])
 894   ])
 895 ])
 896 AS_CASE([$with_ncursesw:$have_ncursesw],
 897   [yes:no], [AC_MSG_ERROR([ncursesw selected, but library not found])])
 898
 899
 900 dnl non-wide ncurses
 901 AC_ARG_WITH([ncurses],
 902   AS_HELP_STRING([--with-ncurses], [build with non-wide ncurses]),
 903   [], [with_ncurses=auto]
 904 )
 905 have_ncurses=no
 906 have_ncurses_header=no
 907 AS_CASE([$with_ncurses:$build_widechar],
 908   [yes:yes], [AC_MSG_ERROR([wide-char support enabled, but non-wide ncurses selects])])
 909
 910 AS_IF([test "x$have_ncursesw" = xno -a "x$with_ncurses" != xno ], [
 911   UL_NCURSES_CHECK([ncurses])
 912   AS_IF([test "x$have_ncurses" = xyes], [
 913     AC_CHECK_HEADERS([ncurses/ncurses.h], [have_ncurses_header=yes])
 914     AC_CHECK_HEADERS([ncurses/term.h])
 915
 916     # Define HAVE_NCURSES_H only if check for HAVE_NCURSES_NCURSES_H is
 917     # unsuccessful to avoid too many *_H permitations in config.h
 918     AS_IF([test "x$have_ncurses_header" = xno], [
 919            AC_CHECK_HEADERS([ncurses.h], [have_ncurses_header=yes])
 920            AC_CHECK_HEADERS([term.h])
 921     ])
 922     AS_IF([test "x$have_ncurses_header" = xno], [have_ncurses=no])
 923   ])
 924   AS_IF([test "x$have_ncurses" = xyes], [
 925     CURSES_LIB_NAME="ncurses"
 926     AC_DEFINE([HAVE_LIBNCURSES], [1], [Define if ncurses library available])
 927   ])
 928 ])
 929 AS_CASE([$with_ncurses:$have_ncurses],
 930   [yes:no], [AC_MSG_ERROR([ncurses selected, but library not found])])
 931
 932 AC_SUBST([NCURSES_CFLAGS])
 933 AC_SUBST([NCURSES_LIBS])
 934 AM_CONDITIONAL([HAVE_NCURSES], [test "x$have_ncursesw" = xyes -o  "x$have_ncurses" = xyes])
 935
 936
 937 AC_ARG_WITH([slang],
 938   AS_HELP_STRING([--with-slang], [compile cfdisk with slang rather than ncurses]),
 939   [], [with_slang=no]
 940 )
 941 have_slang=no
 942 AS_IF([test "x$with_slang" = xyes], [
 943   AC_CHECK_HEADERS([slang.h slang/slang.h])
 944   AC_CHECK_HEADERS([slcurses.h slang/slcurses.h],
 945                    [have_slang=yes], [], [
 946 #ifdef HAVE_SLANG_H
 947 #include <slang.h>
 948 #elif defined(HAVE_SLANG_SLANG_H)
 949 #include <slang/slang.h>
 950 #endif
 951 ])
 952   AS_IF([test "x$have_slang" = xno], [
 953     AC_MSG_ERROR([slang selected but slcurses.h not found])],
 954     [CURSES_LIB_NAME=slang
 955   ])
 956 ])
 957 AM_CONDITIONAL([HAVE_SLANG], [test "x$have_slang" = xyes])
 958
 959
 960 AS_IF([test "x$have_slang" = xyes -o "x$have_ncursesw" = xyes -o "x$have_ncurses" = xyes], [
 961         AC_CHECK_LIB([$CURSES_LIB_NAME], use_default_colors, [
 962                      AC_DEFINE(HAVE_USE_DEFAULT_COLORS, 1,
 963                                [Define if curses library has the use_default_colors().])
 964         ])
 965         AC_CHECK_LIB([$CURSES_LIB_NAME], resizeterm, [
 966                      AC_DEFINE(HAVE_RESIZETERM, 1,
 967                                [Define if curses library has the resizeterm().])
 968         ])
 969 ])
 970
 971
 972 AC_ARG_WITH([tinfo], AS_HELP_STRING([--without-tinfo], [compile without libtinfo]),
 973   [], [with_tinfo=auto]
 974 )
 975 have_tinfo=no
 976 have_tinfow=no
 977 AS_IF([test "x$with_tinfo" != xno], [
 978   AS_IF([test "x$have_ncursesw" = xyes], [
 979     UL_TINFO_CHECK([tinfow])
 980   ])
 981   AS_IF([test "x$have_tinfow" = xno], [
 982     UL_TINFO_CHECK([tinfo])
 983   ])
 984 ])
 985 AC_SUBST([TINFO_LIBS])
 986 AC_SUBST([TINFO_LIBS_STATIC])
 987 AC_SUBST([TINFO_CFLAGS])
 988 AM_CONDITIONAL([HAVE_TINFO], [test "x$have_tinfo" = xyes -o "x$have_tinfow" = xyes])
 989 AS_IF([test "x$have_tinfo" = xyes -o "x$have_tinfow" = xyes], [
 990   AC_DEFINE(HAVE_LIBTINFO, 1, [Define if libtinfo or libtinfow available.])
 991 ])
 992
 993
 994 AC_ARG_WITH([readline],
 995   AS_HELP_STRING([--without-readline], [do not build with GNU Readline support]),
 996   [], [with_readline=auto]
 997 )
 998
 999 AS_IF([test "x$with_readline" = xno], [
1000   AM_CONDITIONAL([HAVE_READLINE], [false])
1001 ], [
1002   UL_CHECK_LIB([readline], [readline])
1003   AS_CASE([$with_readline:$have_readline],
1004     [yes:no],
1005       [AC_MSG_ERROR([readline selected but libreadline not found ])],
1006     [*:yes],
1007       [READLINE_LIBS="-lreadline"
1008        READLINE_LIBS_STATIC="-lreadline $TINFO_LIBS_STATIC"]
1009   )
1010 ])
1011 AC_SUBST([READLINE_LIBS])
1012 AC_SUBST([READLINE_LIBS_STATIC])
1013
1014
1015 AC_ARG_WITH([utempter],
1016   AS_HELP_STRING([--with-utempter], [compile script(1) with libutempter]),
1017   [], [with_utempter=no]
1018 )
1019
1020 AS_IF([test "x$with_utempter" = xyes], [
1021   UL_CHECK_LIB([utempter], [utempter_add_record])
1022   AS_IF([test "x$have_utempter" = xno], [
1023     AC_MSG_ERROR([utempter selected but libutempter not found])
1024   ])
1025 ], [
1026   AM_CONDITIONAL([HAVE_UTEMPTER], [false])
1027 ])
1028
1029
1030 dnl
1031 dnl libuuid
1032 dnl
1033 AC_ARG_ENABLE([libuuid],
1034   AS_HELP_STRING([--disable-libuuid], [do not build libuuid and uuid utilities]),
1035   [], [UL_DEFAULT_ENABLE([libuuid], [yes])]
1036 )
1037 UL_BUILD_INIT([libuuid])
1038 AC_SUBST([LIBUUID_VERSION])
1039 AC_SUBST([LIBUUID_VERSION_INFO])
1040 AM_CONDITIONAL(BUILD_LIBUUID, test "x$build_libuuid" = xyes)
1041
1042 AC_ARG_ENABLE([libuuid-force-uuidd],
1043   AS_HELP_STRING([--enable-libuuid-force-uuidd], [support uuidd even though the daemon is not built]),
1044   [], [enable_libuuid_force_uuidd=no]
1045 )
1046
1047 AS_IF([test "x$build_libuuid" = xyes], [
1048   AC_DEFINE(HAVE_LIBUUID, 1, [Define to 1 if you have the -luuid.])
1049 ])
1050
1051 dnl
1052 dnl libblkid
1053 dnl
1054 AC_ARG_ENABLE([libblkid],
1055   AS_HELP_STRING([--disable-libblkid], [do not build libblkid and many related utilities]),
1056   [], [UL_DEFAULT_ENABLE([libblkid], [check])]
1057 )
1058 UL_BUILD_INIT([libblkid])
1059 UL_REQUIRES_HAVE([libblkid], [openat], [openat functions])
1060 AC_SUBST([LIBBLKID_DATE])
1061 AC_SUBST([LIBBLKID_VERSION])
1062 AC_SUBST([LIBBLKID_VERSION_INFO])
1063 AC_DEFINE_UNQUOTED([LIBBLKID_VERSION], ["$LIBBLKID_VERSION"], [libblkid version string])
1064 AC_DEFINE_UNQUOTED([LIBBLKID_DATE], ["$LIBBLKID_DATE"], [libblkid date string])
1065 AS_IF([test "x$build_libblkid" = xyes], [
1066   AC_DEFINE([HAVE_LIBBLKID], [1], [Define to 1 if you have the -lblkid.])
1067 ])
1068 AM_CONDITIONAL([BUILD_LIBBLKID], [test "x$build_libblkid" = xyes])
1069 AM_CONDITIONAL([BUILD_LIBBLKID_TESTS], [test "x$build_libblkid" = xyes -a "x$enable_static" = xyes])
1070
1071 dnl
1072 dnl libmount
1073 dnl
1074 AC_ARG_ENABLE([libmount],
1075   AS_HELP_STRING([--disable-libmount], [do not build libmount]),
1076   [], [UL_DEFAULT_ENABLE([libmount], [check])]
1077 )
1078 UL_BUILD_INIT([libmount])
1079 UL_REQUIRES_BUILD([libmount], [libblkid])
1080 UL_REQUIRES_HAVE([libmount], [scanf_alloc_modifier], [scanf string alloc modifier])
1081 AM_CONDITIONAL([BUILD_LIBMOUNT], [test "x$build_libmount" = xyes])
1082 AM_CONDITIONAL([BUILD_LIBMOUNT_TESTS], [test "x$build_libmount" = xyes -a "x$enable_static" = xyes])
1083 AS_IF([test "x$build_libmount" = xyes], [
1084         AC_DEFINE(HAVE_LIBMOUNT, 1, [Define if libmount available.])
1085 ])
1086
1087 AC_SUBST([LIBMOUNT_VERSION])
1088 AC_SUBST([LIBMOUNT_MAJOR_VERSION], $PACKAGE_VERSION_MAJOR)
1089 AC_SUBST([LIBMOUNT_MINOR_VERSION], $PACKAGE_VERSION_MINOR)
1090 AC_SUBST([LIBMOUNT_PATCH_VERSION], $PACKAGE_VERSION_RELEASE)
1091 AC_SUBST([LIBMOUNT_VERSION_INFO])
1092 AC_DEFINE_UNQUOTED([LIBMOUNT_VERSION], ["$LIBMOUNT_VERSION"], [libmount version string])
1093
1094 AC_ARG_ENABLE([libmount-support-mtab],
1095   AS_HELP_STRING([--enable-libmount-support-mtab], [support /etc/mtab (default is use /proc/self/mountinfo)]),
1096   [], [enable_libmount_support_mtab=no]
1097 )
1098
1099 AS_IF([test "x$enable_libmount_support_mtab" = xyes], [
1100   AC_DEFINE([USE_LIBMOUNT_SUPPORT_MTAB], [1], [Define to 1 if want to support mtab.])
1101 ])
1102
1103
1104 dnl
1105 dnl libsmartcols
1106 dnl
1107 AC_ARG_ENABLE([libsmartcols],
1108   AS_HELP_STRING([--disable-libsmartcols], [do not build libsmartcols]),
1109   [], [UL_DEFAULT_ENABLE([libsmartcols], [yes])]
1110 )
1111 UL_BUILD_INIT([libsmartcols])
1112 AM_CONDITIONAL([BUILD_LIBSMARTCOLS], [test "x$build_libsmartcols" = xyes])
1113
1114 AC_SUBST([LIBSMARTCOLS_VERSION])
1115 AC_SUBST([LIBSMARTCOLS_VERSION_INFO])
1116 AC_DEFINE_UNQUOTED([LIBSMARTCOLS_VERSION], ["$LIBSMARTCOLS_VERSION"], [libsmartcols version string])
1117
1118
1119 dnl
1120 dnl libfdisk
1121 dnl
1122 AC_ARG_ENABLE([libfdisk],
1123   AS_HELP_STRING([--disable-libfdisk], [do not build libfdisk]),
1124   [], [UL_DEFAULT_ENABLE([libfdisk], [check])]
1125 )
1126 UL_BUILD_INIT([libfdisk])
1127 UL_REQUIRES_BUILD([libfdisk], [libuuid])
1128 AM_CONDITIONAL([BUILD_LIBFDISK], [test "x$build_libfdisk" = xyes])
1129 AM_CONDITIONAL([BUILD_LIBFDISK_TESTS], [test "x$build_libfdisk" = xyes -a "x$enable_static" = xyes])
1130
1131 AS_IF([test "x$build_libblkid" = xyes],
1132   [LIBFDISK_PC_REQUIRES="uuid blkid"],[LIBFDISK_PC_REQUIRES="uuid"])
1133 AC_SUBST([LIBFDISK_PC_REQUIRES])
1134
1135 AC_SUBST([LIBFDISK_VERSION])
1136 AC_SUBST([LIBFDISK_MAJOR_VERSION], $PACKAGE_VERSION_MAJOR)
1137 AC_SUBST([LIBFDISK_MINOR_VERSION], $PACKAGE_VERSION_MINOR)
1138 AC_SUBST([LIBFDISK_PATCH_VERSION], $PACKAGE_VERSION_RELEASE)
1139 AC_SUBST([LIBFDISK_VERSION_INFO])
1140 AC_DEFINE_UNQUOTED([LIBFDISK_VERSION], ["$LIBFDISK_VERSION"], [libfdisk version string])
1141
1142
1143 UL_BUILD_INIT([fdisk], [check])
1144 UL_REQUIRES_HAVE([fdisk], [openat], [openat functions])
1145 UL_REQUIRES_BUILD([fdisk], [libfdisk])
1146 UL_REQUIRES_BUILD([fdisk], [libsmartcols])
1147 AM_CONDITIONAL([BUILD_FDISK], [test "x$build_fdisk" = xyes])
1148
1149
1150 UL_BUILD_INIT([sfdisk], [check])
1151 UL_REQUIRES_HAVE([sfdisk], [openat], [openat functions])
1152 UL_REQUIRES_BUILD([sfdisk], [libfdisk])
1153 UL_REQUIRES_BUILD([sfdisk], [libsmartcols])
1154 AM_CONDITIONAL([BUILD_SFDISK], [test "x$build_sfdisk" = xyes])
1155
1156
1157 UL_BUILD_INIT([cfdisk], [check])
1158 UL_REQUIRES_BUILD([cfdisk], [libfdisk])
1159 UL_REQUIRES_BUILD([cfdisk], [libsmartcols])
1160 UL_REQUIRES_HAVE([cfdisk], [open_memstream], [open_memstream function])
1161 UL_REQUIRES_HAVE([cfdisk], [ncursesw,slang,ncurses], [ncursesw, ncurses or slang library])
1162 AM_CONDITIONAL([BUILD_CFDISK], [test "x$build_cfdisk" = xyes])
1163
1164
1165 AC_ARG_ENABLE([mount],
1166   AS_HELP_STRING([--disable-mount], [do not build mount(8) and umount(8)]),
1167   [], [UL_DEFAULT_ENABLE([mount], [check])]
1168 )
1169 UL_BUILD_INIT([mount])
1170 UL_REQUIRES_LINUX([mount])
1171 UL_REQUIRES_BUILD([mount], [libmount])
1172 AM_CONDITIONAL([BUILD_MOUNT], [test "x$build_mount" = xyes])
1173
1174
1175 AC_ARG_ENABLE([losetup],
1176   AS_HELP_STRING([--disable-losetup], [do not build losetup]),
1177   [], [UL_DEFAULT_ENABLE([losetup], [check])]
1178 )
1179 UL_BUILD_INIT([losetup])
1180 UL_REQUIRES_LINUX([losetup])
1181 UL_REQUIRES_BUILD([losetup], [libsmartcols])
1182 AM_CONDITIONAL([BUILD_LOSETUP], [test "x$build_losetup" = xyes])
1183
1184 AC_ARG_ENABLE([zramctl],
1185   AS_HELP_STRING([--disable-zramctl], [do not build zramctl]),
1186   [], [UL_DEFAULT_ENABLE([zramctl], [check])]
1187 )
1188 UL_BUILD_INIT([zramctl])
1189 UL_REQUIRES_LINUX([zramctl])
1190 UL_REQUIRES_BUILD([zramctl], [libsmartcols])
1191 AM_CONDITIONAL([BUILD_ZRAMCTL], [test "x$build_zramctl" = xyes])
1192
1193 AC_ARG_ENABLE([fsck],
1194   AS_HELP_STRING([--disable-fsck], [do not build fsck]),
1195   [], [UL_DEFAULT_ENABLE([fsck], [check])]
1196 )
1197 UL_BUILD_INIT([fsck])
1198 UL_REQUIRES_BUILD([fsck], [libmount])
1199 AM_CONDITIONAL([BUILD_FSCK], [test "x$build_fsck" = xyes])
1200
1201
1202 AC_ARG_ENABLE([partx],
1203   AS_HELP_STRING([--disable-partx], [do not build addpart, delpart, partx]),
1204   [], [UL_DEFAULT_ENABLE([partx], [check])]
1205 )
1206 UL_BUILD_INIT([partx])
1207 UL_REQUIRES_LINUX([partx])
1208 UL_REQUIRES_BUILD([partx], [libblkid])
1209 UL_REQUIRES_BUILD([partx], [libsmartcols])
1210 AM_CONDITIONAL([BUILD_PARTX], [test "x$build_partx" = xyes])
1211
1212
1213 AC_ARG_ENABLE([uuidd],
1214   AS_HELP_STRING([--disable-uuidd], [do not build the uuid daemon]),
1215   [], [UL_DEFAULT_ENABLE([uuidd], [check])]
1216 )
1217 UL_BUILD_INIT([uuidd])
1218 UL_REQUIRES_BUILD([uuidd], [libuuid])
1219 UL_REQUIRES_HAVE([uuidd], [timer], [timer_create function])
1220 UL_REQUIRES_HAVE([uuidd], [sys_signalfd_h], [sys/signalfd.h header])
1221 AS_IF([test "x$build_uuidd" = xyes || test "x$enable_libuuid_force_uuidd" = xyes], [
1222   AC_DEFINE([HAVE_UUIDD], [1], [Define to 1 if you want to use uuid daemon.])
1223 ])
1224 AM_CONDITIONAL([BUILD_UUIDD], [test "x$build_uuidd" = xyes])
1225
1226
1227 UL_BUILD_INIT([uuidgen], [check])
1228 UL_REQUIRES_BUILD([uuidgen], [libuuid])
1229 AM_CONDITIONAL([BUILD_UUIDGEN], [test "x$build_uuidgen" = xyes])
1230
1231 UL_BUILD_INIT([uuidparse], [check])
1232 UL_REQUIRES_BUILD([uuidparse], [libuuid])
1233 UL_REQUIRES_BUILD([uuidparse], [libsmartcols])
1234 AM_CONDITIONAL([BUILD_UUIDPARSE], [test "x$build_uuidparse" = xyes])
1235
1236 UL_BUILD_INIT([blkid], [check])
1237 UL_REQUIRES_BUILD([blkid], [libblkid])
1238 AM_CONDITIONAL([BUILD_BLKID], [test "x$build_blkid" = xyes])
1239
1240 UL_BUILD_INIT([findfs], [check])
1241 UL_REQUIRES_BUILD([findfs], [libblkid])
1242 AM_CONDITIONAL([BUILD_FINDFS], [test "x$build_findfs" = xyes])
1243
1244 UL_BUILD_INIT([wipefs], [check])
1245 UL_REQUIRES_BUILD([wipefs], [libblkid])
1246 UL_REQUIRES_BUILD([wipefs], [libsmartcols])
1247 AM_CONDITIONAL([BUILD_WIPEFS], [test "x$build_wipefs" = xyes])
1248
1249 UL_BUILD_INIT([findmnt], [check])
1250 UL_REQUIRES_BUILD([findmnt], [libmount])
1251 UL_REQUIRES_BUILD([findmnt], [libblkid])
1252 UL_REQUIRES_BUILD([findmnt], [libsmartcols])
1253 AM_CONDITIONAL([BUILD_FINDMNT], [test "x$build_findmnt" = xyes])
1254
1255
1256 AC_ARG_ENABLE([mountpoint],
1257   AS_HELP_STRING([--disable-mountpoint], [do not build mountpoint]),
1258   [], [UL_DEFAULT_ENABLE([mountpoint], [check])]
1259 )
1260 UL_BUILD_INIT([mountpoint])
1261 UL_REQUIRES_BUILD([mountpoint], [libmount])
1262 AM_CONDITIONAL([BUILD_MOUNTPOINT], [test "x$build_mountpoint" = xyes])
1263
1264
1265 AC_ARG_ENABLE([fallocate],
1266   AS_HELP_STRING([--disable-fallocate], [do not build fallocate]),
1267   [], [UL_DEFAULT_ENABLE([fallocate], [check])]
1268 )
1269 UL_BUILD_INIT([fallocate])
1270 UL_REQUIRES_LINUX([fallocate])
1271 UL_REQUIRES_SYSCALL_CHECK([fallocate], [UL_CHECK_SYSCALL([fallocate])])
1272 AM_CONDITIONAL([BUILD_FALLOCATE], [test "x$build_fallocate" = xyes])
1273
1274 AS_IF([test "x$build_fallocate" = xyes], [
1275   dnl check for valid fallocate() function
1276   dnl with 32 bits glibc 2.10, fallocate() exists but not fallocate64()
1277   dnl when _FILE_OFFSET_BITS==64, fallocate() is redirect to fallocate64()
1278   dnl and program can't be linked.
1279   dnl AC_CHECK_FUNC can't catch such errors since it's redefining
1280   dnl function prototype.
1281   AC_MSG_CHECKING([for valid fallocate() function])
1282   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1283 #ifdef HAVE_UNISTD_H
1284 # include <unistd.h>
1285 #endif
1286 #ifdef HAVE_SYS_TYPES_H
1287 # include <sys/types.h>
1288 #endif
1289 #ifdef HAVE_LINUX_FALLOC_H
1290 # include <linux/falloc.h>
1291 #endif
1292 #ifdef HAVE_FCNTL_H
1293 # include <fcntl.h>
1294 #endif
1295 ]],[[
1296    long ret;
1297    ret = fallocate(0, FALLOC_FL_KEEP_SIZE, 0xfffffffful, 0xfffffffful);
1298    if (ret != 0) {
1299       return 1;
1300    }
1301    ]])],[
1302   AC_MSG_RESULT([yes])
1303   AC_DEFINE([HAVE_FALLOCATE], [1], [Have valid fallocate() function])],[
1304   AC_MSG_RESULT([no])])
1305 ])
1306
1307 AS_IF([test "x$build_fallocate" = xyes], [
1308   dnl check for valid posix_fallocate() function
1309   AC_MSG_CHECKING([for valid posix_fallocate() function])
1310   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1311 #ifdef HAVE_UNISTD_H
1312 # include <unistd.h>
1313 #endif
1314 #ifdef HAVE_SYS_TYPES_H
1315 # include <sys/types.h>
1316 #endif
1317 #ifdef HAVE_LINUX_FALLOC_H
1318 # include <linux/falloc.h>
1319 #endif
1320 #ifdef HAVE_FCNTL_H
1321 # include <fcntl.h>
1322 #endif
1323 ]],[[
1324    long ret;
1325    ret = posix_fallocate(0, 0xfffffffful, 0xfffffffful);
1326    if (ret != 0) {
1327       return 1;
1328    }
1329    ]])],[
1330   AC_MSG_RESULT([yes])
1331   AC_DEFINE([HAVE_POSIX_FALLOCATE], [1], [Have valid posix_fallocate() function])],[
1332   AC_MSG_RESULT([no])])
1333 ])
1334
1335
1336 AC_ARG_ENABLE([unshare],
1337   AS_HELP_STRING([--disable-unshare], [do not build unshare]),
1338   [], [UL_DEFAULT_ENABLE([unshare], [check])]
1339 )
1340 UL_BUILD_INIT([unshare])
1341 UL_REQUIRES_LINUX([unshare])
1342 UL_REQUIRES_SYSCALL_CHECK([unshare], [UL_CHECK_SYSCALL([unshare])])
1343 AM_CONDITIONAL([BUILD_UNSHARE], [test "x$build_unshare" = xyes])
1344 AC_CHECK_FUNCS([unshare])
1345
1346 AC_ARG_ENABLE([nsenter],
1347   AS_HELP_STRING([--disable-nsenter], [do not build nsenter]),
1348   [], [UL_DEFAULT_ENABLE([nsenter], [check])]
1349 )
1350 UL_BUILD_INIT([nsenter])
1351 UL_REQUIRES_LINUX([nsenter])
1352 UL_REQUIRES_SYSCALL_CHECK([nsenter], [UL_CHECK_SYSCALL([setns])], [setns])
1353 AM_CONDITIONAL([BUILD_NSENTER], [test "x$build_nsenter" = xyes])
1354 AC_CHECK_FUNCS([setns])
1355
1356
1357 AC_ARG_WITH([cap_ng],
1358   AS_HELP_STRING([--without-cap-ng], [compile without libcap-ng]),
1359   [], [with_cap_ng=auto]
1360 )
1361 AS_IF([test "x$with_cap_ng" = xno], [
1362   AM_CONDITIONAL([HAVE_CAP_NG], [false])
1363   have_cap_ng=no
1364 ],[
1365   UL_CHECK_LIB([cap-ng], [capng_apply], [cap_ng])
1366 ])
1367
1368
1369 AC_ARG_ENABLE([setpriv],
1370   AS_HELP_STRING([--disable-setpriv], [do not build setpriv]),
1371   [], [UL_DEFAULT_ENABLE([setpriv], [check])]
1372 )
1373 UL_BUILD_INIT([setpriv])
1374 UL_REQUIRES_LINUX([setpriv])
1375 UL_REQUIRES_HAVE([setpriv], [linux_securebits_h], [securebits.h header file])
1376 UL_REQUIRES_HAVE([setpriv], [cap_ng], [libcap-ng library])
1377 AM_CONDITIONAL([BUILD_SETPRIV], [test "x$build_setpriv" = xyes])
1378
1379
1380 AC_ARG_ENABLE([eject],
1381   AS_HELP_STRING([--disable-eject], [do not build eject]),
1382   [], [UL_DEFAULT_ENABLE([eject], [check])]
1383 )
1384 UL_BUILD_INIT([eject])
1385 UL_REQUIRES_LINUX([eject])
1386 UL_REQUIRES_BUILD([eject], [libmount])
1387 AM_CONDITIONAL([BUILD_EJECT], [test "x$build_eject" = xyes])
1388
1389
1390 AC_ARG_ENABLE([agetty],
1391   AS_HELP_STRING([--disable-agetty], [do not build agetty]),
1392   [], [UL_DEFAULT_ENABLE([agetty], [check])]
1393 )
1394 UL_BUILD_INIT([agetty])
1395 UL_REQUIRES_HAVE([agetty], [utmpx_h], [utmpx.h header])
1396 UL_REQUIRES_HAVE([agetty], [gnu_utmpx], [GNU utmpx functions])
1397 AM_CONDITIONAL([BUILD_AGETTY], [test "x$build_agetty" = xyes])
1398 AS_IF([test "x$have_futimens" = xyes -a "x$have_inotify_init1" = xyes ], [
1399   AC_DEFINE([AGETTY_RELOAD], [1], [Enable agetty --reload feature])
1400 ],[
1401   AC_MSG_WARN([futimens or inotify_init1 not found; agetty(8) will not provide ---reload functionality])
1402 ])
1403
1404
1405 AC_ARG_ENABLE([plymouth_support],
1406   AS_HELP_STRING([--disable-plymouth_support], [don not care about plymouth in sylogin(8) and agetty(8)]),
1407   [], [enable_plymouth_support=check]
1408 )
1409 UL_BUILD_INIT([plymouth_support])
1410 UL_REQUIRES_HAVE([plymouth_support], [tiocglcktrmios], [TIOCGLCKTRMIOS flag])
1411 UL_REQUIRES_HAVE([plymouth_support], [sock_cloexec], [SOCK_CLOEXEC flag])
1412 UL_REQUIRES_HAVE([plymouth_support], [sock_nonblock], [SOCK_NONBLOCK flag])
1413 UL_REQUIRES_HAVE([plymouth_support], [so_passcred], [SO_PASSCRED flag])
1414 AM_CONDITIONAL([USE_PLYMOUTH_SUPPORT], [test "x$build_plymouth_support" = xyes])
1415 AS_IF([test "x$build_plymouth_support" = xyes ], [
1416     AC_DEFINE([USE_PLYMOUTH_SUPPORT], [1], [Enable plymouth support feature for sulogin and aggety])
1417 ])
1418
1419
1420 AC_ARG_WITH([libz],
1421   AS_HELP_STRING([--without-libz], [compile without libz]),
1422   [], [with_libz=auto]
1423 )
1424 AS_IF([test "x$with_libz" = xno], [have_z=no], [
1425   AC_CHECK_LIB([z], [crc32], [have_z=yes], [have_z=no])
1426 ])
1427
1428
1429 AC_ARG_ENABLE([cramfs],
1430   AS_HELP_STRING([--disable-cramfs], [do not build fsck.cramfs, mkfs.cramfs]),
1431   [], [UL_DEFAULT_ENABLE([cramfs], [check])]
1432 )
1433 UL_BUILD_INIT([cramfs])
1434 UL_REQUIRES_HAVE([cramfs], [z], [z library])
1435 AM_CONDITIONAL([BUILD_CRAMFS], [test "x$build_cramfs" = xyes])
1436
1437
1438 AC_ARG_ENABLE([bfs],
1439   AS_HELP_STRING([--disable-bfs], [do not build mkfs.bfs]),
1440   [], [UL_DEFAULT_ENABLE([bfs], [yes])]
1441 )
1442 UL_BUILD_INIT([bfs])
1443 AM_CONDITIONAL([BUILD_BFS], [test "x$build_bfs" = xyes])
1444
1445
1446 AC_ARG_ENABLE([minix],
1447   AS_HELP_STRING([--disable-minix], [do not build fsck.minix, mkfs.minix]),
1448   [], [UL_DEFAULT_ENABLE([minix], [yes])]
1449 )
1450 UL_BUILD_INIT([minix])
1451 AM_CONDITIONAL([BUILD_MINIX], [test "x$build_minix" = xyes])
1452
1453
1454 AC_ARG_ENABLE([fdformat],
1455   AS_HELP_STRING([--disable-fdformat], [do not build fdformat]),
1456   [], [UL_DEFAULT_ENABLE([fdformat], [check])]
1457 )
1458 UL_BUILD_INIT([fdformat])
1459 UL_REQUIRES_LINUX([fdformat])
1460 AM_CONDITIONAL([BUILD_FDFORMAT], [test "x$build_fdformat" = xyes])
1461
1462
1463 AC_ARG_ENABLE([hwclock],
1464   AS_HELP_STRING([--disable-hwclock], [do not build hwclock]),
1465   [], [UL_DEFAULT_ENABLE([hwclock], [check])]
1466 )
1467 have_linuxdummy=$linux_os
1468
1469 UL_BUILD_INIT([hwclock])
1470 UL_REQUIRES_HAVE([hwclock], [io, linuxdummy], [ioperm iopl function or Linux])
1471 AM_CONDITIONAL([BUILD_HWCLOCK], [test "x$build_hwclock" = xyes])
1472
1473
1474 UL_BUILD_INIT([mkfs], [yes])
1475 AM_CONDITIONAL([BUILD_MKFS], [test "x$build_mkfs" = xyes])
1476
1477 UL_BUILD_INIT([isosize], [yes])
1478 AM_CONDITIONAL([BUILD_ISOSIZE], [test "x$build_isosize" = xyes])
1479
1480
1481 UL_BUILD_INIT([fstrim], [check])
1482 UL_REQUIRES_LINUX([fstrim])
1483 UL_REQUIRES_BUILD([fstrim], [libmount])
1484 AM_CONDITIONAL([BUILD_FSTRIM], [test "x$build_fstrim" = xyes])
1485
1486
1487 UL_BUILD_INIT([swapon], [check])
1488 UL_REQUIRES_LINUX([swapon])
1489 UL_REQUIRES_SYSCALL_CHECK([swapon], [UL_CHECK_SYSCALL([swapon])], [swapon])
1490 UL_REQUIRES_SYSCALL_CHECK([swapon], [UL_CHECK_SYSCALL([swapoff])], [swapoff])
1491 UL_REQUIRES_BUILD([swapon], [libblkid])
1492 UL_REQUIRES_BUILD([swapon], [libmount])
1493 UL_REQUIRES_BUILD([swapon], [libsmartcols])
1494 AM_CONDITIONAL([BUILD_SWAPON], [test "x$build_swapon" = xyes])
1495 AC_CHECK_FUNCS([swapon])
1496 AC_CHECK_FUNCS([swapoff])
1497
1498
1499 UL_BUILD_INIT([lsblk], [check])
1500 UL_REQUIRES_LINUX([lsblk])
1501 UL_REQUIRES_BUILD([lsblk], [libblkid])
1502 UL_REQUIRES_BUILD([lsblk], [libmount])
1503 UL_REQUIRES_BUILD([lsblk], [libsmartcols])
1504 AM_CONDITIONAL([BUILD_LSBLK], [test "x$build_lsblk" = xyes])
1505
1506
1507 UL_BUILD_INIT([lscpu], [check])
1508 UL_REQUIRES_LINUX([lscpu])
1509 UL_REQUIRES_BUILD([lscpu], [libsmartcols])
1510 UL_REQUIRES_HAVE([lscpu], [cpu_set_t], [cpu_set_t type])
1511 AM_CONDITIONAL([BUILD_LSCPU], [test "x$build_lscpu" = xyes])
1512
1513
1514 AC_ARG_ENABLE([lslogins],
1515   AS_HELP_STRING([--disable-lslogins], [do not build lslogins]),
1516   [], [UL_DEFAULT_ENABLE([lslogins], [check])]
1517 )
1518 UL_BUILD_INIT([lslogins])
1519 UL_REQUIRES_BUILD([lslogins], [libsmartcols])
1520 UL_REQUIRES_HAVE([lslogins], [shadow_h], [shadow.h header])
1521 UL_REQUIRES_HAVE([lslogins], [utmpx_h], [utmpx.h header])
1522 UL_REQUIRES_HAVE([lslogins], [gnu_utmpx], [GNU utmpx functions])
1523 AM_CONDITIONAL([BUILD_LSLOGINS], [test "x$build_lslogins" = xyes])
1524
1525
1526 UL_BUILD_INIT([chcpu], [check])
1527 UL_REQUIRES_LINUX([chcpu])
1528 UL_REQUIRES_HAVE([chcpu], [cpu_set_t], [cpu_set_t type])
1529 AM_CONDITIONAL([BUILD_CHCPU], [test "x$build_chcpu" = xyes])
1530
1531
1532 AC_ARG_ENABLE([wdctl],
1533   AS_HELP_STRING([--disable-wdctl], [do not build wdctl]),
1534   [], [UL_DEFAULT_ENABLE([wdctl], [check])]
1535 )
1536 UL_BUILD_INIT([wdctl])
1537 UL_REQUIRES_LINUX([wdctl])
1538 UL_REQUIRES_BUILD([wdctl], [libsmartcols])
1539 UL_REQUIRES_HAVE([wdctl], [linux_watchdog_h], [linux/watchdog.h header file])
1540 AM_CONDITIONAL([BUILD_WDCTL], [test "x$build_wdctl" = xyes])
1541
1542
1543 UL_BUILD_INIT([swaplabel], [check])
1544 UL_REQUIRES_BUILD([swaplabel], [libblkid])
1545 AM_CONDITIONAL([BUILD_SWAPLABEL], [test "x$build_swaplabel" = xyes])
1546
1547
1548 UL_BUILD_INIT([mkswap], [yes])
1549 AM_CONDITIONAL([BUILD_MKSWAP], [test "x$build_mkswap" = xyes])
1550 AS_IF([test "x$build_mkswap" = xyes -a "x$build_libuuid" != xyes], [
1551   AC_MSG_WARN([uuid library is not found; mkswap(8) will not generate UUIDs])
1552 ])
1553
1554
1555 AC_ARG_ENABLE([cal],
1556   AS_HELP_STRING([--disable-cal], [do not build cal]),
1557   [], [UL_DEFAULT_ENABLE([cal], [check])]
1558 )
1559 UL_BUILD_INIT([cal])
1560 AM_CONDITIONAL([BUILD_CAL], [test "x$build_cal" = xyes])
1561
1562 AC_ARG_ENABLE([logger],
1563   AS_HELP_STRING([--disable-logger], [do not build logger]),
1564   [], [UL_DEFAULT_ENABLE([logger], [check])]
1565 )
1566 UL_BUILD_INIT([logger])
1567 AM_CONDITIONAL([BUILD_LOGGER], [test "x$build_logger" = xyes])
1568
1569 UL_BUILD_INIT([look], [yes])
1570 AM_CONDITIONAL([BUILD_LOOK], [test "x$build_look" = xyes])
1571
1572 UL_BUILD_INIT([mcookie], [yes])
1573 AM_CONDITIONAL([BUILD_MCOOKIE], [test "x$build_mcookie" = xyes])
1574
1575 UL_BUILD_INIT([namei], [yes])
1576 AM_CONDITIONAL([BUILD_NAMEI], [test "x$build_namei" = xyes])
1577
1578 matriplet="$($CC -print-multiarch 2>/dev/null || true)"
1579 if test "x$matriplet" != "x"; then
1580   AC_DEFINE_UNQUOTED([MULTIARCHTRIPLET], ["$matriplet"],
1581   ["Multi-arch triplet for whereis library search path"])
1582 fi
1583 UL_BUILD_INIT([whereis], [yes])
1584 AM_CONDITIONAL([BUILD_WHEREIS], [test "x$build_whereis" = xyes])
1585
1586 UL_BUILD_INIT([getopt], [yes])
1587 AM_CONDITIONAL([BUILD_GETOPT], [test "x$build_getopt" = xyes])
1588
1589
1590 UL_BUILD_INIT([blockdev], [check])
1591 UL_REQUIRES_LINUX([blockdev])
1592 AM_CONDITIONAL([BUILD_BLOCKDEV], [test "x$build_blockdev" = xyes])
1593
1594
1595 UL_BUILD_INIT([prlimit], [check])
1596 UL_REQUIRES_LINUX([prlimit])
1597 UL_REQUIRES_BUILD([prlimit], [libsmartcols])
1598 UL_REQUIRES_SYSCALL_CHECK([prlimit], [UL_CHECK_SYSCALL([prlimit64])], [prlimit64])
1599 AM_CONDITIONAL([BUILD_PRLIMIT], [test "x$build_prlimit" = xyes])
1600 AS_IF([test "x$build_prlimit" = xyes], [
1601   AC_CHECK_FUNCS([prlimit])
1602 ])
1603
1604
1605 UL_BUILD_INIT([lslocks], [check])
1606 UL_REQUIRES_LINUX([lslocks])
1607 UL_REQUIRES_BUILD([lslocks], [libmount])
1608 UL_REQUIRES_BUILD([lslocks], [libsmartcols])
1609 AM_CONDITIONAL([BUILD_LSLOCKS], [test "x$build_lslocks" = xyes])
1610
1611
1612 AC_ARG_ENABLE([switch_root],
1613   AS_HELP_STRING([--disable-switch_root], [do not build switch_root]),
1614   [], [UL_DEFAULT_ENABLE([switch_root], [check])]
1615 )
1616 UL_BUILD_INIT([switch_root])
1617 UL_REQUIRES_LINUX([switch_root])
1618 UL_REQUIRES_HAVE([switch_root], [openat], [openat function])
1619 AM_CONDITIONAL([BUILD_SWITCH_ROOT], [test "x$build_switch_root" = xyes])
1620
1621
1622 AC_ARG_ENABLE([pivot_root],
1623   AS_HELP_STRING([--disable-pivot_root], [do not build pivot_root]),
1624   [], [UL_DEFAULT_ENABLE([pivot_root], [check])]
1625 )
1626 UL_BUILD_INIT([pivot_root])
1627 UL_REQUIRES_LINUX([pivot_root])
1628 UL_REQUIRES_SYSCALL_CHECK([pivot_root], [UL_CHECK_SYSCALL([pivot_root])])
1629 AM_CONDITIONAL([BUILD_PIVOT_ROOT], [test "x$build_pivot_root" = xyes])
1630
1631
1632 UL_BUILD_INIT([flock], [check])
1633 UL_REQUIRES_HAVE([flock], [timer], [timer_create function])
1634 AM_CONDITIONAL([BUILD_FLOCK], [test "x$build_flock" = xyes])
1635
1636
1637 AC_ARG_ENABLE([lsmem],
1638   AS_HELP_STRING([--disable-lsmem], [do not build lsmem]),
1639   [], [UL_DEFAULT_ENABLE([lsmem], [check])]
1640 )
1641 UL_BUILD_INIT([lsmem])
1642 UL_REQUIRES_LINUX([lsmem])
1643 UL_REQUIRES_BUILD([lsmem], [libsmartcols])
1644 AM_CONDITIONAL([BUILD_LSMEM], [test "x$build_lsmem" = xyes])
1645
1646
1647 AC_ARG_ENABLE([chmem],
1648   AS_HELP_STRING([--disable-chmem], [do not build chmem]),
1649   [], [UL_DEFAULT_ENABLE([chmem], [check])]
1650 )
1651 UL_BUILD_INIT([chmem])
1652 UL_REQUIRES_LINUX([chmem])
1653 AM_CONDITIONAL([BUILD_CHMEM], [test "x$build_chmem" = xyes])
1654
1655 UL_BUILD_INIT([ipcmk], [yes])
1656 AM_CONDITIONAL([BUILD_IPCMK], [test "x$build_ipcmk" = xyes])
1657
1658
1659 AC_ARG_ENABLE([ipcrm],
1660   AS_HELP_STRING([--disable-ipcrm], [do not build ipcrm]),
1661   [], [UL_DEFAULT_ENABLE([ipcrm], [yes])]
1662 )
1663 UL_BUILD_INIT([ipcrm])
1664 AM_CONDITIONAL([BUILD_IPCRM], [test "x$build_ipcrm" = xyes])
1665
1666 AC_ARG_ENABLE([ipcs],
1667   AS_HELP_STRING([--disable-ipcs], [do not build ipcs]),
1668   [], [UL_DEFAULT_ENABLE([ipcs], [yes])]
1669 )
1670 UL_BUILD_INIT([ipcs])
1671 AM_CONDITIONAL([BUILD_IPCS], [test "x$build_ipcs" = xyes])
1672
1673 UL_BUILD_INIT([choom], [check])
1674 UL_REQUIRES_LINUX([choom])
1675 AM_CONDITIONAL([BUILD_CHOOM], [test "x$build_choom" = xyes])
1676
1677 UL_BUILD_INIT([lsipc], [check])
1678 UL_REQUIRES_LINUX([lsipc])
1679 UL_REQUIRES_BUILD([lsipc], [libsmartcols])
1680 AM_CONDITIONAL([BUILD_LSIPC], [test "x$build_lsipc" = xyes])
1681
1682 UL_BUILD_INIT([lsns], [check])
1683 UL_REQUIRES_LINUX([lsns])
1684 UL_REQUIRES_BUILD([lsns], [libsmartcols])
1685 UL_REQUIRES_BUILD([lsns], [libmount])
1686 AM_CONDITIONAL([BUILD_LSNS], [test "x$build_lsns" = xyes])
1687
1688 UL_BUILD_INIT([renice], [yes])
1689 AM_CONDITIONAL([BUILD_RENICE], [test "x$build_renice" = xyes])
1690
1691
1692 AC_ARG_ENABLE([rfkill],
1693   AS_HELP_STRING([--disable-rfkill], [do not build rfkill]),
1694   [], [UL_DEFAULT_ENABLE([rfkill], [check])]
1695 )
1696 UL_BUILD_INIT([rfkill])
1697 UL_REQUIRES_LINUX([rfkill])
1698 UL_REQUIRES_BUILD([rfkill], [libsmartcols])
1699 AM_CONDITIONAL([BUILD_RFKILL], [test "x$build_rfkill" = xyes])
1700
1701
1702 UL_BUILD_INIT([setsid], [yes])
1703 AM_CONDITIONAL([BUILD_SETSID], [test "x$build_setsid" = xyes])
1704
1705 UL_BUILD_INIT([readprofile], [check])
1706 UL_REQUIRES_LINUX([readprofile])
1707 AM_CONDITIONAL([BUILD_READPROFILE], [test "x$build_readprofile" = xyes])
1708
1709 UL_BUILD_INIT([dmesg], [check])
1710 UL_REQUIRES_LINUX([dmesg])
1711 AM_CONDITIONAL([BUILD_DMESG], [test "x$build_dmesg" = xyes])
1712
1713 UL_BUILD_INIT([ctrlaltdel], [check])
1714 UL_REQUIRES_LINUX([ctrlaltdel])
1715 dnl we assume reboot() to be the 1-argument variant, because even considering
1716 dnl widely used alternative C libraries like uclibc, dietlibc and musl,
1717 dnl reboot() with multiple arguments is yet only found in glibc versions
1718 dnl earlier than 2.x.
1719 UL_REQUIRES_HAVE([ctrlaltdel], [reboot], [reboot function])
1720 AM_CONDITIONAL([BUILD_CTRLALTDEL], [test "x$build_ctrlaltdel" = xyes])
1721
1722 UL_BUILD_INIT([fincore], [check])
1723 UL_REQUIRES_LINUX([fincore])
1724 UL_REQUIRES_BUILD([fincore], [libsmartcols])
1725 AM_CONDITIONAL([BUILD_FINCORE], [test "x$build_fincore" = xyes])
1726
1727 UL_BUILD_INIT([fsfreeze], [check])
1728 UL_REQUIRES_LINUX([fsfreeze])
1729 AM_CONDITIONAL([BUILD_FSFREEZE], [test "x$build_fsfreeze" = xyes])
1730
1731 UL_BUILD_INIT([blkdiscard], [check])
1732 UL_REQUIRES_LINUX([blkdiscard])
1733 AM_CONDITIONAL([BUILD_BLKDISCARD], [test "x$build_blkdiscard" = xyes])
1734
1735 UL_BUILD_INIT([blkzone], [check])
1736 UL_REQUIRES_LINUX([blkzone])
1737 UL_REQUIRES_HAVE([blkzone], [linux_blkzoned_h], [linux/blkzoned.h header])
1738 AM_CONDITIONAL([BUILD_BLKZONE], [test "x$build_blkzone" = xyes])
1739
1740 UL_BUILD_INIT([ldattach], [check])
1741 UL_REQUIRES_LINUX([ldattach])
1742 AM_CONDITIONAL([BUILD_LDATTACH], [test "x$build_ldattach" = xyes])
1743
1744 UL_BUILD_INIT([rtcwake], [check])
1745 UL_REQUIRES_LINUX([rtcwake])
1746 AM_CONDITIONAL([BUILD_RTCWAKE], [test "x$build_rtcwake" = xyes])
1747
1748 UL_BUILD_INIT([setarch], [check])
1749 UL_REQUIRES_LINUX([setarch])
1750 AM_CONDITIONAL([BUILD_SETARCH], [test "x$build_setarch" = xyes])
1751
1752 UL_BUILD_INIT([script], [check])
1753 UL_REQUIRES_HAVE([script], [sys_signalfd_h], [sys/signalfd.h header])
1754 AM_CONDITIONAL([BUILD_SCRIPT], [test "x$build_script" = xyes])
1755
1756 UL_BUILD_INIT([scriptreplay], [yes])
1757 AM_CONDITIONAL([BUILD_SCRIPTREPLAY], [test "x$build_scriptreplay" = xyes])
1758
1759 UL_BUILD_INIT([col], [yes])
1760 AM_CONDITIONAL([BUILD_COL], [test "x$build_col" = xyes])
1761
1762 UL_BUILD_INIT([colcrt], [yes])
1763 AM_CONDITIONAL([BUILD_COLCRT], [test "x$build_colcrt" = xyes])
1764
1765 UL_BUILD_INIT([colrm], [yes])
1766 AM_CONDITIONAL([BUILD_COLRM], [test "x$build_colrm" = xyes])
1767
1768 UL_BUILD_INIT([column], [check])
1769 UL_REQUIRES_BUILD([column], [libsmartcols])
1770 AM_CONDITIONAL([BUILD_COLUMN], [test "x$build_column" = xyes])
1771
1772 UL_BUILD_INIT([hexdump], [yes])
1773 AM_CONDITIONAL([BUILD_HEXDUMP], [test "x$build_hexdump" = xyes])
1774
1775 UL_BUILD_INIT([rev], [yes])
1776 AM_CONDITIONAL([BUILD_REV], [test "x$build_rev" = xyes])
1777
1778
1779 AC_ARG_ENABLE([tunelp],
1780   AS_HELP_STRING([--enable-tunelp], [build tunelp]),
1781   [], [UL_DEFAULT_ENABLE([tunelp], [no])]
1782 )
1783 UL_BUILD_INIT([tunelp])
1784 UL_REQUIRES_LINUX([tunelp])
1785 AM_CONDITIONAL([BUILD_TUNELP], [test "x$build_tunelp" = xyes])
1786
1787
1788 AC_ARG_ENABLE([kill],
1789   AS_HELP_STRING([--disable-kill], [do not build kill]),
1790   [], [UL_DEFAULT_ENABLE([kill], [check])]
1791 )
1792 UL_BUILD_INIT([kill])
1793 UL_REQUIRES_LINUX([kill])
1794 AM_CONDITIONAL([BUILD_KILL], [test "x$build_kill" = xyes])
1795
1796
1797 AC_ARG_ENABLE([last],
1798   AS_HELP_STRING([--disable-last], [do not build last]),
1799   [], [UL_DEFAULT_ENABLE([last], [check])]
1800 )
1801 UL_BUILD_INIT([last])
1802 UL_REQUIRES_HAVE([last], [utmpx_h], [utmpx.h header])
1803 UL_REQUIRES_HAVE([last], [gnu_utmpx], [GNU utmpx functions])
1804 AM_CONDITIONAL([BUILD_LAST], [test "x$build_last" = xyes])
1805
1806
1807 AC_ARG_ENABLE([utmpdump],
1808   AS_HELP_STRING([--disable-utmpdump], [do not build utmpdump]),
1809   [], [UL_DEFAULT_ENABLE([utmpdump], [check])]
1810 )
1811 UL_BUILD_INIT([utmpdump])
1812 UL_REQUIRES_HAVE([utmpdump], [utmpx_h], [utmpx.h header])
1813 UL_REQUIRES_HAVE([utmpdump], [gnu_utmpx], [GNU utmpx functions])
1814 AM_CONDITIONAL([BUILD_UTMPDUMP], [test "x$build_utmpdump" = xyes])
1815
1816
1817 AC_ARG_ENABLE([line],
1818   AS_HELP_STRING([--enable-line], [build line]),
1819   [], [UL_DEFAULT_ENABLE([line], [no])]
1820 )
1821 UL_BUILD_INIT([line])
1822 AM_CONDITIONAL([BUILD_LINE], [test "x$build_line" = xyes])
1823
1824
1825 AC_ARG_ENABLE([mesg],
1826   AS_HELP_STRING([--disable-mesg], [do not build mesg]),
1827   [], [UL_DEFAULT_ENABLE([mesg], [yes])]
1828 )
1829 UL_BUILD_INIT([mesg])
1830 AM_CONDITIONAL([BUILD_MESG], [test "x$build_mesg" = xyes])
1831
1832
1833 AC_ARG_ENABLE([raw],
1834   AS_HELP_STRING([--disable-raw], [do not build raw]),
1835   [], [UL_DEFAULT_ENABLE([raw], [check])]
1836 )
1837 UL_BUILD_INIT([raw])
1838 UL_REQUIRES_LINUX([raw])
1839 UL_REQUIRES_HAVE([raw], [linux_raw_h], [raw.h header file])
1840 AM_CONDITIONAL([BUILD_RAW], [test "x$build_raw" = xyes])
1841
1842
1843 AC_ARG_ENABLE([rename],
1844   AS_HELP_STRING([--disable-rename], [do not build rename]),
1845   [], [UL_DEFAULT_ENABLE([rename], [yes])]
1846 )
1847 UL_BUILD_INIT([rename])
1848 AM_CONDITIONAL([BUILD_RENAME], [test "x$build_rename" = xyes])
1849
1850
1851 AC_ARG_ENABLE([vipw],
1852   AS_HELP_STRING([--enable-vipw], [build vipw]),
1853   [], [UL_DEFAULT_ENABLE([vipw], [no])]
1854 )
1855 UL_BUILD_INIT([vipw])
1856 UL_REQUIRES_HAVE([vipw], [shadow_h], [shadow.h header])
1857 AM_CONDITIONAL([BUILD_VIPW], [test "x$build_vipw" = xyes])
1858
1859
1860 AC_ARG_ENABLE([newgrp],
1861   AS_HELP_STRING([--enable-newgrp], [build newgrp]),
1862   [], [UL_DEFAULT_ENABLE([newgrp], [no])]
1863 )
1864 UL_BUILD_INIT([newgrp])
1865 AM_CONDITIONAL([BUILD_NEWGRP], [test "x$build_newgrp" = xyes])
1866
1867
1868 AC_ARG_WITH([user], AS_HELP_STRING([--without-user], [compile without libuser (remote chsh)]),
1869   [], [with_user=check]
1870 )
1871 have_user=no
1872 AS_IF([test "x$with_user" != xno], [
1873   PKG_CHECK_MODULES(LIBUSER,[libuser >= 0.58], [have_user=yes], [have_user=no])
1874   AS_CASE([$with_user:$have_user],
1875     [yes:no],
1876       [AC_MSG_ERROR([user selected but libuser not found])],
1877     [*:yes],
1878       [AC_DEFINE([HAVE_LIBUSER], [1], [Define if libuser is available])]
1879   )
1880   # temporary solution, libuser has stupid .pc where are exported all
1881   # private dependencies to Requires: instead of Requires.private:
1882   AS_IF([test "x$have_user" = xyes], [
1883     LIBUSER_LIBS=-luser
1884   ])
1885 ])
1886 AM_CONDITIONAL([HAVE_USER], [test "x$have_user" = xyes])
1887
1888 AC_ARG_ENABLE([chfn-chsh-password],
1889   AS_HELP_STRING([--disable-chfn-chsh-password], [do not require the user to enter the password in chfn and chsh]),
1890   [], [enable_chfn_chsh_password=yes]
1891 )
1892
1893 AC_ARG_ENABLE([chfn-chsh],
1894   AS_HELP_STRING([--enable-chfn-chsh], [build chfn and chsh]),
1895   [], [UL_DEFAULT_ENABLE([chfn_chsh], [check])]
1896 )
1897 UL_BUILD_INIT([chfn_chsh])
1898 UL_REQUIRES_HAVE([chfn_chsh], [shadow_h], [shadow.h header])
1899 UL_REQUIRES_HAVE([chfn_chsh], [getusershell], [getusershell function])
1900
1901 AS_IF([test "x$enable_chfn_chsh_password" = xyes -o "x$have_user" = xyes], [
1902   UL_REQUIRES_HAVE([chfn_chsh], [security_pam_appl_h], [PAM header file])
1903   AC_DEFINE([CHFN_CHSH_PASSWORD], [1], [Should chfn and chsh require the user to enter the password?])
1904 ])
1905 AM_CONDITIONAL([BUILD_CHFN_CHSH], [test "x$build_chfn_chsh" = xyes])
1906 AM_CONDITIONAL([CHFN_CHSH_PASSWORD], [test "x$enable_chfn_chsh_password" = xyes])
1907
1908 AC_ARG_ENABLE([chsh-only-listed],
1909   AS_HELP_STRING([--disable-chsh-only-listed], [chsh: allow shells not in /etc/shells]),
1910   [], enable_chsh_only_listed=yes
1911 )
1912
1913 AS_IF([test "x$enable_chsh_only_listed" = xyes], [
1914   AC_DEFINE([ONLY_LISTED_SHELLS], [1], [Should chsh allow only shells in /etc/shells?])
1915 ])
1916
1917
1918 AC_ARG_ENABLE([login],
1919   AS_HELP_STRING([--disable-login], [do not build login]),
1920   [], [UL_DEFAULT_ENABLE([login], [check])]
1921 )
1922 UL_BUILD_INIT([login])
1923 UL_REQUIRES_HAVE([login], [security_pam_appl_h], [PAM header file])
1924 UL_REQUIRES_HAVE([login], [security_pam_misc_h, security_openpam_h], [PAM conversation functions])
1925 UL_REQUIRES_HAVE([login], [utmpx_h], [utmpx.h header])
1926 UL_REQUIRES_HAVE([login], [gnu_utmpx], [GNU utmpx functions])
1927 AM_CONDITIONAL([BUILD_LOGIN], [test "x$build_login" = xyes])
1928
1929 AC_ARG_ENABLE([login-chown-vcs],
1930   AS_HELP_STRING([--enable-login-chown-vcs], [let login chown /dev/vcsN]),
1931   [], [enable_login_chown_vcs=no]
1932 )
1933
1934 AS_IF([test "x$enable_login_chown_vcs" = xyes], [
1935   AC_DEFINE([LOGIN_CHOWN_VCS], [1], [Should login chown /dev/vcsN?])
1936 ])
1937
1938 AC_ARG_ENABLE([login-stat-mail],
1939   AS_HELP_STRING([--enable-login-stat-mail], [let login stat() the mailbox]),
1940   [], [enable_login_stat_mail=no]
1941 )
1942
1943 AS_IF([test "x$enable_login_stat_mail" = xyes], [
1944   AC_DEFINE([LOGIN_STAT_MAIL], [1], [Should login stat() the mailbox?])
1945 ])
1946
1947
1948 AC_ARG_ENABLE([nologin],
1949   AS_HELP_STRING([--disable-nologin], [do not build nologin]),
1950   [], [UL_DEFAULT_ENABLE([nologin], [yes])]
1951 )
1952 UL_BUILD_INIT([nologin])
1953 AM_CONDITIONAL([BUILD_NOLOGIN], [test "x$build_nologin" = xyes])
1954
1955
1956 AC_ARG_ENABLE([sulogin],
1957   AS_HELP_STRING([--disable-sulogin], [do not build sulogin]),
1958   [], [UL_DEFAULT_ENABLE([sulogin], [check])]
1959 )
1960 UL_BUILD_INIT([sulogin])
1961 UL_REQUIRES_HAVE([sulogin], [shadow_h], [shadow.h header])
1962 AM_CONDITIONAL([BUILD_SULOGIN], [test "x$build_sulogin" = xyes])
1963
1964
1965 AC_ARG_ENABLE([su],
1966   AS_HELP_STRING([--disable-su], [do not build su]),
1967   [], [UL_DEFAULT_ENABLE([su], [check])]
1968 )
1969 UL_BUILD_INIT([su])
1970 UL_REQUIRES_HAVE([su], [security_pam_appl_h], [PAM header file])
1971 UL_REQUIRES_HAVE([su], [utmpx_h], [utmpx.h header])
1972 UL_REQUIRES_HAVE([su], [gnu_utmpx], [GNU utmpx functions])
1973 AM_CONDITIONAL([BUILD_SU], [test "x$build_su" = xyes])
1974
1975
1976 AC_ARG_ENABLE([runuser],
1977   AS_HELP_STRING([--disable-runuser], [do not build runuser]),
1978   [], [UL_DEFAULT_ENABLE([runuser], [check])]
1979 )
1980 UL_BUILD_INIT([runuser])
1981 UL_REQUIRES_HAVE([runuser], [security_pam_appl_h], [PAM header file])
1982 UL_REQUIRES_HAVE([runuser], [utmpx_h], [utmpx.h header])
1983 UL_REQUIRES_HAVE([runuser], [gnu_utmpx], [GNU utmpx functions])
1984 AM_CONDITIONAL([BUILD_RUNUSER], [test "x$build_runuser" = xyes])
1985
1986
1987 AC_ARG_ENABLE([ul],
1988   AS_HELP_STRING([--disable-ul], [do not build ul]),
1989   [], [UL_DEFAULT_ENABLE([ul], [check])]
1990 )
1991 UL_BUILD_INIT([ul])
1992 UL_REQUIRES_HAVE([ul], [ncursesw, ncurses], [ncursesw or ncurses libraries])
1993 AM_CONDITIONAL([BUILD_UL], [test "x$build_ul" = xyes])
1994
1995
1996 AC_ARG_ENABLE([more],
1997   AS_HELP_STRING([--disable-more], [do not build more]),
1998   [], [UL_DEFAULT_ENABLE([more], [check])]
1999 )
2000 UL_BUILD_INIT([more])
2001 UL_REQUIRES_HAVE([more], [ncursesw, ncurses], [ncursesw or ncurses libraries])
2002 AM_CONDITIONAL([BUILD_MORE], [test "x$build_more" = xyes])
2003
2004
2005 AC_ARG_ENABLE([pg],
2006   AS_HELP_STRING([--enable-pg], [build pg]),
2007   [], [UL_DEFAULT_ENABLE([pg], [no])]
2008 )
2009 UL_BUILD_INIT([pg])
2010 UL_REQUIRES_HAVE([pg], [ncursesw, ncurses], [ncursesw or ncurses library])
2011 AM_CONDITIONAL([BUILD_PG], [test "x$build_pg" = xyes])
2012
2013
2014 AC_ARG_ENABLE([setterm],
2015   AS_HELP_STRING([--disable-setterm], [do not build setterm]),
2016   [], [UL_DEFAULT_ENABLE([setterm], [check])]
2017 )
2018 UL_BUILD_INIT([setterm])
2019 UL_REQUIRES_LINUX([setterm])
2020 UL_REQUIRES_HAVE([setterm], [ncursesw, ncurses], [ncursesw or ncurses library])
2021 AM_CONDITIONAL([BUILD_SETTERM], [test "x$build_setterm" = xyes])
2022
2023 # build_schedutils= is just configure-only variable to control
2024 # ionice, taskset and chrt
2025 AC_ARG_ENABLE([schedutils],
2026   AS_HELP_STRING([--disable-schedutils], [do not build chrt, ionice, taskset]),
2027   [], [UL_DEFAULT_ENABLE([schedutils], [check])]
2028 )
2029
2030
2031 UL_ENABLE_ALIAS([ionice], [schedutils])
2032 UL_BUILD_INIT([ionice])
2033 UL_REQUIRES_SYSCALL_CHECK([ionice],
2034         [UL_CHECK_SYSCALL([ioprio_set],
2035           [alpha],      [442],
2036           [i*86],       [289],
2037           [ia64*],      [1274],
2038           [powerpc*],   [273],
2039           [s390*],      [282],
2040           [sparc*],     [196],
2041           [sh*],        [288],
2042           [x86_64*],    [251])],
2043         [ioprio_set])
2044
2045 UL_REQUIRES_SYSCALL_CHECK([ionice],
2046         [UL_CHECK_SYSCALL([ioprio_get],
2047           [alpha],      [443],
2048           [i*86],       [290],
2049           [ia64*],      [1275],
2050           [powerpc*],   [274],
2051           [s390*],      [283],
2052           [sparc*],     [218],
2053           [sh*],        [289],
2054           [x86_64*],    [252])],
2055         [ioprio_get])
2056
2057 AM_CONDITIONAL([BUILD_IONICE], [test "x$build_ionice" = xyes])
2058
2059
2060 UL_ENABLE_ALIAS([taskset], [schedutils])
2061 UL_BUILD_INIT([taskset])
2062 UL_REQUIRES_HAVE([taskset], [cpu_set_t], [cpu_set_t type])
2063 UL_REQUIRES_SYSCALL_CHECK([taskset],
2064         [UL_CHECK_SYSCALL([sched_getaffinity])],
2065         [sched_getaffinity])
2066 AM_CONDITIONAL([BUILD_TASKSET], [test "x$build_taskset" = xyes])
2067
2068
2069 have_schedsetter=no
2070 AS_IF([test "x$ac_cv_func_sched_setscheduler" = xyes], [have_schedsetter=yes],
2071       [test "x$ac_cv_func_sched_setattr" = xyes], [have_schedsetter=yes])
2072
2073 UL_ENABLE_ALIAS([chrt], [schedutils])
2074 UL_BUILD_INIT([chrt])
2075 UL_REQUIRES_HAVE([chrt], [schedsetter], [sched_set functions])
2076 AM_CONDITIONAL([BUILD_CHRT], [test "x$build_chrt" = xyes])
2077
2078 AS_IF([test "x$build_chrt" = xyes], [
2079         UL_CHECK_SYSCALL([sched_setattr])
2080 ])
2081
2082
2083 AC_ARG_ENABLE([wall],
2084   AS_HELP_STRING([--disable-wall], [do not build wall]),
2085   [], [UL_DEFAULT_ENABLE([wall], [check])]
2086 )
2087 UL_BUILD_INIT([wall])
2088 UL_REQUIRES_HAVE([wall], [utmpx_h], [utmpx.h header])
2089 AM_CONDITIONAL([BUILD_WALL], [test "x$build_wall" = xyes])
2090
2091
2092 AC_ARG_ENABLE([write],
2093   AS_HELP_STRING([--enable-write], [build write]),
2094   [], [UL_DEFAULT_ENABLE([write], [no])]
2095 )
2096 UL_BUILD_INIT([write])
2097 UL_REQUIRES_HAVE([write], [utmpx_h], [utmpx.h header])
2098 UL_REQUIRES_HAVE([write], [gnu_utmpx], [GNU utmpx functions])
2099 AM_CONDITIONAL([BUILD_WRITE], [test "x$build_write" = xyes])
2100
2101
2102 AC_ARG_WITH([btrfs],
2103   AS_HELP_STRING([--without-btrfs], [do not build with btrfs support]),
2104   [], [with_btrfs=check]
2105 )
2106 have_btrfs=no
2107 AS_IF([test "x$with_btrfs" != xno], [
2108   AS_CASE([$with_btrfs:$have_linux_btrfs_h],
2109     [yes:no],
2110     [AC_MSG_ERROR([btrfs selected but linux/btrfs.h not found])],
2111     [check:no],
2112        [AC_MSG_WARN([linux/btrfs.h not found, do not build with btrfs support])],
2113     [*:yes],
2114        [have_btrfs=yes
2115         AC_DEFINE([HAVE_BTRFS_SUPPORT], [1], [Define if btrfs stuff is available])]
2116   )
2117 ])
2118 AM_CONDITIONAL([HAVE_BTRFS], [test "x$have_btrfs" = xyes])
2119
2120
2121 AC_ARG_WITH([systemd],
2122   AS_HELP_STRING([--without-systemd], [do not build with systemd support]),
2123   [], [with_systemd=check]
2124 )
2125
2126 have_systemd=no
2127 AS_IF([test "x$with_systemd" != xno], [
2128   # new version -- all libsystemd-* libs merged into libsystemd
2129   PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [have_systemd=yes], [have_systemd=no])
2130   # old versions
2131   AS_IF([test "x$have_systemd" != "xyes"], [
2132     PKG_CHECK_MODULES([SYSTEMD_DAEMON], [libsystemd-daemon],
2133                       [have_systemd_daemon=yes], [have_systemd_daemon=no])
2134     PKG_CHECK_MODULES([SYSTEMD_JOURNAL], [libsystemd-journal],
2135                       [have_systemd_journal=yes], [have_systemd_journal=no])
2136     AS_IF([test "x$have_systemd_daemon" = "xyes" -a "x$have_systemd_journal" = "xyes" ],[
2137            have_systemd=yes])
2138   ])
2139   AS_CASE([$with_systemd:$have_systemd],
2140     [yes:no],
2141       [AC_MSG_ERROR([systemd expected but libsystemd not found])],
2142     [*:yes],
2143        AC_DEFINE([HAVE_LIBSYSTEMD], [1], [Define if libsystemd is available])
2144   )
2145 ])
2146 AM_CONDITIONAL([HAVE_SYSTEMD], [test "x$have_systemd" = xyes])
2147
2148
2149 AC_ARG_WITH([systemdsystemunitdir],
2150   AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [directory for systemd unit files (requires systemd support)]),
2151   [], [with_systemdsystemunitdir=check]
2152 )
2153 AS_IF([test "x$with_systemdsystemunitdir" = xcheck], [
2154   AS_IF([test "x$have_systemd" = xyes], [
2155     with_systemdsystemunitdir=`$PKG_CONFIG --variable=systemdsystemunitdir systemd`
2156   ],[
2157     with_systemdsystemunitdir=no
2158   ])
2159 ])
2160 AS_IF([test "x$with_systemdsystemunitdir" != "xno"], [
2161   AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
2162 ])
2163
2164
2165 AC_ARG_WITH([smack],
2166   AS_HELP_STRING([--with-smack], [build with SMACK support]),
2167   [], [with_smack=no]
2168 )
2169 AS_IF([test "x$with_smack" = xyes], [
2170   AC_DEFINE([HAVE_SMACK], [1], [Add SMACK support])
2171 ])
2172
2173
2174 AC_ARG_WITH([bashcompletiondir],
2175   AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
2176   [],
2177   [AS_IF([`$PKG_CONFIG --exists bash-completion`], [
2178     with_bashcompletiondir=`$PKG_CONFIG --variable=completionsdir bash-completion`
2179   ], [
2180     with_bashcompletiondir=${datadir}/bash-completion/completions
2181   ])
2182 ])
2183 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
2184
2185 AC_ARG_ENABLE([bash-completion],
2186   AS_HELP_STRING([--disable-bash-completion], [do not install bash completion files]),
2187   [], [enable_bash_completion=yes]
2188 )
2189
2190 AM_CONDITIONAL([BUILD_BASH_COMPLETION], [test "x$enable_bash_completion" = xyes])
2191
2192
2193 AC_ARG_WITH([python],
2194   AS_HELP_STRING([--without-python], [do not build python bindings, use --with-python={2,3} to force version]),
2195   [], [with_python=check withval=check]
2196 )
2197
2198 have_python=no
2199 have_libpython=no
2200 AS_IF([test "x$with_python" != xno], [
2201   # We follow distributions default and look for PKG module name "python"
2202   # (minimal version is 2) but if major version is explicitly specified by
2203   # --with-python=2 or --with-python=3 then we look for PKG module "python2" or
2204   # "python3".
2205   AS_IF([test "x$withval" != xno -a "x$withval" != xyes -a "x$withval" != xcheck],
2206         [pymajor="$withval"; PYTHON=python${pymajor}], [pymajor="2"])
2207
2208   # check for python interpreter
2209   AM_PATH_PYTHON([$pymajor], [have_python=yes], [have_python=no])
2210   AS_CASE([$with_python:$have_python],
2211     [yes:no],
2212       [AC_MSG_ERROR([python selected but python interpreter not found])],
2213     [check:no],
2214        [AC_MSG_WARN([python interpreter not found, do not build python bindings])],
2215     [*:yes],
2216        # check for python development stuff
2217        [PKG_CHECK_MODULES([PYTHON], [python-$PYTHON_VERSION],
2218                           [have_libpython=yes], [have_libpython=no])]
2219   )
2220 ])
2221
2222
2223 AC_ARG_ENABLE([pylibmount],
2224   AS_HELP_STRING([--disable-pylibmount], [do not build pylibmount]),
2225   [], [UL_DEFAULT_ENABLE([pylibmount], [check])]
2226 )
2227 UL_BUILD_INIT([pylibmount])
2228 UL_REQUIRES_HAVE([pylibmount], [libpython], [libpython])
2229 UL_REQUIRES_BUILD([pylibmount], [libmount])
2230 AM_CONDITIONAL([BUILD_PYLIBMOUNT], [test "x$build_pylibmount" = "xyes"])
2231
2232 # We need to introduce a verbatim dependency into the Makefile, without automake
2233 # trying to interpret it, so push it as a AM_SUBST_NOTMAKE variable.
2234 verbatim_pylibmount_dependency='
2235
2236 # pylibmountexec module must be installed after usrlib_exec libraries,
2237 # otherwise the libtool relink step will fail to find libmount.la and
2238 # will try -lmount which is possibly not available.
2239 install-pylibmountexecLTLIBRARIES: install-usrlib_execLTLIBRARIES
2240
2241 '
2242 AC_SUBST([verbatim_pylibmount_dependency])
2243 AM_SUBST_NOTMAKE([verbatim_pylibmount_dependency])
2244
2245 AC_ARG_ENABLE([pg-bell],
2246   AS_HELP_STRING([--disable-pg-bell], [let pg not ring the bell on invalid keys]),
2247   [], [enable_pg_bell=yes]
2248 )
2249
2250 AS_IF([test "x$enable_pg_bell" = xyes], [
2251   AC_DEFINE([PG_BELL], [1], [Should pg ring the bell on invalid keys?])
2252 ])
2253
2254
2255 AC_DEFUN([FS_PATHS_DEFAULT], [/sbin:/sbin/fs.d:/sbin/fs])
2256 AC_ARG_ENABLE([fs-paths-default],
2257   AS_HELP_STRING([--enable-fs-paths-default=paths], [default search path for fs helpers @<:@FS_PATHS_DEFAULT@:>@]),
2258   [AS_CASE([$enableval],
2259     [yes], [fs_paths_defaults="FS_PATHS_DEFAULT"],
2260     [no],  [fs_paths_defaults=""],
2261     [fs_paths_defaults="$enableval"]
2262   )],
2263   [fs_paths_defaults="FS_PATHS_DEFAULT"]
2264 )
2265 AC_ARG_ENABLE([fs-paths-extra],
2266   AS_HELP_STRING([--enable-fs-paths-extra=paths], [additional search paths for fs helpers]),
2267   [AS_CASE([$enableval],
2268      [yes|no], [fs_paths_extra=""],
2269      [fs_paths_extra="$enableval"]
2270   )],
2271   [fs_paths_extra=""]
2272 )
2273 fs_paths="$fs_paths_defaults"
2274 AS_IF([test "x$fs_paths_extra" != "x"], [
2275   AS_IF([test "x$fs_paths" != "x"], [
2276     fs_paths="${fs_paths}:"
2277   ])
2278   fs_paths="${fs_paths}${fs_paths_extra}"
2279 ])
2280 AC_DEFINE_UNQUOTED([FS_SEARCH_PATH], "$fs_paths", [search path for fs helpers])
2281
2282
2283 AC_ARG_ENABLE([use-tty-group],
2284   AS_HELP_STRING([--disable-use-tty-group], [do not install wall and write setgid tty]),
2285   [], [enable_use_tty_group=yes]
2286 )
2287 AM_CONDITIONAL([USE_TTY_GROUP], [test "x$enable_use_tty_group" = xyes])
2288
2289 AS_IF([test "x$enable_use_tty_group" = xyes], [
2290   AC_DEFINE([USE_TTY_GROUP], [1], [Should wall and write be installed setgid tty?])
2291 ])
2292
2293
2294 AC_ARG_ENABLE([sulogin-emergency-mount],
2295   AS_HELP_STRING([--enable-sulogin-emergency-mount],
2296                  [use emergency mount of /dev and /proc for sulogin]),
2297   [], [enable_sulogin_emergency_mount=no]
2298 )
2299
2300 AS_IF([test "x$enable_sulogin_emergency_mount" = xyes], [
2301   AC_DEFINE([USE_SULOGIN_EMERGENCY_MOUNT], [1],
2302             [Should sulogin use a emergency mount of /dev and /proc?])
2303 ])
2304
2305
2306 AC_ARG_ENABLE([usrdir-path],
2307   AS_HELP_STRING([--enable-usrdir-path], [use only /usr paths in PATH env. variable (recommended on systems with /bin -> /usr/bin symlinks)]),
2308   [], [enable_usrdir_path=no]
2309 )
2310
2311 AS_IF([test "x$enable_usrdir_path" = xyes], [
2312   AC_DEFINE([USE_USRDIR_PATHS_ONLY], [1], [Define to 1 to remove /bin and /sbin from PATH env.variable])
2313 ])
2314
2315
2316 AC_ARG_ENABLE([makeinstall-chown],
2317   AS_HELP_STRING([--disable-makeinstall-chown], [do not do chown-like operations during "make install"]),
2318   [], [enable_makeinstall_chown=yes]
2319 )
2320 AM_CONDITIONAL([MAKEINSTALL_DO_CHOWN], [test "x$enable_makeinstall_chown" = xyes])
2321
2322
2323 AC_ARG_ENABLE([makeinstall-setuid],
2324   AS_HELP_STRING([--disable-makeinstall-setuid], [do not do setuid chmod operations during "make install"]),
2325   [], [enable_makeinstall_setuid=yes]
2326 )
2327 AM_CONDITIONAL([MAKEINSTALL_DO_SETUID], [test "x$enable_makeinstall_setuid" = xyes])
2328
2329
2330 AC_ARG_ENABLE([colors-default],
2331   AS_HELP_STRING([--disable-colors-default], [do not colorize output from utils by default]),
2332   [], [enable_colors_default=yes]
2333 )
2334 AS_IF([test "x$enable_colors_default" = xyes], [
2335   AC_DEFINE([USE_COLORS_BY_DEFAULT], [1], [Enables colorized output from utils by default])
2336 ])
2337
2338
2339 AC_ARG_VAR([SUID_CFLAGS],
2340            [CFLAGS used for binaries which are usually with the suid bit])
2341 AC_ARG_VAR([SUID_LDFLAGS],
2342            [LDFLAGS used for binaries which are usually with the suid bit])
2343
2344 AC_ARG_VAR([DAEMON_CFLAGS],
2345            [CFLAGS used for binaries which are usually executed as daemons])
2346 AC_ARG_VAR([DAEMON_LDFLAGS],
2347            [LDFLAGS used for binaries which are usually executed as daemons])
2348
2349 AC_ARG_VAR([SOLIB_CFLAGS],
2350            [CFLAGS used for shared libraries])
2351 AC_ARG_VAR([SOLIB_LDFLAGS],
2352            [LDFLAGS used for shared libraries])
2353
2354 AC_ARG_VAR([ADJTIME_PATH],
2355            [Path to hwclock adjtime file, default /etc/adjtime])
2356 AS_IF([test "x$ADJTIME_PATH" = x], [ADJTIME_PATH="/etc/adjtime"])
2357 AC_DEFINE_UNQUOTED([CONFIG_ADJTIME_PATH], "$ADJTIME_PATH", [Path to hwclock adjtime file])
2358
2359
2360 LIBS=""
2361
2362
2363 AC_CONFIG_HEADERS([config.h])
2364
2365 #
2366 # Don't use configure.ac to replace install paths! See Makefile PATHFILES for
2367 # more details.
2368 #
2369 AC_CONFIG_FILES([
2370 Makefile
2371 libblkid/docs/Makefile
2372 libblkid/docs/version.xml
2373 libblkid/src/blkid.h
2374 libfdisk/docs/Makefile
2375 libfdisk/docs/version.xml
2376 libfdisk/src/libfdisk.h
2377 libmount/docs/Makefile
2378 libmount/docs/version.xml
2379 libmount/src/libmount.h
2380 libsmartcols/docs/Makefile
2381 libsmartcols/docs/version.xml
2382 libsmartcols/src/libsmartcols.h
2383 po/Makefile.in
2384 ])
2385
2386 AC_OUTPUT
2387
2388 AC_MSG_RESULT([
2389         ${PACKAGE}  ${VERSION}
2390
2391         prefix:            ${prefix}
2392         exec prefix:       ${exec_prefix}
2393
2394         runstatedir:       ${runstatedir}
2395         bindir:            ${bindir}
2396         sbindir:           ${sbindir}
2397         libdir:            ${libdir}
2398         includedir:        ${includedir}
2399         usrbin_execdir:    ${usrbin_execdir}
2400         usrsbin_execdir:   ${usrsbin_execdir}
2401         usrlib_execdir:    ${usrlib_execdir}
2402
2403         compiler:          ${CC}
2404         cflags:            ${CFLAGS}
2405         suid cflags:       ${SUID_CFLAGS}
2406         ldflags:           ${LDFLAGS}
2407         suid ldflags:      ${SUID_LDFLAGS}
2408
2409         Python:            ${PYTHON}
2410         Python version:    ${PYTHON_VERSION}
2411         Python libs:       ${pyexecdir}
2412
2413         Bash completions:  ${with_bashcompletiondir}
2414         Systemd support:   ${have_systemd}
2415         Systemd unitdir:   ${with_systemdsystemunitdir}
2416         Btrfs support:     ${have_btrfs}
2417         Wide-char support: ${build_widechar}
2418
2419         warnings:
2420
2421 ${WARN_CFLAGS}
2422
2423         Type 'make' or 'make <utilname>' to compile.
2424 ])