configure.ac

   1 AC_INIT([util-linux],
   2         m4_esyscmd([tools/git-version-gen .tarball-version]),
   3         [kzak@redhat.com], [],
   4         [https://www.kernel.org/pub/linux/utils/util-linux/])
   5
   6
   7 AC_PREREQ([2.64])
   8
   9 AC_CONFIG_AUX_DIR([config])
  10 AC_CONFIG_MACRO_DIR([m4])
  11 dnl AC_USE_SYSTEM_EXTENSIONS must be called before any macros that run
  12 dnl the compiler (like LT_INIT) to avoid autoconf errors.
  13 AC_USE_SYSTEM_EXTENSIONS
  14 AM_INIT_AUTOMAKE([-Wall -Wno-portability foreign 1.10 tar-pax no-dist-gzip dist-xz subdir-objects])
  15
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  17                             [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  18 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  19
  20 AC_CONFIG_SRCDIR([sys-utils/mount.c])
  21 AC_PREFIX_DEFAULT([/usr])
  22
  23 dnl version details from <major>.<minor>[-<suffix>]
  24 PACKAGE_VERSION_MAJOR=$(echo $PACKAGE_VERSION | awk -F. '{print $1}')
  25 PACKAGE_VERSION_MINOR=$(echo $PACKAGE_VERSION | awk -F. '{
  26                                                    sub("-.*","",$2); print $2}')
  27 PACKAGE_VERSION_RELEASE=$(echo $PACKAGE_VERSION | awk -F. '{
  28                      sub("-.*","",$3); print $3 ~ /^@<:@0-9@:>@+$/ ? $3 : 0}')
  29
  30 dnl libblkid version
  31 LIBBLKID_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  32 LIBBLKID_DATE="17-May-2023"
  33 LIBBLKID_LT_MAJOR=1
  34 LIBBLKID_LT_MINOR=1
  35 LIBBLKID_LT_MICRO=0
  36 LIBBLKID_VERSION_INFO=`expr $LIBBLKID_LT_MAJOR + $LIBBLKID_LT_MINOR`:$LIBBLKID_LT_MICRO:$LIBBLKID_LT_MINOR
  37
  38 dnl libuuid version
  39 LIBUUID_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  40 LIBUUID_LT_MAJOR=1
  41 LIBUUID_LT_MINOR=3
  42 LIBUUID_LT_MICRO=0
  43 LIBUUID_VERSION_INFO=`expr $LIBUUID_LT_MAJOR + $LIBUUID_LT_MINOR`:$LIBUUID_LT_MICRO:$LIBUUID_LT_MINOR
  44
  45 dnl libmount version
  46 LIBMOUNT_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  47 LIBMOUNT_LT_MAJOR=1
  48 LIBMOUNT_LT_MINOR=1
  49 LIBMOUNT_LT_MICRO=0
  50 LIBMOUNT_VERSION_INFO=`expr $LIBMOUNT_LT_MAJOR + $LIBMOUNT_LT_MINOR`:$LIBMOUNT_LT_MICRO:$LIBMOUNT_LT_MINOR
  51
  52 dnl libsmartcols version
  53 LIBSMARTCOLS_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  54 LIBSMARTCOLS_LT_MAJOR=1
  55 LIBSMARTCOLS_LT_MINOR=1
  56 LIBSMARTCOLS_LT_MICRO=0
  57 LIBSMARTCOLS_VERSION_INFO=`expr $LIBSMARTCOLS_LT_MAJOR + $LIBSMARTCOLS_LT_MINOR`:$LIBSMARTCOLS_LT_MICRO:$LIBSMARTCOLS_LT_MINOR
  58
  59 dnl libfdisk version
  60 LIBFDISK_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  61 LIBFDISK_LT_MAJOR=1
  62 LIBFDISK_LT_MINOR=1
  63 LIBFDISK_LT_MICRO=0
  64 LIBFDISK_VERSION_INFO=`expr $LIBFDISK_LT_MAJOR + $LIBFDISK_LT_MINOR`:$LIBFDISK_LT_MICRO:$LIBFDISK_LT_MINOR
  65
  66 # Check whether exec_prefix=/usr:
  67 AS_CASE([$exec_prefix:$prefix],
  68 [NONE:NONE | NONE:/usr | /usr:*],
  69   [AC_MSG_NOTICE([Default --exec-prefix detected.])
  70    AS_CASE([$bindir],  ['${exec_prefix}/bin'],  [bindir=/bin;   AC_MSG_NOTICE([  --bindir defaults to /bin])  ])
  71    AS_CASE([$sbindir], ['${exec_prefix}/sbin'], [sbindir=/sbin; AC_MSG_NOTICE([  --sbindir defaults to /sbin])])
  72    AS_CASE([$libdir],  ['${exec_prefix}/lib'],  [libdir=/lib;   AC_MSG_NOTICE([  --libdir defaults to /lib])  ])
  73    AS_CASE([$libdir],  ['${exec_prefix}/lib64'],[libdir=/lib64; AC_MSG_NOTICE([  --libdir defaults to /lib64])  ])
  74   ]
  75 )
  76
  77 # Check whether prefix=/usr
  78 AS_CASE([$prefix],
  79 [NONE | /usr],
  80   [AC_MSG_NOTICE([Default --prefix detected.])
  81    AS_CASE([$localstatedir], [NONE | '${prefix}/var' | "${prefix}"/var ],
  82            [localstatedir=/var; AC_MSG_NOTICE([  --localstatedir defaults to /var])])
  83    AS_CASE([$sysconfdir], [NONE | '${prefix}/etc' | "${prefix}"/etc ],
  84            [sysconfdir=/etc; AC_MSG_NOTICE([  --sysconfdir defaults to /etc])])
  85
  86   ]
  87 )
  88
  89 # default for old versions without $runstatedir
  90 AS_IF([test x"$runstatedir" = x], [runstatedir='${localstatedir}/run'])
  91
  92 # our default if $localstatedir unchanged
  93 AS_CASE([$localstatedir:$runstatedir],
  94  [NONE:'${localstatedir}/run' | /var:'${localstatedir}/run' | NONE:'/run' ],
  95    [runstatedir=/run; AC_MSG_NOTICE([  --runstatedir defaults to /run])]
  96 )
  97
  98 AC_SUBST([runstatedir])
  99
 100
 101 # The original default values of {bin,sbin,lib}dir
 102 usrbin_execdir='${exec_prefix}/bin'
 103 AC_SUBST([usrbin_execdir])
 104
 105 usrsbin_execdir='${exec_prefix}/sbin'
 106 AC_SUBST([usrsbin_execdir])
 107
 108 AS_CASE([$libdir],
 109  ['${exec_prefix}/'* | '${prefix}/'* | /usr/* | "${prefix}"/* ],
 110    [usrlib_execdir=$libdir],
 111  [usrlib_execdir='${exec_prefix}'$libdir]
 112 )
 113 AC_SUBST([usrlib_execdir])
 114
 115 # static configuration maintaned by packages (e.g. /usr/lib)
 116 AC_ARG_VAR([SYSCONFSTATICDIR],
 117            [Path to static system configuration, default ${prefix}/lib])
 118 AS_IF([test "x$SYSCONFSTATICDIR" = x],
 119       [sysconfstaticdir='${prefix}/lib'],
 120       [sysconfstaticdir=$SYSCONFSTATICDIR])
 121 AC_SUBST([sysconfstaticdir])
 122
 123 AC_PROG_CC
 124 AM_PROG_CC_C_O
 125 AC_PROG_MKDIR_P
 126 AC_PROG_YACC
 127
 128 # Don't use autotools integrated LEX/YACC support for libsmartcols
 129 AC_PATH_PROG([FLEX], [flex])
 130 AC_PATH_PROG([BISON], [bison])
 131
 132 AC_CANONICAL_HOST
 133 AC_C_CONST
 134 AC_C_VOLATILE
 135
 136 dnl Compiler warnings
 137 UL_WARN_ADD([-fno-common])
 138 UL_WARN_ADD([-Wall])
 139 UL_WARN_ADD([-Wextra])
 140
 141 UL_WARN_ADD([-Waddress-of-packed-member])
 142 UL_WARN_ADD([-Wdiscarded-qualifiers])
 143 UL_WARN_ADD([-Wembedded-directive])
 144 UL_WARN_ADD([-Wextra-semi])
 145 UL_WARN_ADD([-Wformat-security])
 146 UL_WARN_ADD([-Wimplicit-function-declaration])
 147 UL_WARN_ADD([-Wmissing-declarations])
 148 UL_WARN_ADD([-Wmissing-parameter-type])
 149 UL_WARN_ADD([-Wmissing-prototypes])
 150 UL_WARN_ADD([-Wnested-externs])
 151 UL_WARN_ADD([-Wno-missing-field-initializers])
 152 UL_WARN_ADD([-Wold-style-definition])
 153 UL_WARN_ADD([-Wpointer-arith])
 154 UL_WARN_ADD([-Wredundant-decls])
 155 UL_WARN_ADD([-Wsign-compare])
 156 UL_WARN_ADD([-Wstrict-prototypes])
 157 UL_WARN_ADD([-Wtype-limits])
 158 UL_WARN_ADD([-Wuninitialized])
 159 UL_WARN_ADD([-Wunused-but-set-parameter])
 160 UL_WARN_ADD([-Wunused-but-set-variable])
 161 UL_WARN_ADD([-Wunused-parameter])
 162 UL_WARN_ADD([-Wunused-result])
 163 UL_WARN_ADD([-Wunused-variable])
 164 UL_WARN_ADD([-Wvla])
 165 UL_WARN_ADD([-Walloca])
 166
 167 AC_ARG_ENABLE([werror],
 168   AS_HELP_STRING([--enable-werror], [make all compiler warnings into errors]),
 169   [], [enable_werror=no]
 170 )
 171 AS_IF([test "x$enable_werror" = xyes], [
 172   UL_WARN_ADD([-Werror])
 173 ],[
 174   UL_WARN_ADD([-Werror=sequence-point])
 175 ])
 176
 177 AC_SUBST([WARN_CFLAGS])
 178
 179
 180 UL_WARN_ADD([-Wno-clobbered], [BSD_WARN_CFLAGS])
 181 AC_SUBST([BSD_WARN_CFLAGS])
 182
 183 UL_WARN_ADD([-Wno-cast-function-type], [PYTHON_WARN_CFLAGS])
 184 AC_SUBST([PYTHON_WARN_CFLAGS])
 185
 186
 187 AC_ARG_ENABLE([asan],
 188   AS_HELP_STRING([--enable-asan], [compile with Address Sanitizer]),
 189   [], [enable_asan=no]
 190 )
 191 AS_IF([test "x$enable_asan" = xyes], [
 192   UL_WARN_ADD([-fsanitize=address])
 193   ASAN_LDFLAGS="-fsanitize=address"
 194 ])
 195 AC_SUBST([ASAN_LDFLAGS])
 196
 197 AC_ARG_ENABLE([ubsan],
 198   AS_HELP_STRING([--enable-ubsan], [compile with UBsan]),
 199   [], [enable_ubsan=no]
 200 )
 201 AS_IF([test "x$enable_ubsan" = xyes], [
 202   UL_WARN_ADD([-fsanitize=undefined])
 203   UBSAN_LDFLAGS="-fsanitize=undefined"
 204 ])
 205 AC_SUBST([UBSAN_LDFLAGS])
 206
 207 AC_ARG_ENABLE([fuzzing-engine],
 208   AS_HELP_STRING([--enable-fuzzing-engine], [compile with fuzzing engine]),
 209   [], [enable_fuzzing_engine=no]
 210 )
 211 AS_IF([test "x$enable_fuzzing_engine" = xyes && test "x$LIB_FUZZING_ENGINE" = x], [
 212   UL_WARN_ADD([-fno-omit-frame-pointer])
 213   UL_WARN_ADD([-gline-tables-only])
 214   UL_WARN_ADD([-fsanitize=fuzzer-no-link])
 215   FUZZING_ENGINE_LDFLAGS="-fsanitize=fuzzer-no-link"
 216 ])
 217 AC_SUBST([FUZZING_ENGINE_LDFLAGS])
 218 AC_PROG_CXX
 219 AM_CONDITIONAL([FUZZING_ENGINE], [test "x$enable_fuzzing_engine" = xyes])
 220 AM_CONDITIONAL([OSS_FUZZ], [test "x$LIB_FUZZING_ENGINE" != x])
 221
 222 AC_ARG_ENABLE([coverage],
 223   AS_HELP_STRING([--enable-coverage], [compile with gcov]),
 224   [], [enable_coverage=no]
 225 )
 226 AS_IF([test "x$enable_coverage" = xyes], [
 227   UL_WARN_ADD([--coverage])
 228   COVERAGE_LDFLAGS="--coverage"
 229 ])
 230 AC_SUBST([COVERAGE_LDFLAGS])
 231 AM_CONDITIONAL([WITH_COVERAGE], [test "x$enable_coverage" = xyes])
 232
 233 dnl libtool-2
 234 LT_INIT
 235
 236 dnl check supported linker flags
 237 AX_CHECK_VSCRIPT
 238
 239 m4_ifndef([PKG_PROG_PKG_CONFIG],
 240   [m4_fatal([Could not locate the pkg-config autoconf
 241     macros. These are usually located in /usr/share/aclocal/pkg.m4.
 242     If your macros are in a different location, try setting the
 243     environment variable AL_OPTS="-I/other/macro/dir" before running
 244     ./autogen.sh or autoreconf again. Make sure pkg-config is installed.])])
 245 PKG_PROG_PKG_CONFIG
 246 PKG_INSTALLDIR(['${usrlib_execdir}/pkgconfig'])
 247
 248 GTK_DOC_CHECK([1.10])
 249 AC_PATH_PROG([XSLTPROC], [xsltproc])
 250
 251
 252 linux_os=no
 253 bsd_os=no
 254 AS_CASE([${host_os}],
 255   [*linux*],
 256      [linux_os=yes],
 257   [*darwin*],
 258      [darwin_os=yes],
 259   [*bsd*],
 260      [bsd_os=yes])
 261 AM_CONDITIONAL([LINUX], [test "x$linux_os" = xyes])
 262 AM_CONDITIONAL([DARWIN], [test "x$darwin_os" = xyes])
 263 AM_CONDITIONAL([BSD], [test "x$bsd_os" = xyes])
 264
 265 AS_IF([test  "x$darwin_os" = xyes], [
 266   AC_DEFINE([_DARWIN_C_SOURCE], [1], [Enable MAP_ANON in sys/mman.h on Mac OS X])
 267 ])
 268
 269 dnl define ARCH_<NAME> conditionals
 270 UL_SET_ARCH([I86], [i?86-*])
 271 UL_SET_ARCH([86_64], [x86_64*])
 272 UL_SET_ARCH([IA64], [ia64*])
 273 UL_SET_ARCH([S390], [s390*])
 274 UL_SET_ARCH([SPARC], [sparc*])
 275 UL_SET_ARCH([PPC], [ppc*|powerpc*])
 276 UL_SET_ARCH([M68K], [m68*])
 277 UL_SET_ARCH([MIPS], [mips*])
 278 UL_SET_ARCH([HPPA], [hppa*|parisc*])
 279
 280 AC_SYS_LARGEFILE
 281 AC_HEADER_ASSERT
 282 AC_STRUCT_TIMEZONE
 283 UL_YEAR2038_INIT
 284 AC_SYS_YEAR2038_RECOMMENDED
 285
 286 dnl Don't forget to maintain alternatively allowed versions in autogen.sh!
 287 AM_GNU_GETTEXT_VERSION([0.18.3])
 288 AM_GNU_GETTEXT([external])
 289
 290 AS_IF([test -d "$srcdir/po"], [
 291   ALL_LINGUAS=`cd $srcdir/po > /dev/null && echo *.po | sed 's/\.po//g'`
 292 ], [dnl echo $ALL_LINGUAS | sed 's/ /\n/g' | sort -u | column -xc 72 -o ' ' | sed 's/^/\t/'
 293   ALL_LINGUAS="
 294         af      am      ar      as      be      bg      bn      bn_IN   ca
 295         cs      cy      da      de      el      en_GB   es      et      eu_ES
 296         fa      fi      fr      gl      gu      he      hi      hr      hu
 297         hy      id      is      it      ja      ka      kn      ko      ku
 298         lo      lt      lv      mk      ml      mr      ms      my      nb
 299         nl      nn      no      nso     or      pa      pl      pt      pt_BR
 300         ro      ru      si      sk      sl      sq      sr      sr@Latn sv
 301         ta      te      th      tr      uk      ur      vi      zh_CN   zh_TW
 302         zu
 303 "])
 304
 305 AC_CHECK_HEADERS([linux/compiler.h linux/blkpg.h linux/major.h], [], [], [
 306 #ifdef HAVE_LINUX_COMPILER_H
 307 #include <linux/compiler.h>
 308 #endif
 309 ])
 310 AC_CHECK_HEADERS([ \
 311         asm-generic/fcntl.h \
 312         asm/fcntl.h \
 313         asm/io.h \
 314         byteswap.h \
 315         endian.h \
 316         err.h \
 317         errno.h \
 318         fcntl.h \
 319         getopt.h \
 320         inttypes.h \
 321         lastlog.h \
 322         libutil.h \
 323         linux/blkzoned.h \
 324         linux/btrfs.h \
 325         linux/capability.h \
 326         linux/cdrom.h \
 327         linux/falloc.h \
 328         linux/fd.h \
 329         linux/fiemap.h \
 330         linux/landlock.h \
 331         linux/kcmp.h \
 332         linux/net_namespace.h \
 333         linux/nsfs.h \
 334         linux/pr.h \
 335         linux/raw.h \
 336         linux/securebits.h \
 337         linux/tiocl.h \
 338         linux/version.h \
 339         linux/watchdog.h \
 340         linux/if_alg.h \
 341         locale.h \
 342         mntent.h \
 343         net/if_dl.h \
 344         net/if.h \
 345         netinet/in.h \
 346         paths.h \
 347         pty.h \
 348         security/pam_appl.h \
 349         shadow.h \
 350         stdint.h \
 351         stdio_ext.h \
 352         stdlib.h \
 353         sys/disk.h \
 354         sys/disklabel.h \
 355         sys/endian.h \
 356         sys/file.h \
 357         sys/ioccom.h \
 358         sys/ioctl.h \
 359         sys/io.h \
 360         sys/mkdev.h \
 361         sys/mount.h \
 362         sys/param.h \
 363         sys/pidfd.h \
 364         sys/prctl.h \
 365         sys/resource.h \
 366         sys/sendfile.h \
 367         sys/signalfd.h \
 368         sys/socket.h \
 369         sys/sockio.h \
 370         sys/stat.h \
 371         sys/statfs.h \
 372         sys/swap.h \
 373         sys/syscall.h \
 374         sys/sysmacros.h \
 375         sys/time.h \
 376         sys/timex.h \
 377         sys/ttydefaults.h \
 378         sys/types.h \
 379         sys/ucred.h \
 380         sys/un.h \
 381         sys/vfs.h \
 382         sys/xattr.h \
 383         unistd.h \
 384         utmp.h \
 385         utmpx.h \
 386 ])
 387
 388 # There is a collision in old kernel-headers. The both files mount.h and fs.h
 389 # define MS_* macros. Fixed by kernel commit e462ec50cb5fad19f6003a3d8087f4a0945dd2b1.
 390 #
 391 AC_CHECK_HEADERS([linux/fs.h ], [], [],
 392  [#ifdef HAVE_SYS_MOUNT_H
 393    # include <linux/fs.h>
 394    # include <sys/mount.h>
 395   #endif
 396 ])
 397
 398 AC_CHECK_HEADERS([linux/mount.h ], [], [],
 399  [#ifdef HAVE_LINUX_MOUNT_H
 400    # include <linux/mount.h>
 401    #endif
 402 ])
 403
 404 AC_CHECK_HEADERS([linux/gsmmux.h ], [], [],
 405  [#ifdef LINUX_GSMMUX_H
 406    # include <linux/gsmmux.h>
 407    #endif
 408 ])
 409
 410 AC_CHECK_HEADERS([security/pam_misc.h],
 411                 [AM_CONDITIONAL([HAVE_LINUXPAM], [true])],
 412                 [AM_CONDITIONAL([HAVE_LINUXPAM], [false])], [
 413 #ifdef HAVE_SECURITY_PAM_APPL_H
 414 #include <security/pam_appl.h>
 415 #endif
 416 ])
 417
 418 AC_CHECK_DECLS([BLK_ZONE_REP_CAPACITY], [], [], [
 419         #include <linux/blkzoned.h>
 420 ])
 421
 422 AC_CHECK_DECLS([PR_REP_CAPACITY], [], [], [
 423         #include <linux/pr.h>
 424 ])
 425
 426 AC_CHECK_HEADERS([security/openpam.h], [], [], [
 427 #ifdef HAVE_SECURITY_PAM_APPL_H
 428 #include <security/pam_appl.h>
 429 #endif
 430 ])
 431
 432 AC_CHECK_HEADERS([langinfo.h],
 433                 [AM_CONDITIONAL([HAVE_LANGINFO_H], [true])],
 434                 [AM_CONDITIONAL([HAVE_LANGINFO_H], [false])])
 435
 436 AC_MSG_CHECKING([whether langinfo.h defines ALTMON_x constants])
 437 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 438         #include <langinfo.h>
 439 ]], [[
 440         char *str;
 441         str = nl_langinfo (ALTMON_1);
 442         str = nl_langinfo (ALTMON_2);
 443         str = nl_langinfo (ALTMON_3);
 444         str = nl_langinfo (ALTMON_4);
 445         str = nl_langinfo (ALTMON_5);
 446         str = nl_langinfo (ALTMON_6);
 447         str = nl_langinfo (ALTMON_7);
 448         str = nl_langinfo (ALTMON_8);
 449         str = nl_langinfo (ALTMON_9);
 450         str = nl_langinfo (ALTMON_10);
 451         str = nl_langinfo (ALTMON_11);
 452         str = nl_langinfo (ALTMON_12);
 453 ]])], [
 454         AC_MSG_RESULT([yes])
 455         AC_DEFINE([HAVE_LANGINFO_ALTMON], [1],
 456                 [Define if langinfo.h defines ALTMON_x constants])
 457 ], [
 458         AC_MSG_RESULT([no])
 459 ])
 460
 461
 462 AC_MSG_CHECKING([whether langinfo.h defines _NL_ABALTMON_x constants])
 463 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 464         #include <langinfo.h>
 465 ]], [[
 466         char *str;
 467         str = nl_langinfo (_NL_ABALTMON_1);
 468         str = nl_langinfo (_NL_ABALTMON_2);
 469         str = nl_langinfo (_NL_ABALTMON_3);
 470         str = nl_langinfo (_NL_ABALTMON_4);
 471         str = nl_langinfo (_NL_ABALTMON_5);
 472         str = nl_langinfo (_NL_ABALTMON_6);
 473         str = nl_langinfo (_NL_ABALTMON_7);
 474         str = nl_langinfo (_NL_ABALTMON_8);
 475         str = nl_langinfo (_NL_ABALTMON_9);
 476         str = nl_langinfo (_NL_ABALTMON_10);
 477         str = nl_langinfo (_NL_ABALTMON_11);
 478         str = nl_langinfo (_NL_ABALTMON_12);
 479 ]])], [
 480         AC_MSG_RESULT([yes])
 481         AC_DEFINE([HAVE_LANGINFO_NL_ABALTMON], [1],
 482                 [Define if langinfo.h defines _NL_ABALTMON_x constants])
 483 ], [
 484         AC_MSG_RESULT([no])
 485 ])
 486
 487
 488 dnl Convert some ac_cv_header_* variables to have_*
 489 dnl
 490 have_linux_blkzoned_h=$ac_cv_header_linux_blkzoned_h
 491 have_linux_btrfs_h=$ac_cv_header_linux_btrfs_h
 492 have_linux_capability_h=$ac_cv_header_linux_capability_h
 493 have_linux_kcmp_h=$ac_cv_header_linux_kcmp_h
 494 have_linux_mount_h=$ac_cv_header_linux_mount_h
 495 have_linux_pr_h=$ac_cv_header_linux_pr_h
 496 have_linux_raw_h=$ac_cv_header_linux_raw_h
 497 have_linux_securebits_h=$ac_cv_header_linux_securebits_h
 498 have_linux_version_h=$ac_cv_header_linux_version_h
 499 have_linux_watchdog_h=$ac_cv_header_linux_watchdog_h
 500 have_pty_h=$ac_cv_header_pty_h
 501 have_security_openpam_h=$ac_cv_header_security_openpam_h
 502 have_security_pam_appl_h=$ac_cv_header_security_pam_appl_h
 503 have_security_pam_misc_h=$ac_cv_header_security_pam_misc_h
 504 have_shadow_h=$ac_cv_header_shadow_h
 505 have_sys_signalfd_h=$ac_cv_header_sys_signalfd_h
 506 have_utmpx_h=$ac_cv_header_utmpx_h
 507 have_mntent_h=$ac_cv_header_mntent_h
 508
 509 AS_CASE([$linux_os:$have_linux_version_h],
 510   [yes:no],
 511     [AC_MSG_ERROR([kernel headers required on Linux])]
 512 )
 513
 514 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 515 #include <time.h>
 516 #include <unistd.h>
 517 ]], [[
 518     int a = 0;
 519     struct tm *tm = localtime(0);
 520     if (a == -1)  /* false */
 521         sleep(tm->tm_gmtoff);
 522 ]])],
 523 [AC_DEFINE([HAVE_TM_GMTOFF], [1], [Does struct tm have a field tm_gmtoff?])
 524 ])
 525
 526 AC_CHECK_TYPES([struct mount_attr], [], [], [[#include <linux/mount.h>]])
 527 AC_CHECK_TYPES([enum fsconfig_command], [], [], [[#include <linux/mount.h>]])
 528
 529 AC_CHECK_MEMBERS([struct termios.c_line],,,
 530     [[#include <termios.h>]])
 531
 532 AC_CHECK_MEMBERS([struct stat.st_mtim.tv_nsec],,,
 533     [[#include <sys/stat.h>]])
 534
 535 AC_CHECK_TYPES([struct statx], [], [], [[#include <sys/stat.h>]])
 536 AC_CHECK_MEMBERS([struct statx.stx_mnt_id],,,
 537     [[#include <sys/stat.h>]])
 538
 539 AC_CHECK_DECLS([_NL_TIME_WEEK_1STDAY],[],[],[[#include <langinfo.h>]])
 540
 541 AC_CHECK_DECL([environ],
 542         [AC_DEFINE([HAVE_ENVIRON_DECL], [1],
 543                 [Define to 1 if have **environ prototype])],
 544 )
 545
 546 AC_CHECK_DECL([strsignal],
 547         [AC_DEFINE([HAVE_STRSIGNAL_DECL], [1],
 548                 [Define to 1 if have strsignal function prototype])],
 549 )
 550
 551 AC_CHECK_DECL([TIOCGLCKTRMIOS],
 552               [have_tiocglcktrmios=yes], [have_tiocglcktrmios=no],
 553               [#include <sys/ioctl.h>])
 554 AC_CHECK_DECL([SOCK_CLOEXEC],
 555               [have_sock_cloexec=yes], [have_sock_cloexec=no],
 556               [#include <sys/types.h>
 557                #include <sys/socket.h>])
 558 AC_CHECK_DECL([SOCK_NONBLOCK],
 559               [have_sock_nonblock=yes], [have_sock_nonblock=no],
 560               [#include <sys/types.h>
 561                #include <sys/socket.h>])
 562 AC_CHECK_DECL([SO_PASSCRED],
 563               [have_so_passcred=yes], [have_so_passcred=no],
 564               [#include <sys/types.h>
 565                #include <sys/socket.h>])
 566
 567 AC_CHECK_FUNCS([ \
 568         cachestat \
 569         clearenv \
 570         close_range \
 571         eaccess \
 572         err \
 573         errx \
 574         explicit_bzero \
 575         __fpending \
 576         __fpurge \
 577         fpurge \
 578         fnmatch \
 579         fsconfig \
 580         fsmount \
 581         fsopen \
 582         fspick \
 583         fsync \
 584         getdomainname \
 585         getdtablesize \
 586         getexecname \
 587         getmntinfo \
 588         getrandom \
 589         getrlimit \
 590         getsgnam \
 591         getttynam \
 592         inotify_init \
 593         jrand48 \
 594         landlock_create_ruleset \
 595         landlock_add_rule \
 596         landlock_restrict_self \
 597         lchown \
 598         lgetxattr \
 599         llistxattr \
 600         llseek \
 601         newlocale \
 602         mempcpy \
 603         mkostemp \
 604         move_mount \
 605         mount_setattr \
 606         nanosleep \
 607         ntp_gettime \
 608         open_tree \
 609         personality \
 610         pidfd_open \
 611         pidfd_send_signal \
 612         posix_fadvise \
 613         prctl \
 614         qsort_r \
 615         reallocarray \
 616         renameat2 \
 617         rpmatch \
 618         scandirat \
 619         sched_setattr \
 620         sched_setscheduler \
 621         __secure_getenv \
 622         secure_getenv \
 623         sendfile \
 624         setprogname \
 625         setresgid \
 626         setresuid \
 627         sigqueue \
 628         srandom \
 629         statx \
 630         strnchr \
 631         strndup \
 632         strnlen \
 633         strtod_l \
 634         sysconf \
 635         sysinfo \
 636         timegm \
 637         usleep \
 638         uselocale \
 639         utimensat \
 640         vwarnx \
 641         warn \
 642         warnx \
 643 ])
 644 AC_FUNC_FSEEKO
 645
 646 AC_CHECK_FUNCS([futimens], [have_futimens=yes])
 647 AC_CHECK_FUNCS([getusershell], [have_getusershell=yes],[have_getusershell=no])
 648 AC_CHECK_FUNCS([inotify_init1], [have_inotify_init1=yes])
 649 AC_CHECK_FUNCS([ioperm iopl], [have_io=yes])
 650 AC_CHECK_FUNCS([openat fstatat unlinkat], [have_openat=yes], [have_openat=no])
 651 AC_CHECK_FUNCS([open_memstream], [have_open_memstream=yes],[have_open_memstream=no])
 652 AC_CHECK_FUNCS([reboot], [have_reboot=yes],[have_reboot=no])
 653 AC_CHECK_FUNCS([updwtmpx updwtmpx], [have_gnu_utmpx=yes], [have_gnu_utmpx=no])
 654
 655 AM_CONDITIONAL([HAVE_OPENAT], [test "x$have_openat" = xyes])
 656 AM_CONDITIONAL([HAVE_LINUX_LANDLOCK_H], [test "x$ac_cv_header_linux_landlock_h" = xyes])
 657
 658 have_setns_syscall="yes"
 659 UL_CHECK_SYSCALL([setns])
 660 AS_IF([test "x$ul_cv_syscall_setns" = xno], [
 661    have_setns_syscall="no"
 662 ])
 663
 664 UL_CHECK_SYSCALL([pidfd_open])
 665 UL_CHECK_SYSCALL([pidfd_send_signal])
 666 UL_CHECK_SYSCALL([close_range])
 667 UL_CHECK_SYSCALL([fsconfig])
 668 UL_CHECK_SYSCALL([fsmount])
 669 UL_CHECK_SYSCALL([fsopen])
 670 UL_CHECK_SYSCALL([fspick])
 671 UL_CHECK_SYSCALL([mount_setattr])
 672 UL_CHECK_SYSCALL([move_mount])
 673 UL_CHECK_SYSCALL([open_tree])
 674
 675 AS_IF([test "x$ul_cv_syscall_fsconfig" = xno ||
 676        test "x$ul_cv_syscall_fsmount" = xno ||
 677        test "x$ul_cv_syscall_fsopen" = xno ||
 678        test "x$ul_cv_syscall_fspick" = xno ||
 679        test "x$ul_cv_syscall_mount_setattr" = xno ||
 680        test "x$ul_cv_syscall_move_mount" = xno ||
 681        test "x$ul_cv_syscall_open_tree" = xno],
 682    [
 683         have_mountfd_api="no"
 684    ],[
 685         have_mountfd_api="yes"
 686         AC_DEFINE([HAVE_MOUNTFD_API], [1], [Define to 1 if you want mount API based on FDs.])
 687    ])
 688
 689
 690 AC_CHECK_FUNCS([isnan], [],
 691         [AC_CHECK_LIB([m], [isnan], [MATH_LIBS="-lm"])]
 692         [AC_CHECK_LIB([m], [__isnan], [MATH_LIBS="-lm"])]
 693 )
 694 AC_SUBST([MATH_LIBS])
 695
 696
 697 dnl lib/mononotic.c may require -lrt
 698 AC_CHECK_FUNCS([clock_gettime], [],
 699         [AC_CHECK_LIB([rt], [clock_gettime], [REALTIME_LIBS="-lrt"])]
 700 )
 701
 702 have_timer="no"
 703 AC_CHECK_FUNCS([timer_create],
 704         [have_timer="yes"],
 705         [AC_CHECK_LIB([rt], [timer_create], [
 706                 have_timer="yes"
 707                 REALTIME_LIBS="-lrt"
 708                 AC_DEFINE([HAVE_TIMER_CREATE], [1], [Define if timer_create exist in -lrt])
 709         ],[
 710                 AC_SEARCH_LIBS([timer_create], [rt], [
 711                         AC_MSG_RESULT(yes)
 712                         have_timer="yes"
 713                         REALTIME_LIBS="-lrt -lpthread"
 714                         AC_DEFINE([HAVE_TIMER_CREATE], [1], [Define if timer_create exist in -lrt -lpthread])
 715                 ],[], [-lpthread]
 716                 )
 717         ])]
 718 )
 719
 720 AC_SUBST([REALTIME_LIBS])
 721
 722 AS_IF([test x"$have_timer" = xno], [
 723        AC_CHECK_FUNCS([setitimer], [have_timer="yes"], [have_timer="no"])
 724 ])
 725
 726
 727 AC_CHECK_LIB([rtas], [rtas_get_sysparm], [
 728         RTAS_LIBS="-lrtas"
 729         AC_DEFINE([HAVE_LIBRTAS], [1], [Define if librtas exists])
 730 ])
 731 AC_SUBST([RTAS_LIBS])
 732
 733
 734 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 735                 AC_DEFINE([HAVE_SA_LEN], [1], [Define if struct sockaddr contains sa_len]), [],
 736         [#include <sys/types.h>
 737          #include <sys/socket.h>])
 738
 739 SOCKET_LIBS=
 740 AC_SEARCH_LIBS([socket], [socket],
 741         [AS_IF([test x"$ac_cv_search_socket" != x"none required"],
 742                 [SOCKET_LIBS="$SOCKET_LIBS -lsocket"])
 743 ])
 744 AC_SUBST([SOCKET_LIBS])
 745
 746
 747 have_dirfd=no
 748 AC_CHECK_FUNCS([dirfd], [have_dirfd=yes], [have_dirfd=no])
 749 AS_IF([test x"$have_dirfd" = xno], [
 750         AC_CHECK_DECLS([dirfd],
 751                 [have_dirfd=yes], [have_dirfd=no],
 752                 [#include <sys/types.h>
 753                  #include <dirent.h>])
 754 ])
 755
 756 have_ddfd=no
 757 AS_IF([test x"$have_dirfd" = xno], [
 758         AC_CHECK_MEMBERS([DIR.dd_fd],
 759                 [have_ddfd=yes], [have_ddfd=no],
 760                 [#include <sys/types.h>
 761                  #include <dirent.h>])
 762 ])
 763
 764 AM_CONDITIONAL([HAVE_DIRFD], [test "x$have_dirfd" = xyes || test "x$have_ddfd" = xyes])
 765
 766 MQ_LIBS=
 767 AC_CHECK_LIB([rt], [mq_open], [MQ_LIBS="-lrt"])
 768 AC_SUBST([MQ_LIBS])
 769
 770 AC_MSG_CHECKING([whether program_invocation_short_name is defined])
 771 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 772         #include <errno.h>
 773 ]], [[
 774         program_invocation_short_name = "test";
 775 ]])], [
 776         AC_MSG_RESULT([yes])
 777         AC_DEFINE([HAVE_PROGRAM_INVOCATION_SHORT_NAME], [1],
 778                 [Define if program_invocation_short_name is defined])
 779 ], [
 780         AC_MSG_RESULT([no])
 781 ])
 782
 783
 784 AC_MSG_CHECKING([whether __progname is defined])
 785 AC_LINK_IFELSE([AC_LANG_PROGRAM([extern char *__progname;],
 786            [if (*__progname == 0) return 1;])],
 787            AC_DEFINE([HAVE___PROGNAME], [1], [Define if __progname is defined])
 788            AC_MSG_RESULT([yes]),
 789            AC_MSG_RESULT([no]))
 790
 791 AC_CHECK_DECL([IOC_OPAL_GET_STATUS],
 792         [AC_DEFINE([HAVE_OPAL_GET_STATUS], [1],
 793                 [Define to 1 if OPAL status ioctl is defined])],,
 794               [#include <linux/sed-opal.h>])
 795
 796 dnl Static compilation
 797 m4_define([UL_STATIC_PROGRAMS], [blkid, fdisk, losetup, mount, nsenter, sfdisk, umount, unshare])
 798
 799 AC_ARG_ENABLE([static-programs],
 800   [AS_HELP_STRING([--enable-static-programs=LIST],
 801       [link static the programs in LIST (comma-separated,
 802       supported for ]m4_defn([UL_STATIC_PROGRAMS])[)])])
 803
 804 AS_CASE([$enable_static_programs],
 805   [yes],
 806     [enable_static_programs=m4_quote(UL_STATIC_PROGRAMS)],
 807   [no],
 808     [enable_static_programs=]
 809 )
 810
 811 dnl Set all the individual AM_CONDITIONALs
 812 m4_foreach([UL_PRG], m4_defn([UL_STATIC_PROGRAMS]), [
 813   AS_CASE([,$enable_static_programs,],
 814    [*,UL_PRG,*], [static_[]UL_PRG=yes]
 815   )
 816   AS_IF([test "x$static_[]UL_PRG" = xyes], [AC_MSG_NOTICE([enable static build: UL_PRG.])])
 817   AM_CONDITIONAL([HAVE_STATIC_]m4_toupper(UL_PRG),
 818     [test "x$static_[]UL_PRG" = xyes])
 819 ])
 820
 821
 822 AC_ARG_ENABLE([all-programs],
 823   AS_HELP_STRING([--disable-all-programs], [disable everything, might be overridden by --enable-<name>]),
 824   [], [enable_all_programs=undefined]
 825 )
 826
 827 AS_CASE([$enable_all_programs],
 828   [yes], [AC_MSG_WARN([force to build all programs by default])
 829           ul_default_estate=check],
 830   [no],  [AC_MSG_WARN([disable all programs and man pages by default])
 831           ul_default_estate=no]
 832 )
 833
 834
 835 AC_ARG_ENABLE([asciidoc],
 836   AS_HELP_STRING([--disable-asciidoc], [do not generate man pages from asciidoc]),
 837   [], [UL_DEFAULT_ENABLE([asciidoc], [check])]
 838 )
 839 UL_BUILD_INIT([asciidoc])
 840 UL_REQUIRES_PROGRAM([asciidoc], [ASCIIDOCTOR], [asciidoctor], [man pages])
 841 AM_CONDITIONAL([ENABLE_ASCIIDOC], [test "x$build_asciidoc" = xyes])
 842 have_asciidoctor_failure_level=no
 843 AS_IF([test "x$build_asciidoc" = xyes], [
 844        AC_MSG_CHECKING([whether ${ASCIIDOCTOR} supports --failure-level])
 845        AS_IF([${ASCIIDOCTOR} --help | grep failure-level >/dev/null 2>&1 ], [
 846          AC_MSG_RESULT([yes])
 847          have_asciidoctor_failure_level=yes
 848        ], [
 849          AC_MSG_RESULT([no])
 850        ])
 851 ])
 852 AM_CONDITIONAL([HAVE_ASCIIDOCTOR_FAILURE_LEVEL], [test "x$have_asciidoctor_failure_level" = xyes])
 853
 854 have_manpages=no
 855 AS_IF([test -f "$srcdir/sys-utils/mount.8"], [
 856    AC_MSG_NOTICE([re-use already generated man-pages.])
 857    have_manpages=yes]
 858 )
 859 AM_CONDITIONAL([HAVE_MANPAGES], [test "x$have_manpages" = xyes])
 860
 861
 862 AC_ARG_ENABLE([poman],
 863   AS_HELP_STRING([--disable-poman], [generate translated man pages]),
 864   [], [UL_DEFAULT_ENABLE([poman], [check])]
 865 )
 866 UL_BUILD_INIT([poman])
 867 UL_REQUIRES_PROGRAM([poman], [PO4A], [po4a], [translated man pages])
 868 AM_CONDITIONAL([ENABLE_POMAN], [test "x$build_poman" = xyes])
 869
 870
 871 AX_CHECK_TLS
 872
 873 have_pty=no
 874 AC_ARG_WITH([util], AS_HELP_STRING([--without-util], [compile without libutil]),
 875   [], [with_util=auto]
 876 )
 877 AS_IF([test "x$with_util" = xno], [
 878   AM_CONDITIONAL([HAVE_UTIL], [false])
 879   have_util=no
 880 ], [
 881   UL_CHECK_LIB([util], [openpty])
 882 ])
 883
 884 AS_IF([test "x$have_pty_h" = xyes && test "x$have_sys_signalfd_h" = xyes && test "x$have_util" = xyes], [
 885    AM_CONDITIONAL([HAVE_PTY], [true])
 886    AC_DEFINE([HAVE_PTY], [1], [have PTY support])
 887    have_pty=yes
 888 ], [
 889    AM_CONDITIONAL([HAVE_PTY], [false])
 890 ])
 891
 892 AC_CHECK_TYPES([union semun], [], [], [[
 893 #include <sys/sem.h>
 894 ]])
 895 AC_CHECK_TYPES([loff_t])
 896
 897
 898 AC_ARG_ENABLE([widechar],
 899   AS_HELP_STRING([--disable-widechar], [do not compile wide character support]),
 900   [], [enable_widechar=check]
 901 )
 902 UL_BUILD_INIT([widechar])
 903 UL_REQUIRES_COMPILE([widechar], [[
 904   #include <wchar.h>
 905   #include <wctype.h>
 906   #include <stdio.h>
 907   #include <stdlib.h>
 908   ]], [[
 909     wchar_t wc;
 910     wint_t w;
 911     w = fgetwc(stdin);
 912     if (w == WEOF) exit(1);
 913     wc = w;
 914     fputwc(wc,stdout);
 915   ]],
 916   [wchar_t support])
 917
 918 AS_IF([test "x$build_widechar" = xyes ], [
 919   AC_DEFINE([HAVE_WIDECHAR], [1], [Do we have wide character support?])
 920 ])
 921
 922
 923 AC_CHECK_TYPES([cpu_set_t], [have_cpu_set_t=yes], [], [[
 924 #include <sched.h>
 925 ]])
 926
 927 AM_CONDITIONAL([HAVE_CPU_SET_T], [test "x$have_cpu_set_t" = xyes])
 928
 929 AC_CHECK_TYPES([sighandler_t], [], [], [[
 930 #include <signal.h>
 931 ]])
 932
 933 AC_CHECK_DECLS([CPU_ALLOC], [], [], [[
 934 #include <sched.h>
 935 ]])
 936
 937 # on Solaris, you can't mix and match standards, since we use c99
 938 # apparently at this stage, XOPEN_SOURCE will conflict.  As workaround,
 939 # check for crypt.h and use that without XOPEN_SOURCE.
 940 have_crypt=no
 941 AC_CHECK_HEADERS([crypt.h])
 942 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 943 #ifdef HAVE_CRYPT_H
 944 #include <crypt.h>
 945 #else
 946 #define _XOPEN_SOURCE
 947 #include <unistd.h>
 948 #endif
 949 ]], [[
 950 char *c = crypt("abc","pw");
 951 ]])],[
 952   have_libcrypt=no
 953   have_crypt=yes
 954 ],[
 955   UL_SET_LIBS([-lcrypt])
 956   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 957   #ifdef HAVE_CRYPT_H
 958   #include <crypt.h>
 959   #else
 960   #define _XOPEN_SOURCE
 961   #include <unistd.h>
 962   #endif
 963   ]], [[
 964   char *c = crypt("abc","pw");
 965   ]])],[
 966   have_libcrypt=yes
 967   have_crypt=yes
 968   ],[
 969   AC_MSG_WARN([crypt() is not available])
 970   ])
 971   UL_RESTORE_LIBS
 972 ])
 973 AM_CONDITIONAL([HAVE_LIBCRYPT], [test "x$have_libcrypt" = xyes])
 974
 975
 976 AC_ARG_WITH([selinux],
 977   AS_HELP_STRING([--with-selinux], [compile with SELinux support]),
 978   [], [with_selinux=no]
 979 )
 980
 981 AS_IF([test "x$with_selinux" = xno], [
 982   AM_CONDITIONAL([HAVE_SELINUX], [false])
 983 ], [
 984   PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.5], [have_selinux=yes], [have_selinux=no])
 985   AS_CASE([$with_selinux:$have_selinux],
 986     [yes:no], [AC_MSG_ERROR([SELinux selected but libselinux not found or too old])]
 987   )
 988   AS_IF([test "x$have_selinux" = xyes], [
 989     AC_DEFINE([HAVE_LIBSELINUX], [1], [Define if SELinux is available])
 990     UL_PKG_STATIC([SELINUX_LIBS_STATIC], [libselinux])
 991     AM_CONDITIONAL([HAVE_SELINUX], [true])
 992
 993     UL_SET_LIBS([$SELINUX_LIBS])
 994     # This function is missing in old libselinux 1.xx versions
 995     AC_CHECK_FUNCS([security_get_initial_context])
 996     UL_RESTORE_LIBS
 997   ])
 998 ])
 999 AC_SUBST([SELINUX_LIBS])
1000 AC_SUBST([SELINUX_LIBS_STATIC])
1001
1002
1003 AC_ARG_WITH([audit],
1004   AS_HELP_STRING([--with-audit], [compile with audit support]),
1005   [], [with_audit=no]
1006 )
1007
1008 AS_IF([test "x$with_audit" = xno], [
1009   AM_CONDITIONAL([HAVE_AUDIT], [false])
1010 ], [
1011   UL_CHECK_LIB([audit], [audit_log_user_message])
1012   AS_CASE([$with_audit:$have_audit],
1013     [yes:no],
1014       [AC_MSG_ERROR([Audit selected but libaudit not found (or does not support audit_log_user_message())])]
1015   )
1016 ])
1017
1018 AC_ARG_WITH([udev], AS_HELP_STRING([--without-udev], [compile without udev support]),
1019   [], [with_udev=auto]
1020 )
1021
1022 AS_IF([test "x$with_udev" = xno], [
1023   AM_CONDITIONAL([HAVE_UDEV], [false])
1024 ], [
1025   UL_CHECK_LIB([udev], [udev_new])
1026   AS_CASE([$with_udev:$have_udev],
1027     [yes:no],
1028       [AC_MSG_ERROR([udev selected but libudev not found])]
1029   )
1030 ])
1031
1032
1033 dnl wide-char ncurses
1034 AC_ARG_WITH([ncursesw],
1035   AS_HELP_STRING([--without-ncursesw], [do not build with wide-char ncurses]),
1036   [], [with_ncursesw=auto]
1037 )
1038 have_ncursesw=no
1039 have_ncursesw_header=no
1040 AS_IF([test "x$with_ncursesw" != xno], [
1041   UL_NCURSES_CHECK([ncursesw])
1042   AS_IF([test "x$have_ncursesw" = xyes], [
1043     AC_CHECK_HEADERS([ncursesw/ncurses.h], [have_ncursesw_header=yes])
1044     AC_CHECK_HEADERS([ncursesw/term.h])
1045
1046     # Define HAVE_NCURSES_H only if check for HAVE_NCURSESW_NCURSES_H is
1047     # unsuccessful to avoid too many *_H permitations in config.h
1048     AS_IF([test "x$have_ncursesw_header" = xno], [
1049            AC_CHECK_HEADERS([ncurses.h], [have_ncursesw_header=yes])
1050            AC_CHECK_HEADERS([term.h])
1051     ])
1052     AS_IF([test "x$have_ncursesw_header" = xno], [have_ncursesw=no])
1053   ])
1054   AS_IF([test "x$have_ncursesw" = xyes], [
1055     CURSES_LIB_NAME="ncursesw"
1056     AC_DEFINE([HAVE_LIBNCURSESW], [1], [Define if ncursesw library available])
1057   ])
1058 ])
1059 AS_CASE([$with_ncursesw:$have_ncursesw],
1060   [yes:no], [AC_MSG_ERROR([ncursesw selected, but library not found])])
1061
1062
1063 dnl non-wide ncurses
1064 AC_ARG_WITH([ncurses],
1065   AS_HELP_STRING([--with-ncurses], [build with non-wide ncurses]),
1066   [], [with_ncurses=auto]
1067 )
1068 have_ncurses=no
1069 have_ncurses_header=no
1070 AS_CASE([$with_ncurses:$build_widechar],
1071   [yes:yes], [AC_MSG_ERROR([wide-char support enabled, but non-wide ncurses selects])])
1072
1073 AS_IF([test "x$have_ncursesw" = xno && test "x$with_ncurses" != xno ], [
1074   UL_NCURSES_CHECK([ncurses])
1075   AS_IF([test "x$have_ncurses" = xyes], [
1076     AC_CHECK_HEADERS([ncurses/ncurses.h], [have_ncurses_header=yes])
1077     AC_CHECK_HEADERS([ncurses/term.h])
1078
1079     # Define HAVE_NCURSES_H only if check for HAVE_NCURSES_NCURSES_H is
1080     # unsuccessful to avoid too many *_H permitations in config.h
1081     AS_IF([test "x$have_ncurses_header" = xno], [
1082            AC_CHECK_HEADERS([ncurses.h], [have_ncurses_header=yes])
1083            AC_CHECK_HEADERS([term.h])
1084     ])
1085     AS_IF([test "x$have_ncurses_header" = xno], [have_ncurses=no])
1086   ])
1087   AS_IF([test "x$have_ncurses" = xyes], [
1088     CURSES_LIB_NAME="ncurses"
1089     AC_DEFINE([HAVE_LIBNCURSES], [1], [Define if ncurses library available])
1090   ])
1091 ])
1092 AS_CASE([$with_ncurses:$have_ncurses],
1093   [yes:no], [AC_MSG_ERROR([ncurses selected, but library not found])])
1094
1095 AC_SUBST([NCURSES_CFLAGS])
1096 AC_SUBST([NCURSES_LIBS])
1097 AM_CONDITIONAL([HAVE_NCURSES], [test "x$have_ncursesw" = xyes || test "x$have_ncurses" = xyes])
1098
1099
1100 AC_ARG_WITH([slang],
1101   AS_HELP_STRING([--with-slang], [compile cfdisk with slang rather than ncurses]),
1102   [], [with_slang=no]
1103 )
1104 have_slang=no
1105 AS_IF([test "x$with_slang" = xyes], [
1106   AC_CHECK_HEADERS([slang.h slang/slang.h])
1107   AC_CHECK_HEADERS([slcurses.h slang/slcurses.h],
1108                    [have_slang=yes], [], [
1109 #ifdef HAVE_SLANG_H
1110 #include <slang.h>
1111 #elif defined(HAVE_SLANG_SLANG_H)
1112 #include <slang/slang.h>
1113 #endif
1114 ])
1115   AS_IF([test "x$have_slang" = xno], [
1116     AC_MSG_ERROR([slang selected but slcurses.h not found])],
1117     [CURSES_LIB_NAME=slang
1118   ])
1119 ])
1120 AM_CONDITIONAL([HAVE_SLANG], [test "x$have_slang" = xyes])
1121
1122
1123 AS_IF([test "x$have_slang" = xyes || test "x$have_ncursesw" = xyes || test "x$have_ncurses" = xyes], [
1124         AC_CHECK_LIB([$CURSES_LIB_NAME], use_default_colors, [
1125                      AC_DEFINE(HAVE_USE_DEFAULT_COLORS, 1,
1126                                [Define if curses library has the use_default_colors().])
1127         ])
1128         AC_CHECK_LIB([$CURSES_LIB_NAME], resizeterm, [
1129                      AC_DEFINE(HAVE_RESIZETERM, 1,
1130                                [Define if curses library has the resizeterm().])
1131         ])
1132 ])
1133
1134
1135 AC_ARG_WITH([tinfo], AS_HELP_STRING([--without-tinfo], [compile without libtinfo]),
1136   [], [with_tinfo=auto]
1137 )
1138 have_tinfo=no
1139 have_tinfow=no
1140 AS_IF([test "x$with_tinfo" != xno], [
1141   AS_IF([test "x$have_ncursesw" = xyes], [
1142     UL_TINFO_CHECK([tinfow])
1143   ])
1144   AS_IF([test "x$have_tinfow" = xno], [
1145     UL_TINFO_CHECK([tinfo])
1146   ])
1147 ])
1148 AC_SUBST([TINFO_LIBS])
1149 AC_SUBST([TINFO_LIBS_STATIC])
1150 AC_SUBST([TINFO_CFLAGS])
1151 AM_CONDITIONAL([HAVE_TINFO], [test "x$have_tinfo" = xyes || test "x$have_tinfow" = xyes])
1152 AS_IF([test "x$have_tinfo" = xyes || test "x$have_tinfow" = xyes], [
1153   AC_DEFINE(HAVE_LIBTINFO, 1, [Define if libtinfo or libtinfow available.])
1154 ])
1155
1156
1157 AC_ARG_WITH([readline],
1158   AS_HELP_STRING([--without-readline], [do not build with GNU Readline support]),
1159   [], [with_readline=auto]
1160 )
1161
1162 AS_IF([test "x$with_readline" = xno], [
1163   AM_CONDITIONAL([HAVE_READLINE], [false])
1164 ], [
1165   UL_CHECK_LIB([readline], [readline])
1166   AS_CASE([$with_readline:$have_readline],
1167     [yes:no],
1168       [AC_MSG_ERROR([readline selected but libreadline not found ])],
1169     [*:yes],
1170       [READLINE_LIBS="-lreadline"
1171        READLINE_LIBS_STATIC="-lreadline $TINFO_LIBS_STATIC"]
1172   )
1173 ])
1174 AC_SUBST([READLINE_LIBS])
1175 AC_SUBST([READLINE_LIBS_STATIC])
1176
1177
1178 AC_ARG_WITH([utempter],
1179   AS_HELP_STRING([--with-utempter], [compile script(1) with libutempter]),
1180   [], [with_utempter=no]
1181 )
1182
1183 AS_IF([test "x$with_utempter" = xyes], [
1184   UL_CHECK_LIB([utempter], [utempter_add_record])
1185   AS_IF([test "x$have_utempter" = xno], [
1186     AC_MSG_ERROR([utempter selected but libutempter not found])
1187   ])
1188 ], [
1189   AM_CONDITIONAL([HAVE_UTEMPTER], [false])
1190 ])
1191
1192
1193 dnl
1194 dnl libuuid
1195 dnl
1196 AC_ARG_ENABLE([libuuid],
1197   AS_HELP_STRING([--disable-libuuid], [do not build libuuid and uuid utilities]),
1198   [], [UL_DEFAULT_ENABLE([libuuid], [yes])]
1199 )
1200 UL_BUILD_INIT([libuuid])
1201 AC_SUBST([LIBUUID_VERSION])
1202 AC_SUBST([LIBUUID_VERSION_INFO])
1203 AM_CONDITIONAL(BUILD_LIBUUID, test "x$build_libuuid" = xyes)
1204
1205 AC_ARG_ENABLE([libuuid-force-uuidd],
1206   AS_HELP_STRING([--enable-libuuid-force-uuidd], [support uuidd even though the daemon is not built]),
1207   [], [enable_libuuid_force_uuidd=no]
1208 )
1209
1210 AS_IF([test "x$build_libuuid" = xyes], [
1211   AC_DEFINE(HAVE_LIBUUID, 1, [Define to 1 if you have the -luuid.])
1212 ])
1213
1214 dnl
1215 dnl libblkid
1216 dnl
1217 AC_ARG_ENABLE([libblkid],
1218   AS_HELP_STRING([--disable-libblkid], [do not build libblkid and many related utilities]),
1219   [], [UL_DEFAULT_ENABLE([libblkid], [check])]
1220 )
1221 UL_BUILD_INIT([libblkid])
1222 UL_REQUIRES_HAVE([libblkid], [openat], [openat functions])
1223 UL_REQUIRES_HAVE([libblkid], [dirfd,ddfd], [dirfd or ddfd function])
1224 AC_SUBST([LIBBLKID_DATE])
1225 AC_SUBST([LIBBLKID_VERSION])
1226 AC_SUBST([LIBBLKID_VERSION_INFO])
1227 AC_DEFINE_UNQUOTED([LIBBLKID_VERSION], ["$LIBBLKID_VERSION"], [libblkid version string])
1228 AC_DEFINE_UNQUOTED([LIBBLKID_DATE], ["$LIBBLKID_DATE"], [libblkid date string])
1229 AS_IF([test "x$build_libblkid" = xyes], [
1230   AC_DEFINE([HAVE_LIBBLKID], [1], [Define to 1 if you have the -lblkid.])
1231 ])
1232 AM_CONDITIONAL([BUILD_LIBBLKID], [test "x$build_libblkid" = xyes])
1233 AM_CONDITIONAL([BUILD_LIBBLKID_TESTS], [test "x$build_libblkid" = xyes && test "x$enable_static" = xyes])
1234
1235 dnl
1236 dnl libmount
1237 dnl
1238 AC_ARG_ENABLE([libmount],
1239   AS_HELP_STRING([--disable-libmount], [do not build libmount]),
1240   [], [UL_DEFAULT_ENABLE([libmount], [check])]
1241 )
1242 UL_BUILD_INIT([libmount])
1243 UL_REQUIRES_BUILD([libmount], [libblkid])
1244 UL_REQUIRES_HAVE([libmount], [dirfd,ddfd], [dirfd or ddfd function])
1245 UL_REQUIRES_HAVE([libmount], [mntent_h], [mntent.h header file])
1246 AM_CONDITIONAL([BUILD_LIBMOUNT], [test "x$build_libmount" = xyes])
1247 AM_CONDITIONAL([BUILD_LIBMOUNT_TESTS], [test "x$build_libmount" = xyes && test "x$enable_static" = xyes])
1248 AS_IF([test "x$build_libmount" = xyes], [
1249   AC_DEFINE(HAVE_LIBMOUNT, 1, [Define if libmount available.])
1250   AS_IF([test "x$have_setns_syscall" = "xyes"], [
1251     AC_DEFINE([USE_LIBMOUNT_SUPPORT_NAMESPACES], [1], [Define to 1 if want to support namepaces.])
1252   ],[
1253     AC_MSG_WARN([libmount will be compiled without namespaces support])
1254   ])
1255 ])
1256
1257 AC_SUBST([LIBMOUNT_VERSION])
1258 AC_SUBST([LIBMOUNT_MAJOR_VERSION], $PACKAGE_VERSION_MAJOR)
1259 AC_SUBST([LIBMOUNT_MINOR_VERSION], $PACKAGE_VERSION_MINOR)
1260 AC_SUBST([LIBMOUNT_PATCH_VERSION], $PACKAGE_VERSION_RELEASE)
1261 AC_SUBST([LIBMOUNT_VERSION_INFO])
1262 AC_DEFINE_UNQUOTED([LIBMOUNT_VERSION], ["$LIBMOUNT_VERSION"], [libmount version string])
1263
1264 AC_ARG_ENABLE([libmount-mountfd-support],
1265   AS_HELP_STRING([--disable-libmount-mountfd-support], [do not use new mount API based on FDs]),
1266   [], [enable_libmount_mountfd_support=check]
1267 )
1268 UL_BUILD_INIT([libmount_mountfd_support])
1269 UL_REQUIRES_BUILD([libmount_mountfd_support], [libmount])
1270 UL_REQUIRES_LINUX([libmount_mountfd_support])
1271 UL_REQUIRES_HAVE([libmount_mountfd_support], [mountfd_api], [mount FDs based API])
1272 UL_REQUIRES_HAVE([libmount_mountfd_support], [linux_mount_h], [linux/mount.h])
1273 AS_IF([test "x$build_libmount_mountfd_support" = xyes ], [
1274   AC_DEFINE([USE_LIBMOUNT_MOUNTFD_SUPPORT], [1], [Enable support for new mount FD based kernel API])
1275 ])
1276
1277
1278 dnl
1279 dnl libsmartcols
1280 dnl
1281 AC_ARG_ENABLE([libsmartcols],
1282   AS_HELP_STRING([--disable-libsmartcols], [do not build libsmartcols]),
1283   [], [UL_DEFAULT_ENABLE([libsmartcols], [yes])]
1284 )
1285 UL_BUILD_INIT([libsmartcols])
1286 AM_CONDITIONAL([BUILD_LIBSMARTCOLS], [test "x$build_libsmartcols" = xyes])
1287
1288 AC_SUBST([LIBSMARTCOLS_VERSION])
1289 AC_SUBST([LIBSMARTCOLS_VERSION_INFO])
1290 AC_DEFINE_UNQUOTED([LIBSMARTCOLS_VERSION], ["$LIBSMARTCOLS_VERSION"], [libsmartcols version string])
1291
1292
1293 dnl
1294 dnl libfdisk
1295 dnl
1296 AC_ARG_ENABLE([libfdisk],
1297   AS_HELP_STRING([--disable-libfdisk], [do not build libfdisk]),
1298   [], [UL_DEFAULT_ENABLE([libfdisk], [check])]
1299 )
1300 UL_BUILD_INIT([libfdisk])
1301 UL_REQUIRES_BUILD([libfdisk], [libuuid])
1302 AM_CONDITIONAL([BUILD_LIBFDISK], [test "x$build_libfdisk" = xyes])
1303 AM_CONDITIONAL([BUILD_LIBFDISK_TESTS], [test "x$build_libfdisk" = xyes && test "x$enable_static" = xyes])
1304
1305 AS_IF([test "x$build_libblkid" = xyes],
1306   [LIBFDISK_PC_REQUIRES="uuid blkid"],[LIBFDISK_PC_REQUIRES="uuid"])
1307 AC_SUBST([LIBFDISK_PC_REQUIRES])
1308
1309 AC_SUBST([LIBFDISK_VERSION])
1310 AC_SUBST([LIBFDISK_MAJOR_VERSION], $PACKAGE_VERSION_MAJOR)
1311 AC_SUBST([LIBFDISK_MINOR_VERSION], $PACKAGE_VERSION_MINOR)
1312 AC_SUBST([LIBFDISK_PATCH_VERSION], $PACKAGE_VERSION_RELEASE)
1313 AC_SUBST([LIBFDISK_VERSION_INFO])
1314 AC_DEFINE_UNQUOTED([LIBFDISK_VERSION], ["$LIBFDISK_VERSION"], [libfdisk version string])
1315
1316
1317 AC_ARG_ENABLE([fdisks],
1318   AS_HELP_STRING([--disable-fdisks], [do not build fdisk(8), sfdisk(8) and cfdisk(8)]),
1319   [], [UL_DEFAULT_ENABLE([fdisks], [check])]
1320 )
1321 enable_fdisk=$enable_fdisks
1322 enable_sfdisk=$enable_fdisks
1323 enable_cfdisk=$enable_fdisks
1324
1325 UL_BUILD_INIT([fdisk])
1326 UL_REQUIRES_HAVE([fdisk], [openat], [openat functions])
1327 UL_REQUIRES_HAVE([fdisk], [dirfd,ddfd], [dirfd or ddfd function])
1328 UL_REQUIRES_BUILD([fdisk], [libfdisk])
1329 UL_REQUIRES_BUILD([fdisk], [libsmartcols])
1330 AM_CONDITIONAL([BUILD_FDISK], [test "x$build_fdisk" = xyes])
1331
1332
1333 UL_BUILD_INIT([sfdisk])
1334 UL_REQUIRES_HAVE([sfdisk], [openat], [openat functions])
1335 UL_REQUIRES_HAVE([sfdisk], [dirfd,ddfd], [dirfd or ddfd function])
1336 UL_REQUIRES_BUILD([sfdisk], [libfdisk])
1337 UL_REQUIRES_BUILD([sfdisk], [libsmartcols])
1338 AM_CONDITIONAL([BUILD_SFDISK], [test "x$build_sfdisk" = xyes])
1339
1340
1341 UL_BUILD_INIT([cfdisk])
1342 UL_REQUIRES_BUILD([cfdisk], [libfdisk])
1343 UL_REQUIRES_BUILD([cfdisk], [libsmartcols])
1344 UL_REQUIRES_HAVE([cfdisk], [open_memstream], [open_memstream function])
1345 UL_REQUIRES_HAVE([cfdisk], [ncursesw,slang,ncurses], [ncursesw, ncurses or slang library])
1346 AM_CONDITIONAL([BUILD_CFDISK], [test "x$build_cfdisk" = xyes])
1347
1348
1349 AC_ARG_ENABLE([mount],
1350   AS_HELP_STRING([--disable-mount], [do not build mount(8) and umount(8)]),
1351   [], [UL_DEFAULT_ENABLE([mount], [check])]
1352 )
1353 UL_BUILD_INIT([mount])
1354 UL_REQUIRES_LINUX([mount])
1355 UL_REQUIRES_BUILD([mount], [libmount])
1356 AM_CONDITIONAL([BUILD_MOUNT], [test "x$build_mount" = xyes])
1357
1358
1359 AC_ARG_ENABLE([losetup],
1360   AS_HELP_STRING([--disable-losetup], [do not build losetup]),
1361   [], [UL_DEFAULT_ENABLE([losetup], [check])]
1362 )
1363 UL_BUILD_INIT([losetup])
1364 UL_REQUIRES_LINUX([losetup])
1365 UL_REQUIRES_BUILD([losetup], [libsmartcols])
1366 AM_CONDITIONAL([BUILD_LOSETUP], [test "x$build_losetup" = xyes])
1367
1368 AC_ARG_ENABLE([zramctl],
1369   AS_HELP_STRING([--disable-zramctl], [do not build zramctl]),
1370   [], [UL_DEFAULT_ENABLE([zramctl], [check])]
1371 )
1372 UL_BUILD_INIT([zramctl])
1373 UL_REQUIRES_LINUX([zramctl])
1374 UL_REQUIRES_BUILD([zramctl], [libsmartcols])
1375 AM_CONDITIONAL([BUILD_ZRAMCTL], [test "x$build_zramctl" = xyes])
1376
1377 AC_ARG_ENABLE([fsck],
1378   AS_HELP_STRING([--disable-fsck], [do not build fsck]),
1379   [], [UL_DEFAULT_ENABLE([fsck], [check])]
1380 )
1381 UL_BUILD_INIT([fsck])
1382 UL_REQUIRES_BUILD([fsck], [libmount])
1383 AM_CONDITIONAL([BUILD_FSCK], [test "x$build_fsck" = xyes])
1384
1385
1386 AC_ARG_ENABLE([partx],
1387   AS_HELP_STRING([--disable-partx], [do not build addpart, delpart, partx]),
1388   [], [UL_DEFAULT_ENABLE([partx], [check])]
1389 )
1390 UL_BUILD_INIT([partx])
1391 UL_REQUIRES_LINUX([partx])
1392 UL_REQUIRES_BUILD([partx], [libblkid])
1393 UL_REQUIRES_BUILD([partx], [libsmartcols])
1394 AM_CONDITIONAL([BUILD_PARTX], [test "x$build_partx" = xyes])
1395
1396
1397 AC_ARG_ENABLE([uuidd],
1398   AS_HELP_STRING([--disable-uuidd], [do not build the uuid daemon]),
1399   [], [UL_DEFAULT_ENABLE([uuidd], [check])]
1400 )
1401 UL_BUILD_INIT([uuidd])
1402 UL_REQUIRES_BUILD([uuidd], [libuuid])
1403 UL_REQUIRES_HAVE([uuidd], [timer], [timer_create function])
1404 UL_REQUIRES_HAVE([uuidd], [sys_signalfd_h], [sys/signalfd.h header])
1405 AS_IF([test "x$build_uuidd" = xyes || test "x$enable_libuuid_force_uuidd" = xyes], [
1406   AC_DEFINE([HAVE_UUIDD], [1], [Define to 1 if you want to use uuid daemon.])
1407 ])
1408 AM_CONDITIONAL([BUILD_UUIDD], [test "x$build_uuidd" = xyes])
1409
1410
1411 AC_ARG_ENABLE([uuidgen],
1412   AS_HELP_STRING([--disable-uuidgen], [do not build uuidgen]),
1413   [], [UL_DEFAULT_ENABLE([uuidgen], [check])]
1414 )
1415 UL_BUILD_INIT([uuidgen])
1416 UL_REQUIRES_BUILD([uuidgen], [libuuid])
1417 AM_CONDITIONAL([BUILD_UUIDGEN], [test "x$build_uuidgen" = xyes])
1418
1419 UL_BUILD_INIT([uuidparse], [check])
1420 UL_REQUIRES_BUILD([uuidparse], [libuuid])
1421 UL_REQUIRES_BUILD([uuidparse], [libsmartcols])
1422 AM_CONDITIONAL([BUILD_UUIDPARSE], [test "x$build_uuidparse" = xyes])
1423
1424 AC_ARG_ENABLE([blkid],
1425   AS_HELP_STRING([--disable-blkid], [do not build blkid(8)]),
1426   [], [UL_DEFAULT_ENABLE([blkid], [check])]
1427 )
1428 UL_BUILD_INIT([blkid])
1429 UL_REQUIRES_BUILD([blkid], [libblkid])
1430 AM_CONDITIONAL([BUILD_BLKID], [test "x$build_blkid" = xyes])
1431
1432 UL_BUILD_INIT([findfs], [check])
1433 UL_REQUIRES_BUILD([findfs], [libblkid])
1434 AM_CONDITIONAL([BUILD_FINDFS], [test "x$build_findfs" = xyes])
1435
1436 AC_ARG_ENABLE([wipefs],
1437   AS_HELP_STRING([--disable-wipefs], [do not build wipefs]),
1438   [], [UL_DEFAULT_ENABLE([wipefs], [check])]
1439 )
1440 UL_BUILD_INIT([wipefs])
1441 UL_REQUIRES_BUILD([wipefs], [libblkid])
1442 UL_REQUIRES_BUILD([wipefs], [libsmartcols])
1443 AM_CONDITIONAL([BUILD_WIPEFS], [test "x$build_wipefs" = xyes])
1444
1445 UL_BUILD_INIT([findmnt], [check])
1446 UL_REQUIRES_BUILD([findmnt], [libmount])
1447 UL_REQUIRES_BUILD([findmnt], [libblkid])
1448 UL_REQUIRES_BUILD([findmnt], [libsmartcols])
1449 AM_CONDITIONAL([BUILD_FINDMNT], [test "x$build_findmnt" = xyes])
1450
1451
1452 AC_ARG_ENABLE([mountpoint],
1453   AS_HELP_STRING([--disable-mountpoint], [do not build mountpoint]),
1454   [], [UL_DEFAULT_ENABLE([mountpoint], [check])]
1455 )
1456 UL_BUILD_INIT([mountpoint])
1457 UL_REQUIRES_BUILD([mountpoint], [libmount])
1458 AM_CONDITIONAL([BUILD_MOUNTPOINT], [test "x$build_mountpoint" = xyes])
1459
1460
1461 AC_ARG_ENABLE([fallocate],
1462   AS_HELP_STRING([--disable-fallocate], [do not build fallocate]),
1463   [], [UL_DEFAULT_ENABLE([fallocate], [check])]
1464 )
1465 UL_BUILD_INIT([fallocate])
1466 UL_REQUIRES_LINUX([fallocate])
1467 UL_REQUIRES_SYSCALL_CHECK([fallocate], [UL_CHECK_SYSCALL([fallocate])])
1468 AM_CONDITIONAL([BUILD_FALLOCATE], [test "x$build_fallocate" = xyes])
1469
1470 AS_IF([test "x$build_fallocate" = xyes], [
1471   dnl check for valid fallocate() function
1472   dnl with 32 bits glibc 2.10, fallocate() exists but not fallocate64()
1473   dnl when _FILE_OFFSET_BITS==64, fallocate() is redirect to fallocate64()
1474   dnl and program can't be linked.
1475   dnl AC_CHECK_FUNC can't catch such errors since it's redefining
1476   dnl function prototype.
1477   AC_MSG_CHECKING([for valid fallocate() function])
1478   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1479 #ifdef HAVE_UNISTD_H
1480 # include <unistd.h>
1481 #endif
1482 #ifdef HAVE_SYS_TYPES_H
1483 # include <sys/types.h>
1484 #endif
1485 #ifdef HAVE_LINUX_FALLOC_H
1486 # include <linux/falloc.h>
1487 #endif
1488 #ifdef HAVE_FCNTL_H
1489 # include <fcntl.h>
1490 #endif
1491 ]],[[
1492    long ret;
1493    ret = fallocate(0, FALLOC_FL_KEEP_SIZE, 0xfffffffful, 0xfffffffful);
1494    if (ret != 0) {
1495       return 1;
1496    }
1497    ]])],[
1498   AC_MSG_RESULT([yes])
1499   AC_DEFINE([HAVE_FALLOCATE], [1], [Have valid fallocate() function])],[
1500   AC_MSG_RESULT([no])])
1501 ])
1502
1503 AS_IF([test "x$build_fallocate" = xyes], [
1504   dnl check for valid posix_fallocate() function
1505   AC_MSG_CHECKING([for valid posix_fallocate() function])
1506   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1507 #ifdef HAVE_UNISTD_H
1508 # include <unistd.h>
1509 #endif
1510 #ifdef HAVE_SYS_TYPES_H
1511 # include <sys/types.h>
1512 #endif
1513 #ifdef HAVE_LINUX_FALLOC_H
1514 # include <linux/falloc.h>
1515 #endif
1516 #ifdef HAVE_FCNTL_H
1517 # include <fcntl.h>
1518 #endif
1519 ]],[[
1520    long ret;
1521    ret = posix_fallocate(0, 0xfffffffful, 0xfffffffful);
1522    if (ret != 0) {
1523       return 1;
1524    }
1525    ]])],[
1526   AC_MSG_RESULT([yes])
1527   AC_DEFINE([HAVE_POSIX_FALLOCATE], [1], [Have valid posix_fallocate() function])],[
1528   AC_MSG_RESULT([no])])
1529 ])
1530
1531
1532 AC_ARG_ENABLE([unshare],
1533   AS_HELP_STRING([--disable-unshare], [do not build unshare]),
1534   [], [UL_DEFAULT_ENABLE([unshare], [check])]
1535 )
1536 UL_BUILD_INIT([unshare])
1537 UL_REQUIRES_LINUX([unshare])
1538 UL_REQUIRES_SYSCALL_CHECK([unshare], [UL_CHECK_SYSCALL([unshare])])
1539 UL_REQUIRES_HAVE([unshare], [linux_capability_h], [linux/capability.h header file])
1540 AM_CONDITIONAL([BUILD_UNSHARE], [test "x$build_unshare" = xyes])
1541
1542 AC_MSG_CHECKING([for valid unshare() function])
1543 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1544 #include <sched.h>
1545 ]],[[
1546    int ret;
1547    ret = unshare(0);
1548    if (ret != 0) {
1549       return 1;
1550    }
1551    ]])],[
1552   AC_MSG_RESULT([yes])
1553   AC_DEFINE([HAVE_UNSHARE], [1], [Have valid unshare() function])],
1554 [
1555   AC_MSG_RESULT([no])
1556 ])
1557
1558
1559 AC_ARG_ENABLE([nsenter],
1560   AS_HELP_STRING([--disable-nsenter], [do not build nsenter]),
1561   [], [UL_DEFAULT_ENABLE([nsenter], [check])]
1562 )
1563 UL_BUILD_INIT([nsenter])
1564 UL_REQUIRES_LINUX([nsenter])
1565 UL_REQUIRES_HAVE([nsenter], [setns_syscall], [setns syscall])
1566 AM_CONDITIONAL([BUILD_NSENTER], [test "x$build_nsenter" = xyes])
1567
1568 AC_MSG_CHECKING([for valid setns() function])
1569 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1570 #include <sched.h>
1571 #include <errno.h>
1572 ]],[[
1573    int ret;
1574    ret = setns(0, 0);
1575    if (ret != EINVAL && ret != EBADF && ret != EPERM) {
1576       return 1;
1577    }
1578    ]])],[
1579   AC_MSG_RESULT([yes])
1580   AC_DEFINE([HAVE_SETNS], [1], [Have valid setns() function])],
1581 [
1582   AC_MSG_RESULT([no])
1583 ])
1584
1585
1586 AC_ARG_WITH([cap_ng],
1587   AS_HELP_STRING([--without-cap-ng], [compile without libcap-ng]),
1588   [], [with_cap_ng=auto]
1589 )
1590 AS_IF([test "x$with_cap_ng" = xno], [
1591   AM_CONDITIONAL([HAVE_CAP_NG], [false])
1592   have_cap_ng=no
1593 ],[
1594   UL_CHECK_LIB([cap-ng], [capng_apply], [cap_ng])
1595 ])
1596
1597
1598 AC_ARG_ENABLE([setpriv],
1599   AS_HELP_STRING([--disable-setpriv], [do not build setpriv]),
1600   [], [UL_DEFAULT_ENABLE([setpriv], [check])]
1601 )
1602 UL_BUILD_INIT([setpriv])
1603 UL_REQUIRES_LINUX([setpriv])
1604 UL_REQUIRES_HAVE([setpriv], [linux_securebits_h], [linux/securebits.h header file])
1605 UL_REQUIRES_HAVE([setpriv], [linux_capability_h], [linux/capability.h header file])
1606 UL_REQUIRES_HAVE([setpriv], [cap_ng], [libcap-ng library])
1607 AM_CONDITIONAL([BUILD_SETPRIV], [test "x$build_setpriv" = xyes])
1608
1609 AC_ARG_ENABLE([hardlink],
1610   AS_HELP_STRING([--disable-hardlink], [do not build hardlink]),
1611   [], [UL_DEFAULT_ENABLE([hardlink], [check])]
1612 )
1613 UL_BUILD_INIT([hardlink])
1614 AM_CONDITIONAL([BUILD_HARDLINK], [test "x$build_hardlink" = xyes])
1615
1616
1617 AC_ARG_ENABLE([eject],
1618   AS_HELP_STRING([--disable-eject], [do not build eject]),
1619   [], [UL_DEFAULT_ENABLE([eject], [check])]
1620 )
1621 UL_BUILD_INIT([eject])
1622 UL_REQUIRES_LINUX([eject])
1623 UL_REQUIRES_BUILD([eject], [libmount])
1624 AM_CONDITIONAL([BUILD_EJECT], [test "x$build_eject" = xyes])
1625
1626
1627 AC_ARG_ENABLE([agetty],
1628   AS_HELP_STRING([--disable-agetty], [do not build agetty]),
1629   [], [UL_DEFAULT_ENABLE([agetty], [check])]
1630 )
1631 UL_BUILD_INIT([agetty])
1632 UL_REQUIRES_HAVE([agetty], [utmpx_h], [utmpx.h header])
1633 UL_REQUIRES_HAVE([agetty], [gnu_utmpx], [GNU utmpx functions])
1634 AM_CONDITIONAL([BUILD_AGETTY], [test "x$build_agetty" = xyes])
1635 AS_IF([test "x$have_futimens" = xyes && test "x$have_inotify_init1" = xyes ], [
1636   AC_DEFINE([AGETTY_RELOAD], [1], [Enable agetty --reload feature])
1637 ],[
1638   AC_MSG_WARN([futimens or inotify_init1 not found; agetty(8) will not provide ---reload functionality])
1639 ])
1640
1641
1642 AC_ARG_ENABLE([plymouth_support],
1643   AS_HELP_STRING([--disable-plymouth_support], [do not care about plymouth in sulogin(8) and agetty(8)]),
1644   [], [enable_plymouth_support=check]
1645 )
1646 UL_BUILD_INIT([plymouth_support])
1647 UL_REQUIRES_HAVE([plymouth_support], [tiocglcktrmios], [TIOCGLCKTRMIOS flag])
1648 UL_REQUIRES_HAVE([plymouth_support], [sock_cloexec], [SOCK_CLOEXEC flag])
1649 UL_REQUIRES_HAVE([plymouth_support], [sock_nonblock], [SOCK_NONBLOCK flag])
1650 UL_REQUIRES_HAVE([plymouth_support], [so_passcred], [SO_PASSCRED flag])
1651 AM_CONDITIONAL([USE_PLYMOUTH_SUPPORT], [test "x$build_plymouth_support" = xyes])
1652 AS_IF([test "x$build_plymouth_support" = xyes ], [
1653     AC_DEFINE([USE_PLYMOUTH_SUPPORT], [1], [Enable plymouth support feature for sulogin and agetty])
1654 ])
1655
1656
1657 AC_ARG_WITH([libz],
1658   AS_HELP_STRING([--without-libz], [compile without libz]),
1659   [], [with_libz=auto]
1660 )
1661 AS_IF([test "x$with_libz" = xno], [have_z=no], [
1662   AC_CHECK_LIB([z], [crc32], [have_z=yes], [have_z=no])
1663 ])
1664
1665 AC_ARG_WITH([libmagic],
1666   AS_HELP_STRING([--without-libmagic], [compile without libmagic]),
1667   [], [with_libmagic=auto]
1668 )
1669 AS_IF([test "x$with_libmagic" = xno], [have_magic=no], [
1670   AC_CHECK_LIB([magic], [magic_open], [
1671     AC_CHECK_HEADER(magic.h, [
1672       AC_DEFINE([HAVE_MAGIC], [1], [Define to 1 if you have the libmagic present.])
1673       MAGIC_LIBS="-lmagic"
1674     ])
1675   ])
1676 ])
1677 AC_SUBST([MAGIC_LIBS])
1678
1679
1680 AC_ARG_ENABLE([cramfs],
1681   AS_HELP_STRING([--disable-cramfs], [do not build fsck.cramfs, mkfs.cramfs]),
1682   [], [UL_DEFAULT_ENABLE([cramfs], [check])]
1683 )
1684 UL_BUILD_INIT([cramfs])
1685 UL_REQUIRES_HAVE([cramfs], [z], [z library])
1686 AM_CONDITIONAL([BUILD_CRAMFS], [test "x$build_cramfs" = xyes])
1687
1688
1689 AC_ARG_ENABLE([bfs],
1690   AS_HELP_STRING([--disable-bfs], [do not build mkfs.bfs]),
1691   [], [UL_DEFAULT_ENABLE([bfs], [yes])]
1692 )
1693 UL_BUILD_INIT([bfs])
1694 AM_CONDITIONAL([BUILD_BFS], [test "x$build_bfs" = xyes])
1695
1696
1697 AC_ARG_ENABLE([minix],
1698   AS_HELP_STRING([--disable-minix], [do not build fsck.minix, mkfs.minix]),
1699   [], [UL_DEFAULT_ENABLE([minix], [yes])]
1700 )
1701 UL_BUILD_INIT([minix])
1702 AM_CONDITIONAL([BUILD_MINIX], [test "x$build_minix" = xyes])
1703
1704
1705 AC_ARG_ENABLE([fdformat],
1706   AS_HELP_STRING([--enable-fdformat], [build fdformat]),
1707   [], [UL_DEFAULT_ENABLE([fdformat], [no])]
1708 )
1709 UL_BUILD_INIT([fdformat])
1710 UL_REQUIRES_LINUX([fdformat])
1711 AM_CONDITIONAL([BUILD_FDFORMAT], [test "x$build_fdformat" = xyes])
1712
1713
1714 AC_ARG_ENABLE([hwclock],
1715   AS_HELP_STRING([--disable-hwclock], [do not build hwclock]),
1716   [], [UL_DEFAULT_ENABLE([hwclock], [check])]
1717 )
1718 have_linuxdummy=$linux_os
1719
1720 UL_BUILD_INIT([hwclock])
1721 UL_REQUIRES_HAVE([hwclock], [io, linuxdummy], [ioperm iopl function or Linux])
1722 AM_CONDITIONAL([BUILD_HWCLOCK], [test "x$build_hwclock" = xyes])
1723
1724 AC_ARG_ENABLE([hwclock_cmos],
1725   AS_HELP_STRING([--disable-hwclock-cmos], [do not use CMOS clock]),
1726   [], [enable_hwclock_cmos=check]
1727 )
1728 UL_BUILD_INIT([hwclock_cmos])
1729 UL_REQUIRES_BUILD([hwclock_cmos], [hwclock])
1730 UL_REQUIRES_ARCH([hwclock_cmos], [i?86-*,x86_64*])
1731 AM_CONDITIONAL([USE_HWCLOCK_CMOS], [test "x$build_hwclock_cmos" = xyes])
1732 AS_IF([test "x$build_hwclock_cmos" = xyes ], [
1733     AC_DEFINE([USE_HWCLOCK_CMOS], [1], [Define to 1 if want to use CMOS clock.])
1734 ])
1735
1736 AC_ARG_ENABLE([hwclock_gplv3],
1737   AS_HELP_STRING([--disable-hwclock-gplv3], [do not use datetime parsing GPLv3 code]),
1738   [], [enable_hwclock_gplv3=yes]
1739 )
1740 AM_CONDITIONAL([USE_HWCLOCK_GPLv3_DATETIME], [test "x$enable_hwclock_gplv3" = xyes])
1741 AS_IF([test "x$enable_hwclock_gplv3" = xyes ], [
1742     AC_DEFINE([USE_HWCLOCK_GPLv3_DATETIME], [1], [use datetime parsing GPLv3 code to hwclock])
1743 ])
1744
1745
1746 AC_ARG_ENABLE([mkfs],
1747   AS_HELP_STRING([--disable-mkfs], [do not build mkfs(8)]),
1748   [], [UL_DEFAULT_ENABLE([mkfs], [check])]
1749 )
1750 UL_BUILD_INIT([mkfs])
1751 AM_CONDITIONAL([BUILD_MKFS], [test "x$build_mkfs" = xyes])
1752
1753 UL_BUILD_INIT([isosize], [yes])
1754 AM_CONDITIONAL([BUILD_ISOSIZE], [test "x$build_isosize" = xyes])
1755
1756
1757 AC_ARG_ENABLE([fstrim],
1758   AS_HELP_STRING([--disable-fstrim], [do not build fstrim(8)]),
1759   [], [UL_DEFAULT_ENABLE([fstrim], [check])]
1760 )
1761 UL_BUILD_INIT([fstrim])
1762 UL_REQUIRES_LINUX([fstrim])
1763 UL_REQUIRES_BUILD([fstrim], [libmount])
1764 AM_CONDITIONAL([BUILD_FSTRIM], [test "x$build_fstrim" = xyes])
1765
1766
1767 AC_ARG_ENABLE([swapon],
1768   AS_HELP_STRING([--disable-swapon], [do not build swapon(8) and swapoff(8)]),
1769   [], [UL_DEFAULT_ENABLE([swapon], [check])]
1770 )
1771 UL_BUILD_INIT([swapon])
1772 UL_REQUIRES_LINUX([swapon])
1773 UL_REQUIRES_SYSCALL_CHECK([swapon], [UL_CHECK_SYSCALL([swapon])], [swapon])
1774 UL_REQUIRES_SYSCALL_CHECK([swapon], [UL_CHECK_SYSCALL([swapoff])], [swapoff])
1775 UL_REQUIRES_BUILD([swapon], [libblkid])
1776 UL_REQUIRES_BUILD([swapon], [libmount])
1777 UL_REQUIRES_BUILD([swapon], [libsmartcols])
1778 AM_CONDITIONAL([BUILD_SWAPON], [test "x$build_swapon" = xyes])
1779 AC_CHECK_FUNCS([swapon])
1780 AC_CHECK_FUNCS([swapoff])
1781
1782
1783 UL_BUILD_INIT([lsblk], [check])
1784 UL_REQUIRES_LINUX([lsblk])
1785 UL_REQUIRES_BUILD([lsblk], [libblkid])
1786 UL_REQUIRES_BUILD([lsblk], [libmount])
1787 UL_REQUIRES_BUILD([lsblk], [libsmartcols])
1788 AM_CONDITIONAL([BUILD_LSBLK], [test "x$build_lsblk" = xyes])
1789
1790
1791 AC_ARG_ENABLE([lscpu],
1792   AS_HELP_STRING([--disable-lscpu], [do not build lscpu]),
1793   [], [UL_DEFAULT_ENABLE([lscpu], [check])]
1794 )
1795 UL_BUILD_INIT([lscpu])
1796 UL_REQUIRES_LINUX([lscpu])
1797 UL_REQUIRES_BUILD([lscpu], [libsmartcols])
1798 UL_REQUIRES_HAVE([lscpu], [cpu_set_t], [cpu_set_t type])
1799 AM_CONDITIONAL([BUILD_LSCPU], [test "x$build_lscpu" = xyes])
1800
1801 AC_ARG_ENABLE([lsfd],
1802   AS_HELP_STRING([--disable-lsfd], [do not build lsfd]),
1803   [], [UL_DEFAULT_ENABLE([lsfd], [check])]
1804 )
1805 UL_BUILD_INIT([lsfd])
1806 UL_REQUIRES_LINUX([lsfd])
1807 UL_REQUIRES_BUILD([lsfd], [libsmartcols])
1808 AM_CONDITIONAL([BUILD_LSFD], [test "x$build_lsfd" = xyes])
1809
1810 AC_ARG_ENABLE([lslogins],
1811   AS_HELP_STRING([--disable-lslogins], [do not build lslogins]),
1812   [], [UL_DEFAULT_ENABLE([lslogins], [check])]
1813 )
1814 UL_BUILD_INIT([lslogins])
1815 UL_REQUIRES_BUILD([lslogins], [libsmartcols])
1816 UL_REQUIRES_HAVE([lslogins], [shadow_h], [shadow.h header])
1817 UL_REQUIRES_HAVE([lslogins], [utmpx_h], [utmpx.h header])
1818 UL_REQUIRES_HAVE([lslogins], [gnu_utmpx], [GNU utmpx functions])
1819 AM_CONDITIONAL([BUILD_LSLOGINS], [test "x$build_lslogins" = xyes])
1820
1821
1822 UL_BUILD_INIT([chcpu], [check])
1823 UL_REQUIRES_LINUX([chcpu])
1824 UL_REQUIRES_HAVE([chcpu], [cpu_set_t], [cpu_set_t type])
1825 AM_CONDITIONAL([BUILD_CHCPU], [test "x$build_chcpu" = xyes])
1826
1827
1828 AC_ARG_ENABLE([wdctl],
1829   AS_HELP_STRING([--disable-wdctl], [do not build wdctl]),
1830   [], [UL_DEFAULT_ENABLE([wdctl], [check])]
1831 )
1832 UL_BUILD_INIT([wdctl])
1833 UL_REQUIRES_LINUX([wdctl])
1834 UL_REQUIRES_BUILD([wdctl], [libsmartcols])
1835 UL_REQUIRES_HAVE([wdctl], [linux_watchdog_h], [linux/watchdog.h header file])
1836 AM_CONDITIONAL([BUILD_WDCTL], [test "x$build_wdctl" = xyes])
1837
1838
1839 UL_BUILD_INIT([swaplabel], [check])
1840 UL_REQUIRES_BUILD([swaplabel], [libblkid])
1841 AM_CONDITIONAL([BUILD_SWAPLABEL], [test "x$build_swaplabel" = xyes])
1842
1843
1844 UL_BUILD_INIT([mkswap], [yes])
1845 AM_CONDITIONAL([BUILD_MKSWAP], [test "x$build_mkswap" = xyes])
1846 AS_IF([test "x$build_mkswap" = xyes && test "x$build_libuuid" != xyes], [
1847   AC_MSG_WARN([uuid library is not found; mkswap(8) will not generate UUIDs])
1848 ])
1849
1850
1851 AC_ARG_ENABLE([cal],
1852   AS_HELP_STRING([--disable-cal], [do not build cal]),
1853   [], [UL_DEFAULT_ENABLE([cal], [check])]
1854 )
1855 UL_BUILD_INIT([cal])
1856 AM_CONDITIONAL([BUILD_CAL], [test "x$build_cal" = xyes])
1857
1858 AC_ARG_ENABLE([logger],
1859   AS_HELP_STRING([--disable-logger], [do not build logger]),
1860   [], [UL_DEFAULT_ENABLE([logger], [check])]
1861 )
1862 UL_BUILD_INIT([logger])
1863 AM_CONDITIONAL([BUILD_LOGGER], [test "x$build_logger" = xyes])
1864
1865 UL_BUILD_INIT([look], [yes])
1866 AM_CONDITIONAL([BUILD_LOOK], [test "x$build_look" = xyes])
1867
1868 UL_BUILD_INIT([mcookie], [yes])
1869 AM_CONDITIONAL([BUILD_MCOOKIE], [test "x$build_mcookie" = xyes])
1870
1871 UL_BUILD_INIT([namei], [yes])
1872 AM_CONDITIONAL([BUILD_NAMEI], [test "x$build_namei" = xyes])
1873
1874 matriplet="$($CC -print-multiarch 2>/dev/null || true)"
1875 if test "x$matriplet" != "x"; then
1876   AC_DEFINE_UNQUOTED([MULTIARCHTRIPLET], ["$matriplet"],
1877   ["Multi-arch triplet for whereis library search path"])
1878 fi
1879 AC_ARG_ENABLE([whereis],
1880   AS_HELP_STRING([--disable-whereis], [do not build whereis]),
1881   [], [UL_DEFAULT_ENABLE([whereis], [check])]
1882 )
1883 UL_BUILD_INIT([whereis])
1884 AM_CONDITIONAL([BUILD_WHEREIS], [test "x$build_whereis" = xyes])
1885
1886 AC_ARG_ENABLE([pipesz],
1887   AS_HELP_STRING([--disable-pipesz], [do not build pipesz]),
1888   [], [UL_DEFAULT_ENABLE([pipesz], [check])]
1889 )
1890 UL_BUILD_INIT([pipesz])
1891 UL_REQUIRES_LINUX([pipesz])
1892 AM_CONDITIONAL([BUILD_PIPESZ], [test "x$build_pipesz" = xyes])
1893
1894 UL_BUILD_INIT([fadvise], [check])
1895 UL_REQUIRES_LINUX([fadvise])
1896 AM_CONDITIONAL([BUILD_FADVISE], [test "x$build_fadvise" = xyes])
1897
1898 AC_ARG_ENABLE([waitpid],
1899   AS_HELP_STRING([--disable-waitpid], [do not build waitpid]),
1900   [], [UL_DEFAULT_ENABLE([waitpid], [check])]
1901 )
1902 UL_BUILD_INIT([waitpid])
1903 UL_REQUIRES_LINUX([waitpid])
1904 UL_REQUIRES_SYSCALL_CHECK([waitpid], [UL_CHECK_SYSCALL([pidfd_open])], [pidfd_open])
1905 AM_CONDITIONAL([BUILD_WAITPID], [test "x$build_waitpid" = xyes])
1906
1907 UL_BUILD_INIT([enosys], [check])
1908 UL_REQUIRES_LINUX([enosys])
1909 AS_IF([test "x$build_enosys" = xyes], [
1910   AC_MSG_CHECKING([for valid audit arch])
1911   AC_COMPILE_IFELSE(
1912     [AC_LANG_PROGRAM([[#include "${srcdir}/include/audit-arch.h"]])],
1913     [AC_MSG_RESULT([yes])],
1914     [AC_MSG_RESULT([no])
1915      build_enosys=no
1916     ])
1917 ])
1918 AM_CONDITIONAL([BUILD_ENOSYS], [test "x$build_enosys" = xyes])
1919
1920 UL_BUILD_INIT([lsclocks], [check])
1921 UL_REQUIRES_LINUX([lsclocks])
1922 AM_CONDITIONAL([BUILD_LSCLOCKS], [test "x$build_lsclocks" = xyes])
1923
1924 UL_BUILD_INIT([getopt], [yes])
1925 AM_CONDITIONAL([BUILD_GETOPT], [test "x$build_getopt" = xyes])
1926
1927
1928 UL_BUILD_INIT([blockdev], [check])
1929 UL_REQUIRES_LINUX([blockdev])
1930 AM_CONDITIONAL([BUILD_BLOCKDEV], [test "x$build_blockdev" = xyes])
1931
1932
1933 UL_BUILD_INIT([prlimit], [check])
1934 UL_REQUIRES_LINUX([prlimit])
1935 UL_REQUIRES_BUILD([prlimit], [libsmartcols])
1936 UL_REQUIRES_SYSCALL_CHECK([prlimit], [UL_CHECK_SYSCALL([prlimit64])], [prlimit64])
1937 AM_CONDITIONAL([BUILD_PRLIMIT], [test "x$build_prlimit" = xyes])
1938 AS_IF([test "x$build_prlimit" = xyes], [
1939   dnl check for valid prlimit() function
1940   AC_MSG_CHECKING([for valid prlimit() function])
1941   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1942 #include <sys/types.h>
1943 #include <sys/time.h>
1944 #include <sys/resource.h>
1945 #include <stddef.h>
1946 ]],[[
1947    int ret;
1948    ret = prlimit(0, RLIMIT_AS, NULL, NULL);
1949    if (ret != 0) {
1950       return 1;
1951    }
1952    ]])],[
1953   AC_MSG_RESULT([yes])
1954   AC_DEFINE([HAVE_PRLIMIT], [1], [Have valid prlimit() function])],[
1955   AC_MSG_RESULT([no])])
1956 ])
1957
1958
1959
1960 UL_BUILD_INIT([lslocks], [check])
1961 UL_REQUIRES_LINUX([lslocks])
1962 UL_REQUIRES_BUILD([lslocks], [libmount])
1963 UL_REQUIRES_BUILD([lslocks], [libsmartcols])
1964 AM_CONDITIONAL([BUILD_LSLOCKS], [test "x$build_lslocks" = xyes])
1965
1966
1967 AC_ARG_ENABLE([switch_root],
1968   AS_HELP_STRING([--disable-switch_root], [do not build switch_root]),
1969   [], [UL_DEFAULT_ENABLE([switch_root], [check])]
1970 )
1971 UL_BUILD_INIT([switch_root])
1972 UL_REQUIRES_LINUX([switch_root])
1973 UL_REQUIRES_HAVE([switch_root], [openat], [openat function])
1974 UL_REQUIRES_HAVE([switch_root], [dirfd,ddfd], [dirfd or ddfd function])
1975 AM_CONDITIONAL([BUILD_SWITCH_ROOT], [test "x$build_switch_root" = xyes])
1976
1977
1978 AC_ARG_ENABLE([pivot_root],
1979   AS_HELP_STRING([--disable-pivot_root], [do not build pivot_root]),
1980   [], [UL_DEFAULT_ENABLE([pivot_root], [check])]
1981 )
1982 UL_BUILD_INIT([pivot_root])
1983 UL_REQUIRES_LINUX([pivot_root])
1984 UL_REQUIRES_SYSCALL_CHECK([pivot_root], [UL_CHECK_SYSCALL([pivot_root])])
1985 AM_CONDITIONAL([BUILD_PIVOT_ROOT], [test "x$build_pivot_root" = xyes])
1986
1987
1988 UL_BUILD_INIT([flock], [check])
1989 UL_REQUIRES_HAVE([flock], [timer], [timer_create/setitimer function])
1990 AM_CONDITIONAL([BUILD_FLOCK], [test "x$build_flock" = xyes])
1991
1992
1993 AC_ARG_ENABLE([lsmem],
1994   AS_HELP_STRING([--disable-lsmem], [do not build lsmem]),
1995   [], [UL_DEFAULT_ENABLE([lsmem], [check])]
1996 )
1997 UL_BUILD_INIT([lsmem])
1998 UL_REQUIRES_LINUX([lsmem])
1999 UL_REQUIRES_BUILD([lsmem], [libsmartcols])
2000 AM_CONDITIONAL([BUILD_LSMEM], [test "x$build_lsmem" = xyes])
2001
2002
2003 AC_ARG_ENABLE([chmem],
2004   AS_HELP_STRING([--disable-chmem], [do not build chmem]),
2005   [], [UL_DEFAULT_ENABLE([chmem], [check])]
2006 )
2007 UL_BUILD_INIT([chmem])
2008 UL_REQUIRES_LINUX([chmem])
2009 AM_CONDITIONAL([BUILD_CHMEM], [test "x$build_chmem" = xyes])
2010
2011
2012 AC_ARG_ENABLE([ipcmk],
2013   AS_HELP_STRING([--disable-ipcmk], [do not build ipcmk]),
2014   [], [UL_DEFAULT_ENABLE([ipcmk], [check])]
2015 )
2016 UL_BUILD_INIT([ipcmk])
2017 UL_EXCLUDE_ARCH([ipcmk], [*darwin*])
2018 AM_CONDITIONAL([BUILD_IPCMK], [test "x$build_ipcmk" = xyes])
2019
2020 AC_ARG_ENABLE([ipcrm],
2021   AS_HELP_STRING([--disable-ipcrm], [do not build ipcrm]),
2022   [], [UL_DEFAULT_ENABLE([ipcrm], [check])]
2023 )
2024 UL_BUILD_INIT([ipcrm])
2025 UL_EXCLUDE_ARCH([ipcrm], [*darwin*])
2026 AM_CONDITIONAL([BUILD_IPCRM], [test "x$build_ipcrm" = xyes])
2027
2028 AC_ARG_ENABLE([ipcs],
2029   AS_HELP_STRING([--disable-ipcs], [do not build ipcs]),
2030   [], [UL_DEFAULT_ENABLE([ipcs], [check])]
2031 )
2032 UL_BUILD_INIT([ipcs])
2033 UL_EXCLUDE_ARCH([ipcs], [*darwin*])
2034 AM_CONDITIONAL([BUILD_IPCS], [test "x$build_ipcs" = xyes])
2035
2036
2037 AC_ARG_ENABLE([irqtop],
2038   AS_HELP_STRING([--disable-irqtop], [do not build irqtop]),
2039   [], [UL_DEFAULT_ENABLE([irqtop], [check])]
2040 )
2041 UL_BUILD_INIT([irqtop])
2042 UL_REQUIRES_LINUX([irqtop])
2043 UL_REQUIRES_BUILD([irqtop], [libsmartcols])
2044 UL_REQUIRES_HAVE([irqtop], [open_memstream], [open_memstream function])
2045 UL_REQUIRES_HAVE([irqtop], [ncursesw,slang,ncurses], [ncursesw, ncurses or slang library])
2046 AM_CONDITIONAL([BUILD_IRQTOP], [test "x$build_irqtop" = xyes])
2047
2048 AC_ARG_ENABLE([lsirq],
2049   AS_HELP_STRING([--disable-lsirq], [do not build lsirq]),
2050   [], [UL_DEFAULT_ENABLE([lsirq], [check])]
2051 )
2052 UL_BUILD_INIT([lsirq])
2053 UL_REQUIRES_LINUX([lsirq])
2054 UL_REQUIRES_BUILD([lsirq], [libsmartcols])
2055 AM_CONDITIONAL([BUILD_LSIRQ], [test "x$build_lsirq" = xyes])
2056
2057
2058 UL_BUILD_INIT([choom], [check])
2059 UL_REQUIRES_LINUX([choom])
2060 AM_CONDITIONAL([BUILD_CHOOM], [test "x$build_choom" = xyes])
2061
2062 UL_BUILD_INIT([lsipc], [check])
2063 UL_REQUIRES_LINUX([lsipc])
2064 UL_REQUIRES_BUILD([lsipc], [libsmartcols])
2065 AM_CONDITIONAL([BUILD_LSIPC], [test "x$build_lsipc" = xyes])
2066
2067 AC_ARG_ENABLE([lsns],
2068   AS_HELP_STRING([--disable-lsns], [do not build lsns]),
2069   [], [UL_DEFAULT_ENABLE([lsns], [check])]
2070 )
2071 UL_BUILD_INIT([lsns])
2072 UL_REQUIRES_LINUX([lsns])
2073 UL_REQUIRES_BUILD([lsns], [libsmartcols])
2074 UL_REQUIRES_BUILD([lsns], [libmount])
2075 AM_CONDITIONAL([BUILD_LSNS], [test "x$build_lsns" = xyes])
2076
2077 UL_BUILD_INIT([renice], [yes])
2078 AM_CONDITIONAL([BUILD_RENICE], [test "x$build_renice" = xyes])
2079
2080
2081 AC_ARG_ENABLE([rfkill],
2082   AS_HELP_STRING([--disable-rfkill], [do not build rfkill]),
2083   [], [UL_DEFAULT_ENABLE([rfkill], [check])]
2084 )
2085 UL_BUILD_INIT([rfkill])
2086 UL_REQUIRES_LINUX([rfkill])
2087 UL_REQUIRES_BUILD([rfkill], [libsmartcols])
2088 AM_CONDITIONAL([BUILD_RFKILL], [test "x$build_rfkill" = xyes])
2089
2090
2091 UL_BUILD_INIT([setpgid], [yes])
2092 AM_CONDITIONAL([BUILD_SETPGID], [test "x$build_setpgid" = xyes])
2093
2094 UL_BUILD_INIT([setsid], [yes])
2095 AM_CONDITIONAL([BUILD_SETSID], [test "x$build_setsid" = xyes])
2096
2097 UL_BUILD_INIT([readprofile], [check])
2098 UL_REQUIRES_LINUX([readprofile])
2099 AM_CONDITIONAL([BUILD_READPROFILE], [test "x$build_readprofile" = xyes])
2100
2101 UL_BUILD_INIT([dmesg], [check])
2102 UL_REQUIRES_LINUX([dmesg])
2103 AM_CONDITIONAL([BUILD_DMESG], [test "x$build_dmesg" = xyes])
2104
2105 UL_BUILD_INIT([ctrlaltdel], [check])
2106 UL_REQUIRES_LINUX([ctrlaltdel])
2107 dnl we assume reboot() to be the 1-argument variant, because even considering
2108 dnl widely used alternative C libraries like uclibc, dietlibc and musl,
2109 dnl reboot() with multiple arguments is yet only found in glibc versions
2110 dnl earlier than 2.x.
2111 UL_REQUIRES_HAVE([ctrlaltdel], [reboot], [reboot function])
2112 AM_CONDITIONAL([BUILD_CTRLALTDEL], [test "x$build_ctrlaltdel" = xyes])
2113
2114 AC_ARG_ENABLE([exch],
2115   AS_HELP_STRING([--disable-exch], [do not build exch]),
2116   [], [UL_DEFAULT_ENABLE([exch], [check])]
2117 )
2118 UL_BUILD_INIT([exch])
2119 UL_REQUIRES_LINUX([exch])
2120 UL_REQUIRES_SYSCALL_CHECK([exch], [UL_CHECK_SYSCALL([renameat2])])
2121 AM_CONDITIONAL([BUILD_EXCH], [test "x$build_exch" = xyes])
2122
2123 UL_BUILD_INIT([fincore], [check])
2124 UL_REQUIRES_LINUX([fincore])
2125 UL_REQUIRES_BUILD([fincore], [libsmartcols])
2126 AM_CONDITIONAL([BUILD_FINCORE], [test "x$build_fincore" = xyes])
2127
2128 UL_BUILD_INIT([fsfreeze], [check])
2129 UL_REQUIRES_LINUX([fsfreeze])
2130 AM_CONDITIONAL([BUILD_FSFREEZE], [test "x$build_fsfreeze" = xyes])
2131
2132 UL_BUILD_INIT([blkdiscard], [check])
2133 UL_REQUIRES_LINUX([blkdiscard])
2134 AM_CONDITIONAL([BUILD_BLKDISCARD], [test "x$build_blkdiscard" = xyes])
2135
2136 UL_BUILD_INIT([blkzone], [check])
2137 UL_REQUIRES_LINUX([blkzone])
2138 UL_REQUIRES_HAVE([blkzone], [linux_blkzoned_h], [linux/blkzoned.h header])
2139 AM_CONDITIONAL([BUILD_BLKZONE], [test "x$build_blkzone" = xyes])
2140
2141 UL_BUILD_INIT([blkpr], [check])
2142 UL_REQUIRES_LINUX([blkpr])
2143 UL_REQUIRES_HAVE([blkpr], [linux_pr_h], [linux/pr.h header])
2144 AM_CONDITIONAL([BUILD_BLKPR], [test "x$build_blkpr" = xyes])
2145
2146 UL_BUILD_INIT([ldattach], [check])
2147 UL_REQUIRES_LINUX([ldattach])
2148 AM_CONDITIONAL([BUILD_LDATTACH], [test "x$build_ldattach" = xyes])
2149
2150 UL_BUILD_INIT([rtcwake], [check])
2151 UL_REQUIRES_LINUX([rtcwake])
2152 AM_CONDITIONAL([BUILD_RTCWAKE], [test "x$build_rtcwake" = xyes])
2153
2154 UL_BUILD_INIT([setarch], [check])
2155 UL_REQUIRES_LINUX([setarch])
2156 AM_CONDITIONAL([BUILD_SETARCH], [test "x$build_setarch" = xyes])
2157
2158
2159 # build_scriptutils= is just configure-only variable to control
2160 # script, scriptreplay and scriptlive
2161 AC_ARG_ENABLE([scriptutils],
2162   AS_HELP_STRING([--disable-scriptutils], [do not build script, scriptreplay and scriptlive]),
2163   [], [UL_DEFAULT_ENABLE([scriptutils], [check])]
2164 )
2165
2166 UL_ENABLE_ALIAS([script], [scriptutils])
2167 UL_BUILD_INIT([script])
2168 UL_REQUIRES_HAVE([script], [pty], [openpty function (libutil)])
2169 AM_CONDITIONAL([BUILD_SCRIPT], [test "x$build_script" = xyes])
2170
2171 UL_ENABLE_ALIAS([scriptreplay], [scriptutils])
2172 UL_BUILD_INIT([scriptreplay])
2173 AM_CONDITIONAL([BUILD_SCRIPTREPLAY], [test "x$build_scriptreplay" = xyes])
2174
2175 UL_ENABLE_ALIAS([scriptlive], [scriptutils])
2176 UL_BUILD_INIT([scriptlive])
2177 UL_REQUIRES_HAVE([scriptlive], [pty], [openpty function (libutil)])
2178 AM_CONDITIONAL([BUILD_SCRIPTLIVE], [test "x$build_scriptlive" = xyes])
2179
2180
2181 UL_BUILD_INIT([col], [check])
2182 UL_REQUIRES_COMPILE([col], [#include <limits.h>], [__GLIBC__], [building for glibc])
2183 AM_CONDITIONAL([BUILD_COL], [test "x$build_col" = xyes])
2184
2185 UL_BUILD_INIT([colcrt], [yes])
2186 AM_CONDITIONAL([BUILD_COLCRT], [test "x$build_colcrt" = xyes])
2187
2188 UL_BUILD_INIT([colrm], [yes])
2189 AM_CONDITIONAL([BUILD_COLRM], [test "x$build_colrm" = xyes])
2190
2191 UL_BUILD_INIT([column], [check])
2192 UL_REQUIRES_BUILD([column], [libsmartcols])
2193 AM_CONDITIONAL([BUILD_COLUMN], [test "x$build_column" = xyes])
2194
2195 UL_BUILD_INIT([hexdump], [yes])
2196 AM_CONDITIONAL([BUILD_HEXDUMP], [test "x$build_hexdump" = xyes])
2197
2198 UL_BUILD_INIT([rev], [yes])
2199 AM_CONDITIONAL([BUILD_REV], [test "x$build_rev" = xyes])
2200
2201
2202 AC_ARG_ENABLE([tunelp],
2203   AS_HELP_STRING([--enable-tunelp], [build tunelp]),
2204   [], [UL_DEFAULT_ENABLE([tunelp], [no])]
2205 )
2206 UL_BUILD_INIT([tunelp])
2207 UL_REQUIRES_LINUX([tunelp])
2208 AM_CONDITIONAL([BUILD_TUNELP], [test "x$build_tunelp" = xyes])
2209
2210
2211 AC_ARG_ENABLE([kill],
2212   AS_HELP_STRING([--disable-kill], [do not build kill]),
2213   [], [UL_DEFAULT_ENABLE([kill], [check])]
2214 )
2215 UL_BUILD_INIT([kill])
2216 UL_REQUIRES_LINUX([kill])
2217 AM_CONDITIONAL([BUILD_KILL], [test "x$build_kill" = xyes])
2218
2219
2220 AC_ARG_ENABLE([last],
2221   AS_HELP_STRING([--disable-last], [do not build last]),
2222   [], [UL_DEFAULT_ENABLE([last], [check])]
2223 )
2224 UL_BUILD_INIT([last])
2225 UL_REQUIRES_HAVE([last], [utmpx_h], [utmpx.h header])
2226 UL_REQUIRES_HAVE([last], [gnu_utmpx], [GNU utmpx functions])
2227 AM_CONDITIONAL([BUILD_LAST], [test "x$build_last" = xyes])
2228
2229
2230 AC_ARG_ENABLE([utmpdump],
2231   AS_HELP_STRING([--disable-utmpdump], [do not build utmpdump]),
2232   [], [UL_DEFAULT_ENABLE([utmpdump], [check])]
2233 )
2234 UL_BUILD_INIT([utmpdump])
2235 UL_REQUIRES_HAVE([utmpdump], [utmpx_h], [utmpx.h header])
2236 UL_REQUIRES_HAVE([utmpdump], [gnu_utmpx], [GNU utmpx functions])
2237 AM_CONDITIONAL([BUILD_UTMPDUMP], [test "x$build_utmpdump" = xyes])
2238
2239
2240 AC_ARG_ENABLE([line],
2241   AS_HELP_STRING([--enable-line], [build line]),
2242   [], [UL_DEFAULT_ENABLE([line], [no])]
2243 )
2244 UL_BUILD_INIT([line])
2245 AM_CONDITIONAL([BUILD_LINE], [test "x$build_line" = xyes])
2246
2247
2248 AC_ARG_ENABLE([mesg],
2249   AS_HELP_STRING([--disable-mesg], [do not build mesg]),
2250   [], [UL_DEFAULT_ENABLE([mesg], [yes])]
2251 )
2252 UL_BUILD_INIT([mesg])
2253 AM_CONDITIONAL([BUILD_MESG], [test "x$build_mesg" = xyes])
2254
2255
2256 AC_ARG_ENABLE([raw],
2257   AS_HELP_STRING([--disable-raw], [do not build raw]),
2258   [], [UL_DEFAULT_ENABLE([raw], [check])]
2259 )
2260 UL_BUILD_INIT([raw])
2261 UL_REQUIRES_LINUX([raw])
2262 UL_REQUIRES_HAVE([raw], [linux_raw_h], [raw.h header file])
2263 AM_CONDITIONAL([BUILD_RAW], [test "x$build_raw" = xyes])
2264
2265
2266 AC_ARG_ENABLE([rename],
2267   AS_HELP_STRING([--disable-rename], [do not build rename]),
2268   [], [UL_DEFAULT_ENABLE([rename], [yes])]
2269 )
2270 UL_BUILD_INIT([rename])
2271 AM_CONDITIONAL([BUILD_RENAME], [test "x$build_rename" = xyes])
2272
2273
2274 AC_ARG_ENABLE([vipw],
2275   AS_HELP_STRING([--enable-vipw], [build vipw]),
2276   [], [UL_DEFAULT_ENABLE([vipw], [no])]
2277 )
2278 UL_BUILD_INIT([vipw])
2279 UL_REQUIRES_HAVE([vipw], [shadow_h], [shadow.h header])
2280 AM_CONDITIONAL([BUILD_VIPW], [test "x$build_vipw" = xyes])
2281
2282
2283 AC_ARG_ENABLE([newgrp],
2284   AS_HELP_STRING([--enable-newgrp], [build newgrp]),
2285   [], [UL_DEFAULT_ENABLE([newgrp], [no])]
2286 )
2287 UL_BUILD_INIT([newgrp])
2288 UL_REQUIRES_HAVE([newgrp], [crypt], [crypt function])
2289 AM_CONDITIONAL([BUILD_NEWGRP], [test "x$build_newgrp" = xyes])
2290
2291
2292 AC_ARG_WITH([user], AS_HELP_STRING([--without-user], [compile without libuser (remote chsh)]),
2293   [], [with_user=check]
2294 )
2295 have_user=no
2296 AS_IF([test "x$with_user" != xno], [
2297   PKG_CHECK_MODULES(LIBUSER,[libuser >= 0.58], [have_user=yes], [have_user=no])
2298   AS_CASE([$with_user:$have_user],
2299     [yes:no],
2300       [AC_MSG_ERROR([user selected but libuser not found])],
2301     [*:yes],
2302       [AC_DEFINE([HAVE_LIBUSER], [1], [Define if libuser is available])]
2303   )
2304   # temporary solution, libuser has stupid .pc where are exported all
2305   # private dependencies to Requires: instead of Requires.private:
2306   AS_IF([test "x$have_user" = xyes], [
2307     LIBUSER_LIBS=-luser
2308   ])
2309 ])
2310 AM_CONDITIONAL([HAVE_USER], [test "x$have_user" = xyes])
2311
2312 AC_ARG_ENABLE([chfn-chsh-password],
2313   AS_HELP_STRING([--disable-chfn-chsh-password], [do not require the user to enter the password in chfn and chsh]),
2314   [], [enable_chfn_chsh_password=yes]
2315 )
2316
2317 AC_ARG_ENABLE([chfn-chsh],
2318   AS_HELP_STRING([--disable-chfn-chsh], [do not build chfn and chsh]),
2319   [], [UL_DEFAULT_ENABLE([chfn_chsh], [check])]
2320 )
2321 UL_BUILD_INIT([chfn_chsh])
2322 UL_REQUIRES_HAVE([chfn_chsh], [shadow_h], [shadow.h header])
2323 UL_REQUIRES_HAVE([chfn_chsh], [getusershell], [getusershell function])
2324
2325 AS_IF([test "x$enable_chfn_chsh_password" = xyes || test "x$have_user" = xyes], [
2326   UL_REQUIRES_HAVE([chfn_chsh], [security_pam_appl_h], [PAM header file])
2327   AC_DEFINE([CHFN_CHSH_PASSWORD], [1], [Should chfn and chsh require the user to enter the password?])
2328 ])
2329 AM_CONDITIONAL([BUILD_CHFN_CHSH], [test "x$build_chfn_chsh" = xyes])
2330 AM_CONDITIONAL([CHFN_CHSH_PASSWORD], [test "x$enable_chfn_chsh_password" = xyes])
2331
2332 AC_ARG_ENABLE([chsh-only-listed],
2333   AS_HELP_STRING([--disable-chsh-only-listed], [chsh: allow shells not in /etc/shells]),
2334   [], enable_chsh_only_listed=yes
2335 )
2336
2337 AS_IF([test "x$enable_chsh_only_listed" = xyes], [
2338   AC_DEFINE([ONLY_LISTED_SHELLS], [1], [Should chsh allow only shells in /etc/shells?])
2339 ])
2340
2341
2342 AC_ARG_ENABLE([login],
2343   AS_HELP_STRING([--disable-login], [do not build login]),
2344   [], [UL_DEFAULT_ENABLE([login], [check])]
2345 )
2346 UL_BUILD_INIT([login])
2347 UL_REQUIRES_HAVE([login], [security_pam_appl_h], [PAM header file])
2348 UL_REQUIRES_HAVE([login], [security_pam_misc_h, security_openpam_h], [PAM conversation functions])
2349 UL_REQUIRES_HAVE([login], [utmpx_h], [utmpx.h header])
2350 UL_REQUIRES_HAVE([login], [gnu_utmpx], [GNU utmpx functions])
2351 AM_CONDITIONAL([BUILD_LOGIN], [test "x$build_login" = xyes])
2352
2353 AC_ARG_ENABLE([login-chown-vcs],
2354   AS_HELP_STRING([--enable-login-chown-vcs], [let login chown /dev/vcsN]),
2355   [], [enable_login_chown_vcs=no]
2356 )
2357
2358 AS_IF([test "x$enable_login_chown_vcs" = xyes], [
2359   AC_DEFINE([LOGIN_CHOWN_VCS], [1], [Should login chown /dev/vcsN?])
2360 ])
2361
2362 AC_ARG_ENABLE([login-stat-mail],
2363   AS_HELP_STRING([--enable-login-stat-mail], [let login stat() the mailbox]),
2364   [], [enable_login_stat_mail=no]
2365 )
2366
2367 AS_IF([test "x$enable_login_stat_mail" = xyes], [
2368   AC_DEFINE([LOGIN_STAT_MAIL], [1], [Should login stat() the mailbox?])
2369 ])
2370
2371
2372 AC_ARG_ENABLE([nologin],
2373   AS_HELP_STRING([--disable-nologin], [do not build nologin]),
2374   [], [UL_DEFAULT_ENABLE([nologin], [yes])]
2375 )
2376 UL_BUILD_INIT([nologin])
2377 AM_CONDITIONAL([BUILD_NOLOGIN], [test "x$build_nologin" = xyes])
2378
2379
2380 AC_ARG_ENABLE([sulogin],
2381   AS_HELP_STRING([--disable-sulogin], [do not build sulogin]),
2382   [], [UL_DEFAULT_ENABLE([sulogin], [check])]
2383 )
2384 UL_BUILD_INIT([sulogin])
2385 UL_REQUIRES_HAVE([sulogin], [crypt], [crypt function])
2386 UL_REQUIRES_HAVE([sulogin], [shadow_h], [shadow.h header])
2387 AM_CONDITIONAL([BUILD_SULOGIN], [test "x$build_sulogin" = xyes])
2388
2389
2390 AC_ARG_ENABLE([su],
2391   AS_HELP_STRING([--disable-su], [do not build su]),
2392   [], [UL_DEFAULT_ENABLE([su], [check])]
2393 )
2394 UL_BUILD_INIT([su])
2395 UL_REQUIRES_HAVE([su], [security_pam_appl_h], [PAM header file])
2396 UL_REQUIRES_HAVE([su], [utmpx_h], [utmpx.h header])
2397 UL_REQUIRES_HAVE([su], [gnu_utmpx], [GNU utmpx functions])
2398 AM_CONDITIONAL([BUILD_SU], [test "x$build_su" = xyes])
2399
2400
2401 AC_ARG_ENABLE([runuser],
2402   AS_HELP_STRING([--disable-runuser], [do not build runuser]),
2403   [], [UL_DEFAULT_ENABLE([runuser], [check])]
2404 )
2405 UL_BUILD_INIT([runuser])
2406 UL_REQUIRES_HAVE([runuser], [security_pam_appl_h], [PAM header file])
2407 UL_REQUIRES_HAVE([runuser], [utmpx_h], [utmpx.h header])
2408 UL_REQUIRES_HAVE([runuser], [gnu_utmpx], [GNU utmpx functions])
2409 AM_CONDITIONAL([BUILD_RUNUSER], [test "x$build_runuser" = xyes])
2410
2411
2412 AC_ARG_ENABLE([ul],
2413   AS_HELP_STRING([--disable-ul], [do not build ul]),
2414   [], [UL_DEFAULT_ENABLE([ul], [check])]
2415 )
2416 UL_BUILD_INIT([ul])
2417 UL_REQUIRES_HAVE([ul], [ncursesw, ncurses], [ncursesw or ncurses libraries])
2418 AM_CONDITIONAL([BUILD_UL], [test "x$build_ul" = xyes])
2419
2420
2421 AC_ARG_ENABLE([more],
2422   AS_HELP_STRING([--disable-more], [do not build more]),
2423   [], [UL_DEFAULT_ENABLE([more], [check])]
2424 )
2425 UL_BUILD_INIT([more])
2426 UL_REQUIRES_HAVE([more], [ncursesw, ncurses], [ncursesw or ncurses libraries])
2427 UL_REQUIRES_LINUX([more])
2428 AM_CONDITIONAL([BUILD_MORE], [test "x$build_more" = xyes])
2429
2430
2431 AC_ARG_ENABLE([pg],
2432   AS_HELP_STRING([--enable-pg], [build pg]),
2433   [], [UL_DEFAULT_ENABLE([pg], [no])]
2434 )
2435 UL_BUILD_INIT([pg])
2436 UL_REQUIRES_HAVE([pg], [ncursesw, ncurses], [ncursesw or ncurses library])
2437 AM_CONDITIONAL([BUILD_PG], [test "x$build_pg" = xyes])
2438
2439
2440 AC_ARG_ENABLE([setterm],
2441   AS_HELP_STRING([--disable-setterm], [do not build setterm]),
2442   [], [UL_DEFAULT_ENABLE([setterm], [check])]
2443 )
2444 UL_BUILD_INIT([setterm])
2445 UL_REQUIRES_LINUX([setterm])
2446 UL_REQUIRES_HAVE([setterm], [ncursesw, ncurses], [ncursesw or ncurses library])
2447 AM_CONDITIONAL([BUILD_SETTERM], [test "x$build_setterm" = xyes])
2448
2449 # build_schedutils= is just configure-only variable to control
2450 # ionice, taskset and chrt
2451 AC_ARG_ENABLE([schedutils],
2452   AS_HELP_STRING([--disable-schedutils], [do not build chrt, ionice, taskset]),
2453   [], [UL_DEFAULT_ENABLE([schedutils], [check])]
2454 )
2455
2456
2457 UL_ENABLE_ALIAS([ionice], [schedutils])
2458 UL_BUILD_INIT([ionice])
2459 UL_REQUIRES_SYSCALL_CHECK([ionice],
2460         [UL_CHECK_SYSCALL([ioprio_set],
2461           [alpha],      [442],
2462           [i*86],       [289],
2463           [ia64*],      [1274],
2464           [powerpc*],   [273],
2465           [s390*],      [282],
2466           [sparc*],     [196],
2467           [sh*],        [288],
2468           [x86_64*],    [251])],
2469         [ioprio_set])
2470
2471 UL_REQUIRES_SYSCALL_CHECK([ionice],
2472         [UL_CHECK_SYSCALL([ioprio_get],
2473           [alpha],      [443],
2474           [i*86],       [290],
2475           [ia64*],      [1275],
2476           [powerpc*],   [274],
2477           [s390*],      [283],
2478           [sparc*],     [218],
2479           [sh*],        [289],
2480           [x86_64*],    [252])],
2481         [ioprio_get])
2482
2483 AM_CONDITIONAL([BUILD_IONICE], [test "x$build_ionice" = xyes])
2484
2485
2486 UL_ENABLE_ALIAS([taskset], [schedutils])
2487 UL_BUILD_INIT([taskset])
2488 UL_REQUIRES_HAVE([taskset], [cpu_set_t], [cpu_set_t type])
2489 UL_REQUIRES_SYSCALL_CHECK([taskset],
2490         [UL_CHECK_SYSCALL([sched_getaffinity])],
2491         [sched_getaffinity])
2492 AM_CONDITIONAL([BUILD_TASKSET], [test "x$build_taskset" = xyes])
2493
2494
2495 have_schedsetter=no
2496 AS_IF([test "x$ac_cv_func_sched_setscheduler" = xyes], [have_schedsetter=yes],
2497       [test "x$ac_cv_func_sched_setattr" = xyes], [have_schedsetter=yes])
2498
2499 UL_ENABLE_ALIAS([chrt], [schedutils])
2500 UL_BUILD_INIT([chrt])
2501 UL_REQUIRES_HAVE([chrt], [schedsetter], [sched_set functions])
2502 AM_CONDITIONAL([BUILD_CHRT], [test "x$build_chrt" = xyes])
2503
2504 AS_IF([test "x$build_chrt" = xyes], [
2505         UL_CHECK_SYSCALL([sched_setattr])
2506 ])
2507
2508 UL_ENABLE_ALIAS([uclampset], [schedutils])
2509 UL_BUILD_INIT([uclampset])
2510 UL_REQUIRES_SYSCALL_CHECK([uclampset],
2511         [UL_CHECK_SYSCALL([sched_setattr])], [sched_setattr])
2512 AM_CONDITIONAL([BUILD_UCLAMPSET], [test "x$build_uclampset" = xyes])
2513
2514
2515 AC_ARG_ENABLE([wall],
2516   AS_HELP_STRING([--disable-wall], [do not build wall]),
2517   [], [UL_DEFAULT_ENABLE([wall], [check])]
2518 )
2519 UL_BUILD_INIT([wall])
2520 UL_REQUIRES_HAVE([wall], [utmpx_h], [utmpx.h header])
2521 AM_CONDITIONAL([BUILD_WALL], [test "x$build_wall" = xyes])
2522
2523
2524 AC_ARG_ENABLE([write],
2525   AS_HELP_STRING([--enable-write], [build write]),
2526   [], [UL_DEFAULT_ENABLE([write], [no])]
2527 )
2528 UL_BUILD_INIT([write])
2529 UL_REQUIRES_HAVE([write], [utmpx_h], [utmpx.h header])
2530 UL_REQUIRES_HAVE([write], [gnu_utmpx], [GNU utmpx functions])
2531 AM_CONDITIONAL([BUILD_WRITE], [test "x$build_write" = xyes])
2532
2533
2534 AC_ARG_WITH([btrfs],
2535   AS_HELP_STRING([--without-btrfs], [do not build with btrfs support]),
2536   [], [with_btrfs=check]
2537 )
2538 have_btrfs=no
2539 AS_IF([test "x$with_btrfs" != xno], [
2540   AS_CASE([$with_btrfs:$have_linux_btrfs_h],
2541     [yes:no],
2542     [AC_MSG_ERROR([btrfs selected but linux/btrfs.h not found])],
2543     [check:no],
2544        [AC_MSG_WARN([linux/btrfs.h not found, do not build with btrfs support])],
2545     [*:yes],
2546        [have_btrfs=yes
2547         AC_DEFINE([HAVE_BTRFS_SUPPORT], [1], [Define if btrfs stuff is available])]
2548   )
2549 ])
2550 AM_CONDITIONAL([HAVE_BTRFS], [test "x$have_btrfs" = xyes])
2551
2552
2553 AC_ARG_WITH([systemd],
2554   AS_HELP_STRING([--without-systemd], [do not build with systemd support]),
2555   [], [with_systemd=check]
2556 )
2557
2558 have_systemd=no
2559 AS_IF([test "x$with_systemd" != xno], [
2560   # new version -- all libsystemd-* libs merged into libsystemd
2561   PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [have_systemd=yes], [have_systemd=no])
2562   # old versions
2563   AS_IF([test "x$have_systemd" != "xyes"], [
2564     PKG_CHECK_MODULES([SYSTEMD_DAEMON], [libsystemd-daemon],
2565                       [have_systemd_daemon=yes], [have_systemd_daemon=no])
2566     PKG_CHECK_MODULES([SYSTEMD_JOURNAL], [libsystemd-journal],
2567                       [have_systemd_journal=yes], [have_systemd_journal=no])
2568     AS_IF([test "x$have_systemd_daemon" = "xyes" && test "x$have_systemd_journal" = "xyes" ],[
2569            have_systemd=yes])
2570   ])
2571   AS_CASE([$with_systemd:$have_systemd],
2572     [yes:no],
2573       [AC_MSG_ERROR([systemd expected but libsystemd not found])],
2574     [*:yes],
2575        AC_DEFINE([HAVE_LIBSYSTEMD], [1], [Define if libsystemd is available])
2576        AC_DEFINE([USE_SYSTEMD], [1], [Define if systemd support is wanted ])
2577        AC_CHECK_DECLS([sd_session_get_username], [], [], [#include <systemd/sd-login.h>])
2578   )
2579 ])
2580 AM_CONDITIONAL([HAVE_SYSTEMD], [test "x$have_systemd" = xyes])
2581
2582
2583 AC_ARG_WITH([systemdsystemunitdir],
2584   AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [directory for systemd unit files (requires systemd support)]),
2585   [], [
2586   AS_IF([test "x$have_systemd" = xyes], [
2587     PKG_CHECK_VAR([with_systemdsystemunitdir], [systemd], [systemdsystemunitdir],
2588       [],
2589       [with_systemdsystemunitdir=no])
2590   ])
2591 ])
2592 AS_IF([test "x$with_systemdsystemunitdir" != "xno"], [
2593   AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
2594 ])
2595
2596
2597 AC_ARG_WITH([smack],
2598   AS_HELP_STRING([--with-smack], [build with SMACK support]),
2599   [], [with_smack=no]
2600 )
2601 AS_IF([test "x$with_smack" = xyes], [
2602   AC_DEFINE([HAVE_SMACK], [1], [Add SMACK support])
2603 ])
2604
2605 AC_ARG_WITH([econf],
2606   AS_HELP_STRING([--without-econf], [do not use libeconf]),
2607   [], [with_econf=check]
2608 )
2609
2610 have_econf=no
2611 AS_IF([test "x$with_econf" != xno], [
2612   PKG_CHECK_MODULES([ECONF], [libeconf], [have_econf=yes], [have_econf=no])
2613     AS_CASE([$with_econf:$have_econf],
2614     [yes:no],
2615       [AC_MSG_ERROR([libeconf expected but libeconf not found])],
2616     [*:yes],
2617        AC_DEFINE([HAVE_LIBECONF], [1], [Define if libeconf is available])
2618   )
2619 ])
2620 AM_CONDITIONAL([HAVE_ECONF], [test "x$have_econf" = xyes])
2621
2622 AC_ARG_WITH([vendordir],
2623   AS_HELP_STRING([--with-vendordir=DIR], [Directory for distribution provided configuration files]),
2624   [], []
2625 )
2626 AC_SUBST([vendordir], [$with_vendordir])
2627 AM_CONDITIONAL([USE_VENDORDIR], [test "x$with_vendordir" != x])
2628 AS_IF([test "x$with_vendordir" != x], [
2629   AC_DEFINE([USE_VENDORDIR], [1], [Define to 1 to use vendordir])
2630 ])
2631
2632
2633 AC_ARG_ENABLE([bash-completion],
2634   AS_HELP_STRING([--disable-bash-completion], [do not install bash completion files]),
2635   [], [enable_bash_completion=yes]
2636 )
2637
2638 AM_CONDITIONAL([BUILD_BASH_COMPLETION], [test "x$enable_bash_completion" = xyes])
2639
2640 AC_ARG_WITH([bashcompletiondir],
2641   AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
2642   [], [
2643   AS_IF([test "x$enable_bash_completion" = xyes], [
2644     PKG_CHECK_VAR([with_bashcompletiondir], [bash-completion], [completionsdir],
2645       [],
2646       [with_bashcompletiondir=${datadir}/bash-completion/completions])
2647   ])
2648 ])
2649 AS_IF([test "x$enable_bash_completion" = xyes], [
2650   AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
2651 ])
2652
2653
2654 AC_ARG_WITH([python],
2655   AS_HELP_STRING([--without-python], [do not build python bindings, use --with-python={2,3} to force version]),
2656   [], [with_python=check withval=check]
2657 )
2658
2659 have_python=no
2660 have_libpython=no
2661 AS_IF([test "x$with_python" != xno], [
2662   # We follow distributions default and look for PKG module name "python"
2663   # (minimal version is 2) but if major version is explicitly specified by
2664   # --with-python=2 or --with-python=3 then we look for PKG module "python2" or
2665   # "python3".
2666   AS_IF([test "x$withval" != xno && test "x$withval" != xyes && test "x$withval" != xcheck],
2667         [pymajor="$withval"; PYTHON=python${pymajor}], [pymajor="2"])
2668
2669   # check for python interpreter
2670   AM_PATH_PYTHON([$pymajor], [have_python=yes], [have_python=no])
2671   AS_CASE([$with_python:$have_python],
2672     [yes:no],
2673       [AC_MSG_ERROR([python selected but python interpreter not found])],
2674     [check:no],
2675        [AC_MSG_WARN([python interpreter not found, do not build python bindings])],
2676     [*:yes],
2677        # check for python development stuff
2678        [
2679          PKG_CHECK_MODULES([PYTHON], [python-$PYTHON_VERSION], [have_libpython=yes], [have_libpython=no])
2680
2681          # https://github.com/util-linux/util-linux/issues/2366
2682          AX_COMPARE_VERSION([$PYTHON_VERSION], [ge], [3.12], [
2683            UL_WARN_ADD([-Wno-error=redundant-decls], [PYTHON_CFLAGS])
2684          ])
2685        ]
2686   )
2687 ])
2688
2689
2690 AC_ARG_ENABLE([pylibmount],
2691   AS_HELP_STRING([--disable-pylibmount], [do not build pylibmount]),
2692   [], [UL_DEFAULT_ENABLE([pylibmount], [check])]
2693 )
2694 UL_BUILD_INIT([pylibmount])
2695 UL_REQUIRES_HAVE([pylibmount], [libpython], [libpython])
2696 UL_REQUIRES_BUILD([pylibmount], [libmount])
2697 AM_CONDITIONAL([BUILD_PYLIBMOUNT], [test "x$build_pylibmount" = "xyes"])
2698
2699 # We need to introduce a verbatim dependency into the Makefile, without automake
2700 # trying to interpret it, so push it as a AM_SUBST_NOTMAKE variable.
2701 verbatim_pylibmount_dependency='
2702
2703 # pylibmountexec module must be installed after usrlib_exec libraries,
2704 # otherwise the libtool relink step will fail to find libmount.la and
2705 # will try -lmount which is possibly not available.
2706 install-pylibmountexecLTLIBRARIES: install-usrlib_execLTLIBRARIES
2707
2708 '
2709 AC_SUBST([verbatim_pylibmount_dependency])
2710 AM_SUBST_NOTMAKE([verbatim_pylibmount_dependency])
2711
2712 AC_ARG_ENABLE([pg-bell],
2713   AS_HELP_STRING([--disable-pg-bell], [let pg not ring the bell on invalid keys]),
2714   [], [enable_pg_bell=yes]
2715 )
2716
2717 AS_IF([test "x$enable_pg_bell" = xyes], [
2718   AC_DEFINE([PG_BELL], [1], [Should pg ring the bell on invalid keys?])
2719 ])
2720
2721
2722 AC_DEFUN([FS_PATHS_DEFAULT], [/sbin:/sbin/fs.d:/sbin/fs])
2723 AC_ARG_ENABLE([fs-paths-default],
2724   AS_HELP_STRING([--enable-fs-paths-default=paths], [default search path for fs helpers @<:@FS_PATHS_DEFAULT@:>@]),
2725   [AS_CASE([$enableval],
2726     [yes], [fs_paths_defaults="FS_PATHS_DEFAULT"],
2727     [no],  [fs_paths_defaults=""],
2728     [fs_paths_defaults="$enableval"]
2729   )],
2730   [fs_paths_defaults="FS_PATHS_DEFAULT"]
2731 )
2732 AC_ARG_ENABLE([fs-paths-extra],
2733   AS_HELP_STRING([--enable-fs-paths-extra=paths], [additional search paths for fs helpers]),
2734   [AS_CASE([$enableval],
2735      [yes|no], [fs_paths_extra=""],
2736      [fs_paths_extra="$enableval"]
2737   )],
2738   [fs_paths_extra=""]
2739 )
2740 fs_paths="$fs_paths_defaults"
2741 AS_IF([test "x$fs_paths_extra" != "x"], [
2742   AS_IF([test "x$fs_paths" != "x"], [
2743     fs_paths="${fs_paths}:"
2744   ])
2745   fs_paths="${fs_paths}${fs_paths_extra}"
2746 ])
2747 AC_DEFINE_UNQUOTED([FS_SEARCH_PATH], "$fs_paths", [search path for fs helpers])
2748
2749
2750 AC_ARG_ENABLE([use-tty-group],
2751   AS_HELP_STRING([--disable-use-tty-group], [do not install wall and write setgid tty]),
2752   [], [enable_use_tty_group=yes]
2753 )
2754 AM_CONDITIONAL([USE_TTY_GROUP], [test "x$enable_use_tty_group" = xyes])
2755
2756 AS_IF([test "x$enable_use_tty_group" = xyes], [
2757   AC_DEFINE([USE_TTY_GROUP], [1], [Should wall and write be installed setgid tty?])
2758 ])
2759
2760
2761 AC_ARG_ENABLE([sulogin-emergency-mount],
2762   AS_HELP_STRING([--enable-sulogin-emergency-mount],
2763                  [use emergency mount of /dev and /proc for sulogin]),
2764   [], [enable_sulogin_emergency_mount=no]
2765 )
2766
2767 AS_IF([test "x$enable_sulogin_emergency_mount" = xyes], [
2768   AS_IF([test "x$linux_os" = xyes], [ ],
2769         [AC_MSG_ERROR([--enable-sulogin-emergency-mount selected for non-linux system])])
2770   AC_DEFINE([USE_SULOGIN_EMERGENCY_MOUNT], [1],
2771             [Should sulogin use an emergency mount of /dev and /proc?])
2772 ])
2773
2774
2775 AC_ARG_ENABLE([usrdir-path],
2776   AS_HELP_STRING([--enable-usrdir-path], [use only /usr paths in PATH env. variable (recommended on systems with /bin -> /usr/bin symlinks)]),
2777   [], [enable_usrdir_path=no]
2778 )
2779
2780 AS_IF([test "x$enable_usrdir_path" = xyes], [
2781   AC_DEFINE([USE_USRDIR_PATHS_ONLY], [1], [Define to 1 to remove /bin and /sbin from PATH env.variable])
2782 ])
2783
2784
2785 AC_ARG_ENABLE([makeinstall-chown],
2786   AS_HELP_STRING([--disable-makeinstall-chown], [do not do chown-like operations during "make install"]),
2787   [], [enable_makeinstall_chown=yes]
2788 )
2789 AM_CONDITIONAL([MAKEINSTALL_DO_CHOWN], [test "x$enable_makeinstall_chown" = xyes])
2790
2791
2792 AC_ARG_ENABLE([makeinstall-setuid],
2793   AS_HELP_STRING([--disable-makeinstall-setuid], [do not do setuid chmod operations during "make install"]),
2794   [], [enable_makeinstall_setuid=yes]
2795 )
2796 AM_CONDITIONAL([MAKEINSTALL_DO_SETUID], [test "x$enable_makeinstall_setuid" = xyes])
2797
2798
2799 AC_ARG_ENABLE([colors-default],
2800   AS_HELP_STRING([--disable-colors-default], [do not colorize output from utils by default]),
2801   [], [enable_colors_default=yes]
2802 )
2803 AS_IF([test "x$enable_colors_default" = xyes], [
2804   AC_DEFINE([USE_COLORS_BY_DEFAULT], [1], [Enables colorized output from utils by default])
2805 ])
2806
2807
2808 AC_ARG_WITH([cryptsetup],
2809   AS_HELP_STRING([--with-cryptsetup], [compile with cryptsetup support]),
2810   [], [with_cryptsetup=no]
2811 )
2812
2813 AS_IF([test "x$with_cryptsetup" = xno], [
2814   AM_CONDITIONAL([HAVE_CRYPTSETUP], [false])
2815   AM_CONDITIONAL([CRYPTSETUP_VIA_DLOPEN], [false])
2816 ], [
2817   PKG_CHECK_MODULES([CRYPTSETUP], [libcryptsetup],
2818         [AC_DEFINE([HAVE_CRYPTSETUP], [1], [Define if cryptsetup is available])
2819          UL_PKG_STATIC([CRYPTSETUP_LIBS_STATIC], [libcryptsetup])
2820          AM_CONDITIONAL([HAVE_CRYPTSETUP], [true])
2821          SAVE_CFLAGS="$CFLAGS"
2822          CFLAGS="$CRYPTSETUP_CFLAGS $CFLAGS"
2823          SAVE_LIBS="$LIBS"
2824          LIBS="$CRYPTSETUP_LIBS $LIBS"
2825          AC_CHECK_LIB([cryptsetup], [crypt_activate_by_signed_key], [
2826           AC_DEFINE([HAVE_CRYPT_ACTIVATE_BY_SIGNED_KEY], [1], [Define if crypt_activate_by_signed_key exist in -lcryptsetup])
2827          ])
2828          AS_IF([test "x$with_cryptsetup" = xdlopen], [
2829           LIBS="-ldl $LIBS"
2830           AC_CHECK_LIB([dl], [dlsym], [
2831             AC_DEFINE([CRYPTSETUP_VIA_DLOPEN], [1], [Define if cryptsetup is to be loaded via dlopen])
2832             AM_CONDITIONAL([CRYPTSETUP_VIA_DLOPEN], [true])
2833            ], [AC_MSG_ERROR([libdl required to build with cryptsetup support])])
2834          ], [
2835           AM_CONDITIONAL([CRYPTSETUP_VIA_DLOPEN], [false])
2836          ])
2837          CFLAGS="$SAVE_CFLAGS"
2838          LIBS="$SAVE_LIBS"
2839          have_cryptsetup=yes],
2840         [have_cryptsetup=no
2841    AM_CONDITIONAL([HAVE_CRYPTSETUP], [false])
2842    AM_CONDITIONAL([CRYPTSETUP_VIA_DLOPEN], [false])
2843   ])
2844
2845   AS_CASE([$with_cryptsetup:$have_cryptsetup],
2846     [yes:no], [AC_MSG_WARN([cryptsetup selected but libcryptsetup not found])]
2847   )
2848 ])
2849 AC_SUBST([CRYPTSETUP_LIBS])
2850 AC_SUBST([CRYPTSETUP_LIBS_STATIC])
2851
2852
2853 AC_ARG_VAR([SUID_CFLAGS],
2854            [CFLAGS used for binaries which are usually with the suid bit])
2855 AC_ARG_VAR([SUID_LDFLAGS],
2856            [LDFLAGS used for binaries which are usually with the suid bit])
2857
2858 AC_ARG_VAR([DAEMON_CFLAGS],
2859            [CFLAGS used for binaries which are usually executed as daemons])
2860 AC_ARG_VAR([DAEMON_LDFLAGS],
2861            [LDFLAGS used for binaries which are usually executed as daemons])
2862
2863 AC_ARG_VAR([SOLIB_CFLAGS],
2864            [CFLAGS used for shared libraries])
2865 AC_ARG_VAR([SOLIB_LDFLAGS],
2866            [LDFLAGS used for shared libraries])
2867
2868 AC_ARG_VAR([ADJTIME_PATH],
2869            [Path to hwclock adjtime file, default /etc/adjtime])
2870 AS_IF([test "x$ADJTIME_PATH" = x], [ADJTIME_PATH="/etc/adjtime"])
2871 AC_DEFINE_UNQUOTED([CONFIG_ADJTIME_PATH], "$ADJTIME_PATH", [Path to hwclock adjtime file])
2872
2873 if test "x${build_alias}" != "x${host_alias}"; then
2874   AC_MSG_NOTICE([setting link_all_deplibs=unknown for libtool])
2875   # work around Debian patch to libtool breaking cross-compiles
2876   # https://bugs.debian.org/cgi-bin/bugreport.cgi?bug=702737
2877   # https://bugs.debian.org/cgi-bin/bugreport.cgi?bug=297726
2878   link_all_deplibs=unknown
2879 fi
2880
2881
2882 LIBS=""
2883
2884
2885 AC_CONFIG_HEADERS([config.h])
2886
2887 #
2888 # Don't use configure.ac to replace install paths! See Makefile PATHFILES for
2889 # more details.
2890 #
2891 AC_CONFIG_FILES([
2892 Makefile
2893 libblkid/docs/Makefile
2894 libblkid/docs/version.xml
2895 libblkid/src/blkid.h
2896 libfdisk/docs/Makefile
2897 libfdisk/docs/version.xml
2898 libfdisk/src/libfdisk.h
2899 libmount/docs/Makefile
2900 libmount/docs/version.xml
2901 libmount/src/libmount.h
2902 libsmartcols/docs/Makefile
2903 libsmartcols/docs/version.xml
2904 libsmartcols/src/libsmartcols.h
2905 po/Makefile.in
2906 po-man/Makefile
2907 ])
2908
2909 AC_OUTPUT
2910
2911 AC_MSG_RESULT([
2912         ${PACKAGE}  ${VERSION}
2913
2914         prefix:                    ${prefix}
2915         exec prefix:               ${exec_prefix}
2916
2917         bindir:                    ${bindir}
2918         sbindir:                   ${sbindir}
2919         libdir:                    ${libdir}
2920         usrbin_execdir:            ${usrbin_execdir}
2921         usrsbin_execdir:           ${usrsbin_execdir}
2922         usrlib_execdir:            ${usrlib_execdir}
2923
2924         localstatedir:             ${localstatedir}
2925         runstatedir:               ${runstatedir}
2926         includedir:                ${includedir}
2927         sysconfdir:                ${sysconfdir}
2928         sysconfstaticdir:          ${sysconfstaticdir}
2929
2930         vendordir:                 ${with_vendordir}
2931
2932         Python:                    ${PYTHON}
2933         Python version:            ${PYTHON_VERSION}
2934         Python libs:               ${pyexecdir}
2935
2936         Bash completions:          ${with_bashcompletiondir}
2937         Systemd support:           ${have_systemd}
2938         Systemd unitdir:           ${with_systemdsystemunitdir}
2939         libeconf support:          ${have_econf}
2940         Btrfs support:             ${have_btrfs}
2941         Wide-char support:         ${build_widechar}
2942         libcryptsetup support:     ${have_cryptsetup}
2943
2944         Manual pages:              ${build_asciidoc}
2945         Manual pages translated:   ${build_poman}
2946
2947         compiler:                  ${CC} / ${CXX}
2948         suid cflags:               ${SUID_CFLAGS}
2949         ldflags:                   ${LDFLAGS}
2950         suid ldflags:              ${SUID_LDFLAGS}
2951         ASAN enabled:              ${enable_asan}
2952         Fuzzing enabled:           ${enable_fuzzing_engine}
2953         Coverage enabled           ${enable_coverage}
2954
2955         cflags:                    ${CFLAGS}
2956
2957         warnings:
2958
2959 ${WARN_CFLAGS}
2960
2961  Type 'make' or 'make <utilname>' to compile.
2962 ])