configure.ac

   1 AC_INIT([util-linux],
   2         m4_esyscmd([tools/git-version-gen .tarball-version]),
   3         [kzak@redhat.com],,
   4         [http://www.kernel.org/pub/linux/utils/util-linux/])
   5
   6
   7 AC_PREREQ([2.60])
   8
   9 AC_CONFIG_AUX_DIR([config])
  10 AC_CONFIG_MACRO_DIR([m4])
  11 dnl AC_USE_SYSTEM_EXTENSIONS must be called before any macros that run
  12 dnl the compiler (like AC_PROG_LIBTOOL) to avoid autoconf errors.
  13 AC_USE_SYSTEM_EXTENSIONS
  14 AM_INIT_AUTOMAKE([-Wall foreign 1.10 tar-pax no-dist-gzip dist-xz subdir-objects])
  15
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  17                             [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  18 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  19
  20 AC_CONFIG_SRCDIR([sys-utils/mount.c])
  21 AC_PREFIX_DEFAULT([/usr])
  22
  23 dnl version details from <major>.<minor>[-<suffix>]
  24 PACKAGE_VERSION_MAJOR=$(echo $PACKAGE_VERSION | awk -F. '{print $1}')
  25 PACKAGE_VERSION_MINOR=$(echo $PACKAGE_VERSION | awk -F. '{
  26                                                    sub("-.*","",$2); print $2}')
  27 PACKAGE_VERSION_RELEASE=$(echo $PACKAGE_VERSION | awk -F. '{
  28                      sub("-.*","",$3); print $3 ~ /^@<:@0-9@:>@+$/ ? $3 : 0}')
  29
  30 dnl libblkid version
  31 LIBBLKID_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  32 LIBBLKID_DATE="25-Sep-2018"
  33 LIBBLKID_LT_MAJOR=1
  34 LIBBLKID_LT_MINOR=1
  35 LIBBLKID_LT_MICRO=0
  36 LIBBLKID_VERSION_INFO=`expr $LIBBLKID_LT_MAJOR + $LIBBLKID_LT_MINOR`:$LIBBLKID_LT_MICRO:$LIBBLKID_LT_MINOR
  37
  38 dnl libuuid version
  39 LIBUUID_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  40 LIBUUID_LT_MAJOR=1
  41 LIBUUID_LT_MINOR=3
  42 LIBUUID_LT_MICRO=0
  43 LIBUUID_VERSION_INFO=`expr $LIBUUID_LT_MAJOR + $LIBUUID_LT_MINOR`:$LIBUUID_LT_MICRO:$LIBUUID_LT_MINOR
  44
  45 dnl libmount version
  46 LIBMOUNT_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  47 LIBMOUNT_LT_MAJOR=1
  48 LIBMOUNT_LT_MINOR=1
  49 LIBMOUNT_LT_MICRO=0
  50 LIBMOUNT_VERSION_INFO=`expr $LIBMOUNT_LT_MAJOR + $LIBMOUNT_LT_MINOR`:$LIBMOUNT_LT_MICRO:$LIBMOUNT_LT_MINOR
  51
  52 dnl libsmartcols version
  53 LIBSMARTCOLS_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  54 LIBSMARTCOLS_LT_MAJOR=1
  55 LIBSMARTCOLS_LT_MINOR=1
  56 LIBSMARTCOLS_LT_MICRO=0
  57 LIBSMARTCOLS_VERSION_INFO=`expr $LIBSMARTCOLS_LT_MAJOR + $LIBSMARTCOLS_LT_MINOR`:$LIBSMARTCOLS_LT_MICRO:$LIBSMARTCOLS_LT_MINOR
  58
  59 dnl libfdisk version
  60 LIBFDISK_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  61 LIBFDISK_LT_MAJOR=1
  62 LIBFDISK_LT_MINOR=1
  63 LIBFDISK_LT_MICRO=0
  64 LIBFDISK_VERSION_INFO=`expr $LIBFDISK_LT_MAJOR + $LIBFDISK_LT_MINOR`:$LIBFDISK_LT_MICRO:$LIBFDISK_LT_MINOR
  65
  66 # Check whether exec_prefix=/usr:
  67 AS_CASE([$exec_prefix:$prefix],
  68 [NONE:NONE | NONE:/usr | /usr:*],
  69   [AC_MSG_NOTICE([Default --exec-prefix detected.])
  70    AS_CASE([$bindir],  ['${exec_prefix}/bin'],  [bindir=/bin;   AC_MSG_NOTICE([  --bindir defaults to /bin])  ])
  71    AS_CASE([$sbindir], ['${exec_prefix}/sbin'], [sbindir=/sbin; AC_MSG_NOTICE([  --sbindir defaults to /sbin])])
  72    AS_CASE([$libdir],  ['${exec_prefix}/lib'],  [libdir=/lib;   AC_MSG_NOTICE([  --libdir defaults to /lib])  ])
  73    AS_CASE([$libdir],  ['${exec_prefix}/lib64'],[libdir=/lib64; AC_MSG_NOTICE([  --libdir defaults to /lib64])  ])
  74   ]
  75 )
  76
  77
  78 # default for old versions without $runstatedir
  79 AS_IF([test x"$runstatedir" = x], [runstatedir='${localstatedir}/run'])
  80
  81 # our default if $localstatedir unchanged
  82 AS_CASE([$localstatedir:$runstatedir],
  83  [NONE:'${localstatedir}/run' | /var:'${localstatedir}/run' | NONE:'/run' ],
  84    [runstatedir=/run; AC_MSG_NOTICE([  --runstatedir defaults to /run])]
  85 )
  86
  87 AC_SUBST([runstatedir])
  88
  89
  90 # The original default values of {bin,sbin,lib}dir
  91 usrbin_execdir='${exec_prefix}/bin'
  92 AC_SUBST([usrbin_execdir])
  93
  94 usrsbin_execdir='${exec_prefix}/sbin'
  95 AC_SUBST([usrsbin_execdir])
  96
  97 AS_CASE([$libdir],
  98  ['${exec_prefix}/'* | '${prefix}/'* | /usr/* | "${prefix}"/* ],
  99    [usrlib_execdir=$libdir],
 100  [usrlib_execdir='${exec_prefix}'$libdir]
 101 )
 102 AC_SUBST([usrlib_execdir])
 103
 104
 105 AM_PROG_CC_C_O
 106 AC_PROG_MKDIR_P
 107 AC_PROG_CC_STDC
 108 AC_PROG_YACC
 109 AC_CANONICAL_HOST
 110 AC_C_CONST
 111 AC_C_VOLATILE
 112 AC_C_BIGENDIAN
 113
 114 dnl Compiler warnings
 115 UL_WARN_ADD([-fno-common])
 116 UL_WARN_ADD([-Wall])
 117 UL_WARN_ADD([-Werror=sequence-point])
 118 UL_WARN_ADD([-Wextra])
 119 UL_WARN_ADD([-Wextra-semi])
 120 UL_WARN_ADD([-Wembedded-directive])
 121 UL_WARN_ADD([-Wmissing-declarations])
 122 UL_WARN_ADD([-Wmissing-parameter-type])
 123 UL_WARN_ADD([-Wmissing-prototypes])
 124 UL_WARN_ADD([-Wno-missing-field-initializers])
 125 UL_WARN_ADD([-Wredundant-decls])
 126 UL_WARN_ADD([-Wsign-compare])
 127 UL_WARN_ADD([-Wtype-limits])
 128 UL_WARN_ADD([-Wuninitialized])
 129 UL_WARN_ADD([-Wunused-but-set-parameter])
 130 UL_WARN_ADD([-Wunused-but-set-variable])
 131 UL_WARN_ADD([-Wunused-parameter])
 132 UL_WARN_ADD([-Wunused-result])
 133 UL_WARN_ADD([-Wunused-variable])
 134 UL_WARN_ADD([-Wnested-externs])
 135 UL_WARN_ADD([-Wpointer-arith])
 136 UL_WARN_ADD([-Wstrict-prototypes])
 137 UL_WARN_ADD([-Wformat-security])
 138 UL_WARN_ADD([-Wimplicit-function-declaration])
 139 UL_WARN_ADD([-Wdiscarded-qualifiers])
 140 AC_SUBST([WARN_CFLAGS])
 141
 142 UL_WARN_ADD([-Wno-clobbered], [BSD_WARN_CFLAGS])
 143 AC_SUBST([BSD_WARN_CFLAGS])
 144
 145 UL_WARN_ADD([-Wno-cast-function-type], [PYTHON_WARN_CFLAGS])
 146 AC_SUBST([PYTHON_WARN_CFLAGS])
 147
 148 UL_WARN_ADD([-Wno-unused-parameter], [NO_UNUSED_WARN_CFLAGS])
 149 AC_SUBST([NO_UNUSED_WARN_CFLAGS])
 150
 151
 152 AC_ARG_ENABLE([asan],
 153   AS_HELP_STRING([--enable-asan], [compile with Address Sanitizer]),
 154   [], [enable_asan=no]
 155 )
 156 AS_IF([test "x$enable_asan" = xyes], [
 157   UL_WARN_ADD([-fsanitize=address])
 158 ])
 159
 160
 161
 162 dnl libtool-2
 163 LT_INIT
 164
 165 dnl check supported linker flags
 166 AX_CHECK_VSCRIPT
 167
 168 m4_ifndef([PKG_PROG_PKG_CONFIG],
 169   [m4_fatal([Could not locate the pkg-config autoconf
 170     macros. These are usually located in /usr/share/aclocal/pkg.m4.
 171     If your macros are in a different location, try setting the
 172     environment variable AL_OPTS="-I/other/macro/dir" before running
 173     ./autogen.sh or autoreconf again. Make sure pkg-config is installed.])])
 174 PKG_PROG_PKG_CONFIG
 175
 176 GTK_DOC_CHECK([1.10])
 177 AC_PATH_PROG([XSLTPROC], [xsltproc])
 178
 179 linux_os=no
 180 bsd_os=no
 181 AS_CASE([${host_os}],
 182   [*linux*],
 183      [linux_os=yes],
 184   [*darwin*],
 185      [darwin_os=yes],
 186   [*bsd*],
 187      [bsd_os=yes])
 188 AM_CONDITIONAL([LINUX], [test "x$linux_os" = xyes])
 189 AM_CONDITIONAL([DARWIN], [test "x$darwin_os" = xyes])
 190 AM_CONDITIONAL([BSD], [test "x$bsd_os" = xyes])
 191
 192 AS_IF([test  "x$darwin_os" = xyes], [
 193   AC_DEFINE([_DARWIN_C_SOURCE], [1], [Enable MAP_ANON in sys/mman.h on Mac OS X])
 194 ])
 195
 196 dnl define ARCH_<NAME> conditionals
 197 UL_SET_ARCH([I86], [i?86-*])
 198 UL_SET_ARCH([86_64], [x86_64*])
 199 UL_SET_ARCH([IA64], [ia64*])
 200 UL_SET_ARCH([S390], [s390*])
 201 UL_SET_ARCH([SPARC], [sparc*])
 202 UL_SET_ARCH([PPC], [ppc*|powerpc*])
 203 UL_SET_ARCH([M68K], [m68*])
 204 UL_SET_ARCH([MIPS], [mips*])
 205 UL_SET_ARCH([HPPA], [hppa*|parisc*])
 206
 207 AC_SYS_LARGEFILE
 208 AC_HEADER_ASSERT
 209 AC_STRUCT_TIMEZONE
 210
 211 dnl Don't forget to maintain alternatively allowed versions in autogen.sh!
 212 AM_GNU_GETTEXT_VERSION([0.18.3])
 213 AM_GNU_GETTEXT([external])
 214
 215 AS_IF([test -d "$srcdir/po"], [
 216   ALL_LINGUAS=`cd $srcdir/po > /dev/null && echo *.po | sed 's/\.po//g'`
 217 ], [
 218   ALL_LINGUAS="af am ar as be bg bn_IN bn ca cs cy da de el en_GB es et eu_ES fa fi fr gl gu he hi hr hu hy id is it ja ka kn ko ku lo lt lv mk ml mr ms my nb nl nn no nso or pa pl pt_BR pt ro ru si sk sl sq sr@Latn sr sv ta te th tr uk ur vi zh_CN zh_TW zu"
 219 ])
 220
 221 AC_CHECK_HEADERS([linux/compiler.h linux/blkpg.h linux/major.h], [], [], [
 222 #ifdef HAVE_LINUX_COMPILER_H
 223 #include <linux/compiler.h>
 224 #endif
 225 ])
 226 AC_CHECK_HEADERS([ \
 227         asm/io.h \
 228         err.h \
 229         errno.h \
 230         fcntl.h \
 231         getopt.h \
 232         inttypes.h \
 233         lastlog.h \
 234         libutil.h \
 235         linux/btrfs.h \
 236         linux/cdrom.h \
 237         linux/falloc.h \
 238         linux/watchdog.h \
 239         linux/fd.h \
 240         linux/raw.h \
 241         linux/tiocl.h \
 242         linux/version.h \
 243         linux/securebits.h \
 244         linux/net_namespace.h \
 245         locale.h \
 246         mntent.h \
 247         net/if.h \
 248         net/if_dl.h \
 249         netinet/in.h \
 250         paths.h \
 251         pty.h \
 252         security/pam_appl.h \
 253         stdint.h \
 254         stdio_ext.h \
 255         stdlib.h \
 256         endian.h \
 257         byteswap.h \
 258         sys/endian.h \
 259         sys/disk.h \
 260         sys/disklabel.h \
 261         sys/file.h \
 262         sys/io.h \
 263         sys/ioccom.h \
 264         sys/ioctl.h \
 265         sys/mkdev.h \
 266         sys/mount.h \
 267         sys/param.h \
 268         sys/prctl.h \
 269         sys/resource.h \
 270         sys/signalfd.h \
 271         sys/socket.h \
 272         sys/sockio.h \
 273         sys/stat.h \
 274         sys/sysmacros.h \
 275         sys/swap.h \
 276         sys/syscall.h \
 277         sys/time.h \
 278         sys/timex.h \
 279         sys/ttydefaults.h \
 280         sys/types.h \
 281         sys/ucred.h \
 282         sys/un.h \
 283         unistd.h \
 284         shadow.h \
 285         utmp.h \
 286         utmpx.h \
 287 ])
 288
 289 # There is a collision in old kernel-headers. The both files mount.h and fs.h
 290 # define MS_* macros. Fixed by kernel commit e462ec50cb5fad19f6003a3d8087f4a0945dd2b1.
 291 #
 292 AC_CHECK_HEADERS([linux/fs.h ], [], [],
 293  [#ifdef HAVE_SYS_MOUNT_H
 294    # include <linux/fs.h>
 295    # include <sys/mount.h>
 296   #endif
 297 ])
 298
 299 AC_CHECK_HEADERS([linux/gsmmux.h ], [], [],
 300  [#ifdef LINUX_GSMMUX_H
 301    # include <linux/gsmmux.h>
 302    #endif
 303 ])
 304
 305 AC_CHECK_HEADERS([security/pam_misc.h],
 306                 [AM_CONDITIONAL([HAVE_LINUXPAM], [true])],
 307                 [AM_CONDITIONAL([HAVE_LINUXPAM], [false])], [
 308 #ifdef HAVE_SECURITY_PAM_APPL_H
 309 #include <security/pam_appl.h>
 310 #endif
 311 ])
 312
 313 AC_CHECK_HEADERS([linux/blkzoned.h])
 314
 315 AC_CHECK_HEADERS([security/openpam.h], [], [], [
 316 #ifdef HAVE_SECURITY_PAM_APPL_H
 317 #include <security/pam_appl.h>
 318 #endif
 319 ])
 320
 321 AC_CHECK_HEADERS([langinfo.h],
 322                 [AM_CONDITIONAL([HAVE_LANGINFO], [true])],
 323                 [AM_CONDITIONAL([HAVE_LANGINFO], [false])])
 324
 325 AC_MSG_CHECKING([whether langinfo.h defines ALTMON_x constants])
 326 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 327         #include <langinfo.h>
 328 ]], [[
 329         char *str;
 330         str = nl_langinfo (ALTMON_1);
 331         str = nl_langinfo (ALTMON_2);
 332         str = nl_langinfo (ALTMON_3);
 333         str = nl_langinfo (ALTMON_4);
 334         str = nl_langinfo (ALTMON_5);
 335         str = nl_langinfo (ALTMON_6);
 336         str = nl_langinfo (ALTMON_7);
 337         str = nl_langinfo (ALTMON_8);
 338         str = nl_langinfo (ALTMON_9);
 339         str = nl_langinfo (ALTMON_10);
 340         str = nl_langinfo (ALTMON_11);
 341         str = nl_langinfo (ALTMON_12);
 342 ]])], [
 343         AC_MSG_RESULT([yes])
 344         AC_DEFINE([HAVE_LANGINFO_ALTMON], [1],
 345                 [Define if langinfo.h defines ALTMON_x constants])
 346 ], [
 347         AC_MSG_RESULT([no])
 348 ])
 349
 350
 351 AC_MSG_CHECKING([whether langinfo.h defines _NL_ABALTMON_x constants])
 352 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 353         #include <langinfo.h>
 354 ]], [[
 355         char *str;
 356         str = nl_langinfo (_NL_ABALTMON_1);
 357         str = nl_langinfo (_NL_ABALTMON_2);
 358         str = nl_langinfo (_NL_ABALTMON_3);
 359         str = nl_langinfo (_NL_ABALTMON_4);
 360         str = nl_langinfo (_NL_ABALTMON_5);
 361         str = nl_langinfo (_NL_ABALTMON_6);
 362         str = nl_langinfo (_NL_ABALTMON_7);
 363         str = nl_langinfo (_NL_ABALTMON_8);
 364         str = nl_langinfo (_NL_ABALTMON_9);
 365         str = nl_langinfo (_NL_ABALTMON_10);
 366         str = nl_langinfo (_NL_ABALTMON_11);
 367         str = nl_langinfo (_NL_ABALTMON_12);
 368 ]])], [
 369         AC_MSG_RESULT([yes])
 370         AC_DEFINE([HAVE_LANGINFO_NL_ABALTMON], [1],
 371                 [Define if langinfo.h defines _NL_ABALTMON_x constants])
 372 ], [
 373         AC_MSG_RESULT([no])
 374 ])
 375
 376
 377 dnl Convert some ac_cv_header_* variables to have_*
 378 dnl
 379 have_linux_version_h=$ac_cv_header_linux_version_h
 380 have_linux_blkzoned_h=$ac_cv_header_linux_blkzoned_h
 381 have_linux_btrfs_h=$ac_cv_header_linux_btrfs_h
 382 have_linux_raw_h=$ac_cv_header_linux_raw_h
 383 have_linux_securebits_h=$ac_cv_header_linux_securebits_h
 384 have_linux_watchdog_h=$ac_cv_header_linux_watchdog_h
 385 have_security_pam_appl_h=$ac_cv_header_security_pam_appl_h
 386 have_security_pam_misc_h=$ac_cv_header_security_pam_misc_h
 387 have_security_openpam_h=$ac_cv_header_security_openpam_h
 388 have_shadow_h=$ac_cv_header_shadow_h
 389 have_sys_signalfd_h=$ac_cv_header_sys_signalfd_h
 390 have_utmpx_h=$ac_cv_header_utmpx_h
 391
 392 AS_CASE([$linux_os:$have_linux_version_h],
 393   [yes:no],
 394     [AC_MSG_ERROR([kernel headers required on Linux])]
 395 )
 396
 397 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 398 #include <time.h>
 399 #include <unistd.h>
 400 ]], [[
 401     int a = 0;
 402     struct tm *tm = localtime(0);
 403     if (a == -1)  /* false */
 404         sleep(tm->tm_gmtoff);
 405 ]])],
 406 [AC_DEFINE([HAVE_TM_GMTOFF], [1], [Does struct tm have a field tm_gmtoff?])
 407 ])
 408
 409 AC_CHECK_MEMBERS([struct termios.c_line],,,
 410     [[#include <termios.h>]])
 411
 412 AC_CHECK_MEMBERS([struct stat.st_mtim.tv_nsec],,,
 413         [#include <sys/stat.h>])
 414
 415 AC_CHECK_DECLS([_NL_TIME_WEEK_1STDAY],[],[],[[#include <langinfo.h>]])
 416
 417 AC_CHECK_DECL([llseek],
 418         [AC_DEFINE([HAVE_LLSEEK_PROTOTYPE], [1],
 419                         [Define to 1 if have llseek prototype])],
 420         [],
 421         [#include <unistd.h>])
 422
 423 AC_CHECK_DECL([lseek64],
 424         [AC_DEFINE([HAVE_LSEEK64_PROTOTYPE], [1],
 425                         [Define to 1 if have lseek64 prototype])],
 426         [],
 427         [#define _LARGEFILE_SOURCE
 428          #define _LARGEFILE64_SOURCE
 429          #include <unistd.h>])
 430
 431 AC_CHECK_DECL([environ],
 432         [AC_DEFINE([HAVE_ENVIRON_DECL], [1],
 433                 [Define to 1 if have **environ prototype])],
 434 )
 435
 436 AC_CHECK_DECL([strsignal],
 437         [AC_DEFINE([HAVE_STRSIGNAL_DECL], [1],
 438                 [Define to 1 if have strsignal function prototype])],
 439 )
 440
 441 AC_CHECK_DECL([TIOCGLCKTRMIOS],
 442               [have_tiocglcktrmios=yes], [have_tiocglcktrmios=no],
 443               [#include <sys/ioctl.h>])
 444 AC_CHECK_DECL([SOCK_CLOEXEC],
 445               [have_sock_cloexec=yes], [have_sock_cloexec=no],
 446               [#include <sys/types.h>
 447                #include <sys/socket.h>])
 448 AC_CHECK_DECL([SOCK_NONBLOCK],
 449               [have_sock_nonblock=yes], [have_sock_nonblock=no],
 450               [#include <sys/types.h>
 451                #include <sys/socket.h>])
 452 AC_CHECK_DECL([SO_PASSCRED],
 453               [have_so_passcred=yes], [have_so_passcred=no],
 454               [#include <sys/types.h>
 455                #include <sys/socket.h>])
 456
 457 AC_CHECK_FUNCS([ \
 458         clearenv \
 459         __fpurge \
 460         fpurge \
 461         __fpending \
 462         secure_getenv \
 463         __secure_getenv \
 464         eaccess \
 465         err \
 466         errx \
 467         explicit_bzero \
 468         fsync \
 469         utimensat \
 470         getdomainname \
 471         getdtablesize \
 472         getexecname \
 473         getmntinfo \
 474         getrandom \
 475         getrlimit \
 476         getsgnam \
 477         inotify_init \
 478         jrand48 \
 479         lchown \
 480         llseek \
 481         lseek64 \
 482         mempcpy \
 483         mkostemp \
 484         nanosleep \
 485         ntp_gettime \
 486         personality \
 487         posix_fadvise \
 488         prctl \
 489         qsort_r \
 490         rpmatch \
 491         scandirat \
 492         setprogname \
 493         setresgid \
 494         setresuid \
 495         sched_setattr \
 496         sched_setscheduler \
 497         sigqueue \
 498         srandom \
 499         strnchr \
 500         strndup \
 501         strnlen \
 502         sysconf \
 503         sysinfo \
 504         timegm \
 505         usleep \
 506         vwarnx \
 507         warn \
 508         warnx \
 509 ])
 510 AC_FUNC_FSEEKO
 511
 512 AC_CHECK_FUNCS([openat fstatat unlinkat], [have_openat=yes], [have_openat=no])
 513 AC_CHECK_FUNCS([ioperm iopl], [have_io=yes])
 514 AC_CHECK_FUNCS([futimens], [have_futimens=yes])
 515 AC_CHECK_FUNCS([inotify_init1], [have_inotify_init1=yes])
 516 AC_CHECK_FUNCS([open_memstream], [have_open_memstream=yes],[have_open_memstream=no])
 517 AC_CHECK_FUNCS([reboot], [have_reboot=yes],[have_reboot=no])
 518 AC_CHECK_FUNCS([updwtmpx updwtmpx], [have_gnu_utmpx=yes], [have_gnu_utmpx=no])
 519 AC_CHECK_FUNCS([getusershell], [have_getusershell=yes],[have_getusershell=no])
 520
 521 AM_CONDITIONAL([HAVE_OPENAT], [test "x$have_openat" = xyes])
 522
 523 have_setns_syscall="yes"
 524 UL_CHECK_SYSCALL([setns])
 525 AS_IF([test "x$ul_cv_syscall_setns" = xno], [
 526    have_setns_syscall="no"
 527 ])
 528
 529 AC_CHECK_FUNCS([isnan], [],
 530         [AC_CHECK_LIB([m], [isnan], [MATH_LIBS="-lm"])]
 531         [AC_CHECK_LIB([m], [__isnan], [MATH_LIBS="-lm"])]
 532 )
 533 AC_SUBST([MATH_LIBS])
 534
 535
 536 dnl lib/mononotic.c may require -lrt
 537 AC_CHECK_FUNCS([clock_gettime], [],
 538         [AC_CHECK_LIB([rt], [clock_gettime], [REALTIME_LIBS="-lrt"])]
 539 )
 540
 541 have_timer="no"
 542 AC_CHECK_FUNCS([timer_create],
 543         [have_timer="yes"],
 544         [AC_CHECK_LIB([rt], [timer_create], [
 545                 have_timer="yes"
 546                 REALTIME_LIBS="-lrt"
 547         ],[
 548                 AC_SEARCH_LIBS([timer_create], [rt], [
 549                         AC_MSG_RESULT(yes)
 550                         have_timer="yes"
 551                         REALTIME_LIBS="-lrt -lpthread"
 552                 ],[], [-lpthread]
 553                 )
 554                 ])]
 555 )
 556
 557 AC_SUBST([REALTIME_LIBS])
 558
 559
 560 AC_CHECK_LIB([rtas], [rtas_get_sysparm], [
 561         RTAS_LIBS="-lrtas"
 562         AC_DEFINE_UNQUOTED([HAVE_LIBRTAS], [1], [Define if librtas exists]), [],
 563 ])
 564 AC_SUBST([RTAS_LIBS])
 565
 566
 567 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 568                 AC_DEFINE_UNQUOTED([HAVE_SA_LEN], [1], [Define if struct sockaddr contains sa_len]), [],
 569         [#include <sys/types.h>
 570          #include <sys/socket.h>])
 571
 572 SOCKET_LIBS=
 573 AC_SEARCH_LIBS([socket], [socket],
 574         [AS_IF([test x"$ac_cv_search_socket" != x"none required"],
 575                 [SOCKET_LIBS="$SOCKET_LIBS -lsocket"])
 576 ])
 577 AC_SUBST([SOCKET_LIBS])
 578
 579
 580 have_dirfd=no
 581 AC_CHECK_FUNCS([dirfd], [have_dirfd=yes], [have_dirfd=no])
 582 AS_IF([test x"$have_dirfd" = xno], [
 583         AC_CHECK_DECLS([dirfd],
 584                 [have_dirfd=yes], [have_dirfd=no],
 585                 [#include <sys/types.h>
 586                  #include <dirent.h>])
 587 ])
 588
 589 have_ddfd=no
 590 AS_IF([test x"$have_dirfd" = xno], [
 591         AC_CHECK_MEMBERS([DIR.dd_fd],
 592                 [have_ddfd=yes], [have_ddfd=no],
 593                 [#include <sys/types.h>
 594                  #include <dirent.h>])
 595 ])
 596
 597 AS_CASE([$have_dirfd:$have_ddfd],
 598   [no:no],
 599     [AC_MSG_ERROR([cannot find a method to get filedescriptor of directory])]
 600 )
 601
 602
 603 AC_MSG_CHECKING([whether program_invocation_short_name is defined])
 604 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 605         #include <errno.h>
 606 ]], [[
 607         program_invocation_short_name = "test";
 608 ]])], [
 609         AC_MSG_RESULT([yes])
 610         AC_DEFINE([HAVE_PROGRAM_INVOCATION_SHORT_NAME], [1],
 611                 [Define if program_invocation_short_name is defined])
 612 ], [
 613         AC_MSG_RESULT([no])
 614 ])
 615
 616
 617 AC_MSG_CHECKING([whether __progname is defined])
 618 AC_LINK_IFELSE([AC_LANG_PROGRAM([extern char *__progname;],
 619            [if (*__progname == 0) return 1;])],
 620            AC_DEFINE([HAVE___PROGNAME], [1], [Define if __progname is defined])
 621            AC_MSG_RESULT([yes]),
 622            AC_MSG_RESULT([no]))
 623
 624 dnl Static compilation
 625 m4_define([UL_STATIC_PROGRAMS], [losetup, mount, umount, fdisk, sfdisk, blkid, nsenter, unshare])
 626
 627 AC_ARG_ENABLE([static-programs],
 628   [AS_HELP_STRING([--enable-static-programs=LIST],
 629       [link static the programs in LIST (comma-separated,
 630       supported for ]m4_defn([UL_STATIC_PROGRAMS])[)])])
 631
 632 AS_CASE([$enable_static_programs],
 633   [yes],
 634     [enable_static_programs=m4_quote(UL_STATIC_PROGRAMS)],
 635   [no],
 636     [enable_static_programs=]
 637 )
 638
 639 dnl Set all the individual AM_CONDITIONALs
 640 m4_foreach([UL_PRG], m4_defn([UL_STATIC_PROGRAMS]), [
 641   AS_CASE([,$enable_static_programs,],
 642    [*,UL_PRG,*], [static_[]UL_PRG=yes]
 643   )
 644   AS_IF([test "x$static_[]UL_PRG" = xyes], [AC_MSG_NOTICE([enable static build: UL_PRG.])])
 645   AM_CONDITIONAL([HAVE_STATIC_]m4_toupper(UL_PRG),
 646     [test "x$static_[]UL_PRG" = xyes])
 647 ])
 648
 649
 650 AC_ARG_ENABLE([all-programs],
 651   AS_HELP_STRING([--disable-all-programs], [disable everything, might be overridden by --enable-<name>]),
 652   [], [enable_all_programs=undefined]
 653 )
 654
 655 AS_CASE([$enable_all_programs],
 656   [yes], [AC_MSG_WARN([force to build all programs by default])
 657           ul_default_estate=check],
 658   [no],  [AC_MSG_WARN([disable all programs by default])
 659           ul_default_estate=no]
 660 )
 661
 662
 663 AX_CHECK_TLS
 664
 665 AC_DEFUN([UL_SCANF_TYPE_MODIFIER], [dnl
 666 # include <stdio.h>
 667 # include <stdlib.h>
 668 int main()
 669 {
 670         int i;
 671         int rc = 1;
 672         char *s;
 673         i = sscanf("x", $1, &s);
 674         if (i == 1  && *s == 'x')
 675                 rc = 0;
 676         free(s);
 677         return rc;
 678 }])
 679
 680 AC_CACHE_VAL([scanf_cv_alloc_modifier],
 681   AC_RUN_IFELSE([AC_LANG_SOURCE([UL_SCANF_TYPE_MODIFIER(["%ms"])])],
 682     [scanf_cv_alloc_modifier=ms],
 683     AC_RUN_IFELSE([AC_LANG_SOURCE([UL_SCANF_TYPE_MODIFIER(["%as"])])],
 684       [scanf_cv_alloc_modifier=as],
 685       [scanf_cv_alloc_modifier=no]
 686     )
 687     ,
 688
 689     [AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 690      #include <stdio.h>
 691      #include <unistd.h>
 692
 693      #if defined(__GLIBC__) && !defined(__UCLIBC__)
 694
 695      #if !(__GLIBC_PREREQ(2, 7))
 696      #error %m is not available
 697      #endif
 698
 699      #elif defined(_POSIX_VERSION)
 700
 701      #if _POSIX_VERSION < 200809L
 702      #error %m is not available
 703      #endif
 704
 705      #else
 706      #error Your C-library is not supported.
 707      #endif
 708      ])],
 709     [scanf_cv_alloc_modifier=ms],
 710     [scanf_cv_alloc_modifier=no])]
 711   )
 712 )
 713
 714 AC_MSG_CHECKING([scanf string alloc modifiers])
 715 AS_CASE([$scanf_cv_alloc_modifier],
 716   [ms],
 717     [AC_MSG_RESULT([(%ms) yes])
 718      AC_DEFINE([HAVE_SCANF_MS_MODIFIER], [1], [scanf %ms modifier])
 719      have_scanf_alloc_modifier=yes],
 720   [as],
 721     [AC_MSG_RESULT([(%as) yes])
 722      have_scanf_alloc_modifier=yes
 723      AC_DEFINE([HAVE_SCANF_AS_MODIFIER], [1], [scanf %as modifier])],
 724   [AC_MSG_RESULT([no])
 725    have_scanf_alloc_modifier=no]
 726 )
 727
 728
 729 AC_ARG_WITH([util], AS_HELP_STRING([--without-util], [compile without libutil]),
 730   [], [with_util=auto]
 731 )
 732 AS_IF([test "x$with_util" = xno], [
 733   AM_CONDITIONAL([HAVE_UTIL], [false])
 734   have_util=no
 735 ], [
 736   UL_CHECK_LIB([util], [openpty])
 737 ])
 738
 739
 740 AC_CHECK_TYPES([union semun], [], [], [[
 741 #include <sys/sem.h>
 742 ]])
 743 AC_CHECK_TYPES([loff_t])
 744
 745
 746 AC_ARG_ENABLE([widechar],
 747   AS_HELP_STRING([--disable-widechar], [do not compile wide character support]),
 748   [], [enable_widechar=check]
 749 )
 750 UL_BUILD_INIT([widechar])
 751 UL_REQUIRES_COMPILE([widechar], [[
 752   #include <wchar.h>
 753   #include <wctype.h>
 754   #include <stdio.h>
 755   ]], [[
 756     wchar_t wc;
 757     wint_t w;
 758     w = fgetwc(stdin);
 759     if (w == WEOF) exit(1);
 760     wc = w;
 761     fputwc(wc,stdout);
 762   ]],
 763   [wchar_t support])
 764
 765 AS_IF([test "x$build_widechar" = xyes ], [
 766   AC_DEFINE([HAVE_WIDECHAR], [1], [Do we have wide character support?])
 767 ])
 768
 769
 770 AC_CHECK_TYPES([cpu_set_t], [have_cpu_set_t=yes], [], [[
 771 #include <sched.h>
 772 ]])
 773
 774 AM_CONDITIONAL([HAVE_CPU_SET_T], [test "x$have_cpu_set_t" = xyes])
 775
 776 AC_CHECK_TYPES([sighandler_t], [], [], [[
 777 #include <signal.h>
 778 ]])
 779
 780 AC_CHECK_DECLS([CPU_ALLOC], [], [], [[
 781 #include <sched.h>
 782 ]])
 783
 784 # on Solaris, you can't mix and match standards, since we use c99
 785 # aparently at this stage, XOPEN_SOURCE will conflict.  As workaround,
 786 # check for crypt.h and use that without XOPEN_SOURCE.
 787 AC_CHECK_HEADERS([crypt.h])
 788 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 789 #ifdef HAVE_CRYPT_H
 790 #include <crypt.h>
 791 #else
 792 #define _XOPEN_SOURCE
 793 #include <unistd.h>
 794 #endif
 795 ]], [[
 796 char *c = crypt("abc","pw");
 797 ]])],[],[
 798   LIBS="$LIBS -lcrypt"
 799   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 800   #ifdef HAVE_CRYPT_H
 801   #include <crypt.h>
 802   #else
 803   #define _XOPEN_SOURCE
 804   #include <unistd.h>
 805   #endif
 806   ]], [[
 807   char *c = crypt("abc","pw");
 808   ]])],[
 809   AC_DEFINE([HAVE_LIBCRYPT], [1], [Do we need -lcrypt?])
 810   have_libcrypt=yes
 811   ],[
 812   AC_MSG_ERROR([crypt() is not available])
 813   ])
 814 ])
 815 AM_CONDITIONAL([HAVE_LIBCRYPT], [test "x$have_libcrypt" = xyes])
 816
 817
 818 AC_ARG_WITH([selinux],
 819   AS_HELP_STRING([--with-selinux], [compile with SELinux support]),
 820   [], [with_selinux=no]
 821 )
 822
 823 AS_IF([test "x$with_selinux" = xno], [
 824   AM_CONDITIONAL([HAVE_SELINUX], [false])
 825 ], [
 826   PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.0],
 827         [AC_DEFINE([HAVE_LIBSELINUX], [1], [Define if SELinux is available])
 828          UL_PKG_STATIC([SELINUX_LIBS_STATIC], [libselinux])
 829          AM_CONDITIONAL([HAVE_SELINUX], [true])
 830          have_selinux=yes],
 831         [have_selinux=no])
 832
 833   AS_CASE([$with_selinux:$have_selinux],
 834     [yes:no], [AC_MSG_ERROR([SELinux selected but libselinux not found or too old])]
 835   )
 836
 837   AS_IF([test "x$have_selinux" = xyes], [
 838     UL_SET_FLAGS([], [], [$SELINUX_LIBS])
 839     # This function is missing in old libselinux 1.xx versions
 840     AC_CHECK_FUNCS([security_get_initial_context])
 841     UL_RESTORE_FLAGS
 842   ])
 843 ])
 844 AC_SUBST([SELINUX_LIBS])
 845 AC_SUBST([SELINUX_LIBS_STATIC])
 846
 847
 848 AC_ARG_WITH([audit],
 849   AS_HELP_STRING([--with-audit], [compile with audit support]),
 850   [], [with_audit=no]
 851 )
 852
 853 AS_IF([test "x$with_audit" = xno], [
 854   AM_CONDITIONAL([HAVE_AUDIT], [false])
 855 ], [
 856   UL_CHECK_LIB([audit], [audit_log_user_message])
 857   AS_CASE([$with_audit:$have_audit],
 858     [yes:no],
 859       [AC_MSG_ERROR([Audit selected but libaudit not found (or does not support audit_log_user_message())])]
 860   )
 861 ])
 862
 863 AC_ARG_WITH([udev], AS_HELP_STRING([--without-udev], [compile without udev support]),
 864   [], [with_udev=auto]
 865 )
 866
 867 AS_IF([test "x$with_udev" = xno], [
 868   AM_CONDITIONAL([HAVE_UDEV], [false])
 869 ], [
 870   UL_CHECK_LIB([udev], [udev_new])
 871   AS_CASE([$with_udev:$have_udev],
 872     [yes:no],
 873       [AC_MSG_ERROR([udev selected but libudev not found])]
 874   )
 875 ])
 876
 877
 878 dnl wide-char ncurses
 879 AC_ARG_WITH([ncursesw],
 880   AS_HELP_STRING([--without-ncursesw], [do not build with wide-char ncurses]),
 881   [], [with_ncursesw=auto]
 882 )
 883 have_ncursesw=no
 884 have_ncursesw_header=no
 885 AS_IF([test "x$with_ncursesw" != xno], [
 886   UL_NCURSES_CHECK([ncursesw])
 887   AS_IF([test "x$have_ncursesw" = xyes], [
 888     AC_CHECK_HEADERS([ncursesw/ncurses.h], [have_ncursesw_header=yes])
 889     AC_CHECK_HEADERS([ncursesw/term.h])
 890
 891     # Define HAVE_NCURSES_H only if check for HAVE_NCURSESW_NCURSES_H is
 892     # unsuccessful to avoid too many *_H permitations in config.h
 893     AS_IF([test "x$have_ncursesw_header" = xno], [
 894            AC_CHECK_HEADERS([ncurses.h], [have_ncursesw_header=yes])
 895            AC_CHECK_HEADERS([term.h])
 896     ])
 897     AS_IF([test "x$have_ncursesw_header" = xno], [have_ncursesw=no])
 898   ])
 899   AS_IF([test "x$have_ncursesw" = xyes], [
 900     CURSES_LIB_NAME="ncursesw"
 901     AC_DEFINE([HAVE_LIBNCURSESW], [1], [Define if ncursesw library available])
 902   ])
 903 ])
 904 AS_CASE([$with_ncursesw:$have_ncursesw],
 905   [yes:no], [AC_MSG_ERROR([ncursesw selected, but library not found])])
 906
 907
 908 dnl non-wide ncurses
 909 AC_ARG_WITH([ncurses],
 910   AS_HELP_STRING([--with-ncurses], [build with non-wide ncurses]),
 911   [], [with_ncurses=auto]
 912 )
 913 have_ncurses=no
 914 have_ncurses_header=no
 915 AS_CASE([$with_ncurses:$build_widechar],
 916   [yes:yes], [AC_MSG_ERROR([wide-char support enabled, but non-wide ncurses selects])])
 917
 918 AS_IF([test "x$have_ncursesw" = xno -a "x$with_ncurses" != xno ], [
 919   UL_NCURSES_CHECK([ncurses])
 920   AS_IF([test "x$have_ncurses" = xyes], [
 921     AC_CHECK_HEADERS([ncurses/ncurses.h], [have_ncurses_header=yes])
 922     AC_CHECK_HEADERS([ncurses/term.h])
 923
 924     # Define HAVE_NCURSES_H only if check for HAVE_NCURSES_NCURSES_H is
 925     # unsuccessful to avoid too many *_H permitations in config.h
 926     AS_IF([test "x$have_ncurses_header" = xno], [
 927            AC_CHECK_HEADERS([ncurses.h], [have_ncurses_header=yes])
 928            AC_CHECK_HEADERS([term.h])
 929     ])
 930     AS_IF([test "x$have_ncurses_header" = xno], [have_ncurses=no])
 931   ])
 932   AS_IF([test "x$have_ncurses" = xyes], [
 933     CURSES_LIB_NAME="ncurses"
 934     AC_DEFINE([HAVE_LIBNCURSES], [1], [Define if ncurses library available])
 935   ])
 936 ])
 937 AS_CASE([$with_ncurses:$have_ncurses],
 938   [yes:no], [AC_MSG_ERROR([ncurses selected, but library not found])])
 939
 940 AC_SUBST([NCURSES_CFLAGS])
 941 AC_SUBST([NCURSES_LIBS])
 942 AM_CONDITIONAL([HAVE_NCURSES], [test "x$have_ncursesw" = xyes -o  "x$have_ncurses" = xyes])
 943
 944
 945 AC_ARG_WITH([slang],
 946   AS_HELP_STRING([--with-slang], [compile cfdisk with slang rather than ncurses]),
 947   [], [with_slang=no]
 948 )
 949 have_slang=no
 950 AS_IF([test "x$with_slang" = xyes], [
 951   AC_CHECK_HEADERS([slang.h slang/slang.h])
 952   AC_CHECK_HEADERS([slcurses.h slang/slcurses.h],
 953                    [have_slang=yes], [], [
 954 #ifdef HAVE_SLANG_H
 955 #include <slang.h>
 956 #elif defined(HAVE_SLANG_SLANG_H)
 957 #include <slang/slang.h>
 958 #endif
 959 ])
 960   AS_IF([test "x$have_slang" = xno], [
 961     AC_MSG_ERROR([slang selected but slcurses.h not found])],
 962     [CURSES_LIB_NAME=slang
 963   ])
 964 ])
 965 AM_CONDITIONAL([HAVE_SLANG], [test "x$have_slang" = xyes])
 966
 967
 968 AS_IF([test "x$have_slang" = xyes -o "x$have_ncursesw" = xyes -o "x$have_ncurses" = xyes], [
 969         AC_CHECK_LIB([$CURSES_LIB_NAME], use_default_colors, [
 970                      AC_DEFINE(HAVE_USE_DEFAULT_COLORS, 1,
 971                                [Define if curses library has the use_default_colors().])
 972         ])
 973         AC_CHECK_LIB([$CURSES_LIB_NAME], resizeterm, [
 974                      AC_DEFINE(HAVE_RESIZETERM, 1,
 975                                [Define if curses library has the resizeterm().])
 976         ])
 977 ])
 978
 979
 980 AC_ARG_WITH([tinfo], AS_HELP_STRING([--without-tinfo], [compile without libtinfo]),
 981   [], [with_tinfo=auto]
 982 )
 983 have_tinfo=no
 984 have_tinfow=no
 985 AS_IF([test "x$with_tinfo" != xno], [
 986   AS_IF([test "x$have_ncursesw" = xyes], [
 987     UL_TINFO_CHECK([tinfow])
 988   ])
 989   AS_IF([test "x$have_tinfow" = xno], [
 990     UL_TINFO_CHECK([tinfo])
 991   ])
 992 ])
 993 AC_SUBST([TINFO_LIBS])
 994 AC_SUBST([TINFO_LIBS_STATIC])
 995 AC_SUBST([TINFO_CFLAGS])
 996 AM_CONDITIONAL([HAVE_TINFO], [test "x$have_tinfo" = xyes -o "x$have_tinfow" = xyes])
 997 AS_IF([test "x$have_tinfo" = xyes -o "x$have_tinfow" = xyes], [
 998   AC_DEFINE(HAVE_LIBTINFO, 1, [Define if libtinfo or libtinfow available.])
 999 ])
1000
1001
1002 AC_ARG_WITH([readline],
1003   AS_HELP_STRING([--without-readline], [do not build with GNU Readline support]),
1004   [], [with_readline=auto]
1005 )
1006
1007 AS_IF([test "x$with_readline" = xno], [
1008   AM_CONDITIONAL([HAVE_READLINE], [false])
1009 ], [
1010   UL_CHECK_LIB([readline], [readline])
1011   AS_CASE([$with_readline:$have_readline],
1012     [yes:no],
1013       [AC_MSG_ERROR([readline selected but libreadline not found ])],
1014     [*:yes],
1015       [READLINE_LIBS="-lreadline"
1016        READLINE_LIBS_STATIC="-lreadline $TINFO_LIBS_STATIC"]
1017   )
1018 ])
1019 AC_SUBST([READLINE_LIBS])
1020 AC_SUBST([READLINE_LIBS_STATIC])
1021
1022
1023 AC_ARG_WITH([utempter],
1024   AS_HELP_STRING([--with-utempter], [compile script(1) with libutempter]),
1025   [], [with_utempter=no]
1026 )
1027
1028 AS_IF([test "x$with_utempter" = xyes], [
1029   UL_CHECK_LIB([utempter], [utempter_add_record])
1030   AS_IF([test "x$have_utempter" = xno], [
1031     AC_MSG_ERROR([utempter selected but libutempter not found])
1032   ])
1033 ], [
1034   AM_CONDITIONAL([HAVE_UTEMPTER], [false])
1035 ])
1036
1037
1038 dnl
1039 dnl libuuid
1040 dnl
1041 AC_ARG_ENABLE([libuuid],
1042   AS_HELP_STRING([--disable-libuuid], [do not build libuuid and uuid utilities]),
1043   [], [UL_DEFAULT_ENABLE([libuuid], [yes])]
1044 )
1045 UL_BUILD_INIT([libuuid])
1046 AC_SUBST([LIBUUID_VERSION])
1047 AC_SUBST([LIBUUID_VERSION_INFO])
1048 AM_CONDITIONAL(BUILD_LIBUUID, test "x$build_libuuid" = xyes)
1049
1050 AC_ARG_ENABLE([libuuid-force-uuidd],
1051   AS_HELP_STRING([--enable-libuuid-force-uuidd], [support uuidd even though the daemon is not built]),
1052   [], [enable_libuuid_force_uuidd=no]
1053 )
1054
1055 AS_IF([test "x$build_libuuid" = xyes], [
1056   AC_DEFINE(HAVE_LIBUUID, 1, [Define to 1 if you have the -luuid.])
1057 ])
1058
1059 dnl
1060 dnl libblkid
1061 dnl
1062 AC_ARG_ENABLE([libblkid],
1063   AS_HELP_STRING([--disable-libblkid], [do not build libblkid and many related utilities]),
1064   [], [UL_DEFAULT_ENABLE([libblkid], [check])]
1065 )
1066 UL_BUILD_INIT([libblkid])
1067 UL_REQUIRES_HAVE([libblkid], [openat], [openat functions])
1068 AC_SUBST([LIBBLKID_DATE])
1069 AC_SUBST([LIBBLKID_VERSION])
1070 AC_SUBST([LIBBLKID_VERSION_INFO])
1071 AC_DEFINE_UNQUOTED([LIBBLKID_VERSION], ["$LIBBLKID_VERSION"], [libblkid version string])
1072 AC_DEFINE_UNQUOTED([LIBBLKID_DATE], ["$LIBBLKID_DATE"], [libblkid date string])
1073 AS_IF([test "x$build_libblkid" = xyes], [
1074   AC_DEFINE([HAVE_LIBBLKID], [1], [Define to 1 if you have the -lblkid.])
1075 ])
1076 AM_CONDITIONAL([BUILD_LIBBLKID], [test "x$build_libblkid" = xyes])
1077 AM_CONDITIONAL([BUILD_LIBBLKID_TESTS], [test "x$build_libblkid" = xyes -a "x$enable_static" = xyes])
1078
1079 dnl
1080 dnl libmount
1081 dnl
1082 AC_ARG_ENABLE([libmount],
1083   AS_HELP_STRING([--disable-libmount], [do not build libmount]),
1084   [], [UL_DEFAULT_ENABLE([libmount], [check])]
1085 )
1086 UL_BUILD_INIT([libmount])
1087 UL_REQUIRES_BUILD([libmount], [libblkid])
1088 UL_REQUIRES_HAVE([libmount], [scanf_alloc_modifier], [scanf string alloc modifier])
1089 AM_CONDITIONAL([BUILD_LIBMOUNT], [test "x$build_libmount" = xyes])
1090 AM_CONDITIONAL([BUILD_LIBMOUNT_TESTS], [test "x$build_libmount" = xyes -a "x$enable_static" = xyes])
1091 AS_IF([test "x$build_libmount" = xyes], [
1092   AC_DEFINE(HAVE_LIBMOUNT, 1, [Define if libmount available.])
1093   AS_IF([test "x$have_setns_syscall" = "xyes"], [
1094     AC_DEFINE([USE_LIBMOUNT_SUPPORT_NAMESPACES], [1], [Define to 1 if want to support namepaces.])
1095   ],[
1096     AC_MSG_WARN([libmount will be compiled without namespaces support])
1097   ])
1098 ])
1099
1100 AC_SUBST([LIBMOUNT_VERSION])
1101 AC_SUBST([LIBMOUNT_MAJOR_VERSION], $PACKAGE_VERSION_MAJOR)
1102 AC_SUBST([LIBMOUNT_MINOR_VERSION], $PACKAGE_VERSION_MINOR)
1103 AC_SUBST([LIBMOUNT_PATCH_VERSION], $PACKAGE_VERSION_RELEASE)
1104 AC_SUBST([LIBMOUNT_VERSION_INFO])
1105 AC_DEFINE_UNQUOTED([LIBMOUNT_VERSION], ["$LIBMOUNT_VERSION"], [libmount version string])
1106
1107 AC_ARG_ENABLE([libmount-support-mtab],
1108   AS_HELP_STRING([--enable-libmount-support-mtab], [support /etc/mtab (default is use /proc/self/mountinfo)]),
1109   [], [enable_libmount_support_mtab=no]
1110 )
1111
1112 AS_IF([test "x$enable_libmount_support_mtab" = xyes], [
1113   AC_DEFINE([USE_LIBMOUNT_SUPPORT_MTAB], [1], [Define to 1 if want to support mtab.])
1114 ])
1115
1116 dnl
1117 dnl libsmartcols
1118 dnl
1119 AC_ARG_ENABLE([libsmartcols],
1120   AS_HELP_STRING([--disable-libsmartcols], [do not build libsmartcols]),
1121   [], [UL_DEFAULT_ENABLE([libsmartcols], [yes])]
1122 )
1123 UL_BUILD_INIT([libsmartcols])
1124 AM_CONDITIONAL([BUILD_LIBSMARTCOLS], [test "x$build_libsmartcols" = xyes])
1125
1126 AC_SUBST([LIBSMARTCOLS_VERSION])
1127 AC_SUBST([LIBSMARTCOLS_VERSION_INFO])
1128 AC_DEFINE_UNQUOTED([LIBSMARTCOLS_VERSION], ["$LIBSMARTCOLS_VERSION"], [libsmartcols version string])
1129
1130
1131 dnl
1132 dnl libfdisk
1133 dnl
1134 AC_ARG_ENABLE([libfdisk],
1135   AS_HELP_STRING([--disable-libfdisk], [do not build libfdisk]),
1136   [], [UL_DEFAULT_ENABLE([libfdisk], [check])]
1137 )
1138 UL_BUILD_INIT([libfdisk])
1139 UL_REQUIRES_BUILD([libfdisk], [libuuid])
1140 AM_CONDITIONAL([BUILD_LIBFDISK], [test "x$build_libfdisk" = xyes])
1141 AM_CONDITIONAL([BUILD_LIBFDISK_TESTS], [test "x$build_libfdisk" = xyes -a "x$enable_static" = xyes])
1142
1143 AS_IF([test "x$build_libblkid" = xyes],
1144   [LIBFDISK_PC_REQUIRES="uuid blkid"],[LIBFDISK_PC_REQUIRES="uuid"])
1145 AC_SUBST([LIBFDISK_PC_REQUIRES])
1146
1147 AC_SUBST([LIBFDISK_VERSION])
1148 AC_SUBST([LIBFDISK_MAJOR_VERSION], $PACKAGE_VERSION_MAJOR)
1149 AC_SUBST([LIBFDISK_MINOR_VERSION], $PACKAGE_VERSION_MINOR)
1150 AC_SUBST([LIBFDISK_PATCH_VERSION], $PACKAGE_VERSION_RELEASE)
1151 AC_SUBST([LIBFDISK_VERSION_INFO])
1152 AC_DEFINE_UNQUOTED([LIBFDISK_VERSION], ["$LIBFDISK_VERSION"], [libfdisk version string])
1153
1154
1155 UL_BUILD_INIT([fdisk], [check])
1156 UL_REQUIRES_HAVE([fdisk], [openat], [openat functions])
1157 UL_REQUIRES_BUILD([fdisk], [libfdisk])
1158 UL_REQUIRES_BUILD([fdisk], [libsmartcols])
1159 AM_CONDITIONAL([BUILD_FDISK], [test "x$build_fdisk" = xyes])
1160
1161
1162 UL_BUILD_INIT([sfdisk], [check])
1163 UL_REQUIRES_HAVE([sfdisk], [openat], [openat functions])
1164 UL_REQUIRES_BUILD([sfdisk], [libfdisk])
1165 UL_REQUIRES_BUILD([sfdisk], [libsmartcols])
1166 AM_CONDITIONAL([BUILD_SFDISK], [test "x$build_sfdisk" = xyes])
1167
1168
1169 UL_BUILD_INIT([cfdisk], [check])
1170 UL_REQUIRES_BUILD([cfdisk], [libfdisk])
1171 UL_REQUIRES_BUILD([cfdisk], [libsmartcols])
1172 UL_REQUIRES_HAVE([cfdisk], [open_memstream], [open_memstream function])
1173 UL_REQUIRES_HAVE([cfdisk], [ncursesw,slang,ncurses], [ncursesw, ncurses or slang library])
1174 AM_CONDITIONAL([BUILD_CFDISK], [test "x$build_cfdisk" = xyes])
1175
1176
1177 AC_ARG_ENABLE([mount],
1178   AS_HELP_STRING([--disable-mount], [do not build mount(8) and umount(8)]),
1179   [], [UL_DEFAULT_ENABLE([mount], [check])]
1180 )
1181 UL_BUILD_INIT([mount])
1182 UL_REQUIRES_LINUX([mount])
1183 UL_REQUIRES_BUILD([mount], [libmount])
1184 AM_CONDITIONAL([BUILD_MOUNT], [test "x$build_mount" = xyes])
1185
1186
1187 AC_ARG_ENABLE([losetup],
1188   AS_HELP_STRING([--disable-losetup], [do not build losetup]),
1189   [], [UL_DEFAULT_ENABLE([losetup], [check])]
1190 )
1191 UL_BUILD_INIT([losetup])
1192 UL_REQUIRES_LINUX([losetup])
1193 UL_REQUIRES_BUILD([losetup], [libsmartcols])
1194 AM_CONDITIONAL([BUILD_LOSETUP], [test "x$build_losetup" = xyes])
1195
1196 AC_ARG_ENABLE([zramctl],
1197   AS_HELP_STRING([--disable-zramctl], [do not build zramctl]),
1198   [], [UL_DEFAULT_ENABLE([zramctl], [check])]
1199 )
1200 UL_BUILD_INIT([zramctl])
1201 UL_REQUIRES_LINUX([zramctl])
1202 UL_REQUIRES_BUILD([zramctl], [libsmartcols])
1203 AM_CONDITIONAL([BUILD_ZRAMCTL], [test "x$build_zramctl" = xyes])
1204
1205 AC_ARG_ENABLE([fsck],
1206   AS_HELP_STRING([--disable-fsck], [do not build fsck]),
1207   [], [UL_DEFAULT_ENABLE([fsck], [check])]
1208 )
1209 UL_BUILD_INIT([fsck])
1210 UL_REQUIRES_BUILD([fsck], [libmount])
1211 AM_CONDITIONAL([BUILD_FSCK], [test "x$build_fsck" = xyes])
1212
1213
1214 AC_ARG_ENABLE([partx],
1215   AS_HELP_STRING([--disable-partx], [do not build addpart, delpart, partx]),
1216   [], [UL_DEFAULT_ENABLE([partx], [check])]
1217 )
1218 UL_BUILD_INIT([partx])
1219 UL_REQUIRES_LINUX([partx])
1220 UL_REQUIRES_BUILD([partx], [libblkid])
1221 UL_REQUIRES_BUILD([partx], [libsmartcols])
1222 AM_CONDITIONAL([BUILD_PARTX], [test "x$build_partx" = xyes])
1223
1224
1225 AC_ARG_ENABLE([uuidd],
1226   AS_HELP_STRING([--disable-uuidd], [do not build the uuid daemon]),
1227   [], [UL_DEFAULT_ENABLE([uuidd], [check])]
1228 )
1229 UL_BUILD_INIT([uuidd])
1230 UL_REQUIRES_BUILD([uuidd], [libuuid])
1231 UL_REQUIRES_HAVE([uuidd], [timer], [timer_create function])
1232 UL_REQUIRES_HAVE([uuidd], [sys_signalfd_h], [sys/signalfd.h header])
1233 AS_IF([test "x$build_uuidd" = xyes || test "x$enable_libuuid_force_uuidd" = xyes], [
1234   AC_DEFINE([HAVE_UUIDD], [1], [Define to 1 if you want to use uuid daemon.])
1235 ])
1236 AM_CONDITIONAL([BUILD_UUIDD], [test "x$build_uuidd" = xyes])
1237
1238
1239 UL_BUILD_INIT([uuidgen], [check])
1240 UL_REQUIRES_BUILD([uuidgen], [libuuid])
1241 AM_CONDITIONAL([BUILD_UUIDGEN], [test "x$build_uuidgen" = xyes])
1242
1243 UL_BUILD_INIT([uuidparse], [check])
1244 UL_REQUIRES_BUILD([uuidparse], [libuuid])
1245 UL_REQUIRES_BUILD([uuidparse], [libsmartcols])
1246 AM_CONDITIONAL([BUILD_UUIDPARSE], [test "x$build_uuidparse" = xyes])
1247
1248 UL_BUILD_INIT([blkid], [check])
1249 UL_REQUIRES_BUILD([blkid], [libblkid])
1250 AM_CONDITIONAL([BUILD_BLKID], [test "x$build_blkid" = xyes])
1251
1252 UL_BUILD_INIT([findfs], [check])
1253 UL_REQUIRES_BUILD([findfs], [libblkid])
1254 AM_CONDITIONAL([BUILD_FINDFS], [test "x$build_findfs" = xyes])
1255
1256 UL_BUILD_INIT([wipefs], [check])
1257 UL_REQUIRES_BUILD([wipefs], [libblkid])
1258 UL_REQUIRES_BUILD([wipefs], [libsmartcols])
1259 AM_CONDITIONAL([BUILD_WIPEFS], [test "x$build_wipefs" = xyes])
1260
1261 UL_BUILD_INIT([findmnt], [check])
1262 UL_REQUIRES_BUILD([findmnt], [libmount])
1263 UL_REQUIRES_BUILD([findmnt], [libblkid])
1264 UL_REQUIRES_BUILD([findmnt], [libsmartcols])
1265 AM_CONDITIONAL([BUILD_FINDMNT], [test "x$build_findmnt" = xyes])
1266
1267
1268 AC_ARG_ENABLE([mountpoint],
1269   AS_HELP_STRING([--disable-mountpoint], [do not build mountpoint]),
1270   [], [UL_DEFAULT_ENABLE([mountpoint], [check])]
1271 )
1272 UL_BUILD_INIT([mountpoint])
1273 UL_REQUIRES_BUILD([mountpoint], [libmount])
1274 AM_CONDITIONAL([BUILD_MOUNTPOINT], [test "x$build_mountpoint" = xyes])
1275
1276
1277 AC_ARG_ENABLE([fallocate],
1278   AS_HELP_STRING([--disable-fallocate], [do not build fallocate]),
1279   [], [UL_DEFAULT_ENABLE([fallocate], [check])]
1280 )
1281 UL_BUILD_INIT([fallocate])
1282 UL_REQUIRES_LINUX([fallocate])
1283 UL_REQUIRES_SYSCALL_CHECK([fallocate], [UL_CHECK_SYSCALL([fallocate])])
1284 AM_CONDITIONAL([BUILD_FALLOCATE], [test "x$build_fallocate" = xyes])
1285
1286 AS_IF([test "x$build_fallocate" = xyes], [
1287   dnl check for valid fallocate() function
1288   dnl with 32 bits glibc 2.10, fallocate() exists but not fallocate64()
1289   dnl when _FILE_OFFSET_BITS==64, fallocate() is redirect to fallocate64()
1290   dnl and program can't be linked.
1291   dnl AC_CHECK_FUNC can't catch such errors since it's redefining
1292   dnl function prototype.
1293   AC_MSG_CHECKING([for valid fallocate() function])
1294   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1295 #ifdef HAVE_UNISTD_H
1296 # include <unistd.h>
1297 #endif
1298 #ifdef HAVE_SYS_TYPES_H
1299 # include <sys/types.h>
1300 #endif
1301 #ifdef HAVE_LINUX_FALLOC_H
1302 # include <linux/falloc.h>
1303 #endif
1304 #ifdef HAVE_FCNTL_H
1305 # include <fcntl.h>
1306 #endif
1307 ]],[[
1308    long ret;
1309    ret = fallocate(0, FALLOC_FL_KEEP_SIZE, 0xfffffffful, 0xfffffffful);
1310    if (ret != 0) {
1311       return 1;
1312    }
1313    ]])],[
1314   AC_MSG_RESULT([yes])
1315   AC_DEFINE([HAVE_FALLOCATE], [1], [Have valid fallocate() function])],[
1316   AC_MSG_RESULT([no])])
1317 ])
1318
1319 AS_IF([test "x$build_fallocate" = xyes], [
1320   dnl check for valid posix_fallocate() function
1321   AC_MSG_CHECKING([for valid posix_fallocate() function])
1322   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1323 #ifdef HAVE_UNISTD_H
1324 # include <unistd.h>
1325 #endif
1326 #ifdef HAVE_SYS_TYPES_H
1327 # include <sys/types.h>
1328 #endif
1329 #ifdef HAVE_LINUX_FALLOC_H
1330 # include <linux/falloc.h>
1331 #endif
1332 #ifdef HAVE_FCNTL_H
1333 # include <fcntl.h>
1334 #endif
1335 ]],[[
1336    long ret;
1337    ret = posix_fallocate(0, 0xfffffffful, 0xfffffffful);
1338    if (ret != 0) {
1339       return 1;
1340    }
1341    ]])],[
1342   AC_MSG_RESULT([yes])
1343   AC_DEFINE([HAVE_POSIX_FALLOCATE], [1], [Have valid posix_fallocate() function])],[
1344   AC_MSG_RESULT([no])])
1345 ])
1346
1347
1348 AC_ARG_ENABLE([unshare],
1349   AS_HELP_STRING([--disable-unshare], [do not build unshare]),
1350   [], [UL_DEFAULT_ENABLE([unshare], [check])]
1351 )
1352 UL_BUILD_INIT([unshare])
1353 UL_REQUIRES_LINUX([unshare])
1354 UL_REQUIRES_SYSCALL_CHECK([unshare], [UL_CHECK_SYSCALL([unshare])])
1355 AM_CONDITIONAL([BUILD_UNSHARE], [test "x$build_unshare" = xyes])
1356 AC_CHECK_FUNCS([unshare])
1357
1358 AC_ARG_ENABLE([nsenter],
1359   AS_HELP_STRING([--disable-nsenter], [do not build nsenter]),
1360   [], [UL_DEFAULT_ENABLE([nsenter], [check])]
1361 )
1362 UL_BUILD_INIT([nsenter])
1363 UL_REQUIRES_LINUX([nsenter])
1364 UL_REQUIRES_HAVE([nsenter], [setns_syscall], [setns syscall])
1365 AM_CONDITIONAL([BUILD_NSENTER], [test "x$build_nsenter" = xyes])
1366 AC_CHECK_FUNCS([setns])
1367
1368
1369 AC_ARG_WITH([cap_ng],
1370   AS_HELP_STRING([--without-cap-ng], [compile without libcap-ng]),
1371   [], [with_cap_ng=auto]
1372 )
1373 AS_IF([test "x$with_cap_ng" = xno], [
1374   AM_CONDITIONAL([HAVE_CAP_NG], [false])
1375   have_cap_ng=no
1376 ],[
1377   UL_CHECK_LIB([cap-ng], [capng_apply], [cap_ng])
1378 ])
1379
1380
1381 AC_ARG_ENABLE([setpriv],
1382   AS_HELP_STRING([--disable-setpriv], [do not build setpriv]),
1383   [], [UL_DEFAULT_ENABLE([setpriv], [check])]
1384 )
1385 UL_BUILD_INIT([setpriv])
1386 UL_REQUIRES_LINUX([setpriv])
1387 UL_REQUIRES_HAVE([setpriv], [linux_securebits_h], [securebits.h header file])
1388 UL_REQUIRES_HAVE([setpriv], [cap_ng], [libcap-ng library])
1389 AM_CONDITIONAL([BUILD_SETPRIV], [test "x$build_setpriv" = xyes])
1390
1391
1392 AC_ARG_ENABLE([eject],
1393   AS_HELP_STRING([--disable-eject], [do not build eject]),
1394   [], [UL_DEFAULT_ENABLE([eject], [check])]
1395 )
1396 UL_BUILD_INIT([eject])
1397 UL_REQUIRES_LINUX([eject])
1398 UL_REQUIRES_BUILD([eject], [libmount])
1399 AM_CONDITIONAL([BUILD_EJECT], [test "x$build_eject" = xyes])
1400
1401
1402 AC_ARG_ENABLE([agetty],
1403   AS_HELP_STRING([--disable-agetty], [do not build agetty]),
1404   [], [UL_DEFAULT_ENABLE([agetty], [check])]
1405 )
1406 UL_BUILD_INIT([agetty])
1407 UL_REQUIRES_HAVE([agetty], [utmpx_h], [utmpx.h header])
1408 UL_REQUIRES_HAVE([agetty], [gnu_utmpx], [GNU utmpx functions])
1409 AM_CONDITIONAL([BUILD_AGETTY], [test "x$build_agetty" = xyes])
1410 AS_IF([test "x$have_futimens" = xyes -a "x$have_inotify_init1" = xyes ], [
1411   AC_DEFINE([AGETTY_RELOAD], [1], [Enable agetty --reload feature])
1412 ],[
1413   AC_MSG_WARN([futimens or inotify_init1 not found; agetty(8) will not provide ---reload functionality])
1414 ])
1415
1416
1417 AC_ARG_ENABLE([plymouth_support],
1418   AS_HELP_STRING([--disable-plymouth_support], [don not care about plymouth in sylogin(8) and agetty(8)]),
1419   [], [enable_plymouth_support=check]
1420 )
1421 UL_BUILD_INIT([plymouth_support])
1422 UL_REQUIRES_HAVE([plymouth_support], [tiocglcktrmios], [TIOCGLCKTRMIOS flag])
1423 UL_REQUIRES_HAVE([plymouth_support], [sock_cloexec], [SOCK_CLOEXEC flag])
1424 UL_REQUIRES_HAVE([plymouth_support], [sock_nonblock], [SOCK_NONBLOCK flag])
1425 UL_REQUIRES_HAVE([plymouth_support], [so_passcred], [SO_PASSCRED flag])
1426 AM_CONDITIONAL([USE_PLYMOUTH_SUPPORT], [test "x$build_plymouth_support" = xyes])
1427 AS_IF([test "x$build_plymouth_support" = xyes ], [
1428     AC_DEFINE([USE_PLYMOUTH_SUPPORT], [1], [Enable plymouth support feature for sulogin and aggety])
1429 ])
1430
1431
1432 AC_ARG_WITH([libz],
1433   AS_HELP_STRING([--without-libz], [compile without libz]),
1434   [], [with_libz=auto]
1435 )
1436 AS_IF([test "x$with_libz" = xno], [have_z=no], [
1437   AC_CHECK_LIB([z], [crc32], [have_z=yes], [have_z=no])
1438 ])
1439
1440
1441 AC_ARG_ENABLE([cramfs],
1442   AS_HELP_STRING([--disable-cramfs], [do not build fsck.cramfs, mkfs.cramfs]),
1443   [], [UL_DEFAULT_ENABLE([cramfs], [check])]
1444 )
1445 UL_BUILD_INIT([cramfs])
1446 UL_REQUIRES_HAVE([cramfs], [z], [z library])
1447 AM_CONDITIONAL([BUILD_CRAMFS], [test "x$build_cramfs" = xyes])
1448
1449
1450 AC_ARG_ENABLE([bfs],
1451   AS_HELP_STRING([--disable-bfs], [do not build mkfs.bfs]),
1452   [], [UL_DEFAULT_ENABLE([bfs], [yes])]
1453 )
1454 UL_BUILD_INIT([bfs])
1455 AM_CONDITIONAL([BUILD_BFS], [test "x$build_bfs" = xyes])
1456
1457
1458 AC_ARG_ENABLE([minix],
1459   AS_HELP_STRING([--disable-minix], [do not build fsck.minix, mkfs.minix]),
1460   [], [UL_DEFAULT_ENABLE([minix], [yes])]
1461 )
1462 UL_BUILD_INIT([minix])
1463 AM_CONDITIONAL([BUILD_MINIX], [test "x$build_minix" = xyes])
1464
1465
1466 AC_ARG_ENABLE([fdformat],
1467   AS_HELP_STRING([--disable-fdformat], [do not build fdformat]),
1468   [], [UL_DEFAULT_ENABLE([fdformat], [check])]
1469 )
1470 UL_BUILD_INIT([fdformat])
1471 UL_REQUIRES_LINUX([fdformat])
1472 AM_CONDITIONAL([BUILD_FDFORMAT], [test "x$build_fdformat" = xyes])
1473
1474
1475 AC_ARG_ENABLE([hwclock],
1476   AS_HELP_STRING([--disable-hwclock], [do not build hwclock]),
1477   [], [UL_DEFAULT_ENABLE([hwclock], [check])]
1478 )
1479 have_linuxdummy=$linux_os
1480
1481 UL_BUILD_INIT([hwclock])
1482 UL_REQUIRES_HAVE([hwclock], [io, linuxdummy], [ioperm iopl function or Linux])
1483 AM_CONDITIONAL([BUILD_HWCLOCK], [test "x$build_hwclock" = xyes])
1484
1485
1486 UL_BUILD_INIT([mkfs], [yes])
1487 AM_CONDITIONAL([BUILD_MKFS], [test "x$build_mkfs" = xyes])
1488
1489 UL_BUILD_INIT([isosize], [yes])
1490 AM_CONDITIONAL([BUILD_ISOSIZE], [test "x$build_isosize" = xyes])
1491
1492
1493 UL_BUILD_INIT([fstrim], [check])
1494 UL_REQUIRES_LINUX([fstrim])
1495 UL_REQUIRES_BUILD([fstrim], [libmount])
1496 AM_CONDITIONAL([BUILD_FSTRIM], [test "x$build_fstrim" = xyes])
1497
1498
1499 UL_BUILD_INIT([swapon], [check])
1500 UL_REQUIRES_LINUX([swapon])
1501 UL_REQUIRES_SYSCALL_CHECK([swapon], [UL_CHECK_SYSCALL([swapon])], [swapon])
1502 UL_REQUIRES_SYSCALL_CHECK([swapon], [UL_CHECK_SYSCALL([swapoff])], [swapoff])
1503 UL_REQUIRES_BUILD([swapon], [libblkid])
1504 UL_REQUIRES_BUILD([swapon], [libmount])
1505 UL_REQUIRES_BUILD([swapon], [libsmartcols])
1506 AM_CONDITIONAL([BUILD_SWAPON], [test "x$build_swapon" = xyes])
1507 AC_CHECK_FUNCS([swapon])
1508 AC_CHECK_FUNCS([swapoff])
1509
1510
1511 UL_BUILD_INIT([lsblk], [check])
1512 UL_REQUIRES_LINUX([lsblk])
1513 UL_REQUIRES_BUILD([lsblk], [libblkid])
1514 UL_REQUIRES_BUILD([lsblk], [libmount])
1515 UL_REQUIRES_BUILD([lsblk], [libsmartcols])
1516 AM_CONDITIONAL([BUILD_LSBLK], [test "x$build_lsblk" = xyes])
1517
1518
1519 UL_BUILD_INIT([lscpu], [check])
1520 UL_REQUIRES_LINUX([lscpu])
1521 UL_REQUIRES_BUILD([lscpu], [libsmartcols])
1522 UL_REQUIRES_HAVE([lscpu], [cpu_set_t], [cpu_set_t type])
1523 AM_CONDITIONAL([BUILD_LSCPU], [test "x$build_lscpu" = xyes])
1524
1525
1526 AC_ARG_ENABLE([lslogins],
1527   AS_HELP_STRING([--disable-lslogins], [do not build lslogins]),
1528   [], [UL_DEFAULT_ENABLE([lslogins], [check])]
1529 )
1530 UL_BUILD_INIT([lslogins])
1531 UL_REQUIRES_BUILD([lslogins], [libsmartcols])
1532 UL_REQUIRES_HAVE([lslogins], [shadow_h], [shadow.h header])
1533 UL_REQUIRES_HAVE([lslogins], [utmpx_h], [utmpx.h header])
1534 UL_REQUIRES_HAVE([lslogins], [gnu_utmpx], [GNU utmpx functions])
1535 AM_CONDITIONAL([BUILD_LSLOGINS], [test "x$build_lslogins" = xyes])
1536
1537
1538 UL_BUILD_INIT([chcpu], [check])
1539 UL_REQUIRES_LINUX([chcpu])
1540 UL_REQUIRES_HAVE([chcpu], [cpu_set_t], [cpu_set_t type])
1541 AM_CONDITIONAL([BUILD_CHCPU], [test "x$build_chcpu" = xyes])
1542
1543
1544 AC_ARG_ENABLE([wdctl],
1545   AS_HELP_STRING([--disable-wdctl], [do not build wdctl]),
1546   [], [UL_DEFAULT_ENABLE([wdctl], [check])]
1547 )
1548 UL_BUILD_INIT([wdctl])
1549 UL_REQUIRES_LINUX([wdctl])
1550 UL_REQUIRES_BUILD([wdctl], [libsmartcols])
1551 UL_REQUIRES_HAVE([wdctl], [linux_watchdog_h], [linux/watchdog.h header file])
1552 AM_CONDITIONAL([BUILD_WDCTL], [test "x$build_wdctl" = xyes])
1553
1554
1555 UL_BUILD_INIT([swaplabel], [check])
1556 UL_REQUIRES_BUILD([swaplabel], [libblkid])
1557 AM_CONDITIONAL([BUILD_SWAPLABEL], [test "x$build_swaplabel" = xyes])
1558
1559
1560 UL_BUILD_INIT([mkswap], [yes])
1561 AM_CONDITIONAL([BUILD_MKSWAP], [test "x$build_mkswap" = xyes])
1562 AS_IF([test "x$build_mkswap" = xyes -a "x$build_libuuid" != xyes], [
1563   AC_MSG_WARN([uuid library is not found; mkswap(8) will not generate UUIDs])
1564 ])
1565
1566
1567 AC_ARG_ENABLE([cal],
1568   AS_HELP_STRING([--disable-cal], [do not build cal]),
1569   [], [UL_DEFAULT_ENABLE([cal], [check])]
1570 )
1571 UL_BUILD_INIT([cal])
1572 AM_CONDITIONAL([BUILD_CAL], [test "x$build_cal" = xyes])
1573
1574 AC_ARG_ENABLE([logger],
1575   AS_HELP_STRING([--disable-logger], [do not build logger]),
1576   [], [UL_DEFAULT_ENABLE([logger], [check])]
1577 )
1578 UL_BUILD_INIT([logger])
1579 AM_CONDITIONAL([BUILD_LOGGER], [test "x$build_logger" = xyes])
1580
1581 UL_BUILD_INIT([look], [yes])
1582 AM_CONDITIONAL([BUILD_LOOK], [test "x$build_look" = xyes])
1583
1584 UL_BUILD_INIT([mcookie], [yes])
1585 AM_CONDITIONAL([BUILD_MCOOKIE], [test "x$build_mcookie" = xyes])
1586
1587 UL_BUILD_INIT([namei], [yes])
1588 AM_CONDITIONAL([BUILD_NAMEI], [test "x$build_namei" = xyes])
1589
1590 matriplet="$($CC -print-multiarch 2>/dev/null || true)"
1591 if test "x$matriplet" != "x"; then
1592   AC_DEFINE_UNQUOTED([MULTIARCHTRIPLET], ["$matriplet"],
1593   ["Multi-arch triplet for whereis library search path"])
1594 fi
1595 UL_BUILD_INIT([whereis], [yes])
1596 AM_CONDITIONAL([BUILD_WHEREIS], [test "x$build_whereis" = xyes])
1597
1598 UL_BUILD_INIT([getopt], [yes])
1599 AM_CONDITIONAL([BUILD_GETOPT], [test "x$build_getopt" = xyes])
1600
1601
1602 UL_BUILD_INIT([blockdev], [check])
1603 UL_REQUIRES_LINUX([blockdev])
1604 AM_CONDITIONAL([BUILD_BLOCKDEV], [test "x$build_blockdev" = xyes])
1605
1606
1607 UL_BUILD_INIT([prlimit], [check])
1608 UL_REQUIRES_LINUX([prlimit])
1609 UL_REQUIRES_BUILD([prlimit], [libsmartcols])
1610 UL_REQUIRES_SYSCALL_CHECK([prlimit], [UL_CHECK_SYSCALL([prlimit64])], [prlimit64])
1611 AM_CONDITIONAL([BUILD_PRLIMIT], [test "x$build_prlimit" = xyes])
1612 AS_IF([test "x$build_prlimit" = xyes], [
1613   AC_CHECK_FUNCS([prlimit])
1614 ])
1615
1616
1617 UL_BUILD_INIT([lslocks], [check])
1618 UL_REQUIRES_LINUX([lslocks])
1619 UL_REQUIRES_BUILD([lslocks], [libmount])
1620 UL_REQUIRES_BUILD([lslocks], [libsmartcols])
1621 AM_CONDITIONAL([BUILD_LSLOCKS], [test "x$build_lslocks" = xyes])
1622
1623
1624 AC_ARG_ENABLE([switch_root],
1625   AS_HELP_STRING([--disable-switch_root], [do not build switch_root]),
1626   [], [UL_DEFAULT_ENABLE([switch_root], [check])]
1627 )
1628 UL_BUILD_INIT([switch_root])
1629 UL_REQUIRES_LINUX([switch_root])
1630 UL_REQUIRES_HAVE([switch_root], [openat], [openat function])
1631 AM_CONDITIONAL([BUILD_SWITCH_ROOT], [test "x$build_switch_root" = xyes])
1632
1633
1634 AC_ARG_ENABLE([pivot_root],
1635   AS_HELP_STRING([--disable-pivot_root], [do not build pivot_root]),
1636   [], [UL_DEFAULT_ENABLE([pivot_root], [check])]
1637 )
1638 UL_BUILD_INIT([pivot_root])
1639 UL_REQUIRES_LINUX([pivot_root])
1640 UL_REQUIRES_SYSCALL_CHECK([pivot_root], [UL_CHECK_SYSCALL([pivot_root])])
1641 AM_CONDITIONAL([BUILD_PIVOT_ROOT], [test "x$build_pivot_root" = xyes])
1642
1643
1644 UL_BUILD_INIT([flock], [check])
1645 UL_REQUIRES_HAVE([flock], [timer], [timer_create function])
1646 AM_CONDITIONAL([BUILD_FLOCK], [test "x$build_flock" = xyes])
1647
1648
1649 AC_ARG_ENABLE([lsmem],
1650   AS_HELP_STRING([--disable-lsmem], [do not build lsmem]),
1651   [], [UL_DEFAULT_ENABLE([lsmem], [check])]
1652 )
1653 UL_BUILD_INIT([lsmem])
1654 UL_REQUIRES_LINUX([lsmem])
1655 UL_REQUIRES_BUILD([lsmem], [libsmartcols])
1656 AM_CONDITIONAL([BUILD_LSMEM], [test "x$build_lsmem" = xyes])
1657
1658
1659 AC_ARG_ENABLE([chmem],
1660   AS_HELP_STRING([--disable-chmem], [do not build chmem]),
1661   [], [UL_DEFAULT_ENABLE([chmem], [check])]
1662 )
1663 UL_BUILD_INIT([chmem])
1664 UL_REQUIRES_LINUX([chmem])
1665 AM_CONDITIONAL([BUILD_CHMEM], [test "x$build_chmem" = xyes])
1666
1667 UL_BUILD_INIT([ipcmk], [yes])
1668 AM_CONDITIONAL([BUILD_IPCMK], [test "x$build_ipcmk" = xyes])
1669
1670
1671 AC_ARG_ENABLE([ipcrm],
1672   AS_HELP_STRING([--disable-ipcrm], [do not build ipcrm]),
1673   [], [UL_DEFAULT_ENABLE([ipcrm], [yes])]
1674 )
1675 UL_BUILD_INIT([ipcrm])
1676 AM_CONDITIONAL([BUILD_IPCRM], [test "x$build_ipcrm" = xyes])
1677
1678 AC_ARG_ENABLE([ipcs],
1679   AS_HELP_STRING([--disable-ipcs], [do not build ipcs]),
1680   [], [UL_DEFAULT_ENABLE([ipcs], [yes])]
1681 )
1682 UL_BUILD_INIT([ipcs])
1683 AM_CONDITIONAL([BUILD_IPCS], [test "x$build_ipcs" = xyes])
1684
1685 UL_BUILD_INIT([choom], [check])
1686 UL_REQUIRES_LINUX([choom])
1687 AM_CONDITIONAL([BUILD_CHOOM], [test "x$build_choom" = xyes])
1688
1689 UL_BUILD_INIT([lsipc], [check])
1690 UL_REQUIRES_LINUX([lsipc])
1691 UL_REQUIRES_BUILD([lsipc], [libsmartcols])
1692 AM_CONDITIONAL([BUILD_LSIPC], [test "x$build_lsipc" = xyes])
1693
1694 UL_BUILD_INIT([lsns], [check])
1695 UL_REQUIRES_LINUX([lsns])
1696 UL_REQUIRES_BUILD([lsns], [libsmartcols])
1697 UL_REQUIRES_BUILD([lsns], [libmount])
1698 AM_CONDITIONAL([BUILD_LSNS], [test "x$build_lsns" = xyes])
1699
1700 UL_BUILD_INIT([renice], [yes])
1701 AM_CONDITIONAL([BUILD_RENICE], [test "x$build_renice" = xyes])
1702
1703
1704 AC_ARG_ENABLE([rfkill],
1705   AS_HELP_STRING([--disable-rfkill], [do not build rfkill]),
1706   [], [UL_DEFAULT_ENABLE([rfkill], [check])]
1707 )
1708 UL_BUILD_INIT([rfkill])
1709 UL_REQUIRES_LINUX([rfkill])
1710 UL_REQUIRES_BUILD([rfkill], [libsmartcols])
1711 AM_CONDITIONAL([BUILD_RFKILL], [test "x$build_rfkill" = xyes])
1712
1713
1714 UL_BUILD_INIT([setsid], [yes])
1715 AM_CONDITIONAL([BUILD_SETSID], [test "x$build_setsid" = xyes])
1716
1717 UL_BUILD_INIT([readprofile], [check])
1718 UL_REQUIRES_LINUX([readprofile])
1719 AM_CONDITIONAL([BUILD_READPROFILE], [test "x$build_readprofile" = xyes])
1720
1721 UL_BUILD_INIT([dmesg], [check])
1722 UL_REQUIRES_LINUX([dmesg])
1723 AM_CONDITIONAL([BUILD_DMESG], [test "x$build_dmesg" = xyes])
1724
1725 UL_BUILD_INIT([ctrlaltdel], [check])
1726 UL_REQUIRES_LINUX([ctrlaltdel])
1727 dnl we assume reboot() to be the 1-argument variant, because even considering
1728 dnl widely used alternative C libraries like uclibc, dietlibc and musl,
1729 dnl reboot() with multiple arguments is yet only found in glibc versions
1730 dnl earlier than 2.x.
1731 UL_REQUIRES_HAVE([ctrlaltdel], [reboot], [reboot function])
1732 AM_CONDITIONAL([BUILD_CTRLALTDEL], [test "x$build_ctrlaltdel" = xyes])
1733
1734 UL_BUILD_INIT([fincore], [check])
1735 UL_REQUIRES_LINUX([fincore])
1736 UL_REQUIRES_BUILD([fincore], [libsmartcols])
1737 AM_CONDITIONAL([BUILD_FINCORE], [test "x$build_fincore" = xyes])
1738
1739 UL_BUILD_INIT([fsfreeze], [check])
1740 UL_REQUIRES_LINUX([fsfreeze])
1741 AM_CONDITIONAL([BUILD_FSFREEZE], [test "x$build_fsfreeze" = xyes])
1742
1743 UL_BUILD_INIT([blkdiscard], [check])
1744 UL_REQUIRES_LINUX([blkdiscard])
1745 AM_CONDITIONAL([BUILD_BLKDISCARD], [test "x$build_blkdiscard" = xyes])
1746
1747 UL_BUILD_INIT([blkzone], [check])
1748 UL_REQUIRES_LINUX([blkzone])
1749 UL_REQUIRES_HAVE([blkzone], [linux_blkzoned_h], [linux/blkzoned.h header])
1750 AM_CONDITIONAL([BUILD_BLKZONE], [test "x$build_blkzone" = xyes])
1751
1752 UL_BUILD_INIT([ldattach], [check])
1753 UL_REQUIRES_LINUX([ldattach])
1754 AM_CONDITIONAL([BUILD_LDATTACH], [test "x$build_ldattach" = xyes])
1755
1756 UL_BUILD_INIT([rtcwake], [check])
1757 UL_REQUIRES_LINUX([rtcwake])
1758 AM_CONDITIONAL([BUILD_RTCWAKE], [test "x$build_rtcwake" = xyes])
1759
1760 UL_BUILD_INIT([setarch], [check])
1761 UL_REQUIRES_LINUX([setarch])
1762 AM_CONDITIONAL([BUILD_SETARCH], [test "x$build_setarch" = xyes])
1763
1764 UL_BUILD_INIT([script], [check])
1765 UL_REQUIRES_HAVE([script], [sys_signalfd_h], [sys/signalfd.h header])
1766 AM_CONDITIONAL([BUILD_SCRIPT], [test "x$build_script" = xyes])
1767
1768 UL_BUILD_INIT([scriptreplay], [yes])
1769 AM_CONDITIONAL([BUILD_SCRIPTREPLAY], [test "x$build_scriptreplay" = xyes])
1770
1771 UL_BUILD_INIT([col], [yes])
1772 AM_CONDITIONAL([BUILD_COL], [test "x$build_col" = xyes])
1773
1774 UL_BUILD_INIT([colcrt], [yes])
1775 AM_CONDITIONAL([BUILD_COLCRT], [test "x$build_colcrt" = xyes])
1776
1777 UL_BUILD_INIT([colrm], [yes])
1778 AM_CONDITIONAL([BUILD_COLRM], [test "x$build_colrm" = xyes])
1779
1780 UL_BUILD_INIT([column], [check])
1781 UL_REQUIRES_BUILD([column], [libsmartcols])
1782 AM_CONDITIONAL([BUILD_COLUMN], [test "x$build_column" = xyes])
1783
1784 UL_BUILD_INIT([hexdump], [yes])
1785 AM_CONDITIONAL([BUILD_HEXDUMP], [test "x$build_hexdump" = xyes])
1786
1787 UL_BUILD_INIT([rev], [yes])
1788 AM_CONDITIONAL([BUILD_REV], [test "x$build_rev" = xyes])
1789
1790
1791 AC_ARG_ENABLE([tunelp],
1792   AS_HELP_STRING([--enable-tunelp], [build tunelp]),
1793   [], [UL_DEFAULT_ENABLE([tunelp], [no])]
1794 )
1795 UL_BUILD_INIT([tunelp])
1796 UL_REQUIRES_LINUX([tunelp])
1797 AM_CONDITIONAL([BUILD_TUNELP], [test "x$build_tunelp" = xyes])
1798
1799
1800 AC_ARG_ENABLE([kill],
1801   AS_HELP_STRING([--disable-kill], [do not build kill]),
1802   [], [UL_DEFAULT_ENABLE([kill], [check])]
1803 )
1804 UL_BUILD_INIT([kill])
1805 UL_REQUIRES_LINUX([kill])
1806 AM_CONDITIONAL([BUILD_KILL], [test "x$build_kill" = xyes])
1807
1808
1809 AC_ARG_ENABLE([last],
1810   AS_HELP_STRING([--disable-last], [do not build last]),
1811   [], [UL_DEFAULT_ENABLE([last], [check])]
1812 )
1813 UL_BUILD_INIT([last])
1814 UL_REQUIRES_HAVE([last], [utmpx_h], [utmpx.h header])
1815 UL_REQUIRES_HAVE([last], [gnu_utmpx], [GNU utmpx functions])
1816 AM_CONDITIONAL([BUILD_LAST], [test "x$build_last" = xyes])
1817
1818
1819 AC_ARG_ENABLE([utmpdump],
1820   AS_HELP_STRING([--disable-utmpdump], [do not build utmpdump]),
1821   [], [UL_DEFAULT_ENABLE([utmpdump], [check])]
1822 )
1823 UL_BUILD_INIT([utmpdump])
1824 UL_REQUIRES_HAVE([utmpdump], [utmpx_h], [utmpx.h header])
1825 UL_REQUIRES_HAVE([utmpdump], [gnu_utmpx], [GNU utmpx functions])
1826 AM_CONDITIONAL([BUILD_UTMPDUMP], [test "x$build_utmpdump" = xyes])
1827
1828
1829 AC_ARG_ENABLE([line],
1830   AS_HELP_STRING([--enable-line], [build line]),
1831   [], [UL_DEFAULT_ENABLE([line], [no])]
1832 )
1833 UL_BUILD_INIT([line])
1834 AM_CONDITIONAL([BUILD_LINE], [test "x$build_line" = xyes])
1835
1836
1837 AC_ARG_ENABLE([mesg],
1838   AS_HELP_STRING([--disable-mesg], [do not build mesg]),
1839   [], [UL_DEFAULT_ENABLE([mesg], [yes])]
1840 )
1841 UL_BUILD_INIT([mesg])
1842 AM_CONDITIONAL([BUILD_MESG], [test "x$build_mesg" = xyes])
1843
1844
1845 AC_ARG_ENABLE([raw],
1846   AS_HELP_STRING([--disable-raw], [do not build raw]),
1847   [], [UL_DEFAULT_ENABLE([raw], [check])]
1848 )
1849 UL_BUILD_INIT([raw])
1850 UL_REQUIRES_LINUX([raw])
1851 UL_REQUIRES_HAVE([raw], [linux_raw_h], [raw.h header file])
1852 AM_CONDITIONAL([BUILD_RAW], [test "x$build_raw" = xyes])
1853
1854
1855 AC_ARG_ENABLE([rename],
1856   AS_HELP_STRING([--disable-rename], [do not build rename]),
1857   [], [UL_DEFAULT_ENABLE([rename], [yes])]
1858 )
1859 UL_BUILD_INIT([rename])
1860 AM_CONDITIONAL([BUILD_RENAME], [test "x$build_rename" = xyes])
1861
1862
1863 AC_ARG_ENABLE([vipw],
1864   AS_HELP_STRING([--enable-vipw], [build vipw]),
1865   [], [UL_DEFAULT_ENABLE([vipw], [no])]
1866 )
1867 UL_BUILD_INIT([vipw])
1868 UL_REQUIRES_HAVE([vipw], [shadow_h], [shadow.h header])
1869 AM_CONDITIONAL([BUILD_VIPW], [test "x$build_vipw" = xyes])
1870
1871
1872 AC_ARG_ENABLE([newgrp],
1873   AS_HELP_STRING([--enable-newgrp], [build newgrp]),
1874   [], [UL_DEFAULT_ENABLE([newgrp], [no])]
1875 )
1876 UL_BUILD_INIT([newgrp])
1877 AM_CONDITIONAL([BUILD_NEWGRP], [test "x$build_newgrp" = xyes])
1878
1879
1880 AC_ARG_WITH([user], AS_HELP_STRING([--without-user], [compile without libuser (remote chsh)]),
1881   [], [with_user=check]
1882 )
1883 have_user=no
1884 AS_IF([test "x$with_user" != xno], [
1885   PKG_CHECK_MODULES(LIBUSER,[libuser >= 0.58], [have_user=yes], [have_user=no])
1886   AS_CASE([$with_user:$have_user],
1887     [yes:no],
1888       [AC_MSG_ERROR([user selected but libuser not found])],
1889     [*:yes],
1890       [AC_DEFINE([HAVE_LIBUSER], [1], [Define if libuser is available])]
1891   )
1892   # temporary solution, libuser has stupid .pc where are exported all
1893   # private dependencies to Requires: instead of Requires.private:
1894   AS_IF([test "x$have_user" = xyes], [
1895     LIBUSER_LIBS=-luser
1896   ])
1897 ])
1898 AM_CONDITIONAL([HAVE_USER], [test "x$have_user" = xyes])
1899
1900 AC_ARG_ENABLE([chfn-chsh-password],
1901   AS_HELP_STRING([--disable-chfn-chsh-password], [do not require the user to enter the password in chfn and chsh]),
1902   [], [enable_chfn_chsh_password=yes]
1903 )
1904
1905 AC_ARG_ENABLE([chfn-chsh],
1906   AS_HELP_STRING([--enable-chfn-chsh], [build chfn and chsh]),
1907   [], [UL_DEFAULT_ENABLE([chfn_chsh], [check])]
1908 )
1909 UL_BUILD_INIT([chfn_chsh])
1910 UL_REQUIRES_HAVE([chfn_chsh], [shadow_h], [shadow.h header])
1911 UL_REQUIRES_HAVE([chfn_chsh], [getusershell], [getusershell function])
1912
1913 AS_IF([test "x$enable_chfn_chsh_password" = xyes -o "x$have_user" = xyes], [
1914   UL_REQUIRES_HAVE([chfn_chsh], [security_pam_appl_h], [PAM header file])
1915   AC_DEFINE([CHFN_CHSH_PASSWORD], [1], [Should chfn and chsh require the user to enter the password?])
1916 ])
1917 AM_CONDITIONAL([BUILD_CHFN_CHSH], [test "x$build_chfn_chsh" = xyes])
1918 AM_CONDITIONAL([CHFN_CHSH_PASSWORD], [test "x$enable_chfn_chsh_password" = xyes])
1919
1920 AC_ARG_ENABLE([chsh-only-listed],
1921   AS_HELP_STRING([--disable-chsh-only-listed], [chsh: allow shells not in /etc/shells]),
1922   [], enable_chsh_only_listed=yes
1923 )
1924
1925 AS_IF([test "x$enable_chsh_only_listed" = xyes], [
1926   AC_DEFINE([ONLY_LISTED_SHELLS], [1], [Should chsh allow only shells in /etc/shells?])
1927 ])
1928
1929
1930 AC_ARG_ENABLE([login],
1931   AS_HELP_STRING([--disable-login], [do not build login]),
1932   [], [UL_DEFAULT_ENABLE([login], [check])]
1933 )
1934 UL_BUILD_INIT([login])
1935 UL_REQUIRES_HAVE([login], [security_pam_appl_h], [PAM header file])
1936 UL_REQUIRES_HAVE([login], [security_pam_misc_h, security_openpam_h], [PAM conversation functions])
1937 UL_REQUIRES_HAVE([login], [utmpx_h], [utmpx.h header])
1938 UL_REQUIRES_HAVE([login], [gnu_utmpx], [GNU utmpx functions])
1939 AM_CONDITIONAL([BUILD_LOGIN], [test "x$build_login" = xyes])
1940
1941 AC_ARG_ENABLE([login-chown-vcs],
1942   AS_HELP_STRING([--enable-login-chown-vcs], [let login chown /dev/vcsN]),
1943   [], [enable_login_chown_vcs=no]
1944 )
1945
1946 AS_IF([test "x$enable_login_chown_vcs" = xyes], [
1947   AC_DEFINE([LOGIN_CHOWN_VCS], [1], [Should login chown /dev/vcsN?])
1948 ])
1949
1950 AC_ARG_ENABLE([login-stat-mail],
1951   AS_HELP_STRING([--enable-login-stat-mail], [let login stat() the mailbox]),
1952   [], [enable_login_stat_mail=no]
1953 )
1954
1955 AS_IF([test "x$enable_login_stat_mail" = xyes], [
1956   AC_DEFINE([LOGIN_STAT_MAIL], [1], [Should login stat() the mailbox?])
1957 ])
1958
1959
1960 AC_ARG_ENABLE([nologin],
1961   AS_HELP_STRING([--disable-nologin], [do not build nologin]),
1962   [], [UL_DEFAULT_ENABLE([nologin], [yes])]
1963 )
1964 UL_BUILD_INIT([nologin])
1965 AM_CONDITIONAL([BUILD_NOLOGIN], [test "x$build_nologin" = xyes])
1966
1967
1968 AC_ARG_ENABLE([sulogin],
1969   AS_HELP_STRING([--disable-sulogin], [do not build sulogin]),
1970   [], [UL_DEFAULT_ENABLE([sulogin], [check])]
1971 )
1972 UL_BUILD_INIT([sulogin])
1973 UL_REQUIRES_HAVE([sulogin], [shadow_h], [shadow.h header])
1974 AM_CONDITIONAL([BUILD_SULOGIN], [test "x$build_sulogin" = xyes])
1975
1976
1977 AC_ARG_ENABLE([su],
1978   AS_HELP_STRING([--disable-su], [do not build su]),
1979   [], [UL_DEFAULT_ENABLE([su], [check])]
1980 )
1981 UL_BUILD_INIT([su])
1982 UL_REQUIRES_HAVE([su], [security_pam_appl_h], [PAM header file])
1983 UL_REQUIRES_HAVE([su], [utmpx_h], [utmpx.h header])
1984 UL_REQUIRES_HAVE([su], [gnu_utmpx], [GNU utmpx functions])
1985 AM_CONDITIONAL([BUILD_SU], [test "x$build_su" = xyes])
1986
1987
1988 AC_ARG_ENABLE([runuser],
1989   AS_HELP_STRING([--disable-runuser], [do not build runuser]),
1990   [], [UL_DEFAULT_ENABLE([runuser], [check])]
1991 )
1992 UL_BUILD_INIT([runuser])
1993 UL_REQUIRES_HAVE([runuser], [security_pam_appl_h], [PAM header file])
1994 UL_REQUIRES_HAVE([runuser], [utmpx_h], [utmpx.h header])
1995 UL_REQUIRES_HAVE([runuser], [gnu_utmpx], [GNU utmpx functions])
1996 AM_CONDITIONAL([BUILD_RUNUSER], [test "x$build_runuser" = xyes])
1997
1998
1999 AC_ARG_ENABLE([ul],
2000   AS_HELP_STRING([--disable-ul], [do not build ul]),
2001   [], [UL_DEFAULT_ENABLE([ul], [check])]
2002 )
2003 UL_BUILD_INIT([ul])
2004 UL_REQUIRES_HAVE([ul], [ncursesw, ncurses], [ncursesw or ncurses libraries])
2005 AM_CONDITIONAL([BUILD_UL], [test "x$build_ul" = xyes])
2006
2007
2008 AC_ARG_ENABLE([more],
2009   AS_HELP_STRING([--disable-more], [do not build more]),
2010   [], [UL_DEFAULT_ENABLE([more], [check])]
2011 )
2012 UL_BUILD_INIT([more])
2013 UL_REQUIRES_HAVE([more], [ncursesw, ncurses], [ncursesw or ncurses libraries])
2014 AM_CONDITIONAL([BUILD_MORE], [test "x$build_more" = xyes])
2015
2016
2017 AC_ARG_ENABLE([pg],
2018   AS_HELP_STRING([--enable-pg], [build pg]),
2019   [], [UL_DEFAULT_ENABLE([pg], [no])]
2020 )
2021 UL_BUILD_INIT([pg])
2022 UL_REQUIRES_HAVE([pg], [ncursesw, ncurses], [ncursesw or ncurses library])
2023 AM_CONDITIONAL([BUILD_PG], [test "x$build_pg" = xyes])
2024
2025
2026 AC_ARG_ENABLE([setterm],
2027   AS_HELP_STRING([--disable-setterm], [do not build setterm]),
2028   [], [UL_DEFAULT_ENABLE([setterm], [check])]
2029 )
2030 UL_BUILD_INIT([setterm])
2031 UL_REQUIRES_LINUX([setterm])
2032 UL_REQUIRES_HAVE([setterm], [ncursesw, ncurses], [ncursesw or ncurses library])
2033 AM_CONDITIONAL([BUILD_SETTERM], [test "x$build_setterm" = xyes])
2034
2035 # build_schedutils= is just configure-only variable to control
2036 # ionice, taskset and chrt
2037 AC_ARG_ENABLE([schedutils],
2038   AS_HELP_STRING([--disable-schedutils], [do not build chrt, ionice, taskset]),
2039   [], [UL_DEFAULT_ENABLE([schedutils], [check])]
2040 )
2041
2042
2043 UL_ENABLE_ALIAS([ionice], [schedutils])
2044 UL_BUILD_INIT([ionice])
2045 UL_REQUIRES_SYSCALL_CHECK([ionice],
2046         [UL_CHECK_SYSCALL([ioprio_set],
2047           [alpha],      [442],
2048           [i*86],       [289],
2049           [ia64*],      [1274],
2050           [powerpc*],   [273],
2051           [s390*],      [282],
2052           [sparc*],     [196],
2053           [sh*],        [288],
2054           [x86_64*],    [251])],
2055         [ioprio_set])
2056
2057 UL_REQUIRES_SYSCALL_CHECK([ionice],
2058         [UL_CHECK_SYSCALL([ioprio_get],
2059           [alpha],      [443],
2060           [i*86],       [290],
2061           [ia64*],      [1275],
2062           [powerpc*],   [274],
2063           [s390*],      [283],
2064           [sparc*],     [218],
2065           [sh*],        [289],
2066           [x86_64*],    [252])],
2067         [ioprio_get])
2068
2069 AM_CONDITIONAL([BUILD_IONICE], [test "x$build_ionice" = xyes])
2070
2071
2072 UL_ENABLE_ALIAS([taskset], [schedutils])
2073 UL_BUILD_INIT([taskset])
2074 UL_REQUIRES_HAVE([taskset], [cpu_set_t], [cpu_set_t type])
2075 UL_REQUIRES_SYSCALL_CHECK([taskset],
2076         [UL_CHECK_SYSCALL([sched_getaffinity])],
2077         [sched_getaffinity])
2078 AM_CONDITIONAL([BUILD_TASKSET], [test "x$build_taskset" = xyes])
2079
2080
2081 have_schedsetter=no
2082 AS_IF([test "x$ac_cv_func_sched_setscheduler" = xyes], [have_schedsetter=yes],
2083       [test "x$ac_cv_func_sched_setattr" = xyes], [have_schedsetter=yes])
2084
2085 UL_ENABLE_ALIAS([chrt], [schedutils])
2086 UL_BUILD_INIT([chrt])
2087 UL_REQUIRES_HAVE([chrt], [schedsetter], [sched_set functions])
2088 AM_CONDITIONAL([BUILD_CHRT], [test "x$build_chrt" = xyes])
2089
2090 AS_IF([test "x$build_chrt" = xyes], [
2091         UL_CHECK_SYSCALL([sched_setattr])
2092 ])
2093
2094
2095 AC_ARG_ENABLE([wall],
2096   AS_HELP_STRING([--disable-wall], [do not build wall]),
2097   [], [UL_DEFAULT_ENABLE([wall], [check])]
2098 )
2099 UL_BUILD_INIT([wall])
2100 UL_REQUIRES_HAVE([wall], [utmpx_h], [utmpx.h header])
2101 AM_CONDITIONAL([BUILD_WALL], [test "x$build_wall" = xyes])
2102
2103
2104 AC_ARG_ENABLE([write],
2105   AS_HELP_STRING([--enable-write], [build write]),
2106   [], [UL_DEFAULT_ENABLE([write], [no])]
2107 )
2108 UL_BUILD_INIT([write])
2109 UL_REQUIRES_HAVE([write], [utmpx_h], [utmpx.h header])
2110 UL_REQUIRES_HAVE([write], [gnu_utmpx], [GNU utmpx functions])
2111 AM_CONDITIONAL([BUILD_WRITE], [test "x$build_write" = xyes])
2112
2113
2114 AC_ARG_WITH([btrfs],
2115   AS_HELP_STRING([--without-btrfs], [do not build with btrfs support]),
2116   [], [with_btrfs=check]
2117 )
2118 have_btrfs=no
2119 AS_IF([test "x$with_btrfs" != xno], [
2120   AS_CASE([$with_btrfs:$have_linux_btrfs_h],
2121     [yes:no],
2122     [AC_MSG_ERROR([btrfs selected but linux/btrfs.h not found])],
2123     [check:no],
2124        [AC_MSG_WARN([linux/btrfs.h not found, do not build with btrfs support])],
2125     [*:yes],
2126        [have_btrfs=yes
2127         AC_DEFINE([HAVE_BTRFS_SUPPORT], [1], [Define if btrfs stuff is available])]
2128   )
2129 ])
2130 AM_CONDITIONAL([HAVE_BTRFS], [test "x$have_btrfs" = xyes])
2131
2132
2133 AC_ARG_WITH([systemd],
2134   AS_HELP_STRING([--without-systemd], [do not build with systemd support]),
2135   [], [with_systemd=check]
2136 )
2137
2138 have_systemd=no
2139 AS_IF([test "x$with_systemd" != xno], [
2140   # new version -- all libsystemd-* libs merged into libsystemd
2141   PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [have_systemd=yes], [have_systemd=no])
2142   # old versions
2143   AS_IF([test "x$have_systemd" != "xyes"], [
2144     PKG_CHECK_MODULES([SYSTEMD_DAEMON], [libsystemd-daemon],
2145                       [have_systemd_daemon=yes], [have_systemd_daemon=no])
2146     PKG_CHECK_MODULES([SYSTEMD_JOURNAL], [libsystemd-journal],
2147                       [have_systemd_journal=yes], [have_systemd_journal=no])
2148     AS_IF([test "x$have_systemd_daemon" = "xyes" -a "x$have_systemd_journal" = "xyes" ],[
2149            have_systemd=yes])
2150   ])
2151   AS_CASE([$with_systemd:$have_systemd],
2152     [yes:no],
2153       [AC_MSG_ERROR([systemd expected but libsystemd not found])],
2154     [*:yes],
2155        AC_DEFINE([HAVE_LIBSYSTEMD], [1], [Define if libsystemd is available])
2156   )
2157 ])
2158 AM_CONDITIONAL([HAVE_SYSTEMD], [test "x$have_systemd" = xyes])
2159
2160
2161 AC_ARG_WITH([systemdsystemunitdir],
2162   AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [directory for systemd unit files (requires systemd support)]),
2163   [], [with_systemdsystemunitdir=check]
2164 )
2165 AS_IF([test "x$with_systemdsystemunitdir" = xcheck], [
2166   AS_IF([test "x$have_systemd" = xyes], [
2167     with_systemdsystemunitdir=`$PKG_CONFIG --variable=systemdsystemunitdir systemd`
2168   ],[
2169     with_systemdsystemunitdir=no
2170   ])
2171 ])
2172 AS_IF([test "x$with_systemdsystemunitdir" != "xno"], [
2173   AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
2174 ])
2175
2176
2177 AC_ARG_WITH([smack],
2178   AS_HELP_STRING([--with-smack], [build with SMACK support]),
2179   [], [with_smack=no]
2180 )
2181 AS_IF([test "x$with_smack" = xyes], [
2182   AC_DEFINE([HAVE_SMACK], [1], [Add SMACK support])
2183 ])
2184
2185
2186 AC_ARG_WITH([bashcompletiondir],
2187   AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
2188   [],
2189   [AS_IF([`$PKG_CONFIG --exists bash-completion`], [
2190     with_bashcompletiondir=`$PKG_CONFIG --variable=completionsdir bash-completion`
2191   ], [
2192     with_bashcompletiondir=${datadir}/bash-completion/completions
2193   ])
2194 ])
2195 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
2196
2197 AC_ARG_ENABLE([bash-completion],
2198   AS_HELP_STRING([--disable-bash-completion], [do not install bash completion files]),
2199   [], [enable_bash_completion=yes]
2200 )
2201
2202 AM_CONDITIONAL([BUILD_BASH_COMPLETION], [test "x$enable_bash_completion" = xyes])
2203
2204
2205 AC_ARG_WITH([python],
2206   AS_HELP_STRING([--without-python], [do not build python bindings, use --with-python={2,3} to force version]),
2207   [], [with_python=check withval=check]
2208 )
2209
2210 have_python=no
2211 have_libpython=no
2212 AS_IF([test "x$with_python" != xno], [
2213   # We follow distributions default and look for PKG module name "python"
2214   # (minimal version is 2) but if major version is explicitly specified by
2215   # --with-python=2 or --with-python=3 then we look for PKG module "python2" or
2216   # "python3".
2217   AS_IF([test "x$withval" != xno -a "x$withval" != xyes -a "x$withval" != xcheck],
2218         [pymajor="$withval"; PYTHON=python${pymajor}], [pymajor="2"])
2219
2220   # check for python interpreter
2221   AM_PATH_PYTHON([$pymajor], [have_python=yes], [have_python=no])
2222   AS_CASE([$with_python:$have_python],
2223     [yes:no],
2224       [AC_MSG_ERROR([python selected but python interpreter not found])],
2225     [check:no],
2226        [AC_MSG_WARN([python interpreter not found, do not build python bindings])],
2227     [*:yes],
2228        # check for python development stuff
2229        [PKG_CHECK_MODULES([PYTHON], [python-$PYTHON_VERSION],
2230                           [have_libpython=yes], [have_libpython=no])]
2231   )
2232 ])
2233
2234
2235 AC_ARG_ENABLE([pylibmount],
2236   AS_HELP_STRING([--disable-pylibmount], [do not build pylibmount]),
2237   [], [UL_DEFAULT_ENABLE([pylibmount], [check])]
2238 )
2239 UL_BUILD_INIT([pylibmount])
2240 UL_REQUIRES_HAVE([pylibmount], [libpython], [libpython])
2241 UL_REQUIRES_BUILD([pylibmount], [libmount])
2242 AM_CONDITIONAL([BUILD_PYLIBMOUNT], [test "x$build_pylibmount" = "xyes"])
2243
2244 # We need to introduce a verbatim dependency into the Makefile, without automake
2245 # trying to interpret it, so push it as a AM_SUBST_NOTMAKE variable.
2246 verbatim_pylibmount_dependency='
2247
2248 # pylibmountexec module must be installed after usrlib_exec libraries,
2249 # otherwise the libtool relink step will fail to find libmount.la and
2250 # will try -lmount which is possibly not available.
2251 install-pylibmountexecLTLIBRARIES: install-usrlib_execLTLIBRARIES
2252
2253 '
2254 AC_SUBST([verbatim_pylibmount_dependency])
2255 AM_SUBST_NOTMAKE([verbatim_pylibmount_dependency])
2256
2257 AC_ARG_ENABLE([pg-bell],
2258   AS_HELP_STRING([--disable-pg-bell], [let pg not ring the bell on invalid keys]),
2259   [], [enable_pg_bell=yes]
2260 )
2261
2262 AS_IF([test "x$enable_pg_bell" = xyes], [
2263   AC_DEFINE([PG_BELL], [1], [Should pg ring the bell on invalid keys?])
2264 ])
2265
2266
2267 AC_DEFUN([FS_PATHS_DEFAULT], [/sbin:/sbin/fs.d:/sbin/fs])
2268 AC_ARG_ENABLE([fs-paths-default],
2269   AS_HELP_STRING([--enable-fs-paths-default=paths], [default search path for fs helpers @<:@FS_PATHS_DEFAULT@:>@]),
2270   [AS_CASE([$enableval],
2271     [yes], [fs_paths_defaults="FS_PATHS_DEFAULT"],
2272     [no],  [fs_paths_defaults=""],
2273     [fs_paths_defaults="$enableval"]
2274   )],
2275   [fs_paths_defaults="FS_PATHS_DEFAULT"]
2276 )
2277 AC_ARG_ENABLE([fs-paths-extra],
2278   AS_HELP_STRING([--enable-fs-paths-extra=paths], [additional search paths for fs helpers]),
2279   [AS_CASE([$enableval],
2280      [yes|no], [fs_paths_extra=""],
2281      [fs_paths_extra="$enableval"]
2282   )],
2283   [fs_paths_extra=""]
2284 )
2285 fs_paths="$fs_paths_defaults"
2286 AS_IF([test "x$fs_paths_extra" != "x"], [
2287   AS_IF([test "x$fs_paths" != "x"], [
2288     fs_paths="${fs_paths}:"
2289   ])
2290   fs_paths="${fs_paths}${fs_paths_extra}"
2291 ])
2292 AC_DEFINE_UNQUOTED([FS_SEARCH_PATH], "$fs_paths", [search path for fs helpers])
2293
2294
2295 AC_ARG_ENABLE([use-tty-group],
2296   AS_HELP_STRING([--disable-use-tty-group], [do not install wall and write setgid tty]),
2297   [], [enable_use_tty_group=yes]
2298 )
2299 AM_CONDITIONAL([USE_TTY_GROUP], [test "x$enable_use_tty_group" = xyes])
2300
2301 AS_IF([test "x$enable_use_tty_group" = xyes], [
2302   AC_DEFINE([USE_TTY_GROUP], [1], [Should wall and write be installed setgid tty?])
2303 ])
2304
2305
2306 AC_ARG_ENABLE([sulogin-emergency-mount],
2307   AS_HELP_STRING([--enable-sulogin-emergency-mount],
2308                  [use emergency mount of /dev and /proc for sulogin]),
2309   [], [enable_sulogin_emergency_mount=no]
2310 )
2311
2312 AS_IF([test "x$enable_sulogin_emergency_mount" = xyes], [
2313   AC_DEFINE([USE_SULOGIN_EMERGENCY_MOUNT], [1],
2314             [Should sulogin use a emergency mount of /dev and /proc?])
2315 ])
2316
2317
2318 AC_ARG_ENABLE([usrdir-path],
2319   AS_HELP_STRING([--enable-usrdir-path], [use only /usr paths in PATH env. variable (recommended on systems with /bin -> /usr/bin symlinks)]),
2320   [], [enable_usrdir_path=no]
2321 )
2322
2323 AS_IF([test "x$enable_usrdir_path" = xyes], [
2324   AC_DEFINE([USE_USRDIR_PATHS_ONLY], [1], [Define to 1 to remove /bin and /sbin from PATH env.variable])
2325 ])
2326
2327
2328 AC_ARG_ENABLE([makeinstall-chown],
2329   AS_HELP_STRING([--disable-makeinstall-chown], [do not do chown-like operations during "make install"]),
2330   [], [enable_makeinstall_chown=yes]
2331 )
2332 AM_CONDITIONAL([MAKEINSTALL_DO_CHOWN], [test "x$enable_makeinstall_chown" = xyes])
2333
2334
2335 AC_ARG_ENABLE([makeinstall-setuid],
2336   AS_HELP_STRING([--disable-makeinstall-setuid], [do not do setuid chmod operations during "make install"]),
2337   [], [enable_makeinstall_setuid=yes]
2338 )
2339 AM_CONDITIONAL([MAKEINSTALL_DO_SETUID], [test "x$enable_makeinstall_setuid" = xyes])
2340
2341
2342 AC_ARG_ENABLE([colors-default],
2343   AS_HELP_STRING([--disable-colors-default], [do not colorize output from utils by default]),
2344   [], [enable_colors_default=yes]
2345 )
2346 AS_IF([test "x$enable_colors_default" = xyes], [
2347   AC_DEFINE([USE_COLORS_BY_DEFAULT], [1], [Enables colorized output from utils by default])
2348 ])
2349
2350
2351 AC_ARG_VAR([SUID_CFLAGS],
2352            [CFLAGS used for binaries which are usually with the suid bit])
2353 AC_ARG_VAR([SUID_LDFLAGS],
2354            [LDFLAGS used for binaries which are usually with the suid bit])
2355
2356 AC_ARG_VAR([DAEMON_CFLAGS],
2357            [CFLAGS used for binaries which are usually executed as daemons])
2358 AC_ARG_VAR([DAEMON_LDFLAGS],
2359            [LDFLAGS used for binaries which are usually executed as daemons])
2360
2361 AC_ARG_VAR([SOLIB_CFLAGS],
2362            [CFLAGS used for shared libraries])
2363 AC_ARG_VAR([SOLIB_LDFLAGS],
2364            [LDFLAGS used for shared libraries])
2365
2366 AC_ARG_VAR([ADJTIME_PATH],
2367            [Path to hwclock adjtime file, default /etc/adjtime])
2368 AS_IF([test "x$ADJTIME_PATH" = x], [ADJTIME_PATH="/etc/adjtime"])
2369 AC_DEFINE_UNQUOTED([CONFIG_ADJTIME_PATH], "$ADJTIME_PATH", [Path to hwclock adjtime file])
2370
2371
2372 LIBS=""
2373
2374
2375 AC_CONFIG_HEADERS([config.h])
2376
2377 #
2378 # Don't use configure.ac to replace install paths! See Makefile PATHFILES for
2379 # more details.
2380 #
2381 AC_CONFIG_FILES([
2382 Makefile
2383 libblkid/docs/Makefile
2384 libblkid/docs/version.xml
2385 libblkid/src/blkid.h
2386 libfdisk/docs/Makefile
2387 libfdisk/docs/version.xml
2388 libfdisk/src/libfdisk.h
2389 libmount/docs/Makefile
2390 libmount/docs/version.xml
2391 libmount/src/libmount.h
2392 libsmartcols/docs/Makefile
2393 libsmartcols/docs/version.xml
2394 libsmartcols/src/libsmartcols.h
2395 po/Makefile.in
2396 ])
2397
2398 AC_OUTPUT
2399
2400 AC_MSG_RESULT([
2401         ${PACKAGE}  ${VERSION}
2402
2403         prefix:            ${prefix}
2404         exec prefix:       ${exec_prefix}
2405
2406         runstatedir:       ${runstatedir}
2407         bindir:            ${bindir}
2408         sbindir:           ${sbindir}
2409         libdir:            ${libdir}
2410         includedir:        ${includedir}
2411         usrbin_execdir:    ${usrbin_execdir}
2412         usrsbin_execdir:   ${usrsbin_execdir}
2413         usrlib_execdir:    ${usrlib_execdir}
2414
2415         compiler:          ${CC}
2416         cflags:            ${CFLAGS}
2417         suid cflags:       ${SUID_CFLAGS}
2418         ldflags:           ${LDFLAGS}
2419         suid ldflags:      ${SUID_LDFLAGS}
2420
2421         Python:            ${PYTHON}
2422         Python version:    ${PYTHON_VERSION}
2423         Python libs:       ${pyexecdir}
2424
2425         Bash completions:  ${with_bashcompletiondir}
2426         Systemd support:   ${have_systemd}
2427         Systemd unitdir:   ${with_systemdsystemunitdir}
2428         Btrfs support:     ${have_btrfs}
2429         Wide-char support: ${build_widechar}
2430
2431         warnings:
2432
2433 ${WARN_CFLAGS}
2434
2435         Type 'make' or 'make <utilname>' to compile.
2436 ])