configure.ac

   1 AC_INIT([util-linux],
   2         m4_esyscmd([tools/git-version-gen .tarball-version]),
   3         [kzak@redhat.com], [],
   4         [https://www.kernel.org/pub/linux/utils/util-linux/])
   5
   6
   7 AC_PREREQ([2.64])
   8
   9 AC_CONFIG_AUX_DIR([config])
  10 AC_CONFIG_MACRO_DIR([m4])
  11 dnl AC_USE_SYSTEM_EXTENSIONS must be called before any macros that run
  12 dnl the compiler (like LT_INIT) to avoid autoconf errors.
  13 AC_USE_SYSTEM_EXTENSIONS
  14 AM_INIT_AUTOMAKE([-Wall -Wno-portability foreign 1.10 tar-pax no-dist-gzip dist-xz subdir-objects])
  15
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  17                             [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  18 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  19
  20 AC_CONFIG_SRCDIR([sys-utils/mount.c])
  21 AC_PREFIX_DEFAULT([/usr])
  22
  23 dnl version details from <major>.<minor>[-<suffix>]
  24 PACKAGE_VERSION_MAJOR=$(echo $PACKAGE_VERSION | awk -F. '{print $1}')
  25 PACKAGE_VERSION_MINOR=$(echo $PACKAGE_VERSION | awk -F. '{
  26                                                    sub("-.*","",$2); print $2}')
  27 PACKAGE_VERSION_RELEASE=$(echo $PACKAGE_VERSION | awk -F. '{
  28                      sub("-.*","",$3); print $3 ~ /^@<:@0-9@:>@+$/ ? $3 : 0}')
  29
  30 dnl libblkid version
  31 LIBBLKID_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  32 LIBBLKID_DATE="24-Jan-2024"
  33 LIBBLKID_LT_MAJOR=1
  34 LIBBLKID_LT_MINOR=1
  35 LIBBLKID_LT_MICRO=0
  36 LIBBLKID_VERSION_INFO=`expr $LIBBLKID_LT_MAJOR + $LIBBLKID_LT_MINOR`:$LIBBLKID_LT_MICRO:$LIBBLKID_LT_MINOR
  37
  38 dnl libuuid version
  39 LIBUUID_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  40 LIBUUID_LT_MAJOR=1
  41 LIBUUID_LT_MINOR=3
  42 LIBUUID_LT_MICRO=0
  43 LIBUUID_VERSION_INFO=`expr $LIBUUID_LT_MAJOR + $LIBUUID_LT_MINOR`:$LIBUUID_LT_MICRO:$LIBUUID_LT_MINOR
  44
  45 dnl liblastlog2 version
  46 LIBLASTLOG2_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  47 LIBLASTLOG2_LT_MAJOR=2
  48 LIBLASTLOG2_LT_MINOR=0
  49 LIBLASTLOG2_LT_MICRO=0
  50 LIBLASTLOG2_VERSION_INFO=`expr $LIBLASTLOG2_LT_MAJOR + $LIBLASTLOG2_LT_MINOR`:$LIBLASTLOG2_LT_MICRO:$LIBLASTLOG2_LT_MINOR
  51
  52 dnl libmount version
  53 LIBMOUNT_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  54 LIBMOUNT_LT_MAJOR=1
  55 LIBMOUNT_LT_MINOR=1
  56 LIBMOUNT_LT_MICRO=0
  57 LIBMOUNT_VERSION_INFO=`expr $LIBMOUNT_LT_MAJOR + $LIBMOUNT_LT_MINOR`:$LIBMOUNT_LT_MICRO:$LIBMOUNT_LT_MINOR
  58
  59 dnl libsmartcols version
  60 LIBSMARTCOLS_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  61 LIBSMARTCOLS_LT_MAJOR=1
  62 LIBSMARTCOLS_LT_MINOR=1
  63 LIBSMARTCOLS_LT_MICRO=0
  64 LIBSMARTCOLS_VERSION_INFO=`expr $LIBSMARTCOLS_LT_MAJOR + $LIBSMARTCOLS_LT_MINOR`:$LIBSMARTCOLS_LT_MICRO:$LIBSMARTCOLS_LT_MINOR
  65
  66 dnl libfdisk version
  67 LIBFDISK_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  68 LIBFDISK_LT_MAJOR=1
  69 LIBFDISK_LT_MINOR=1
  70 LIBFDISK_LT_MICRO=0
  71 LIBFDISK_VERSION_INFO=`expr $LIBFDISK_LT_MAJOR + $LIBFDISK_LT_MINOR`:$LIBFDISK_LT_MICRO:$LIBFDISK_LT_MINOR
  72
  73 # Check whether exec_prefix=/usr:
  74 AS_CASE([$exec_prefix:$prefix],
  75 [NONE:NONE | NONE:/usr | /usr:*],
  76   [AC_MSG_NOTICE([Default --exec-prefix detected.])
  77    AS_CASE([$bindir],  ['${exec_prefix}/bin'],  [bindir=/bin;   AC_MSG_NOTICE([  --bindir defaults to /bin])  ])
  78    AS_CASE([$sbindir], ['${exec_prefix}/sbin'], [sbindir=/sbin; AC_MSG_NOTICE([  --sbindir defaults to /sbin])])
  79    AS_CASE([$libdir],  ['${exec_prefix}/lib'],  [libdir=/lib;   AC_MSG_NOTICE([  --libdir defaults to /lib])  ])
  80    AS_CASE([$libdir],  ['${exec_prefix}/lib64'],[libdir=/lib64; AC_MSG_NOTICE([  --libdir defaults to /lib64])  ])
  81   ]
  82 )
  83
  84 # Check whether prefix=/usr
  85 AS_CASE([$prefix],
  86 [NONE | /usr],
  87   [AC_MSG_NOTICE([Default --prefix detected.])
  88    AS_CASE([$localstatedir], [NONE | '${prefix}/var' | "${prefix}"/var ],
  89            [localstatedir=/var; AC_MSG_NOTICE([  --localstatedir defaults to /var])])
  90    AS_CASE([$sysconfdir], [NONE | '${prefix}/etc' | "${prefix}"/etc ],
  91            [sysconfdir=/etc; AC_MSG_NOTICE([  --sysconfdir defaults to /etc])])
  92
  93   ]
  94 )
  95 AC_SUBST([localstatedir])
  96
  97
  98 # default for old versions without $runstatedir
  99 AS_IF([test x"$runstatedir" = x], [runstatedir='${localstatedir}/run'])
 100
 101 # our default if $localstatedir unchanged
 102 AS_CASE([$localstatedir:$runstatedir],
 103  [NONE:'${localstatedir}/run' | /var:'${localstatedir}/run' | NONE:'/run' ],
 104    [runstatedir=/run; AC_MSG_NOTICE([  --runstatedir defaults to /run])]
 105 )
 106 AC_SUBST([runstatedir])
 107
 108
 109 # The original default values of {bin,sbin,lib}dir
 110 usrbin_execdir='${exec_prefix}/bin'
 111 AC_SUBST([usrbin_execdir])
 112
 113 usrsbin_execdir='${exec_prefix}/sbin'
 114 AC_SUBST([usrsbin_execdir])
 115
 116 AS_CASE([$libdir],
 117  ['${exec_prefix}/'* | '${prefix}/'* | /usr/* | "${prefix}"/* ],
 118    [usrlib_execdir=$libdir],
 119  [usrlib_execdir='${exec_prefix}'$libdir]
 120 )
 121 AC_SUBST([usrlib_execdir])
 122
 123 # static configuration maintaned by packages (e.g. /usr/lib)
 124 AC_ARG_VAR([SYSCONFSTATICDIR],
 125            [Path to static system configuration, default ${prefix}/lib])
 126 AS_IF([test "x$SYSCONFSTATICDIR" = x],
 127       [sysconfstaticdir='${prefix}/lib'],
 128       [sysconfstaticdir=$SYSCONFSTATICDIR])
 129 AC_SUBST([sysconfstaticdir])
 130
 131 AC_PROG_CC
 132 AM_PROG_CC_C_O
 133 AC_PROG_MKDIR_P
 134 AC_PROG_YACC
 135 AC_PROG_AWK
 136
 137 # Don't use autotools integrated LEX/YACC support for libsmartcols
 138 AC_PATH_PROG([FLEX], [flex])
 139 AC_PATH_PROG([BISON], [bison])
 140
 141 AC_CANONICAL_HOST
 142 AC_C_CONST
 143 AC_C_VOLATILE
 144
 145 dnl Compiler warnings
 146 UL_WARN_ADD([-fno-common])
 147 UL_WARN_ADD([-Wall])
 148 UL_WARN_ADD([-Wextra])
 149
 150 UL_WARN_ADD([-Waddress-of-packed-member])
 151 UL_WARN_ADD([-Wdiscarded-qualifiers])
 152 UL_WARN_ADD([-Wembedded-directive])
 153 UL_WARN_ADD([-Wextra-semi])
 154 UL_WARN_ADD([-Wformat-security])
 155 UL_WARN_ADD([-Wimplicit-function-declaration])
 156 UL_WARN_ADD([-Wmissing-declarations])
 157 UL_WARN_ADD([-Wmissing-parameter-type])
 158 UL_WARN_ADD([-Wmissing-prototypes])
 159 UL_WARN_ADD([-Wnested-externs])
 160 UL_WARN_ADD([-Wno-missing-field-initializers])
 161 UL_WARN_ADD([-Wold-style-definition])
 162 UL_WARN_ADD([-Wpointer-arith])
 163 UL_WARN_ADD([-Wredundant-decls])
 164 UL_WARN_ADD([-Wsign-compare])
 165 UL_WARN_ADD([-Wstrict-prototypes])
 166 UL_WARN_ADD([-Wtype-limits])
 167 UL_WARN_ADD([-Wuninitialized])
 168 UL_WARN_ADD([-Wunused-but-set-parameter])
 169 UL_WARN_ADD([-Wunused-but-set-variable])
 170 UL_WARN_ADD([-Wunused-parameter])
 171 UL_WARN_ADD([-Wunused-result])
 172 UL_WARN_ADD([-Wunused-variable])
 173 UL_WARN_ADD([-Wvla])
 174 UL_WARN_ADD([-Walloca])
 175
 176 AC_ARG_ENABLE([werror],
 177   AS_HELP_STRING([--enable-werror], [make all compiler warnings into errors]),
 178   [], [enable_werror=no]
 179 )
 180 AS_IF([test "x$enable_werror" = xyes], [
 181   UL_WARN_ADD([-Werror])
 182 ],[
 183   UL_WARN_ADD([-Werror=sequence-point])
 184 ])
 185
 186 AC_SUBST([WARN_CFLAGS])
 187
 188
 189 UL_WARN_ADD([-Wno-clobbered], [BSD_WARN_CFLAGS])
 190 AC_SUBST([BSD_WARN_CFLAGS])
 191
 192 UL_WARN_ADD([-Wno-cast-function-type], [PYTHON_WARN_CFLAGS])
 193 AC_SUBST([PYTHON_WARN_CFLAGS])
 194
 195
 196 AC_ARG_ENABLE([asan],
 197   AS_HELP_STRING([--enable-asan], [compile with Address Sanitizer]),
 198   [], [enable_asan=no]
 199 )
 200 AS_IF([test "x$enable_asan" = xyes], [
 201   UL_WARN_ADD([-fsanitize=address])
 202   ASAN_LDFLAGS="-fsanitize=address"
 203 ])
 204 AC_SUBST([ASAN_LDFLAGS])
 205
 206 AC_ARG_ENABLE([ubsan],
 207   AS_HELP_STRING([--enable-ubsan], [compile with UBsan]),
 208   [], [enable_ubsan=no]
 209 )
 210 AS_IF([test "x$enable_ubsan" = xyes], [
 211   UL_WARN_ADD([-fsanitize=undefined])
 212   UBSAN_LDFLAGS="-fsanitize=undefined"
 213 ])
 214 AC_SUBST([UBSAN_LDFLAGS])
 215
 216 AC_ARG_ENABLE([fuzzing-engine],
 217   AS_HELP_STRING([--enable-fuzzing-engine], [compile with fuzzing engine]),
 218   [], [enable_fuzzing_engine=no]
 219 )
 220 AS_IF([test "x$enable_fuzzing_engine" = xyes && test "x$LIB_FUZZING_ENGINE" = x], [
 221   UL_WARN_ADD([-fno-omit-frame-pointer])
 222   UL_WARN_ADD([-gline-tables-only])
 223   UL_WARN_ADD([-fsanitize=fuzzer-no-link])
 224   FUZZING_ENGINE_LDFLAGS="-fsanitize=fuzzer-no-link"
 225 ])
 226 AC_SUBST([FUZZING_ENGINE_LDFLAGS])
 227 AC_PROG_CXX
 228 AM_CONDITIONAL([FUZZING_ENGINE], [test "x$enable_fuzzing_engine" = xyes])
 229 AM_CONDITIONAL([OSS_FUZZ], [test "x$LIB_FUZZING_ENGINE" != x])
 230
 231 AC_ARG_ENABLE([coverage],
 232   AS_HELP_STRING([--enable-coverage], [compile with gcov]),
 233   [], [enable_coverage=no]
 234 )
 235 AS_IF([test "x$enable_coverage" = xyes], [
 236   UL_WARN_ADD([--coverage])
 237   COVERAGE_LDFLAGS="--coverage"
 238 ])
 239 AC_SUBST([COVERAGE_LDFLAGS])
 240 AM_CONDITIONAL([WITH_COVERAGE], [test "x$enable_coverage" = xyes])
 241
 242 dnl libtool-2
 243 LT_INIT
 244
 245 dnl check supported linker flags
 246 AX_CHECK_VSCRIPT
 247
 248 m4_ifndef([PKG_PROG_PKG_CONFIG],
 249   [m4_fatal([Could not locate the pkg-config autoconf
 250     macros. These are usually located in /usr/share/aclocal/pkg.m4.
 251     If your macros are in a different location, try setting the
 252     environment variable AL_OPTS="-I/other/macro/dir" before running
 253     ./autogen.sh or autoreconf again. Make sure pkg-config is installed.])])
 254 PKG_PROG_PKG_CONFIG
 255 PKG_INSTALLDIR(['${usrlib_execdir}/pkgconfig'])
 256
 257 GTK_DOC_CHECK([1.10])
 258 AC_PATH_PROG([XSLTPROC], [xsltproc])
 259
 260
 261 linux_os=no
 262 bsd_os=no
 263 AS_CASE([${host_os}],
 264   [*linux*],
 265      [linux_os=yes],
 266   [*darwin*],
 267      [darwin_os=yes],
 268   [*bsd*],
 269      [bsd_os=yes])
 270 AM_CONDITIONAL([LINUX], [test "x$linux_os" = xyes])
 271 AM_CONDITIONAL([DARWIN], [test "x$darwin_os" = xyes])
 272 AM_CONDITIONAL([BSD], [test "x$bsd_os" = xyes])
 273
 274 AS_IF([test  "x$darwin_os" = xyes], [
 275   AC_DEFINE([_DARWIN_C_SOURCE], [1], [Enable MAP_ANON in sys/mman.h on Mac OS X])
 276 ])
 277
 278 dnl define ARCH_<NAME> conditionals
 279 UL_SET_ARCH([I86], [i?86-*])
 280 UL_SET_ARCH([86_64], [x86_64*])
 281 UL_SET_ARCH([IA64], [ia64*])
 282 UL_SET_ARCH([S390], [s390*])
 283 UL_SET_ARCH([SPARC], [sparc*])
 284 UL_SET_ARCH([PPC], [ppc*|powerpc*])
 285 UL_SET_ARCH([M68K], [m68*])
 286 UL_SET_ARCH([MIPS], [mips*])
 287 UL_SET_ARCH([HPPA], [hppa*|parisc*])
 288
 289 AC_SYS_LARGEFILE
 290 AC_HEADER_ASSERT
 291 AC_STRUCT_TIMEZONE
 292 UL_YEAR2038_INIT
 293 AC_SYS_YEAR2038_RECOMMENDED
 294
 295 dnl Don't forget to maintain alternatively allowed versions in autogen.sh!
 296 AM_GNU_GETTEXT_VERSION([0.18.3])
 297 AM_GNU_GETTEXT([external])
 298
 299 AS_IF([test -d "$srcdir/po"], [
 300   ALL_LINGUAS=`cd $srcdir/po > /dev/null && echo *.po | sed 's/\.po//g'`
 301 ], [dnl echo $ALL_LINGUAS | sed 's/ /\n/g' | sort -u | column -xc 72 -o ' ' | sed 's/^/\t/'
 302   ALL_LINGUAS="
 303         af      am      ar      as      be      bg      bn      bn_IN   ca
 304         cs      cy      da      de      el      en_GB   es      et      eu_ES
 305         fa      fi      fr      gl      gu      he      hi      hr      hu
 306         hy      id      is      it      ja      ka      kn      ko      ku
 307         lo      lt      lv      mk      ml      mr      ms      my      nb
 308         nl      nn      no      nso     or      pa      pl      pt      pt_BR
 309         ro      ru      si      sk      sl      sq      sr      sr@Latn sv
 310         ta      te      th      tr      uk      ur      vi      zh_CN   zh_TW
 311         zu
 312 "])
 313
 314 AC_CHECK_HEADERS([linux/compiler.h linux/blkpg.h linux/major.h], [], [], [
 315 #ifdef HAVE_LINUX_COMPILER_H
 316 #include <linux/compiler.h>
 317 #endif
 318 ])
 319 AC_CHECK_HEADERS([ \
 320         asm-generic/fcntl.h \
 321         asm/fcntl.h \
 322         asm/io.h \
 323         byteswap.h \
 324         endian.h \
 325         err.h \
 326         errno.h \
 327         fcntl.h \
 328         getopt.h \
 329         inttypes.h \
 330         lastlog.h \
 331         libutil.h \
 332         linux/blkzoned.h \
 333         linux/btrfs.h \
 334         linux/capability.h \
 335         linux/cdrom.h \
 336         linux/falloc.h \
 337         linux/fd.h \
 338         linux/fiemap.h \
 339         linux/landlock.h \
 340         linux/kcmp.h \
 341         linux/net_namespace.h \
 342         linux/nsfs.h \
 343         linux/pr.h \
 344         linux/raw.h \
 345         linux/securebits.h \
 346         linux/tiocl.h \
 347         linux/version.h \
 348         linux/watchdog.h \
 349         linux/if_alg.h \
 350         locale.h \
 351         mntent.h \
 352         net/if_dl.h \
 353         net/if.h \
 354         netinet/in.h \
 355         paths.h \
 356         pty.h \
 357         security/pam_appl.h \
 358         security/pam_modules.h \
 359         shadow.h \
 360         stdint.h \
 361         stdio_ext.h \
 362         stdlib.h \
 363         sys/disk.h \
 364         sys/disklabel.h \
 365         sys/endian.h \
 366         sys/file.h \
 367         sys/ioccom.h \
 368         sys/ioctl.h \
 369         sys/io.h \
 370         sys/mkdev.h \
 371         sys/mount.h \
 372         sys/param.h \
 373         sys/pidfd.h \
 374         sys/prctl.h \
 375         sys/resource.h \
 376         sys/sendfile.h \
 377         sys/signalfd.h \
 378         sys/socket.h \
 379         sys/sockio.h \
 380         sys/stat.h \
 381         sys/statfs.h \
 382         sys/swap.h \
 383         sys/syscall.h \
 384         sys/sysmacros.h \
 385         sys/time.h \
 386         sys/timex.h \
 387         sys/ttydefaults.h \
 388         sys/types.h \
 389         sys/ucred.h \
 390         sys/un.h \
 391         sys/vfs.h \
 392         sys/xattr.h \
 393         unistd.h \
 394         utmp.h \
 395         utmpx.h \
 396 ])
 397
 398 # There is a collision in old kernel-headers. The both files mount.h and fs.h
 399 # define MS_* macros. Fixed by kernel commit e462ec50cb5fad19f6003a3d8087f4a0945dd2b1.
 400 #
 401 AC_CHECK_HEADERS([linux/fs.h ], [], [],
 402  [#ifdef HAVE_SYS_MOUNT_H
 403    # include <linux/fs.h>
 404    # include <sys/mount.h>
 405   #endif
 406 ])
 407
 408 AC_CHECK_HEADERS([linux/mount.h ], [], [],
 409  [#ifdef HAVE_LINUX_MOUNT_H
 410    # include <linux/mount.h>
 411    #endif
 412 ])
 413
 414 AC_CHECK_HEADERS([linux/gsmmux.h ], [], [],
 415  [#ifdef LINUX_GSMMUX_H
 416    # include <linux/gsmmux.h>
 417    #endif
 418 ])
 419
 420 AC_CHECK_HEADERS([security/pam_misc.h],
 421                 [AM_CONDITIONAL([HAVE_LINUXPAM], [true])],
 422                 [AM_CONDITIONAL([HAVE_LINUXPAM], [false])], [
 423 #ifdef HAVE_SECURITY_PAM_APPL_H
 424 #include <security/pam_appl.h>
 425 #endif
 426 ])
 427
 428 AC_CHECK_DECLS([BLK_ZONE_REP_CAPACITY], [], [], [
 429         #include <linux/blkzoned.h>
 430 ])
 431
 432 AC_CHECK_DECLS([PR_REP_CAPACITY], [], [], [
 433         #include <linux/pr.h>
 434 ])
 435
 436 AC_CHECK_HEADERS([security/openpam.h], [], [], [
 437 #ifdef HAVE_SECURITY_PAM_APPL_H
 438 #include <security/pam_appl.h>
 439 #endif
 440 ])
 441
 442 AC_CHECK_HEADERS([langinfo.h],
 443                 [AM_CONDITIONAL([HAVE_LANGINFO_H], [true])],
 444                 [AM_CONDITIONAL([HAVE_LANGINFO_H], [false])])
 445
 446 AC_MSG_CHECKING([whether langinfo.h defines ALTMON_x constants])
 447 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 448         #include <langinfo.h>
 449 ]], [[
 450         char *str;
 451         str = nl_langinfo (ALTMON_1);
 452         str = nl_langinfo (ALTMON_2);
 453         str = nl_langinfo (ALTMON_3);
 454         str = nl_langinfo (ALTMON_4);
 455         str = nl_langinfo (ALTMON_5);
 456         str = nl_langinfo (ALTMON_6);
 457         str = nl_langinfo (ALTMON_7);
 458         str = nl_langinfo (ALTMON_8);
 459         str = nl_langinfo (ALTMON_9);
 460         str = nl_langinfo (ALTMON_10);
 461         str = nl_langinfo (ALTMON_11);
 462         str = nl_langinfo (ALTMON_12);
 463 ]])], [
 464         AC_MSG_RESULT([yes])
 465         AC_DEFINE([HAVE_LANGINFO_ALTMON], [1],
 466                 [Define if langinfo.h defines ALTMON_x constants])
 467 ], [
 468         AC_MSG_RESULT([no])
 469 ])
 470
 471
 472 AC_MSG_CHECKING([whether langinfo.h defines _NL_ABALTMON_x constants])
 473 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 474         #include <langinfo.h>
 475 ]], [[
 476         char *str;
 477         str = nl_langinfo (_NL_ABALTMON_1);
 478         str = nl_langinfo (_NL_ABALTMON_2);
 479         str = nl_langinfo (_NL_ABALTMON_3);
 480         str = nl_langinfo (_NL_ABALTMON_4);
 481         str = nl_langinfo (_NL_ABALTMON_5);
 482         str = nl_langinfo (_NL_ABALTMON_6);
 483         str = nl_langinfo (_NL_ABALTMON_7);
 484         str = nl_langinfo (_NL_ABALTMON_8);
 485         str = nl_langinfo (_NL_ABALTMON_9);
 486         str = nl_langinfo (_NL_ABALTMON_10);
 487         str = nl_langinfo (_NL_ABALTMON_11);
 488         str = nl_langinfo (_NL_ABALTMON_12);
 489 ]])], [
 490         AC_MSG_RESULT([yes])
 491         AC_DEFINE([HAVE_LANGINFO_NL_ABALTMON], [1],
 492                 [Define if langinfo.h defines _NL_ABALTMON_x constants])
 493 ], [
 494         AC_MSG_RESULT([no])
 495 ])
 496
 497
 498 dnl Convert some ac_cv_header_* variables to have_*
 499 dnl
 500 have_linux_blkzoned_h=$ac_cv_header_linux_blkzoned_h
 501 have_linux_btrfs_h=$ac_cv_header_linux_btrfs_h
 502 have_linux_capability_h=$ac_cv_header_linux_capability_h
 503 have_linux_kcmp_h=$ac_cv_header_linux_kcmp_h
 504 have_linux_mount_h=$ac_cv_header_linux_mount_h
 505 have_linux_pr_h=$ac_cv_header_linux_pr_h
 506 have_linux_raw_h=$ac_cv_header_linux_raw_h
 507 have_linux_securebits_h=$ac_cv_header_linux_securebits_h
 508 have_linux_version_h=$ac_cv_header_linux_version_h
 509 have_linux_watchdog_h=$ac_cv_header_linux_watchdog_h
 510 have_pty_h=$ac_cv_header_pty_h
 511 have_security_openpam_h=$ac_cv_header_security_openpam_h
 512 have_security_pam_appl_h=$ac_cv_header_security_pam_appl_h
 513 have_security_pam_misc_h=$ac_cv_header_security_pam_misc_h
 514 have_security_pam_modules_h=$ac_cv_header_security_pam_modules_h
 515 have_shadow_h=$ac_cv_header_shadow_h
 516 have_sys_signalfd_h=$ac_cv_header_sys_signalfd_h
 517 have_utmpx_h=$ac_cv_header_utmpx_h
 518 have_mntent_h=$ac_cv_header_mntent_h
 519
 520 AS_CASE([$linux_os:$have_linux_version_h],
 521   [yes:no],
 522     [AC_MSG_ERROR([kernel headers required on Linux])]
 523 )
 524
 525 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 526 #include <time.h>
 527 #include <unistd.h>
 528 ]], [[
 529     int a = 0;
 530     struct tm *tm = localtime(0);
 531     if (a == -1)  /* false */
 532         sleep(tm->tm_gmtoff);
 533 ]])],
 534 [AC_DEFINE([HAVE_TM_GMTOFF], [1], [Does struct tm have a field tm_gmtoff?])
 535 ])
 536
 537 AC_CHECK_TYPES([struct mount_attr], [], [], [[#include <linux/mount.h>]])
 538 AC_CHECK_TYPES([enum fsconfig_command], [], [], [[#include <linux/mount.h>]])
 539
 540 AC_CHECK_MEMBERS([struct termios.c_line],,,
 541     [[#include <termios.h>]])
 542
 543 AC_CHECK_MEMBERS([struct stat.st_mtim.tv_nsec],,,
 544     [[#include <sys/stat.h>]])
 545
 546 AC_CHECK_TYPES([struct statx], [], [], [[#include <sys/stat.h>]])
 547 AC_CHECK_MEMBERS([struct statx.stx_mnt_id],,,
 548     [[#include <sys/stat.h>]])
 549
 550 AC_CHECK_DECLS([_NL_TIME_WEEK_1STDAY],[],[],[[#include <langinfo.h>]])
 551
 552 AC_CHECK_DECL([environ],
 553         [AC_DEFINE([HAVE_ENVIRON_DECL], [1],
 554                 [Define to 1 if have **environ prototype])],
 555 )
 556
 557 AC_CHECK_DECL([strsignal],
 558         [AC_DEFINE([HAVE_STRSIGNAL_DECL], [1],
 559                 [Define to 1 if have strsignal function prototype])],
 560 )
 561
 562 AC_CHECK_DECL([TIOCGLCKTRMIOS],
 563               [have_tiocglcktrmios=yes], [have_tiocglcktrmios=no],
 564               [#include <sys/ioctl.h>])
 565 AC_CHECK_DECL([SOCK_CLOEXEC],
 566               [have_sock_cloexec=yes], [have_sock_cloexec=no],
 567               [#include <sys/types.h>
 568                #include <sys/socket.h>])
 569 AC_CHECK_DECL([SOCK_NONBLOCK],
 570               [have_sock_nonblock=yes], [have_sock_nonblock=no],
 571               [#include <sys/types.h>
 572                #include <sys/socket.h>])
 573 AC_CHECK_DECL([SO_PASSCRED],
 574               [have_so_passcred=yes], [have_so_passcred=no],
 575               [#include <sys/types.h>
 576                #include <sys/socket.h>])
 577
 578 AC_CHECK_FUNCS([ \
 579         cachestat \
 580         clearenv \
 581         close_range \
 582         eaccess \
 583         err \
 584         errx \
 585         explicit_bzero \
 586         __fpending \
 587         __fpurge \
 588         fpurge \
 589         fnmatch \
 590         fsconfig \
 591         fsmount \
 592         fsopen \
 593         fspick \
 594         fsync \
 595         getdomainname \
 596         getdtablesize \
 597         getexecname \
 598         getmntinfo \
 599         getrandom \
 600         getrlimit \
 601         getsgnam \
 602         getttynam \
 603         inotify_init \
 604         jrand48 \
 605         landlock_create_ruleset \
 606         landlock_add_rule \
 607         landlock_restrict_self \
 608         lchown \
 609         lgetxattr \
 610         llistxattr \
 611         llseek \
 612         newlocale \
 613         mempcpy \
 614         mkostemp \
 615         move_mount \
 616         mount_setattr \
 617         nanosleep \
 618         ntp_gettime \
 619         open_tree \
 620         personality \
 621         pidfd_open \
 622         pidfd_send_signal \
 623         posix_fadvise \
 624         prctl \
 625         qsort_r \
 626         reallocarray \
 627         renameat2 \
 628         rpmatch \
 629         scandirat \
 630         sched_setattr \
 631         sched_setscheduler \
 632         __secure_getenv \
 633         secure_getenv \
 634         sendfile \
 635         setprogname \
 636         setresgid \
 637         setresuid \
 638         sigqueue \
 639         srandom \
 640         statx \
 641         strnchr \
 642         strndup \
 643         strnlen \
 644         strtod_l \
 645         sysconf \
 646         sysinfo \
 647         timegm \
 648         usleep \
 649         uselocale \
 650         utimensat \
 651         vwarnx \
 652         warn \
 653         warnx \
 654 ])
 655 AC_FUNC_FSEEKO
 656
 657 AC_CHECK_FUNCS([futimens], [have_futimens=yes])
 658 AC_CHECK_FUNCS([getusershell], [have_getusershell=yes],[have_getusershell=no])
 659 AC_CHECK_FUNCS([inotify_init1], [have_inotify_init1=yes])
 660 AC_CHECK_FUNCS([ioperm iopl], [have_io=yes])
 661 AC_CHECK_FUNCS([openat fstatat unlinkat], [have_openat=yes], [have_openat=no])
 662 AC_CHECK_FUNCS([open_memstream], [have_open_memstream=yes],[have_open_memstream=no])
 663 AC_CHECK_FUNCS([reboot], [have_reboot=yes],[have_reboot=no])
 664 AC_CHECK_FUNCS([updwtmpx updwtmpx], [have_gnu_utmpx=yes], [have_gnu_utmpx=no])
 665
 666 AM_CONDITIONAL([HAVE_OPENAT], [test "x$have_openat" = xyes])
 667 AM_CONDITIONAL([HAVE_LINUX_LANDLOCK_H], [test "x$ac_cv_header_linux_landlock_h" = xyes])
 668
 669 have_setns_syscall="yes"
 670 UL_CHECK_SYSCALL([setns])
 671 AS_IF([test "x$ul_cv_syscall_setns" = xno], [
 672    have_setns_syscall="no"
 673 ])
 674
 675 UL_CHECK_SYSCALL([pidfd_open])
 676 UL_CHECK_SYSCALL([pidfd_send_signal])
 677 UL_CHECK_SYSCALL([close_range])
 678 UL_CHECK_SYSCALL([fsconfig])
 679 UL_CHECK_SYSCALL([fsmount])
 680 UL_CHECK_SYSCALL([fsopen])
 681 UL_CHECK_SYSCALL([fspick])
 682 UL_CHECK_SYSCALL([mount_setattr])
 683 UL_CHECK_SYSCALL([move_mount])
 684 UL_CHECK_SYSCALL([open_tree])
 685
 686 AS_IF([test "x$ul_cv_syscall_fsconfig" = xno ||
 687        test "x$ul_cv_syscall_fsmount" = xno ||
 688        test "x$ul_cv_syscall_fsopen" = xno ||
 689        test "x$ul_cv_syscall_fspick" = xno ||
 690        test "x$ul_cv_syscall_mount_setattr" = xno ||
 691        test "x$ul_cv_syscall_move_mount" = xno ||
 692        test "x$ul_cv_syscall_open_tree" = xno],
 693    [
 694         have_mountfd_api="no"
 695    ],[
 696         have_mountfd_api="yes"
 697         AC_DEFINE([HAVE_MOUNTFD_API], [1], [Define to 1 if you want mount API based on FDs.])
 698    ])
 699
 700
 701 AC_CHECK_FUNCS([isnan], [],
 702         [AC_CHECK_LIB([m], [isnan], [MATH_LIBS="-lm"])]
 703         [AC_CHECK_LIB([m], [__isnan], [MATH_LIBS="-lm"])]
 704 )
 705 AC_SUBST([MATH_LIBS])
 706
 707
 708 dnl lib/mononotic.c may require -lrt
 709 AC_CHECK_FUNCS([clock_gettime], [],
 710         [AC_CHECK_LIB([rt], [clock_gettime], [REALTIME_LIBS="-lrt"])]
 711 )
 712
 713 have_timer="no"
 714 AC_CHECK_FUNCS([timer_create],
 715         [have_timer="yes"],
 716         [AC_CHECK_LIB([rt], [timer_create], [
 717                 have_timer="yes"
 718                 REALTIME_LIBS="-lrt"
 719                 AC_DEFINE([HAVE_TIMER_CREATE], [1], [Define if timer_create exist in -lrt])
 720         ],[
 721                 AC_SEARCH_LIBS([timer_create], [rt], [
 722                         AC_MSG_RESULT(yes)
 723                         have_timer="yes"
 724                         REALTIME_LIBS="-lrt -lpthread"
 725                         AC_DEFINE([HAVE_TIMER_CREATE], [1], [Define if timer_create exist in -lrt -lpthread])
 726                 ],[], [-lpthread]
 727                 )
 728         ])]
 729 )
 730
 731 AC_SUBST([REALTIME_LIBS])
 732
 733 AS_IF([test x"$have_timer" = xno], [
 734        AC_CHECK_FUNCS([setitimer], [have_timer="yes"], [have_timer="no"])
 735 ])
 736
 737
 738 AC_CHECK_LIB([rtas], [rtas_get_sysparm], [
 739         RTAS_LIBS="-lrtas"
 740         AC_DEFINE([HAVE_LIBRTAS], [1], [Define if librtas exists])
 741 ])
 742 AC_SUBST([RTAS_LIBS])
 743
 744
 745 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 746                 AC_DEFINE([HAVE_SA_LEN], [1], [Define if struct sockaddr contains sa_len]), [],
 747         [#include <sys/types.h>
 748          #include <sys/socket.h>])
 749
 750 SOCKET_LIBS=
 751 AC_SEARCH_LIBS([socket], [socket],
 752         [AS_IF([test x"$ac_cv_search_socket" != x"none required"],
 753                 [SOCKET_LIBS="$SOCKET_LIBS -lsocket"])
 754 ])
 755 AC_SUBST([SOCKET_LIBS])
 756
 757
 758 have_dirfd=no
 759 AC_CHECK_FUNCS([dirfd], [have_dirfd=yes], [have_dirfd=no])
 760 AS_IF([test x"$have_dirfd" = xno], [
 761         AC_CHECK_DECLS([dirfd],
 762                 [have_dirfd=yes], [have_dirfd=no],
 763                 [#include <sys/types.h>
 764                  #include <dirent.h>])
 765 ])
 766
 767 have_ddfd=no
 768 AS_IF([test x"$have_dirfd" = xno], [
 769         AC_CHECK_MEMBERS([DIR.dd_fd],
 770                 [have_ddfd=yes], [have_ddfd=no],
 771                 [#include <sys/types.h>
 772                  #include <dirent.h>])
 773 ])
 774
 775 AM_CONDITIONAL([HAVE_DIRFD], [test "x$have_dirfd" = xyes || test "x$have_ddfd" = xyes])
 776
 777 MQ_LIBS=
 778 AC_CHECK_LIB([rt], [mq_open], [MQ_LIBS="-lrt"])
 779 AC_SUBST([MQ_LIBS])
 780
 781 AC_MSG_CHECKING([whether program_invocation_short_name is defined])
 782 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 783         #include <errno.h>
 784 ]], [[
 785         program_invocation_short_name = "test";
 786 ]])], [
 787         AC_MSG_RESULT([yes])
 788         AC_DEFINE([HAVE_PROGRAM_INVOCATION_SHORT_NAME], [1],
 789                 [Define if program_invocation_short_name is defined])
 790 ], [
 791         AC_MSG_RESULT([no])
 792 ])
 793
 794
 795 AC_MSG_CHECKING([whether __progname is defined])
 796 AC_LINK_IFELSE([AC_LANG_PROGRAM([extern char *__progname;],
 797            [if (*__progname == 0) return 1;])],
 798            AC_DEFINE([HAVE___PROGNAME], [1], [Define if __progname is defined])
 799            AC_MSG_RESULT([yes]),
 800            AC_MSG_RESULT([no]))
 801
 802 AC_CHECK_DECL([IOC_OPAL_GET_STATUS],
 803         [AC_DEFINE([HAVE_OPAL_GET_STATUS], [1],
 804                 [Define to 1 if OPAL status ioctl is defined])],,
 805               [#include <linux/sed-opal.h>])
 806
 807 dnl Static compilation
 808 m4_define([UL_STATIC_PROGRAMS], [blkid, fdisk, losetup, mount, nsenter, partx, sfdisk, umount, unshare])
 809
 810 AC_ARG_ENABLE([static-programs],
 811   [AS_HELP_STRING([--enable-static-programs=LIST],
 812       [link static the programs in LIST (comma-separated,
 813       supported for ]m4_defn([UL_STATIC_PROGRAMS])[)])])
 814
 815 AS_CASE([$enable_static_programs],
 816   [yes],
 817     [enable_static_programs=m4_quote(UL_STATIC_PROGRAMS)],
 818   [no],
 819     [enable_static_programs=]
 820 )
 821
 822 dnl Set all the individual AM_CONDITIONALs
 823 m4_foreach([UL_PRG], m4_defn([UL_STATIC_PROGRAMS]), [
 824   AS_CASE([,$enable_static_programs,],
 825    [*,UL_PRG,*], [static_[]UL_PRG=yes]
 826   )
 827   AS_IF([test "x$static_[]UL_PRG" = xyes], [AC_MSG_NOTICE([enable static build: UL_PRG.])])
 828   AM_CONDITIONAL([HAVE_STATIC_]m4_toupper(UL_PRG),
 829     [test "x$static_[]UL_PRG" = xyes])
 830 ])
 831
 832
 833 AC_ARG_ENABLE([all-programs],
 834   AS_HELP_STRING([--disable-all-programs], [disable everything, might be overridden by --enable-<name>]),
 835   [], [enable_all_programs=undefined]
 836 )
 837
 838 AS_CASE([$enable_all_programs],
 839   [yes], [AC_MSG_WARN([force to build all programs by default])
 840           ul_default_estate=check],
 841   [no],  [AC_MSG_WARN([disable all programs and man pages by default])
 842           ul_default_estate=no]
 843 )
 844
 845
 846 AC_ARG_ENABLE([asciidoc],
 847   AS_HELP_STRING([--disable-asciidoc], [do not generate man pages from asciidoc]),
 848   [], [UL_DEFAULT_ENABLE([asciidoc], [check])]
 849 )
 850 UL_BUILD_INIT([asciidoc])
 851 UL_REQUIRES_PROGRAM([asciidoc], [ASCIIDOCTOR], [asciidoctor], [man pages])
 852 AM_CONDITIONAL([ENABLE_ASCIIDOC], [test "x$build_asciidoc" = xyes])
 853 have_asciidoctor_failure_level=no
 854 AS_IF([test "x$build_asciidoc" = xyes], [
 855        AC_MSG_CHECKING([whether ${ASCIIDOCTOR} supports --failure-level])
 856        AS_IF([${ASCIIDOCTOR} --help | grep failure-level >/dev/null 2>&1 ], [
 857          AC_MSG_RESULT([yes])
 858          have_asciidoctor_failure_level=yes
 859        ], [
 860          AC_MSG_RESULT([no])
 861        ])
 862 ])
 863 AM_CONDITIONAL([HAVE_ASCIIDOCTOR_FAILURE_LEVEL], [test "x$have_asciidoctor_failure_level" = xyes])
 864
 865 have_manpages=no
 866 AS_IF([test -f "$srcdir/sys-utils/mount.8"], [
 867    AC_MSG_NOTICE([re-use already generated man-pages.])
 868    have_manpages=yes]
 869 )
 870 AM_CONDITIONAL([HAVE_MANPAGES], [test "x$have_manpages" = xyes])
 871
 872
 873 AC_ARG_ENABLE([poman],
 874   AS_HELP_STRING([--disable-poman], [generate translated man pages]),
 875   [], [UL_DEFAULT_ENABLE([poman], [check])]
 876 )
 877 UL_BUILD_INIT([poman])
 878 UL_REQUIRES_PROGRAM([poman], [PO4A], [po4a], [translated man pages])
 879 AM_CONDITIONAL([ENABLE_POMAN], [test "x$build_poman" = xyes])
 880
 881
 882 AX_CHECK_TLS
 883
 884 have_pty=no
 885 AC_ARG_WITH([util], AS_HELP_STRING([--without-util], [compile without libutil]),
 886   [], [with_util=auto]
 887 )
 888 AS_IF([test "x$with_util" = xno], [
 889   AM_CONDITIONAL([HAVE_UTIL], [false])
 890   have_util=no
 891 ], [
 892   UL_CHECK_LIB([util], [openpty])
 893 ])
 894
 895 AS_IF([test "x$have_pty_h" = xyes && test "x$have_sys_signalfd_h" = xyes && test "x$have_util" = xyes], [
 896    AM_CONDITIONAL([HAVE_PTY], [true])
 897    AC_DEFINE([HAVE_PTY], [1], [have PTY support])
 898    have_pty=yes
 899 ], [
 900    AM_CONDITIONAL([HAVE_PTY], [false])
 901 ])
 902
 903 AC_CHECK_TYPES([union semun], [], [], [[
 904 #include <sys/sem.h>
 905 ]])
 906 AC_CHECK_TYPES([loff_t])
 907
 908
 909 AC_ARG_ENABLE([widechar],
 910   AS_HELP_STRING([--disable-widechar], [do not compile wide character support]),
 911   [], [enable_widechar=check]
 912 )
 913 UL_BUILD_INIT([widechar])
 914 UL_REQUIRES_COMPILE([widechar], [[
 915   #include <wchar.h>
 916   #include <wctype.h>
 917   #include <stdio.h>
 918   #include <stdlib.h>
 919   ]], [[
 920     wchar_t wc;
 921     wint_t w;
 922     w = fgetwc(stdin);
 923     if (w == WEOF) exit(1);
 924     wc = w;
 925     fputwc(wc,stdout);
 926   ]],
 927   [wchar_t support])
 928
 929 AS_IF([test "x$build_widechar" = xyes ], [
 930   AC_DEFINE([HAVE_WIDECHAR], [1], [Do we have wide character support?])
 931 ])
 932
 933
 934 AC_CHECK_TYPES([cpu_set_t], [have_cpu_set_t=yes], [], [[
 935 #include <sched.h>
 936 ]])
 937
 938 AM_CONDITIONAL([HAVE_CPU_SET_T], [test "x$have_cpu_set_t" = xyes])
 939
 940 AC_CHECK_TYPES([sighandler_t], [], [], [[
 941 #include <signal.h>
 942 ]])
 943
 944 AC_CHECK_DECLS([CPU_ALLOC], [], [], [[
 945 #include <sched.h>
 946 ]])
 947
 948 # on Solaris, you can't mix and match standards, since we use c99
 949 # apparently at this stage, XOPEN_SOURCE will conflict.  As workaround,
 950 # check for crypt.h and use that without XOPEN_SOURCE.
 951 have_crypt=no
 952 AC_CHECK_HEADERS([crypt.h])
 953 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 954 #ifdef HAVE_CRYPT_H
 955 #include <crypt.h>
 956 #else
 957 #define _XOPEN_SOURCE
 958 #include <unistd.h>
 959 #endif
 960 ]], [[
 961 char *c = crypt("abc","pw");
 962 ]])],[
 963   have_libcrypt=no
 964   have_crypt=yes
 965 ],[
 966   UL_SET_LIBS([-lcrypt])
 967   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 968   #ifdef HAVE_CRYPT_H
 969   #include <crypt.h>
 970   #else
 971   #define _XOPEN_SOURCE
 972   #include <unistd.h>
 973   #endif
 974   ]], [[
 975   char *c = crypt("abc","pw");
 976   ]])],[
 977   have_libcrypt=yes
 978   have_crypt=yes
 979   ],[
 980   AC_MSG_WARN([crypt() is not available])
 981   ])
 982   UL_RESTORE_LIBS
 983 ])
 984 AM_CONDITIONAL([HAVE_LIBCRYPT], [test "x$have_libcrypt" = xyes])
 985
 986
 987 AC_ARG_WITH([selinux],
 988   AS_HELP_STRING([--with-selinux], [compile with SELinux support]),
 989   [], [with_selinux=no]
 990 )
 991
 992 AS_IF([test "x$with_selinux" = xno], [
 993   AM_CONDITIONAL([HAVE_SELINUX], [false])
 994 ], [
 995   PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.5], [have_selinux=yes], [have_selinux=no])
 996   AS_CASE([$with_selinux:$have_selinux],
 997     [yes:no], [AC_MSG_ERROR([SELinux selected but libselinux not found or too old])]
 998   )
 999   AS_IF([test "x$have_selinux" = xyes], [
1000     AC_DEFINE([HAVE_LIBSELINUX], [1], [Define if SELinux is available])
1001     UL_PKG_STATIC([SELINUX_LIBS_STATIC], [libselinux])
1002     AM_CONDITIONAL([HAVE_SELINUX], [true])
1003
1004     UL_SET_LIBS([$SELINUX_LIBS])
1005     # This function is missing in old libselinux 1.xx versions
1006     AC_CHECK_FUNCS([security_get_initial_context])
1007     UL_RESTORE_LIBS
1008   ])
1009 ])
1010 AC_SUBST([SELINUX_LIBS])
1011 AC_SUBST([SELINUX_LIBS_STATIC])
1012
1013
1014 AC_ARG_WITH([audit],
1015   AS_HELP_STRING([--with-audit], [compile with audit support]),
1016   [], [with_audit=no]
1017 )
1018
1019 AS_IF([test "x$with_audit" = xno], [
1020   AM_CONDITIONAL([HAVE_AUDIT], [false])
1021 ], [
1022   UL_CHECK_LIB([audit], [audit_log_user_message])
1023   AS_CASE([$with_audit:$have_audit],
1024     [yes:no],
1025       [AC_MSG_ERROR([Audit selected but libaudit not found (or does not support audit_log_user_message())])]
1026   )
1027 ])
1028
1029 AC_ARG_WITH([udev], AS_HELP_STRING([--without-udev], [compile without udev support]),
1030   [], [with_udev=auto]
1031 )
1032
1033 AS_IF([test "x$with_udev" = xno], [
1034   AM_CONDITIONAL([HAVE_UDEV], [false])
1035 ], [
1036   UL_CHECK_LIB([udev], [udev_new])
1037   AS_CASE([$with_udev:$have_udev],
1038     [yes:no],
1039       [AC_MSG_ERROR([udev selected but libudev not found])]
1040   )
1041 ])
1042
1043
1044 dnl wide-char ncurses
1045 AC_ARG_WITH([ncursesw],
1046   AS_HELP_STRING([--without-ncursesw], [do not build with wide-char ncurses]),
1047   [], [with_ncursesw=auto]
1048 )
1049 have_ncursesw=no
1050 have_ncursesw_header=no
1051 AS_IF([test "x$with_ncursesw" != xno], [
1052   UL_NCURSES_CHECK([ncursesw])
1053   AS_IF([test "x$have_ncursesw" = xyes], [
1054     AC_CHECK_HEADERS([ncursesw/ncurses.h], [have_ncursesw_header=yes])
1055     AC_CHECK_HEADERS([ncursesw/term.h])
1056
1057     # Define HAVE_NCURSES_H only if check for HAVE_NCURSESW_NCURSES_H is
1058     # unsuccessful to avoid too many *_H permitations in config.h
1059     AS_IF([test "x$have_ncursesw_header" = xno], [
1060            AC_CHECK_HEADERS([ncurses.h], [have_ncursesw_header=yes])
1061            AC_CHECK_HEADERS([term.h])
1062     ])
1063     AS_IF([test "x$have_ncursesw_header" = xno], [have_ncursesw=no])
1064   ])
1065   AS_IF([test "x$have_ncursesw" = xyes], [
1066     CURSES_LIB_NAME="ncursesw"
1067     AC_DEFINE([HAVE_LIBNCURSESW], [1], [Define if ncursesw library available])
1068   ])
1069 ])
1070 AS_CASE([$with_ncursesw:$have_ncursesw],
1071   [yes:no], [AC_MSG_ERROR([ncursesw selected, but library not found])])
1072
1073
1074 dnl non-wide ncurses
1075 AC_ARG_WITH([ncurses],
1076   AS_HELP_STRING([--with-ncurses], [build with non-wide ncurses]),
1077   [], [with_ncurses=auto]
1078 )
1079 have_ncurses=no
1080 have_ncurses_header=no
1081 AS_CASE([$with_ncurses:$build_widechar],
1082   [yes:yes], [AC_MSG_ERROR([wide-char support enabled, but non-wide ncurses selects])])
1083
1084 AS_IF([test "x$have_ncursesw" = xno && test "x$with_ncurses" != xno ], [
1085   UL_NCURSES_CHECK([ncurses])
1086   AS_IF([test "x$have_ncurses" = xyes], [
1087     AC_CHECK_HEADERS([ncurses/ncurses.h], [have_ncurses_header=yes])
1088     AC_CHECK_HEADERS([ncurses/term.h])
1089
1090     # Define HAVE_NCURSES_H only if check for HAVE_NCURSES_NCURSES_H is
1091     # unsuccessful to avoid too many *_H permitations in config.h
1092     AS_IF([test "x$have_ncurses_header" = xno], [
1093            AC_CHECK_HEADERS([ncurses.h], [have_ncurses_header=yes])
1094            AC_CHECK_HEADERS([term.h])
1095     ])
1096     AS_IF([test "x$have_ncurses_header" = xno], [have_ncurses=no])
1097   ])
1098   AS_IF([test "x$have_ncurses" = xyes], [
1099     CURSES_LIB_NAME="ncurses"
1100     AC_DEFINE([HAVE_LIBNCURSES], [1], [Define if ncurses library available])
1101   ])
1102 ])
1103 AS_CASE([$with_ncurses:$have_ncurses],
1104   [yes:no], [AC_MSG_ERROR([ncurses selected, but library not found])])
1105
1106 AC_SUBST([NCURSES_CFLAGS])
1107 AC_SUBST([NCURSES_LIBS])
1108 AM_CONDITIONAL([HAVE_NCURSES], [test "x$have_ncursesw" = xyes || test "x$have_ncurses" = xyes])
1109
1110
1111 AC_ARG_WITH([slang],
1112   AS_HELP_STRING([--with-slang], [compile cfdisk with slang rather than ncurses]),
1113   [], [with_slang=no]
1114 )
1115 have_slang=no
1116 AS_IF([test "x$with_slang" = xyes], [
1117   AC_CHECK_HEADERS([slang.h slang/slang.h])
1118   AC_CHECK_HEADERS([slcurses.h slang/slcurses.h],
1119                    [have_slang=yes], [], [
1120 #ifdef HAVE_SLANG_H
1121 #include <slang.h>
1122 #elif defined(HAVE_SLANG_SLANG_H)
1123 #include <slang/slang.h>
1124 #endif
1125 ])
1126   AS_IF([test "x$have_slang" = xno], [
1127     AC_MSG_ERROR([slang selected but slcurses.h not found])],
1128     [CURSES_LIB_NAME=slang
1129   ])
1130 ])
1131 AM_CONDITIONAL([HAVE_SLANG], [test "x$have_slang" = xyes])
1132
1133
1134 AS_IF([test "x$have_slang" = xyes || test "x$have_ncursesw" = xyes || test "x$have_ncurses" = xyes], [
1135         AC_CHECK_LIB([$CURSES_LIB_NAME], use_default_colors, [
1136                      AC_DEFINE(HAVE_USE_DEFAULT_COLORS, 1,
1137                                [Define if curses library has the use_default_colors().])
1138         ])
1139         AC_CHECK_LIB([$CURSES_LIB_NAME], resizeterm, [
1140                      AC_DEFINE(HAVE_RESIZETERM, 1,
1141                                [Define if curses library has the resizeterm().])
1142         ])
1143 ])
1144
1145
1146 AC_ARG_WITH([tinfo], AS_HELP_STRING([--without-tinfo], [compile without libtinfo]),
1147   [], [with_tinfo=auto]
1148 )
1149 have_tinfo=no
1150 have_tinfow=no
1151 AS_IF([test "x$with_tinfo" != xno], [
1152   AS_IF([test "x$have_ncursesw" = xyes], [
1153     UL_TINFO_CHECK([tinfow])
1154   ])
1155   AS_IF([test "x$have_tinfow" = xno], [
1156     UL_TINFO_CHECK([tinfo])
1157   ])
1158 ])
1159 AC_SUBST([TINFO_LIBS])
1160 AC_SUBST([TINFO_LIBS_STATIC])
1161 AC_SUBST([TINFO_CFLAGS])
1162 AM_CONDITIONAL([HAVE_TINFO], [test "x$have_tinfo" = xyes || test "x$have_tinfow" = xyes])
1163 AS_IF([test "x$have_tinfo" = xyes || test "x$have_tinfow" = xyes], [
1164   AC_DEFINE(HAVE_LIBTINFO, 1, [Define if libtinfo or libtinfow available.])
1165 ])
1166
1167
1168 AC_ARG_WITH([readline],
1169   AS_HELP_STRING([--without-readline], [do not build with GNU Readline support]),
1170   [], [with_readline=auto]
1171 )
1172
1173 AS_IF([test "x$with_readline" = xno], [
1174   AM_CONDITIONAL([HAVE_READLINE], [false])
1175 ], [
1176   UL_CHECK_LIB([readline], [readline])
1177   AS_CASE([$with_readline:$have_readline],
1178     [yes:no],
1179       [AC_MSG_ERROR([readline selected but libreadline not found ])],
1180     [*:yes],
1181       [READLINE_LIBS="-lreadline"
1182        READLINE_LIBS_STATIC="-lreadline $TINFO_LIBS_STATIC"]
1183   )
1184 ])
1185 AC_SUBST([READLINE_LIBS])
1186 AC_SUBST([READLINE_LIBS_STATIC])
1187
1188
1189 AC_ARG_WITH([utempter],
1190   AS_HELP_STRING([--with-utempter], [compile script(1) with libutempter]),
1191   [], [with_utempter=no]
1192 )
1193
1194 AS_IF([test "x$with_utempter" = xyes], [
1195   UL_CHECK_LIB([utempter], [utempter_add_record])
1196   AS_IF([test "x$have_utempter" = xno], [
1197     AC_MSG_ERROR([utempter selected but libutempter not found])
1198   ])
1199 ], [
1200   AM_CONDITIONAL([HAVE_UTEMPTER], [false])
1201 ])
1202
1203
1204 dnl
1205 dnl libuuid
1206 dnl
1207 AC_ARG_ENABLE([libuuid],
1208   AS_HELP_STRING([--disable-libuuid], [do not build libuuid and uuid utilities]),
1209   [], [UL_DEFAULT_ENABLE([libuuid], [yes])]
1210 )
1211 UL_BUILD_INIT([libuuid])
1212 AC_SUBST([LIBUUID_VERSION])
1213 AC_SUBST([LIBUUID_VERSION_INFO])
1214 AM_CONDITIONAL(BUILD_LIBUUID, test "x$build_libuuid" = xyes)
1215
1216 AC_ARG_ENABLE([libuuid-force-uuidd],
1217   AS_HELP_STRING([--enable-libuuid-force-uuidd], [support uuidd even though the daemon is not built]),
1218   [], [enable_libuuid_force_uuidd=no]
1219 )
1220
1221 AS_IF([test "x$build_libuuid" = xyes], [
1222   AC_DEFINE(HAVE_LIBUUID, 1, [Define to 1 if you have the -luuid.])
1223 ])
1224
1225 dnl
1226 dnl liblastlog2
1227 dnl
1228 AC_ARG_ENABLE([liblastlog2],
1229   AS_HELP_STRING([--disable-liblastlog2], [do not build liblastlog2 and lastlog2 utilities]),
1230   [], [UL_DEFAULT_ENABLE([liblastlog2], [yes])]
1231 )
1232 UL_BUILD_INIT([liblastlog2])
1233
1234 have_sqlite3=no
1235 AS_IF([test "x$build_liblastlog2" = xyes], [
1236   PKG_CHECK_MODULES([SQLITE3], [sqlite3], [have_sqlite3=yes], [have_sqlite3=no])
1237 ])
1238 UL_REQUIRES_HAVE([liblastlog2], [sqlite3], [sqlite3 library])
1239 AC_SUBST([SQLITE3_LIBS])
1240
1241 AC_SUBST([LIBLASTLOG2_VERSION])
1242 AC_SUBST([LIBLASTLOG2_VERSION_INFO])
1243 AC_DEFINE_UNQUOTED([LIBLASTLOG2_VERSION], ["$LIBLASTLOG2_VERSION"], [liblastlog2 version string])
1244 AM_CONDITIONAL([BUILD_LIBLASTLOG2], [test "x$build_liblastlog2" = xyes])
1245 AM_CONDITIONAL([BUILD_LIBLASTLOG2_TESTS], [test "x$build_liblastlog2" = xyes && test "x$enable_static" = xyes])
1246
1247
1248 AC_ARG_ENABLE([pam_lastlog2],
1249   AS_HELP_STRING([--disable-pam-lastlog2], [do not build PAM lastlog2 module]),
1250   [], [UL_DEFAULT_ENABLE([pam_lastlog2], [check])]
1251 )
1252 UL_BUILD_INIT([pam_lastlog2])
1253 UL_REQUIRES_BUILD([pam_lastlog2], [liblastlog2])
1254 UL_REQUIRES_HAVE([pam_lastlog2], [security_pam_modules_h], [pam_modules.h header file])
1255 AM_CONDITIONAL([BUILD_PAM_LASTLOG2], [test "x$build_pam_lastlog2" = xyes])
1256
1257
1258 dnl
1259 dnl libblkid
1260 dnl
1261 AC_ARG_ENABLE([libblkid],
1262   AS_HELP_STRING([--disable-libblkid], [do not build libblkid and many related utilities]),
1263   [], [UL_DEFAULT_ENABLE([libblkid], [check])]
1264 )
1265 UL_BUILD_INIT([libblkid])
1266 UL_REQUIRES_HAVE([libblkid], [openat], [openat functions])
1267 UL_REQUIRES_HAVE([libblkid], [dirfd,ddfd], [dirfd or ddfd function])
1268 AC_SUBST([LIBBLKID_DATE])
1269 AC_SUBST([LIBBLKID_VERSION])
1270 AC_SUBST([LIBBLKID_VERSION_INFO])
1271 AC_DEFINE_UNQUOTED([LIBBLKID_VERSION], ["$LIBBLKID_VERSION"], [libblkid version string])
1272 AC_DEFINE_UNQUOTED([LIBBLKID_DATE], ["$LIBBLKID_DATE"], [libblkid date string])
1273 AS_IF([test "x$build_libblkid" = xyes], [
1274   AC_DEFINE([HAVE_LIBBLKID], [1], [Define to 1 if you have the -lblkid.])
1275 ])
1276 AM_CONDITIONAL([BUILD_LIBBLKID], [test "x$build_libblkid" = xyes])
1277 AM_CONDITIONAL([BUILD_LIBBLKID_TESTS], [test "x$build_libblkid" = xyes && test "x$enable_static" = xyes])
1278
1279 dnl
1280 dnl libmount
1281 dnl
1282 AC_ARG_ENABLE([libmount],
1283   AS_HELP_STRING([--disable-libmount], [do not build libmount]),
1284   [], [UL_DEFAULT_ENABLE([libmount], [check])]
1285 )
1286 UL_BUILD_INIT([libmount])
1287 UL_REQUIRES_BUILD([libmount], [libblkid])
1288 UL_REQUIRES_HAVE([libmount], [dirfd,ddfd], [dirfd or ddfd function])
1289 UL_REQUIRES_HAVE([libmount], [mntent_h], [mntent.h header file])
1290 AM_CONDITIONAL([BUILD_LIBMOUNT], [test "x$build_libmount" = xyes])
1291 AM_CONDITIONAL([BUILD_LIBMOUNT_TESTS], [test "x$build_libmount" = xyes && test "x$enable_static" = xyes])
1292 AS_IF([test "x$build_libmount" = xyes], [
1293   AC_DEFINE(HAVE_LIBMOUNT, 1, [Define if libmount available.])
1294   AS_IF([test "x$have_setns_syscall" = "xyes"], [
1295     AC_DEFINE([USE_LIBMOUNT_SUPPORT_NAMESPACES], [1], [Define to 1 if want to support namepaces.])
1296   ],[
1297     AC_MSG_WARN([libmount will be compiled without namespaces support])
1298   ])
1299 ])
1300
1301 AC_SUBST([LIBMOUNT_VERSION])
1302 AC_SUBST([LIBMOUNT_MAJOR_VERSION], $PACKAGE_VERSION_MAJOR)
1303 AC_SUBST([LIBMOUNT_MINOR_VERSION], $PACKAGE_VERSION_MINOR)
1304 AC_SUBST([LIBMOUNT_PATCH_VERSION], $PACKAGE_VERSION_RELEASE)
1305 AC_SUBST([LIBMOUNT_VERSION_INFO])
1306 AC_DEFINE_UNQUOTED([LIBMOUNT_VERSION], ["$LIBMOUNT_VERSION"], [libmount version string])
1307
1308 AC_ARG_ENABLE([libmount-mountfd-support],
1309   AS_HELP_STRING([--disable-libmount-mountfd-support], [do not use new mount API based on FDs]),
1310   [], [enable_libmount_mountfd_support=check]
1311 )
1312 UL_BUILD_INIT([libmount_mountfd_support])
1313 UL_REQUIRES_BUILD([libmount_mountfd_support], [libmount])
1314 UL_REQUIRES_LINUX([libmount_mountfd_support])
1315 UL_REQUIRES_HAVE([libmount_mountfd_support], [mountfd_api], [mount FDs based API])
1316 UL_REQUIRES_HAVE([libmount_mountfd_support], [linux_mount_h], [linux/mount.h])
1317 AS_IF([test "x$build_libmount_mountfd_support" = xyes ], [
1318   AC_DEFINE([USE_LIBMOUNT_MOUNTFD_SUPPORT], [1], [Enable support for new mount FD based kernel API])
1319 ])
1320
1321
1322 dnl
1323 dnl libsmartcols
1324 dnl
1325 AC_ARG_ENABLE([libsmartcols],
1326   AS_HELP_STRING([--disable-libsmartcols], [do not build libsmartcols]),
1327   [], [UL_DEFAULT_ENABLE([libsmartcols], [yes])]
1328 )
1329 UL_BUILD_INIT([libsmartcols])
1330 AM_CONDITIONAL([BUILD_LIBSMARTCOLS], [test "x$build_libsmartcols" = xyes])
1331
1332 AC_SUBST([LIBSMARTCOLS_VERSION])
1333 AC_SUBST([LIBSMARTCOLS_VERSION_INFO])
1334 AC_DEFINE_UNQUOTED([LIBSMARTCOLS_VERSION], ["$LIBSMARTCOLS_VERSION"], [libsmartcols version string])
1335
1336
1337 dnl
1338 dnl libfdisk
1339 dnl
1340 AC_ARG_ENABLE([libfdisk],
1341   AS_HELP_STRING([--disable-libfdisk], [do not build libfdisk]),
1342   [], [UL_DEFAULT_ENABLE([libfdisk], [check])]
1343 )
1344 UL_BUILD_INIT([libfdisk])
1345 UL_REQUIRES_BUILD([libfdisk], [libuuid])
1346 AM_CONDITIONAL([BUILD_LIBFDISK], [test "x$build_libfdisk" = xyes])
1347 AM_CONDITIONAL([BUILD_LIBFDISK_TESTS], [test "x$build_libfdisk" = xyes && test "x$enable_static" = xyes])
1348
1349 AS_IF([test "x$build_libblkid" = xyes],
1350   [LIBFDISK_PC_REQUIRES="uuid blkid"],[LIBFDISK_PC_REQUIRES="uuid"])
1351 AC_SUBST([LIBFDISK_PC_REQUIRES])
1352
1353 AC_SUBST([LIBFDISK_VERSION])
1354 AC_SUBST([LIBFDISK_MAJOR_VERSION], $PACKAGE_VERSION_MAJOR)
1355 AC_SUBST([LIBFDISK_MINOR_VERSION], $PACKAGE_VERSION_MINOR)
1356 AC_SUBST([LIBFDISK_PATCH_VERSION], $PACKAGE_VERSION_RELEASE)
1357 AC_SUBST([LIBFDISK_VERSION_INFO])
1358 AC_DEFINE_UNQUOTED([LIBFDISK_VERSION], ["$LIBFDISK_VERSION"], [libfdisk version string])
1359
1360
1361 AC_ARG_ENABLE([fdisks],
1362   AS_HELP_STRING([--disable-fdisks], [do not build fdisk(8), sfdisk(8) and cfdisk(8)]),
1363   [], [UL_DEFAULT_ENABLE([fdisks], [check])]
1364 )
1365 enable_fdisk=$enable_fdisks
1366 enable_sfdisk=$enable_fdisks
1367 enable_cfdisk=$enable_fdisks
1368
1369 UL_BUILD_INIT([fdisk])
1370 UL_REQUIRES_HAVE([fdisk], [openat], [openat functions])
1371 UL_REQUIRES_HAVE([fdisk], [dirfd,ddfd], [dirfd or ddfd function])
1372 UL_REQUIRES_BUILD([fdisk], [libfdisk])
1373 UL_REQUIRES_BUILD([fdisk], [libsmartcols])
1374 AM_CONDITIONAL([BUILD_FDISK], [test "x$build_fdisk" = xyes])
1375
1376
1377 UL_BUILD_INIT([sfdisk])
1378 UL_REQUIRES_HAVE([sfdisk], [openat], [openat functions])
1379 UL_REQUIRES_HAVE([sfdisk], [dirfd,ddfd], [dirfd or ddfd function])
1380 UL_REQUIRES_BUILD([sfdisk], [libfdisk])
1381 UL_REQUIRES_BUILD([sfdisk], [libsmartcols])
1382 AM_CONDITIONAL([BUILD_SFDISK], [test "x$build_sfdisk" = xyes])
1383
1384
1385 UL_BUILD_INIT([cfdisk])
1386 UL_REQUIRES_BUILD([cfdisk], [libfdisk])
1387 UL_REQUIRES_BUILD([cfdisk], [libsmartcols])
1388 UL_REQUIRES_HAVE([cfdisk], [open_memstream], [open_memstream function])
1389 UL_REQUIRES_HAVE([cfdisk], [ncursesw,slang,ncurses], [ncursesw, ncurses or slang library])
1390 AM_CONDITIONAL([BUILD_CFDISK], [test "x$build_cfdisk" = xyes])
1391
1392
1393 AC_ARG_ENABLE([mount],
1394   AS_HELP_STRING([--disable-mount], [do not build mount(8) and umount(8)]),
1395   [], [UL_DEFAULT_ENABLE([mount], [check])]
1396 )
1397 UL_BUILD_INIT([mount])
1398 UL_REQUIRES_LINUX([mount])
1399 UL_REQUIRES_BUILD([mount], [libmount])
1400 AM_CONDITIONAL([BUILD_MOUNT], [test "x$build_mount" = xyes])
1401
1402
1403 AC_ARG_ENABLE([losetup],
1404   AS_HELP_STRING([--disable-losetup], [do not build losetup]),
1405   [], [UL_DEFAULT_ENABLE([losetup], [check])]
1406 )
1407 UL_BUILD_INIT([losetup])
1408 UL_REQUIRES_LINUX([losetup])
1409 UL_REQUIRES_BUILD([losetup], [libsmartcols])
1410 AM_CONDITIONAL([BUILD_LOSETUP], [test "x$build_losetup" = xyes])
1411
1412 AC_ARG_ENABLE([zramctl],
1413   AS_HELP_STRING([--disable-zramctl], [do not build zramctl]),
1414   [], [UL_DEFAULT_ENABLE([zramctl], [check])]
1415 )
1416 UL_BUILD_INIT([zramctl])
1417 UL_REQUIRES_LINUX([zramctl])
1418 UL_REQUIRES_BUILD([zramctl], [libsmartcols])
1419 AM_CONDITIONAL([BUILD_ZRAMCTL], [test "x$build_zramctl" = xyes])
1420
1421 AC_ARG_ENABLE([fsck],
1422   AS_HELP_STRING([--disable-fsck], [do not build fsck]),
1423   [], [UL_DEFAULT_ENABLE([fsck], [check])]
1424 )
1425 UL_BUILD_INIT([fsck])
1426 UL_REQUIRES_BUILD([fsck], [libmount])
1427 AM_CONDITIONAL([BUILD_FSCK], [test "x$build_fsck" = xyes])
1428
1429
1430 AC_ARG_ENABLE([partx],
1431   AS_HELP_STRING([--disable-partx], [do not build addpart, delpart, partx]),
1432   [], [UL_DEFAULT_ENABLE([partx], [check])]
1433 )
1434 UL_BUILD_INIT([partx])
1435 UL_REQUIRES_LINUX([partx])
1436 UL_REQUIRES_BUILD([partx], [libblkid])
1437 UL_REQUIRES_BUILD([partx], [libsmartcols])
1438 AM_CONDITIONAL([BUILD_PARTX], [test "x$build_partx" = xyes])
1439
1440
1441 AC_ARG_ENABLE([uuidd],
1442   AS_HELP_STRING([--disable-uuidd], [do not build the uuid daemon]),
1443   [], [UL_DEFAULT_ENABLE([uuidd], [check])]
1444 )
1445 UL_BUILD_INIT([uuidd])
1446 UL_REQUIRES_BUILD([uuidd], [libuuid])
1447 UL_REQUIRES_HAVE([uuidd], [timer], [timer_create function])
1448 UL_REQUIRES_HAVE([uuidd], [sys_signalfd_h], [sys/signalfd.h header])
1449 AS_IF([test "x$build_uuidd" = xyes || test "x$enable_libuuid_force_uuidd" = xyes], [
1450   AC_DEFINE([HAVE_UUIDD], [1], [Define to 1 if you want to use uuid daemon.])
1451 ])
1452 AM_CONDITIONAL([BUILD_UUIDD], [test "x$build_uuidd" = xyes])
1453
1454
1455 AC_ARG_ENABLE([uuidgen],
1456   AS_HELP_STRING([--disable-uuidgen], [do not build uuidgen]),
1457   [], [UL_DEFAULT_ENABLE([uuidgen], [check])]
1458 )
1459 UL_BUILD_INIT([uuidgen])
1460 UL_REQUIRES_BUILD([uuidgen], [libuuid])
1461 AM_CONDITIONAL([BUILD_UUIDGEN], [test "x$build_uuidgen" = xyes])
1462
1463 UL_BUILD_INIT([uuidparse], [check])
1464 UL_REQUIRES_BUILD([uuidparse], [libuuid])
1465 UL_REQUIRES_BUILD([uuidparse], [libsmartcols])
1466 AM_CONDITIONAL([BUILD_UUIDPARSE], [test "x$build_uuidparse" = xyes])
1467
1468 AC_ARG_ENABLE([blkid],
1469   AS_HELP_STRING([--disable-blkid], [do not build blkid(8)]),
1470   [], [UL_DEFAULT_ENABLE([blkid], [check])]
1471 )
1472 UL_BUILD_INIT([blkid])
1473 UL_REQUIRES_BUILD([blkid], [libblkid])
1474 AM_CONDITIONAL([BUILD_BLKID], [test "x$build_blkid" = xyes])
1475
1476 UL_BUILD_INIT([findfs], [check])
1477 UL_REQUIRES_BUILD([findfs], [libblkid])
1478 AM_CONDITIONAL([BUILD_FINDFS], [test "x$build_findfs" = xyes])
1479
1480 AC_ARG_ENABLE([wipefs],
1481   AS_HELP_STRING([--disable-wipefs], [do not build wipefs]),
1482   [], [UL_DEFAULT_ENABLE([wipefs], [check])]
1483 )
1484 UL_BUILD_INIT([wipefs])
1485 UL_REQUIRES_BUILD([wipefs], [libblkid])
1486 UL_REQUIRES_BUILD([wipefs], [libsmartcols])
1487 AM_CONDITIONAL([BUILD_WIPEFS], [test "x$build_wipefs" = xyes])
1488
1489 UL_BUILD_INIT([findmnt], [check])
1490 UL_REQUIRES_BUILD([findmnt], [libmount])
1491 UL_REQUIRES_BUILD([findmnt], [libblkid])
1492 UL_REQUIRES_BUILD([findmnt], [libsmartcols])
1493 AM_CONDITIONAL([BUILD_FINDMNT], [test "x$build_findmnt" = xyes])
1494
1495
1496 AC_ARG_ENABLE([mountpoint],
1497   AS_HELP_STRING([--disable-mountpoint], [do not build mountpoint]),
1498   [], [UL_DEFAULT_ENABLE([mountpoint], [check])]
1499 )
1500 UL_BUILD_INIT([mountpoint])
1501 UL_REQUIRES_BUILD([mountpoint], [libmount])
1502 AM_CONDITIONAL([BUILD_MOUNTPOINT], [test "x$build_mountpoint" = xyes])
1503
1504
1505 AC_ARG_ENABLE([fallocate],
1506   AS_HELP_STRING([--disable-fallocate], [do not build fallocate]),
1507   [], [UL_DEFAULT_ENABLE([fallocate], [check])]
1508 )
1509 UL_BUILD_INIT([fallocate])
1510 UL_REQUIRES_LINUX([fallocate])
1511 UL_REQUIRES_SYSCALL_CHECK([fallocate], [UL_CHECK_SYSCALL([fallocate])])
1512 AM_CONDITIONAL([BUILD_FALLOCATE], [test "x$build_fallocate" = xyes])
1513
1514 AS_IF([test "x$build_fallocate" = xyes], [
1515   dnl check for valid fallocate() function
1516   dnl with 32 bits glibc 2.10, fallocate() exists but not fallocate64()
1517   dnl when _FILE_OFFSET_BITS==64, fallocate() is redirect to fallocate64()
1518   dnl and program can't be linked.
1519   dnl AC_CHECK_FUNC can't catch such errors since it's redefining
1520   dnl function prototype.
1521   AC_MSG_CHECKING([for valid fallocate() function])
1522   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1523 #ifdef HAVE_UNISTD_H
1524 # include <unistd.h>
1525 #endif
1526 #ifdef HAVE_SYS_TYPES_H
1527 # include <sys/types.h>
1528 #endif
1529 #ifdef HAVE_LINUX_FALLOC_H
1530 # include <linux/falloc.h>
1531 #endif
1532 #ifdef HAVE_FCNTL_H
1533 # include <fcntl.h>
1534 #endif
1535 ]],[[
1536    long ret;
1537    ret = fallocate(0, FALLOC_FL_KEEP_SIZE, 0xfffffffful, 0xfffffffful);
1538    if (ret != 0) {
1539       return 1;
1540    }
1541    ]])],[
1542   AC_MSG_RESULT([yes])
1543   AC_DEFINE([HAVE_FALLOCATE], [1], [Have valid fallocate() function])],[
1544   AC_MSG_RESULT([no])])
1545 ])
1546
1547 AS_IF([test "x$build_fallocate" = xyes], [
1548   dnl check for valid posix_fallocate() function
1549   AC_MSG_CHECKING([for valid posix_fallocate() function])
1550   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1551 #ifdef HAVE_UNISTD_H
1552 # include <unistd.h>
1553 #endif
1554 #ifdef HAVE_SYS_TYPES_H
1555 # include <sys/types.h>
1556 #endif
1557 #ifdef HAVE_LINUX_FALLOC_H
1558 # include <linux/falloc.h>
1559 #endif
1560 #ifdef HAVE_FCNTL_H
1561 # include <fcntl.h>
1562 #endif
1563 ]],[[
1564    long ret;
1565    ret = posix_fallocate(0, 0xfffffffful, 0xfffffffful);
1566    if (ret != 0) {
1567       return 1;
1568    }
1569    ]])],[
1570   AC_MSG_RESULT([yes])
1571   AC_DEFINE([HAVE_POSIX_FALLOCATE], [1], [Have valid posix_fallocate() function])],[
1572   AC_MSG_RESULT([no])])
1573 ])
1574
1575
1576 AC_ARG_ENABLE([unshare],
1577   AS_HELP_STRING([--disable-unshare], [do not build unshare]),
1578   [], [UL_DEFAULT_ENABLE([unshare], [check])]
1579 )
1580 UL_BUILD_INIT([unshare])
1581 UL_REQUIRES_LINUX([unshare])
1582 UL_REQUIRES_SYSCALL_CHECK([unshare], [UL_CHECK_SYSCALL([unshare])])
1583 UL_REQUIRES_HAVE([unshare], [linux_capability_h], [linux/capability.h header file])
1584 AM_CONDITIONAL([BUILD_UNSHARE], [test "x$build_unshare" = xyes])
1585
1586 AC_MSG_CHECKING([for valid unshare() function])
1587 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1588 #include <sched.h>
1589 ]],[[
1590    int ret;
1591    ret = unshare(0);
1592    if (ret != 0) {
1593       return 1;
1594    }
1595    ]])],[
1596   AC_MSG_RESULT([yes])
1597   AC_DEFINE([HAVE_UNSHARE], [1], [Have valid unshare() function])],
1598 [
1599   AC_MSG_RESULT([no])
1600 ])
1601
1602
1603 AC_ARG_ENABLE([nsenter],
1604   AS_HELP_STRING([--disable-nsenter], [do not build nsenter]),
1605   [], [UL_DEFAULT_ENABLE([nsenter], [check])]
1606 )
1607 UL_BUILD_INIT([nsenter])
1608 UL_REQUIRES_LINUX([nsenter])
1609 UL_REQUIRES_HAVE([nsenter], [setns_syscall], [setns syscall])
1610 AM_CONDITIONAL([BUILD_NSENTER], [test "x$build_nsenter" = xyes])
1611
1612 AC_MSG_CHECKING([for valid setns() function])
1613 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1614 #include <sched.h>
1615 #include <errno.h>
1616 ]],[[
1617    int ret;
1618    ret = setns(0, 0);
1619    if (ret != EINVAL && ret != EBADF && ret != EPERM) {
1620       return 1;
1621    }
1622    ]])],[
1623   AC_MSG_RESULT([yes])
1624   AC_DEFINE([HAVE_SETNS], [1], [Have valid setns() function])],
1625 [
1626   AC_MSG_RESULT([no])
1627 ])
1628
1629
1630 AC_ARG_WITH([cap_ng],
1631   AS_HELP_STRING([--without-cap-ng], [compile without libcap-ng]),
1632   [], [with_cap_ng=auto]
1633 )
1634 AS_IF([test "x$with_cap_ng" = xno], [
1635   AM_CONDITIONAL([HAVE_CAP_NG], [false])
1636   have_cap_ng=no
1637 ],[
1638   UL_CHECK_LIB([cap-ng], [capng_apply], [cap_ng])
1639 ])
1640
1641
1642 AC_ARG_ENABLE([setpriv],
1643   AS_HELP_STRING([--disable-setpriv], [do not build setpriv]),
1644   [], [UL_DEFAULT_ENABLE([setpriv], [check])]
1645 )
1646 UL_BUILD_INIT([setpriv])
1647 UL_REQUIRES_LINUX([setpriv])
1648 UL_REQUIRES_HAVE([setpriv], [linux_securebits_h], [linux/securebits.h header file])
1649 UL_REQUIRES_HAVE([setpriv], [linux_capability_h], [linux/capability.h header file])
1650 UL_REQUIRES_HAVE([setpriv], [cap_ng], [libcap-ng library])
1651 AM_CONDITIONAL([BUILD_SETPRIV], [test "x$build_setpriv" = xyes])
1652
1653 AC_ARG_ENABLE([hardlink],
1654   AS_HELP_STRING([--disable-hardlink], [do not build hardlink]),
1655   [], [UL_DEFAULT_ENABLE([hardlink], [check])]
1656 )
1657 UL_BUILD_INIT([hardlink])
1658 AM_CONDITIONAL([BUILD_HARDLINK], [test "x$build_hardlink" = xyes])
1659
1660
1661 AC_ARG_ENABLE([eject],
1662   AS_HELP_STRING([--disable-eject], [do not build eject]),
1663   [], [UL_DEFAULT_ENABLE([eject], [check])]
1664 )
1665 UL_BUILD_INIT([eject])
1666 UL_REQUIRES_LINUX([eject])
1667 UL_REQUIRES_BUILD([eject], [libmount])
1668 AM_CONDITIONAL([BUILD_EJECT], [test "x$build_eject" = xyes])
1669
1670
1671 AC_ARG_ENABLE([agetty],
1672   AS_HELP_STRING([--disable-agetty], [do not build agetty]),
1673   [], [UL_DEFAULT_ENABLE([agetty], [check])]
1674 )
1675 UL_BUILD_INIT([agetty])
1676 UL_REQUIRES_HAVE([agetty], [utmpx_h], [utmpx.h header])
1677 UL_REQUIRES_HAVE([agetty], [gnu_utmpx], [GNU utmpx functions])
1678 AM_CONDITIONAL([BUILD_AGETTY], [test "x$build_agetty" = xyes])
1679 AS_IF([test "x$have_futimens" = xyes && test "x$have_inotify_init1" = xyes ], [
1680   AC_DEFINE([AGETTY_RELOAD], [1], [Enable agetty --reload feature])
1681 ],[
1682   AC_MSG_WARN([futimens or inotify_init1 not found; agetty(8) will not provide ---reload functionality])
1683 ])
1684
1685
1686 AC_ARG_ENABLE([plymouth_support],
1687   AS_HELP_STRING([--disable-plymouth_support], [do not care about plymouth in sulogin(8) and agetty(8)]),
1688   [], [enable_plymouth_support=check]
1689 )
1690 UL_BUILD_INIT([plymouth_support])
1691 UL_REQUIRES_HAVE([plymouth_support], [tiocglcktrmios], [TIOCGLCKTRMIOS flag])
1692 UL_REQUIRES_HAVE([plymouth_support], [sock_cloexec], [SOCK_CLOEXEC flag])
1693 UL_REQUIRES_HAVE([plymouth_support], [sock_nonblock], [SOCK_NONBLOCK flag])
1694 UL_REQUIRES_HAVE([plymouth_support], [so_passcred], [SO_PASSCRED flag])
1695 AM_CONDITIONAL([USE_PLYMOUTH_SUPPORT], [test "x$build_plymouth_support" = xyes])
1696 AS_IF([test "x$build_plymouth_support" = xyes ], [
1697     AC_DEFINE([USE_PLYMOUTH_SUPPORT], [1], [Enable plymouth support feature for sulogin and agetty])
1698 ])
1699
1700
1701 AC_ARG_WITH([libz],
1702   AS_HELP_STRING([--without-libz], [compile without libz]),
1703   [], [with_libz=auto]
1704 )
1705 AS_IF([test "x$with_libz" = xno], [have_z=no], [
1706   AC_CHECK_LIB([z], [crc32], [have_z=yes], [have_z=no])
1707 ])
1708
1709 AC_ARG_WITH([libmagic],
1710   AS_HELP_STRING([--without-libmagic], [compile without libmagic]),
1711   [], [with_libmagic=auto]
1712 )
1713 AS_IF([test "x$with_libmagic" = xno], [have_magic=no], [
1714   AC_CHECK_LIB([magic], [magic_open], [
1715     AC_CHECK_HEADER(magic.h, [
1716       AC_DEFINE([HAVE_MAGIC], [1], [Define to 1 if you have the libmagic present.])
1717       MAGIC_LIBS="-lmagic"
1718     ])
1719   ])
1720 ])
1721 AC_SUBST([MAGIC_LIBS])
1722
1723
1724 AC_ARG_ENABLE([cramfs],
1725   AS_HELP_STRING([--disable-cramfs], [do not build fsck.cramfs, mkfs.cramfs]),
1726   [], [UL_DEFAULT_ENABLE([cramfs], [check])]
1727 )
1728 UL_BUILD_INIT([cramfs])
1729 UL_REQUIRES_HAVE([cramfs], [z], [z library])
1730 AM_CONDITIONAL([BUILD_CRAMFS], [test "x$build_cramfs" = xyes])
1731
1732
1733 AC_ARG_ENABLE([bfs],
1734   AS_HELP_STRING([--disable-bfs], [do not build mkfs.bfs]),
1735   [], [UL_DEFAULT_ENABLE([bfs], [yes])]
1736 )
1737 UL_BUILD_INIT([bfs])
1738 AM_CONDITIONAL([BUILD_BFS], [test "x$build_bfs" = xyes])
1739
1740
1741 AC_ARG_ENABLE([minix],
1742   AS_HELP_STRING([--disable-minix], [do not build fsck.minix, mkfs.minix]),
1743   [], [UL_DEFAULT_ENABLE([minix], [yes])]
1744 )
1745 UL_BUILD_INIT([minix])
1746 AM_CONDITIONAL([BUILD_MINIX], [test "x$build_minix" = xyes])
1747
1748
1749 AC_ARG_ENABLE([fdformat],
1750   AS_HELP_STRING([--enable-fdformat], [build fdformat]),
1751   [], [UL_DEFAULT_ENABLE([fdformat], [no])]
1752 )
1753 UL_BUILD_INIT([fdformat])
1754 UL_REQUIRES_LINUX([fdformat])
1755 AM_CONDITIONAL([BUILD_FDFORMAT], [test "x$build_fdformat" = xyes])
1756
1757
1758 AC_ARG_ENABLE([hwclock],
1759   AS_HELP_STRING([--disable-hwclock], [do not build hwclock]),
1760   [], [UL_DEFAULT_ENABLE([hwclock], [check])]
1761 )
1762 have_linuxdummy=$linux_os
1763
1764 UL_BUILD_INIT([hwclock])
1765 UL_REQUIRES_HAVE([hwclock], [io, linuxdummy], [ioperm iopl function or Linux])
1766 AM_CONDITIONAL([BUILD_HWCLOCK], [test "x$build_hwclock" = xyes])
1767
1768 AC_ARG_ENABLE([hwclock_cmos],
1769   AS_HELP_STRING([--disable-hwclock-cmos], [do not use CMOS clock]),
1770   [], [enable_hwclock_cmos=check]
1771 )
1772 UL_BUILD_INIT([hwclock_cmos])
1773 UL_REQUIRES_BUILD([hwclock_cmos], [hwclock])
1774 UL_REQUIRES_ARCH([hwclock_cmos], [i?86-*,x86_64*])
1775 AM_CONDITIONAL([USE_HWCLOCK_CMOS], [test "x$build_hwclock_cmos" = xyes])
1776 AS_IF([test "x$build_hwclock_cmos" = xyes ], [
1777     AC_DEFINE([USE_HWCLOCK_CMOS], [1], [Define to 1 if want to use CMOS clock.])
1778 ])
1779
1780 AC_ARG_ENABLE([hwclock_gplv3],
1781   AS_HELP_STRING([--disable-hwclock-gplv3], [do not use datetime parsing GPLv3 code]),
1782   [], [enable_hwclock_gplv3=yes]
1783 )
1784 AM_CONDITIONAL([USE_HWCLOCK_GPLv3_DATETIME], [test "x$enable_hwclock_gplv3" = xyes])
1785 AS_IF([test "x$enable_hwclock_gplv3" = xyes ], [
1786     AC_DEFINE([USE_HWCLOCK_GPLv3_DATETIME], [1], [use datetime parsing GPLv3 code to hwclock])
1787 ])
1788
1789
1790 AC_ARG_ENABLE([mkfs],
1791   AS_HELP_STRING([--disable-mkfs], [do not build mkfs(8)]),
1792   [], [UL_DEFAULT_ENABLE([mkfs], [check])]
1793 )
1794 UL_BUILD_INIT([mkfs])
1795 AM_CONDITIONAL([BUILD_MKFS], [test "x$build_mkfs" = xyes])
1796
1797 UL_BUILD_INIT([isosize], [yes])
1798 AM_CONDITIONAL([BUILD_ISOSIZE], [test "x$build_isosize" = xyes])
1799
1800
1801 AC_ARG_ENABLE([fstrim],
1802   AS_HELP_STRING([--disable-fstrim], [do not build fstrim(8)]),
1803   [], [UL_DEFAULT_ENABLE([fstrim], [check])]
1804 )
1805 UL_BUILD_INIT([fstrim])
1806 UL_REQUIRES_LINUX([fstrim])
1807 UL_REQUIRES_BUILD([fstrim], [libmount])
1808 AM_CONDITIONAL([BUILD_FSTRIM], [test "x$build_fstrim" = xyes])
1809
1810
1811 AC_ARG_ENABLE([swapon],
1812   AS_HELP_STRING([--disable-swapon], [do not build swapon(8) and swapoff(8)]),
1813   [], [UL_DEFAULT_ENABLE([swapon], [check])]
1814 )
1815 UL_BUILD_INIT([swapon])
1816 UL_REQUIRES_LINUX([swapon])
1817 UL_REQUIRES_SYSCALL_CHECK([swapon], [UL_CHECK_SYSCALL([swapon])], [swapon])
1818 UL_REQUIRES_SYSCALL_CHECK([swapon], [UL_CHECK_SYSCALL([swapoff])], [swapoff])
1819 UL_REQUIRES_BUILD([swapon], [libblkid])
1820 UL_REQUIRES_BUILD([swapon], [libmount])
1821 UL_REQUIRES_BUILD([swapon], [libsmartcols])
1822 AM_CONDITIONAL([BUILD_SWAPON], [test "x$build_swapon" = xyes])
1823 AC_CHECK_FUNCS([swapon])
1824 AC_CHECK_FUNCS([swapoff])
1825
1826
1827 UL_BUILD_INIT([lsblk], [check])
1828 UL_REQUIRES_LINUX([lsblk])
1829 UL_REQUIRES_BUILD([lsblk], [libblkid])
1830 UL_REQUIRES_BUILD([lsblk], [libmount])
1831 UL_REQUIRES_BUILD([lsblk], [libsmartcols])
1832 AM_CONDITIONAL([BUILD_LSBLK], [test "x$build_lsblk" = xyes])
1833
1834
1835 AC_ARG_ENABLE([lscpu],
1836   AS_HELP_STRING([--disable-lscpu], [do not build lscpu]),
1837   [], [UL_DEFAULT_ENABLE([lscpu], [check])]
1838 )
1839 UL_BUILD_INIT([lscpu])
1840 UL_REQUIRES_LINUX([lscpu])
1841 UL_REQUIRES_BUILD([lscpu], [libsmartcols])
1842 UL_REQUIRES_HAVE([lscpu], [cpu_set_t], [cpu_set_t type])
1843 AM_CONDITIONAL([BUILD_LSCPU], [test "x$build_lscpu" = xyes])
1844
1845 AC_ARG_ENABLE([lsfd],
1846   AS_HELP_STRING([--disable-lsfd], [do not build lsfd]),
1847   [], [UL_DEFAULT_ENABLE([lsfd], [check])]
1848 )
1849 UL_BUILD_INIT([lsfd])
1850 UL_REQUIRES_LINUX([lsfd])
1851 UL_REQUIRES_BUILD([lsfd], [libsmartcols])
1852 AM_CONDITIONAL([BUILD_LSFD], [test "x$build_lsfd" = xyes])
1853
1854 AC_ARG_ENABLE([lslogins],
1855   AS_HELP_STRING([--disable-lslogins], [do not build lslogins]),
1856   [], [UL_DEFAULT_ENABLE([lslogins], [check])]
1857 )
1858 UL_BUILD_INIT([lslogins])
1859 UL_REQUIRES_BUILD([lslogins], [libsmartcols])
1860 UL_REQUIRES_HAVE([lslogins], [shadow_h], [shadow.h header])
1861 UL_REQUIRES_HAVE([lslogins], [utmpx_h], [utmpx.h header])
1862 UL_REQUIRES_HAVE([lslogins], [gnu_utmpx], [GNU utmpx functions])
1863 AM_CONDITIONAL([BUILD_LSLOGINS], [test "x$build_lslogins" = xyes])
1864
1865
1866 UL_BUILD_INIT([chcpu], [check])
1867 UL_REQUIRES_LINUX([chcpu])
1868 UL_REQUIRES_HAVE([chcpu], [cpu_set_t], [cpu_set_t type])
1869 AM_CONDITIONAL([BUILD_CHCPU], [test "x$build_chcpu" = xyes])
1870
1871
1872 AC_ARG_ENABLE([wdctl],
1873   AS_HELP_STRING([--disable-wdctl], [do not build wdctl]),
1874   [], [UL_DEFAULT_ENABLE([wdctl], [check])]
1875 )
1876 UL_BUILD_INIT([wdctl])
1877 UL_REQUIRES_LINUX([wdctl])
1878 UL_REQUIRES_BUILD([wdctl], [libsmartcols])
1879 UL_REQUIRES_HAVE([wdctl], [linux_watchdog_h], [linux/watchdog.h header file])
1880 AM_CONDITIONAL([BUILD_WDCTL], [test "x$build_wdctl" = xyes])
1881
1882
1883 UL_BUILD_INIT([swaplabel], [check])
1884 UL_REQUIRES_BUILD([swaplabel], [libblkid])
1885 AM_CONDITIONAL([BUILD_SWAPLABEL], [test "x$build_swaplabel" = xyes])
1886
1887
1888 UL_BUILD_INIT([mkswap], [yes])
1889 AM_CONDITIONAL([BUILD_MKSWAP], [test "x$build_mkswap" = xyes])
1890 AS_IF([test "x$build_mkswap" = xyes && test "x$build_libuuid" != xyes], [
1891   AC_MSG_WARN([uuid library is not found; mkswap(8) will not generate UUIDs])
1892 ])
1893
1894
1895 AC_ARG_ENABLE([cal],
1896   AS_HELP_STRING([--disable-cal], [do not build cal]),
1897   [], [UL_DEFAULT_ENABLE([cal], [check])]
1898 )
1899 UL_BUILD_INIT([cal])
1900 AM_CONDITIONAL([BUILD_CAL], [test "x$build_cal" = xyes])
1901
1902 AC_ARG_ENABLE([logger],
1903   AS_HELP_STRING([--disable-logger], [do not build logger]),
1904   [], [UL_DEFAULT_ENABLE([logger], [check])]
1905 )
1906 UL_BUILD_INIT([logger])
1907 AM_CONDITIONAL([BUILD_LOGGER], [test "x$build_logger" = xyes])
1908
1909 UL_BUILD_INIT([look], [yes])
1910 AM_CONDITIONAL([BUILD_LOOK], [test "x$build_look" = xyes])
1911
1912 UL_BUILD_INIT([mcookie], [yes])
1913 AM_CONDITIONAL([BUILD_MCOOKIE], [test "x$build_mcookie" = xyes])
1914
1915 UL_BUILD_INIT([namei], [yes])
1916 AM_CONDITIONAL([BUILD_NAMEI], [test "x$build_namei" = xyes])
1917
1918 matriplet="$($CC -print-multiarch 2>/dev/null || true)"
1919 if test "x$matriplet" != "x"; then
1920   AC_DEFINE_UNQUOTED([MULTIARCHTRIPLET], ["$matriplet"],
1921   ["Multi-arch triplet for whereis library search path"])
1922 fi
1923 AC_ARG_ENABLE([whereis],
1924   AS_HELP_STRING([--disable-whereis], [do not build whereis]),
1925   [], [UL_DEFAULT_ENABLE([whereis], [check])]
1926 )
1927 UL_BUILD_INIT([whereis])
1928 AM_CONDITIONAL([BUILD_WHEREIS], [test "x$build_whereis" = xyes])
1929
1930 AC_ARG_ENABLE([pipesz],
1931   AS_HELP_STRING([--disable-pipesz], [do not build pipesz]),
1932   [], [UL_DEFAULT_ENABLE([pipesz], [check])]
1933 )
1934 UL_BUILD_INIT([pipesz])
1935 UL_REQUIRES_LINUX([pipesz])
1936 AM_CONDITIONAL([BUILD_PIPESZ], [test "x$build_pipesz" = xyes])
1937
1938 UL_BUILD_INIT([fadvise], [check])
1939 UL_REQUIRES_LINUX([fadvise])
1940 AM_CONDITIONAL([BUILD_FADVISE], [test "x$build_fadvise" = xyes])
1941
1942 AC_ARG_ENABLE([waitpid],
1943   AS_HELP_STRING([--disable-waitpid], [do not build waitpid]),
1944   [], [UL_DEFAULT_ENABLE([waitpid], [check])]
1945 )
1946 UL_BUILD_INIT([waitpid])
1947 UL_REQUIRES_LINUX([waitpid])
1948 UL_REQUIRES_SYSCALL_CHECK([waitpid], [UL_CHECK_SYSCALL([pidfd_open])], [pidfd_open])
1949 AM_CONDITIONAL([BUILD_WAITPID], [test "x$build_waitpid" = xyes])
1950
1951 UL_BUILD_INIT([enosys], [check])
1952 UL_REQUIRES_LINUX([enosys])
1953 AS_IF([test "x$build_enosys" = xyes], [
1954   AC_MSG_CHECKING([for valid audit arch])
1955   AC_COMPILE_IFELSE(
1956     [AC_LANG_PROGRAM([[#include "${srcdir}/include/audit-arch.h"]])],
1957     [AC_MSG_RESULT([yes])],
1958     [AC_MSG_RESULT([no])
1959      build_enosys=no
1960     ])
1961 ])
1962 AM_CONDITIONAL([BUILD_ENOSYS], [test "x$build_enosys" = xyes])
1963
1964 UL_BUILD_INIT([lsclocks], [check])
1965 UL_REQUIRES_LINUX([lsclocks])
1966 UL_REQUIRES_BUILD([lsclocks], [libsmartcols])
1967 AM_CONDITIONAL([BUILD_LSCLOCKS], [test "x$build_lsclocks" = xyes])
1968
1969 UL_BUILD_INIT([getopt], [yes])
1970 AM_CONDITIONAL([BUILD_GETOPT], [test "x$build_getopt" = xyes])
1971
1972
1973 UL_BUILD_INIT([blockdev], [check])
1974 UL_REQUIRES_LINUX([blockdev])
1975 AM_CONDITIONAL([BUILD_BLOCKDEV], [test "x$build_blockdev" = xyes])
1976
1977
1978 UL_BUILD_INIT([prlimit], [check])
1979 UL_REQUIRES_LINUX([prlimit])
1980 UL_REQUIRES_BUILD([prlimit], [libsmartcols])
1981 UL_REQUIRES_SYSCALL_CHECK([prlimit], [UL_CHECK_SYSCALL([prlimit64])], [prlimit64])
1982 AM_CONDITIONAL([BUILD_PRLIMIT], [test "x$build_prlimit" = xyes])
1983 AS_IF([test "x$build_prlimit" = xyes], [
1984   dnl check for valid prlimit() function
1985   AC_MSG_CHECKING([for valid prlimit() function])
1986   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1987 #include <sys/types.h>
1988 #include <sys/time.h>
1989 #include <sys/resource.h>
1990 #include <stddef.h>
1991 ]],[[
1992    int ret;
1993    ret = prlimit(0, RLIMIT_AS, NULL, NULL);
1994    if (ret != 0) {
1995       return 1;
1996    }
1997    ]])],[
1998   AC_MSG_RESULT([yes])
1999   AC_DEFINE([HAVE_PRLIMIT], [1], [Have valid prlimit() function])],[
2000   AC_MSG_RESULT([no])])
2001 ])
2002
2003
2004
2005 UL_BUILD_INIT([lslocks], [check])
2006 UL_REQUIRES_LINUX([lslocks])
2007 UL_REQUIRES_BUILD([lslocks], [libmount])
2008 UL_REQUIRES_BUILD([lslocks], [libsmartcols])
2009 AM_CONDITIONAL([BUILD_LSLOCKS], [test "x$build_lslocks" = xyes])
2010
2011
2012 AC_ARG_ENABLE([switch_root],
2013   AS_HELP_STRING([--disable-switch_root], [do not build switch_root]),
2014   [], [UL_DEFAULT_ENABLE([switch_root], [check])]
2015 )
2016 UL_BUILD_INIT([switch_root])
2017 UL_REQUIRES_LINUX([switch_root])
2018 UL_REQUIRES_HAVE([switch_root], [openat], [openat function])
2019 UL_REQUIRES_HAVE([switch_root], [dirfd,ddfd], [dirfd or ddfd function])
2020 AM_CONDITIONAL([BUILD_SWITCH_ROOT], [test "x$build_switch_root" = xyes])
2021
2022
2023 AC_ARG_ENABLE([pivot_root],
2024   AS_HELP_STRING([--disable-pivot_root], [do not build pivot_root]),
2025   [], [UL_DEFAULT_ENABLE([pivot_root], [check])]
2026 )
2027 UL_BUILD_INIT([pivot_root])
2028 UL_REQUIRES_LINUX([pivot_root])
2029 UL_REQUIRES_SYSCALL_CHECK([pivot_root], [UL_CHECK_SYSCALL([pivot_root])])
2030 AM_CONDITIONAL([BUILD_PIVOT_ROOT], [test "x$build_pivot_root" = xyes])
2031
2032
2033 UL_BUILD_INIT([flock], [check])
2034 UL_REQUIRES_HAVE([flock], [timer], [timer_create/setitimer function])
2035 AM_CONDITIONAL([BUILD_FLOCK], [test "x$build_flock" = xyes])
2036
2037
2038 AC_ARG_ENABLE([lsmem],
2039   AS_HELP_STRING([--disable-lsmem], [do not build lsmem]),
2040   [], [UL_DEFAULT_ENABLE([lsmem], [check])]
2041 )
2042 UL_BUILD_INIT([lsmem])
2043 UL_REQUIRES_LINUX([lsmem])
2044 UL_REQUIRES_BUILD([lsmem], [libsmartcols])
2045 AM_CONDITIONAL([BUILD_LSMEM], [test "x$build_lsmem" = xyes])
2046
2047
2048 AC_ARG_ENABLE([chmem],
2049   AS_HELP_STRING([--disable-chmem], [do not build chmem]),
2050   [], [UL_DEFAULT_ENABLE([chmem], [check])]
2051 )
2052 UL_BUILD_INIT([chmem])
2053 UL_REQUIRES_LINUX([chmem])
2054 AM_CONDITIONAL([BUILD_CHMEM], [test "x$build_chmem" = xyes])
2055
2056
2057 AC_ARG_ENABLE([ipcmk],
2058   AS_HELP_STRING([--disable-ipcmk], [do not build ipcmk]),
2059   [], [UL_DEFAULT_ENABLE([ipcmk], [check])]
2060 )
2061 UL_BUILD_INIT([ipcmk])
2062 UL_EXCLUDE_ARCH([ipcmk], [*darwin*])
2063 AM_CONDITIONAL([BUILD_IPCMK], [test "x$build_ipcmk" = xyes])
2064
2065 AC_ARG_ENABLE([ipcrm],
2066   AS_HELP_STRING([--disable-ipcrm], [do not build ipcrm]),
2067   [], [UL_DEFAULT_ENABLE([ipcrm], [check])]
2068 )
2069 UL_BUILD_INIT([ipcrm])
2070 UL_EXCLUDE_ARCH([ipcrm], [*darwin*])
2071 AM_CONDITIONAL([BUILD_IPCRM], [test "x$build_ipcrm" = xyes])
2072
2073 AC_ARG_ENABLE([ipcs],
2074   AS_HELP_STRING([--disable-ipcs], [do not build ipcs]),
2075   [], [UL_DEFAULT_ENABLE([ipcs], [check])]
2076 )
2077 UL_BUILD_INIT([ipcs])
2078 UL_EXCLUDE_ARCH([ipcs], [*darwin*])
2079 AM_CONDITIONAL([BUILD_IPCS], [test "x$build_ipcs" = xyes])
2080
2081
2082 AC_ARG_ENABLE([irqtop],
2083   AS_HELP_STRING([--disable-irqtop], [do not build irqtop]),
2084   [], [UL_DEFAULT_ENABLE([irqtop], [check])]
2085 )
2086 UL_BUILD_INIT([irqtop])
2087 UL_REQUIRES_LINUX([irqtop])
2088 UL_REQUIRES_BUILD([irqtop], [libsmartcols])
2089 UL_REQUIRES_HAVE([irqtop], [open_memstream], [open_memstream function])
2090 UL_REQUIRES_HAVE([irqtop], [ncursesw,slang,ncurses], [ncursesw, ncurses or slang library])
2091 AM_CONDITIONAL([BUILD_IRQTOP], [test "x$build_irqtop" = xyes])
2092
2093 AC_ARG_ENABLE([lsirq],
2094   AS_HELP_STRING([--disable-lsirq], [do not build lsirq]),
2095   [], [UL_DEFAULT_ENABLE([lsirq], [check])]
2096 )
2097 UL_BUILD_INIT([lsirq])
2098 UL_REQUIRES_LINUX([lsirq])
2099 UL_REQUIRES_BUILD([lsirq], [libsmartcols])
2100 AM_CONDITIONAL([BUILD_LSIRQ], [test "x$build_lsirq" = xyes])
2101
2102
2103 UL_BUILD_INIT([choom], [check])
2104 UL_REQUIRES_LINUX([choom])
2105 AM_CONDITIONAL([BUILD_CHOOM], [test "x$build_choom" = xyes])
2106
2107 UL_BUILD_INIT([lsipc], [check])
2108 UL_REQUIRES_LINUX([lsipc])
2109 UL_REQUIRES_BUILD([lsipc], [libsmartcols])
2110 AM_CONDITIONAL([BUILD_LSIPC], [test "x$build_lsipc" = xyes])
2111
2112 AC_ARG_ENABLE([lsns],
2113   AS_HELP_STRING([--disable-lsns], [do not build lsns]),
2114   [], [UL_DEFAULT_ENABLE([lsns], [check])]
2115 )
2116 UL_BUILD_INIT([lsns])
2117 UL_REQUIRES_LINUX([lsns])
2118 UL_REQUIRES_BUILD([lsns], [libsmartcols])
2119 UL_REQUIRES_BUILD([lsns], [libmount])
2120 AM_CONDITIONAL([BUILD_LSNS], [test "x$build_lsns" = xyes])
2121
2122 UL_BUILD_INIT([renice], [yes])
2123 AM_CONDITIONAL([BUILD_RENICE], [test "x$build_renice" = xyes])
2124
2125
2126 AC_ARG_ENABLE([rfkill],
2127   AS_HELP_STRING([--disable-rfkill], [do not build rfkill]),
2128   [], [UL_DEFAULT_ENABLE([rfkill], [check])]
2129 )
2130 UL_BUILD_INIT([rfkill])
2131 UL_REQUIRES_LINUX([rfkill])
2132 UL_REQUIRES_BUILD([rfkill], [libsmartcols])
2133 AM_CONDITIONAL([BUILD_RFKILL], [test "x$build_rfkill" = xyes])
2134
2135
2136 UL_BUILD_INIT([setpgid], [yes])
2137 AM_CONDITIONAL([BUILD_SETPGID], [test "x$build_setpgid" = xyes])
2138
2139 UL_BUILD_INIT([setsid], [yes])
2140 AM_CONDITIONAL([BUILD_SETSID], [test "x$build_setsid" = xyes])
2141
2142 UL_BUILD_INIT([readprofile], [check])
2143 UL_REQUIRES_LINUX([readprofile])
2144 AM_CONDITIONAL([BUILD_READPROFILE], [test "x$build_readprofile" = xyes])
2145
2146 UL_BUILD_INIT([dmesg], [check])
2147 UL_REQUIRES_LINUX([dmesg])
2148 AM_CONDITIONAL([BUILD_DMESG], [test "x$build_dmesg" = xyes])
2149
2150 UL_BUILD_INIT([ctrlaltdel], [check])
2151 UL_REQUIRES_LINUX([ctrlaltdel])
2152 dnl we assume reboot() to be the 1-argument variant, because even considering
2153 dnl widely used alternative C libraries like uclibc, dietlibc and musl,
2154 dnl reboot() with multiple arguments is yet only found in glibc versions
2155 dnl earlier than 2.x.
2156 UL_REQUIRES_HAVE([ctrlaltdel], [reboot], [reboot function])
2157 AM_CONDITIONAL([BUILD_CTRLALTDEL], [test "x$build_ctrlaltdel" = xyes])
2158
2159 AC_ARG_ENABLE([exch],
2160   AS_HELP_STRING([--disable-exch], [do not build exch]),
2161   [], [UL_DEFAULT_ENABLE([exch], [check])]
2162 )
2163 UL_BUILD_INIT([exch])
2164 UL_REQUIRES_LINUX([exch])
2165 UL_REQUIRES_SYSCALL_CHECK([exch], [UL_CHECK_SYSCALL([renameat2])])
2166 AM_CONDITIONAL([BUILD_EXCH], [test "x$build_exch" = xyes])
2167
2168 UL_BUILD_INIT([fincore], [check])
2169 UL_REQUIRES_LINUX([fincore])
2170 UL_REQUIRES_BUILD([fincore], [libsmartcols])
2171 AM_CONDITIONAL([BUILD_FINCORE], [test "x$build_fincore" = xyes])
2172
2173 UL_BUILD_INIT([fsfreeze], [check])
2174 UL_REQUIRES_LINUX([fsfreeze])
2175 AM_CONDITIONAL([BUILD_FSFREEZE], [test "x$build_fsfreeze" = xyes])
2176
2177 UL_BUILD_INIT([blkdiscard], [check])
2178 UL_REQUIRES_LINUX([blkdiscard])
2179 AM_CONDITIONAL([BUILD_BLKDISCARD], [test "x$build_blkdiscard" = xyes])
2180
2181 UL_BUILD_INIT([blkzone], [check])
2182 UL_REQUIRES_LINUX([blkzone])
2183 UL_REQUIRES_HAVE([blkzone], [linux_blkzoned_h], [linux/blkzoned.h header])
2184 AM_CONDITIONAL([BUILD_BLKZONE], [test "x$build_blkzone" = xyes])
2185
2186 UL_BUILD_INIT([blkpr], [check])
2187 UL_REQUIRES_LINUX([blkpr])
2188 UL_REQUIRES_HAVE([blkpr], [linux_pr_h], [linux/pr.h header])
2189 AM_CONDITIONAL([BUILD_BLKPR], [test "x$build_blkpr" = xyes])
2190
2191 UL_BUILD_INIT([ldattach], [check])
2192 UL_REQUIRES_LINUX([ldattach])
2193 AM_CONDITIONAL([BUILD_LDATTACH], [test "x$build_ldattach" = xyes])
2194
2195 UL_BUILD_INIT([rtcwake], [check])
2196 UL_REQUIRES_LINUX([rtcwake])
2197 AM_CONDITIONAL([BUILD_RTCWAKE], [test "x$build_rtcwake" = xyes])
2198
2199 UL_BUILD_INIT([setarch], [check])
2200 UL_REQUIRES_LINUX([setarch])
2201 AM_CONDITIONAL([BUILD_SETARCH], [test "x$build_setarch" = xyes])
2202
2203
2204 # build_scriptutils= is just configure-only variable to control
2205 # script, scriptreplay and scriptlive
2206 AC_ARG_ENABLE([scriptutils],
2207   AS_HELP_STRING([--disable-scriptutils], [do not build script, scriptreplay and scriptlive]),
2208   [], [UL_DEFAULT_ENABLE([scriptutils], [check])]
2209 )
2210
2211 UL_ENABLE_ALIAS([script], [scriptutils])
2212 UL_BUILD_INIT([script])
2213 UL_REQUIRES_HAVE([script], [pty], [openpty function (libutil)])
2214 AM_CONDITIONAL([BUILD_SCRIPT], [test "x$build_script" = xyes])
2215
2216 UL_ENABLE_ALIAS([scriptreplay], [scriptutils])
2217 UL_BUILD_INIT([scriptreplay])
2218 AM_CONDITIONAL([BUILD_SCRIPTREPLAY], [test "x$build_scriptreplay" = xyes])
2219
2220 UL_ENABLE_ALIAS([scriptlive], [scriptutils])
2221 UL_BUILD_INIT([scriptlive])
2222 UL_REQUIRES_HAVE([scriptlive], [pty], [openpty function (libutil)])
2223 AM_CONDITIONAL([BUILD_SCRIPTLIVE], [test "x$build_scriptlive" = xyes])
2224
2225
2226 UL_BUILD_INIT([col], [check])
2227 UL_REQUIRES_COMPILE([col], [#include <limits.h>], [__GLIBC__], [building for glibc])
2228 AM_CONDITIONAL([BUILD_COL], [test "x$build_col" = xyes])
2229
2230 UL_BUILD_INIT([colcrt], [yes])
2231 AM_CONDITIONAL([BUILD_COLCRT], [test "x$build_colcrt" = xyes])
2232
2233 UL_BUILD_INIT([colrm], [yes])
2234 AM_CONDITIONAL([BUILD_COLRM], [test "x$build_colrm" = xyes])
2235
2236 UL_BUILD_INIT([column], [check])
2237 UL_REQUIRES_BUILD([column], [libsmartcols])
2238 AM_CONDITIONAL([BUILD_COLUMN], [test "x$build_column" = xyes])
2239
2240 UL_BUILD_INIT([hexdump], [yes])
2241 AM_CONDITIONAL([BUILD_HEXDUMP], [test "x$build_hexdump" = xyes])
2242
2243 UL_BUILD_INIT([rev], [yes])
2244 AM_CONDITIONAL([BUILD_REV], [test "x$build_rev" = xyes])
2245
2246
2247 AC_ARG_ENABLE([tunelp],
2248   AS_HELP_STRING([--enable-tunelp], [build tunelp]),
2249   [], [UL_DEFAULT_ENABLE([tunelp], [no])]
2250 )
2251 UL_BUILD_INIT([tunelp])
2252 UL_REQUIRES_LINUX([tunelp])
2253 AM_CONDITIONAL([BUILD_TUNELP], [test "x$build_tunelp" = xyes])
2254
2255
2256 AC_ARG_ENABLE([kill],
2257   AS_HELP_STRING([--disable-kill], [do not build kill]),
2258   [], [UL_DEFAULT_ENABLE([kill], [check])]
2259 )
2260 UL_BUILD_INIT([kill])
2261 UL_REQUIRES_LINUX([kill])
2262 AM_CONDITIONAL([BUILD_KILL], [test "x$build_kill" = xyes])
2263
2264
2265 AC_ARG_ENABLE([last],
2266   AS_HELP_STRING([--disable-last], [do not build last]),
2267   [], [UL_DEFAULT_ENABLE([last], [check])]
2268 )
2269 UL_BUILD_INIT([last])
2270 UL_REQUIRES_HAVE([last], [utmpx_h], [utmpx.h header])
2271 UL_REQUIRES_HAVE([last], [gnu_utmpx], [GNU utmpx functions])
2272 AM_CONDITIONAL([BUILD_LAST], [test "x$build_last" = xyes])
2273
2274
2275 AC_ARG_ENABLE([utmpdump],
2276   AS_HELP_STRING([--disable-utmpdump], [do not build utmpdump]),
2277   [], [UL_DEFAULT_ENABLE([utmpdump], [check])]
2278 )
2279 UL_BUILD_INIT([utmpdump])
2280 UL_REQUIRES_HAVE([utmpdump], [utmpx_h], [utmpx.h header])
2281 UL_REQUIRES_HAVE([utmpdump], [gnu_utmpx], [GNU utmpx functions])
2282 AM_CONDITIONAL([BUILD_UTMPDUMP], [test "x$build_utmpdump" = xyes])
2283
2284
2285 AC_ARG_ENABLE([line],
2286   AS_HELP_STRING([--enable-line], [build line]),
2287   [], [UL_DEFAULT_ENABLE([line], [no])]
2288 )
2289 UL_BUILD_INIT([line])
2290 AM_CONDITIONAL([BUILD_LINE], [test "x$build_line" = xyes])
2291
2292
2293 AC_ARG_ENABLE([mesg],
2294   AS_HELP_STRING([--disable-mesg], [do not build mesg]),
2295   [], [UL_DEFAULT_ENABLE([mesg], [yes])]
2296 )
2297 UL_BUILD_INIT([mesg])
2298 AM_CONDITIONAL([BUILD_MESG], [test "x$build_mesg" = xyes])
2299
2300
2301 AC_ARG_ENABLE([raw],
2302   AS_HELP_STRING([--disable-raw], [do not build raw]),
2303   [], [UL_DEFAULT_ENABLE([raw], [check])]
2304 )
2305 UL_BUILD_INIT([raw])
2306 UL_REQUIRES_LINUX([raw])
2307 UL_REQUIRES_HAVE([raw], [linux_raw_h], [raw.h header file])
2308 AM_CONDITIONAL([BUILD_RAW], [test "x$build_raw" = xyes])
2309
2310
2311 AC_ARG_ENABLE([rename],
2312   AS_HELP_STRING([--disable-rename], [do not build rename]),
2313   [], [UL_DEFAULT_ENABLE([rename], [yes])]
2314 )
2315 UL_BUILD_INIT([rename])
2316 AM_CONDITIONAL([BUILD_RENAME], [test "x$build_rename" = xyes])
2317
2318
2319 AC_ARG_ENABLE([vipw],
2320   AS_HELP_STRING([--enable-vipw], [build vipw]),
2321   [], [UL_DEFAULT_ENABLE([vipw], [no])]
2322 )
2323 UL_BUILD_INIT([vipw])
2324 UL_REQUIRES_HAVE([vipw], [shadow_h], [shadow.h header])
2325 AM_CONDITIONAL([BUILD_VIPW], [test "x$build_vipw" = xyes])
2326
2327
2328 AC_ARG_ENABLE([newgrp],
2329   AS_HELP_STRING([--enable-newgrp], [build newgrp]),
2330   [], [UL_DEFAULT_ENABLE([newgrp], [no])]
2331 )
2332 UL_BUILD_INIT([newgrp])
2333 UL_REQUIRES_HAVE([newgrp], [crypt], [crypt function])
2334 AM_CONDITIONAL([BUILD_NEWGRP], [test "x$build_newgrp" = xyes])
2335
2336
2337 AC_ARG_WITH([user], AS_HELP_STRING([--without-user], [compile without libuser (remote chsh)]),
2338   [], [with_user=check]
2339 )
2340 have_user=no
2341 AS_IF([test "x$with_user" != xno], [
2342   PKG_CHECK_MODULES(LIBUSER,[libuser >= 0.58], [have_user=yes], [have_user=no])
2343   AS_CASE([$with_user:$have_user],
2344     [yes:no],
2345       [AC_MSG_ERROR([user selected but libuser not found])],
2346     [*:yes],
2347       [AC_DEFINE([HAVE_LIBUSER], [1], [Define if libuser is available])]
2348   )
2349   # temporary solution, libuser has stupid .pc where are exported all
2350   # private dependencies to Requires: instead of Requires.private:
2351   AS_IF([test "x$have_user" = xyes], [
2352     LIBUSER_LIBS=-luser
2353   ])
2354 ])
2355 AM_CONDITIONAL([HAVE_USER], [test "x$have_user" = xyes])
2356
2357 AC_ARG_ENABLE([chfn-chsh-password],
2358   AS_HELP_STRING([--disable-chfn-chsh-password], [do not require the user to enter the password in chfn and chsh]),
2359   [], [enable_chfn_chsh_password=yes]
2360 )
2361
2362 AC_ARG_ENABLE([chfn-chsh],
2363   AS_HELP_STRING([--disable-chfn-chsh], [do not build chfn and chsh]),
2364   [], [UL_DEFAULT_ENABLE([chfn_chsh], [check])]
2365 )
2366 UL_BUILD_INIT([chfn_chsh])
2367 UL_REQUIRES_HAVE([chfn_chsh], [shadow_h], [shadow.h header])
2368 UL_REQUIRES_HAVE([chfn_chsh], [getusershell], [getusershell function])
2369
2370 AS_IF([test "x$enable_chfn_chsh_password" = xyes || test "x$have_user" = xyes], [
2371   UL_REQUIRES_HAVE([chfn_chsh], [security_pam_appl_h], [PAM header file])
2372   AC_DEFINE([CHFN_CHSH_PASSWORD], [1], [Should chfn and chsh require the user to enter the password?])
2373 ])
2374 AM_CONDITIONAL([BUILD_CHFN_CHSH], [test "x$build_chfn_chsh" = xyes])
2375 AM_CONDITIONAL([CHFN_CHSH_PASSWORD], [test "x$enable_chfn_chsh_password" = xyes])
2376
2377 AC_ARG_ENABLE([chsh-only-listed],
2378   AS_HELP_STRING([--disable-chsh-only-listed], [chsh: allow shells not in /etc/shells]),
2379   [], enable_chsh_only_listed=yes
2380 )
2381
2382 AS_IF([test "x$enable_chsh_only_listed" = xyes], [
2383   AC_DEFINE([ONLY_LISTED_SHELLS], [1], [Should chsh allow only shells in /etc/shells?])
2384 ])
2385
2386
2387 AC_ARG_ENABLE([login],
2388   AS_HELP_STRING([--disable-login], [do not build login]),
2389   [], [UL_DEFAULT_ENABLE([login], [check])]
2390 )
2391 UL_BUILD_INIT([login])
2392 UL_REQUIRES_HAVE([login], [security_pam_appl_h], [PAM header file])
2393 UL_REQUIRES_HAVE([login], [security_pam_misc_h, security_openpam_h], [PAM conversation functions])
2394 UL_REQUIRES_HAVE([login], [utmpx_h], [utmpx.h header])
2395 UL_REQUIRES_HAVE([login], [gnu_utmpx], [GNU utmpx functions])
2396 AM_CONDITIONAL([BUILD_LOGIN], [test "x$build_login" = xyes])
2397
2398 AC_ARG_ENABLE([login-chown-vcs],
2399   AS_HELP_STRING([--enable-login-chown-vcs], [let login chown /dev/vcsN]),
2400   [], [enable_login_chown_vcs=no]
2401 )
2402
2403 AS_IF([test "x$enable_login_chown_vcs" = xyes], [
2404   AC_DEFINE([LOGIN_CHOWN_VCS], [1], [Should login chown /dev/vcsN?])
2405 ])
2406
2407 AC_ARG_ENABLE([login-stat-mail],
2408   AS_HELP_STRING([--enable-login-stat-mail], [let login stat() the mailbox]),
2409   [], [enable_login_stat_mail=no]
2410 )
2411
2412 AS_IF([test "x$enable_login_stat_mail" = xyes], [
2413   AC_DEFINE([LOGIN_STAT_MAIL], [1], [Should login stat() the mailbox?])
2414 ])
2415
2416 AC_ARG_ENABLE([login-lastlog],
2417   AS_HELP_STRING([--enable-login-lastlog], [program login writes lastlog entries]),
2418   [], [enable_login_lastlogin=no]
2419 )
2420
2421 AS_IF([test "x$enable_login_lastlogin" != xno], [
2422   AC_DEFINE([USE_LOGIN_LASTLOG],
2423             [1],
2424             [Define if program login writes lastlog entries])
2425 ])
2426
2427 AC_ARG_ENABLE([nologin],
2428   AS_HELP_STRING([--disable-nologin], [do not build nologin]),
2429   [], [UL_DEFAULT_ENABLE([nologin], [yes])]
2430 )
2431 UL_BUILD_INIT([nologin])
2432 AM_CONDITIONAL([BUILD_NOLOGIN], [test "x$build_nologin" = xyes])
2433
2434
2435 AC_ARG_ENABLE([sulogin],
2436   AS_HELP_STRING([--disable-sulogin], [do not build sulogin]),
2437   [], [UL_DEFAULT_ENABLE([sulogin], [check])]
2438 )
2439 UL_BUILD_INIT([sulogin])
2440 UL_REQUIRES_HAVE([sulogin], [crypt], [crypt function])
2441 UL_REQUIRES_HAVE([sulogin], [shadow_h], [shadow.h header])
2442 AM_CONDITIONAL([BUILD_SULOGIN], [test "x$build_sulogin" = xyes])
2443
2444
2445 AC_ARG_ENABLE([su],
2446   AS_HELP_STRING([--disable-su], [do not build su]),
2447   [], [UL_DEFAULT_ENABLE([su], [check])]
2448 )
2449 UL_BUILD_INIT([su])
2450 UL_REQUIRES_HAVE([su], [security_pam_appl_h], [PAM header file])
2451 UL_REQUIRES_HAVE([su], [utmpx_h], [utmpx.h header])
2452 UL_REQUIRES_HAVE([su], [gnu_utmpx], [GNU utmpx functions])
2453 AM_CONDITIONAL([BUILD_SU], [test "x$build_su" = xyes])
2454
2455
2456 AC_ARG_ENABLE([runuser],
2457   AS_HELP_STRING([--disable-runuser], [do not build runuser]),
2458   [], [UL_DEFAULT_ENABLE([runuser], [check])]
2459 )
2460 UL_BUILD_INIT([runuser])
2461 UL_REQUIRES_HAVE([runuser], [security_pam_appl_h], [PAM header file])
2462 UL_REQUIRES_HAVE([runuser], [utmpx_h], [utmpx.h header])
2463 UL_REQUIRES_HAVE([runuser], [gnu_utmpx], [GNU utmpx functions])
2464 AM_CONDITIONAL([BUILD_RUNUSER], [test "x$build_runuser" = xyes])
2465
2466
2467 AC_ARG_ENABLE([ul],
2468   AS_HELP_STRING([--disable-ul], [do not build ul]),
2469   [], [UL_DEFAULT_ENABLE([ul], [check])]
2470 )
2471 UL_BUILD_INIT([ul])
2472 UL_REQUIRES_HAVE([ul], [ncursesw, ncurses], [ncursesw or ncurses libraries])
2473 AM_CONDITIONAL([BUILD_UL], [test "x$build_ul" = xyes])
2474
2475
2476 AC_ARG_ENABLE([more],
2477   AS_HELP_STRING([--disable-more], [do not build more]),
2478   [], [UL_DEFAULT_ENABLE([more], [check])]
2479 )
2480 UL_BUILD_INIT([more])
2481 UL_REQUIRES_HAVE([more], [ncursesw, ncurses], [ncursesw or ncurses libraries])
2482 UL_REQUIRES_LINUX([more])
2483 AM_CONDITIONAL([BUILD_MORE], [test "x$build_more" = xyes])
2484
2485
2486 AC_ARG_ENABLE([pg],
2487   AS_HELP_STRING([--enable-pg], [build pg]),
2488   [], [UL_DEFAULT_ENABLE([pg], [no])]
2489 )
2490 UL_BUILD_INIT([pg])
2491 UL_REQUIRES_HAVE([pg], [ncursesw, ncurses], [ncursesw or ncurses library])
2492 AM_CONDITIONAL([BUILD_PG], [test "x$build_pg" = xyes])
2493
2494
2495 AC_ARG_ENABLE([setterm],
2496   AS_HELP_STRING([--disable-setterm], [do not build setterm]),
2497   [], [UL_DEFAULT_ENABLE([setterm], [check])]
2498 )
2499 UL_BUILD_INIT([setterm])
2500 UL_REQUIRES_LINUX([setterm])
2501 UL_REQUIRES_HAVE([setterm], [ncursesw, ncurses], [ncursesw or ncurses library])
2502 AM_CONDITIONAL([BUILD_SETTERM], [test "x$build_setterm" = xyes])
2503
2504 # build_schedutils= is just configure-only variable to control
2505 # ionice, taskset and chrt
2506 AC_ARG_ENABLE([schedutils],
2507   AS_HELP_STRING([--disable-schedutils], [do not build chrt, ionice, taskset]),
2508   [], [UL_DEFAULT_ENABLE([schedutils], [check])]
2509 )
2510
2511
2512 UL_ENABLE_ALIAS([ionice], [schedutils])
2513 UL_BUILD_INIT([ionice])
2514 UL_REQUIRES_SYSCALL_CHECK([ionice],
2515         [UL_CHECK_SYSCALL([ioprio_set],
2516           [alpha],      [442],
2517           [i*86],       [289],
2518           [ia64*],      [1274],
2519           [powerpc*],   [273],
2520           [s390*],      [282],
2521           [sparc*],     [196],
2522           [sh*],        [288],
2523           [x86_64*],    [251])],
2524         [ioprio_set])
2525
2526 UL_REQUIRES_SYSCALL_CHECK([ionice],
2527         [UL_CHECK_SYSCALL([ioprio_get],
2528           [alpha],      [443],
2529           [i*86],       [290],
2530           [ia64*],      [1275],
2531           [powerpc*],   [274],
2532           [s390*],      [283],
2533           [sparc*],     [218],
2534           [sh*],        [289],
2535           [x86_64*],    [252])],
2536         [ioprio_get])
2537
2538 AM_CONDITIONAL([BUILD_IONICE], [test "x$build_ionice" = xyes])
2539
2540
2541 UL_ENABLE_ALIAS([taskset], [schedutils])
2542 UL_BUILD_INIT([taskset])
2543 UL_REQUIRES_HAVE([taskset], [cpu_set_t], [cpu_set_t type])
2544 UL_REQUIRES_SYSCALL_CHECK([taskset],
2545         [UL_CHECK_SYSCALL([sched_getaffinity])],
2546         [sched_getaffinity])
2547 AM_CONDITIONAL([BUILD_TASKSET], [test "x$build_taskset" = xyes])
2548
2549
2550 have_schedsetter=no
2551 AS_IF([test "x$ac_cv_func_sched_setscheduler" = xyes], [have_schedsetter=yes],
2552       [test "x$ac_cv_func_sched_setattr" = xyes], [have_schedsetter=yes])
2553
2554 UL_ENABLE_ALIAS([chrt], [schedutils])
2555 UL_BUILD_INIT([chrt])
2556 UL_REQUIRES_HAVE([chrt], [schedsetter], [sched_set functions])
2557 AM_CONDITIONAL([BUILD_CHRT], [test "x$build_chrt" = xyes])
2558
2559 AS_IF([test "x$build_chrt" = xyes], [
2560         UL_CHECK_SYSCALL([sched_setattr])
2561 ])
2562
2563 UL_ENABLE_ALIAS([uclampset], [schedutils])
2564 UL_BUILD_INIT([uclampset])
2565 UL_REQUIRES_SYSCALL_CHECK([uclampset],
2566         [UL_CHECK_SYSCALL([sched_setattr])], [sched_setattr])
2567 AM_CONDITIONAL([BUILD_UCLAMPSET], [test "x$build_uclampset" = xyes])
2568
2569
2570 AC_ARG_ENABLE([wall],
2571   AS_HELP_STRING([--disable-wall], [do not build wall]),
2572   [], [UL_DEFAULT_ENABLE([wall], [check])]
2573 )
2574 UL_BUILD_INIT([wall])
2575 UL_REQUIRES_HAVE([wall], [utmpx_h], [utmpx.h header])
2576 AM_CONDITIONAL([BUILD_WALL], [test "x$build_wall" = xyes])
2577
2578
2579 AC_ARG_ENABLE([write],
2580   AS_HELP_STRING([--enable-write], [build write]),
2581   [], [UL_DEFAULT_ENABLE([write], [no])]
2582 )
2583 UL_BUILD_INIT([write])
2584 UL_REQUIRES_HAVE([write], [utmpx_h], [utmpx.h header])
2585 UL_REQUIRES_HAVE([write], [gnu_utmpx], [GNU utmpx functions])
2586 AM_CONDITIONAL([BUILD_WRITE], [test "x$build_write" = xyes])
2587
2588
2589 AC_ARG_WITH([btrfs],
2590   AS_HELP_STRING([--without-btrfs], [do not build with btrfs support]),
2591   [], [with_btrfs=check]
2592 )
2593 have_btrfs=no
2594 AS_IF([test "x$with_btrfs" != xno], [
2595   AS_CASE([$with_btrfs:$have_linux_btrfs_h],
2596     [yes:no],
2597     [AC_MSG_ERROR([btrfs selected but linux/btrfs.h not found])],
2598     [check:no],
2599        [AC_MSG_WARN([linux/btrfs.h not found, do not build with btrfs support])],
2600     [*:yes],
2601        [have_btrfs=yes
2602         AC_DEFINE([HAVE_BTRFS_SUPPORT], [1], [Define if btrfs stuff is available])]
2603   )
2604 ])
2605 AM_CONDITIONAL([HAVE_BTRFS], [test "x$have_btrfs" = xyes])
2606
2607
2608 AC_ARG_WITH([systemd],
2609   AS_HELP_STRING([--without-systemd], [do not build with systemd support]),
2610   [], [with_systemd=check]
2611 )
2612
2613 have_systemd=no
2614 AS_IF([test "x$with_systemd" != xno], [
2615   # new version -- all libsystemd-* libs merged into libsystemd
2616   PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [have_systemd=yes], [have_systemd=no])
2617   # old versions
2618   AS_IF([test "x$have_systemd" != "xyes"], [
2619     PKG_CHECK_MODULES([SYSTEMD_DAEMON], [libsystemd-daemon],
2620                       [have_systemd_daemon=yes], [have_systemd_daemon=no])
2621     PKG_CHECK_MODULES([SYSTEMD_JOURNAL], [libsystemd-journal],
2622                       [have_systemd_journal=yes], [have_systemd_journal=no])
2623     AS_IF([test "x$have_systemd_daemon" = "xyes" && test "x$have_systemd_journal" = "xyes" ],[
2624            have_systemd=yes])
2625   ])
2626   AS_CASE([$with_systemd:$have_systemd],
2627     [yes:no],
2628       [AC_MSG_ERROR([systemd expected but libsystemd not found])],
2629     [*:yes],
2630        AC_DEFINE([HAVE_LIBSYSTEMD], [1], [Define if libsystemd is available])
2631        AC_DEFINE([USE_SYSTEMD], [1], [Define if systemd support is wanted ])
2632        AC_CHECK_DECLS([sd_session_get_username], [], [], [#include <systemd/sd-login.h>])
2633   )
2634 ])
2635 AM_CONDITIONAL([HAVE_SYSTEMD], [test "x$have_systemd" = xyes])
2636
2637
2638 AC_ARG_WITH([systemdsystemunitdir],
2639   AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [directory for systemd unit files (requires systemd support)]),
2640   [], [
2641   AS_IF([test "x$have_systemd" = xyes], [
2642     PKG_CHECK_VAR([with_systemdsystemunitdir], [systemd], [systemdsystemunitdir],
2643       [],
2644       [with_systemdsystemunitdir=no])
2645   ])
2646 ])
2647 AS_IF([test "x$with_systemdsystemunitdir" != "xno"], [
2648   AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
2649 ])
2650
2651 AC_ARG_WITH([tmpfilesdir],
2652   AS_HELP_STRING([--with-tmpfilesdir=DIR], [directory for tmpfiles. See tmpfiles.d(5) for details]),
2653   [], [
2654   AS_IF([test "x$have_systemd" = xyes], [
2655     PKG_CHECK_VAR([with_tmpfilesdir], [systemd], [tmpfilesdir],
2656       [],
2657       [with_tmpfilesdir=no])
2658   ])
2659 ])
2660 AS_IF([test "x$with_tmpfilesdir" != "xno"], [
2661   AC_SUBST([tmpfilesdir], [$with_tmpfilesdir])
2662 ])
2663
2664 AC_ARG_WITH([smack],
2665   AS_HELP_STRING([--with-smack], [build with SMACK support]),
2666   [], [with_smack=no]
2667 )
2668 AS_IF([test "x$with_smack" = xyes], [
2669   AC_DEFINE([HAVE_SMACK], [1], [Add SMACK support])
2670 ])
2671
2672 AC_ARG_WITH([econf],
2673   AS_HELP_STRING([--without-econf], [do not use libeconf]),
2674   [], [with_econf=check]
2675 )
2676
2677 have_econf=no
2678 AS_IF([test "x$with_econf" != xno], [
2679   PKG_CHECK_MODULES([ECONF], [libeconf], [have_econf=yes], [have_econf=no])
2680     AS_CASE([$with_econf:$have_econf],
2681     [yes:no],
2682       [AC_MSG_ERROR([libeconf expected but libeconf not found])],
2683     [*:yes],
2684        AC_DEFINE([HAVE_LIBECONF], [1], [Define if libeconf is available])
2685   )
2686 ])
2687 AM_CONDITIONAL([HAVE_ECONF], [test "x$have_econf" = xyes])
2688
2689 AC_ARG_WITH([vendordir],
2690   AS_HELP_STRING([--with-vendordir=DIR], [Directory for distribution provided configuration files]),
2691   [], []
2692 )
2693 AC_SUBST([vendordir], [$with_vendordir])
2694 AM_CONDITIONAL([USE_VENDORDIR], [test "x$with_vendordir" != x])
2695 AS_IF([test "x$with_vendordir" != x], [
2696   AC_DEFINE([USE_VENDORDIR], [1], [Define to 1 to use vendordir])
2697 ])
2698
2699
2700 AC_ARG_ENABLE([bash-completion],
2701   AS_HELP_STRING([--disable-bash-completion], [do not install bash completion files]),
2702   [], [enable_bash_completion=yes]
2703 )
2704
2705 AM_CONDITIONAL([BUILD_BASH_COMPLETION], [test "x$enable_bash_completion" = xyes])
2706
2707 AC_ARG_WITH([bashcompletiondir],
2708   AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
2709   [], [
2710   AS_IF([test "x$enable_bash_completion" = xyes], [
2711     PKG_CHECK_VAR([with_bashcompletiondir], [bash-completion], [completionsdir],
2712       [],
2713       [with_bashcompletiondir=${datadir}/bash-completion/completions])
2714   ])
2715 ])
2716 AS_IF([test "x$enable_bash_completion" = xyes], [
2717   AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
2718 ])
2719
2720
2721 AC_ARG_WITH([python],
2722   AS_HELP_STRING([--without-python], [do not build python bindings, use --with-python={2,3} to force version]),
2723   [], [with_python=check withval=check]
2724 )
2725
2726 have_python=no
2727 have_libpython=no
2728 AS_IF([test "x$with_python" != xno], [
2729   # We follow distributions default and look for PKG module name "python"
2730   # (minimal version is 2) but if major version is explicitly specified by
2731   # --with-python=2 or --with-python=3 then we look for PKG module "python2" or
2732   # "python3".
2733   AS_IF([test "x$withval" != xno && test "x$withval" != xyes && test "x$withval" != xcheck],
2734         [pymajor="$withval"; PYTHON=python${pymajor}], [pymajor="2"])
2735
2736   # check for python interpreter
2737   AM_PATH_PYTHON([$pymajor], [have_python=yes], [have_python=no])
2738   AS_CASE([$with_python:$have_python],
2739     [yes:no],
2740       [AC_MSG_ERROR([python selected but python interpreter not found])],
2741     [check:no],
2742        [AC_MSG_WARN([python interpreter not found, do not build python bindings])],
2743     [*:yes],
2744        # check for python development stuff
2745        [
2746          PKG_CHECK_MODULES([PYTHON], [python-$PYTHON_VERSION], [have_libpython=yes], [have_libpython=no])
2747
2748          # https://github.com/util-linux/util-linux/issues/2366
2749          AX_COMPARE_VERSION([$PYTHON_VERSION], [ge], [3.12], [
2750            UL_WARN_ADD([-Wno-error=redundant-decls], [PYTHON_CFLAGS])
2751          ])
2752        ]
2753   )
2754 ])
2755
2756
2757 AC_ARG_ENABLE([pylibmount],
2758   AS_HELP_STRING([--disable-pylibmount], [do not build pylibmount]),
2759   [], [UL_DEFAULT_ENABLE([pylibmount], [check])]
2760 )
2761 UL_BUILD_INIT([pylibmount])
2762 UL_REQUIRES_HAVE([pylibmount], [libpython], [libpython])
2763 UL_REQUIRES_BUILD([pylibmount], [libmount])
2764 AM_CONDITIONAL([BUILD_PYLIBMOUNT], [test "x$build_pylibmount" = "xyes"])
2765
2766 # We need to introduce a verbatim dependency into the Makefile, without automake
2767 # trying to interpret it, so push it as a AM_SUBST_NOTMAKE variable.
2768 verbatim_pylibmount_dependency='
2769
2770 # pylibmountexec module must be installed after usrlib_exec libraries,
2771 # otherwise the libtool relink step will fail to find libmount.la and
2772 # will try -lmount which is possibly not available.
2773 install-pylibmountexecLTLIBRARIES: install-usrlib_execLTLIBRARIES
2774
2775 '
2776 AC_SUBST([verbatim_pylibmount_dependency])
2777 AM_SUBST_NOTMAKE([verbatim_pylibmount_dependency])
2778
2779 AC_ARG_ENABLE([pg-bell],
2780   AS_HELP_STRING([--disable-pg-bell], [let pg not ring the bell on invalid keys]),
2781   [], [enable_pg_bell=yes]
2782 )
2783
2784 AS_IF([test "x$enable_pg_bell" = xyes], [
2785   AC_DEFINE([PG_BELL], [1], [Should pg ring the bell on invalid keys?])
2786 ])
2787
2788
2789 AC_DEFUN([FS_PATHS_DEFAULT], [/sbin:/sbin/fs.d:/sbin/fs])
2790 AC_ARG_ENABLE([fs-paths-default],
2791   AS_HELP_STRING([--enable-fs-paths-default=paths], [default search path for fs helpers @<:@FS_PATHS_DEFAULT@:>@]),
2792   [AS_CASE([$enableval],
2793     [yes], [fs_paths_defaults="FS_PATHS_DEFAULT"],
2794     [no],  [fs_paths_defaults=""],
2795     [fs_paths_defaults="$enableval"]
2796   )],
2797   [fs_paths_defaults="FS_PATHS_DEFAULT"]
2798 )
2799 AC_ARG_ENABLE([fs-paths-extra],
2800   AS_HELP_STRING([--enable-fs-paths-extra=paths], [additional search paths for fs helpers]),
2801   [AS_CASE([$enableval],
2802      [yes|no], [fs_paths_extra=""],
2803      [fs_paths_extra="$enableval"]
2804   )],
2805   [fs_paths_extra=""]
2806 )
2807 fs_paths="$fs_paths_defaults"
2808 AS_IF([test "x$fs_paths_extra" != "x"], [
2809   AS_IF([test "x$fs_paths" != "x"], [
2810     fs_paths="${fs_paths}:"
2811   ])
2812   fs_paths="${fs_paths}${fs_paths_extra}"
2813 ])
2814 AC_DEFINE_UNQUOTED([FS_SEARCH_PATH], "$fs_paths", [search path for fs helpers])
2815
2816
2817 AC_ARG_ENABLE([use-tty-group],
2818   AS_HELP_STRING([--disable-use-tty-group], [do not install wall and write setgid tty]),
2819   [], [enable_use_tty_group=yes]
2820 )
2821 AM_CONDITIONAL([USE_TTY_GROUP], [test "x$enable_use_tty_group" = xyes])
2822
2823 AS_IF([test "x$enable_use_tty_group" = xyes], [
2824   AC_DEFINE([USE_TTY_GROUP], [1], [Should wall and write be installed setgid tty?])
2825 ])
2826
2827
2828 AC_ARG_ENABLE([sulogin-emergency-mount],
2829   AS_HELP_STRING([--enable-sulogin-emergency-mount],
2830                  [use emergency mount of /dev and /proc for sulogin]),
2831   [], [enable_sulogin_emergency_mount=no]
2832 )
2833
2834 AS_IF([test "x$enable_sulogin_emergency_mount" = xyes], [
2835   AS_IF([test "x$linux_os" = xyes], [ ],
2836         [AC_MSG_ERROR([--enable-sulogin-emergency-mount selected for non-linux system])])
2837   AC_DEFINE([USE_SULOGIN_EMERGENCY_MOUNT], [1],
2838             [Should sulogin use an emergency mount of /dev and /proc?])
2839 ])
2840
2841
2842 AC_ARG_ENABLE([usrdir-path],
2843   AS_HELP_STRING([--enable-usrdir-path], [use only /usr paths in PATH env. variable (recommended on systems with /bin -> /usr/bin symlinks)]),
2844   [], [enable_usrdir_path=no]
2845 )
2846
2847 AS_IF([test "x$enable_usrdir_path" = xyes], [
2848   AC_DEFINE([USE_USRDIR_PATHS_ONLY], [1], [Define to 1 to remove /bin and /sbin from PATH env.variable])
2849 ])
2850
2851
2852 AC_ARG_ENABLE([makeinstall-chown],
2853   AS_HELP_STRING([--disable-makeinstall-chown], [do not do chown-like operations during "make install"]),
2854   [], [enable_makeinstall_chown=yes]
2855 )
2856 AM_CONDITIONAL([MAKEINSTALL_DO_CHOWN], [test "x$enable_makeinstall_chown" = xyes])
2857
2858
2859 AC_ARG_ENABLE([makeinstall-setuid],
2860   AS_HELP_STRING([--disable-makeinstall-setuid], [do not do setuid chmod operations during "make install"]),
2861   [], [enable_makeinstall_setuid=yes]
2862 )
2863 AM_CONDITIONAL([MAKEINSTALL_DO_SETUID], [test "x$enable_makeinstall_setuid" = xyes])
2864
2865
2866 AC_ARG_ENABLE([colors-default],
2867   AS_HELP_STRING([--disable-colors-default], [do not colorize output from utils by default]),
2868   [], [enable_colors_default=yes]
2869 )
2870 AS_IF([test "x$enable_colors_default" = xyes], [
2871   AC_DEFINE([USE_COLORS_BY_DEFAULT], [1], [Enables colorized output from utils by default])
2872 ])
2873
2874
2875 AC_ARG_WITH([cryptsetup],
2876   AS_HELP_STRING([--with-cryptsetup], [compile with cryptsetup support]),
2877   [], [with_cryptsetup=no]
2878 )
2879
2880 AS_IF([test "x$with_cryptsetup" = xno], [
2881   AM_CONDITIONAL([HAVE_CRYPTSETUP], [false])
2882   AM_CONDITIONAL([CRYPTSETUP_VIA_DLOPEN], [false])
2883 ], [
2884   PKG_CHECK_MODULES([CRYPTSETUP], [libcryptsetup],
2885         [AC_DEFINE([HAVE_CRYPTSETUP], [1], [Define if cryptsetup is available])
2886          UL_PKG_STATIC([CRYPTSETUP_LIBS_STATIC], [libcryptsetup])
2887          AM_CONDITIONAL([HAVE_CRYPTSETUP], [true])
2888          SAVE_CFLAGS="$CFLAGS"
2889          CFLAGS="$CRYPTSETUP_CFLAGS $CFLAGS"
2890          SAVE_LIBS="$LIBS"
2891          LIBS="$CRYPTSETUP_LIBS $LIBS"
2892          AC_CHECK_LIB([cryptsetup], [crypt_activate_by_signed_key], [
2893           AC_DEFINE([HAVE_CRYPT_ACTIVATE_BY_SIGNED_KEY], [1], [Define if crypt_activate_by_signed_key exist in -lcryptsetup])
2894          ])
2895          AS_IF([test "x$with_cryptsetup" = xdlopen], [
2896           LIBS="-ldl $LIBS"
2897           AC_CHECK_LIB([dl], [dlsym], [
2898             AC_DEFINE([CRYPTSETUP_VIA_DLOPEN], [1], [Define if cryptsetup is to be loaded via dlopen])
2899             AM_CONDITIONAL([CRYPTSETUP_VIA_DLOPEN], [true])
2900            ], [AC_MSG_ERROR([libdl required to build with cryptsetup support])])
2901          ], [
2902           AM_CONDITIONAL([CRYPTSETUP_VIA_DLOPEN], [false])
2903          ])
2904          CFLAGS="$SAVE_CFLAGS"
2905          LIBS="$SAVE_LIBS"
2906          have_cryptsetup=yes],
2907         [have_cryptsetup=no
2908    AM_CONDITIONAL([HAVE_CRYPTSETUP], [false])
2909    AM_CONDITIONAL([CRYPTSETUP_VIA_DLOPEN], [false])
2910   ])
2911
2912   AS_CASE([$with_cryptsetup:$have_cryptsetup],
2913     [yes:no], [AC_MSG_WARN([cryptsetup selected but libcryptsetup not found])]
2914   )
2915 ])
2916 AC_SUBST([CRYPTSETUP_LIBS])
2917 AC_SUBST([CRYPTSETUP_LIBS_STATIC])
2918
2919
2920 AC_ARG_VAR([SUID_CFLAGS],
2921            [CFLAGS used for binaries which are usually with the suid bit])
2922 AC_ARG_VAR([SUID_LDFLAGS],
2923            [LDFLAGS used for binaries which are usually with the suid bit])
2924
2925 AC_ARG_VAR([DAEMON_CFLAGS],
2926            [CFLAGS used for binaries which are usually executed as daemons])
2927 AC_ARG_VAR([DAEMON_LDFLAGS],
2928            [LDFLAGS used for binaries which are usually executed as daemons])
2929
2930 AC_ARG_VAR([SOLIB_CFLAGS],
2931            [CFLAGS used for shared libraries])
2932 AC_ARG_VAR([SOLIB_LDFLAGS],
2933            [LDFLAGS used for shared libraries])
2934
2935 AC_ARG_VAR([ADJTIME_PATH],
2936            [Path to hwclock adjtime file, default /etc/adjtime])
2937 AS_IF([test "x$ADJTIME_PATH" = x], [ADJTIME_PATH="/etc/adjtime"])
2938 AC_DEFINE_UNQUOTED([CONFIG_ADJTIME_PATH], "$ADJTIME_PATH", [Path to hwclock adjtime file])
2939
2940 if test "x${build_alias}" != "x${host_alias}"; then
2941   AC_MSG_NOTICE([setting link_all_deplibs=unknown for libtool])
2942   # work around Debian patch to libtool breaking cross-compiles
2943   # https://bugs.debian.org/cgi-bin/bugreport.cgi?bug=702737
2944   # https://bugs.debian.org/cgi-bin/bugreport.cgi?bug=297726
2945   link_all_deplibs=unknown
2946 fi
2947
2948
2949 LIBS=""
2950
2951
2952 AC_CONFIG_HEADERS([config.h])
2953
2954 #
2955 # Don't use configure.ac to replace install paths! See Makefile PATHFILES for
2956 # more details.
2957 #
2958 AC_CONFIG_FILES([
2959 Makefile
2960 libblkid/docs/Makefile
2961 libblkid/docs/version.xml
2962 libblkid/src/blkid.h
2963 libfdisk/docs/Makefile
2964 libfdisk/docs/version.xml
2965 libfdisk/src/libfdisk.h
2966 libmount/docs/Makefile
2967 libmount/docs/version.xml
2968 libmount/src/libmount.h
2969 libsmartcols/docs/Makefile
2970 libsmartcols/docs/version.xml
2971 libsmartcols/src/libsmartcols.h
2972 po/Makefile.in
2973 po-man/Makefile
2974 ])
2975
2976 AC_OUTPUT
2977
2978 AC_MSG_RESULT([
2979         ${PACKAGE}  ${VERSION}
2980
2981         prefix:                    ${prefix}
2982         exec prefix:               ${exec_prefix}
2983
2984         bindir:                    ${bindir}
2985         sbindir:                   ${sbindir}
2986         libdir:                    ${libdir}
2987         usrbin_execdir:            ${usrbin_execdir}
2988         usrsbin_execdir:           ${usrsbin_execdir}
2989         usrlib_execdir:            ${usrlib_execdir}
2990
2991         localstatedir:             ${localstatedir}
2992         runstatedir:               ${runstatedir}
2993         includedir:                ${includedir}
2994         sysconfdir:                ${sysconfdir}
2995         sysconfstaticdir:          ${sysconfstaticdir}
2996
2997         vendordir:                 ${with_vendordir}
2998
2999         Python:                    ${PYTHON}
3000         Python version:            ${PYTHON_VERSION}
3001         Python libs:               ${pyexecdir}
3002
3003         Bash completions:          ${with_bashcompletiondir}
3004         Systemd support:           ${have_systemd}
3005         Systemd unitdir:           ${with_systemdsystemunitdir}
3006         tmpfilesdir:               ${with_tmpfilesdir}
3007         libeconf support:          ${have_econf}
3008         Btrfs support:             ${have_btrfs}
3009         lastlog2 support:          ${build_liblastlog2}
3010         Wide-char support:         ${build_widechar}
3011         libcryptsetup support:     ${have_cryptsetup}
3012
3013         Manual pages:              ${build_asciidoc}
3014         Manual pages translated:   ${build_poman}
3015
3016         compiler:                  ${CC} / ${CXX}
3017         suid cflags:               ${SUID_CFLAGS}
3018         ldflags:                   ${LDFLAGS}
3019         suid ldflags:              ${SUID_LDFLAGS}
3020         ASAN enabled:              ${enable_asan}
3021         Fuzzing enabled:           ${enable_fuzzing_engine}
3022         Coverage enabled           ${enable_coverage}
3023
3024         cflags:                    ${CFLAGS}
3025
3026         warnings:
3027
3028 ${WARN_CFLAGS}
3029
3030  Type 'make' or 'make <utilname>' to compile.
3031 ])