configure.ac

   1 AC_INIT([util-linux],
   2         m4_esyscmd([tools/git-version-gen .tarball-version]),
   3         [kzak@redhat.com],,
   4         [http://www.kernel.org/pub/linux/utils/util-linux/])
   5
   6
   7 AC_PREREQ([2.60])
   8
   9 AC_CONFIG_AUX_DIR([config])
  10 AC_CONFIG_MACRO_DIR([m4])
  11 dnl AC_USE_SYSTEM_EXTENSIONS must be called before any macros that run
  12 dnl the compiler (like AC_PROG_LIBTOOL) to avoid autoconf errors.
  13 AC_USE_SYSTEM_EXTENSIONS
  14 AM_INIT_AUTOMAKE([-Wall foreign 1.10 tar-pax no-dist-gzip dist-xz subdir-objects])
  15
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  17                             [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  18 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  19
  20 AC_CONFIG_SRCDIR([sys-utils/mount.c])
  21 AC_PREFIX_DEFAULT([/usr])
  22
  23 dnl version details from <major>.<minor>[-<suffix>]
  24 PACKAGE_VERSION_MAJOR=$(echo $PACKAGE_VERSION | awk -F. '{print $1}')
  25 PACKAGE_VERSION_MINOR=$(echo $PACKAGE_VERSION | awk -F. '{
  26                                                    sub("-.*","",$2); print $2}')
  27 PACKAGE_VERSION_RELEASE=$(echo $PACKAGE_VERSION | awk -F. '{
  28                      sub("-.*","",$3); print $3 ~ /^@<:@0-9@:>@+$/ ? $3 : 0}')
  29
  30 dnl libblkid version
  31 LIBBLKID_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  32 LIBBLKID_DATE="06-Nov-2018"
  33 LIBBLKID_LT_MAJOR=1
  34 LIBBLKID_LT_MINOR=1
  35 LIBBLKID_LT_MICRO=0
  36 LIBBLKID_VERSION_INFO=`expr $LIBBLKID_LT_MAJOR + $LIBBLKID_LT_MINOR`:$LIBBLKID_LT_MICRO:$LIBBLKID_LT_MINOR
  37
  38 dnl libuuid version
  39 LIBUUID_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  40 LIBUUID_LT_MAJOR=1
  41 LIBUUID_LT_MINOR=3
  42 LIBUUID_LT_MICRO=0
  43 LIBUUID_VERSION_INFO=`expr $LIBUUID_LT_MAJOR + $LIBUUID_LT_MINOR`:$LIBUUID_LT_MICRO:$LIBUUID_LT_MINOR
  44
  45 dnl libmount version
  46 LIBMOUNT_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  47 LIBMOUNT_LT_MAJOR=1
  48 LIBMOUNT_LT_MINOR=1
  49 LIBMOUNT_LT_MICRO=0
  50 LIBMOUNT_VERSION_INFO=`expr $LIBMOUNT_LT_MAJOR + $LIBMOUNT_LT_MINOR`:$LIBMOUNT_LT_MICRO:$LIBMOUNT_LT_MINOR
  51
  52 dnl libsmartcols version
  53 LIBSMARTCOLS_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  54 LIBSMARTCOLS_LT_MAJOR=1
  55 LIBSMARTCOLS_LT_MINOR=1
  56 LIBSMARTCOLS_LT_MICRO=0
  57 LIBSMARTCOLS_VERSION_INFO=`expr $LIBSMARTCOLS_LT_MAJOR + $LIBSMARTCOLS_LT_MINOR`:$LIBSMARTCOLS_LT_MICRO:$LIBSMARTCOLS_LT_MINOR
  58
  59 dnl libfdisk version
  60 LIBFDISK_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  61 LIBFDISK_LT_MAJOR=1
  62 LIBFDISK_LT_MINOR=1
  63 LIBFDISK_LT_MICRO=0
  64 LIBFDISK_VERSION_INFO=`expr $LIBFDISK_LT_MAJOR + $LIBFDISK_LT_MINOR`:$LIBFDISK_LT_MICRO:$LIBFDISK_LT_MINOR
  65
  66 # Check whether exec_prefix=/usr:
  67 AS_CASE([$exec_prefix:$prefix],
  68 [NONE:NONE | NONE:/usr | /usr:*],
  69   [AC_MSG_NOTICE([Default --exec-prefix detected.])
  70    AS_CASE([$bindir],  ['${exec_prefix}/bin'],  [bindir=/bin;   AC_MSG_NOTICE([  --bindir defaults to /bin])  ])
  71    AS_CASE([$sbindir], ['${exec_prefix}/sbin'], [sbindir=/sbin; AC_MSG_NOTICE([  --sbindir defaults to /sbin])])
  72    AS_CASE([$libdir],  ['${exec_prefix}/lib'],  [libdir=/lib;   AC_MSG_NOTICE([  --libdir defaults to /lib])  ])
  73    AS_CASE([$libdir],  ['${exec_prefix}/lib64'],[libdir=/lib64; AC_MSG_NOTICE([  --libdir defaults to /lib64])  ])
  74   ]
  75 )
  76
  77
  78 # default for old versions without $runstatedir
  79 AS_IF([test x"$runstatedir" = x], [runstatedir='${localstatedir}/run'])
  80
  81 # our default if $localstatedir unchanged
  82 AS_CASE([$localstatedir:$runstatedir],
  83  [NONE:'${localstatedir}/run' | /var:'${localstatedir}/run' | NONE:'/run' ],
  84    [runstatedir=/run; AC_MSG_NOTICE([  --runstatedir defaults to /run])]
  85 )
  86
  87 AC_SUBST([runstatedir])
  88
  89
  90 # The original default values of {bin,sbin,lib}dir
  91 usrbin_execdir='${exec_prefix}/bin'
  92 AC_SUBST([usrbin_execdir])
  93
  94 usrsbin_execdir='${exec_prefix}/sbin'
  95 AC_SUBST([usrsbin_execdir])
  96
  97 AS_CASE([$libdir],
  98  ['${exec_prefix}/'* | '${prefix}/'* | /usr/* | "${prefix}"/* ],
  99    [usrlib_execdir=$libdir],
 100  [usrlib_execdir='${exec_prefix}'$libdir]
 101 )
 102 AC_SUBST([usrlib_execdir])
 103
 104
 105 AM_PROG_CC_C_O
 106 AC_PROG_MKDIR_P
 107 AC_PROG_CC_STDC
 108 AC_PROG_YACC
 109 AC_CANONICAL_HOST
 110 AC_C_CONST
 111 AC_C_VOLATILE
 112 AC_C_BIGENDIAN
 113
 114 dnl Compiler warnings
 115 UL_WARN_ADD([-fno-common])
 116 UL_WARN_ADD([-Wall])
 117 UL_WARN_ADD([-Werror=sequence-point])
 118 UL_WARN_ADD([-Wextra])
 119 UL_WARN_ADD([-Wextra-semi])
 120 UL_WARN_ADD([-Wembedded-directive])
 121 UL_WARN_ADD([-Wmissing-declarations])
 122 UL_WARN_ADD([-Wmissing-parameter-type])
 123 UL_WARN_ADD([-Wmissing-prototypes])
 124 UL_WARN_ADD([-Wno-missing-field-initializers])
 125 UL_WARN_ADD([-Wredundant-decls])
 126 UL_WARN_ADD([-Wsign-compare])
 127 UL_WARN_ADD([-Wtype-limits])
 128 UL_WARN_ADD([-Wuninitialized])
 129 UL_WARN_ADD([-Wunused-but-set-parameter])
 130 UL_WARN_ADD([-Wunused-but-set-variable])
 131 UL_WARN_ADD([-Wunused-parameter])
 132 UL_WARN_ADD([-Wunused-result])
 133 UL_WARN_ADD([-Wunused-variable])
 134 UL_WARN_ADD([-Wnested-externs])
 135 UL_WARN_ADD([-Wpointer-arith])
 136 UL_WARN_ADD([-Wstrict-prototypes])
 137 UL_WARN_ADD([-Wformat-security])
 138 UL_WARN_ADD([-Wimplicit-function-declaration])
 139 UL_WARN_ADD([-Wdiscarded-qualifiers])
 140 AC_SUBST([WARN_CFLAGS])
 141
 142 UL_WARN_ADD([-Wno-clobbered], [BSD_WARN_CFLAGS])
 143 AC_SUBST([BSD_WARN_CFLAGS])
 144
 145 UL_WARN_ADD([-Wno-cast-function-type], [PYTHON_WARN_CFLAGS])
 146 AC_SUBST([PYTHON_WARN_CFLAGS])
 147
 148 UL_WARN_ADD([-Wno-unused-parameter], [NO_UNUSED_WARN_CFLAGS])
 149 AC_SUBST([NO_UNUSED_WARN_CFLAGS])
 150
 151
 152 AC_ARG_ENABLE([asan],
 153   AS_HELP_STRING([--enable-asan], [compile with Address Sanitizer]),
 154   [], [enable_asan=no]
 155 )
 156 AS_IF([test "x$enable_asan" = xyes], [
 157   UL_WARN_ADD([-fsanitize=address])
 158 ])
 159
 160
 161
 162 dnl libtool-2
 163 LT_INIT
 164
 165 dnl check supported linker flags
 166 AX_CHECK_VSCRIPT
 167
 168 m4_ifndef([PKG_PROG_PKG_CONFIG],
 169   [m4_fatal([Could not locate the pkg-config autoconf
 170     macros. These are usually located in /usr/share/aclocal/pkg.m4.
 171     If your macros are in a different location, try setting the
 172     environment variable AL_OPTS="-I/other/macro/dir" before running
 173     ./autogen.sh or autoreconf again. Make sure pkg-config is installed.])])
 174 PKG_PROG_PKG_CONFIG
 175
 176 GTK_DOC_CHECK([1.10])
 177 AC_PATH_PROG([XSLTPROC], [xsltproc])
 178
 179 linux_os=no
 180 bsd_os=no
 181 AS_CASE([${host_os}],
 182   [*linux*],
 183      [linux_os=yes],
 184   [*darwin*],
 185      [darwin_os=yes],
 186   [*bsd*],
 187      [bsd_os=yes])
 188 AM_CONDITIONAL([LINUX], [test "x$linux_os" = xyes])
 189 AM_CONDITIONAL([DARWIN], [test "x$darwin_os" = xyes])
 190 AM_CONDITIONAL([BSD], [test "x$bsd_os" = xyes])
 191
 192 AS_IF([test  "x$darwin_os" = xyes], [
 193   AC_DEFINE([_DARWIN_C_SOURCE], [1], [Enable MAP_ANON in sys/mman.h on Mac OS X])
 194 ])
 195
 196 dnl define ARCH_<NAME> conditionals
 197 UL_SET_ARCH([I86], [i?86-*])
 198 UL_SET_ARCH([86_64], [x86_64*])
 199 UL_SET_ARCH([IA64], [ia64*])
 200 UL_SET_ARCH([S390], [s390*])
 201 UL_SET_ARCH([SPARC], [sparc*])
 202 UL_SET_ARCH([PPC], [ppc*|powerpc*])
 203 UL_SET_ARCH([M68K], [m68*])
 204 UL_SET_ARCH([MIPS], [mips*])
 205 UL_SET_ARCH([HPPA], [hppa*|parisc*])
 206
 207 AC_SYS_LARGEFILE
 208 AC_HEADER_ASSERT
 209 AC_STRUCT_TIMEZONE
 210
 211 dnl Don't forget to maintain alternatively allowed versions in autogen.sh!
 212 AM_GNU_GETTEXT_VERSION([0.18.3])
 213 AM_GNU_GETTEXT([external])
 214
 215 AS_IF([test -d "$srcdir/po"], [
 216   ALL_LINGUAS=`cd $srcdir/po > /dev/null && echo *.po | sed 's/\.po//g'`
 217 ], [
 218   ALL_LINGUAS="af am ar as be bg bn_IN bn ca cs cy da de el en_GB es et eu_ES fa fi fr gl gu he hi hr hu hy id is it ja ka kn ko ku lo lt lv mk ml mr ms my nb nl nn no nso or pa pl pt_BR pt ro ru si sk sl sq sr@Latn sr sv ta te th tr uk ur vi zh_CN zh_TW zu"
 219 ])
 220
 221 AC_CHECK_HEADERS([linux/compiler.h linux/blkpg.h linux/major.h], [], [], [
 222 #ifdef HAVE_LINUX_COMPILER_H
 223 #include <linux/compiler.h>
 224 #endif
 225 ])
 226 AC_CHECK_HEADERS([ \
 227         asm/io.h \
 228         err.h \
 229         errno.h \
 230         fcntl.h \
 231         getopt.h \
 232         inttypes.h \
 233         lastlog.h \
 234         libutil.h \
 235         linux/btrfs.h \
 236         linux/cdrom.h \
 237         linux/falloc.h \
 238         linux/watchdog.h \
 239         linux/fd.h \
 240         linux/raw.h \
 241         linux/tiocl.h \
 242         linux/version.h \
 243         linux/securebits.h \
 244         linux/net_namespace.h \
 245         locale.h \
 246         mntent.h \
 247         net/if.h \
 248         net/if_dl.h \
 249         netinet/in.h \
 250         paths.h \
 251         pty.h \
 252         security/pam_appl.h \
 253         stdint.h \
 254         stdio_ext.h \
 255         stdlib.h \
 256         endian.h \
 257         byteswap.h \
 258         sys/endian.h \
 259         sys/disk.h \
 260         sys/disklabel.h \
 261         sys/file.h \
 262         sys/io.h \
 263         sys/ioccom.h \
 264         sys/ioctl.h \
 265         sys/mkdev.h \
 266         sys/mount.h \
 267         sys/param.h \
 268         sys/prctl.h \
 269         sys/resource.h \
 270         sys/signalfd.h \
 271         sys/socket.h \
 272         sys/sockio.h \
 273         sys/stat.h \
 274         sys/sysmacros.h \
 275         sys/swap.h \
 276         sys/syscall.h \
 277         sys/time.h \
 278         sys/timex.h \
 279         sys/ttydefaults.h \
 280         sys/types.h \
 281         sys/ucred.h \
 282         sys/un.h \
 283         unistd.h \
 284         shadow.h \
 285         utmp.h \
 286         utmpx.h \
 287 ])
 288
 289 # There is a collision in old kernel-headers. The both files mount.h and fs.h
 290 # define MS_* macros. Fixed by kernel commit e462ec50cb5fad19f6003a3d8087f4a0945dd2b1.
 291 #
 292 AC_CHECK_HEADERS([linux/fs.h ], [], [],
 293  [#ifdef HAVE_SYS_MOUNT_H
 294    # include <linux/fs.h>
 295    # include <sys/mount.h>
 296   #endif
 297 ])
 298
 299 AC_CHECK_HEADERS([linux/gsmmux.h ], [], [],
 300  [#ifdef LINUX_GSMMUX_H
 301    # include <linux/gsmmux.h>
 302    #endif
 303 ])
 304
 305 AC_CHECK_HEADERS([security/pam_misc.h],
 306                 [AM_CONDITIONAL([HAVE_LINUXPAM], [true])],
 307                 [AM_CONDITIONAL([HAVE_LINUXPAM], [false])], [
 308 #ifdef HAVE_SECURITY_PAM_APPL_H
 309 #include <security/pam_appl.h>
 310 #endif
 311 ])
 312
 313 AC_CHECK_HEADERS([linux/blkzoned.h])
 314
 315 AC_CHECK_HEADERS([security/openpam.h], [], [], [
 316 #ifdef HAVE_SECURITY_PAM_APPL_H
 317 #include <security/pam_appl.h>
 318 #endif
 319 ])
 320
 321 AC_CHECK_HEADERS([langinfo.h],
 322                 [AM_CONDITIONAL([HAVE_LANGINFO], [true])],
 323                 [AM_CONDITIONAL([HAVE_LANGINFO], [false])])
 324
 325 AC_MSG_CHECKING([whether langinfo.h defines ALTMON_x constants])
 326 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 327         #include <langinfo.h>
 328 ]], [[
 329         char *str;
 330         str = nl_langinfo (ALTMON_1);
 331         str = nl_langinfo (ALTMON_2);
 332         str = nl_langinfo (ALTMON_3);
 333         str = nl_langinfo (ALTMON_4);
 334         str = nl_langinfo (ALTMON_5);
 335         str = nl_langinfo (ALTMON_6);
 336         str = nl_langinfo (ALTMON_7);
 337         str = nl_langinfo (ALTMON_8);
 338         str = nl_langinfo (ALTMON_9);
 339         str = nl_langinfo (ALTMON_10);
 340         str = nl_langinfo (ALTMON_11);
 341         str = nl_langinfo (ALTMON_12);
 342 ]])], [
 343         AC_MSG_RESULT([yes])
 344         AC_DEFINE([HAVE_LANGINFO_ALTMON], [1],
 345                 [Define if langinfo.h defines ALTMON_x constants])
 346 ], [
 347         AC_MSG_RESULT([no])
 348 ])
 349
 350
 351 AC_MSG_CHECKING([whether langinfo.h defines _NL_ABALTMON_x constants])
 352 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 353         #include <langinfo.h>
 354 ]], [[
 355         char *str;
 356         str = nl_langinfo (_NL_ABALTMON_1);
 357         str = nl_langinfo (_NL_ABALTMON_2);
 358         str = nl_langinfo (_NL_ABALTMON_3);
 359         str = nl_langinfo (_NL_ABALTMON_4);
 360         str = nl_langinfo (_NL_ABALTMON_5);
 361         str = nl_langinfo (_NL_ABALTMON_6);
 362         str = nl_langinfo (_NL_ABALTMON_7);
 363         str = nl_langinfo (_NL_ABALTMON_8);
 364         str = nl_langinfo (_NL_ABALTMON_9);
 365         str = nl_langinfo (_NL_ABALTMON_10);
 366         str = nl_langinfo (_NL_ABALTMON_11);
 367         str = nl_langinfo (_NL_ABALTMON_12);
 368 ]])], [
 369         AC_MSG_RESULT([yes])
 370         AC_DEFINE([HAVE_LANGINFO_NL_ABALTMON], [1],
 371                 [Define if langinfo.h defines _NL_ABALTMON_x constants])
 372 ], [
 373         AC_MSG_RESULT([no])
 374 ])
 375
 376
 377 dnl Convert some ac_cv_header_* variables to have_*
 378 dnl
 379 have_linux_version_h=$ac_cv_header_linux_version_h
 380 have_linux_blkzoned_h=$ac_cv_header_linux_blkzoned_h
 381 have_linux_btrfs_h=$ac_cv_header_linux_btrfs_h
 382 have_linux_raw_h=$ac_cv_header_linux_raw_h
 383 have_linux_securebits_h=$ac_cv_header_linux_securebits_h
 384 have_linux_watchdog_h=$ac_cv_header_linux_watchdog_h
 385 have_security_pam_appl_h=$ac_cv_header_security_pam_appl_h
 386 have_security_pam_misc_h=$ac_cv_header_security_pam_misc_h
 387 have_security_openpam_h=$ac_cv_header_security_openpam_h
 388 have_shadow_h=$ac_cv_header_shadow_h
 389 have_sys_signalfd_h=$ac_cv_header_sys_signalfd_h
 390 have_utmpx_h=$ac_cv_header_utmpx_h
 391
 392 AS_CASE([$linux_os:$have_linux_version_h],
 393   [yes:no],
 394     [AC_MSG_ERROR([kernel headers required on Linux])]
 395 )
 396
 397 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 398 #include <time.h>
 399 #include <unistd.h>
 400 ]], [[
 401     int a = 0;
 402     struct tm *tm = localtime(0);
 403     if (a == -1)  /* false */
 404         sleep(tm->tm_gmtoff);
 405 ]])],
 406 [AC_DEFINE([HAVE_TM_GMTOFF], [1], [Does struct tm have a field tm_gmtoff?])
 407 ])
 408
 409 AC_CHECK_MEMBERS([struct termios.c_line],,,
 410     [[#include <termios.h>]])
 411
 412 AC_CHECK_MEMBERS([struct stat.st_mtim.tv_nsec],,,
 413         [#include <sys/stat.h>])
 414
 415 AC_CHECK_DECLS([_NL_TIME_WEEK_1STDAY],[],[],[[#include <langinfo.h>]])
 416
 417 AC_CHECK_DECL([llseek],
 418         [AC_DEFINE([HAVE_LLSEEK_PROTOTYPE], [1],
 419                         [Define to 1 if have llseek prototype])],
 420         [],
 421         [#include <unistd.h>])
 422
 423 AC_CHECK_DECL([lseek64],
 424         [AC_DEFINE([HAVE_LSEEK64_PROTOTYPE], [1],
 425                         [Define to 1 if have lseek64 prototype])],
 426         [],
 427         [#define _LARGEFILE_SOURCE
 428          #define _LARGEFILE64_SOURCE
 429          #include <unistd.h>])
 430
 431 AC_CHECK_DECL([environ],
 432         [AC_DEFINE([HAVE_ENVIRON_DECL], [1],
 433                 [Define to 1 if have **environ prototype])],
 434 )
 435
 436 AC_CHECK_DECL([strsignal],
 437         [AC_DEFINE([HAVE_STRSIGNAL_DECL], [1],
 438                 [Define to 1 if have strsignal function prototype])],
 439 )
 440
 441 AC_CHECK_DECL([TIOCGLCKTRMIOS],
 442               [have_tiocglcktrmios=yes], [have_tiocglcktrmios=no],
 443               [#include <sys/ioctl.h>])
 444 AC_CHECK_DECL([SOCK_CLOEXEC],
 445               [have_sock_cloexec=yes], [have_sock_cloexec=no],
 446               [#include <sys/types.h>
 447                #include <sys/socket.h>])
 448 AC_CHECK_DECL([SOCK_NONBLOCK],
 449               [have_sock_nonblock=yes], [have_sock_nonblock=no],
 450               [#include <sys/types.h>
 451                #include <sys/socket.h>])
 452 AC_CHECK_DECL([SO_PASSCRED],
 453               [have_so_passcred=yes], [have_so_passcred=no],
 454               [#include <sys/types.h>
 455                #include <sys/socket.h>])
 456
 457 AC_CHECK_FUNCS([ \
 458         clearenv \
 459         __fpurge \
 460         fpurge \
 461         __fpending \
 462         secure_getenv \
 463         __secure_getenv \
 464         eaccess \
 465         err \
 466         errx \
 467         explicit_bzero \
 468         fsync \
 469         utimensat \
 470         getdomainname \
 471         getdtablesize \
 472         getexecname \
 473         getmntinfo \
 474         getrandom \
 475         getrlimit \
 476         getsgnam \
 477         inotify_init \
 478         jrand48 \
 479         lchown \
 480         llseek \
 481         lseek64 \
 482         mempcpy \
 483         mkostemp \
 484         nanosleep \
 485         ntp_gettime \
 486         personality \
 487         posix_fadvise \
 488         prctl \
 489         qsort_r \
 490         rpmatch \
 491         scandirat \
 492         setprogname \
 493         setresgid \
 494         setresuid \
 495         sched_setattr \
 496         sched_setscheduler \
 497         sigqueue \
 498         srandom \
 499         strnchr \
 500         strndup \
 501         strnlen \
 502         sysconf \
 503         sysinfo \
 504         timegm \
 505         usleep \
 506         vwarnx \
 507         warn \
 508         warnx \
 509 ])
 510 AC_FUNC_FSEEKO
 511
 512 AC_CHECK_FUNCS([openat fstatat unlinkat], [have_openat=yes], [have_openat=no])
 513 AC_CHECK_FUNCS([ioperm iopl], [have_io=yes])
 514 AC_CHECK_FUNCS([futimens], [have_futimens=yes])
 515 AC_CHECK_FUNCS([inotify_init1], [have_inotify_init1=yes])
 516 AC_CHECK_FUNCS([open_memstream], [have_open_memstream=yes],[have_open_memstream=no])
 517 AC_CHECK_FUNCS([reboot], [have_reboot=yes],[have_reboot=no])
 518 AC_CHECK_FUNCS([updwtmpx updwtmpx], [have_gnu_utmpx=yes], [have_gnu_utmpx=no])
 519 AC_CHECK_FUNCS([getusershell], [have_getusershell=yes],[have_getusershell=no])
 520
 521 AM_CONDITIONAL([HAVE_OPENAT], [test "x$have_openat" = xyes])
 522
 523 have_setns_syscall="yes"
 524 UL_CHECK_SYSCALL([setns])
 525 AS_IF([test "x$ul_cv_syscall_setns" = xno], [
 526    have_setns_syscall="no"
 527 ])
 528
 529 AC_CHECK_FUNCS([isnan], [],
 530         [AC_CHECK_LIB([m], [isnan], [MATH_LIBS="-lm"])]
 531         [AC_CHECK_LIB([m], [__isnan], [MATH_LIBS="-lm"])]
 532 )
 533 AC_SUBST([MATH_LIBS])
 534
 535
 536 dnl lib/mononotic.c may require -lrt
 537 AC_CHECK_FUNCS([clock_gettime], [],
 538         [AC_CHECK_LIB([rt], [clock_gettime], [REALTIME_LIBS="-lrt"])]
 539 )
 540
 541 have_timer="no"
 542 AC_CHECK_FUNCS([timer_create],
 543         [have_timer="yes"],
 544         [AC_CHECK_LIB([rt], [timer_create], [
 545                 have_timer="yes"
 546                 REALTIME_LIBS="-lrt"
 547                 AC_DEFINE_UNQUOTED([HAVE_TIMER_CREATE], [1], [Define if timer_create exist in -lrt])
 548         ],[
 549                 AC_SEARCH_LIBS([timer_create], [rt], [
 550                         AC_MSG_RESULT(yes)
 551                         have_timer="yes"
 552                         REALTIME_LIBS="-lrt -lpthread"
 553                         AC_DEFINE_UNQUOTED([HAVE_TIMER_CREATE], [1], [Define if timer_create exist in -lrt -lpthread])
 554                 ],[], [-lpthread]
 555                 )
 556         ])]
 557 )
 558
 559 AC_SUBST([REALTIME_LIBS])
 560
 561
 562 AC_CHECK_LIB([rtas], [rtas_get_sysparm], [
 563         RTAS_LIBS="-lrtas"
 564         AC_DEFINE_UNQUOTED([HAVE_LIBRTAS], [1], [Define if librtas exists]), [],
 565 ])
 566 AC_SUBST([RTAS_LIBS])
 567
 568
 569 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 570                 AC_DEFINE_UNQUOTED([HAVE_SA_LEN], [1], [Define if struct sockaddr contains sa_len]), [],
 571         [#include <sys/types.h>
 572          #include <sys/socket.h>])
 573
 574 SOCKET_LIBS=
 575 AC_SEARCH_LIBS([socket], [socket],
 576         [AS_IF([test x"$ac_cv_search_socket" != x"none required"],
 577                 [SOCKET_LIBS="$SOCKET_LIBS -lsocket"])
 578 ])
 579 AC_SUBST([SOCKET_LIBS])
 580
 581
 582 have_dirfd=no
 583 AC_CHECK_FUNCS([dirfd], [have_dirfd=yes], [have_dirfd=no])
 584 AS_IF([test x"$have_dirfd" = xno], [
 585         AC_CHECK_DECLS([dirfd],
 586                 [have_dirfd=yes], [have_dirfd=no],
 587                 [#include <sys/types.h>
 588                  #include <dirent.h>])
 589 ])
 590
 591 have_ddfd=no
 592 AS_IF([test x"$have_dirfd" = xno], [
 593         AC_CHECK_MEMBERS([DIR.dd_fd],
 594                 [have_ddfd=yes], [have_ddfd=no],
 595                 [#include <sys/types.h>
 596                  #include <dirent.h>])
 597 ])
 598
 599 AS_CASE([$have_dirfd:$have_ddfd],
 600   [no:no],
 601     [AC_MSG_ERROR([cannot find a method to get filedescriptor of directory])]
 602 )
 603
 604
 605 AC_MSG_CHECKING([whether program_invocation_short_name is defined])
 606 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 607         #include <errno.h>
 608 ]], [[
 609         program_invocation_short_name = "test";
 610 ]])], [
 611         AC_MSG_RESULT([yes])
 612         AC_DEFINE([HAVE_PROGRAM_INVOCATION_SHORT_NAME], [1],
 613                 [Define if program_invocation_short_name is defined])
 614 ], [
 615         AC_MSG_RESULT([no])
 616 ])
 617
 618
 619 AC_MSG_CHECKING([whether __progname is defined])
 620 AC_LINK_IFELSE([AC_LANG_PROGRAM([extern char *__progname;],
 621            [if (*__progname == 0) return 1;])],
 622            AC_DEFINE([HAVE___PROGNAME], [1], [Define if __progname is defined])
 623            AC_MSG_RESULT([yes]),
 624            AC_MSG_RESULT([no]))
 625
 626 dnl Static compilation
 627 m4_define([UL_STATIC_PROGRAMS], [losetup, mount, umount, fdisk, sfdisk, blkid, nsenter, unshare])
 628
 629 AC_ARG_ENABLE([static-programs],
 630   [AS_HELP_STRING([--enable-static-programs=LIST],
 631       [link static the programs in LIST (comma-separated,
 632       supported for ]m4_defn([UL_STATIC_PROGRAMS])[)])])
 633
 634 AS_CASE([$enable_static_programs],
 635   [yes],
 636     [enable_static_programs=m4_quote(UL_STATIC_PROGRAMS)],
 637   [no],
 638     [enable_static_programs=]
 639 )
 640
 641 dnl Set all the individual AM_CONDITIONALs
 642 m4_foreach([UL_PRG], m4_defn([UL_STATIC_PROGRAMS]), [
 643   AS_CASE([,$enable_static_programs,],
 644    [*,UL_PRG,*], [static_[]UL_PRG=yes]
 645   )
 646   AS_IF([test "x$static_[]UL_PRG" = xyes], [AC_MSG_NOTICE([enable static build: UL_PRG.])])
 647   AM_CONDITIONAL([HAVE_STATIC_]m4_toupper(UL_PRG),
 648     [test "x$static_[]UL_PRG" = xyes])
 649 ])
 650
 651
 652 AC_ARG_ENABLE([all-programs],
 653   AS_HELP_STRING([--disable-all-programs], [disable everything, might be overridden by --enable-<name>]),
 654   [], [enable_all_programs=undefined]
 655 )
 656
 657 AS_CASE([$enable_all_programs],
 658   [yes], [AC_MSG_WARN([force to build all programs by default])
 659           ul_default_estate=check],
 660   [no],  [AC_MSG_WARN([disable all programs by default])
 661           ul_default_estate=no]
 662 )
 663
 664
 665 AX_CHECK_TLS
 666
 667 AC_DEFUN([UL_SCANF_TYPE_MODIFIER], [dnl
 668 # include <stdio.h>
 669 # include <stdlib.h>
 670 int main()
 671 {
 672         int i;
 673         int rc = 1;
 674         char *s;
 675         i = sscanf("x", $1, &s);
 676         if (i == 1  && *s == 'x')
 677                 rc = 0;
 678         free(s);
 679         return rc;
 680 }])
 681
 682 AC_CACHE_VAL([scanf_cv_alloc_modifier],
 683   AC_RUN_IFELSE([AC_LANG_SOURCE([UL_SCANF_TYPE_MODIFIER(["%ms"])])],
 684     [scanf_cv_alloc_modifier=ms],
 685     AC_RUN_IFELSE([AC_LANG_SOURCE([UL_SCANF_TYPE_MODIFIER(["%as"])])],
 686       [scanf_cv_alloc_modifier=as],
 687       [scanf_cv_alloc_modifier=no]
 688     )
 689     ,
 690
 691     [AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 692      #include <stdio.h>
 693      #include <unistd.h>
 694
 695      #if defined(__GLIBC__) && !defined(__UCLIBC__)
 696
 697      #if !(__GLIBC_PREREQ(2, 7))
 698      #error %m is not available
 699      #endif
 700
 701      #elif defined(_POSIX_VERSION)
 702
 703      #if _POSIX_VERSION < 200809L
 704      #error %m is not available
 705      #endif
 706
 707      #else
 708      #error Your C-library is not supported.
 709      #endif
 710      ])],
 711     [scanf_cv_alloc_modifier=ms],
 712     [scanf_cv_alloc_modifier=no])]
 713   )
 714 )
 715
 716 AC_MSG_CHECKING([scanf string alloc modifiers])
 717 AS_CASE([$scanf_cv_alloc_modifier],
 718   [ms],
 719     [AC_MSG_RESULT([(%ms) yes])
 720      AC_DEFINE([HAVE_SCANF_MS_MODIFIER], [1], [scanf %ms modifier])
 721      have_scanf_alloc_modifier=yes],
 722   [as],
 723     [AC_MSG_RESULT([(%as) yes])
 724      have_scanf_alloc_modifier=yes
 725      AC_DEFINE([HAVE_SCANF_AS_MODIFIER], [1], [scanf %as modifier])],
 726   [AC_MSG_RESULT([no])
 727    have_scanf_alloc_modifier=no]
 728 )
 729
 730
 731 AC_ARG_WITH([util], AS_HELP_STRING([--without-util], [compile without libutil]),
 732   [], [with_util=auto]
 733 )
 734 AS_IF([test "x$with_util" = xno], [
 735   AM_CONDITIONAL([HAVE_UTIL], [false])
 736   have_util=no
 737 ], [
 738   UL_CHECK_LIB([util], [openpty])
 739 ])
 740
 741
 742 AC_CHECK_TYPES([union semun], [], [], [[
 743 #include <sys/sem.h>
 744 ]])
 745 AC_CHECK_TYPES([loff_t])
 746
 747
 748 AC_ARG_ENABLE([widechar],
 749   AS_HELP_STRING([--disable-widechar], [do not compile wide character support]),
 750   [], [enable_widechar=check]
 751 )
 752 UL_BUILD_INIT([widechar])
 753 UL_REQUIRES_COMPILE([widechar], [[
 754   #include <wchar.h>
 755   #include <wctype.h>
 756   #include <stdio.h>
 757   ]], [[
 758     wchar_t wc;
 759     wint_t w;
 760     w = fgetwc(stdin);
 761     if (w == WEOF) exit(1);
 762     wc = w;
 763     fputwc(wc,stdout);
 764   ]],
 765   [wchar_t support])
 766
 767 AS_IF([test "x$build_widechar" = xyes ], [
 768   AC_DEFINE([HAVE_WIDECHAR], [1], [Do we have wide character support?])
 769 ])
 770
 771
 772 AC_CHECK_TYPES([cpu_set_t], [have_cpu_set_t=yes], [], [[
 773 #include <sched.h>
 774 ]])
 775
 776 AM_CONDITIONAL([HAVE_CPU_SET_T], [test "x$have_cpu_set_t" = xyes])
 777
 778 AC_CHECK_TYPES([sighandler_t], [], [], [[
 779 #include <signal.h>
 780 ]])
 781
 782 AC_CHECK_DECLS([CPU_ALLOC], [], [], [[
 783 #include <sched.h>
 784 ]])
 785
 786 # on Solaris, you can't mix and match standards, since we use c99
 787 # aparently at this stage, XOPEN_SOURCE will conflict.  As workaround,
 788 # check for crypt.h and use that without XOPEN_SOURCE.
 789 AC_CHECK_HEADERS([crypt.h])
 790 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 791 #ifdef HAVE_CRYPT_H
 792 #include <crypt.h>
 793 #else
 794 #define _XOPEN_SOURCE
 795 #include <unistd.h>
 796 #endif
 797 ]], [[
 798 char *c = crypt("abc","pw");
 799 ]])],[],[
 800   LIBS="$LIBS -lcrypt"
 801   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 802   #ifdef HAVE_CRYPT_H
 803   #include <crypt.h>
 804   #else
 805   #define _XOPEN_SOURCE
 806   #include <unistd.h>
 807   #endif
 808   ]], [[
 809   char *c = crypt("abc","pw");
 810   ]])],[
 811   AC_DEFINE([HAVE_LIBCRYPT], [1], [Do we need -lcrypt?])
 812   have_libcrypt=yes
 813   ],[
 814   AC_MSG_ERROR([crypt() is not available])
 815   ])
 816 ])
 817 AM_CONDITIONAL([HAVE_LIBCRYPT], [test "x$have_libcrypt" = xyes])
 818
 819
 820 AC_ARG_WITH([selinux],
 821   AS_HELP_STRING([--with-selinux], [compile with SELinux support]),
 822   [], [with_selinux=no]
 823 )
 824
 825 AS_IF([test "x$with_selinux" = xno], [
 826   AM_CONDITIONAL([HAVE_SELINUX], [false])
 827 ], [
 828   PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.0],
 829         [AC_DEFINE([HAVE_LIBSELINUX], [1], [Define if SELinux is available])
 830          UL_PKG_STATIC([SELINUX_LIBS_STATIC], [libselinux])
 831          AM_CONDITIONAL([HAVE_SELINUX], [true])
 832          have_selinux=yes],
 833         [have_selinux=no])
 834
 835   AS_CASE([$with_selinux:$have_selinux],
 836     [yes:no], [AC_MSG_ERROR([SELinux selected but libselinux not found or too old])]
 837   )
 838
 839   AS_IF([test "x$have_selinux" = xyes], [
 840     UL_SET_FLAGS([], [], [$SELINUX_LIBS])
 841     # This function is missing in old libselinux 1.xx versions
 842     AC_CHECK_FUNCS([security_get_initial_context])
 843     UL_RESTORE_FLAGS
 844   ])
 845 ])
 846 AC_SUBST([SELINUX_LIBS])
 847 AC_SUBST([SELINUX_LIBS_STATIC])
 848
 849
 850 AC_ARG_WITH([audit],
 851   AS_HELP_STRING([--with-audit], [compile with audit support]),
 852   [], [with_audit=no]
 853 )
 854
 855 AS_IF([test "x$with_audit" = xno], [
 856   AM_CONDITIONAL([HAVE_AUDIT], [false])
 857 ], [
 858   UL_CHECK_LIB([audit], [audit_log_user_message])
 859   AS_CASE([$with_audit:$have_audit],
 860     [yes:no],
 861       [AC_MSG_ERROR([Audit selected but libaudit not found (or does not support audit_log_user_message())])]
 862   )
 863 ])
 864
 865 AC_ARG_WITH([udev], AS_HELP_STRING([--without-udev], [compile without udev support]),
 866   [], [with_udev=auto]
 867 )
 868
 869 AS_IF([test "x$with_udev" = xno], [
 870   AM_CONDITIONAL([HAVE_UDEV], [false])
 871 ], [
 872   UL_CHECK_LIB([udev], [udev_new])
 873   AS_CASE([$with_udev:$have_udev],
 874     [yes:no],
 875       [AC_MSG_ERROR([udev selected but libudev not found])]
 876   )
 877 ])
 878
 879
 880 dnl wide-char ncurses
 881 AC_ARG_WITH([ncursesw],
 882   AS_HELP_STRING([--without-ncursesw], [do not build with wide-char ncurses]),
 883   [], [with_ncursesw=auto]
 884 )
 885 have_ncursesw=no
 886 have_ncursesw_header=no
 887 AS_IF([test "x$with_ncursesw" != xno], [
 888   UL_NCURSES_CHECK([ncursesw])
 889   AS_IF([test "x$have_ncursesw" = xyes], [
 890     AC_CHECK_HEADERS([ncursesw/ncurses.h], [have_ncursesw_header=yes])
 891     AC_CHECK_HEADERS([ncursesw/term.h])
 892
 893     # Define HAVE_NCURSES_H only if check for HAVE_NCURSESW_NCURSES_H is
 894     # unsuccessful to avoid too many *_H permitations in config.h
 895     AS_IF([test "x$have_ncursesw_header" = xno], [
 896            AC_CHECK_HEADERS([ncurses.h], [have_ncursesw_header=yes])
 897            AC_CHECK_HEADERS([term.h])
 898     ])
 899     AS_IF([test "x$have_ncursesw_header" = xno], [have_ncursesw=no])
 900   ])
 901   AS_IF([test "x$have_ncursesw" = xyes], [
 902     CURSES_LIB_NAME="ncursesw"
 903     AC_DEFINE([HAVE_LIBNCURSESW], [1], [Define if ncursesw library available])
 904   ])
 905 ])
 906 AS_CASE([$with_ncursesw:$have_ncursesw],
 907   [yes:no], [AC_MSG_ERROR([ncursesw selected, but library not found])])
 908
 909
 910 dnl non-wide ncurses
 911 AC_ARG_WITH([ncurses],
 912   AS_HELP_STRING([--with-ncurses], [build with non-wide ncurses]),
 913   [], [with_ncurses=auto]
 914 )
 915 have_ncurses=no
 916 have_ncurses_header=no
 917 AS_CASE([$with_ncurses:$build_widechar],
 918   [yes:yes], [AC_MSG_ERROR([wide-char support enabled, but non-wide ncurses selects])])
 919
 920 AS_IF([test "x$have_ncursesw" = xno -a "x$with_ncurses" != xno ], [
 921   UL_NCURSES_CHECK([ncurses])
 922   AS_IF([test "x$have_ncurses" = xyes], [
 923     AC_CHECK_HEADERS([ncurses/ncurses.h], [have_ncurses_header=yes])
 924     AC_CHECK_HEADERS([ncurses/term.h])
 925
 926     # Define HAVE_NCURSES_H only if check for HAVE_NCURSES_NCURSES_H is
 927     # unsuccessful to avoid too many *_H permitations in config.h
 928     AS_IF([test "x$have_ncurses_header" = xno], [
 929            AC_CHECK_HEADERS([ncurses.h], [have_ncurses_header=yes])
 930            AC_CHECK_HEADERS([term.h])
 931     ])
 932     AS_IF([test "x$have_ncurses_header" = xno], [have_ncurses=no])
 933   ])
 934   AS_IF([test "x$have_ncurses" = xyes], [
 935     CURSES_LIB_NAME="ncurses"
 936     AC_DEFINE([HAVE_LIBNCURSES], [1], [Define if ncurses library available])
 937   ])
 938 ])
 939 AS_CASE([$with_ncurses:$have_ncurses],
 940   [yes:no], [AC_MSG_ERROR([ncurses selected, but library not found])])
 941
 942 AC_SUBST([NCURSES_CFLAGS])
 943 AC_SUBST([NCURSES_LIBS])
 944 AM_CONDITIONAL([HAVE_NCURSES], [test "x$have_ncursesw" = xyes -o  "x$have_ncurses" = xyes])
 945
 946
 947 AC_ARG_WITH([slang],
 948   AS_HELP_STRING([--with-slang], [compile cfdisk with slang rather than ncurses]),
 949   [], [with_slang=no]
 950 )
 951 have_slang=no
 952 AS_IF([test "x$with_slang" = xyes], [
 953   AC_CHECK_HEADERS([slang.h slang/slang.h])
 954   AC_CHECK_HEADERS([slcurses.h slang/slcurses.h],
 955                    [have_slang=yes], [], [
 956 #ifdef HAVE_SLANG_H
 957 #include <slang.h>
 958 #elif defined(HAVE_SLANG_SLANG_H)
 959 #include <slang/slang.h>
 960 #endif
 961 ])
 962   AS_IF([test "x$have_slang" = xno], [
 963     AC_MSG_ERROR([slang selected but slcurses.h not found])],
 964     [CURSES_LIB_NAME=slang
 965   ])
 966 ])
 967 AM_CONDITIONAL([HAVE_SLANG], [test "x$have_slang" = xyes])
 968
 969
 970 AS_IF([test "x$have_slang" = xyes -o "x$have_ncursesw" = xyes -o "x$have_ncurses" = xyes], [
 971         AC_CHECK_LIB([$CURSES_LIB_NAME], use_default_colors, [
 972                      AC_DEFINE(HAVE_USE_DEFAULT_COLORS, 1,
 973                                [Define if curses library has the use_default_colors().])
 974         ])
 975         AC_CHECK_LIB([$CURSES_LIB_NAME], resizeterm, [
 976                      AC_DEFINE(HAVE_RESIZETERM, 1,
 977                                [Define if curses library has the resizeterm().])
 978         ])
 979 ])
 980
 981
 982 AC_ARG_WITH([tinfo], AS_HELP_STRING([--without-tinfo], [compile without libtinfo]),
 983   [], [with_tinfo=auto]
 984 )
 985 have_tinfo=no
 986 have_tinfow=no
 987 AS_IF([test "x$with_tinfo" != xno], [
 988   AS_IF([test "x$have_ncursesw" = xyes], [
 989     UL_TINFO_CHECK([tinfow])
 990   ])
 991   AS_IF([test "x$have_tinfow" = xno], [
 992     UL_TINFO_CHECK([tinfo])
 993   ])
 994 ])
 995 AC_SUBST([TINFO_LIBS])
 996 AC_SUBST([TINFO_LIBS_STATIC])
 997 AC_SUBST([TINFO_CFLAGS])
 998 AM_CONDITIONAL([HAVE_TINFO], [test "x$have_tinfo" = xyes -o "x$have_tinfow" = xyes])
 999 AS_IF([test "x$have_tinfo" = xyes -o "x$have_tinfow" = xyes], [
1000   AC_DEFINE(HAVE_LIBTINFO, 1, [Define if libtinfo or libtinfow available.])
1001 ])
1002
1003
1004 AC_ARG_WITH([readline],
1005   AS_HELP_STRING([--without-readline], [do not build with GNU Readline support]),
1006   [], [with_readline=auto]
1007 )
1008
1009 AS_IF([test "x$with_readline" = xno], [
1010   AM_CONDITIONAL([HAVE_READLINE], [false])
1011 ], [
1012   UL_CHECK_LIB([readline], [readline])
1013   AS_CASE([$with_readline:$have_readline],
1014     [yes:no],
1015       [AC_MSG_ERROR([readline selected but libreadline not found ])],
1016     [*:yes],
1017       [READLINE_LIBS="-lreadline"
1018        READLINE_LIBS_STATIC="-lreadline $TINFO_LIBS_STATIC"]
1019   )
1020 ])
1021 AC_SUBST([READLINE_LIBS])
1022 AC_SUBST([READLINE_LIBS_STATIC])
1023
1024
1025 AC_ARG_WITH([utempter],
1026   AS_HELP_STRING([--with-utempter], [compile script(1) with libutempter]),
1027   [], [with_utempter=no]
1028 )
1029
1030 AS_IF([test "x$with_utempter" = xyes], [
1031   UL_CHECK_LIB([utempter], [utempter_add_record])
1032   AS_IF([test "x$have_utempter" = xno], [
1033     AC_MSG_ERROR([utempter selected but libutempter not found])
1034   ])
1035 ], [
1036   AM_CONDITIONAL([HAVE_UTEMPTER], [false])
1037 ])
1038
1039
1040 dnl
1041 dnl libuuid
1042 dnl
1043 AC_ARG_ENABLE([libuuid],
1044   AS_HELP_STRING([--disable-libuuid], [do not build libuuid and uuid utilities]),
1045   [], [UL_DEFAULT_ENABLE([libuuid], [yes])]
1046 )
1047 UL_BUILD_INIT([libuuid])
1048 AC_SUBST([LIBUUID_VERSION])
1049 AC_SUBST([LIBUUID_VERSION_INFO])
1050 AM_CONDITIONAL(BUILD_LIBUUID, test "x$build_libuuid" = xyes)
1051
1052 AC_ARG_ENABLE([libuuid-force-uuidd],
1053   AS_HELP_STRING([--enable-libuuid-force-uuidd], [support uuidd even though the daemon is not built]),
1054   [], [enable_libuuid_force_uuidd=no]
1055 )
1056
1057 AS_IF([test "x$build_libuuid" = xyes], [
1058   AC_DEFINE(HAVE_LIBUUID, 1, [Define to 1 if you have the -luuid.])
1059 ])
1060
1061 dnl
1062 dnl libblkid
1063 dnl
1064 AC_ARG_ENABLE([libblkid],
1065   AS_HELP_STRING([--disable-libblkid], [do not build libblkid and many related utilities]),
1066   [], [UL_DEFAULT_ENABLE([libblkid], [check])]
1067 )
1068 UL_BUILD_INIT([libblkid])
1069 UL_REQUIRES_HAVE([libblkid], [openat], [openat functions])
1070 AC_SUBST([LIBBLKID_DATE])
1071 AC_SUBST([LIBBLKID_VERSION])
1072 AC_SUBST([LIBBLKID_VERSION_INFO])
1073 AC_DEFINE_UNQUOTED([LIBBLKID_VERSION], ["$LIBBLKID_VERSION"], [libblkid version string])
1074 AC_DEFINE_UNQUOTED([LIBBLKID_DATE], ["$LIBBLKID_DATE"], [libblkid date string])
1075 AS_IF([test "x$build_libblkid" = xyes], [
1076   AC_DEFINE([HAVE_LIBBLKID], [1], [Define to 1 if you have the -lblkid.])
1077 ])
1078 AM_CONDITIONAL([BUILD_LIBBLKID], [test "x$build_libblkid" = xyes])
1079 AM_CONDITIONAL([BUILD_LIBBLKID_TESTS], [test "x$build_libblkid" = xyes -a "x$enable_static" = xyes])
1080
1081 dnl
1082 dnl libmount
1083 dnl
1084 AC_ARG_ENABLE([libmount],
1085   AS_HELP_STRING([--disable-libmount], [do not build libmount]),
1086   [], [UL_DEFAULT_ENABLE([libmount], [check])]
1087 )
1088 UL_BUILD_INIT([libmount])
1089 UL_REQUIRES_BUILD([libmount], [libblkid])
1090 UL_REQUIRES_HAVE([libmount], [scanf_alloc_modifier], [scanf string alloc modifier])
1091 AM_CONDITIONAL([BUILD_LIBMOUNT], [test "x$build_libmount" = xyes])
1092 AM_CONDITIONAL([BUILD_LIBMOUNT_TESTS], [test "x$build_libmount" = xyes -a "x$enable_static" = xyes])
1093 AS_IF([test "x$build_libmount" = xyes], [
1094   AC_DEFINE(HAVE_LIBMOUNT, 1, [Define if libmount available.])
1095   AS_IF([test "x$have_setns_syscall" = "xyes"], [
1096     AC_DEFINE([USE_LIBMOUNT_SUPPORT_NAMESPACES], [1], [Define to 1 if want to support namepaces.])
1097   ],[
1098     AC_MSG_WARN([libmount will be compiled without namespaces support])
1099   ])
1100 ])
1101
1102 AC_SUBST([LIBMOUNT_VERSION])
1103 AC_SUBST([LIBMOUNT_MAJOR_VERSION], $PACKAGE_VERSION_MAJOR)
1104 AC_SUBST([LIBMOUNT_MINOR_VERSION], $PACKAGE_VERSION_MINOR)
1105 AC_SUBST([LIBMOUNT_PATCH_VERSION], $PACKAGE_VERSION_RELEASE)
1106 AC_SUBST([LIBMOUNT_VERSION_INFO])
1107 AC_DEFINE_UNQUOTED([LIBMOUNT_VERSION], ["$LIBMOUNT_VERSION"], [libmount version string])
1108
1109 AC_ARG_ENABLE([libmount-support-mtab],
1110   AS_HELP_STRING([--enable-libmount-support-mtab], [support /etc/mtab (default is use /proc/self/mountinfo)]),
1111   [], [enable_libmount_support_mtab=no]
1112 )
1113
1114 AS_IF([test "x$enable_libmount_support_mtab" = xyes], [
1115   AC_DEFINE([USE_LIBMOUNT_SUPPORT_MTAB], [1], [Define to 1 if want to support mtab.])
1116 ])
1117
1118 dnl
1119 dnl libsmartcols
1120 dnl
1121 AC_ARG_ENABLE([libsmartcols],
1122   AS_HELP_STRING([--disable-libsmartcols], [do not build libsmartcols]),
1123   [], [UL_DEFAULT_ENABLE([libsmartcols], [yes])]
1124 )
1125 UL_BUILD_INIT([libsmartcols])
1126 AM_CONDITIONAL([BUILD_LIBSMARTCOLS], [test "x$build_libsmartcols" = xyes])
1127
1128 AC_SUBST([LIBSMARTCOLS_VERSION])
1129 AC_SUBST([LIBSMARTCOLS_VERSION_INFO])
1130 AC_DEFINE_UNQUOTED([LIBSMARTCOLS_VERSION], ["$LIBSMARTCOLS_VERSION"], [libsmartcols version string])
1131
1132
1133 dnl
1134 dnl libfdisk
1135 dnl
1136 AC_ARG_ENABLE([libfdisk],
1137   AS_HELP_STRING([--disable-libfdisk], [do not build libfdisk]),
1138   [], [UL_DEFAULT_ENABLE([libfdisk], [check])]
1139 )
1140 UL_BUILD_INIT([libfdisk])
1141 UL_REQUIRES_BUILD([libfdisk], [libuuid])
1142 AM_CONDITIONAL([BUILD_LIBFDISK], [test "x$build_libfdisk" = xyes])
1143 AM_CONDITIONAL([BUILD_LIBFDISK_TESTS], [test "x$build_libfdisk" = xyes -a "x$enable_static" = xyes])
1144
1145 AS_IF([test "x$build_libblkid" = xyes],
1146   [LIBFDISK_PC_REQUIRES="uuid blkid"],[LIBFDISK_PC_REQUIRES="uuid"])
1147 AC_SUBST([LIBFDISK_PC_REQUIRES])
1148
1149 AC_SUBST([LIBFDISK_VERSION])
1150 AC_SUBST([LIBFDISK_MAJOR_VERSION], $PACKAGE_VERSION_MAJOR)
1151 AC_SUBST([LIBFDISK_MINOR_VERSION], $PACKAGE_VERSION_MINOR)
1152 AC_SUBST([LIBFDISK_PATCH_VERSION], $PACKAGE_VERSION_RELEASE)
1153 AC_SUBST([LIBFDISK_VERSION_INFO])
1154 AC_DEFINE_UNQUOTED([LIBFDISK_VERSION], ["$LIBFDISK_VERSION"], [libfdisk version string])
1155
1156
1157 AC_ARG_ENABLE([fdisks],
1158   AS_HELP_STRING([--disable-fdisks], [do not build fdisk(8), sfdisk(8) and cfdisk(8)]),
1159   [], [UL_DEFAULT_ENABLE([fdisks], [check])]
1160 )
1161 enable_fdisk=$enable_fdisks
1162 enable_sfdisk=$enable_fdisks
1163 enable_cfdisk=$enable_fdisks
1164
1165 UL_BUILD_INIT([fdisk])
1166 UL_REQUIRES_HAVE([fdisk], [openat], [openat functions])
1167 UL_REQUIRES_BUILD([fdisk], [libfdisk])
1168 UL_REQUIRES_BUILD([fdisk], [libsmartcols])
1169 AM_CONDITIONAL([BUILD_FDISK], [test "x$build_fdisk" = xyes])
1170
1171
1172 UL_BUILD_INIT([sfdisk])
1173 UL_REQUIRES_HAVE([sfdisk], [openat], [openat functions])
1174 UL_REQUIRES_BUILD([sfdisk], [libfdisk])
1175 UL_REQUIRES_BUILD([sfdisk], [libsmartcols])
1176 AM_CONDITIONAL([BUILD_SFDISK], [test "x$build_sfdisk" = xyes])
1177
1178
1179 UL_BUILD_INIT([cfdisk])
1180 UL_REQUIRES_BUILD([cfdisk], [libfdisk])
1181 UL_REQUIRES_BUILD([cfdisk], [libsmartcols])
1182 UL_REQUIRES_HAVE([cfdisk], [open_memstream], [open_memstream function])
1183 UL_REQUIRES_HAVE([cfdisk], [ncursesw,slang,ncurses], [ncursesw, ncurses or slang library])
1184 AM_CONDITIONAL([BUILD_CFDISK], [test "x$build_cfdisk" = xyes])
1185
1186
1187 AC_ARG_ENABLE([mount],
1188   AS_HELP_STRING([--disable-mount], [do not build mount(8) and umount(8)]),
1189   [], [UL_DEFAULT_ENABLE([mount], [check])]
1190 )
1191 UL_BUILD_INIT([mount])
1192 UL_REQUIRES_LINUX([mount])
1193 UL_REQUIRES_BUILD([mount], [libmount])
1194 AM_CONDITIONAL([BUILD_MOUNT], [test "x$build_mount" = xyes])
1195
1196
1197 AC_ARG_ENABLE([losetup],
1198   AS_HELP_STRING([--disable-losetup], [do not build losetup]),
1199   [], [UL_DEFAULT_ENABLE([losetup], [check])]
1200 )
1201 UL_BUILD_INIT([losetup])
1202 UL_REQUIRES_LINUX([losetup])
1203 UL_REQUIRES_BUILD([losetup], [libsmartcols])
1204 AM_CONDITIONAL([BUILD_LOSETUP], [test "x$build_losetup" = xyes])
1205
1206 AC_ARG_ENABLE([zramctl],
1207   AS_HELP_STRING([--disable-zramctl], [do not build zramctl]),
1208   [], [UL_DEFAULT_ENABLE([zramctl], [check])]
1209 )
1210 UL_BUILD_INIT([zramctl])
1211 UL_REQUIRES_LINUX([zramctl])
1212 UL_REQUIRES_BUILD([zramctl], [libsmartcols])
1213 AM_CONDITIONAL([BUILD_ZRAMCTL], [test "x$build_zramctl" = xyes])
1214
1215 AC_ARG_ENABLE([fsck],
1216   AS_HELP_STRING([--disable-fsck], [do not build fsck]),
1217   [], [UL_DEFAULT_ENABLE([fsck], [check])]
1218 )
1219 UL_BUILD_INIT([fsck])
1220 UL_REQUIRES_BUILD([fsck], [libmount])
1221 AM_CONDITIONAL([BUILD_FSCK], [test "x$build_fsck" = xyes])
1222
1223
1224 AC_ARG_ENABLE([partx],
1225   AS_HELP_STRING([--disable-partx], [do not build addpart, delpart, partx]),
1226   [], [UL_DEFAULT_ENABLE([partx], [check])]
1227 )
1228 UL_BUILD_INIT([partx])
1229 UL_REQUIRES_LINUX([partx])
1230 UL_REQUIRES_BUILD([partx], [libblkid])
1231 UL_REQUIRES_BUILD([partx], [libsmartcols])
1232 AM_CONDITIONAL([BUILD_PARTX], [test "x$build_partx" = xyes])
1233
1234
1235 AC_ARG_ENABLE([uuidd],
1236   AS_HELP_STRING([--disable-uuidd], [do not build the uuid daemon]),
1237   [], [UL_DEFAULT_ENABLE([uuidd], [check])]
1238 )
1239 UL_BUILD_INIT([uuidd])
1240 UL_REQUIRES_BUILD([uuidd], [libuuid])
1241 UL_REQUIRES_HAVE([uuidd], [timer], [timer_create function])
1242 UL_REQUIRES_HAVE([uuidd], [sys_signalfd_h], [sys/signalfd.h header])
1243 AS_IF([test "x$build_uuidd" = xyes || test "x$enable_libuuid_force_uuidd" = xyes], [
1244   AC_DEFINE([HAVE_UUIDD], [1], [Define to 1 if you want to use uuid daemon.])
1245 ])
1246 AM_CONDITIONAL([BUILD_UUIDD], [test "x$build_uuidd" = xyes])
1247
1248
1249 UL_BUILD_INIT([uuidgen], [check])
1250 UL_REQUIRES_BUILD([uuidgen], [libuuid])
1251 AM_CONDITIONAL([BUILD_UUIDGEN], [test "x$build_uuidgen" = xyes])
1252
1253 UL_BUILD_INIT([uuidparse], [check])
1254 UL_REQUIRES_BUILD([uuidparse], [libuuid])
1255 UL_REQUIRES_BUILD([uuidparse], [libsmartcols])
1256 AM_CONDITIONAL([BUILD_UUIDPARSE], [test "x$build_uuidparse" = xyes])
1257
1258 UL_BUILD_INIT([blkid], [check])
1259 UL_REQUIRES_BUILD([blkid], [libblkid])
1260 AM_CONDITIONAL([BUILD_BLKID], [test "x$build_blkid" = xyes])
1261
1262 UL_BUILD_INIT([findfs], [check])
1263 UL_REQUIRES_BUILD([findfs], [libblkid])
1264 AM_CONDITIONAL([BUILD_FINDFS], [test "x$build_findfs" = xyes])
1265
1266 UL_BUILD_INIT([wipefs], [check])
1267 UL_REQUIRES_BUILD([wipefs], [libblkid])
1268 UL_REQUIRES_BUILD([wipefs], [libsmartcols])
1269 AM_CONDITIONAL([BUILD_WIPEFS], [test "x$build_wipefs" = xyes])
1270
1271 UL_BUILD_INIT([findmnt], [check])
1272 UL_REQUIRES_BUILD([findmnt], [libmount])
1273 UL_REQUIRES_BUILD([findmnt], [libblkid])
1274 UL_REQUIRES_BUILD([findmnt], [libsmartcols])
1275 AM_CONDITIONAL([BUILD_FINDMNT], [test "x$build_findmnt" = xyes])
1276
1277
1278 AC_ARG_ENABLE([mountpoint],
1279   AS_HELP_STRING([--disable-mountpoint], [do not build mountpoint]),
1280   [], [UL_DEFAULT_ENABLE([mountpoint], [check])]
1281 )
1282 UL_BUILD_INIT([mountpoint])
1283 UL_REQUIRES_BUILD([mountpoint], [libmount])
1284 AM_CONDITIONAL([BUILD_MOUNTPOINT], [test "x$build_mountpoint" = xyes])
1285
1286
1287 AC_ARG_ENABLE([fallocate],
1288   AS_HELP_STRING([--disable-fallocate], [do not build fallocate]),
1289   [], [UL_DEFAULT_ENABLE([fallocate], [check])]
1290 )
1291 UL_BUILD_INIT([fallocate])
1292 UL_REQUIRES_LINUX([fallocate])
1293 UL_REQUIRES_SYSCALL_CHECK([fallocate], [UL_CHECK_SYSCALL([fallocate])])
1294 AM_CONDITIONAL([BUILD_FALLOCATE], [test "x$build_fallocate" = xyes])
1295
1296 AS_IF([test "x$build_fallocate" = xyes], [
1297   dnl check for valid fallocate() function
1298   dnl with 32 bits glibc 2.10, fallocate() exists but not fallocate64()
1299   dnl when _FILE_OFFSET_BITS==64, fallocate() is redirect to fallocate64()
1300   dnl and program can't be linked.
1301   dnl AC_CHECK_FUNC can't catch such errors since it's redefining
1302   dnl function prototype.
1303   AC_MSG_CHECKING([for valid fallocate() function])
1304   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1305 #ifdef HAVE_UNISTD_H
1306 # include <unistd.h>
1307 #endif
1308 #ifdef HAVE_SYS_TYPES_H
1309 # include <sys/types.h>
1310 #endif
1311 #ifdef HAVE_LINUX_FALLOC_H
1312 # include <linux/falloc.h>
1313 #endif
1314 #ifdef HAVE_FCNTL_H
1315 # include <fcntl.h>
1316 #endif
1317 ]],[[
1318    long ret;
1319    ret = fallocate(0, FALLOC_FL_KEEP_SIZE, 0xfffffffful, 0xfffffffful);
1320    if (ret != 0) {
1321       return 1;
1322    }
1323    ]])],[
1324   AC_MSG_RESULT([yes])
1325   AC_DEFINE([HAVE_FALLOCATE], [1], [Have valid fallocate() function])],[
1326   AC_MSG_RESULT([no])])
1327 ])
1328
1329 AS_IF([test "x$build_fallocate" = xyes], [
1330   dnl check for valid posix_fallocate() function
1331   AC_MSG_CHECKING([for valid posix_fallocate() function])
1332   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1333 #ifdef HAVE_UNISTD_H
1334 # include <unistd.h>
1335 #endif
1336 #ifdef HAVE_SYS_TYPES_H
1337 # include <sys/types.h>
1338 #endif
1339 #ifdef HAVE_LINUX_FALLOC_H
1340 # include <linux/falloc.h>
1341 #endif
1342 #ifdef HAVE_FCNTL_H
1343 # include <fcntl.h>
1344 #endif
1345 ]],[[
1346    long ret;
1347    ret = posix_fallocate(0, 0xfffffffful, 0xfffffffful);
1348    if (ret != 0) {
1349       return 1;
1350    }
1351    ]])],[
1352   AC_MSG_RESULT([yes])
1353   AC_DEFINE([HAVE_POSIX_FALLOCATE], [1], [Have valid posix_fallocate() function])],[
1354   AC_MSG_RESULT([no])])
1355 ])
1356
1357
1358 AC_ARG_ENABLE([unshare],
1359   AS_HELP_STRING([--disable-unshare], [do not build unshare]),
1360   [], [UL_DEFAULT_ENABLE([unshare], [check])]
1361 )
1362 UL_BUILD_INIT([unshare])
1363 UL_REQUIRES_LINUX([unshare])
1364 UL_REQUIRES_SYSCALL_CHECK([unshare], [UL_CHECK_SYSCALL([unshare])])
1365 AM_CONDITIONAL([BUILD_UNSHARE], [test "x$build_unshare" = xyes])
1366 AC_CHECK_FUNCS([unshare])
1367
1368 AC_ARG_ENABLE([nsenter],
1369   AS_HELP_STRING([--disable-nsenter], [do not build nsenter]),
1370   [], [UL_DEFAULT_ENABLE([nsenter], [check])]
1371 )
1372 UL_BUILD_INIT([nsenter])
1373 UL_REQUIRES_LINUX([nsenter])
1374 UL_REQUIRES_HAVE([nsenter], [setns_syscall], [setns syscall])
1375 AM_CONDITIONAL([BUILD_NSENTER], [test "x$build_nsenter" = xyes])
1376 AC_CHECK_FUNCS([setns])
1377
1378
1379 AC_ARG_WITH([cap_ng],
1380   AS_HELP_STRING([--without-cap-ng], [compile without libcap-ng]),
1381   [], [with_cap_ng=auto]
1382 )
1383 AS_IF([test "x$with_cap_ng" = xno], [
1384   AM_CONDITIONAL([HAVE_CAP_NG], [false])
1385   have_cap_ng=no
1386 ],[
1387   UL_CHECK_LIB([cap-ng], [capng_apply], [cap_ng])
1388 ])
1389
1390
1391 AC_ARG_ENABLE([setpriv],
1392   AS_HELP_STRING([--disable-setpriv], [do not build setpriv]),
1393   [], [UL_DEFAULT_ENABLE([setpriv], [check])]
1394 )
1395 UL_BUILD_INIT([setpriv])
1396 UL_REQUIRES_LINUX([setpriv])
1397 UL_REQUIRES_HAVE([setpriv], [linux_securebits_h], [securebits.h header file])
1398 UL_REQUIRES_HAVE([setpriv], [cap_ng], [libcap-ng library])
1399 AM_CONDITIONAL([BUILD_SETPRIV], [test "x$build_setpriv" = xyes])
1400
1401
1402 AC_ARG_ENABLE([eject],
1403   AS_HELP_STRING([--disable-eject], [do not build eject]),
1404   [], [UL_DEFAULT_ENABLE([eject], [check])]
1405 )
1406 UL_BUILD_INIT([eject])
1407 UL_REQUIRES_LINUX([eject])
1408 UL_REQUIRES_BUILD([eject], [libmount])
1409 AM_CONDITIONAL([BUILD_EJECT], [test "x$build_eject" = xyes])
1410
1411
1412 AC_ARG_ENABLE([agetty],
1413   AS_HELP_STRING([--disable-agetty], [do not build agetty]),
1414   [], [UL_DEFAULT_ENABLE([agetty], [check])]
1415 )
1416 UL_BUILD_INIT([agetty])
1417 UL_REQUIRES_HAVE([agetty], [utmpx_h], [utmpx.h header])
1418 UL_REQUIRES_HAVE([agetty], [gnu_utmpx], [GNU utmpx functions])
1419 AM_CONDITIONAL([BUILD_AGETTY], [test "x$build_agetty" = xyes])
1420 AS_IF([test "x$have_futimens" = xyes -a "x$have_inotify_init1" = xyes ], [
1421   AC_DEFINE([AGETTY_RELOAD], [1], [Enable agetty --reload feature])
1422 ],[
1423   AC_MSG_WARN([futimens or inotify_init1 not found; agetty(8) will not provide ---reload functionality])
1424 ])
1425
1426
1427 AC_ARG_ENABLE([plymouth_support],
1428   AS_HELP_STRING([--disable-plymouth_support], [don not care about plymouth in sylogin(8) and agetty(8)]),
1429   [], [enable_plymouth_support=check]
1430 )
1431 UL_BUILD_INIT([plymouth_support])
1432 UL_REQUIRES_HAVE([plymouth_support], [tiocglcktrmios], [TIOCGLCKTRMIOS flag])
1433 UL_REQUIRES_HAVE([plymouth_support], [sock_cloexec], [SOCK_CLOEXEC flag])
1434 UL_REQUIRES_HAVE([plymouth_support], [sock_nonblock], [SOCK_NONBLOCK flag])
1435 UL_REQUIRES_HAVE([plymouth_support], [so_passcred], [SO_PASSCRED flag])
1436 AM_CONDITIONAL([USE_PLYMOUTH_SUPPORT], [test "x$build_plymouth_support" = xyes])
1437 AS_IF([test "x$build_plymouth_support" = xyes ], [
1438     AC_DEFINE([USE_PLYMOUTH_SUPPORT], [1], [Enable plymouth support feature for sulogin and aggety])
1439 ])
1440
1441
1442 AC_ARG_WITH([libz],
1443   AS_HELP_STRING([--without-libz], [compile without libz]),
1444   [], [with_libz=auto]
1445 )
1446 AS_IF([test "x$with_libz" = xno], [have_z=no], [
1447   AC_CHECK_LIB([z], [crc32], [have_z=yes], [have_z=no])
1448 ])
1449
1450
1451 AC_ARG_ENABLE([cramfs],
1452   AS_HELP_STRING([--disable-cramfs], [do not build fsck.cramfs, mkfs.cramfs]),
1453   [], [UL_DEFAULT_ENABLE([cramfs], [check])]
1454 )
1455 UL_BUILD_INIT([cramfs])
1456 UL_REQUIRES_HAVE([cramfs], [z], [z library])
1457 AM_CONDITIONAL([BUILD_CRAMFS], [test "x$build_cramfs" = xyes])
1458
1459
1460 AC_ARG_ENABLE([bfs],
1461   AS_HELP_STRING([--disable-bfs], [do not build mkfs.bfs]),
1462   [], [UL_DEFAULT_ENABLE([bfs], [yes])]
1463 )
1464 UL_BUILD_INIT([bfs])
1465 AM_CONDITIONAL([BUILD_BFS], [test "x$build_bfs" = xyes])
1466
1467
1468 AC_ARG_ENABLE([minix],
1469   AS_HELP_STRING([--disable-minix], [do not build fsck.minix, mkfs.minix]),
1470   [], [UL_DEFAULT_ENABLE([minix], [yes])]
1471 )
1472 UL_BUILD_INIT([minix])
1473 AM_CONDITIONAL([BUILD_MINIX], [test "x$build_minix" = xyes])
1474
1475
1476 AC_ARG_ENABLE([fdformat],
1477   AS_HELP_STRING([--disable-fdformat], [do not build fdformat]),
1478   [], [UL_DEFAULT_ENABLE([fdformat], [check])]
1479 )
1480 UL_BUILD_INIT([fdformat])
1481 UL_REQUIRES_LINUX([fdformat])
1482 AM_CONDITIONAL([BUILD_FDFORMAT], [test "x$build_fdformat" = xyes])
1483
1484
1485 AC_ARG_ENABLE([hwclock],
1486   AS_HELP_STRING([--disable-hwclock], [do not build hwclock]),
1487   [], [UL_DEFAULT_ENABLE([hwclock], [check])]
1488 )
1489 have_linuxdummy=$linux_os
1490
1491 UL_BUILD_INIT([hwclock])
1492 UL_REQUIRES_HAVE([hwclock], [io, linuxdummy], [ioperm iopl function or Linux])
1493 AM_CONDITIONAL([BUILD_HWCLOCK], [test "x$build_hwclock" = xyes])
1494
1495
1496 UL_BUILD_INIT([mkfs], [yes])
1497 AM_CONDITIONAL([BUILD_MKFS], [test "x$build_mkfs" = xyes])
1498
1499 UL_BUILD_INIT([isosize], [yes])
1500 AM_CONDITIONAL([BUILD_ISOSIZE], [test "x$build_isosize" = xyes])
1501
1502
1503 UL_BUILD_INIT([fstrim], [check])
1504 UL_REQUIRES_LINUX([fstrim])
1505 UL_REQUIRES_BUILD([fstrim], [libmount])
1506 AM_CONDITIONAL([BUILD_FSTRIM], [test "x$build_fstrim" = xyes])
1507
1508
1509 UL_BUILD_INIT([swapon], [check])
1510 UL_REQUIRES_LINUX([swapon])
1511 UL_REQUIRES_SYSCALL_CHECK([swapon], [UL_CHECK_SYSCALL([swapon])], [swapon])
1512 UL_REQUIRES_SYSCALL_CHECK([swapon], [UL_CHECK_SYSCALL([swapoff])], [swapoff])
1513 UL_REQUIRES_BUILD([swapon], [libblkid])
1514 UL_REQUIRES_BUILD([swapon], [libmount])
1515 UL_REQUIRES_BUILD([swapon], [libsmartcols])
1516 AM_CONDITIONAL([BUILD_SWAPON], [test "x$build_swapon" = xyes])
1517 AC_CHECK_FUNCS([swapon])
1518 AC_CHECK_FUNCS([swapoff])
1519
1520
1521 UL_BUILD_INIT([lsblk], [check])
1522 UL_REQUIRES_LINUX([lsblk])
1523 UL_REQUIRES_BUILD([lsblk], [libblkid])
1524 UL_REQUIRES_BUILD([lsblk], [libmount])
1525 UL_REQUIRES_BUILD([lsblk], [libsmartcols])
1526 AM_CONDITIONAL([BUILD_LSBLK], [test "x$build_lsblk" = xyes])
1527
1528
1529 UL_BUILD_INIT([lscpu], [check])
1530 UL_REQUIRES_LINUX([lscpu])
1531 UL_REQUIRES_BUILD([lscpu], [libsmartcols])
1532 UL_REQUIRES_HAVE([lscpu], [cpu_set_t], [cpu_set_t type])
1533 AM_CONDITIONAL([BUILD_LSCPU], [test "x$build_lscpu" = xyes])
1534
1535
1536 AC_ARG_ENABLE([lslogins],
1537   AS_HELP_STRING([--disable-lslogins], [do not build lslogins]),
1538   [], [UL_DEFAULT_ENABLE([lslogins], [check])]
1539 )
1540 UL_BUILD_INIT([lslogins])
1541 UL_REQUIRES_BUILD([lslogins], [libsmartcols])
1542 UL_REQUIRES_HAVE([lslogins], [shadow_h], [shadow.h header])
1543 UL_REQUIRES_HAVE([lslogins], [utmpx_h], [utmpx.h header])
1544 UL_REQUIRES_HAVE([lslogins], [gnu_utmpx], [GNU utmpx functions])
1545 AM_CONDITIONAL([BUILD_LSLOGINS], [test "x$build_lslogins" = xyes])
1546
1547
1548 UL_BUILD_INIT([chcpu], [check])
1549 UL_REQUIRES_LINUX([chcpu])
1550 UL_REQUIRES_HAVE([chcpu], [cpu_set_t], [cpu_set_t type])
1551 AM_CONDITIONAL([BUILD_CHCPU], [test "x$build_chcpu" = xyes])
1552
1553
1554 AC_ARG_ENABLE([wdctl],
1555   AS_HELP_STRING([--disable-wdctl], [do not build wdctl]),
1556   [], [UL_DEFAULT_ENABLE([wdctl], [check])]
1557 )
1558 UL_BUILD_INIT([wdctl])
1559 UL_REQUIRES_LINUX([wdctl])
1560 UL_REQUIRES_BUILD([wdctl], [libsmartcols])
1561 UL_REQUIRES_HAVE([wdctl], [linux_watchdog_h], [linux/watchdog.h header file])
1562 AM_CONDITIONAL([BUILD_WDCTL], [test "x$build_wdctl" = xyes])
1563
1564
1565 UL_BUILD_INIT([swaplabel], [check])
1566 UL_REQUIRES_BUILD([swaplabel], [libblkid])
1567 AM_CONDITIONAL([BUILD_SWAPLABEL], [test "x$build_swaplabel" = xyes])
1568
1569
1570 UL_BUILD_INIT([mkswap], [yes])
1571 AM_CONDITIONAL([BUILD_MKSWAP], [test "x$build_mkswap" = xyes])
1572 AS_IF([test "x$build_mkswap" = xyes -a "x$build_libuuid" != xyes], [
1573   AC_MSG_WARN([uuid library is not found; mkswap(8) will not generate UUIDs])
1574 ])
1575
1576
1577 AC_ARG_ENABLE([cal],
1578   AS_HELP_STRING([--disable-cal], [do not build cal]),
1579   [], [UL_DEFAULT_ENABLE([cal], [check])]
1580 )
1581 UL_BUILD_INIT([cal])
1582 AM_CONDITIONAL([BUILD_CAL], [test "x$build_cal" = xyes])
1583
1584 AC_ARG_ENABLE([logger],
1585   AS_HELP_STRING([--disable-logger], [do not build logger]),
1586   [], [UL_DEFAULT_ENABLE([logger], [check])]
1587 )
1588 UL_BUILD_INIT([logger])
1589 AM_CONDITIONAL([BUILD_LOGGER], [test "x$build_logger" = xyes])
1590
1591 UL_BUILD_INIT([look], [yes])
1592 AM_CONDITIONAL([BUILD_LOOK], [test "x$build_look" = xyes])
1593
1594 UL_BUILD_INIT([mcookie], [yes])
1595 AM_CONDITIONAL([BUILD_MCOOKIE], [test "x$build_mcookie" = xyes])
1596
1597 UL_BUILD_INIT([namei], [yes])
1598 AM_CONDITIONAL([BUILD_NAMEI], [test "x$build_namei" = xyes])
1599
1600 matriplet="$($CC -print-multiarch 2>/dev/null || true)"
1601 if test "x$matriplet" != "x"; then
1602   AC_DEFINE_UNQUOTED([MULTIARCHTRIPLET], ["$matriplet"],
1603   ["Multi-arch triplet for whereis library search path"])
1604 fi
1605 UL_BUILD_INIT([whereis], [yes])
1606 AM_CONDITIONAL([BUILD_WHEREIS], [test "x$build_whereis" = xyes])
1607
1608 UL_BUILD_INIT([getopt], [yes])
1609 AM_CONDITIONAL([BUILD_GETOPT], [test "x$build_getopt" = xyes])
1610
1611
1612 UL_BUILD_INIT([blockdev], [check])
1613 UL_REQUIRES_LINUX([blockdev])
1614 AM_CONDITIONAL([BUILD_BLOCKDEV], [test "x$build_blockdev" = xyes])
1615
1616
1617 UL_BUILD_INIT([prlimit], [check])
1618 UL_REQUIRES_LINUX([prlimit])
1619 UL_REQUIRES_BUILD([prlimit], [libsmartcols])
1620 UL_REQUIRES_SYSCALL_CHECK([prlimit], [UL_CHECK_SYSCALL([prlimit64])], [prlimit64])
1621 AM_CONDITIONAL([BUILD_PRLIMIT], [test "x$build_prlimit" = xyes])
1622 AS_IF([test "x$build_prlimit" = xyes], [
1623   AC_CHECK_FUNCS([prlimit])
1624 ])
1625
1626
1627 UL_BUILD_INIT([lslocks], [check])
1628 UL_REQUIRES_LINUX([lslocks])
1629 UL_REQUIRES_BUILD([lslocks], [libmount])
1630 UL_REQUIRES_BUILD([lslocks], [libsmartcols])
1631 AM_CONDITIONAL([BUILD_LSLOCKS], [test "x$build_lslocks" = xyes])
1632
1633
1634 AC_ARG_ENABLE([switch_root],
1635   AS_HELP_STRING([--disable-switch_root], [do not build switch_root]),
1636   [], [UL_DEFAULT_ENABLE([switch_root], [check])]
1637 )
1638 UL_BUILD_INIT([switch_root])
1639 UL_REQUIRES_LINUX([switch_root])
1640 UL_REQUIRES_HAVE([switch_root], [openat], [openat function])
1641 AM_CONDITIONAL([BUILD_SWITCH_ROOT], [test "x$build_switch_root" = xyes])
1642
1643
1644 AC_ARG_ENABLE([pivot_root],
1645   AS_HELP_STRING([--disable-pivot_root], [do not build pivot_root]),
1646   [], [UL_DEFAULT_ENABLE([pivot_root], [check])]
1647 )
1648 UL_BUILD_INIT([pivot_root])
1649 UL_REQUIRES_LINUX([pivot_root])
1650 UL_REQUIRES_SYSCALL_CHECK([pivot_root], [UL_CHECK_SYSCALL([pivot_root])])
1651 AM_CONDITIONAL([BUILD_PIVOT_ROOT], [test "x$build_pivot_root" = xyes])
1652
1653
1654 UL_BUILD_INIT([flock], [check])
1655 UL_REQUIRES_HAVE([flock], [timer], [timer_create function])
1656 AM_CONDITIONAL([BUILD_FLOCK], [test "x$build_flock" = xyes])
1657
1658
1659 AC_ARG_ENABLE([lsmem],
1660   AS_HELP_STRING([--disable-lsmem], [do not build lsmem]),
1661   [], [UL_DEFAULT_ENABLE([lsmem], [check])]
1662 )
1663 UL_BUILD_INIT([lsmem])
1664 UL_REQUIRES_LINUX([lsmem])
1665 UL_REQUIRES_BUILD([lsmem], [libsmartcols])
1666 AM_CONDITIONAL([BUILD_LSMEM], [test "x$build_lsmem" = xyes])
1667
1668
1669 AC_ARG_ENABLE([chmem],
1670   AS_HELP_STRING([--disable-chmem], [do not build chmem]),
1671   [], [UL_DEFAULT_ENABLE([chmem], [check])]
1672 )
1673 UL_BUILD_INIT([chmem])
1674 UL_REQUIRES_LINUX([chmem])
1675 AM_CONDITIONAL([BUILD_CHMEM], [test "x$build_chmem" = xyes])
1676
1677 UL_BUILD_INIT([ipcmk], [yes])
1678 AM_CONDITIONAL([BUILD_IPCMK], [test "x$build_ipcmk" = xyes])
1679
1680
1681 AC_ARG_ENABLE([ipcrm],
1682   AS_HELP_STRING([--disable-ipcrm], [do not build ipcrm]),
1683   [], [UL_DEFAULT_ENABLE([ipcrm], [yes])]
1684 )
1685 UL_BUILD_INIT([ipcrm])
1686 AM_CONDITIONAL([BUILD_IPCRM], [test "x$build_ipcrm" = xyes])
1687
1688 AC_ARG_ENABLE([ipcs],
1689   AS_HELP_STRING([--disable-ipcs], [do not build ipcs]),
1690   [], [UL_DEFAULT_ENABLE([ipcs], [yes])]
1691 )
1692 UL_BUILD_INIT([ipcs])
1693 AM_CONDITIONAL([BUILD_IPCS], [test "x$build_ipcs" = xyes])
1694
1695 UL_BUILD_INIT([choom], [check])
1696 UL_REQUIRES_LINUX([choom])
1697 AM_CONDITIONAL([BUILD_CHOOM], [test "x$build_choom" = xyes])
1698
1699 UL_BUILD_INIT([lsipc], [check])
1700 UL_REQUIRES_LINUX([lsipc])
1701 UL_REQUIRES_BUILD([lsipc], [libsmartcols])
1702 AM_CONDITIONAL([BUILD_LSIPC], [test "x$build_lsipc" = xyes])
1703
1704 UL_BUILD_INIT([lsns], [check])
1705 UL_REQUIRES_LINUX([lsns])
1706 UL_REQUIRES_BUILD([lsns], [libsmartcols])
1707 UL_REQUIRES_BUILD([lsns], [libmount])
1708 AM_CONDITIONAL([BUILD_LSNS], [test "x$build_lsns" = xyes])
1709
1710 UL_BUILD_INIT([renice], [yes])
1711 AM_CONDITIONAL([BUILD_RENICE], [test "x$build_renice" = xyes])
1712
1713
1714 AC_ARG_ENABLE([rfkill],
1715   AS_HELP_STRING([--disable-rfkill], [do not build rfkill]),
1716   [], [UL_DEFAULT_ENABLE([rfkill], [check])]
1717 )
1718 UL_BUILD_INIT([rfkill])
1719 UL_REQUIRES_LINUX([rfkill])
1720 UL_REQUIRES_BUILD([rfkill], [libsmartcols])
1721 AM_CONDITIONAL([BUILD_RFKILL], [test "x$build_rfkill" = xyes])
1722
1723
1724 UL_BUILD_INIT([setsid], [yes])
1725 AM_CONDITIONAL([BUILD_SETSID], [test "x$build_setsid" = xyes])
1726
1727 UL_BUILD_INIT([readprofile], [check])
1728 UL_REQUIRES_LINUX([readprofile])
1729 AM_CONDITIONAL([BUILD_READPROFILE], [test "x$build_readprofile" = xyes])
1730
1731 UL_BUILD_INIT([dmesg], [check])
1732 UL_REQUIRES_LINUX([dmesg])
1733 AM_CONDITIONAL([BUILD_DMESG], [test "x$build_dmesg" = xyes])
1734
1735 UL_BUILD_INIT([ctrlaltdel], [check])
1736 UL_REQUIRES_LINUX([ctrlaltdel])
1737 dnl we assume reboot() to be the 1-argument variant, because even considering
1738 dnl widely used alternative C libraries like uclibc, dietlibc and musl,
1739 dnl reboot() with multiple arguments is yet only found in glibc versions
1740 dnl earlier than 2.x.
1741 UL_REQUIRES_HAVE([ctrlaltdel], [reboot], [reboot function])
1742 AM_CONDITIONAL([BUILD_CTRLALTDEL], [test "x$build_ctrlaltdel" = xyes])
1743
1744 UL_BUILD_INIT([fincore], [check])
1745 UL_REQUIRES_LINUX([fincore])
1746 UL_REQUIRES_BUILD([fincore], [libsmartcols])
1747 AM_CONDITIONAL([BUILD_FINCORE], [test "x$build_fincore" = xyes])
1748
1749 UL_BUILD_INIT([fsfreeze], [check])
1750 UL_REQUIRES_LINUX([fsfreeze])
1751 AM_CONDITIONAL([BUILD_FSFREEZE], [test "x$build_fsfreeze" = xyes])
1752
1753 UL_BUILD_INIT([blkdiscard], [check])
1754 UL_REQUIRES_LINUX([blkdiscard])
1755 AM_CONDITIONAL([BUILD_BLKDISCARD], [test "x$build_blkdiscard" = xyes])
1756
1757 UL_BUILD_INIT([blkzone], [check])
1758 UL_REQUIRES_LINUX([blkzone])
1759 UL_REQUIRES_HAVE([blkzone], [linux_blkzoned_h], [linux/blkzoned.h header])
1760 AM_CONDITIONAL([BUILD_BLKZONE], [test "x$build_blkzone" = xyes])
1761
1762 UL_BUILD_INIT([ldattach], [check])
1763 UL_REQUIRES_LINUX([ldattach])
1764 AM_CONDITIONAL([BUILD_LDATTACH], [test "x$build_ldattach" = xyes])
1765
1766 UL_BUILD_INIT([rtcwake], [check])
1767 UL_REQUIRES_LINUX([rtcwake])
1768 AM_CONDITIONAL([BUILD_RTCWAKE], [test "x$build_rtcwake" = xyes])
1769
1770 UL_BUILD_INIT([setarch], [check])
1771 UL_REQUIRES_LINUX([setarch])
1772 AM_CONDITIONAL([BUILD_SETARCH], [test "x$build_setarch" = xyes])
1773
1774 UL_BUILD_INIT([script], [check])
1775 UL_REQUIRES_HAVE([script], [sys_signalfd_h], [sys/signalfd.h header])
1776 AM_CONDITIONAL([BUILD_SCRIPT], [test "x$build_script" = xyes])
1777
1778 UL_BUILD_INIT([scriptreplay], [yes])
1779 AM_CONDITIONAL([BUILD_SCRIPTREPLAY], [test "x$build_scriptreplay" = xyes])
1780
1781 UL_BUILD_INIT([col], [yes])
1782 AM_CONDITIONAL([BUILD_COL], [test "x$build_col" = xyes])
1783
1784 UL_BUILD_INIT([colcrt], [yes])
1785 AM_CONDITIONAL([BUILD_COLCRT], [test "x$build_colcrt" = xyes])
1786
1787 UL_BUILD_INIT([colrm], [yes])
1788 AM_CONDITIONAL([BUILD_COLRM], [test "x$build_colrm" = xyes])
1789
1790 UL_BUILD_INIT([column], [check])
1791 UL_REQUIRES_BUILD([column], [libsmartcols])
1792 AM_CONDITIONAL([BUILD_COLUMN], [test "x$build_column" = xyes])
1793
1794 UL_BUILD_INIT([hexdump], [yes])
1795 AM_CONDITIONAL([BUILD_HEXDUMP], [test "x$build_hexdump" = xyes])
1796
1797 UL_BUILD_INIT([rev], [yes])
1798 AM_CONDITIONAL([BUILD_REV], [test "x$build_rev" = xyes])
1799
1800
1801 AC_ARG_ENABLE([tunelp],
1802   AS_HELP_STRING([--enable-tunelp], [build tunelp]),
1803   [], [UL_DEFAULT_ENABLE([tunelp], [no])]
1804 )
1805 UL_BUILD_INIT([tunelp])
1806 UL_REQUIRES_LINUX([tunelp])
1807 AM_CONDITIONAL([BUILD_TUNELP], [test "x$build_tunelp" = xyes])
1808
1809
1810 AC_ARG_ENABLE([kill],
1811   AS_HELP_STRING([--disable-kill], [do not build kill]),
1812   [], [UL_DEFAULT_ENABLE([kill], [check])]
1813 )
1814 UL_BUILD_INIT([kill])
1815 UL_REQUIRES_LINUX([kill])
1816 AM_CONDITIONAL([BUILD_KILL], [test "x$build_kill" = xyes])
1817
1818
1819 AC_ARG_ENABLE([last],
1820   AS_HELP_STRING([--disable-last], [do not build last]),
1821   [], [UL_DEFAULT_ENABLE([last], [check])]
1822 )
1823 UL_BUILD_INIT([last])
1824 UL_REQUIRES_HAVE([last], [utmpx_h], [utmpx.h header])
1825 UL_REQUIRES_HAVE([last], [gnu_utmpx], [GNU utmpx functions])
1826 AM_CONDITIONAL([BUILD_LAST], [test "x$build_last" = xyes])
1827
1828
1829 AC_ARG_ENABLE([utmpdump],
1830   AS_HELP_STRING([--disable-utmpdump], [do not build utmpdump]),
1831   [], [UL_DEFAULT_ENABLE([utmpdump], [check])]
1832 )
1833 UL_BUILD_INIT([utmpdump])
1834 UL_REQUIRES_HAVE([utmpdump], [utmpx_h], [utmpx.h header])
1835 UL_REQUIRES_HAVE([utmpdump], [gnu_utmpx], [GNU utmpx functions])
1836 AM_CONDITIONAL([BUILD_UTMPDUMP], [test "x$build_utmpdump" = xyes])
1837
1838
1839 AC_ARG_ENABLE([line],
1840   AS_HELP_STRING([--enable-line], [build line]),
1841   [], [UL_DEFAULT_ENABLE([line], [no])]
1842 )
1843 UL_BUILD_INIT([line])
1844 AM_CONDITIONAL([BUILD_LINE], [test "x$build_line" = xyes])
1845
1846
1847 AC_ARG_ENABLE([mesg],
1848   AS_HELP_STRING([--disable-mesg], [do not build mesg]),
1849   [], [UL_DEFAULT_ENABLE([mesg], [yes])]
1850 )
1851 UL_BUILD_INIT([mesg])
1852 AM_CONDITIONAL([BUILD_MESG], [test "x$build_mesg" = xyes])
1853
1854
1855 AC_ARG_ENABLE([raw],
1856   AS_HELP_STRING([--disable-raw], [do not build raw]),
1857   [], [UL_DEFAULT_ENABLE([raw], [check])]
1858 )
1859 UL_BUILD_INIT([raw])
1860 UL_REQUIRES_LINUX([raw])
1861 UL_REQUIRES_HAVE([raw], [linux_raw_h], [raw.h header file])
1862 AM_CONDITIONAL([BUILD_RAW], [test "x$build_raw" = xyes])
1863
1864
1865 AC_ARG_ENABLE([rename],
1866   AS_HELP_STRING([--disable-rename], [do not build rename]),
1867   [], [UL_DEFAULT_ENABLE([rename], [yes])]
1868 )
1869 UL_BUILD_INIT([rename])
1870 AM_CONDITIONAL([BUILD_RENAME], [test "x$build_rename" = xyes])
1871
1872
1873 AC_ARG_ENABLE([vipw],
1874   AS_HELP_STRING([--enable-vipw], [build vipw]),
1875   [], [UL_DEFAULT_ENABLE([vipw], [no])]
1876 )
1877 UL_BUILD_INIT([vipw])
1878 UL_REQUIRES_HAVE([vipw], [shadow_h], [shadow.h header])
1879 AM_CONDITIONAL([BUILD_VIPW], [test "x$build_vipw" = xyes])
1880
1881
1882 AC_ARG_ENABLE([newgrp],
1883   AS_HELP_STRING([--enable-newgrp], [build newgrp]),
1884   [], [UL_DEFAULT_ENABLE([newgrp], [no])]
1885 )
1886 UL_BUILD_INIT([newgrp])
1887 AM_CONDITIONAL([BUILD_NEWGRP], [test "x$build_newgrp" = xyes])
1888
1889
1890 AC_ARG_WITH([user], AS_HELP_STRING([--without-user], [compile without libuser (remote chsh)]),
1891   [], [with_user=check]
1892 )
1893 have_user=no
1894 AS_IF([test "x$with_user" != xno], [
1895   PKG_CHECK_MODULES(LIBUSER,[libuser >= 0.58], [have_user=yes], [have_user=no])
1896   AS_CASE([$with_user:$have_user],
1897     [yes:no],
1898       [AC_MSG_ERROR([user selected but libuser not found])],
1899     [*:yes],
1900       [AC_DEFINE([HAVE_LIBUSER], [1], [Define if libuser is available])]
1901   )
1902   # temporary solution, libuser has stupid .pc where are exported all
1903   # private dependencies to Requires: instead of Requires.private:
1904   AS_IF([test "x$have_user" = xyes], [
1905     LIBUSER_LIBS=-luser
1906   ])
1907 ])
1908 AM_CONDITIONAL([HAVE_USER], [test "x$have_user" = xyes])
1909
1910 AC_ARG_ENABLE([chfn-chsh-password],
1911   AS_HELP_STRING([--disable-chfn-chsh-password], [do not require the user to enter the password in chfn and chsh]),
1912   [], [enable_chfn_chsh_password=yes]
1913 )
1914
1915 AC_ARG_ENABLE([chfn-chsh],
1916   AS_HELP_STRING([--enable-chfn-chsh], [build chfn and chsh]),
1917   [], [UL_DEFAULT_ENABLE([chfn_chsh], [check])]
1918 )
1919 UL_BUILD_INIT([chfn_chsh])
1920 UL_REQUIRES_HAVE([chfn_chsh], [shadow_h], [shadow.h header])
1921 UL_REQUIRES_HAVE([chfn_chsh], [getusershell], [getusershell function])
1922
1923 AS_IF([test "x$enable_chfn_chsh_password" = xyes -o "x$have_user" = xyes], [
1924   UL_REQUIRES_HAVE([chfn_chsh], [security_pam_appl_h], [PAM header file])
1925   AC_DEFINE([CHFN_CHSH_PASSWORD], [1], [Should chfn and chsh require the user to enter the password?])
1926 ])
1927 AM_CONDITIONAL([BUILD_CHFN_CHSH], [test "x$build_chfn_chsh" = xyes])
1928 AM_CONDITIONAL([CHFN_CHSH_PASSWORD], [test "x$enable_chfn_chsh_password" = xyes])
1929
1930 AC_ARG_ENABLE([chsh-only-listed],
1931   AS_HELP_STRING([--disable-chsh-only-listed], [chsh: allow shells not in /etc/shells]),
1932   [], enable_chsh_only_listed=yes
1933 )
1934
1935 AS_IF([test "x$enable_chsh_only_listed" = xyes], [
1936   AC_DEFINE([ONLY_LISTED_SHELLS], [1], [Should chsh allow only shells in /etc/shells?])
1937 ])
1938
1939
1940 AC_ARG_ENABLE([login],
1941   AS_HELP_STRING([--disable-login], [do not build login]),
1942   [], [UL_DEFAULT_ENABLE([login], [check])]
1943 )
1944 UL_BUILD_INIT([login])
1945 UL_REQUIRES_HAVE([login], [security_pam_appl_h], [PAM header file])
1946 UL_REQUIRES_HAVE([login], [security_pam_misc_h, security_openpam_h], [PAM conversation functions])
1947 UL_REQUIRES_HAVE([login], [utmpx_h], [utmpx.h header])
1948 UL_REQUIRES_HAVE([login], [gnu_utmpx], [GNU utmpx functions])
1949 AM_CONDITIONAL([BUILD_LOGIN], [test "x$build_login" = xyes])
1950
1951 AC_ARG_ENABLE([login-chown-vcs],
1952   AS_HELP_STRING([--enable-login-chown-vcs], [let login chown /dev/vcsN]),
1953   [], [enable_login_chown_vcs=no]
1954 )
1955
1956 AS_IF([test "x$enable_login_chown_vcs" = xyes], [
1957   AC_DEFINE([LOGIN_CHOWN_VCS], [1], [Should login chown /dev/vcsN?])
1958 ])
1959
1960 AC_ARG_ENABLE([login-stat-mail],
1961   AS_HELP_STRING([--enable-login-stat-mail], [let login stat() the mailbox]),
1962   [], [enable_login_stat_mail=no]
1963 )
1964
1965 AS_IF([test "x$enable_login_stat_mail" = xyes], [
1966   AC_DEFINE([LOGIN_STAT_MAIL], [1], [Should login stat() the mailbox?])
1967 ])
1968
1969
1970 AC_ARG_ENABLE([nologin],
1971   AS_HELP_STRING([--disable-nologin], [do not build nologin]),
1972   [], [UL_DEFAULT_ENABLE([nologin], [yes])]
1973 )
1974 UL_BUILD_INIT([nologin])
1975 AM_CONDITIONAL([BUILD_NOLOGIN], [test "x$build_nologin" = xyes])
1976
1977
1978 AC_ARG_ENABLE([sulogin],
1979   AS_HELP_STRING([--disable-sulogin], [do not build sulogin]),
1980   [], [UL_DEFAULT_ENABLE([sulogin], [check])]
1981 )
1982 UL_BUILD_INIT([sulogin])
1983 UL_REQUIRES_HAVE([sulogin], [shadow_h], [shadow.h header])
1984 AM_CONDITIONAL([BUILD_SULOGIN], [test "x$build_sulogin" = xyes])
1985
1986
1987 AC_ARG_ENABLE([su],
1988   AS_HELP_STRING([--disable-su], [do not build su]),
1989   [], [UL_DEFAULT_ENABLE([su], [check])]
1990 )
1991 UL_BUILD_INIT([su])
1992 UL_REQUIRES_HAVE([su], [security_pam_appl_h], [PAM header file])
1993 UL_REQUIRES_HAVE([su], [utmpx_h], [utmpx.h header])
1994 UL_REQUIRES_HAVE([su], [gnu_utmpx], [GNU utmpx functions])
1995 AM_CONDITIONAL([BUILD_SU], [test "x$build_su" = xyes])
1996
1997
1998 AC_ARG_ENABLE([runuser],
1999   AS_HELP_STRING([--disable-runuser], [do not build runuser]),
2000   [], [UL_DEFAULT_ENABLE([runuser], [check])]
2001 )
2002 UL_BUILD_INIT([runuser])
2003 UL_REQUIRES_HAVE([runuser], [security_pam_appl_h], [PAM header file])
2004 UL_REQUIRES_HAVE([runuser], [utmpx_h], [utmpx.h header])
2005 UL_REQUIRES_HAVE([runuser], [gnu_utmpx], [GNU utmpx functions])
2006 AM_CONDITIONAL([BUILD_RUNUSER], [test "x$build_runuser" = xyes])
2007
2008
2009 AC_ARG_ENABLE([ul],
2010   AS_HELP_STRING([--disable-ul], [do not build ul]),
2011   [], [UL_DEFAULT_ENABLE([ul], [check])]
2012 )
2013 UL_BUILD_INIT([ul])
2014 UL_REQUIRES_HAVE([ul], [ncursesw, ncurses], [ncursesw or ncurses libraries])
2015 AM_CONDITIONAL([BUILD_UL], [test "x$build_ul" = xyes])
2016
2017
2018 AC_ARG_ENABLE([more],
2019   AS_HELP_STRING([--disable-more], [do not build more]),
2020   [], [UL_DEFAULT_ENABLE([more], [check])]
2021 )
2022 UL_BUILD_INIT([more])
2023 UL_REQUIRES_HAVE([more], [ncursesw, ncurses], [ncursesw or ncurses libraries])
2024 AM_CONDITIONAL([BUILD_MORE], [test "x$build_more" = xyes])
2025
2026
2027 AC_ARG_ENABLE([pg],
2028   AS_HELP_STRING([--enable-pg], [build pg]),
2029   [], [UL_DEFAULT_ENABLE([pg], [no])]
2030 )
2031 UL_BUILD_INIT([pg])
2032 UL_REQUIRES_HAVE([pg], [ncursesw, ncurses], [ncursesw or ncurses library])
2033 AM_CONDITIONAL([BUILD_PG], [test "x$build_pg" = xyes])
2034
2035
2036 AC_ARG_ENABLE([setterm],
2037   AS_HELP_STRING([--disable-setterm], [do not build setterm]),
2038   [], [UL_DEFAULT_ENABLE([setterm], [check])]
2039 )
2040 UL_BUILD_INIT([setterm])
2041 UL_REQUIRES_LINUX([setterm])
2042 UL_REQUIRES_HAVE([setterm], [ncursesw, ncurses], [ncursesw or ncurses library])
2043 AM_CONDITIONAL([BUILD_SETTERM], [test "x$build_setterm" = xyes])
2044
2045 # build_schedutils= is just configure-only variable to control
2046 # ionice, taskset and chrt
2047 AC_ARG_ENABLE([schedutils],
2048   AS_HELP_STRING([--disable-schedutils], [do not build chrt, ionice, taskset]),
2049   [], [UL_DEFAULT_ENABLE([schedutils], [check])]
2050 )
2051
2052
2053 UL_ENABLE_ALIAS([ionice], [schedutils])
2054 UL_BUILD_INIT([ionice])
2055 UL_REQUIRES_SYSCALL_CHECK([ionice],
2056         [UL_CHECK_SYSCALL([ioprio_set],
2057           [alpha],      [442],
2058           [i*86],       [289],
2059           [ia64*],      [1274],
2060           [powerpc*],   [273],
2061           [s390*],      [282],
2062           [sparc*],     [196],
2063           [sh*],        [288],
2064           [x86_64*],    [251])],
2065         [ioprio_set])
2066
2067 UL_REQUIRES_SYSCALL_CHECK([ionice],
2068         [UL_CHECK_SYSCALL([ioprio_get],
2069           [alpha],      [443],
2070           [i*86],       [290],
2071           [ia64*],      [1275],
2072           [powerpc*],   [274],
2073           [s390*],      [283],
2074           [sparc*],     [218],
2075           [sh*],        [289],
2076           [x86_64*],    [252])],
2077         [ioprio_get])
2078
2079 AM_CONDITIONAL([BUILD_IONICE], [test "x$build_ionice" = xyes])
2080
2081
2082 UL_ENABLE_ALIAS([taskset], [schedutils])
2083 UL_BUILD_INIT([taskset])
2084 UL_REQUIRES_HAVE([taskset], [cpu_set_t], [cpu_set_t type])
2085 UL_REQUIRES_SYSCALL_CHECK([taskset],
2086         [UL_CHECK_SYSCALL([sched_getaffinity])],
2087         [sched_getaffinity])
2088 AM_CONDITIONAL([BUILD_TASKSET], [test "x$build_taskset" = xyes])
2089
2090
2091 have_schedsetter=no
2092 AS_IF([test "x$ac_cv_func_sched_setscheduler" = xyes], [have_schedsetter=yes],
2093       [test "x$ac_cv_func_sched_setattr" = xyes], [have_schedsetter=yes])
2094
2095 UL_ENABLE_ALIAS([chrt], [schedutils])
2096 UL_BUILD_INIT([chrt])
2097 UL_REQUIRES_HAVE([chrt], [schedsetter], [sched_set functions])
2098 AM_CONDITIONAL([BUILD_CHRT], [test "x$build_chrt" = xyes])
2099
2100 AS_IF([test "x$build_chrt" = xyes], [
2101         UL_CHECK_SYSCALL([sched_setattr])
2102 ])
2103
2104
2105 AC_ARG_ENABLE([wall],
2106   AS_HELP_STRING([--disable-wall], [do not build wall]),
2107   [], [UL_DEFAULT_ENABLE([wall], [check])]
2108 )
2109 UL_BUILD_INIT([wall])
2110 UL_REQUIRES_HAVE([wall], [utmpx_h], [utmpx.h header])
2111 AM_CONDITIONAL([BUILD_WALL], [test "x$build_wall" = xyes])
2112
2113
2114 AC_ARG_ENABLE([write],
2115   AS_HELP_STRING([--enable-write], [build write]),
2116   [], [UL_DEFAULT_ENABLE([write], [no])]
2117 )
2118 UL_BUILD_INIT([write])
2119 UL_REQUIRES_HAVE([write], [utmpx_h], [utmpx.h header])
2120 UL_REQUIRES_HAVE([write], [gnu_utmpx], [GNU utmpx functions])
2121 AM_CONDITIONAL([BUILD_WRITE], [test "x$build_write" = xyes])
2122
2123
2124 AC_ARG_WITH([btrfs],
2125   AS_HELP_STRING([--without-btrfs], [do not build with btrfs support]),
2126   [], [with_btrfs=check]
2127 )
2128 have_btrfs=no
2129 AS_IF([test "x$with_btrfs" != xno], [
2130   AS_CASE([$with_btrfs:$have_linux_btrfs_h],
2131     [yes:no],
2132     [AC_MSG_ERROR([btrfs selected but linux/btrfs.h not found])],
2133     [check:no],
2134        [AC_MSG_WARN([linux/btrfs.h not found, do not build with btrfs support])],
2135     [*:yes],
2136        [have_btrfs=yes
2137         AC_DEFINE([HAVE_BTRFS_SUPPORT], [1], [Define if btrfs stuff is available])]
2138   )
2139 ])
2140 AM_CONDITIONAL([HAVE_BTRFS], [test "x$have_btrfs" = xyes])
2141
2142
2143 AC_ARG_WITH([systemd],
2144   AS_HELP_STRING([--without-systemd], [do not build with systemd support]),
2145   [], [with_systemd=check]
2146 )
2147
2148 have_systemd=no
2149 AS_IF([test "x$with_systemd" != xno], [
2150   # new version -- all libsystemd-* libs merged into libsystemd
2151   PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [have_systemd=yes], [have_systemd=no])
2152   # old versions
2153   AS_IF([test "x$have_systemd" != "xyes"], [
2154     PKG_CHECK_MODULES([SYSTEMD_DAEMON], [libsystemd-daemon],
2155                       [have_systemd_daemon=yes], [have_systemd_daemon=no])
2156     PKG_CHECK_MODULES([SYSTEMD_JOURNAL], [libsystemd-journal],
2157                       [have_systemd_journal=yes], [have_systemd_journal=no])
2158     AS_IF([test "x$have_systemd_daemon" = "xyes" -a "x$have_systemd_journal" = "xyes" ],[
2159            have_systemd=yes])
2160   ])
2161   AS_CASE([$with_systemd:$have_systemd],
2162     [yes:no],
2163       [AC_MSG_ERROR([systemd expected but libsystemd not found])],
2164     [*:yes],
2165        AC_DEFINE([HAVE_LIBSYSTEMD], [1], [Define if libsystemd is available])
2166   )
2167 ])
2168 AM_CONDITIONAL([HAVE_SYSTEMD], [test "x$have_systemd" = xyes])
2169
2170
2171 AC_ARG_WITH([systemdsystemunitdir],
2172   AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [directory for systemd unit files (requires systemd support)]),
2173   [], [with_systemdsystemunitdir=check]
2174 )
2175 AS_IF([test "x$with_systemdsystemunitdir" = xcheck], [
2176   AS_IF([test "x$have_systemd" = xyes], [
2177     with_systemdsystemunitdir=`$PKG_CONFIG --variable=systemdsystemunitdir systemd`
2178   ],[
2179     with_systemdsystemunitdir=no
2180   ])
2181 ])
2182 AS_IF([test "x$with_systemdsystemunitdir" != "xno"], [
2183   AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
2184 ])
2185
2186
2187 AC_ARG_WITH([smack],
2188   AS_HELP_STRING([--with-smack], [build with SMACK support]),
2189   [], [with_smack=no]
2190 )
2191 AS_IF([test "x$with_smack" = xyes], [
2192   AC_DEFINE([HAVE_SMACK], [1], [Add SMACK support])
2193 ])
2194
2195
2196 AC_ARG_WITH([bashcompletiondir],
2197   AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
2198   [],
2199   [AS_IF([`$PKG_CONFIG --exists bash-completion`], [
2200     with_bashcompletiondir=`$PKG_CONFIG --variable=completionsdir bash-completion`
2201   ], [
2202     with_bashcompletiondir=${datadir}/bash-completion/completions
2203   ])
2204 ])
2205 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
2206
2207 AC_ARG_ENABLE([bash-completion],
2208   AS_HELP_STRING([--disable-bash-completion], [do not install bash completion files]),
2209   [], [enable_bash_completion=yes]
2210 )
2211
2212 AM_CONDITIONAL([BUILD_BASH_COMPLETION], [test "x$enable_bash_completion" = xyes])
2213
2214
2215 AC_ARG_WITH([python],
2216   AS_HELP_STRING([--without-python], [do not build python bindings, use --with-python={2,3} to force version]),
2217   [], [with_python=check withval=check]
2218 )
2219
2220 have_python=no
2221 have_libpython=no
2222 AS_IF([test "x$with_python" != xno], [
2223   # We follow distributions default and look for PKG module name "python"
2224   # (minimal version is 2) but if major version is explicitly specified by
2225   # --with-python=2 or --with-python=3 then we look for PKG module "python2" or
2226   # "python3".
2227   AS_IF([test "x$withval" != xno -a "x$withval" != xyes -a "x$withval" != xcheck],
2228         [pymajor="$withval"; PYTHON=python${pymajor}], [pymajor="2"])
2229
2230   # check for python interpreter
2231   AM_PATH_PYTHON([$pymajor], [have_python=yes], [have_python=no])
2232   AS_CASE([$with_python:$have_python],
2233     [yes:no],
2234       [AC_MSG_ERROR([python selected but python interpreter not found])],
2235     [check:no],
2236        [AC_MSG_WARN([python interpreter not found, do not build python bindings])],
2237     [*:yes],
2238        # check for python development stuff
2239        [PKG_CHECK_MODULES([PYTHON], [python-$PYTHON_VERSION],
2240                           [have_libpython=yes], [have_libpython=no])]
2241   )
2242 ])
2243
2244
2245 AC_ARG_ENABLE([pylibmount],
2246   AS_HELP_STRING([--disable-pylibmount], [do not build pylibmount]),
2247   [], [UL_DEFAULT_ENABLE([pylibmount], [check])]
2248 )
2249 UL_BUILD_INIT([pylibmount])
2250 UL_REQUIRES_HAVE([pylibmount], [libpython], [libpython])
2251 UL_REQUIRES_BUILD([pylibmount], [libmount])
2252 AM_CONDITIONAL([BUILD_PYLIBMOUNT], [test "x$build_pylibmount" = "xyes"])
2253
2254 # We need to introduce a verbatim dependency into the Makefile, without automake
2255 # trying to interpret it, so push it as a AM_SUBST_NOTMAKE variable.
2256 verbatim_pylibmount_dependency='
2257
2258 # pylibmountexec module must be installed after usrlib_exec libraries,
2259 # otherwise the libtool relink step will fail to find libmount.la and
2260 # will try -lmount which is possibly not available.
2261 install-pylibmountexecLTLIBRARIES: install-usrlib_execLTLIBRARIES
2262
2263 '
2264 AC_SUBST([verbatim_pylibmount_dependency])
2265 AM_SUBST_NOTMAKE([verbatim_pylibmount_dependency])
2266
2267 AC_ARG_ENABLE([pg-bell],
2268   AS_HELP_STRING([--disable-pg-bell], [let pg not ring the bell on invalid keys]),
2269   [], [enable_pg_bell=yes]
2270 )
2271
2272 AS_IF([test "x$enable_pg_bell" = xyes], [
2273   AC_DEFINE([PG_BELL], [1], [Should pg ring the bell on invalid keys?])
2274 ])
2275
2276
2277 AC_DEFUN([FS_PATHS_DEFAULT], [/sbin:/sbin/fs.d:/sbin/fs])
2278 AC_ARG_ENABLE([fs-paths-default],
2279   AS_HELP_STRING([--enable-fs-paths-default=paths], [default search path for fs helpers @<:@FS_PATHS_DEFAULT@:>@]),
2280   [AS_CASE([$enableval],
2281     [yes], [fs_paths_defaults="FS_PATHS_DEFAULT"],
2282     [no],  [fs_paths_defaults=""],
2283     [fs_paths_defaults="$enableval"]
2284   )],
2285   [fs_paths_defaults="FS_PATHS_DEFAULT"]
2286 )
2287 AC_ARG_ENABLE([fs-paths-extra],
2288   AS_HELP_STRING([--enable-fs-paths-extra=paths], [additional search paths for fs helpers]),
2289   [AS_CASE([$enableval],
2290      [yes|no], [fs_paths_extra=""],
2291      [fs_paths_extra="$enableval"]
2292   )],
2293   [fs_paths_extra=""]
2294 )
2295 fs_paths="$fs_paths_defaults"
2296 AS_IF([test "x$fs_paths_extra" != "x"], [
2297   AS_IF([test "x$fs_paths" != "x"], [
2298     fs_paths="${fs_paths}:"
2299   ])
2300   fs_paths="${fs_paths}${fs_paths_extra}"
2301 ])
2302 AC_DEFINE_UNQUOTED([FS_SEARCH_PATH], "$fs_paths", [search path for fs helpers])
2303
2304
2305 AC_ARG_ENABLE([use-tty-group],
2306   AS_HELP_STRING([--disable-use-tty-group], [do not install wall and write setgid tty]),
2307   [], [enable_use_tty_group=yes]
2308 )
2309 AM_CONDITIONAL([USE_TTY_GROUP], [test "x$enable_use_tty_group" = xyes])
2310
2311 AS_IF([test "x$enable_use_tty_group" = xyes], [
2312   AC_DEFINE([USE_TTY_GROUP], [1], [Should wall and write be installed setgid tty?])
2313 ])
2314
2315
2316 AC_ARG_ENABLE([sulogin-emergency-mount],
2317   AS_HELP_STRING([--enable-sulogin-emergency-mount],
2318                  [use emergency mount of /dev and /proc for sulogin]),
2319   [], [enable_sulogin_emergency_mount=no]
2320 )
2321
2322 AS_IF([test "x$enable_sulogin_emergency_mount" = xyes], [
2323   AC_DEFINE([USE_SULOGIN_EMERGENCY_MOUNT], [1],
2324             [Should sulogin use a emergency mount of /dev and /proc?])
2325 ])
2326
2327
2328 AC_ARG_ENABLE([usrdir-path],
2329   AS_HELP_STRING([--enable-usrdir-path], [use only /usr paths in PATH env. variable (recommended on systems with /bin -> /usr/bin symlinks)]),
2330   [], [enable_usrdir_path=no]
2331 )
2332
2333 AS_IF([test "x$enable_usrdir_path" = xyes], [
2334   AC_DEFINE([USE_USRDIR_PATHS_ONLY], [1], [Define to 1 to remove /bin and /sbin from PATH env.variable])
2335 ])
2336
2337
2338 AC_ARG_ENABLE([makeinstall-chown],
2339   AS_HELP_STRING([--disable-makeinstall-chown], [do not do chown-like operations during "make install"]),
2340   [], [enable_makeinstall_chown=yes]
2341 )
2342 AM_CONDITIONAL([MAKEINSTALL_DO_CHOWN], [test "x$enable_makeinstall_chown" = xyes])
2343
2344
2345 AC_ARG_ENABLE([makeinstall-setuid],
2346   AS_HELP_STRING([--disable-makeinstall-setuid], [do not do setuid chmod operations during "make install"]),
2347   [], [enable_makeinstall_setuid=yes]
2348 )
2349 AM_CONDITIONAL([MAKEINSTALL_DO_SETUID], [test "x$enable_makeinstall_setuid" = xyes])
2350
2351
2352 AC_ARG_ENABLE([colors-default],
2353   AS_HELP_STRING([--disable-colors-default], [do not colorize output from utils by default]),
2354   [], [enable_colors_default=yes]
2355 )
2356 AS_IF([test "x$enable_colors_default" = xyes], [
2357   AC_DEFINE([USE_COLORS_BY_DEFAULT], [1], [Enables colorized output from utils by default])
2358 ])
2359
2360
2361 AC_ARG_VAR([SUID_CFLAGS],
2362            [CFLAGS used for binaries which are usually with the suid bit])
2363 AC_ARG_VAR([SUID_LDFLAGS],
2364            [LDFLAGS used for binaries which are usually with the suid bit])
2365
2366 AC_ARG_VAR([DAEMON_CFLAGS],
2367            [CFLAGS used for binaries which are usually executed as daemons])
2368 AC_ARG_VAR([DAEMON_LDFLAGS],
2369            [LDFLAGS used for binaries which are usually executed as daemons])
2370
2371 AC_ARG_VAR([SOLIB_CFLAGS],
2372            [CFLAGS used for shared libraries])
2373 AC_ARG_VAR([SOLIB_LDFLAGS],
2374            [LDFLAGS used for shared libraries])
2375
2376 AC_ARG_VAR([ADJTIME_PATH],
2377            [Path to hwclock adjtime file, default /etc/adjtime])
2378 AS_IF([test "x$ADJTIME_PATH" = x], [ADJTIME_PATH="/etc/adjtime"])
2379 AC_DEFINE_UNQUOTED([CONFIG_ADJTIME_PATH], "$ADJTIME_PATH", [Path to hwclock adjtime file])
2380
2381
2382 LIBS=""
2383
2384
2385 AC_CONFIG_HEADERS([config.h])
2386
2387 #
2388 # Don't use configure.ac to replace install paths! See Makefile PATHFILES for
2389 # more details.
2390 #
2391 AC_CONFIG_FILES([
2392 Makefile
2393 libblkid/docs/Makefile
2394 libblkid/docs/version.xml
2395 libblkid/src/blkid.h
2396 libfdisk/docs/Makefile
2397 libfdisk/docs/version.xml
2398 libfdisk/src/libfdisk.h
2399 libmount/docs/Makefile
2400 libmount/docs/version.xml
2401 libmount/src/libmount.h
2402 libsmartcols/docs/Makefile
2403 libsmartcols/docs/version.xml
2404 libsmartcols/src/libsmartcols.h
2405 po/Makefile.in
2406 ])
2407
2408 AC_OUTPUT
2409
2410 AC_MSG_RESULT([
2411         ${PACKAGE}  ${VERSION}
2412
2413         prefix:            ${prefix}
2414         exec prefix:       ${exec_prefix}
2415
2416         runstatedir:       ${runstatedir}
2417         bindir:            ${bindir}
2418         sbindir:           ${sbindir}
2419         libdir:            ${libdir}
2420         includedir:        ${includedir}
2421         usrbin_execdir:    ${usrbin_execdir}
2422         usrsbin_execdir:   ${usrsbin_execdir}
2423         usrlib_execdir:    ${usrlib_execdir}
2424
2425         compiler:          ${CC}
2426         cflags:            ${CFLAGS}
2427         suid cflags:       ${SUID_CFLAGS}
2428         ldflags:           ${LDFLAGS}
2429         suid ldflags:      ${SUID_LDFLAGS}
2430
2431         Python:            ${PYTHON}
2432         Python version:    ${PYTHON_VERSION}
2433         Python libs:       ${pyexecdir}
2434
2435         Bash completions:  ${with_bashcompletiondir}
2436         Systemd support:   ${have_systemd}
2437         Systemd unitdir:   ${with_systemdsystemunitdir}
2438         Btrfs support:     ${have_btrfs}
2439         Wide-char support: ${build_widechar}
2440
2441         warnings:
2442
2443 ${WARN_CFLAGS}
2444
2445         Type 'make' or 'make <utilname>' to compile.
2446 ])