configure.ac

   1 AC_INIT([util-linux],
   2         m4_esyscmd([tools/git-version-gen .tarball-version]),
   3         [kzak@redhat.com],,
   4         [http://www.kernel.org/pub/linux/utils/util-linux/])
   5
   6
   7 AC_PREREQ([2.60])
   8
   9 AC_CONFIG_AUX_DIR([config])
  10 AC_CONFIG_MACRO_DIR([m4])
  11 dnl AC_USE_SYSTEM_EXTENSIONS must be called before any macros that run
  12 dnl the compiler (like AC_PROG_LIBTOOL) to avoid autoconf errors.
  13 AC_USE_SYSTEM_EXTENSIONS
  14 AM_INIT_AUTOMAKE([-Wall foreign 1.10 tar-pax no-dist-gzip dist-xz subdir-objects])
  15
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  17                             [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  18 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  19
  20 AC_CONFIG_SRCDIR([sys-utils/mount.c])
  21 AC_PREFIX_DEFAULT([/usr])
  22
  23 dnl version details from <major>.<minor>[-<suffix>]
  24 PACKAGE_VERSION_MAJOR=$(echo $PACKAGE_VERSION | awk -F. '{print $1}')
  25 PACKAGE_VERSION_MINOR=$(echo $PACKAGE_VERSION | awk -F. '{
  26                                                    sub("-.*","",$2); print $2}')
  27 PACKAGE_VERSION_RELEASE=$(echo $PACKAGE_VERSION | awk -F. '{
  28                      sub("-.*","",$3); print $3 ~ /^@<:@0-9@:>@+$/ ? $3 : 0}')
  29
  30 dnl libblkid version
  31 LIBBLKID_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  32 LIBBLKID_DATE="21-Mar-2018"
  33 LIBBLKID_LT_MAJOR=1
  34 LIBBLKID_LT_MINOR=1
  35 LIBBLKID_LT_MICRO=0
  36 LIBBLKID_VERSION_INFO=`expr $LIBBLKID_LT_MAJOR + $LIBBLKID_LT_MINOR`:$LIBBLKID_LT_MICRO:$LIBBLKID_LT_MINOR
  37
  38 dnl libuuid version
  39 LIBUUID_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  40 LIBUUID_LT_MAJOR=1
  41 LIBUUID_LT_MINOR=3
  42 LIBUUID_LT_MICRO=0
  43 LIBUUID_VERSION_INFO=`expr $LIBUUID_LT_MAJOR + $LIBUUID_LT_MINOR`:$LIBUUID_LT_MICRO:$LIBUUID_LT_MINOR
  44
  45 dnl libmount version
  46 LIBMOUNT_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  47 LIBMOUNT_LT_MAJOR=1
  48 LIBMOUNT_LT_MINOR=1
  49 LIBMOUNT_LT_MICRO=0
  50 LIBMOUNT_VERSION_INFO=`expr $LIBMOUNT_LT_MAJOR + $LIBMOUNT_LT_MINOR`:$LIBMOUNT_LT_MICRO:$LIBMOUNT_LT_MINOR
  51
  52 dnl libsmartcols version
  53 LIBSMARTCOLS_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  54 LIBSMARTCOLS_LT_MAJOR=1
  55 LIBSMARTCOLS_LT_MINOR=1
  56 LIBSMARTCOLS_LT_MICRO=0
  57 LIBSMARTCOLS_VERSION_INFO=`expr $LIBSMARTCOLS_LT_MAJOR + $LIBSMARTCOLS_LT_MINOR`:$LIBSMARTCOLS_LT_MICRO:$LIBSMARTCOLS_LT_MINOR
  58
  59 dnl libfdisk version
  60 LIBFDISK_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  61 LIBFDISK_LT_MAJOR=1
  62 LIBFDISK_LT_MINOR=1
  63 LIBFDISK_LT_MICRO=0
  64 LIBFDISK_VERSION_INFO=`expr $LIBFDISK_LT_MAJOR + $LIBFDISK_LT_MINOR`:$LIBFDISK_LT_MICRO:$LIBFDISK_LT_MINOR
  65
  66 # Check whether exec_prefix=/usr:
  67 AS_CASE([$exec_prefix:$prefix],
  68 [NONE:NONE | NONE:/usr | /usr:*],
  69   [AC_MSG_NOTICE([Default --exec-prefix detected.])
  70    AS_CASE([$bindir],  ['${exec_prefix}/bin'],  [bindir=/bin;   AC_MSG_NOTICE([  --bindir defaults to /bin])  ])
  71    AS_CASE([$sbindir], ['${exec_prefix}/sbin'], [sbindir=/sbin; AC_MSG_NOTICE([  --sbindir defaults to /sbin])])
  72    AS_CASE([$libdir],  ['${exec_prefix}/lib'],  [libdir=/lib;   AC_MSG_NOTICE([  --libdir defaults to /lib])  ])
  73   ]
  74 )
  75
  76
  77 # default for old versions without $runstatedir
  78 AS_IF([test x"$runstatedir" = x], [runstatedir='${localstatedir}/run'])
  79
  80 # our default if $localstatedir unchanged
  81 AS_CASE([$localstatedir:$runstatedir],
  82  [NONE:'${localstatedir}/run' | /var:'${localstatedir}/run' | NONE:'/run' ],
  83    [runstatedir=/run; AC_MSG_NOTICE([  --runstatedir defaults to /run])]
  84 )
  85
  86 AC_SUBST([runstatedir])
  87
  88
  89 # The original default values of {bin,sbin,lib}dir
  90 usrbin_execdir='${exec_prefix}/bin'
  91 AC_SUBST([usrbin_execdir])
  92
  93 usrsbin_execdir='${exec_prefix}/sbin'
  94 AC_SUBST([usrsbin_execdir])
  95
  96 AS_CASE([$libdir],
  97  ['${exec_prefix}/'* | '${prefix}/'* | /usr/* | "${prefix}"/* ],
  98    [usrlib_execdir=$libdir],
  99  [usrlib_execdir='${exec_prefix}'$libdir]
 100 )
 101 AC_SUBST([usrlib_execdir])
 102
 103
 104 AM_PROG_CC_C_O
 105 AC_PROG_MKDIR_P
 106 AC_PROG_CC_STDC
 107 AC_PROG_YACC
 108 AC_CANONICAL_HOST
 109 AC_C_CONST
 110 AC_C_VOLATILE
 111 AC_C_BIGENDIAN
 112
 113 dnl Compiler warnings
 114 UL_WARN_ADD([-fno-common])
 115 UL_WARN_ADD([-Wall])
 116 UL_WARN_ADD([-Werror=sequence-point])
 117 UL_WARN_ADD([-Wextra])
 118 UL_WARN_ADD([-Wextra-semi])
 119 UL_WARN_ADD([-Wembedded-directive])
 120 UL_WARN_ADD([-Wmissing-declarations])
 121 UL_WARN_ADD([-Wmissing-parameter-type])
 122 UL_WARN_ADD([-Wmissing-prototypes])
 123 UL_WARN_ADD([-Wno-missing-field-initializers])
 124 UL_WARN_ADD([-Wredundant-decls])
 125 UL_WARN_ADD([-Wsign-compare])
 126 UL_WARN_ADD([-Wtype-limits])
 127 UL_WARN_ADD([-Wuninitialized])
 128 UL_WARN_ADD([-Wunused-but-set-parameter])
 129 UL_WARN_ADD([-Wunused-but-set-variable])
 130 UL_WARN_ADD([-Wunused-parameter])
 131 UL_WARN_ADD([-Wunused-result])
 132 UL_WARN_ADD([-Wunused-variable])
 133 UL_WARN_ADD([-Wnested-externs])
 134 UL_WARN_ADD([-Wpointer-arith])
 135 UL_WARN_ADD([-Wstrict-prototypes])
 136 UL_WARN_ADD([-Wformat-security])
 137 UL_WARN_ADD([-Wimplicit-function-declaration])
 138 UL_WARN_ADD([-Wdiscarded-qualifiers])
 139 AC_SUBST([WARN_CFLAGS])
 140
 141 UL_WARN_ADD([-Wno-clobbered], [BSD_WARN_CFLAGS])
 142 AC_SUBST([BSD_WARN_CFLAGS])
 143
 144 UL_WARN_ADD([-Wno-cast-function-type], [PYTHON_WARN_CFLAGS])
 145 AC_SUBST([PYTHON_WARN_CFLAGS])
 146
 147 UL_WARN_ADD([-Wno-unused-parameter], [NO_UNUSED_WARN_CFLAGS])
 148 AC_SUBST([NO_UNUSED_WARN_CFLAGS])
 149
 150
 151 AC_ARG_ENABLE([asan],
 152   AS_HELP_STRING([--enable-asan], [compile with Address Sanitizer]),
 153   [], [enable_asan=no]
 154 )
 155 AS_IF([test "x$enable_asan" = xyes], [
 156   UL_WARN_ADD([-fsanitize=address])
 157 ])
 158
 159
 160
 161 dnl libtool-2
 162 LT_INIT
 163
 164 dnl check supported linker flags
 165 AX_CHECK_VSCRIPT
 166
 167 m4_ifndef([PKG_PROG_PKG_CONFIG],
 168   [m4_fatal([Could not locate the pkg-config autoconf
 169     macros. These are usually located in /usr/share/aclocal/pkg.m4.
 170     If your macros are in a different location, try setting the
 171     environment variable AL_OPTS="-I/other/macro/dir" before running
 172     ./autogen.sh or autoreconf again. Make sure pkg-config is installed.])])
 173 PKG_PROG_PKG_CONFIG
 174
 175 GTK_DOC_CHECK([1.10])
 176 AC_PATH_PROG([XSLTPROC], [xsltproc])
 177
 178 linux_os=no
 179 bsd_os=no
 180 AS_CASE([${host_os}],
 181   [*linux*],
 182      [linux_os=yes],
 183   [*darwin*],
 184      [darwin_os=yes],
 185   [*bsd*],
 186      [bsd_os=yes])
 187 AM_CONDITIONAL([LINUX], [test "x$linux_os" = xyes])
 188 AM_CONDITIONAL([DARWIN], [test "x$darwin_os" = xyes])
 189 AM_CONDITIONAL([BSD], [test "x$bsd_os" = xyes])
 190
 191 AS_IF([test  "x$darwin_os" = xyes], [
 192   AC_DEFINE([_DARWIN_C_SOURCE], [1], [Enable MAP_ANON in sys/mman.h on Mac OS X])
 193 ])
 194
 195 dnl define ARCH_<NAME> conditionals
 196 UL_SET_ARCH([I86], [i?86-*])
 197 UL_SET_ARCH([86_64], [x86_64*])
 198 UL_SET_ARCH([IA64], [ia64*])
 199 UL_SET_ARCH([S390], [s390*])
 200 UL_SET_ARCH([SPARC], [sparc*])
 201 UL_SET_ARCH([PPC], [ppc*|powerpc*])
 202 UL_SET_ARCH([M68K], [m68*])
 203 UL_SET_ARCH([MIPS], [mips*])
 204 UL_SET_ARCH([HPPA], [hppa*|parisc*])
 205
 206 AC_SYS_LARGEFILE
 207 AC_HEADER_ASSERT
 208 AC_STRUCT_TIMEZONE
 209
 210 dnl Don't forget to maintain alternatively allowed versions in autogen.sh!
 211 AM_GNU_GETTEXT_VERSION([0.18.3])
 212 AM_GNU_GETTEXT([external])
 213
 214 AS_IF([test -d "$srcdir/po"], [
 215   ALL_LINGUAS=`cd $srcdir/po > /dev/null && echo *.po | sed 's/\.po//g'`
 216 ], [
 217   ALL_LINGUAS="af am ar as be bg bn_IN bn ca cs cy da de el en_GB es et eu_ES fa fi fr gl gu he hi hr hu hy id is it ja ka kn ko ku lo lt lv mk ml mr ms my nb nl nn no nso or pa pl pt_BR pt ro ru si sk sl sq sr@Latn sr sv ta te th tr uk ur vi zh_CN zh_TW zu"
 218 ])
 219
 220 AC_CHECK_HEADERS([linux/compiler.h linux/blkpg.h linux/major.h], [], [], [
 221 #ifdef HAVE_LINUX_COMPILER_H
 222 #include <linux/compiler.h>
 223 #endif
 224 ])
 225 AC_CHECK_HEADERS([ \
 226         asm/io.h \
 227         err.h \
 228         errno.h \
 229         fcntl.h \
 230         getopt.h \
 231         inttypes.h \
 232         lastlog.h \
 233         libutil.h \
 234         linux/btrfs.h \
 235         linux/cdrom.h \
 236         linux/falloc.h \
 237         linux/watchdog.h \
 238         linux/fd.h \
 239         linux/raw.h \
 240         linux/tiocl.h \
 241         linux/version.h \
 242         linux/securebits.h \
 243         linux/net_namespace.h \
 244         locale.h \
 245         mntent.h \
 246         net/if.h \
 247         net/if_dl.h \
 248         netinet/in.h \
 249         paths.h \
 250         pty.h \
 251         security/pam_appl.h \
 252         stdint.h \
 253         stdio_ext.h \
 254         stdlib.h \
 255         endian.h \
 256         byteswap.h \
 257         sys/endian.h \
 258         sys/disk.h \
 259         sys/disklabel.h \
 260         sys/file.h \
 261         sys/io.h \
 262         sys/ioccom.h \
 263         sys/ioctl.h \
 264         sys/mkdev.h \
 265         sys/mount.h \
 266         sys/param.h \
 267         sys/prctl.h \
 268         sys/resource.h \
 269         sys/signalfd.h \
 270         sys/socket.h \
 271         sys/sockio.h \
 272         sys/stat.h \
 273         sys/sysmacros.h \
 274         sys/swap.h \
 275         sys/syscall.h \
 276         sys/time.h \
 277         sys/timex.h \
 278         sys/ttydefaults.h \
 279         sys/types.h \
 280         sys/ucred.h \
 281         sys/un.h \
 282         unistd.h \
 283         shadow.h \
 284         utmp.h \
 285         utmpx.h \
 286 ])
 287
 288 # There is a collision in old kernel-headers. The both files mount.h and fs.h
 289 # define MS_* macros. Fixed by kernel commit e462ec50cb5fad19f6003a3d8087f4a0945dd2b1.
 290 #
 291 AC_CHECK_HEADERS([linux/fs.h ], [], [],
 292  [#ifdef HAVE_SYS_MOUNT_H
 293    # include <linux/fs.h>
 294    # include <sys/mount.h>
 295   #endif
 296 ])
 297
 298 AC_CHECK_HEADERS([linux/gsmmux.h ], [], [],
 299  [#ifdef LINUX_GSMMUX_H
 300    # include <linux/gsmmux.h>
 301    #endif
 302 ])
 303
 304 AC_CHECK_HEADERS([security/pam_misc.h],
 305                 [AM_CONDITIONAL([HAVE_LINUXPAM], [true])],
 306                 [AM_CONDITIONAL([HAVE_LINUXPAM], [false])], [
 307 #ifdef HAVE_SECURITY_PAM_APPL_H
 308 #include <security/pam_appl.h>
 309 #endif
 310 ])
 311
 312 AC_CHECK_HEADERS([linux/blkzoned.h])
 313
 314 AC_CHECK_HEADERS([security/openpam.h], [], [], [
 315 #ifdef HAVE_SECURITY_PAM_APPL_H
 316 #include <security/pam_appl.h>
 317 #endif
 318 ])
 319
 320 AC_CHECK_HEADERS([langinfo.h],
 321                 [AM_CONDITIONAL([HAVE_LANGINFO], [true])],
 322                 [AM_CONDITIONAL([HAVE_LANGINFO], [false])])
 323
 324 AC_MSG_CHECKING([whether langinfo.h defines ALTMON_x constants])
 325 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 326         #include <langinfo.h>
 327 ]], [[
 328         char *str;
 329         str = nl_langinfo (ALTMON_1);
 330         str = nl_langinfo (ALTMON_2);
 331         str = nl_langinfo (ALTMON_3);
 332         str = nl_langinfo (ALTMON_4);
 333         str = nl_langinfo (ALTMON_5);
 334         str = nl_langinfo (ALTMON_6);
 335         str = nl_langinfo (ALTMON_7);
 336         str = nl_langinfo (ALTMON_8);
 337         str = nl_langinfo (ALTMON_9);
 338         str = nl_langinfo (ALTMON_10);
 339         str = nl_langinfo (ALTMON_11);
 340         str = nl_langinfo (ALTMON_12);
 341 ]])], [
 342         AC_MSG_RESULT([yes])
 343         AC_DEFINE([HAVE_LANGINFO_ALTMON], [1],
 344                 [Define if langinfo.h defines ALTMON_x constants])
 345 ], [
 346         AC_MSG_RESULT([no])
 347 ])
 348
 349
 350 AC_MSG_CHECKING([whether langinfo.h defines _NL_ABALTMON_x constants])
 351 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 352         #include <langinfo.h>
 353 ]], [[
 354         char *str;
 355         str = nl_langinfo (_NL_ABALTMON_1);
 356         str = nl_langinfo (_NL_ABALTMON_2);
 357         str = nl_langinfo (_NL_ABALTMON_3);
 358         str = nl_langinfo (_NL_ABALTMON_4);
 359         str = nl_langinfo (_NL_ABALTMON_5);
 360         str = nl_langinfo (_NL_ABALTMON_6);
 361         str = nl_langinfo (_NL_ABALTMON_7);
 362         str = nl_langinfo (_NL_ABALTMON_8);
 363         str = nl_langinfo (_NL_ABALTMON_9);
 364         str = nl_langinfo (_NL_ABALTMON_10);
 365         str = nl_langinfo (_NL_ABALTMON_11);
 366         str = nl_langinfo (_NL_ABALTMON_12);
 367 ]])], [
 368         AC_MSG_RESULT([yes])
 369         AC_DEFINE([HAVE_LANGINFO_NL_ABALTMON], [1],
 370                 [Define if langinfo.h defines _NL_ABALTMON_x constants])
 371 ], [
 372         AC_MSG_RESULT([no])
 373 ])
 374
 375
 376 dnl Convert some ac_cv_header_* variables to have_*
 377 dnl
 378 have_linux_version_h=$ac_cv_header_linux_version_h
 379 have_linux_blkzoned_h=$ac_cv_header_linux_blkzoned_h
 380 have_linux_btrfs_h=$ac_cv_header_linux_btrfs_h
 381 have_linux_raw_h=$ac_cv_header_linux_raw_h
 382 have_linux_securebits_h=$ac_cv_header_linux_securebits_h
 383 have_linux_watchdog_h=$ac_cv_header_linux_watchdog_h
 384 have_security_pam_appl_h=$ac_cv_header_security_pam_appl_h
 385 have_security_pam_misc_h=$ac_cv_header_security_pam_misc_h
 386 have_security_openpam_h=$ac_cv_header_security_openpam_h
 387 have_shadow_h=$ac_cv_header_shadow_h
 388 have_sys_signalfd_h=$ac_cv_header_sys_signalfd_h
 389 have_utmpx_h=$ac_cv_header_utmpx_h
 390
 391 AS_CASE([$linux_os:$have_linux_version_h],
 392   [yes:no],
 393     [AC_MSG_ERROR([kernel headers required on Linux])]
 394 )
 395
 396 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 397 #include <time.h>
 398 #include <unistd.h>
 399 ]], [[
 400     int a = 0;
 401     struct tm *tm = localtime(0);
 402     if (a == -1)  /* false */
 403         sleep(tm->tm_gmtoff);
 404 ]])],
 405 [AC_DEFINE([HAVE_TM_GMTOFF], [1], [Does struct tm have a field tm_gmtoff?])
 406 ])
 407
 408 AC_CHECK_MEMBERS([struct termios.c_line],,,
 409     [[#include <termios.h>]])
 410
 411 AC_CHECK_MEMBERS([struct stat.st_mtim.tv_nsec],,,
 412         [#include <sys/stat.h>])
 413
 414 AC_CHECK_DECLS([_NL_TIME_WEEK_1STDAY],[],[],[[#include <langinfo.h>]])
 415
 416 AC_CHECK_DECL([llseek],
 417         [AC_DEFINE([HAVE_LLSEEK_PROTOTYPE], [1],
 418                         [Define to 1 if have llseek prototype])],
 419         [],
 420         [#include <unistd.h>])
 421
 422 AC_CHECK_DECL([lseek64],
 423         [AC_DEFINE([HAVE_LSEEK64_PROTOTYPE], [1],
 424                         [Define to 1 if have lseek64 prototype])],
 425         [],
 426         [#define _LARGEFILE_SOURCE
 427          #define _LARGEFILE64_SOURCE
 428          #include <unistd.h>])
 429
 430 AC_CHECK_DECL([environ],
 431         [AC_DEFINE([HAVE_ENVIRON_DECL], [1],
 432                 [Define to 1 if have **environ prototype])],
 433 )
 434
 435 AC_CHECK_DECL([strsignal],
 436         [AC_DEFINE([HAVE_STRSIGNAL_DECL], [1],
 437                 [Define to 1 if have strsignal function prototype])],
 438 )
 439
 440 AC_CHECK_DECL([TIOCGLCKTRMIOS],
 441               [have_tiocglcktrmios=yes], [have_tiocglcktrmios=no],
 442               [#include <sys/ioctl.h>])
 443 AC_CHECK_DECL([SOCK_CLOEXEC],
 444               [have_sock_cloexec=yes], [have_sock_cloexec=no],
 445               [#include <sys/types.h>
 446                #include <sys/socket.h>])
 447 AC_CHECK_DECL([SOCK_NONBLOCK],
 448               [have_sock_nonblock=yes], [have_sock_nonblock=no],
 449               [#include <sys/types.h>
 450                #include <sys/socket.h>])
 451 AC_CHECK_DECL([SO_PASSCRED],
 452               [have_so_passcred=yes], [have_so_passcred=no],
 453               [#include <sys/types.h>
 454                #include <sys/socket.h>])
 455
 456 AC_CHECK_FUNCS([ \
 457         clearenv \
 458         __fpurge \
 459         fpurge \
 460         __fpending \
 461         secure_getenv \
 462         __secure_getenv \
 463         eaccess \
 464         err \
 465         errx \
 466         explicit_bzero \
 467         fsync \
 468         utimensat \
 469         getdomainname \
 470         getdtablesize \
 471         getexecname \
 472         getmntinfo \
 473         getrandom \
 474         getrlimit \
 475         getsgnam \
 476         inotify_init \
 477         jrand48 \
 478         lchown \
 479         llseek \
 480         lseek64 \
 481         mempcpy \
 482         mkostemp \
 483         nanosleep \
 484         ntp_gettime \
 485         personality \
 486         posix_fadvise \
 487         prctl \
 488         qsort_r \
 489         rpmatch \
 490         scandirat \
 491         setprogname \
 492         setresgid \
 493         setresuid \
 494         sched_setattr \
 495         sched_setscheduler \
 496         sigqueue \
 497         srandom \
 498         strnchr \
 499         strndup \
 500         strnlen \
 501         sysconf \
 502         sysinfo \
 503         timegm \
 504         usleep \
 505         vwarnx \
 506         warn \
 507         warnx \
 508 ])
 509 AC_FUNC_FSEEKO
 510
 511 AC_CHECK_FUNCS([openat fstatat unlinkat], [have_openat=yes], [have_openat=no])
 512 AC_CHECK_FUNCS([ioperm iopl], [have_io=yes])
 513 AC_CHECK_FUNCS([futimens], [have_futimens=yes])
 514 AC_CHECK_FUNCS([inotify_init1], [have_inotify_init1=yes])
 515 AC_CHECK_FUNCS([open_memstream], [have_open_memstream=yes],[have_open_memstream=no])
 516 AC_CHECK_FUNCS([reboot], [have_reboot=yes],[have_reboot=no])
 517 AC_CHECK_FUNCS([updwtmpx updwtmpx], [have_gnu_utmpx=yes], [have_gnu_utmpx=no])
 518 AC_CHECK_FUNCS([getusershell], [have_getusershell=yes],[have_getusershell=no])
 519
 520 AM_CONDITIONAL([HAVE_OPENAT], [test "x$have_openat" = xyes])
 521
 522
 523 AC_CHECK_FUNCS([isnan], [],
 524         [AC_CHECK_LIB([m], [isnan], [MATH_LIBS="-lm"])]
 525         [AC_CHECK_LIB([m], [__isnan], [MATH_LIBS="-lm"])]
 526 )
 527 AC_SUBST([MATH_LIBS])
 528
 529
 530 dnl lib/mononotic.c may require -lrt
 531 AC_CHECK_FUNCS([clock_gettime], [],
 532         [AC_CHECK_LIB([rt], [clock_gettime], [REALTIME_LIBS="-lrt"])]
 533 )
 534
 535 have_timer="no"
 536 AC_CHECK_FUNCS([timer_create],
 537         [have_timer="yes"],
 538         [AC_CHECK_LIB([rt], [timer_create], [
 539                 have_timer="yes"
 540                 REALTIME_LIBS="-lrt"
 541         ],[
 542                 AC_SEARCH_LIBS([timer_create], [rt], [
 543                         AC_MSG_RESULT(yes)
 544                         have_timer="yes"
 545                         REALTIME_LIBS="-lrt -lpthread"
 546                 ],[], [-lpthread]
 547                 )
 548                 ])]
 549 )
 550
 551 AC_SUBST([REALTIME_LIBS])
 552
 553
 554 AC_CHECK_LIB([rtas], [rtas_get_sysparm], [
 555         RTAS_LIBS="-lrtas"
 556         AC_DEFINE_UNQUOTED([HAVE_LIBRTAS], [1], [Define if librtas exists]), [],
 557 ])
 558 AC_SUBST([RTAS_LIBS])
 559
 560
 561 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 562                 AC_DEFINE_UNQUOTED([HAVE_SA_LEN], [1], [Define if struct sockaddr contains sa_len]), [],
 563         [#include <sys/types.h>
 564          #include <sys/socket.h>])
 565
 566 SOCKET_LIBS=
 567 AC_SEARCH_LIBS([socket], [socket],
 568         [AS_IF([test x"$ac_cv_search_socket" != x"none required"],
 569                 [SOCKET_LIBS="$SOCKET_LIBS -lsocket"])
 570 ])
 571 AC_SUBST([SOCKET_LIBS])
 572
 573
 574 have_dirfd=no
 575 AC_CHECK_FUNCS([dirfd], [have_dirfd=yes], [have_dirfd=no])
 576 AS_IF([test x"$have_dirfd" = xno], [
 577         AC_CHECK_DECLS([dirfd],
 578                 [have_dirfd=yes], [have_dirfd=no],
 579                 [#include <sys/types.h>
 580                  #include <dirent.h>])
 581 ])
 582
 583 have_ddfd=no
 584 AS_IF([test x"$have_dirfd" = xno], [
 585         AC_CHECK_MEMBERS([DIR.dd_fd],
 586                 [have_ddfd=yes], [have_ddfd=no],
 587                 [#include <sys/types.h>
 588                  #include <dirent.h>])
 589 ])
 590
 591 AS_CASE([$have_dirfd:$have_ddfd],
 592   [no:no],
 593     [AC_MSG_ERROR([cannot find a method to get filedescriptor of directory])]
 594 )
 595
 596
 597 AC_MSG_CHECKING([whether program_invocation_short_name is defined])
 598 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 599         #include <errno.h>
 600 ]], [[
 601         program_invocation_short_name = "test";
 602 ]])], [
 603         AC_MSG_RESULT([yes])
 604         AC_DEFINE([HAVE_PROGRAM_INVOCATION_SHORT_NAME], [1],
 605                 [Define if program_invocation_short_name is defined])
 606 ], [
 607         AC_MSG_RESULT([no])
 608 ])
 609
 610
 611 AC_MSG_CHECKING([whether __progname is defined])
 612 AC_LINK_IFELSE([AC_LANG_PROGRAM([extern char *__progname;],
 613            [if (*__progname == 0) return 1;])],
 614            AC_DEFINE([HAVE___PROGNAME], [1], [Define if __progname is defined])
 615            AC_MSG_RESULT([yes]),
 616            AC_MSG_RESULT([no]))
 617
 618 dnl Static compilation
 619 m4_define([UL_STATIC_PROGRAMS], [losetup, mount, umount, fdisk, sfdisk, blkid, nsenter, unshare])
 620
 621 AC_ARG_ENABLE([static-programs],
 622   [AS_HELP_STRING([--enable-static-programs=LIST],
 623       [link static the programs in LIST (comma-separated,
 624       supported for ]m4_defn([UL_STATIC_PROGRAMS])[)])])
 625
 626 AS_CASE([$enable_static_programs],
 627   [yes],
 628     [enable_static_programs=m4_quote(UL_STATIC_PROGRAMS)],
 629   [no],
 630     [enable_static_programs=]
 631 )
 632
 633 dnl Set all the individual AM_CONDITIONALs
 634 m4_foreach([UL_PRG], m4_defn([UL_STATIC_PROGRAMS]), [
 635   AS_CASE([,$enable_static_programs,],
 636    [*,UL_PRG,*], [static_[]UL_PRG=yes]
 637   )
 638   AS_IF([test "x$static_[]UL_PRG" = xyes], [AC_MSG_NOTICE([enable static build: UL_PRG.])])
 639   AM_CONDITIONAL([HAVE_STATIC_]m4_toupper(UL_PRG),
 640     [test "x$static_[]UL_PRG" = xyes])
 641 ])
 642
 643
 644 AC_ARG_ENABLE([all-programs],
 645   AS_HELP_STRING([--disable-all-programs], [disable everything, might be overridden by --enable-<name>]),
 646   [], [enable_all_programs=undefined]
 647 )
 648
 649 AS_CASE([$enable_all_programs],
 650   [yes], [AC_MSG_WARN([force to build all programs by default])
 651           ul_default_estate=check],
 652   [no],  [AC_MSG_WARN([disable all programs by default])
 653           ul_default_estate=no]
 654 )
 655
 656
 657 AX_CHECK_TLS
 658
 659 AC_DEFUN([UL_SCANF_TYPE_MODIFIER], [dnl
 660 # include <stdio.h>
 661 # include <stdlib.h>
 662 int main()
 663 {
 664         int i;
 665         int rc = 1;
 666         char *s;
 667         i = sscanf("x", $1, &s);
 668         if (i == 1  && *s == 'x')
 669                 rc = 0;
 670         free(s);
 671         return rc;
 672 }])
 673
 674 AC_CACHE_VAL([scanf_cv_alloc_modifier],
 675   AC_RUN_IFELSE([AC_LANG_SOURCE([UL_SCANF_TYPE_MODIFIER(["%ms"])])],
 676     [scanf_cv_alloc_modifier=ms],
 677     AC_RUN_IFELSE([AC_LANG_SOURCE([UL_SCANF_TYPE_MODIFIER(["%as"])])],
 678       [scanf_cv_alloc_modifier=as],
 679       [scanf_cv_alloc_modifier=no]
 680     )
 681     ,
 682
 683     [AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 684      #include <stdio.h>
 685      #include <unistd.h>
 686
 687      #if defined(__GLIBC__) && !defined(__UCLIBC__)
 688
 689      #if !(__GLIBC_PREREQ(2, 7))
 690      #error %m is not available
 691      #endif
 692
 693      #elif defined(_POSIX_VERSION)
 694
 695      #if _POSIX_VERSION < 200809L
 696      #error %m is not available
 697      #endif
 698
 699      #else
 700      #error Your C-library is not supported.
 701      #endif
 702      ])],
 703     [scanf_cv_alloc_modifier=ms],
 704     [scanf_cv_alloc_modifier=no])]
 705   )
 706 )
 707
 708 AC_MSG_CHECKING([scanf string alloc modifiers])
 709 AS_CASE([$scanf_cv_alloc_modifier],
 710   [ms],
 711     [AC_MSG_RESULT([(%ms) yes])
 712      AC_DEFINE([HAVE_SCANF_MS_MODIFIER], [1], [scanf %ms modifier])
 713      have_scanf_alloc_modifier=yes],
 714   [as],
 715     [AC_MSG_RESULT([(%as) yes])
 716      have_scanf_alloc_modifier=yes
 717      AC_DEFINE([HAVE_SCANF_AS_MODIFIER], [1], [scanf %as modifier])],
 718   [AC_MSG_RESULT([no])
 719    have_scanf_alloc_modifier=no]
 720 )
 721
 722
 723 AC_ARG_WITH([util], AS_HELP_STRING([--without-util], [compile without libutil]),
 724   [], [with_util=auto]
 725 )
 726 AS_IF([test "x$with_util" = xno], [
 727   AM_CONDITIONAL([HAVE_UTIL], [false])
 728   have_util=no
 729 ], [
 730   UL_CHECK_LIB([util], [openpty])
 731 ])
 732
 733
 734 AC_CHECK_TYPES([union semun], [], [], [[
 735 #include <sys/sem.h>
 736 ]])
 737 AC_CHECK_TYPES([loff_t])
 738
 739
 740 AC_ARG_ENABLE([widechar],
 741   AS_HELP_STRING([--disable-widechar], [do not compile wide character support]),
 742   [], [enable_widechar=check]
 743 )
 744 UL_BUILD_INIT([widechar])
 745 UL_REQUIRES_COMPILE([widechar], [[
 746   #include <wchar.h>
 747   #include <wctype.h>
 748   #include <stdio.h>
 749   ]], [[
 750     wchar_t wc;
 751     wint_t w;
 752     w = fgetwc(stdin);
 753     if (w == WEOF) exit(1);
 754     wc = w;
 755     fputwc(wc,stdout);
 756   ]],
 757   [wchar_t support])
 758
 759 AS_IF([test "x$build_widechar" = xyes ], [
 760   AC_DEFINE([HAVE_WIDECHAR], [1], [Do we have wide character support?])
 761 ])
 762
 763
 764 AC_CHECK_TYPES([cpu_set_t], [have_cpu_set_t=yes], [], [[
 765 #include <sched.h>
 766 ]])
 767
 768 AM_CONDITIONAL([HAVE_CPU_SET_T], [test "x$have_cpu_set_t" = xyes])
 769
 770 AC_CHECK_TYPES([sighandler_t], [], [], [[
 771 #include <signal.h>
 772 ]])
 773
 774 AC_CHECK_DECLS([CPU_ALLOC], [], [], [[
 775 #include <sched.h>
 776 ]])
 777
 778 # on Solaris, you can't mix and match standards, since we use c99
 779 # aparently at this stage, XOPEN_SOURCE will conflict.  As workaround,
 780 # check for crypt.h and use that without XOPEN_SOURCE.
 781 AC_CHECK_HEADERS([crypt.h])
 782 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 783 #ifdef HAVE_CRYPT_H
 784 #include <crypt.h>
 785 #else
 786 #define _XOPEN_SOURCE
 787 #include <unistd.h>
 788 #endif
 789 ]], [[
 790 char *c = crypt("abc","pw");
 791 ]])],[],[
 792   LIBS="$LIBS -lcrypt"
 793   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 794   #ifdef HAVE_CRYPT_H
 795   #include <crypt.h>
 796   #else
 797   #define _XOPEN_SOURCE
 798   #include <unistd.h>
 799   #endif
 800   ]], [[
 801   char *c = crypt("abc","pw");
 802   ]])],[
 803   AC_DEFINE([HAVE_LIBCRYPT], [1], [Do we need -lcrypt?])
 804   have_libcrypt=yes
 805   ],[
 806   AC_MSG_ERROR([crypt() is not available])
 807   ])
 808 ])
 809 AM_CONDITIONAL([HAVE_LIBCRYPT], [test "x$have_libcrypt" = xyes])
 810
 811
 812 AC_ARG_WITH([selinux],
 813   AS_HELP_STRING([--with-selinux], [compile with SELinux support]),
 814   [], [with_selinux=no]
 815 )
 816
 817 AS_IF([test "x$with_selinux" = xno], [
 818   AM_CONDITIONAL([HAVE_SELINUX], [false])
 819 ], [
 820   PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.0],
 821         [AC_DEFINE([HAVE_LIBSELINUX], [1], [Define if SELinux is available])
 822          UL_PKG_STATIC([SELINUX_LIBS_STATIC], [libselinux])
 823          AM_CONDITIONAL([HAVE_SELINUX], [true])
 824          have_selinux=yes],
 825         [have_selinux=no])
 826
 827   AS_CASE([$with_selinux:$have_selinux],
 828     [yes:no], [AC_MSG_ERROR([SELinux selected but libselinux not found or too old])]
 829   )
 830
 831   AS_IF([test "x$have_selinux" = xyes], [
 832     UL_SET_FLAGS([], [], [$SELINUX_LIBS])
 833     # This function is missing in old libselinux 1.xx versions
 834     AC_CHECK_FUNCS([security_get_initial_context])
 835     UL_RESTORE_FLAGS
 836   ])
 837 ])
 838 AC_SUBST([SELINUX_LIBS])
 839 AC_SUBST([SELINUX_LIBS_STATIC])
 840
 841
 842 AC_ARG_WITH([audit],
 843   AS_HELP_STRING([--with-audit], [compile with audit support]),
 844   [], [with_audit=no]
 845 )
 846
 847 AS_IF([test "x$with_audit" = xno], [
 848   AM_CONDITIONAL([HAVE_AUDIT], [false])
 849 ], [
 850   UL_CHECK_LIB([audit], [audit_log_user_message])
 851   AS_CASE([$with_audit:$have_audit],
 852     [yes:no],
 853       [AC_MSG_ERROR([Audit selected but libaudit not found (or does not support audit_log_user_message())])]
 854   )
 855 ])
 856
 857 AC_ARG_WITH([udev], AS_HELP_STRING([--without-udev], [compile without udev support]),
 858   [], [with_udev=auto]
 859 )
 860
 861 AS_IF([test "x$with_udev" = xno], [
 862   AM_CONDITIONAL([HAVE_UDEV], [false])
 863 ], [
 864   UL_CHECK_LIB([udev], [udev_new])
 865   AS_CASE([$with_udev:$have_udev],
 866     [yes:no],
 867       [AC_MSG_ERROR([udev selected but libudev not found])]
 868   )
 869 ])
 870
 871
 872 dnl wide-char ncurses
 873 AC_ARG_WITH([ncursesw],
 874   AS_HELP_STRING([--without-ncursesw], [do not build with wide-char ncurses]),
 875   [], [with_ncursesw=auto]
 876 )
 877 have_ncursesw=no
 878 have_ncursesw_header=no
 879 AS_IF([test "x$with_ncursesw" != xno], [
 880   UL_NCURSES_CHECK([ncursesw])
 881   AS_IF([test "x$have_ncursesw" = xyes], [
 882     AC_CHECK_HEADERS([ncursesw/ncurses.h], [have_ncursesw_header=yes])
 883     AC_CHECK_HEADERS([ncursesw/term.h])
 884
 885     # Define HAVE_NCURSES_H only if check for HAVE_NCURSESW_NCURSES_H is
 886     # unsuccessful to avoid too many *_H permitations in config.h
 887     AS_IF([test "x$have_ncursesw_header" = xno], [
 888            AC_CHECK_HEADERS([ncurses.h], [have_ncursesw_header=yes])
 889            AC_CHECK_HEADERS([term.h])
 890     ])
 891     AS_IF([test "x$have_ncursesw_header" = xno], [have_ncursesw=no])
 892   ])
 893   AS_IF([test "x$have_ncursesw" = xyes], [
 894     CURSES_LIB_NAME="ncursesw"
 895     AC_DEFINE([HAVE_LIBNCURSESW], [1], [Define if ncursesw library available])
 896   ])
 897 ])
 898 AS_CASE([$with_ncursesw:$have_ncursesw],
 899   [yes:no], [AC_MSG_ERROR([ncursesw selected, but library not found])])
 900
 901
 902 dnl non-wide ncurses
 903 AC_ARG_WITH([ncurses],
 904   AS_HELP_STRING([--with-ncurses], [build with non-wide ncurses]),
 905   [], [with_ncurses=auto]
 906 )
 907 have_ncurses=no
 908 have_ncurses_header=no
 909 AS_CASE([$with_ncurses:$build_widechar],
 910   [yes:yes], [AC_MSG_ERROR([wide-char support enabled, but non-wide ncurses selects])])
 911
 912 AS_IF([test "x$have_ncursesw" = xno -a "x$with_ncurses" != xno ], [
 913   UL_NCURSES_CHECK([ncurses])
 914   AS_IF([test "x$have_ncurses" = xyes], [
 915     AC_CHECK_HEADERS([ncurses/ncurses.h], [have_ncurses_header=yes])
 916     AC_CHECK_HEADERS([ncurses/term.h])
 917
 918     # Define HAVE_NCURSES_H only if check for HAVE_NCURSES_NCURSES_H is
 919     # unsuccessful to avoid too many *_H permitations in config.h
 920     AS_IF([test "x$have_ncurses_header" = xno], [
 921            AC_CHECK_HEADERS([ncurses.h], [have_ncurses_header=yes])
 922            AC_CHECK_HEADERS([term.h])
 923     ])
 924     AS_IF([test "x$have_ncurses_header" = xno], [have_ncurses=no])
 925   ])
 926   AS_IF([test "x$have_ncurses" = xyes], [
 927     CURSES_LIB_NAME="ncurses"
 928     AC_DEFINE([HAVE_LIBNCURSES], [1], [Define if ncurses library available])
 929   ])
 930 ])
 931 AS_CASE([$with_ncurses:$have_ncurses],
 932   [yes:no], [AC_MSG_ERROR([ncurses selected, but library not found])])
 933
 934 AC_SUBST([NCURSES_CFLAGS])
 935 AC_SUBST([NCURSES_LIBS])
 936 AM_CONDITIONAL([HAVE_NCURSES], [test "x$have_ncursesw" = xyes -o  "x$have_ncurses" = xyes])
 937
 938
 939 AC_ARG_WITH([slang],
 940   AS_HELP_STRING([--with-slang], [compile cfdisk with slang rather than ncurses]),
 941   [], [with_slang=no]
 942 )
 943 have_slang=no
 944 AS_IF([test "x$with_slang" = xyes], [
 945   AC_CHECK_HEADERS([slang.h slang/slang.h])
 946   AC_CHECK_HEADERS([slcurses.h slang/slcurses.h],
 947                    [have_slang=yes], [], [
 948 #ifdef HAVE_SLANG_H
 949 #include <slang.h>
 950 #elif defined(HAVE_SLANG_SLANG_H)
 951 #include <slang/slang.h>
 952 #endif
 953 ])
 954   AS_IF([test "x$have_slang" = xno], [
 955     AC_MSG_ERROR([slang selected but slcurses.h not found])],
 956     [CURSES_LIB_NAME=slang
 957   ])
 958 ])
 959 AM_CONDITIONAL([HAVE_SLANG], [test "x$have_slang" = xyes])
 960
 961
 962 AS_IF([test "x$have_slang" = xyes -o "x$have_ncursesw" = xyes -o "x$have_ncurses" = xyes], [
 963         AC_CHECK_LIB([$CURSES_LIB_NAME], use_default_colors, [
 964                      AC_DEFINE(HAVE_USE_DEFAULT_COLORS, 1,
 965                                [Define if curses library has the use_default_colors().])
 966         ])
 967         AC_CHECK_LIB([$CURSES_LIB_NAME], resizeterm, [
 968                      AC_DEFINE(HAVE_RESIZETERM, 1,
 969                                [Define if curses library has the resizeterm().])
 970         ])
 971 ])
 972
 973
 974 AC_ARG_WITH([tinfo], AS_HELP_STRING([--without-tinfo], [compile without libtinfo]),
 975   [], [with_tinfo=auto]
 976 )
 977 have_tinfo=no
 978 have_tinfow=no
 979 AS_IF([test "x$with_tinfo" != xno], [
 980   AS_IF([test "x$have_ncursesw" = xyes], [
 981     UL_TINFO_CHECK([tinfow])
 982   ])
 983   AS_IF([test "x$have_tinfow" = xno], [
 984     UL_TINFO_CHECK([tinfo])
 985   ])
 986 ])
 987 AC_SUBST([TINFO_LIBS])
 988 AC_SUBST([TINFO_LIBS_STATIC])
 989 AC_SUBST([TINFO_CFLAGS])
 990 AM_CONDITIONAL([HAVE_TINFO], [test "x$have_tinfo" = xyes -o "x$have_tinfow" = xyes])
 991 AS_IF([test "x$have_tinfo" = xyes -o "x$have_tinfow" = xyes], [
 992   AC_DEFINE(HAVE_LIBTINFO, 1, [Define if libtinfo or libtinfow available.])
 993 ])
 994
 995
 996 AC_ARG_WITH([readline],
 997   AS_HELP_STRING([--without-readline], [do not build with GNU Readline support]),
 998   [], [with_readline=auto]
 999 )
1000
1001 AS_IF([test "x$with_readline" = xno], [
1002   AM_CONDITIONAL([HAVE_READLINE], [false])
1003 ], [
1004   UL_CHECK_LIB([readline], [readline])
1005   AS_CASE([$with_readline:$have_readline],
1006     [yes:no],
1007       [AC_MSG_ERROR([readline selected but libreadline not found ])],
1008     [*:yes],
1009       [READLINE_LIBS="-lreadline"
1010        READLINE_LIBS_STATIC="-lreadline $TINFO_LIBS_STATIC"]
1011   )
1012 ])
1013 AC_SUBST([READLINE_LIBS])
1014 AC_SUBST([READLINE_LIBS_STATIC])
1015
1016
1017 AC_ARG_WITH([utempter],
1018   AS_HELP_STRING([--with-utempter], [compile script(1) with libutempter]),
1019   [], [with_utempter=no]
1020 )
1021
1022 AS_IF([test "x$with_utempter" = xyes], [
1023   UL_CHECK_LIB([utempter], [utempter_add_record])
1024   AS_IF([test "x$have_utempter" = xno], [
1025     AC_MSG_ERROR([utempter selected but libutempter not found])
1026   ])
1027 ], [
1028   AM_CONDITIONAL([HAVE_UTEMPTER], [false])
1029 ])
1030
1031
1032 dnl
1033 dnl libuuid
1034 dnl
1035 AC_ARG_ENABLE([libuuid],
1036   AS_HELP_STRING([--disable-libuuid], [do not build libuuid and uuid utilities]),
1037   [], [UL_DEFAULT_ENABLE([libuuid], [yes])]
1038 )
1039 UL_BUILD_INIT([libuuid])
1040 AC_SUBST([LIBUUID_VERSION])
1041 AC_SUBST([LIBUUID_VERSION_INFO])
1042 AM_CONDITIONAL(BUILD_LIBUUID, test "x$build_libuuid" = xyes)
1043
1044 AC_ARG_ENABLE([libuuid-force-uuidd],
1045   AS_HELP_STRING([--enable-libuuid-force-uuidd], [support uuidd even though the daemon is not built]),
1046   [], [enable_libuuid_force_uuidd=no]
1047 )
1048
1049 AS_IF([test "x$build_libuuid" = xyes], [
1050   AC_DEFINE(HAVE_LIBUUID, 1, [Define to 1 if you have the -luuid.])
1051 ])
1052
1053 dnl
1054 dnl libblkid
1055 dnl
1056 AC_ARG_ENABLE([libblkid],
1057   AS_HELP_STRING([--disable-libblkid], [do not build libblkid and many related utilities]),
1058   [], [UL_DEFAULT_ENABLE([libblkid], [check])]
1059 )
1060 UL_BUILD_INIT([libblkid])
1061 UL_REQUIRES_HAVE([libblkid], [openat], [openat functions])
1062 AC_SUBST([LIBBLKID_DATE])
1063 AC_SUBST([LIBBLKID_VERSION])
1064 AC_SUBST([LIBBLKID_VERSION_INFO])
1065 AC_DEFINE_UNQUOTED([LIBBLKID_VERSION], ["$LIBBLKID_VERSION"], [libblkid version string])
1066 AC_DEFINE_UNQUOTED([LIBBLKID_DATE], ["$LIBBLKID_DATE"], [libblkid date string])
1067 AS_IF([test "x$build_libblkid" = xyes], [
1068   AC_DEFINE([HAVE_LIBBLKID], [1], [Define to 1 if you have the -lblkid.])
1069 ])
1070 AM_CONDITIONAL([BUILD_LIBBLKID], [test "x$build_libblkid" = xyes])
1071 AM_CONDITIONAL([BUILD_LIBBLKID_TESTS], [test "x$build_libblkid" = xyes -a "x$enable_static" = xyes])
1072
1073 dnl
1074 dnl libmount
1075 dnl
1076 AC_ARG_ENABLE([libmount],
1077   AS_HELP_STRING([--disable-libmount], [do not build libmount]),
1078   [], [UL_DEFAULT_ENABLE([libmount], [check])]
1079 )
1080 UL_BUILD_INIT([libmount])
1081 UL_REQUIRES_BUILD([libmount], [libblkid])
1082 UL_REQUIRES_HAVE([libmount], [scanf_alloc_modifier], [scanf string alloc modifier])
1083 AM_CONDITIONAL([BUILD_LIBMOUNT], [test "x$build_libmount" = xyes])
1084 AM_CONDITIONAL([BUILD_LIBMOUNT_TESTS], [test "x$build_libmount" = xyes -a "x$enable_static" = xyes])
1085 AS_IF([test "x$build_libmount" = xyes], [
1086         AC_DEFINE(HAVE_LIBMOUNT, 1, [Define if libmount available.])
1087 ])
1088
1089 AC_SUBST([LIBMOUNT_VERSION])
1090 AC_SUBST([LIBMOUNT_MAJOR_VERSION], $PACKAGE_VERSION_MAJOR)
1091 AC_SUBST([LIBMOUNT_MINOR_VERSION], $PACKAGE_VERSION_MINOR)
1092 AC_SUBST([LIBMOUNT_PATCH_VERSION], $PACKAGE_VERSION_RELEASE)
1093 AC_SUBST([LIBMOUNT_VERSION_INFO])
1094 AC_DEFINE_UNQUOTED([LIBMOUNT_VERSION], ["$LIBMOUNT_VERSION"], [libmount version string])
1095
1096 AC_ARG_ENABLE([libmount-support-mtab],
1097   AS_HELP_STRING([--enable-libmount-support-mtab], [support /etc/mtab (default is use /proc/self/mountinfo)]),
1098   [], [enable_libmount_support_mtab=no]
1099 )
1100
1101 AS_IF([test "x$enable_libmount_support_mtab" = xyes], [
1102   AC_DEFINE([USE_LIBMOUNT_SUPPORT_MTAB], [1], [Define to 1 if want to support mtab.])
1103 ])
1104
1105
1106 dnl
1107 dnl libsmartcols
1108 dnl
1109 AC_ARG_ENABLE([libsmartcols],
1110   AS_HELP_STRING([--disable-libsmartcols], [do not build libsmartcols]),
1111   [], [UL_DEFAULT_ENABLE([libsmartcols], [yes])]
1112 )
1113 UL_BUILD_INIT([libsmartcols])
1114 AM_CONDITIONAL([BUILD_LIBSMARTCOLS], [test "x$build_libsmartcols" = xyes])
1115
1116 AC_SUBST([LIBSMARTCOLS_VERSION])
1117 AC_SUBST([LIBSMARTCOLS_VERSION_INFO])
1118 AC_DEFINE_UNQUOTED([LIBSMARTCOLS_VERSION], ["$LIBSMARTCOLS_VERSION"], [libsmartcols version string])
1119
1120
1121 dnl
1122 dnl libfdisk
1123 dnl
1124 AC_ARG_ENABLE([libfdisk],
1125   AS_HELP_STRING([--disable-libfdisk], [do not build libfdisk]),
1126   [], [UL_DEFAULT_ENABLE([libfdisk], [check])]
1127 )
1128 UL_BUILD_INIT([libfdisk])
1129 UL_REQUIRES_BUILD([libfdisk], [libuuid])
1130 AM_CONDITIONAL([BUILD_LIBFDISK], [test "x$build_libfdisk" = xyes])
1131 AM_CONDITIONAL([BUILD_LIBFDISK_TESTS], [test "x$build_libfdisk" = xyes -a "x$enable_static" = xyes])
1132
1133 AS_IF([test "x$build_libblkid" = xyes],
1134   [LIBFDISK_PC_REQUIRES="uuid blkid"],[LIBFDISK_PC_REQUIRES="uuid"])
1135 AC_SUBST([LIBFDISK_PC_REQUIRES])
1136
1137 AC_SUBST([LIBFDISK_VERSION])
1138 AC_SUBST([LIBFDISK_MAJOR_VERSION], $PACKAGE_VERSION_MAJOR)
1139 AC_SUBST([LIBFDISK_MINOR_VERSION], $PACKAGE_VERSION_MINOR)
1140 AC_SUBST([LIBFDISK_PATCH_VERSION], $PACKAGE_VERSION_RELEASE)
1141 AC_SUBST([LIBFDISK_VERSION_INFO])
1142 AC_DEFINE_UNQUOTED([LIBFDISK_VERSION], ["$LIBFDISK_VERSION"], [libfdisk version string])
1143
1144
1145 UL_BUILD_INIT([fdisk], [check])
1146 UL_REQUIRES_HAVE([fdisk], [openat], [openat functions])
1147 UL_REQUIRES_BUILD([fdisk], [libfdisk])
1148 UL_REQUIRES_BUILD([fdisk], [libsmartcols])
1149 AM_CONDITIONAL([BUILD_FDISK], [test "x$build_fdisk" = xyes])
1150
1151
1152 UL_BUILD_INIT([sfdisk], [check])
1153 UL_REQUIRES_HAVE([sfdisk], [openat], [openat functions])
1154 UL_REQUIRES_BUILD([sfdisk], [libfdisk])
1155 UL_REQUIRES_BUILD([sfdisk], [libsmartcols])
1156 AM_CONDITIONAL([BUILD_SFDISK], [test "x$build_sfdisk" = xyes])
1157
1158
1159 UL_BUILD_INIT([cfdisk], [check])
1160 UL_REQUIRES_BUILD([cfdisk], [libfdisk])
1161 UL_REQUIRES_BUILD([cfdisk], [libsmartcols])
1162 UL_REQUIRES_HAVE([cfdisk], [open_memstream], [open_memstream function])
1163 UL_REQUIRES_HAVE([cfdisk], [ncursesw,slang,ncurses], [ncursesw, ncurses or slang library])
1164 AM_CONDITIONAL([BUILD_CFDISK], [test "x$build_cfdisk" = xyes])
1165
1166
1167 AC_ARG_ENABLE([mount],
1168   AS_HELP_STRING([--disable-mount], [do not build mount(8) and umount(8)]),
1169   [], [UL_DEFAULT_ENABLE([mount], [check])]
1170 )
1171 UL_BUILD_INIT([mount])
1172 UL_REQUIRES_LINUX([mount])
1173 UL_REQUIRES_BUILD([mount], [libmount])
1174 AM_CONDITIONAL([BUILD_MOUNT], [test "x$build_mount" = xyes])
1175
1176
1177 AC_ARG_ENABLE([losetup],
1178   AS_HELP_STRING([--disable-losetup], [do not build losetup]),
1179   [], [UL_DEFAULT_ENABLE([losetup], [check])]
1180 )
1181 UL_BUILD_INIT([losetup])
1182 UL_REQUIRES_LINUX([losetup])
1183 UL_REQUIRES_BUILD([losetup], [libsmartcols])
1184 AM_CONDITIONAL([BUILD_LOSETUP], [test "x$build_losetup" = xyes])
1185
1186 AC_ARG_ENABLE([zramctl],
1187   AS_HELP_STRING([--disable-zramctl], [do not build zramctl]),
1188   [], [UL_DEFAULT_ENABLE([zramctl], [check])]
1189 )
1190 UL_BUILD_INIT([zramctl])
1191 UL_REQUIRES_LINUX([zramctl])
1192 UL_REQUIRES_BUILD([zramctl], [libsmartcols])
1193 AM_CONDITIONAL([BUILD_ZRAMCTL], [test "x$build_zramctl" = xyes])
1194
1195 AC_ARG_ENABLE([fsck],
1196   AS_HELP_STRING([--disable-fsck], [do not build fsck]),
1197   [], [UL_DEFAULT_ENABLE([fsck], [check])]
1198 )
1199 UL_BUILD_INIT([fsck])
1200 UL_REQUIRES_BUILD([fsck], [libmount])
1201 AM_CONDITIONAL([BUILD_FSCK], [test "x$build_fsck" = xyes])
1202
1203
1204 AC_ARG_ENABLE([partx],
1205   AS_HELP_STRING([--disable-partx], [do not build addpart, delpart, partx]),
1206   [], [UL_DEFAULT_ENABLE([partx], [check])]
1207 )
1208 UL_BUILD_INIT([partx])
1209 UL_REQUIRES_LINUX([partx])
1210 UL_REQUIRES_BUILD([partx], [libblkid])
1211 UL_REQUIRES_BUILD([partx], [libsmartcols])
1212 AM_CONDITIONAL([BUILD_PARTX], [test "x$build_partx" = xyes])
1213
1214
1215 AC_ARG_ENABLE([uuidd],
1216   AS_HELP_STRING([--disable-uuidd], [do not build the uuid daemon]),
1217   [], [UL_DEFAULT_ENABLE([uuidd], [check])]
1218 )
1219 UL_BUILD_INIT([uuidd])
1220 UL_REQUIRES_BUILD([uuidd], [libuuid])
1221 UL_REQUIRES_HAVE([uuidd], [timer], [timer_create function])
1222 UL_REQUIRES_HAVE([uuidd], [sys_signalfd_h], [sys/signalfd.h header])
1223 AS_IF([test "x$build_uuidd" = xyes || test "x$enable_libuuid_force_uuidd" = xyes], [
1224   AC_DEFINE([HAVE_UUIDD], [1], [Define to 1 if you want to use uuid daemon.])
1225 ])
1226 AM_CONDITIONAL([BUILD_UUIDD], [test "x$build_uuidd" = xyes])
1227
1228
1229 UL_BUILD_INIT([uuidgen], [check])
1230 UL_REQUIRES_BUILD([uuidgen], [libuuid])
1231 AM_CONDITIONAL([BUILD_UUIDGEN], [test "x$build_uuidgen" = xyes])
1232
1233 UL_BUILD_INIT([uuidparse], [check])
1234 UL_REQUIRES_BUILD([uuidparse], [libuuid])
1235 UL_REQUIRES_BUILD([uuidparse], [libsmartcols])
1236 AM_CONDITIONAL([BUILD_UUIDPARSE], [test "x$build_uuidparse" = xyes])
1237
1238 UL_BUILD_INIT([blkid], [check])
1239 UL_REQUIRES_BUILD([blkid], [libblkid])
1240 AM_CONDITIONAL([BUILD_BLKID], [test "x$build_blkid" = xyes])
1241
1242 UL_BUILD_INIT([findfs], [check])
1243 UL_REQUIRES_BUILD([findfs], [libblkid])
1244 AM_CONDITIONAL([BUILD_FINDFS], [test "x$build_findfs" = xyes])
1245
1246 UL_BUILD_INIT([wipefs], [check])
1247 UL_REQUIRES_BUILD([wipefs], [libblkid])
1248 UL_REQUIRES_BUILD([wipefs], [libsmartcols])
1249 AM_CONDITIONAL([BUILD_WIPEFS], [test "x$build_wipefs" = xyes])
1250
1251 UL_BUILD_INIT([findmnt], [check])
1252 UL_REQUIRES_BUILD([findmnt], [libmount])
1253 UL_REQUIRES_BUILD([findmnt], [libblkid])
1254 UL_REQUIRES_BUILD([findmnt], [libsmartcols])
1255 AM_CONDITIONAL([BUILD_FINDMNT], [test "x$build_findmnt" = xyes])
1256
1257
1258 AC_ARG_ENABLE([mountpoint],
1259   AS_HELP_STRING([--disable-mountpoint], [do not build mountpoint]),
1260   [], [UL_DEFAULT_ENABLE([mountpoint], [check])]
1261 )
1262 UL_BUILD_INIT([mountpoint])
1263 UL_REQUIRES_BUILD([mountpoint], [libmount])
1264 AM_CONDITIONAL([BUILD_MOUNTPOINT], [test "x$build_mountpoint" = xyes])
1265
1266
1267 AC_ARG_ENABLE([fallocate],
1268   AS_HELP_STRING([--disable-fallocate], [do not build fallocate]),
1269   [], [UL_DEFAULT_ENABLE([fallocate], [check])]
1270 )
1271 UL_BUILD_INIT([fallocate])
1272 UL_REQUIRES_LINUX([fallocate])
1273 UL_REQUIRES_SYSCALL_CHECK([fallocate], [UL_CHECK_SYSCALL([fallocate])])
1274 AM_CONDITIONAL([BUILD_FALLOCATE], [test "x$build_fallocate" = xyes])
1275
1276 AS_IF([test "x$build_fallocate" = xyes], [
1277   dnl check for valid fallocate() function
1278   dnl with 32 bits glibc 2.10, fallocate() exists but not fallocate64()
1279   dnl when _FILE_OFFSET_BITS==64, fallocate() is redirect to fallocate64()
1280   dnl and program can't be linked.
1281   dnl AC_CHECK_FUNC can't catch such errors since it's redefining
1282   dnl function prototype.
1283   AC_MSG_CHECKING([for valid fallocate() function])
1284   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1285 #ifdef HAVE_UNISTD_H
1286 # include <unistd.h>
1287 #endif
1288 #ifdef HAVE_SYS_TYPES_H
1289 # include <sys/types.h>
1290 #endif
1291 #ifdef HAVE_LINUX_FALLOC_H
1292 # include <linux/falloc.h>
1293 #endif
1294 #ifdef HAVE_FCNTL_H
1295 # include <fcntl.h>
1296 #endif
1297 ]],[[
1298    long ret;
1299    ret = fallocate(0, FALLOC_FL_KEEP_SIZE, 0xfffffffful, 0xfffffffful);
1300    if (ret != 0) {
1301       return 1;
1302    }
1303    ]])],[
1304   AC_MSG_RESULT([yes])
1305   AC_DEFINE([HAVE_FALLOCATE], [1], [Have valid fallocate() function])],[
1306   AC_MSG_RESULT([no])])
1307 ])
1308
1309 AS_IF([test "x$build_fallocate" = xyes], [
1310   dnl check for valid posix_fallocate() function
1311   AC_MSG_CHECKING([for valid posix_fallocate() function])
1312   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1313 #ifdef HAVE_UNISTD_H
1314 # include <unistd.h>
1315 #endif
1316 #ifdef HAVE_SYS_TYPES_H
1317 # include <sys/types.h>
1318 #endif
1319 #ifdef HAVE_LINUX_FALLOC_H
1320 # include <linux/falloc.h>
1321 #endif
1322 #ifdef HAVE_FCNTL_H
1323 # include <fcntl.h>
1324 #endif
1325 ]],[[
1326    long ret;
1327    ret = posix_fallocate(0, 0xfffffffful, 0xfffffffful);
1328    if (ret != 0) {
1329       return 1;
1330    }
1331    ]])],[
1332   AC_MSG_RESULT([yes])
1333   AC_DEFINE([HAVE_POSIX_FALLOCATE], [1], [Have valid posix_fallocate() function])],[
1334   AC_MSG_RESULT([no])])
1335 ])
1336
1337
1338 AC_ARG_ENABLE([unshare],
1339   AS_HELP_STRING([--disable-unshare], [do not build unshare]),
1340   [], [UL_DEFAULT_ENABLE([unshare], [check])]
1341 )
1342 UL_BUILD_INIT([unshare])
1343 UL_REQUIRES_LINUX([unshare])
1344 UL_REQUIRES_SYSCALL_CHECK([unshare], [UL_CHECK_SYSCALL([unshare])])
1345 AM_CONDITIONAL([BUILD_UNSHARE], [test "x$build_unshare" = xyes])
1346 AC_CHECK_FUNCS([unshare])
1347
1348 AC_ARG_ENABLE([nsenter],
1349   AS_HELP_STRING([--disable-nsenter], [do not build nsenter]),
1350   [], [UL_DEFAULT_ENABLE([nsenter], [check])]
1351 )
1352 UL_BUILD_INIT([nsenter])
1353 UL_REQUIRES_LINUX([nsenter])
1354 UL_REQUIRES_SYSCALL_CHECK([nsenter], [UL_CHECK_SYSCALL([setns])], [setns])
1355 AM_CONDITIONAL([BUILD_NSENTER], [test "x$build_nsenter" = xyes])
1356 AC_CHECK_FUNCS([setns])
1357
1358
1359 AC_ARG_WITH([cap_ng],
1360   AS_HELP_STRING([--without-cap-ng], [compile without libcap-ng]),
1361   [], [with_cap_ng=auto]
1362 )
1363 AS_IF([test "x$with_cap_ng" = xno], [
1364   AM_CONDITIONAL([HAVE_CAP_NG], [false])
1365   have_cap_ng=no
1366 ],[
1367   UL_CHECK_LIB([cap-ng], [capng_apply], [cap_ng])
1368 ])
1369
1370
1371 AC_ARG_ENABLE([setpriv],
1372   AS_HELP_STRING([--disable-setpriv], [do not build setpriv]),
1373   [], [UL_DEFAULT_ENABLE([setpriv], [check])]
1374 )
1375 UL_BUILD_INIT([setpriv])
1376 UL_REQUIRES_LINUX([setpriv])
1377 UL_REQUIRES_HAVE([setpriv], [linux_securebits_h], [securebits.h header file])
1378 UL_REQUIRES_HAVE([setpriv], [cap_ng], [libcap-ng library])
1379 AM_CONDITIONAL([BUILD_SETPRIV], [test "x$build_setpriv" = xyes])
1380
1381
1382 AC_ARG_ENABLE([eject],
1383   AS_HELP_STRING([--disable-eject], [do not build eject]),
1384   [], [UL_DEFAULT_ENABLE([eject], [check])]
1385 )
1386 UL_BUILD_INIT([eject])
1387 UL_REQUIRES_LINUX([eject])
1388 UL_REQUIRES_BUILD([eject], [libmount])
1389 AM_CONDITIONAL([BUILD_EJECT], [test "x$build_eject" = xyes])
1390
1391
1392 AC_ARG_ENABLE([agetty],
1393   AS_HELP_STRING([--disable-agetty], [do not build agetty]),
1394   [], [UL_DEFAULT_ENABLE([agetty], [check])]
1395 )
1396 UL_BUILD_INIT([agetty])
1397 UL_REQUIRES_HAVE([agetty], [utmpx_h], [utmpx.h header])
1398 UL_REQUIRES_HAVE([agetty], [gnu_utmpx], [GNU utmpx functions])
1399 AM_CONDITIONAL([BUILD_AGETTY], [test "x$build_agetty" = xyes])
1400 AS_IF([test "x$have_futimens" = xyes -a "x$have_inotify_init1" = xyes ], [
1401   AC_DEFINE([AGETTY_RELOAD], [1], [Enable agetty --reload feature])
1402 ],[
1403   AC_MSG_WARN([futimens or inotify_init1 not found; agetty(8) will not provide ---reload functionality])
1404 ])
1405
1406
1407 AC_ARG_ENABLE([plymouth_support],
1408   AS_HELP_STRING([--disable-plymouth_support], [don not care about plymouth in sylogin(8) and agetty(8)]),
1409   [], [enable_plymouth_support=check]
1410 )
1411 UL_BUILD_INIT([plymouth_support])
1412 UL_REQUIRES_HAVE([plymouth_support], [tiocglcktrmios], [TIOCGLCKTRMIOS flag])
1413 UL_REQUIRES_HAVE([plymouth_support], [sock_cloexec], [SOCK_CLOEXEC flag])
1414 UL_REQUIRES_HAVE([plymouth_support], [sock_nonblock], [SOCK_NONBLOCK flag])
1415 UL_REQUIRES_HAVE([plymouth_support], [so_passcred], [SO_PASSCRED flag])
1416 AM_CONDITIONAL([USE_PLYMOUTH_SUPPORT], [test "x$build_plymouth_support" = xyes])
1417 AS_IF([test "x$build_plymouth_support" = xyes ], [
1418     AC_DEFINE([USE_PLYMOUTH_SUPPORT], [1], [Enable plymouth support feature for sulogin and aggety])
1419 ])
1420
1421
1422 AC_ARG_WITH([libz],
1423   AS_HELP_STRING([--without-libz], [compile without libz]),
1424   [], [with_libz=auto]
1425 )
1426 AS_IF([test "x$with_libz" = xno], [have_z=no], [
1427   AC_CHECK_LIB([z], [crc32], [have_z=yes], [have_z=no])
1428 ])
1429
1430
1431 AC_ARG_ENABLE([cramfs],
1432   AS_HELP_STRING([--disable-cramfs], [do not build fsck.cramfs, mkfs.cramfs]),
1433   [], [UL_DEFAULT_ENABLE([cramfs], [check])]
1434 )
1435 UL_BUILD_INIT([cramfs])
1436 UL_REQUIRES_HAVE([cramfs], [z], [z library])
1437 AM_CONDITIONAL([BUILD_CRAMFS], [test "x$build_cramfs" = xyes])
1438
1439
1440 AC_ARG_ENABLE([bfs],
1441   AS_HELP_STRING([--disable-bfs], [do not build mkfs.bfs]),
1442   [], [UL_DEFAULT_ENABLE([bfs], [yes])]
1443 )
1444 UL_BUILD_INIT([bfs])
1445 AM_CONDITIONAL([BUILD_BFS], [test "x$build_bfs" = xyes])
1446
1447
1448 AC_ARG_ENABLE([minix],
1449   AS_HELP_STRING([--disable-minix], [do not build fsck.minix, mkfs.minix]),
1450   [], [UL_DEFAULT_ENABLE([minix], [yes])]
1451 )
1452 UL_BUILD_INIT([minix])
1453 AM_CONDITIONAL([BUILD_MINIX], [test "x$build_minix" = xyes])
1454
1455
1456 AC_ARG_ENABLE([fdformat],
1457   AS_HELP_STRING([--disable-fdformat], [do not build fdformat]),
1458   [], [UL_DEFAULT_ENABLE([fdformat], [check])]
1459 )
1460 UL_BUILD_INIT([fdformat])
1461 UL_REQUIRES_LINUX([fdformat])
1462 AM_CONDITIONAL([BUILD_FDFORMAT], [test "x$build_fdformat" = xyes])
1463
1464
1465 AC_ARG_ENABLE([hwclock],
1466   AS_HELP_STRING([--disable-hwclock], [do not build hwclock]),
1467   [], [UL_DEFAULT_ENABLE([hwclock], [check])]
1468 )
1469 have_linuxdummy=$linux_os
1470
1471 UL_BUILD_INIT([hwclock])
1472 UL_REQUIRES_HAVE([hwclock], [io, linuxdummy], [ioperm iopl function or Linux])
1473 AM_CONDITIONAL([BUILD_HWCLOCK], [test "x$build_hwclock" = xyes])
1474
1475
1476 UL_BUILD_INIT([mkfs], [yes])
1477 AM_CONDITIONAL([BUILD_MKFS], [test "x$build_mkfs" = xyes])
1478
1479 UL_BUILD_INIT([isosize], [yes])
1480 AM_CONDITIONAL([BUILD_ISOSIZE], [test "x$build_isosize" = xyes])
1481
1482
1483 UL_BUILD_INIT([fstrim], [check])
1484 UL_REQUIRES_LINUX([fstrim])
1485 UL_REQUIRES_BUILD([fstrim], [libmount])
1486 AM_CONDITIONAL([BUILD_FSTRIM], [test "x$build_fstrim" = xyes])
1487
1488
1489 UL_BUILD_INIT([swapon], [check])
1490 UL_REQUIRES_LINUX([swapon])
1491 UL_REQUIRES_SYSCALL_CHECK([swapon], [UL_CHECK_SYSCALL([swapon])], [swapon])
1492 UL_REQUIRES_SYSCALL_CHECK([swapon], [UL_CHECK_SYSCALL([swapoff])], [swapoff])
1493 UL_REQUIRES_BUILD([swapon], [libblkid])
1494 UL_REQUIRES_BUILD([swapon], [libmount])
1495 UL_REQUIRES_BUILD([swapon], [libsmartcols])
1496 AM_CONDITIONAL([BUILD_SWAPON], [test "x$build_swapon" = xyes])
1497 AC_CHECK_FUNCS([swapon])
1498 AC_CHECK_FUNCS([swapoff])
1499
1500
1501 UL_BUILD_INIT([lsblk], [check])
1502 UL_REQUIRES_LINUX([lsblk])
1503 UL_REQUIRES_BUILD([lsblk], [libblkid])
1504 UL_REQUIRES_BUILD([lsblk], [libmount])
1505 UL_REQUIRES_BUILD([lsblk], [libsmartcols])
1506 AM_CONDITIONAL([BUILD_LSBLK], [test "x$build_lsblk" = xyes])
1507
1508
1509 UL_BUILD_INIT([lscpu], [check])
1510 UL_REQUIRES_LINUX([lscpu])
1511 UL_REQUIRES_BUILD([lscpu], [libsmartcols])
1512 UL_REQUIRES_HAVE([lscpu], [cpu_set_t], [cpu_set_t type])
1513 AM_CONDITIONAL([BUILD_LSCPU], [test "x$build_lscpu" = xyes])
1514
1515
1516 AC_ARG_ENABLE([lslogins],
1517   AS_HELP_STRING([--disable-lslogins], [do not build lslogins]),
1518   [], [UL_DEFAULT_ENABLE([lslogins], [check])]
1519 )
1520 UL_BUILD_INIT([lslogins])
1521 UL_REQUIRES_BUILD([lslogins], [libsmartcols])
1522 UL_REQUIRES_HAVE([lslogins], [shadow_h], [shadow.h header])
1523 UL_REQUIRES_HAVE([lslogins], [utmpx_h], [utmpx.h header])
1524 UL_REQUIRES_HAVE([lslogins], [gnu_utmpx], [GNU utmpx functions])
1525 AM_CONDITIONAL([BUILD_LSLOGINS], [test "x$build_lslogins" = xyes])
1526
1527
1528 UL_BUILD_INIT([chcpu], [check])
1529 UL_REQUIRES_LINUX([chcpu])
1530 UL_REQUIRES_HAVE([chcpu], [cpu_set_t], [cpu_set_t type])
1531 AM_CONDITIONAL([BUILD_CHCPU], [test "x$build_chcpu" = xyes])
1532
1533
1534 AC_ARG_ENABLE([wdctl],
1535   AS_HELP_STRING([--disable-wdctl], [do not build wdctl]),
1536   [], [UL_DEFAULT_ENABLE([wdctl], [check])]
1537 )
1538 UL_BUILD_INIT([wdctl])
1539 UL_REQUIRES_LINUX([wdctl])
1540 UL_REQUIRES_BUILD([wdctl], [libsmartcols])
1541 UL_REQUIRES_HAVE([wdctl], [linux_watchdog_h], [linux/watchdog.h header file])
1542 AM_CONDITIONAL([BUILD_WDCTL], [test "x$build_wdctl" = xyes])
1543
1544
1545 UL_BUILD_INIT([swaplabel], [check])
1546 UL_REQUIRES_BUILD([swaplabel], [libblkid])
1547 AM_CONDITIONAL([BUILD_SWAPLABEL], [test "x$build_swaplabel" = xyes])
1548
1549
1550 UL_BUILD_INIT([mkswap], [yes])
1551 AM_CONDITIONAL([BUILD_MKSWAP], [test "x$build_mkswap" = xyes])
1552 AS_IF([test "x$build_mkswap" = xyes -a "x$build_libuuid" != xyes], [
1553   AC_MSG_WARN([uuid library is not found; mkswap(8) will not generate UUIDs])
1554 ])
1555
1556
1557 AC_ARG_ENABLE([cal],
1558   AS_HELP_STRING([--disable-cal], [do not build cal]),
1559   [], [UL_DEFAULT_ENABLE([cal], [check])]
1560 )
1561 UL_BUILD_INIT([cal])
1562 AM_CONDITIONAL([BUILD_CAL], [test "x$build_cal" = xyes])
1563
1564 AC_ARG_ENABLE([logger],
1565   AS_HELP_STRING([--disable-logger], [do not build logger]),
1566   [], [UL_DEFAULT_ENABLE([logger], [check])]
1567 )
1568 UL_BUILD_INIT([logger])
1569 AM_CONDITIONAL([BUILD_LOGGER], [test "x$build_logger" = xyes])
1570
1571 UL_BUILD_INIT([look], [yes])
1572 AM_CONDITIONAL([BUILD_LOOK], [test "x$build_look" = xyes])
1573
1574 UL_BUILD_INIT([mcookie], [yes])
1575 AM_CONDITIONAL([BUILD_MCOOKIE], [test "x$build_mcookie" = xyes])
1576
1577 UL_BUILD_INIT([namei], [yes])
1578 AM_CONDITIONAL([BUILD_NAMEI], [test "x$build_namei" = xyes])
1579
1580 matriplet="$($CC -print-multiarch 2>/dev/null || true)"
1581 if test "x$matriplet" != "x"; then
1582   AC_DEFINE_UNQUOTED([MULTIARCHTRIPLET], ["$matriplet"],
1583   ["Multi-arch triplet for whereis library search path"])
1584 fi
1585 UL_BUILD_INIT([whereis], [yes])
1586 AM_CONDITIONAL([BUILD_WHEREIS], [test "x$build_whereis" = xyes])
1587
1588 UL_BUILD_INIT([getopt], [yes])
1589 AM_CONDITIONAL([BUILD_GETOPT], [test "x$build_getopt" = xyes])
1590
1591
1592 UL_BUILD_INIT([blockdev], [check])
1593 UL_REQUIRES_LINUX([blockdev])
1594 AM_CONDITIONAL([BUILD_BLOCKDEV], [test "x$build_blockdev" = xyes])
1595
1596
1597 UL_BUILD_INIT([prlimit], [check])
1598 UL_REQUIRES_LINUX([prlimit])
1599 UL_REQUIRES_BUILD([prlimit], [libsmartcols])
1600 UL_REQUIRES_SYSCALL_CHECK([prlimit], [UL_CHECK_SYSCALL([prlimit64])], [prlimit64])
1601 AM_CONDITIONAL([BUILD_PRLIMIT], [test "x$build_prlimit" = xyes])
1602 AS_IF([test "x$build_prlimit" = xyes], [
1603   AC_CHECK_FUNCS([prlimit])
1604 ])
1605
1606
1607 UL_BUILD_INIT([lslocks], [check])
1608 UL_REQUIRES_LINUX([lslocks])
1609 UL_REQUIRES_BUILD([lslocks], [libmount])
1610 UL_REQUIRES_BUILD([lslocks], [libsmartcols])
1611 AM_CONDITIONAL([BUILD_LSLOCKS], [test "x$build_lslocks" = xyes])
1612
1613
1614 AC_ARG_ENABLE([switch_root],
1615   AS_HELP_STRING([--disable-switch_root], [do not build switch_root]),
1616   [], [UL_DEFAULT_ENABLE([switch_root], [check])]
1617 )
1618 UL_BUILD_INIT([switch_root])
1619 UL_REQUIRES_LINUX([switch_root])
1620 UL_REQUIRES_HAVE([switch_root], [openat], [openat function])
1621 AM_CONDITIONAL([BUILD_SWITCH_ROOT], [test "x$build_switch_root" = xyes])
1622
1623
1624 AC_ARG_ENABLE([pivot_root],
1625   AS_HELP_STRING([--disable-pivot_root], [do not build pivot_root]),
1626   [], [UL_DEFAULT_ENABLE([pivot_root], [check])]
1627 )
1628 UL_BUILD_INIT([pivot_root])
1629 UL_REQUIRES_LINUX([pivot_root])
1630 UL_REQUIRES_SYSCALL_CHECK([pivot_root], [UL_CHECK_SYSCALL([pivot_root])])
1631 AM_CONDITIONAL([BUILD_PIVOT_ROOT], [test "x$build_pivot_root" = xyes])
1632
1633
1634 UL_BUILD_INIT([flock], [check])
1635 UL_REQUIRES_HAVE([flock], [timer], [timer_create function])
1636 AM_CONDITIONAL([BUILD_FLOCK], [test "x$build_flock" = xyes])
1637
1638
1639 AC_ARG_ENABLE([lsmem],
1640   AS_HELP_STRING([--disable-lsmem], [do not build lsmem]),
1641   [], [UL_DEFAULT_ENABLE([lsmem], [check])]
1642 )
1643 UL_BUILD_INIT([lsmem])
1644 UL_REQUIRES_LINUX([lsmem])
1645 UL_REQUIRES_BUILD([lsmem], [libsmartcols])
1646 AM_CONDITIONAL([BUILD_LSMEM], [test "x$build_lsmem" = xyes])
1647
1648
1649 AC_ARG_ENABLE([chmem],
1650   AS_HELP_STRING([--disable-chmem], [do not build chmem]),
1651   [], [UL_DEFAULT_ENABLE([chmem], [check])]
1652 )
1653 UL_BUILD_INIT([chmem])
1654 UL_REQUIRES_LINUX([chmem])
1655 AM_CONDITIONAL([BUILD_CHMEM], [test "x$build_chmem" = xyes])
1656
1657 UL_BUILD_INIT([ipcmk], [yes])
1658 AM_CONDITIONAL([BUILD_IPCMK], [test "x$build_ipcmk" = xyes])
1659
1660
1661 AC_ARG_ENABLE([ipcrm],
1662   AS_HELP_STRING([--disable-ipcrm], [do not build ipcrm]),
1663   [], [UL_DEFAULT_ENABLE([ipcrm], [yes])]
1664 )
1665 UL_BUILD_INIT([ipcrm])
1666 AM_CONDITIONAL([BUILD_IPCRM], [test "x$build_ipcrm" = xyes])
1667
1668 AC_ARG_ENABLE([ipcs],
1669   AS_HELP_STRING([--disable-ipcs], [do not build ipcs]),
1670   [], [UL_DEFAULT_ENABLE([ipcs], [yes])]
1671 )
1672 UL_BUILD_INIT([ipcs])
1673 AM_CONDITIONAL([BUILD_IPCS], [test "x$build_ipcs" = xyes])
1674
1675 UL_BUILD_INIT([choom], [check])
1676 UL_REQUIRES_LINUX([choom])
1677 AM_CONDITIONAL([BUILD_CHOOM], [test "x$build_choom" = xyes])
1678
1679 UL_BUILD_INIT([lsipc], [check])
1680 UL_REQUIRES_LINUX([lsipc])
1681 UL_REQUIRES_BUILD([lsipc], [libsmartcols])
1682 AM_CONDITIONAL([BUILD_LSIPC], [test "x$build_lsipc" = xyes])
1683
1684 UL_BUILD_INIT([lsns], [check])
1685 UL_REQUIRES_LINUX([lsns])
1686 UL_REQUIRES_BUILD([lsns], [libsmartcols])
1687 UL_REQUIRES_BUILD([lsns], [libmount])
1688 AM_CONDITIONAL([BUILD_LSNS], [test "x$build_lsns" = xyes])
1689
1690 UL_BUILD_INIT([renice], [yes])
1691 AM_CONDITIONAL([BUILD_RENICE], [test "x$build_renice" = xyes])
1692
1693
1694 AC_ARG_ENABLE([rfkill],
1695   AS_HELP_STRING([--disable-rfkill], [do not build rfkill]),
1696   [], [UL_DEFAULT_ENABLE([rfkill], [check])]
1697 )
1698 UL_BUILD_INIT([rfkill])
1699 UL_REQUIRES_LINUX([rfkill])
1700 UL_REQUIRES_BUILD([rfkill], [libsmartcols])
1701 AM_CONDITIONAL([BUILD_RFKILL], [test "x$build_rfkill" = xyes])
1702
1703
1704 UL_BUILD_INIT([setsid], [yes])
1705 AM_CONDITIONAL([BUILD_SETSID], [test "x$build_setsid" = xyes])
1706
1707 UL_BUILD_INIT([readprofile], [check])
1708 UL_REQUIRES_LINUX([readprofile])
1709 AM_CONDITIONAL([BUILD_READPROFILE], [test "x$build_readprofile" = xyes])
1710
1711 UL_BUILD_INIT([dmesg], [check])
1712 UL_REQUIRES_LINUX([dmesg])
1713 AM_CONDITIONAL([BUILD_DMESG], [test "x$build_dmesg" = xyes])
1714
1715 UL_BUILD_INIT([ctrlaltdel], [check])
1716 UL_REQUIRES_LINUX([ctrlaltdel])
1717 dnl we assume reboot() to be the 1-argument variant, because even considering
1718 dnl widely used alternative C libraries like uclibc, dietlibc and musl,
1719 dnl reboot() with multiple arguments is yet only found in glibc versions
1720 dnl earlier than 2.x.
1721 UL_REQUIRES_HAVE([ctrlaltdel], [reboot], [reboot function])
1722 AM_CONDITIONAL([BUILD_CTRLALTDEL], [test "x$build_ctrlaltdel" = xyes])
1723
1724 UL_BUILD_INIT([fincore], [check])
1725 UL_REQUIRES_LINUX([fincore])
1726 UL_REQUIRES_BUILD([fincore], [libsmartcols])
1727 AM_CONDITIONAL([BUILD_FINCORE], [test "x$build_fincore" = xyes])
1728
1729 UL_BUILD_INIT([fsfreeze], [check])
1730 UL_REQUIRES_LINUX([fsfreeze])
1731 AM_CONDITIONAL([BUILD_FSFREEZE], [test "x$build_fsfreeze" = xyes])
1732
1733 UL_BUILD_INIT([blkdiscard], [check])
1734 UL_REQUIRES_LINUX([blkdiscard])
1735 AM_CONDITIONAL([BUILD_BLKDISCARD], [test "x$build_blkdiscard" = xyes])
1736
1737 UL_BUILD_INIT([blkzone], [check])
1738 UL_REQUIRES_LINUX([blkzone])
1739 UL_REQUIRES_HAVE([blkzone], [linux_blkzoned_h], [linux/blkzoned.h header])
1740 AM_CONDITIONAL([BUILD_BLKZONE], [test "x$build_blkzone" = xyes])
1741
1742 UL_BUILD_INIT([ldattach], [check])
1743 UL_REQUIRES_LINUX([ldattach])
1744 AM_CONDITIONAL([BUILD_LDATTACH], [test "x$build_ldattach" = xyes])
1745
1746 UL_BUILD_INIT([rtcwake], [check])
1747 UL_REQUIRES_LINUX([rtcwake])
1748 AM_CONDITIONAL([BUILD_RTCWAKE], [test "x$build_rtcwake" = xyes])
1749
1750 UL_BUILD_INIT([setarch], [check])
1751 UL_REQUIRES_LINUX([setarch])
1752 AM_CONDITIONAL([BUILD_SETARCH], [test "x$build_setarch" = xyes])
1753
1754 UL_BUILD_INIT([script], [check])
1755 UL_REQUIRES_HAVE([script], [sys_signalfd_h], [sys/signalfd.h header])
1756 AM_CONDITIONAL([BUILD_SCRIPT], [test "x$build_script" = xyes])
1757
1758 UL_BUILD_INIT([scriptreplay], [yes])
1759 AM_CONDITIONAL([BUILD_SCRIPTREPLAY], [test "x$build_scriptreplay" = xyes])
1760
1761 UL_BUILD_INIT([col], [yes])
1762 AM_CONDITIONAL([BUILD_COL], [test "x$build_col" = xyes])
1763
1764 UL_BUILD_INIT([colcrt], [yes])
1765 AM_CONDITIONAL([BUILD_COLCRT], [test "x$build_colcrt" = xyes])
1766
1767 UL_BUILD_INIT([colrm], [yes])
1768 AM_CONDITIONAL([BUILD_COLRM], [test "x$build_colrm" = xyes])
1769
1770 UL_BUILD_INIT([column], [check])
1771 UL_REQUIRES_BUILD([column], [libsmartcols])
1772 AM_CONDITIONAL([BUILD_COLUMN], [test "x$build_column" = xyes])
1773
1774 UL_BUILD_INIT([hexdump], [yes])
1775 AM_CONDITIONAL([BUILD_HEXDUMP], [test "x$build_hexdump" = xyes])
1776
1777 UL_BUILD_INIT([rev], [yes])
1778 AM_CONDITIONAL([BUILD_REV], [test "x$build_rev" = xyes])
1779
1780
1781 AC_ARG_ENABLE([tunelp],
1782   AS_HELP_STRING([--enable-tunelp], [build tunelp]),
1783   [], [UL_DEFAULT_ENABLE([tunelp], [no])]
1784 )
1785 UL_BUILD_INIT([tunelp])
1786 UL_REQUIRES_LINUX([tunelp])
1787 AM_CONDITIONAL([BUILD_TUNELP], [test "x$build_tunelp" = xyes])
1788
1789
1790 AC_ARG_ENABLE([kill],
1791   AS_HELP_STRING([--disable-kill], [do not build kill]),
1792   [], [UL_DEFAULT_ENABLE([kill], [check])]
1793 )
1794 UL_BUILD_INIT([kill])
1795 UL_REQUIRES_LINUX([kill])
1796 AM_CONDITIONAL([BUILD_KILL], [test "x$build_kill" = xyes])
1797
1798
1799 AC_ARG_ENABLE([last],
1800   AS_HELP_STRING([--disable-last], [do not build last]),
1801   [], [UL_DEFAULT_ENABLE([last], [check])]
1802 )
1803 UL_BUILD_INIT([last])
1804 UL_REQUIRES_HAVE([last], [utmpx_h], [utmpx.h header])
1805 UL_REQUIRES_HAVE([last], [gnu_utmpx], [GNU utmpx functions])
1806 AM_CONDITIONAL([BUILD_LAST], [test "x$build_last" = xyes])
1807
1808
1809 AC_ARG_ENABLE([utmpdump],
1810   AS_HELP_STRING([--disable-utmpdump], [do not build utmpdump]),
1811   [], [UL_DEFAULT_ENABLE([utmpdump], [check])]
1812 )
1813 UL_BUILD_INIT([utmpdump])
1814 UL_REQUIRES_HAVE([utmpdump], [utmpx_h], [utmpx.h header])
1815 UL_REQUIRES_HAVE([utmpdump], [gnu_utmpx], [GNU utmpx functions])
1816 AM_CONDITIONAL([BUILD_UTMPDUMP], [test "x$build_utmpdump" = xyes])
1817
1818
1819 AC_ARG_ENABLE([line],
1820   AS_HELP_STRING([--enable-line], [build line]),
1821   [], [UL_DEFAULT_ENABLE([line], [no])]
1822 )
1823 UL_BUILD_INIT([line])
1824 AM_CONDITIONAL([BUILD_LINE], [test "x$build_line" = xyes])
1825
1826
1827 AC_ARG_ENABLE([mesg],
1828   AS_HELP_STRING([--disable-mesg], [do not build mesg]),
1829   [], [UL_DEFAULT_ENABLE([mesg], [yes])]
1830 )
1831 UL_BUILD_INIT([mesg])
1832 AM_CONDITIONAL([BUILD_MESG], [test "x$build_mesg" = xyes])
1833
1834
1835 AC_ARG_ENABLE([raw],
1836   AS_HELP_STRING([--disable-raw], [do not build raw]),
1837   [], [UL_DEFAULT_ENABLE([raw], [check])]
1838 )
1839 UL_BUILD_INIT([raw])
1840 UL_REQUIRES_LINUX([raw])
1841 UL_REQUIRES_HAVE([raw], [linux_raw_h], [raw.h header file])
1842 AM_CONDITIONAL([BUILD_RAW], [test "x$build_raw" = xyes])
1843
1844
1845 AC_ARG_ENABLE([rename],
1846   AS_HELP_STRING([--disable-rename], [do not build rename]),
1847   [], [UL_DEFAULT_ENABLE([rename], [yes])]
1848 )
1849 UL_BUILD_INIT([rename])
1850 AM_CONDITIONAL([BUILD_RENAME], [test "x$build_rename" = xyes])
1851
1852
1853 AC_ARG_ENABLE([vipw],
1854   AS_HELP_STRING([--enable-vipw], [build vipw]),
1855   [], [UL_DEFAULT_ENABLE([vipw], [no])]
1856 )
1857 UL_BUILD_INIT([vipw])
1858 UL_REQUIRES_HAVE([vipw], [shadow_h], [shadow.h header])
1859 AM_CONDITIONAL([BUILD_VIPW], [test "x$build_vipw" = xyes])
1860
1861
1862 AC_ARG_ENABLE([newgrp],
1863   AS_HELP_STRING([--enable-newgrp], [build newgrp]),
1864   [], [UL_DEFAULT_ENABLE([newgrp], [no])]
1865 )
1866 UL_BUILD_INIT([newgrp])
1867 AM_CONDITIONAL([BUILD_NEWGRP], [test "x$build_newgrp" = xyes])
1868
1869
1870 AC_ARG_WITH([user], AS_HELP_STRING([--without-user], [compile without libuser (remote chsh)]),
1871   [], [with_user=check]
1872 )
1873 have_user=no
1874 AS_IF([test "x$with_user" != xno], [
1875   PKG_CHECK_MODULES(LIBUSER,[libuser >= 0.58], [have_user=yes], [have_user=no])
1876   AS_CASE([$with_user:$have_user],
1877     [yes:no],
1878       [AC_MSG_ERROR([user selected but libuser not found])],
1879     [*:yes],
1880       [AC_DEFINE([HAVE_LIBUSER], [1], [Define if libuser is available])]
1881   )
1882   # temporary solution, libuser has stupid .pc where are exported all
1883   # private dependencies to Requires: instead of Requires.private:
1884   AS_IF([test "x$have_user" = xyes], [
1885     LIBUSER_LIBS=-luser
1886   ])
1887 ])
1888 AM_CONDITIONAL([HAVE_USER], [test "x$have_user" = xyes])
1889
1890 AC_ARG_ENABLE([chfn-chsh-password],
1891   AS_HELP_STRING([--disable-chfn-chsh-password], [do not require the user to enter the password in chfn and chsh]),
1892   [], [enable_chfn_chsh_password=yes]
1893 )
1894
1895 AC_ARG_ENABLE([chfn-chsh],
1896   AS_HELP_STRING([--enable-chfn-chsh], [build chfn and chsh]),
1897   [], [UL_DEFAULT_ENABLE([chfn_chsh], [check])]
1898 )
1899 UL_BUILD_INIT([chfn_chsh])
1900 UL_REQUIRES_HAVE([chfn_chsh], [shadow_h], [shadow.h header])
1901 UL_REQUIRES_HAVE([chfn_chsh], [getusershell], [getusershell function])
1902
1903 AS_IF([test "x$enable_chfn_chsh_password" = xyes -o "x$have_user" = xyes], [
1904   UL_REQUIRES_HAVE([chfn_chsh], [security_pam_appl_h], [PAM header file])
1905   AC_DEFINE([CHFN_CHSH_PASSWORD], [1], [Should chfn and chsh require the user to enter the password?])
1906 ])
1907 AM_CONDITIONAL([BUILD_CHFN_CHSH], [test "x$build_chfn_chsh" = xyes])
1908 AM_CONDITIONAL([CHFN_CHSH_PASSWORD], [test "x$enable_chfn_chsh_password" = xyes])
1909
1910 AC_ARG_ENABLE([chsh-only-listed],
1911   AS_HELP_STRING([--disable-chsh-only-listed], [chsh: allow shells not in /etc/shells]),
1912   [], enable_chsh_only_listed=yes
1913 )
1914
1915 AS_IF([test "x$enable_chsh_only_listed" = xyes], [
1916   AC_DEFINE([ONLY_LISTED_SHELLS], [1], [Should chsh allow only shells in /etc/shells?])
1917 ])
1918
1919
1920 AC_ARG_ENABLE([login],
1921   AS_HELP_STRING([--disable-login], [do not build login]),
1922   [], [UL_DEFAULT_ENABLE([login], [check])]
1923 )
1924 UL_BUILD_INIT([login])
1925 UL_REQUIRES_HAVE([login], [security_pam_appl_h], [PAM header file])
1926 UL_REQUIRES_HAVE([login], [security_pam_misc_h, security_openpam_h], [PAM conversation functions])
1927 UL_REQUIRES_HAVE([login], [utmpx_h], [utmpx.h header])
1928 UL_REQUIRES_HAVE([login], [gnu_utmpx], [GNU utmpx functions])
1929 AM_CONDITIONAL([BUILD_LOGIN], [test "x$build_login" = xyes])
1930
1931 AC_ARG_ENABLE([login-chown-vcs],
1932   AS_HELP_STRING([--enable-login-chown-vcs], [let login chown /dev/vcsN]),
1933   [], [enable_login_chown_vcs=no]
1934 )
1935
1936 AS_IF([test "x$enable_login_chown_vcs" = xyes], [
1937   AC_DEFINE([LOGIN_CHOWN_VCS], [1], [Should login chown /dev/vcsN?])
1938 ])
1939
1940 AC_ARG_ENABLE([login-stat-mail],
1941   AS_HELP_STRING([--enable-login-stat-mail], [let login stat() the mailbox]),
1942   [], [enable_login_stat_mail=no]
1943 )
1944
1945 AS_IF([test "x$enable_login_stat_mail" = xyes], [
1946   AC_DEFINE([LOGIN_STAT_MAIL], [1], [Should login stat() the mailbox?])
1947 ])
1948
1949
1950 AC_ARG_ENABLE([nologin],
1951   AS_HELP_STRING([--disable-nologin], [do not build nologin]),
1952   [], [UL_DEFAULT_ENABLE([nologin], [yes])]
1953 )
1954 UL_BUILD_INIT([nologin])
1955 AM_CONDITIONAL([BUILD_NOLOGIN], [test "x$build_nologin" = xyes])
1956
1957
1958 AC_ARG_ENABLE([sulogin],
1959   AS_HELP_STRING([--disable-sulogin], [do not build sulogin]),
1960   [], [UL_DEFAULT_ENABLE([sulogin], [check])]
1961 )
1962 UL_BUILD_INIT([sulogin])
1963 UL_REQUIRES_HAVE([sulogin], [shadow_h], [shadow.h header])
1964 AM_CONDITIONAL([BUILD_SULOGIN], [test "x$build_sulogin" = xyes])
1965
1966
1967 AC_ARG_ENABLE([su],
1968   AS_HELP_STRING([--disable-su], [do not build su]),
1969   [], [UL_DEFAULT_ENABLE([su], [check])]
1970 )
1971 UL_BUILD_INIT([su])
1972 UL_REQUIRES_HAVE([su], [security_pam_appl_h], [PAM header file])
1973 UL_REQUIRES_HAVE([su], [utmpx_h], [utmpx.h header])
1974 UL_REQUIRES_HAVE([su], [gnu_utmpx], [GNU utmpx functions])
1975 AM_CONDITIONAL([BUILD_SU], [test "x$build_su" = xyes])
1976
1977
1978 AC_ARG_ENABLE([runuser],
1979   AS_HELP_STRING([--disable-runuser], [do not build runuser]),
1980   [], [UL_DEFAULT_ENABLE([runuser], [check])]
1981 )
1982 UL_BUILD_INIT([runuser])
1983 UL_REQUIRES_HAVE([runuser], [security_pam_appl_h], [PAM header file])
1984 UL_REQUIRES_HAVE([runuser], [utmpx_h], [utmpx.h header])
1985 UL_REQUIRES_HAVE([runuser], [gnu_utmpx], [GNU utmpx functions])
1986 AM_CONDITIONAL([BUILD_RUNUSER], [test "x$build_runuser" = xyes])
1987
1988
1989 AC_ARG_ENABLE([ul],
1990   AS_HELP_STRING([--disable-ul], [do not build ul]),
1991   [], [UL_DEFAULT_ENABLE([ul], [check])]
1992 )
1993 UL_BUILD_INIT([ul])
1994 UL_REQUIRES_HAVE([ul], [ncursesw, ncurses], [ncursesw or ncurses libraries])
1995 AM_CONDITIONAL([BUILD_UL], [test "x$build_ul" = xyes])
1996
1997
1998 AC_ARG_ENABLE([more],
1999   AS_HELP_STRING([--disable-more], [do not build more]),
2000   [], [UL_DEFAULT_ENABLE([more], [check])]
2001 )
2002 UL_BUILD_INIT([more])
2003 UL_REQUIRES_HAVE([more], [ncursesw, ncurses], [ncursesw or ncurses libraries])
2004 AM_CONDITIONAL([BUILD_MORE], [test "x$build_more" = xyes])
2005
2006
2007 AC_ARG_ENABLE([pg],
2008   AS_HELP_STRING([--enable-pg], [build pg]),
2009   [], [UL_DEFAULT_ENABLE([pg], [no])]
2010 )
2011 UL_BUILD_INIT([pg])
2012 UL_REQUIRES_HAVE([pg], [ncursesw, ncurses], [ncursesw or ncurses library])
2013 AM_CONDITIONAL([BUILD_PG], [test "x$build_pg" = xyes])
2014
2015
2016 AC_ARG_ENABLE([setterm],
2017   AS_HELP_STRING([--disable-setterm], [do not build setterm]),
2018   [], [UL_DEFAULT_ENABLE([setterm], [check])]
2019 )
2020 UL_BUILD_INIT([setterm])
2021 UL_REQUIRES_LINUX([setterm])
2022 UL_REQUIRES_HAVE([setterm], [ncursesw, ncurses], [ncursesw or ncurses library])
2023 AM_CONDITIONAL([BUILD_SETTERM], [test "x$build_setterm" = xyes])
2024
2025 # build_schedutils= is just configure-only variable to control
2026 # ionice, taskset and chrt
2027 AC_ARG_ENABLE([schedutils],
2028   AS_HELP_STRING([--disable-schedutils], [do not build chrt, ionice, taskset]),
2029   [], [UL_DEFAULT_ENABLE([schedutils], [check])]
2030 )
2031
2032
2033 UL_ENABLE_ALIAS([ionice], [schedutils])
2034 UL_BUILD_INIT([ionice])
2035 UL_REQUIRES_SYSCALL_CHECK([ionice],
2036         [UL_CHECK_SYSCALL([ioprio_set],
2037           [alpha],      [442],
2038           [i*86],       [289],
2039           [ia64*],      [1274],
2040           [powerpc*],   [273],
2041           [s390*],      [282],
2042           [sparc*],     [196],
2043           [sh*],        [288],
2044           [x86_64*],    [251])],
2045         [ioprio_set])
2046
2047 UL_REQUIRES_SYSCALL_CHECK([ionice],
2048         [UL_CHECK_SYSCALL([ioprio_get],
2049           [alpha],      [443],
2050           [i*86],       [290],
2051           [ia64*],      [1275],
2052           [powerpc*],   [274],
2053           [s390*],      [283],
2054           [sparc*],     [218],
2055           [sh*],        [289],
2056           [x86_64*],    [252])],
2057         [ioprio_get])
2058
2059 AM_CONDITIONAL([BUILD_IONICE], [test "x$build_ionice" = xyes])
2060
2061
2062 UL_ENABLE_ALIAS([taskset], [schedutils])
2063 UL_BUILD_INIT([taskset])
2064 UL_REQUIRES_HAVE([taskset], [cpu_set_t], [cpu_set_t type])
2065 UL_REQUIRES_SYSCALL_CHECK([taskset],
2066         [UL_CHECK_SYSCALL([sched_getaffinity])],
2067         [sched_getaffinity])
2068 AM_CONDITIONAL([BUILD_TASKSET], [test "x$build_taskset" = xyes])
2069
2070
2071 have_schedsetter=no
2072 AS_IF([test "x$ac_cv_func_sched_setscheduler" = xyes], [have_schedsetter=yes],
2073       [test "x$ac_cv_func_sched_setattr" = xyes], [have_schedsetter=yes])
2074
2075 UL_ENABLE_ALIAS([chrt], [schedutils])
2076 UL_BUILD_INIT([chrt])
2077 UL_REQUIRES_HAVE([chrt], [schedsetter], [sched_set functions])
2078 AM_CONDITIONAL([BUILD_CHRT], [test "x$build_chrt" = xyes])
2079
2080 AS_IF([test "x$build_chrt" = xyes], [
2081         UL_CHECK_SYSCALL([sched_setattr])
2082 ])
2083
2084
2085 AC_ARG_ENABLE([wall],
2086   AS_HELP_STRING([--disable-wall], [do not build wall]),
2087   [], [UL_DEFAULT_ENABLE([wall], [check])]
2088 )
2089 UL_BUILD_INIT([wall])
2090 UL_REQUIRES_HAVE([wall], [utmpx_h], [utmpx.h header])
2091 AM_CONDITIONAL([BUILD_WALL], [test "x$build_wall" = xyes])
2092
2093
2094 AC_ARG_ENABLE([write],
2095   AS_HELP_STRING([--enable-write], [build write]),
2096   [], [UL_DEFAULT_ENABLE([write], [no])]
2097 )
2098 UL_BUILD_INIT([write])
2099 UL_REQUIRES_HAVE([write], [utmpx_h], [utmpx.h header])
2100 UL_REQUIRES_HAVE([write], [gnu_utmpx], [GNU utmpx functions])
2101 AM_CONDITIONAL([BUILD_WRITE], [test "x$build_write" = xyes])
2102
2103
2104 AC_ARG_WITH([btrfs],
2105   AS_HELP_STRING([--without-btrfs], [do not build with btrfs support]),
2106   [], [with_btrfs=check]
2107 )
2108 have_btrfs=no
2109 AS_IF([test "x$with_btrfs" != xno], [
2110   AS_CASE([$with_btrfs:$have_linux_btrfs_h],
2111     [yes:no],
2112     [AC_MSG_ERROR([btrfs selected but linux/btrfs.h not found])],
2113     [check:no],
2114        [AC_MSG_WARN([linux/btrfs.h not found, do not build with btrfs support])],
2115     [*:yes],
2116        [have_btrfs=yes
2117         AC_DEFINE([HAVE_BTRFS_SUPPORT], [1], [Define if btrfs stuff is available])]
2118   )
2119 ])
2120 AM_CONDITIONAL([HAVE_BTRFS], [test "x$have_btrfs" = xyes])
2121
2122
2123 AC_ARG_WITH([systemd],
2124   AS_HELP_STRING([--without-systemd], [do not build with systemd support]),
2125   [], [with_systemd=check]
2126 )
2127
2128 have_systemd=no
2129 AS_IF([test "x$with_systemd" != xno], [
2130   # new version -- all libsystemd-* libs merged into libsystemd
2131   PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [have_systemd=yes], [have_systemd=no])
2132   # old versions
2133   AS_IF([test "x$have_systemd" != "xyes"], [
2134     PKG_CHECK_MODULES([SYSTEMD_DAEMON], [libsystemd-daemon],
2135                       [have_systemd_daemon=yes], [have_systemd_daemon=no])
2136     PKG_CHECK_MODULES([SYSTEMD_JOURNAL], [libsystemd-journal],
2137                       [have_systemd_journal=yes], [have_systemd_journal=no])
2138     AS_IF([test "x$have_systemd_daemon" = "xyes" -a "x$have_systemd_journal" = "xyes" ],[
2139            have_systemd=yes])
2140   ])
2141   AS_CASE([$with_systemd:$have_systemd],
2142     [yes:no],
2143       [AC_MSG_ERROR([systemd expected but libsystemd not found])],
2144     [*:yes],
2145        AC_DEFINE([HAVE_LIBSYSTEMD], [1], [Define if libsystemd is available])
2146   )
2147 ])
2148 AM_CONDITIONAL([HAVE_SYSTEMD], [test "x$have_systemd" = xyes])
2149
2150
2151 AC_ARG_WITH([systemdsystemunitdir],
2152   AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [directory for systemd unit files (requires systemd support)]),
2153   [], [with_systemdsystemunitdir=check]
2154 )
2155 AS_IF([test "x$with_systemdsystemunitdir" = xcheck], [
2156   AS_IF([test "x$have_systemd" = xyes], [
2157     with_systemdsystemunitdir=`$PKG_CONFIG --variable=systemdsystemunitdir systemd`
2158   ],[
2159     with_systemdsystemunitdir=no
2160   ])
2161 ])
2162 AS_IF([test "x$with_systemdsystemunitdir" != "xno"], [
2163   AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
2164 ])
2165
2166
2167 AC_ARG_WITH([smack],
2168   AS_HELP_STRING([--with-smack], [build with SMACK support]),
2169   [], [with_smack=no]
2170 )
2171 AS_IF([test "x$with_smack" = xyes], [
2172   AC_DEFINE([HAVE_SMACK], [1], [Add SMACK support])
2173 ])
2174
2175
2176 AC_ARG_WITH([bashcompletiondir],
2177   AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
2178   [],
2179   [AS_IF([`$PKG_CONFIG --exists bash-completion`], [
2180     with_bashcompletiondir=`$PKG_CONFIG --variable=completionsdir bash-completion`
2181   ], [
2182     with_bashcompletiondir=${datadir}/bash-completion/completions
2183   ])
2184 ])
2185 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
2186
2187 AC_ARG_ENABLE([bash-completion],
2188   AS_HELP_STRING([--disable-bash-completion], [do not install bash completion files]),
2189   [], [enable_bash_completion=yes]
2190 )
2191
2192 AM_CONDITIONAL([BUILD_BASH_COMPLETION], [test "x$enable_bash_completion" = xyes])
2193
2194
2195 AC_ARG_WITH([python],
2196   AS_HELP_STRING([--without-python], [do not build python bindings, use --with-python={2,3} to force version]),
2197   [], [with_python=check withval=check]
2198 )
2199
2200 have_python=no
2201 have_libpython=no
2202 AS_IF([test "x$with_python" != xno], [
2203   # We follow distributions default and look for PKG module name "python"
2204   # (minimal version is 2) but if major version is explicitly specified by
2205   # --with-python=2 or --with-python=3 then we look for PKG module "python2" or
2206   # "python3".
2207   AS_IF([test "x$withval" != xno -a "x$withval" != xyes -a "x$withval" != xcheck],
2208         [pymajor="$withval"; PYTHON=python${pymajor}], [pymajor="2"])
2209
2210   # check for python interpreter
2211   AM_PATH_PYTHON([$pymajor], [have_python=yes], [have_python=no])
2212   AS_CASE([$with_python:$have_python],
2213     [yes:no],
2214       [AC_MSG_ERROR([python selected but python interpreter not found])],
2215     [check:no],
2216        [AC_MSG_WARN([python interpreter not found, do not build python bindings])],
2217     [*:yes],
2218        # check for python development stuff
2219        [PKG_CHECK_MODULES([PYTHON], [python-$PYTHON_VERSION],
2220                           [have_libpython=yes], [have_libpython=no])]
2221   )
2222 ])
2223
2224
2225 AC_ARG_ENABLE([pylibmount],
2226   AS_HELP_STRING([--disable-pylibmount], [do not build pylibmount]),
2227   [], [UL_DEFAULT_ENABLE([pylibmount], [check])]
2228 )
2229 UL_BUILD_INIT([pylibmount])
2230 UL_REQUIRES_HAVE([pylibmount], [libpython], [libpython])
2231 UL_REQUIRES_BUILD([pylibmount], [libmount])
2232 AM_CONDITIONAL([BUILD_PYLIBMOUNT], [test "x$build_pylibmount" = "xyes"])
2233
2234 # We need to introduce a verbatim dependency into the Makefile, without automake
2235 # trying to interpret it, so push it as a AM_SUBST_NOTMAKE variable.
2236 verbatim_pylibmount_dependency='
2237
2238 # pylibmountexec module must be installed after usrlib_exec libraries,
2239 # otherwise the libtool relink step will fail to find libmount.la and
2240 # will try -lmount which is possibly not available.
2241 install-pylibmountexecLTLIBRARIES: install-usrlib_execLTLIBRARIES
2242
2243 '
2244 AC_SUBST([verbatim_pylibmount_dependency])
2245 AM_SUBST_NOTMAKE([verbatim_pylibmount_dependency])
2246
2247 AC_ARG_ENABLE([pg-bell],
2248   AS_HELP_STRING([--disable-pg-bell], [let pg not ring the bell on invalid keys]),
2249   [], [enable_pg_bell=yes]
2250 )
2251
2252 AS_IF([test "x$enable_pg_bell" = xyes], [
2253   AC_DEFINE([PG_BELL], [1], [Should pg ring the bell on invalid keys?])
2254 ])
2255
2256
2257 AC_DEFUN([FS_PATHS_DEFAULT], [/sbin:/sbin/fs.d:/sbin/fs])
2258 AC_ARG_ENABLE([fs-paths-default],
2259   AS_HELP_STRING([--enable-fs-paths-default=paths], [default search path for fs helpers @<:@FS_PATHS_DEFAULT@:>@]),
2260   [AS_CASE([$enableval],
2261     [yes], [fs_paths_defaults="FS_PATHS_DEFAULT"],
2262     [no],  [fs_paths_defaults=""],
2263     [fs_paths_defaults="$enableval"]
2264   )],
2265   [fs_paths_defaults="FS_PATHS_DEFAULT"]
2266 )
2267 AC_ARG_ENABLE([fs-paths-extra],
2268   AS_HELP_STRING([--enable-fs-paths-extra=paths], [additional search paths for fs helpers]),
2269   [AS_CASE([$enableval],
2270      [yes|no], [fs_paths_extra=""],
2271      [fs_paths_extra="$enableval"]
2272   )],
2273   [fs_paths_extra=""]
2274 )
2275 fs_paths="$fs_paths_defaults"
2276 AS_IF([test "x$fs_paths_extra" != "x"], [
2277   AS_IF([test "x$fs_paths" != "x"], [
2278     fs_paths="${fs_paths}:"
2279   ])
2280   fs_paths="${fs_paths}${fs_paths_extra}"
2281 ])
2282 AC_DEFINE_UNQUOTED([FS_SEARCH_PATH], "$fs_paths", [search path for fs helpers])
2283
2284
2285 AC_ARG_ENABLE([use-tty-group],
2286   AS_HELP_STRING([--disable-use-tty-group], [do not install wall and write setgid tty]),
2287   [], [enable_use_tty_group=yes]
2288 )
2289 AM_CONDITIONAL([USE_TTY_GROUP], [test "x$enable_use_tty_group" = xyes])
2290
2291 AS_IF([test "x$enable_use_tty_group" = xyes], [
2292   AC_DEFINE([USE_TTY_GROUP], [1], [Should wall and write be installed setgid tty?])
2293 ])
2294
2295
2296 AC_ARG_ENABLE([sulogin-emergency-mount],
2297   AS_HELP_STRING([--enable-sulogin-emergency-mount],
2298                  [use emergency mount of /dev and /proc for sulogin]),
2299   [], [enable_sulogin_emergency_mount=no]
2300 )
2301
2302 AS_IF([test "x$enable_sulogin_emergency_mount" = xyes], [
2303   AC_DEFINE([USE_SULOGIN_EMERGENCY_MOUNT], [1],
2304             [Should sulogin use a emergency mount of /dev and /proc?])
2305 ])
2306
2307
2308 AC_ARG_ENABLE([usrdir-path],
2309   AS_HELP_STRING([--enable-usrdir-path], [use only /usr paths in PATH env. variable (recommended on systems with /bin -> /usr/bin symlinks)]),
2310   [], [enable_usrdir_path=no]
2311 )
2312
2313 AS_IF([test "x$enable_usrdir_path" = xyes], [
2314   AC_DEFINE([USE_USRDIR_PATHS_ONLY], [1], [Define to 1 to remove /bin and /sbin from PATH env.variable])
2315 ])
2316
2317
2318 AC_ARG_ENABLE([makeinstall-chown],
2319   AS_HELP_STRING([--disable-makeinstall-chown], [do not do chown-like operations during "make install"]),
2320   [], [enable_makeinstall_chown=yes]
2321 )
2322 AM_CONDITIONAL([MAKEINSTALL_DO_CHOWN], [test "x$enable_makeinstall_chown" = xyes])
2323
2324
2325 AC_ARG_ENABLE([makeinstall-setuid],
2326   AS_HELP_STRING([--disable-makeinstall-setuid], [do not do setuid chmod operations during "make install"]),
2327   [], [enable_makeinstall_setuid=yes]
2328 )
2329 AM_CONDITIONAL([MAKEINSTALL_DO_SETUID], [test "x$enable_makeinstall_setuid" = xyes])
2330
2331
2332 AC_ARG_ENABLE([colors-default],
2333   AS_HELP_STRING([--disable-colors-default], [do not colorize output from utils by default]),
2334   [], [enable_colors_default=yes]
2335 )
2336 AS_IF([test "x$enable_colors_default" = xyes], [
2337   AC_DEFINE([USE_COLORS_BY_DEFAULT], [1], [Enables colorized output from utils by default])
2338 ])
2339
2340
2341 AC_ARG_VAR([SUID_CFLAGS],
2342            [CFLAGS used for binaries which are usually with the suid bit])
2343 AC_ARG_VAR([SUID_LDFLAGS],
2344            [LDFLAGS used for binaries which are usually with the suid bit])
2345
2346 AC_ARG_VAR([DAEMON_CFLAGS],
2347            [CFLAGS used for binaries which are usually executed as daemons])
2348 AC_ARG_VAR([DAEMON_LDFLAGS],
2349            [LDFLAGS used for binaries which are usually executed as daemons])
2350
2351 AC_ARG_VAR([SOLIB_CFLAGS],
2352            [CFLAGS used for shared libraries])
2353 AC_ARG_VAR([SOLIB_LDFLAGS],
2354            [LDFLAGS used for shared libraries])
2355
2356 AC_ARG_VAR([ADJTIME_PATH],
2357            [Path to hwclock adjtime file, default /etc/adjtime])
2358 AS_IF([test "x$ADJTIME_PATH" = x], [ADJTIME_PATH="/etc/adjtime"])
2359 AC_DEFINE_UNQUOTED([CONFIG_ADJTIME_PATH], "$ADJTIME_PATH", [Path to hwclock adjtime file])
2360
2361
2362 LIBS=""
2363
2364
2365 AC_CONFIG_HEADERS([config.h])
2366
2367 #
2368 # Don't use configure.ac to replace install paths! See Makefile PATHFILES for
2369 # more details.
2370 #
2371 AC_CONFIG_FILES([
2372 Makefile
2373 libblkid/docs/Makefile
2374 libblkid/docs/version.xml
2375 libblkid/src/blkid.h
2376 libfdisk/docs/Makefile
2377 libfdisk/docs/version.xml
2378 libfdisk/src/libfdisk.h
2379 libmount/docs/Makefile
2380 libmount/docs/version.xml
2381 libmount/src/libmount.h
2382 libsmartcols/docs/Makefile
2383 libsmartcols/docs/version.xml
2384 libsmartcols/src/libsmartcols.h
2385 po/Makefile.in
2386 ])
2387
2388 AC_OUTPUT
2389
2390 AC_MSG_RESULT([
2391         ${PACKAGE}  ${VERSION}
2392
2393         prefix:            ${prefix}
2394         exec prefix:       ${exec_prefix}
2395
2396         runstatedir:       ${runstatedir}
2397         bindir:            ${bindir}
2398         sbindir:           ${sbindir}
2399         libdir:            ${libdir}
2400         includedir:        ${includedir}
2401         usrbin_execdir:    ${usrbin_execdir}
2402         usrsbin_execdir:   ${usrsbin_execdir}
2403         usrlib_execdir:    ${usrlib_execdir}
2404
2405         compiler:          ${CC}
2406         cflags:            ${CFLAGS}
2407         suid cflags:       ${SUID_CFLAGS}
2408         ldflags:           ${LDFLAGS}
2409         suid ldflags:      ${SUID_LDFLAGS}
2410
2411         Python:            ${PYTHON}
2412         Python version:    ${PYTHON_VERSION}
2413         Python libs:       ${pyexecdir}
2414
2415         Bash completions:  ${with_bashcompletiondir}
2416         Systemd support:   ${have_systemd}
2417         Systemd unitdir:   ${with_systemdsystemunitdir}
2418         Btrfs support:     ${have_btrfs}
2419         Wide-char support: ${build_widechar}
2420
2421         warnings:
2422
2423 ${WARN_CFLAGS}
2424
2425         Type 'make' or 'make <utilname>' to compile.
2426 ])