configure.ac

   1 AC_INIT([util-linux],
   2         m4_esyscmd([tools/git-version-gen .tarball-version]),
   3         [kzak@redhat.com],,
   4         [http://www.kernel.org/pub/linux/utils/util-linux/])
   5
   6
   7 AC_PREREQ([2.60])
   8
   9 AC_CONFIG_AUX_DIR([config])
  10 AC_CONFIG_MACRO_DIR([m4])
  11 dnl AC_USE_SYSTEM_EXTENSIONS must be called before any macros that run
  12 dnl the compiler (like AC_PROG_LIBTOOL) to avoid autoconf errors.
  13 AC_USE_SYSTEM_EXTENSIONS
  14 AM_INIT_AUTOMAKE([-Wall foreign 1.10 tar-pax no-dist-gzip dist-xz subdir-objects])
  15
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  17                             [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  18 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  19
  20 AC_CONFIG_SRCDIR([sys-utils/mount.c])
  21 AC_PREFIX_DEFAULT([/usr])
  22
  23 dnl version details from <major>.<minor>[-<suffix>]
  24 PACKAGE_VERSION_MAJOR=$(echo $PACKAGE_VERSION | awk -F. '{print $1}')
  25 PACKAGE_VERSION_MINOR=$(echo $PACKAGE_VERSION | awk -F. '{
  26                                                    sub("-.*","",$2); print $2}')
  27 PACKAGE_VERSION_RELEASE=$(echo $PACKAGE_VERSION | awk -F. '{
  28                      sub("-.*","",$3); print $3 ~ /^@<:@0-9@:>@+$/ ? $3 : 0}')
  29
  30 dnl libblkid version
  31 LIBBLKID_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  32 LIBBLKID_DATE="06-Nov-2018"
  33 LIBBLKID_LT_MAJOR=1
  34 LIBBLKID_LT_MINOR=1
  35 LIBBLKID_LT_MICRO=0
  36 LIBBLKID_VERSION_INFO=`expr $LIBBLKID_LT_MAJOR + $LIBBLKID_LT_MINOR`:$LIBBLKID_LT_MICRO:$LIBBLKID_LT_MINOR
  37
  38 dnl libuuid version
  39 LIBUUID_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  40 LIBUUID_LT_MAJOR=1
  41 LIBUUID_LT_MINOR=3
  42 LIBUUID_LT_MICRO=0
  43 LIBUUID_VERSION_INFO=`expr $LIBUUID_LT_MAJOR + $LIBUUID_LT_MINOR`:$LIBUUID_LT_MICRO:$LIBUUID_LT_MINOR
  44
  45 dnl libmount version
  46 LIBMOUNT_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  47 LIBMOUNT_LT_MAJOR=1
  48 LIBMOUNT_LT_MINOR=1
  49 LIBMOUNT_LT_MICRO=0
  50 LIBMOUNT_VERSION_INFO=`expr $LIBMOUNT_LT_MAJOR + $LIBMOUNT_LT_MINOR`:$LIBMOUNT_LT_MICRO:$LIBMOUNT_LT_MINOR
  51
  52 dnl libsmartcols version
  53 LIBSMARTCOLS_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  54 LIBSMARTCOLS_LT_MAJOR=1
  55 LIBSMARTCOLS_LT_MINOR=1
  56 LIBSMARTCOLS_LT_MICRO=0
  57 LIBSMARTCOLS_VERSION_INFO=`expr $LIBSMARTCOLS_LT_MAJOR + $LIBSMARTCOLS_LT_MINOR`:$LIBSMARTCOLS_LT_MICRO:$LIBSMARTCOLS_LT_MINOR
  58
  59 dnl libfdisk version
  60 LIBFDISK_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  61 LIBFDISK_LT_MAJOR=1
  62 LIBFDISK_LT_MINOR=1
  63 LIBFDISK_LT_MICRO=0
  64 LIBFDISK_VERSION_INFO=`expr $LIBFDISK_LT_MAJOR + $LIBFDISK_LT_MINOR`:$LIBFDISK_LT_MICRO:$LIBFDISK_LT_MINOR
  65
  66 # Check whether exec_prefix=/usr:
  67 AS_CASE([$exec_prefix:$prefix],
  68 [NONE:NONE | NONE:/usr | /usr:*],
  69   [AC_MSG_NOTICE([Default --exec-prefix detected.])
  70    AS_CASE([$bindir],  ['${exec_prefix}/bin'],  [bindir=/bin;   AC_MSG_NOTICE([  --bindir defaults to /bin])  ])
  71    AS_CASE([$sbindir], ['${exec_prefix}/sbin'], [sbindir=/sbin; AC_MSG_NOTICE([  --sbindir defaults to /sbin])])
  72    AS_CASE([$libdir],  ['${exec_prefix}/lib'],  [libdir=/lib;   AC_MSG_NOTICE([  --libdir defaults to /lib])  ])
  73    AS_CASE([$libdir],  ['${exec_prefix}/lib64'],[libdir=/lib64; AC_MSG_NOTICE([  --libdir defaults to /lib64])  ])
  74   ]
  75 )
  76
  77
  78 # default for old versions without $runstatedir
  79 AS_IF([test x"$runstatedir" = x], [runstatedir='${localstatedir}/run'])
  80
  81 # our default if $localstatedir unchanged
  82 AS_CASE([$localstatedir:$runstatedir],
  83  [NONE:'${localstatedir}/run' | /var:'${localstatedir}/run' | NONE:'/run' ],
  84    [runstatedir=/run; AC_MSG_NOTICE([  --runstatedir defaults to /run])]
  85 )
  86
  87 AC_SUBST([runstatedir])
  88
  89
  90 # The original default values of {bin,sbin,lib}dir
  91 usrbin_execdir='${exec_prefix}/bin'
  92 AC_SUBST([usrbin_execdir])
  93
  94 usrsbin_execdir='${exec_prefix}/sbin'
  95 AC_SUBST([usrsbin_execdir])
  96
  97 AS_CASE([$libdir],
  98  ['${exec_prefix}/'* | '${prefix}/'* | /usr/* | "${prefix}"/* ],
  99    [usrlib_execdir=$libdir],
 100  [usrlib_execdir='${exec_prefix}'$libdir]
 101 )
 102 AC_SUBST([usrlib_execdir])
 103
 104
 105 AM_PROG_CC_C_O
 106 AC_PROG_MKDIR_P
 107 AC_PROG_CC_STDC
 108 AC_PROG_YACC
 109 AC_CANONICAL_HOST
 110 AC_C_CONST
 111 AC_C_VOLATILE
 112 AC_C_BIGENDIAN
 113
 114 dnl Compiler warnings
 115 UL_WARN_ADD([-fno-common])
 116 UL_WARN_ADD([-Wall])
 117 UL_WARN_ADD([-Werror=sequence-point])
 118 UL_WARN_ADD([-Wextra])
 119 UL_WARN_ADD([-Wextra-semi])
 120 UL_WARN_ADD([-Wembedded-directive])
 121 UL_WARN_ADD([-Wmissing-declarations])
 122 UL_WARN_ADD([-Wmissing-parameter-type])
 123 UL_WARN_ADD([-Wmissing-prototypes])
 124 UL_WARN_ADD([-Wno-missing-field-initializers])
 125 UL_WARN_ADD([-Wredundant-decls])
 126 UL_WARN_ADD([-Wsign-compare])
 127 UL_WARN_ADD([-Wtype-limits])
 128 UL_WARN_ADD([-Wuninitialized])
 129 UL_WARN_ADD([-Wunused-but-set-parameter])
 130 UL_WARN_ADD([-Wunused-but-set-variable])
 131 UL_WARN_ADD([-Wunused-parameter])
 132 UL_WARN_ADD([-Wunused-result])
 133 UL_WARN_ADD([-Wunused-variable])
 134 UL_WARN_ADD([-Wnested-externs])
 135 UL_WARN_ADD([-Wpointer-arith])
 136 UL_WARN_ADD([-Wstrict-prototypes])
 137 UL_WARN_ADD([-Wformat-security])
 138 UL_WARN_ADD([-Wimplicit-function-declaration])
 139 UL_WARN_ADD([-Wdiscarded-qualifiers])
 140 AC_SUBST([WARN_CFLAGS])
 141
 142 UL_WARN_ADD([-Wno-clobbered], [BSD_WARN_CFLAGS])
 143 AC_SUBST([BSD_WARN_CFLAGS])
 144
 145 UL_WARN_ADD([-Wno-cast-function-type], [PYTHON_WARN_CFLAGS])
 146 AC_SUBST([PYTHON_WARN_CFLAGS])
 147
 148 UL_WARN_ADD([-Wno-unused-parameter], [NO_UNUSED_WARN_CFLAGS])
 149 AC_SUBST([NO_UNUSED_WARN_CFLAGS])
 150
 151
 152 AC_ARG_ENABLE([asan],
 153   AS_HELP_STRING([--enable-asan], [compile with Address Sanitizer]),
 154   [], [enable_asan=no]
 155 )
 156 AS_IF([test "x$enable_asan" = xyes], [
 157   UL_WARN_ADD([-fsanitize=address])
 158 ])
 159
 160
 161
 162 dnl libtool-2
 163 LT_INIT
 164
 165 dnl check supported linker flags
 166 AX_CHECK_VSCRIPT
 167
 168 m4_ifndef([PKG_PROG_PKG_CONFIG],
 169   [m4_fatal([Could not locate the pkg-config autoconf
 170     macros. These are usually located in /usr/share/aclocal/pkg.m4.
 171     If your macros are in a different location, try setting the
 172     environment variable AL_OPTS="-I/other/macro/dir" before running
 173     ./autogen.sh or autoreconf again. Make sure pkg-config is installed.])])
 174 PKG_PROG_PKG_CONFIG
 175
 176 GTK_DOC_CHECK([1.10])
 177 AC_PATH_PROG([XSLTPROC], [xsltproc])
 178
 179 linux_os=no
 180 bsd_os=no
 181 AS_CASE([${host_os}],
 182   [*linux*],
 183      [linux_os=yes],
 184   [*darwin*],
 185      [darwin_os=yes],
 186   [*bsd*],
 187      [bsd_os=yes])
 188 AM_CONDITIONAL([LINUX], [test "x$linux_os" = xyes])
 189 AM_CONDITIONAL([DARWIN], [test "x$darwin_os" = xyes])
 190 AM_CONDITIONAL([BSD], [test "x$bsd_os" = xyes])
 191
 192 AS_IF([test  "x$darwin_os" = xyes], [
 193   AC_DEFINE([_DARWIN_C_SOURCE], [1], [Enable MAP_ANON in sys/mman.h on Mac OS X])
 194 ])
 195
 196 dnl define ARCH_<NAME> conditionals
 197 UL_SET_ARCH([I86], [i?86-*])
 198 UL_SET_ARCH([86_64], [x86_64*])
 199 UL_SET_ARCH([IA64], [ia64*])
 200 UL_SET_ARCH([S390], [s390*])
 201 UL_SET_ARCH([SPARC], [sparc*])
 202 UL_SET_ARCH([PPC], [ppc*|powerpc*])
 203 UL_SET_ARCH([M68K], [m68*])
 204 UL_SET_ARCH([MIPS], [mips*])
 205 UL_SET_ARCH([HPPA], [hppa*|parisc*])
 206
 207 AC_SYS_LARGEFILE
 208 AC_HEADER_ASSERT
 209 AC_STRUCT_TIMEZONE
 210
 211 dnl Don't forget to maintain alternatively allowed versions in autogen.sh!
 212 AM_GNU_GETTEXT_VERSION([0.18.3])
 213 AM_GNU_GETTEXT([external])
 214
 215 AS_IF([test -d "$srcdir/po"], [
 216   ALL_LINGUAS=`cd $srcdir/po > /dev/null && echo *.po | sed 's/\.po//g'`
 217 ], [
 218   ALL_LINGUAS="af am ar as be bg bn_IN bn ca cs cy da de el en_GB es et eu_ES fa fi fr gl gu he hi hr hu hy id is it ja ka kn ko ku lo lt lv mk ml mr ms my nb nl nn no nso or pa pl pt_BR pt ro ru si sk sl sq sr@Latn sr sv ta te th tr uk ur vi zh_CN zh_TW zu"
 219 ])
 220
 221 AC_CHECK_HEADERS([linux/compiler.h linux/blkpg.h linux/major.h], [], [], [
 222 #ifdef HAVE_LINUX_COMPILER_H
 223 #include <linux/compiler.h>
 224 #endif
 225 ])
 226 AC_CHECK_HEADERS([ \
 227         asm/io.h \
 228         err.h \
 229         errno.h \
 230         fcntl.h \
 231         getopt.h \
 232         inttypes.h \
 233         lastlog.h \
 234         libutil.h \
 235         linux/btrfs.h \
 236         linux/cdrom.h \
 237         linux/falloc.h \
 238         linux/watchdog.h \
 239         linux/fd.h \
 240         linux/raw.h \
 241         linux/tiocl.h \
 242         linux/version.h \
 243         linux/securebits.h \
 244         linux/net_namespace.h \
 245         locale.h \
 246         mntent.h \
 247         net/if.h \
 248         net/if_dl.h \
 249         netinet/in.h \
 250         paths.h \
 251         pty.h \
 252         security/pam_appl.h \
 253         stdint.h \
 254         stdio_ext.h \
 255         stdlib.h \
 256         endian.h \
 257         byteswap.h \
 258         sys/endian.h \
 259         sys/disk.h \
 260         sys/disklabel.h \
 261         sys/file.h \
 262         sys/io.h \
 263         sys/ioccom.h \
 264         sys/ioctl.h \
 265         sys/mkdev.h \
 266         sys/mount.h \
 267         sys/param.h \
 268         sys/prctl.h \
 269         sys/resource.h \
 270         sys/signalfd.h \
 271         sys/socket.h \
 272         sys/sockio.h \
 273         sys/stat.h \
 274         sys/sysmacros.h \
 275         sys/swap.h \
 276         sys/syscall.h \
 277         sys/time.h \
 278         sys/timex.h \
 279         sys/ttydefaults.h \
 280         sys/types.h \
 281         sys/ucred.h \
 282         sys/un.h \
 283         unistd.h \
 284         shadow.h \
 285         utmp.h \
 286         utmpx.h \
 287 ])
 288
 289 # There is a collision in old kernel-headers. The both files mount.h and fs.h
 290 # define MS_* macros. Fixed by kernel commit e462ec50cb5fad19f6003a3d8087f4a0945dd2b1.
 291 #
 292 AC_CHECK_HEADERS([linux/fs.h ], [], [],
 293  [#ifdef HAVE_SYS_MOUNT_H
 294    # include <linux/fs.h>
 295    # include <sys/mount.h>
 296   #endif
 297 ])
 298
 299 AC_CHECK_HEADERS([linux/gsmmux.h ], [], [],
 300  [#ifdef LINUX_GSMMUX_H
 301    # include <linux/gsmmux.h>
 302    #endif
 303 ])
 304
 305 AC_CHECK_HEADERS([security/pam_misc.h],
 306                 [AM_CONDITIONAL([HAVE_LINUXPAM], [true])],
 307                 [AM_CONDITIONAL([HAVE_LINUXPAM], [false])], [
 308 #ifdef HAVE_SECURITY_PAM_APPL_H
 309 #include <security/pam_appl.h>
 310 #endif
 311 ])
 312
 313 AC_CHECK_HEADERS([linux/blkzoned.h])
 314
 315 AC_CHECK_HEADERS([security/openpam.h], [], [], [
 316 #ifdef HAVE_SECURITY_PAM_APPL_H
 317 #include <security/pam_appl.h>
 318 #endif
 319 ])
 320
 321 AC_CHECK_HEADERS([langinfo.h],
 322                 [AM_CONDITIONAL([HAVE_LANGINFO], [true])],
 323                 [AM_CONDITIONAL([HAVE_LANGINFO], [false])])
 324
 325 AC_MSG_CHECKING([whether langinfo.h defines ALTMON_x constants])
 326 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 327         #include <langinfo.h>
 328 ]], [[
 329         char *str;
 330         str = nl_langinfo (ALTMON_1);
 331         str = nl_langinfo (ALTMON_2);
 332         str = nl_langinfo (ALTMON_3);
 333         str = nl_langinfo (ALTMON_4);
 334         str = nl_langinfo (ALTMON_5);
 335         str = nl_langinfo (ALTMON_6);
 336         str = nl_langinfo (ALTMON_7);
 337         str = nl_langinfo (ALTMON_8);
 338         str = nl_langinfo (ALTMON_9);
 339         str = nl_langinfo (ALTMON_10);
 340         str = nl_langinfo (ALTMON_11);
 341         str = nl_langinfo (ALTMON_12);
 342 ]])], [
 343         AC_MSG_RESULT([yes])
 344         AC_DEFINE([HAVE_LANGINFO_ALTMON], [1],
 345                 [Define if langinfo.h defines ALTMON_x constants])
 346 ], [
 347         AC_MSG_RESULT([no])
 348 ])
 349
 350
 351 AC_MSG_CHECKING([whether langinfo.h defines _NL_ABALTMON_x constants])
 352 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 353         #include <langinfo.h>
 354 ]], [[
 355         char *str;
 356         str = nl_langinfo (_NL_ABALTMON_1);
 357         str = nl_langinfo (_NL_ABALTMON_2);
 358         str = nl_langinfo (_NL_ABALTMON_3);
 359         str = nl_langinfo (_NL_ABALTMON_4);
 360         str = nl_langinfo (_NL_ABALTMON_5);
 361         str = nl_langinfo (_NL_ABALTMON_6);
 362         str = nl_langinfo (_NL_ABALTMON_7);
 363         str = nl_langinfo (_NL_ABALTMON_8);
 364         str = nl_langinfo (_NL_ABALTMON_9);
 365         str = nl_langinfo (_NL_ABALTMON_10);
 366         str = nl_langinfo (_NL_ABALTMON_11);
 367         str = nl_langinfo (_NL_ABALTMON_12);
 368 ]])], [
 369         AC_MSG_RESULT([yes])
 370         AC_DEFINE([HAVE_LANGINFO_NL_ABALTMON], [1],
 371                 [Define if langinfo.h defines _NL_ABALTMON_x constants])
 372 ], [
 373         AC_MSG_RESULT([no])
 374 ])
 375
 376
 377 dnl Convert some ac_cv_header_* variables to have_*
 378 dnl
 379 have_linux_version_h=$ac_cv_header_linux_version_h
 380 have_linux_blkzoned_h=$ac_cv_header_linux_blkzoned_h
 381 have_linux_btrfs_h=$ac_cv_header_linux_btrfs_h
 382 have_linux_raw_h=$ac_cv_header_linux_raw_h
 383 have_linux_securebits_h=$ac_cv_header_linux_securebits_h
 384 have_linux_watchdog_h=$ac_cv_header_linux_watchdog_h
 385 have_security_pam_appl_h=$ac_cv_header_security_pam_appl_h
 386 have_security_pam_misc_h=$ac_cv_header_security_pam_misc_h
 387 have_security_openpam_h=$ac_cv_header_security_openpam_h
 388 have_shadow_h=$ac_cv_header_shadow_h
 389 have_sys_signalfd_h=$ac_cv_header_sys_signalfd_h
 390 have_utmpx_h=$ac_cv_header_utmpx_h
 391
 392 AS_CASE([$linux_os:$have_linux_version_h],
 393   [yes:no],
 394     [AC_MSG_ERROR([kernel headers required on Linux])]
 395 )
 396
 397 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 398 #include <time.h>
 399 #include <unistd.h>
 400 ]], [[
 401     int a = 0;
 402     struct tm *tm = localtime(0);
 403     if (a == -1)  /* false */
 404         sleep(tm->tm_gmtoff);
 405 ]])],
 406 [AC_DEFINE([HAVE_TM_GMTOFF], [1], [Does struct tm have a field tm_gmtoff?])
 407 ])
 408
 409 AC_CHECK_MEMBERS([struct termios.c_line],,,
 410     [[#include <termios.h>]])
 411
 412 AC_CHECK_MEMBERS([struct stat.st_mtim.tv_nsec],,,
 413         [#include <sys/stat.h>])
 414
 415 AC_CHECK_DECLS([_NL_TIME_WEEK_1STDAY],[],[],[[#include <langinfo.h>]])
 416
 417 AC_CHECK_DECL([llseek],
 418         [AC_DEFINE([HAVE_LLSEEK_PROTOTYPE], [1],
 419                         [Define to 1 if have llseek prototype])],
 420         [],
 421         [#include <unistd.h>])
 422
 423 AC_CHECK_DECL([lseek64],
 424         [AC_DEFINE([HAVE_LSEEK64_PROTOTYPE], [1],
 425                         [Define to 1 if have lseek64 prototype])],
 426         [],
 427         [#define _LARGEFILE_SOURCE
 428          #define _LARGEFILE64_SOURCE
 429          #include <unistd.h>])
 430
 431 AC_CHECK_DECL([environ],
 432         [AC_DEFINE([HAVE_ENVIRON_DECL], [1],
 433                 [Define to 1 if have **environ prototype])],
 434 )
 435
 436 AC_CHECK_DECL([strsignal],
 437         [AC_DEFINE([HAVE_STRSIGNAL_DECL], [1],
 438                 [Define to 1 if have strsignal function prototype])],
 439 )
 440
 441 AC_CHECK_DECL([TIOCGLCKTRMIOS],
 442               [have_tiocglcktrmios=yes], [have_tiocglcktrmios=no],
 443               [#include <sys/ioctl.h>])
 444 AC_CHECK_DECL([SOCK_CLOEXEC],
 445               [have_sock_cloexec=yes], [have_sock_cloexec=no],
 446               [#include <sys/types.h>
 447                #include <sys/socket.h>])
 448 AC_CHECK_DECL([SOCK_NONBLOCK],
 449               [have_sock_nonblock=yes], [have_sock_nonblock=no],
 450               [#include <sys/types.h>
 451                #include <sys/socket.h>])
 452 AC_CHECK_DECL([SO_PASSCRED],
 453               [have_so_passcred=yes], [have_so_passcred=no],
 454               [#include <sys/types.h>
 455                #include <sys/socket.h>])
 456
 457 AC_CHECK_FUNCS([ \
 458         clearenv \
 459         __fpurge \
 460         fpurge \
 461         __fpending \
 462         secure_getenv \
 463         __secure_getenv \
 464         eaccess \
 465         err \
 466         errx \
 467         explicit_bzero \
 468         fsync \
 469         utimensat \
 470         getdomainname \
 471         getdtablesize \
 472         getexecname \
 473         getmntinfo \
 474         getrandom \
 475         getrlimit \
 476         getsgnam \
 477         inotify_init \
 478         jrand48 \
 479         lchown \
 480         llseek \
 481         lseek64 \
 482         mempcpy \
 483         mkostemp \
 484         nanosleep \
 485         ntp_gettime \
 486         personality \
 487         posix_fadvise \
 488         prctl \
 489         qsort_r \
 490         rpmatch \
 491         scandirat \
 492         setprogname \
 493         setresgid \
 494         setresuid \
 495         sched_setattr \
 496         sched_setscheduler \
 497         sigqueue \
 498         srandom \
 499         strnchr \
 500         strndup \
 501         strnlen \
 502         sysconf \
 503         sysinfo \
 504         timegm \
 505         usleep \
 506         vwarnx \
 507         warn \
 508         warnx \
 509 ])
 510 AC_FUNC_FSEEKO
 511
 512 AC_CHECK_FUNCS([openat fstatat unlinkat], [have_openat=yes], [have_openat=no])
 513 AC_CHECK_FUNCS([ioperm iopl], [have_io=yes])
 514 AC_CHECK_FUNCS([futimens], [have_futimens=yes])
 515 AC_CHECK_FUNCS([inotify_init1], [have_inotify_init1=yes])
 516 AC_CHECK_FUNCS([open_memstream], [have_open_memstream=yes],[have_open_memstream=no])
 517 AC_CHECK_FUNCS([reboot], [have_reboot=yes],[have_reboot=no])
 518 AC_CHECK_FUNCS([updwtmpx updwtmpx], [have_gnu_utmpx=yes], [have_gnu_utmpx=no])
 519 AC_CHECK_FUNCS([getusershell], [have_getusershell=yes],[have_getusershell=no])
 520
 521 AM_CONDITIONAL([HAVE_OPENAT], [test "x$have_openat" = xyes])
 522
 523 have_setns_syscall="yes"
 524 UL_CHECK_SYSCALL([setns])
 525 AS_IF([test "x$ul_cv_syscall_setns" = xno], [
 526    have_setns_syscall="no"
 527 ])
 528
 529 AC_CHECK_FUNCS([isnan], [],
 530         [AC_CHECK_LIB([m], [isnan], [MATH_LIBS="-lm"])]
 531         [AC_CHECK_LIB([m], [__isnan], [MATH_LIBS="-lm"])]
 532 )
 533 AC_SUBST([MATH_LIBS])
 534
 535
 536 dnl lib/mononotic.c may require -lrt
 537 AC_CHECK_FUNCS([clock_gettime], [],
 538         [AC_CHECK_LIB([rt], [clock_gettime], [REALTIME_LIBS="-lrt"])]
 539 )
 540
 541 have_timer="no"
 542 AC_CHECK_FUNCS([timer_create],
 543         [have_timer="yes"],
 544         [AC_CHECK_LIB([rt], [timer_create], [
 545                 have_timer="yes"
 546                 REALTIME_LIBS="-lrt"
 547                 AC_DEFINE_UNQUOTED([HAVE_TIMER_CREATE], [1], [Define if timer_create exist in -lrt])
 548         ],[
 549                 AC_SEARCH_LIBS([timer_create], [rt], [
 550                         AC_MSG_RESULT(yes)
 551                         have_timer="yes"
 552                         REALTIME_LIBS="-lrt -lpthread"
 553                         AC_DEFINE_UNQUOTED([HAVE_TIMER_CREATE], [1], [Define if timer_create exist in -lrt -lpthread])
 554                 ],[], [-lpthread]
 555                 )
 556         ])]
 557 )
 558
 559 AC_SUBST([REALTIME_LIBS])
 560
 561 AS_IF([test x"$have_timer" = xno], [
 562        AC_CHECK_FUNCS([setitimer], [have_timer="yes"], [have_timer="no"])
 563 ])
 564
 565
 566 AC_CHECK_LIB([rtas], [rtas_get_sysparm], [
 567         RTAS_LIBS="-lrtas"
 568         AC_DEFINE_UNQUOTED([HAVE_LIBRTAS], [1], [Define if librtas exists]), [],
 569 ])
 570 AC_SUBST([RTAS_LIBS])
 571
 572
 573 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 574                 AC_DEFINE_UNQUOTED([HAVE_SA_LEN], [1], [Define if struct sockaddr contains sa_len]), [],
 575         [#include <sys/types.h>
 576          #include <sys/socket.h>])
 577
 578 SOCKET_LIBS=
 579 AC_SEARCH_LIBS([socket], [socket],
 580         [AS_IF([test x"$ac_cv_search_socket" != x"none required"],
 581                 [SOCKET_LIBS="$SOCKET_LIBS -lsocket"])
 582 ])
 583 AC_SUBST([SOCKET_LIBS])
 584
 585
 586 have_dirfd=no
 587 AC_CHECK_FUNCS([dirfd], [have_dirfd=yes], [have_dirfd=no])
 588 AS_IF([test x"$have_dirfd" = xno], [
 589         AC_CHECK_DECLS([dirfd],
 590                 [have_dirfd=yes], [have_dirfd=no],
 591                 [#include <sys/types.h>
 592                  #include <dirent.h>])
 593 ])
 594
 595 have_ddfd=no
 596 AS_IF([test x"$have_dirfd" = xno], [
 597         AC_CHECK_MEMBERS([DIR.dd_fd],
 598                 [have_ddfd=yes], [have_ddfd=no],
 599                 [#include <sys/types.h>
 600                  #include <dirent.h>])
 601 ])
 602
 603 AM_CONDITIONAL([HAVE_DIRFD], [test "x$have_dirfd" = xyes -o "x$have_ddfd" = xyes])
 604
 605
 606 AC_MSG_CHECKING([whether program_invocation_short_name is defined])
 607 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 608         #include <errno.h>
 609 ]], [[
 610         program_invocation_short_name = "test";
 611 ]])], [
 612         AC_MSG_RESULT([yes])
 613         AC_DEFINE([HAVE_PROGRAM_INVOCATION_SHORT_NAME], [1],
 614                 [Define if program_invocation_short_name is defined])
 615 ], [
 616         AC_MSG_RESULT([no])
 617 ])
 618
 619
 620 AC_MSG_CHECKING([whether __progname is defined])
 621 AC_LINK_IFELSE([AC_LANG_PROGRAM([extern char *__progname;],
 622            [if (*__progname == 0) return 1;])],
 623            AC_DEFINE([HAVE___PROGNAME], [1], [Define if __progname is defined])
 624            AC_MSG_RESULT([yes]),
 625            AC_MSG_RESULT([no]))
 626
 627 dnl Static compilation
 628 m4_define([UL_STATIC_PROGRAMS], [losetup, mount, umount, fdisk, sfdisk, blkid, nsenter, unshare])
 629
 630 AC_ARG_ENABLE([static-programs],
 631   [AS_HELP_STRING([--enable-static-programs=LIST],
 632       [link static the programs in LIST (comma-separated,
 633       supported for ]m4_defn([UL_STATIC_PROGRAMS])[)])])
 634
 635 AS_CASE([$enable_static_programs],
 636   [yes],
 637     [enable_static_programs=m4_quote(UL_STATIC_PROGRAMS)],
 638   [no],
 639     [enable_static_programs=]
 640 )
 641
 642 dnl Set all the individual AM_CONDITIONALs
 643 m4_foreach([UL_PRG], m4_defn([UL_STATIC_PROGRAMS]), [
 644   AS_CASE([,$enable_static_programs,],
 645    [*,UL_PRG,*], [static_[]UL_PRG=yes]
 646   )
 647   AS_IF([test "x$static_[]UL_PRG" = xyes], [AC_MSG_NOTICE([enable static build: UL_PRG.])])
 648   AM_CONDITIONAL([HAVE_STATIC_]m4_toupper(UL_PRG),
 649     [test "x$static_[]UL_PRG" = xyes])
 650 ])
 651
 652
 653 AC_ARG_ENABLE([all-programs],
 654   AS_HELP_STRING([--disable-all-programs], [disable everything, might be overridden by --enable-<name>]),
 655   [], [enable_all_programs=undefined]
 656 )
 657
 658 AS_CASE([$enable_all_programs],
 659   [yes], [AC_MSG_WARN([force to build all programs by default])
 660           ul_default_estate=check],
 661   [no],  [AC_MSG_WARN([disable all programs by default])
 662           ul_default_estate=no]
 663 )
 664
 665
 666 AX_CHECK_TLS
 667
 668 AC_DEFUN([UL_SCANF_TYPE_MODIFIER], [dnl
 669 # include <stdio.h>
 670 # include <stdlib.h>
 671 int main()
 672 {
 673         int i;
 674         int rc = 1;
 675         char *s;
 676         i = sscanf("x", $1, &s);
 677         if (i == 1  && *s == 'x')
 678                 rc = 0;
 679         free(s);
 680         return rc;
 681 }])
 682
 683 AC_CACHE_VAL([scanf_cv_alloc_modifier],
 684   AC_RUN_IFELSE([AC_LANG_SOURCE([UL_SCANF_TYPE_MODIFIER(["%ms"])])],
 685     [scanf_cv_alloc_modifier=ms],
 686     AC_RUN_IFELSE([AC_LANG_SOURCE([UL_SCANF_TYPE_MODIFIER(["%as"])])],
 687       [scanf_cv_alloc_modifier=as],
 688       [scanf_cv_alloc_modifier=no]
 689     )
 690     ,
 691
 692     [AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 693      #include <stdio.h>
 694      #include <unistd.h>
 695
 696      #if defined(__GLIBC__) && !defined(__UCLIBC__)
 697
 698      #if !(__GLIBC_PREREQ(2, 7))
 699      #error %m is not available
 700      #endif
 701
 702      #elif defined(_POSIX_VERSION)
 703
 704      #if _POSIX_VERSION < 200809L
 705      #error %m is not available
 706      #endif
 707
 708      #else
 709      #error Your C-library is not supported.
 710      #endif
 711      ])],
 712     [scanf_cv_alloc_modifier=ms],
 713     [scanf_cv_alloc_modifier=no])]
 714   )
 715 )
 716
 717 AC_MSG_CHECKING([scanf string alloc modifiers])
 718 AS_CASE([$scanf_cv_alloc_modifier],
 719   [ms],
 720     [AC_MSG_RESULT([(%ms) yes])
 721      AC_DEFINE([HAVE_SCANF_MS_MODIFIER], [1], [scanf %ms modifier])
 722      have_scanf_alloc_modifier=yes],
 723   [as],
 724     [AC_MSG_RESULT([(%as) yes])
 725      have_scanf_alloc_modifier=yes
 726      AC_DEFINE([HAVE_SCANF_AS_MODIFIER], [1], [scanf %as modifier])],
 727   [AC_MSG_RESULT([no])
 728    have_scanf_alloc_modifier=no]
 729 )
 730
 731
 732 AC_ARG_WITH([util], AS_HELP_STRING([--without-util], [compile without libutil]),
 733   [], [with_util=auto]
 734 )
 735 AS_IF([test "x$with_util" = xno], [
 736   AM_CONDITIONAL([HAVE_UTIL], [false])
 737   have_util=no
 738 ], [
 739   UL_CHECK_LIB([util], [openpty])
 740 ])
 741
 742
 743 AC_CHECK_TYPES([union semun], [], [], [[
 744 #include <sys/sem.h>
 745 ]])
 746 AC_CHECK_TYPES([loff_t])
 747
 748
 749 AC_ARG_ENABLE([widechar],
 750   AS_HELP_STRING([--disable-widechar], [do not compile wide character support]),
 751   [], [enable_widechar=check]
 752 )
 753 UL_BUILD_INIT([widechar])
 754 UL_REQUIRES_COMPILE([widechar], [[
 755   #include <wchar.h>
 756   #include <wctype.h>
 757   #include <stdio.h>
 758   ]], [[
 759     wchar_t wc;
 760     wint_t w;
 761     w = fgetwc(stdin);
 762     if (w == WEOF) exit(1);
 763     wc = w;
 764     fputwc(wc,stdout);
 765   ]],
 766   [wchar_t support])
 767
 768 AS_IF([test "x$build_widechar" = xyes ], [
 769   AC_DEFINE([HAVE_WIDECHAR], [1], [Do we have wide character support?])
 770 ])
 771
 772
 773 AC_CHECK_TYPES([cpu_set_t], [have_cpu_set_t=yes], [], [[
 774 #include <sched.h>
 775 ]])
 776
 777 AM_CONDITIONAL([HAVE_CPU_SET_T], [test "x$have_cpu_set_t" = xyes])
 778
 779 AC_CHECK_TYPES([sighandler_t], [], [], [[
 780 #include <signal.h>
 781 ]])
 782
 783 AC_CHECK_DECLS([CPU_ALLOC], [], [], [[
 784 #include <sched.h>
 785 ]])
 786
 787 # on Solaris, you can't mix and match standards, since we use c99
 788 # aparently at this stage, XOPEN_SOURCE will conflict.  As workaround,
 789 # check for crypt.h and use that without XOPEN_SOURCE.
 790 have_crypt=no
 791 AC_CHECK_HEADERS([crypt.h])
 792 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 793 #ifdef HAVE_CRYPT_H
 794 #include <crypt.h>
 795 #else
 796 #define _XOPEN_SOURCE
 797 #include <unistd.h>
 798 #endif
 799 ]], [[
 800 char *c = crypt("abc","pw");
 801 ]])],[
 802   have_libcrypt=no
 803   have_crypt=yes
 804 ],[
 805   LIBS="$LIBS -lcrypt"
 806   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 807   #ifdef HAVE_CRYPT_H
 808   #include <crypt.h>
 809   #else
 810   #define _XOPEN_SOURCE
 811   #include <unistd.h>
 812   #endif
 813   ]], [[
 814   char *c = crypt("abc","pw");
 815   ]])],[
 816   AC_DEFINE([HAVE_LIBCRYPT], [1], [Do we need -lcrypt?])
 817   have_libcrypt=yes
 818   have_crypt=yes
 819   ],[
 820   AC_MSG_WARN([crypt() is not available])
 821   ])
 822 ])
 823 AM_CONDITIONAL([HAVE_LIBCRYPT], [test "x$have_libcrypt" = xyes])
 824
 825
 826 AC_ARG_WITH([selinux],
 827   AS_HELP_STRING([--with-selinux], [compile with SELinux support]),
 828   [], [with_selinux=no]
 829 )
 830
 831 AS_IF([test "x$with_selinux" = xno], [
 832   AM_CONDITIONAL([HAVE_SELINUX], [false])
 833 ], [
 834   PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.0],
 835         [AC_DEFINE([HAVE_LIBSELINUX], [1], [Define if SELinux is available])
 836          UL_PKG_STATIC([SELINUX_LIBS_STATIC], [libselinux])
 837          AM_CONDITIONAL([HAVE_SELINUX], [true])
 838          have_selinux=yes],
 839         [have_selinux=no])
 840
 841   AS_CASE([$with_selinux:$have_selinux],
 842     [yes:no], [AC_MSG_ERROR([SELinux selected but libselinux not found or too old])]
 843   )
 844
 845   AS_IF([test "x$have_selinux" = xyes], [
 846     UL_SET_FLAGS([], [], [$SELINUX_LIBS])
 847     # This function is missing in old libselinux 1.xx versions
 848     AC_CHECK_FUNCS([security_get_initial_context])
 849     UL_RESTORE_FLAGS
 850   ])
 851 ])
 852 AC_SUBST([SELINUX_LIBS])
 853 AC_SUBST([SELINUX_LIBS_STATIC])
 854
 855
 856 AC_ARG_WITH([audit],
 857   AS_HELP_STRING([--with-audit], [compile with audit support]),
 858   [], [with_audit=no]
 859 )
 860
 861 AS_IF([test "x$with_audit" = xno], [
 862   AM_CONDITIONAL([HAVE_AUDIT], [false])
 863 ], [
 864   UL_CHECK_LIB([audit], [audit_log_user_message])
 865   AS_CASE([$with_audit:$have_audit],
 866     [yes:no],
 867       [AC_MSG_ERROR([Audit selected but libaudit not found (or does not support audit_log_user_message())])]
 868   )
 869 ])
 870
 871 AC_ARG_WITH([udev], AS_HELP_STRING([--without-udev], [compile without udev support]),
 872   [], [with_udev=auto]
 873 )
 874
 875 AS_IF([test "x$with_udev" = xno], [
 876   AM_CONDITIONAL([HAVE_UDEV], [false])
 877 ], [
 878   UL_CHECK_LIB([udev], [udev_new])
 879   AS_CASE([$with_udev:$have_udev],
 880     [yes:no],
 881       [AC_MSG_ERROR([udev selected but libudev not found])]
 882   )
 883 ])
 884
 885
 886 dnl wide-char ncurses
 887 AC_ARG_WITH([ncursesw],
 888   AS_HELP_STRING([--without-ncursesw], [do not build with wide-char ncurses]),
 889   [], [with_ncursesw=auto]
 890 )
 891 have_ncursesw=no
 892 have_ncursesw_header=no
 893 AS_IF([test "x$with_ncursesw" != xno], [
 894   UL_NCURSES_CHECK([ncursesw])
 895   AS_IF([test "x$have_ncursesw" = xyes], [
 896     AC_CHECK_HEADERS([ncursesw/ncurses.h], [have_ncursesw_header=yes])
 897     AC_CHECK_HEADERS([ncursesw/term.h])
 898
 899     # Define HAVE_NCURSES_H only if check for HAVE_NCURSESW_NCURSES_H is
 900     # unsuccessful to avoid too many *_H permitations in config.h
 901     AS_IF([test "x$have_ncursesw_header" = xno], [
 902            AC_CHECK_HEADERS([ncurses.h], [have_ncursesw_header=yes])
 903            AC_CHECK_HEADERS([term.h])
 904     ])
 905     AS_IF([test "x$have_ncursesw_header" = xno], [have_ncursesw=no])
 906   ])
 907   AS_IF([test "x$have_ncursesw" = xyes], [
 908     CURSES_LIB_NAME="ncursesw"
 909     AC_DEFINE([HAVE_LIBNCURSESW], [1], [Define if ncursesw library available])
 910   ])
 911 ])
 912 AS_CASE([$with_ncursesw:$have_ncursesw],
 913   [yes:no], [AC_MSG_ERROR([ncursesw selected, but library not found])])
 914
 915
 916 dnl non-wide ncurses
 917 AC_ARG_WITH([ncurses],
 918   AS_HELP_STRING([--with-ncurses], [build with non-wide ncurses]),
 919   [], [with_ncurses=auto]
 920 )
 921 have_ncurses=no
 922 have_ncurses_header=no
 923 AS_CASE([$with_ncurses:$build_widechar],
 924   [yes:yes], [AC_MSG_ERROR([wide-char support enabled, but non-wide ncurses selects])])
 925
 926 AS_IF([test "x$have_ncursesw" = xno -a "x$with_ncurses" != xno ], [
 927   UL_NCURSES_CHECK([ncurses])
 928   AS_IF([test "x$have_ncurses" = xyes], [
 929     AC_CHECK_HEADERS([ncurses/ncurses.h], [have_ncurses_header=yes])
 930     AC_CHECK_HEADERS([ncurses/term.h])
 931
 932     # Define HAVE_NCURSES_H only if check for HAVE_NCURSES_NCURSES_H is
 933     # unsuccessful to avoid too many *_H permitations in config.h
 934     AS_IF([test "x$have_ncurses_header" = xno], [
 935            AC_CHECK_HEADERS([ncurses.h], [have_ncurses_header=yes])
 936            AC_CHECK_HEADERS([term.h])
 937     ])
 938     AS_IF([test "x$have_ncurses_header" = xno], [have_ncurses=no])
 939   ])
 940   AS_IF([test "x$have_ncurses" = xyes], [
 941     CURSES_LIB_NAME="ncurses"
 942     AC_DEFINE([HAVE_LIBNCURSES], [1], [Define if ncurses library available])
 943   ])
 944 ])
 945 AS_CASE([$with_ncurses:$have_ncurses],
 946   [yes:no], [AC_MSG_ERROR([ncurses selected, but library not found])])
 947
 948 AC_SUBST([NCURSES_CFLAGS])
 949 AC_SUBST([NCURSES_LIBS])
 950 AM_CONDITIONAL([HAVE_NCURSES], [test "x$have_ncursesw" = xyes -o  "x$have_ncurses" = xyes])
 951
 952
 953 AC_ARG_WITH([slang],
 954   AS_HELP_STRING([--with-slang], [compile cfdisk with slang rather than ncurses]),
 955   [], [with_slang=no]
 956 )
 957 have_slang=no
 958 AS_IF([test "x$with_slang" = xyes], [
 959   AC_CHECK_HEADERS([slang.h slang/slang.h])
 960   AC_CHECK_HEADERS([slcurses.h slang/slcurses.h],
 961                    [have_slang=yes], [], [
 962 #ifdef HAVE_SLANG_H
 963 #include <slang.h>
 964 #elif defined(HAVE_SLANG_SLANG_H)
 965 #include <slang/slang.h>
 966 #endif
 967 ])
 968   AS_IF([test "x$have_slang" = xno], [
 969     AC_MSG_ERROR([slang selected but slcurses.h not found])],
 970     [CURSES_LIB_NAME=slang
 971   ])
 972 ])
 973 AM_CONDITIONAL([HAVE_SLANG], [test "x$have_slang" = xyes])
 974
 975
 976 AS_IF([test "x$have_slang" = xyes -o "x$have_ncursesw" = xyes -o "x$have_ncurses" = xyes], [
 977         AC_CHECK_LIB([$CURSES_LIB_NAME], use_default_colors, [
 978                      AC_DEFINE(HAVE_USE_DEFAULT_COLORS, 1,
 979                                [Define if curses library has the use_default_colors().])
 980         ])
 981         AC_CHECK_LIB([$CURSES_LIB_NAME], resizeterm, [
 982                      AC_DEFINE(HAVE_RESIZETERM, 1,
 983                                [Define if curses library has the resizeterm().])
 984         ])
 985 ])
 986
 987
 988 AC_ARG_WITH([tinfo], AS_HELP_STRING([--without-tinfo], [compile without libtinfo]),
 989   [], [with_tinfo=auto]
 990 )
 991 have_tinfo=no
 992 have_tinfow=no
 993 AS_IF([test "x$with_tinfo" != xno], [
 994   AS_IF([test "x$have_ncursesw" = xyes], [
 995     UL_TINFO_CHECK([tinfow])
 996   ])
 997   AS_IF([test "x$have_tinfow" = xno], [
 998     UL_TINFO_CHECK([tinfo])
 999   ])
1000 ])
1001 AC_SUBST([TINFO_LIBS])
1002 AC_SUBST([TINFO_LIBS_STATIC])
1003 AC_SUBST([TINFO_CFLAGS])
1004 AM_CONDITIONAL([HAVE_TINFO], [test "x$have_tinfo" = xyes -o "x$have_tinfow" = xyes])
1005 AS_IF([test "x$have_tinfo" = xyes -o "x$have_tinfow" = xyes], [
1006   AC_DEFINE(HAVE_LIBTINFO, 1, [Define if libtinfo or libtinfow available.])
1007 ])
1008
1009
1010 AC_ARG_WITH([readline],
1011   AS_HELP_STRING([--without-readline], [do not build with GNU Readline support]),
1012   [], [with_readline=auto]
1013 )
1014
1015 AS_IF([test "x$with_readline" = xno], [
1016   AM_CONDITIONAL([HAVE_READLINE], [false])
1017 ], [
1018   UL_CHECK_LIB([readline], [readline])
1019   AS_CASE([$with_readline:$have_readline],
1020     [yes:no],
1021       [AC_MSG_ERROR([readline selected but libreadline not found ])],
1022     [*:yes],
1023       [READLINE_LIBS="-lreadline"
1024        READLINE_LIBS_STATIC="-lreadline $TINFO_LIBS_STATIC"]
1025   )
1026 ])
1027 AC_SUBST([READLINE_LIBS])
1028 AC_SUBST([READLINE_LIBS_STATIC])
1029
1030
1031 AC_ARG_WITH([utempter],
1032   AS_HELP_STRING([--with-utempter], [compile script(1) with libutempter]),
1033   [], [with_utempter=no]
1034 )
1035
1036 AS_IF([test "x$with_utempter" = xyes], [
1037   UL_CHECK_LIB([utempter], [utempter_add_record])
1038   AS_IF([test "x$have_utempter" = xno], [
1039     AC_MSG_ERROR([utempter selected but libutempter not found])
1040   ])
1041 ], [
1042   AM_CONDITIONAL([HAVE_UTEMPTER], [false])
1043 ])
1044
1045
1046 dnl
1047 dnl libuuid
1048 dnl
1049 AC_ARG_ENABLE([libuuid],
1050   AS_HELP_STRING([--disable-libuuid], [do not build libuuid and uuid utilities]),
1051   [], [UL_DEFAULT_ENABLE([libuuid], [yes])]
1052 )
1053 UL_BUILD_INIT([libuuid])
1054 AC_SUBST([LIBUUID_VERSION])
1055 AC_SUBST([LIBUUID_VERSION_INFO])
1056 AM_CONDITIONAL(BUILD_LIBUUID, test "x$build_libuuid" = xyes)
1057
1058 AC_ARG_ENABLE([libuuid-force-uuidd],
1059   AS_HELP_STRING([--enable-libuuid-force-uuidd], [support uuidd even though the daemon is not built]),
1060   [], [enable_libuuid_force_uuidd=no]
1061 )
1062
1063 AS_IF([test "x$build_libuuid" = xyes], [
1064   AC_DEFINE(HAVE_LIBUUID, 1, [Define to 1 if you have the -luuid.])
1065 ])
1066
1067 dnl
1068 dnl libblkid
1069 dnl
1070 AC_ARG_ENABLE([libblkid],
1071   AS_HELP_STRING([--disable-libblkid], [do not build libblkid and many related utilities]),
1072   [], [UL_DEFAULT_ENABLE([libblkid], [check])]
1073 )
1074 UL_BUILD_INIT([libblkid])
1075 UL_REQUIRES_HAVE([libblkid], [openat], [openat functions])
1076 UL_REQUIRES_HAVE([libblkid], [dirfd,ddfd], [dirfd or ddfd function])
1077 AC_SUBST([LIBBLKID_DATE])
1078 AC_SUBST([LIBBLKID_VERSION])
1079 AC_SUBST([LIBBLKID_VERSION_INFO])
1080 AC_DEFINE_UNQUOTED([LIBBLKID_VERSION], ["$LIBBLKID_VERSION"], [libblkid version string])
1081 AC_DEFINE_UNQUOTED([LIBBLKID_DATE], ["$LIBBLKID_DATE"], [libblkid date string])
1082 AS_IF([test "x$build_libblkid" = xyes], [
1083   AC_DEFINE([HAVE_LIBBLKID], [1], [Define to 1 if you have the -lblkid.])
1084 ])
1085 AM_CONDITIONAL([BUILD_LIBBLKID], [test "x$build_libblkid" = xyes])
1086 AM_CONDITIONAL([BUILD_LIBBLKID_TESTS], [test "x$build_libblkid" = xyes -a "x$enable_static" = xyes])
1087
1088 dnl
1089 dnl libmount
1090 dnl
1091 AC_ARG_ENABLE([libmount],
1092   AS_HELP_STRING([--disable-libmount], [do not build libmount]),
1093   [], [UL_DEFAULT_ENABLE([libmount], [check])]
1094 )
1095 UL_BUILD_INIT([libmount])
1096 UL_REQUIRES_BUILD([libmount], [libblkid])
1097 UL_REQUIRES_HAVE([libmount], [scanf_alloc_modifier], [scanf string alloc modifier])
1098 UL_REQUIRES_HAVE([libmount], [dirfd,ddfd], [dirfd or ddfd function])
1099 AM_CONDITIONAL([BUILD_LIBMOUNT], [test "x$build_libmount" = xyes])
1100 AM_CONDITIONAL([BUILD_LIBMOUNT_TESTS], [test "x$build_libmount" = xyes -a "x$enable_static" = xyes])
1101 AS_IF([test "x$build_libmount" = xyes], [
1102   AC_DEFINE(HAVE_LIBMOUNT, 1, [Define if libmount available.])
1103   AS_IF([test "x$have_setns_syscall" = "xyes"], [
1104     AC_DEFINE([USE_LIBMOUNT_SUPPORT_NAMESPACES], [1], [Define to 1 if want to support namepaces.])
1105   ],[
1106     AC_MSG_WARN([libmount will be compiled without namespaces support])
1107   ])
1108 ])
1109
1110 AC_SUBST([LIBMOUNT_VERSION])
1111 AC_SUBST([LIBMOUNT_MAJOR_VERSION], $PACKAGE_VERSION_MAJOR)
1112 AC_SUBST([LIBMOUNT_MINOR_VERSION], $PACKAGE_VERSION_MINOR)
1113 AC_SUBST([LIBMOUNT_PATCH_VERSION], $PACKAGE_VERSION_RELEASE)
1114 AC_SUBST([LIBMOUNT_VERSION_INFO])
1115 AC_DEFINE_UNQUOTED([LIBMOUNT_VERSION], ["$LIBMOUNT_VERSION"], [libmount version string])
1116
1117 AC_ARG_ENABLE([libmount-support-mtab],
1118   AS_HELP_STRING([--enable-libmount-support-mtab], [support /etc/mtab (default is use /proc/self/mountinfo)]),
1119   [], [enable_libmount_support_mtab=no]
1120 )
1121
1122 AS_IF([test "x$enable_libmount_support_mtab" = xyes], [
1123   AC_DEFINE([USE_LIBMOUNT_SUPPORT_MTAB], [1], [Define to 1 if want to support mtab.])
1124 ])
1125
1126 dnl
1127 dnl libsmartcols
1128 dnl
1129 AC_ARG_ENABLE([libsmartcols],
1130   AS_HELP_STRING([--disable-libsmartcols], [do not build libsmartcols]),
1131   [], [UL_DEFAULT_ENABLE([libsmartcols], [yes])]
1132 )
1133 UL_BUILD_INIT([libsmartcols])
1134 AM_CONDITIONAL([BUILD_LIBSMARTCOLS], [test "x$build_libsmartcols" = xyes])
1135
1136 AC_SUBST([LIBSMARTCOLS_VERSION])
1137 AC_SUBST([LIBSMARTCOLS_VERSION_INFO])
1138 AC_DEFINE_UNQUOTED([LIBSMARTCOLS_VERSION], ["$LIBSMARTCOLS_VERSION"], [libsmartcols version string])
1139
1140
1141 dnl
1142 dnl libfdisk
1143 dnl
1144 AC_ARG_ENABLE([libfdisk],
1145   AS_HELP_STRING([--disable-libfdisk], [do not build libfdisk]),
1146   [], [UL_DEFAULT_ENABLE([libfdisk], [check])]
1147 )
1148 UL_BUILD_INIT([libfdisk])
1149 UL_REQUIRES_BUILD([libfdisk], [libuuid])
1150 AM_CONDITIONAL([BUILD_LIBFDISK], [test "x$build_libfdisk" = xyes])
1151 AM_CONDITIONAL([BUILD_LIBFDISK_TESTS], [test "x$build_libfdisk" = xyes -a "x$enable_static" = xyes])
1152
1153 AS_IF([test "x$build_libblkid" = xyes],
1154   [LIBFDISK_PC_REQUIRES="uuid blkid"],[LIBFDISK_PC_REQUIRES="uuid"])
1155 AC_SUBST([LIBFDISK_PC_REQUIRES])
1156
1157 AC_SUBST([LIBFDISK_VERSION])
1158 AC_SUBST([LIBFDISK_MAJOR_VERSION], $PACKAGE_VERSION_MAJOR)
1159 AC_SUBST([LIBFDISK_MINOR_VERSION], $PACKAGE_VERSION_MINOR)
1160 AC_SUBST([LIBFDISK_PATCH_VERSION], $PACKAGE_VERSION_RELEASE)
1161 AC_SUBST([LIBFDISK_VERSION_INFO])
1162 AC_DEFINE_UNQUOTED([LIBFDISK_VERSION], ["$LIBFDISK_VERSION"], [libfdisk version string])
1163
1164
1165 AC_ARG_ENABLE([fdisks],
1166   AS_HELP_STRING([--disable-fdisks], [do not build fdisk(8), sfdisk(8) and cfdisk(8)]),
1167   [], [UL_DEFAULT_ENABLE([fdisks], [check])]
1168 )
1169 enable_fdisk=$enable_fdisks
1170 enable_sfdisk=$enable_fdisks
1171 enable_cfdisk=$enable_fdisks
1172
1173 UL_BUILD_INIT([fdisk])
1174 UL_REQUIRES_HAVE([fdisk], [openat], [openat functions])
1175 UL_REQUIRES_HAVE([fdisk], [dirfd,ddfd], [dirfd or ddfd function])
1176 UL_REQUIRES_BUILD([fdisk], [libfdisk])
1177 UL_REQUIRES_BUILD([fdisk], [libsmartcols])
1178 AM_CONDITIONAL([BUILD_FDISK], [test "x$build_fdisk" = xyes])
1179
1180
1181 UL_BUILD_INIT([sfdisk])
1182 UL_REQUIRES_HAVE([sfdisk], [openat], [openat functions])
1183 UL_REQUIRES_HAVE([sfdisk], [dirfd,ddfd], [dirfd or ddfd function])
1184 UL_REQUIRES_BUILD([sfdisk], [libfdisk])
1185 UL_REQUIRES_BUILD([sfdisk], [libsmartcols])
1186 AM_CONDITIONAL([BUILD_SFDISK], [test "x$build_sfdisk" = xyes])
1187
1188
1189 UL_BUILD_INIT([cfdisk])
1190 UL_REQUIRES_BUILD([cfdisk], [libfdisk])
1191 UL_REQUIRES_BUILD([cfdisk], [libsmartcols])
1192 UL_REQUIRES_HAVE([cfdisk], [open_memstream], [open_memstream function])
1193 UL_REQUIRES_HAVE([cfdisk], [ncursesw,slang,ncurses], [ncursesw, ncurses or slang library])
1194 AM_CONDITIONAL([BUILD_CFDISK], [test "x$build_cfdisk" = xyes])
1195
1196
1197 AC_ARG_ENABLE([mount],
1198   AS_HELP_STRING([--disable-mount], [do not build mount(8) and umount(8)]),
1199   [], [UL_DEFAULT_ENABLE([mount], [check])]
1200 )
1201 UL_BUILD_INIT([mount])
1202 UL_REQUIRES_LINUX([mount])
1203 UL_REQUIRES_BUILD([mount], [libmount])
1204 AM_CONDITIONAL([BUILD_MOUNT], [test "x$build_mount" = xyes])
1205
1206
1207 AC_ARG_ENABLE([losetup],
1208   AS_HELP_STRING([--disable-losetup], [do not build losetup]),
1209   [], [UL_DEFAULT_ENABLE([losetup], [check])]
1210 )
1211 UL_BUILD_INIT([losetup])
1212 UL_REQUIRES_LINUX([losetup])
1213 UL_REQUIRES_BUILD([losetup], [libsmartcols])
1214 AM_CONDITIONAL([BUILD_LOSETUP], [test "x$build_losetup" = xyes])
1215
1216 AC_ARG_ENABLE([zramctl],
1217   AS_HELP_STRING([--disable-zramctl], [do not build zramctl]),
1218   [], [UL_DEFAULT_ENABLE([zramctl], [check])]
1219 )
1220 UL_BUILD_INIT([zramctl])
1221 UL_REQUIRES_LINUX([zramctl])
1222 UL_REQUIRES_BUILD([zramctl], [libsmartcols])
1223 AM_CONDITIONAL([BUILD_ZRAMCTL], [test "x$build_zramctl" = xyes])
1224
1225 AC_ARG_ENABLE([fsck],
1226   AS_HELP_STRING([--disable-fsck], [do not build fsck]),
1227   [], [UL_DEFAULT_ENABLE([fsck], [check])]
1228 )
1229 UL_BUILD_INIT([fsck])
1230 UL_REQUIRES_BUILD([fsck], [libmount])
1231 AM_CONDITIONAL([BUILD_FSCK], [test "x$build_fsck" = xyes])
1232
1233
1234 AC_ARG_ENABLE([partx],
1235   AS_HELP_STRING([--disable-partx], [do not build addpart, delpart, partx]),
1236   [], [UL_DEFAULT_ENABLE([partx], [check])]
1237 )
1238 UL_BUILD_INIT([partx])
1239 UL_REQUIRES_LINUX([partx])
1240 UL_REQUIRES_BUILD([partx], [libblkid])
1241 UL_REQUIRES_BUILD([partx], [libsmartcols])
1242 AM_CONDITIONAL([BUILD_PARTX], [test "x$build_partx" = xyes])
1243
1244
1245 AC_ARG_ENABLE([uuidd],
1246   AS_HELP_STRING([--disable-uuidd], [do not build the uuid daemon]),
1247   [], [UL_DEFAULT_ENABLE([uuidd], [check])]
1248 )
1249 UL_BUILD_INIT([uuidd])
1250 UL_REQUIRES_BUILD([uuidd], [libuuid])
1251 UL_REQUIRES_HAVE([uuidd], [timer], [timer_create function])
1252 UL_REQUIRES_HAVE([uuidd], [sys_signalfd_h], [sys/signalfd.h header])
1253 AS_IF([test "x$build_uuidd" = xyes || test "x$enable_libuuid_force_uuidd" = xyes], [
1254   AC_DEFINE([HAVE_UUIDD], [1], [Define to 1 if you want to use uuid daemon.])
1255 ])
1256 AM_CONDITIONAL([BUILD_UUIDD], [test "x$build_uuidd" = xyes])
1257
1258
1259 UL_BUILD_INIT([uuidgen], [check])
1260 UL_REQUIRES_BUILD([uuidgen], [libuuid])
1261 AM_CONDITIONAL([BUILD_UUIDGEN], [test "x$build_uuidgen" = xyes])
1262
1263 UL_BUILD_INIT([uuidparse], [check])
1264 UL_REQUIRES_BUILD([uuidparse], [libuuid])
1265 UL_REQUIRES_BUILD([uuidparse], [libsmartcols])
1266 AM_CONDITIONAL([BUILD_UUIDPARSE], [test "x$build_uuidparse" = xyes])
1267
1268 UL_BUILD_INIT([blkid], [check])
1269 UL_REQUIRES_BUILD([blkid], [libblkid])
1270 AM_CONDITIONAL([BUILD_BLKID], [test "x$build_blkid" = xyes])
1271
1272 UL_BUILD_INIT([findfs], [check])
1273 UL_REQUIRES_BUILD([findfs], [libblkid])
1274 AM_CONDITIONAL([BUILD_FINDFS], [test "x$build_findfs" = xyes])
1275
1276 UL_BUILD_INIT([wipefs], [check])
1277 UL_REQUIRES_BUILD([wipefs], [libblkid])
1278 UL_REQUIRES_BUILD([wipefs], [libsmartcols])
1279 AM_CONDITIONAL([BUILD_WIPEFS], [test "x$build_wipefs" = xyes])
1280
1281 UL_BUILD_INIT([findmnt], [check])
1282 UL_REQUIRES_BUILD([findmnt], [libmount])
1283 UL_REQUIRES_BUILD([findmnt], [libblkid])
1284 UL_REQUIRES_BUILD([findmnt], [libsmartcols])
1285 AM_CONDITIONAL([BUILD_FINDMNT], [test "x$build_findmnt" = xyes])
1286
1287
1288 AC_ARG_ENABLE([mountpoint],
1289   AS_HELP_STRING([--disable-mountpoint], [do not build mountpoint]),
1290   [], [UL_DEFAULT_ENABLE([mountpoint], [check])]
1291 )
1292 UL_BUILD_INIT([mountpoint])
1293 UL_REQUIRES_BUILD([mountpoint], [libmount])
1294 AM_CONDITIONAL([BUILD_MOUNTPOINT], [test "x$build_mountpoint" = xyes])
1295
1296
1297 AC_ARG_ENABLE([fallocate],
1298   AS_HELP_STRING([--disable-fallocate], [do not build fallocate]),
1299   [], [UL_DEFAULT_ENABLE([fallocate], [check])]
1300 )
1301 UL_BUILD_INIT([fallocate])
1302 UL_REQUIRES_LINUX([fallocate])
1303 UL_REQUIRES_SYSCALL_CHECK([fallocate], [UL_CHECK_SYSCALL([fallocate])])
1304 AM_CONDITIONAL([BUILD_FALLOCATE], [test "x$build_fallocate" = xyes])
1305
1306 AS_IF([test "x$build_fallocate" = xyes], [
1307   dnl check for valid fallocate() function
1308   dnl with 32 bits glibc 2.10, fallocate() exists but not fallocate64()
1309   dnl when _FILE_OFFSET_BITS==64, fallocate() is redirect to fallocate64()
1310   dnl and program can't be linked.
1311   dnl AC_CHECK_FUNC can't catch such errors since it's redefining
1312   dnl function prototype.
1313   AC_MSG_CHECKING([for valid fallocate() function])
1314   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1315 #ifdef HAVE_UNISTD_H
1316 # include <unistd.h>
1317 #endif
1318 #ifdef HAVE_SYS_TYPES_H
1319 # include <sys/types.h>
1320 #endif
1321 #ifdef HAVE_LINUX_FALLOC_H
1322 # include <linux/falloc.h>
1323 #endif
1324 #ifdef HAVE_FCNTL_H
1325 # include <fcntl.h>
1326 #endif
1327 ]],[[
1328    long ret;
1329    ret = fallocate(0, FALLOC_FL_KEEP_SIZE, 0xfffffffful, 0xfffffffful);
1330    if (ret != 0) {
1331       return 1;
1332    }
1333    ]])],[
1334   AC_MSG_RESULT([yes])
1335   AC_DEFINE([HAVE_FALLOCATE], [1], [Have valid fallocate() function])],[
1336   AC_MSG_RESULT([no])])
1337 ])
1338
1339 AS_IF([test "x$build_fallocate" = xyes], [
1340   dnl check for valid posix_fallocate() function
1341   AC_MSG_CHECKING([for valid posix_fallocate() function])
1342   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1343 #ifdef HAVE_UNISTD_H
1344 # include <unistd.h>
1345 #endif
1346 #ifdef HAVE_SYS_TYPES_H
1347 # include <sys/types.h>
1348 #endif
1349 #ifdef HAVE_LINUX_FALLOC_H
1350 # include <linux/falloc.h>
1351 #endif
1352 #ifdef HAVE_FCNTL_H
1353 # include <fcntl.h>
1354 #endif
1355 ]],[[
1356    long ret;
1357    ret = posix_fallocate(0, 0xfffffffful, 0xfffffffful);
1358    if (ret != 0) {
1359       return 1;
1360    }
1361    ]])],[
1362   AC_MSG_RESULT([yes])
1363   AC_DEFINE([HAVE_POSIX_FALLOCATE], [1], [Have valid posix_fallocate() function])],[
1364   AC_MSG_RESULT([no])])
1365 ])
1366
1367
1368 AC_ARG_ENABLE([unshare],
1369   AS_HELP_STRING([--disable-unshare], [do not build unshare]),
1370   [], [UL_DEFAULT_ENABLE([unshare], [check])]
1371 )
1372 UL_BUILD_INIT([unshare])
1373 UL_REQUIRES_LINUX([unshare])
1374 UL_REQUIRES_SYSCALL_CHECK([unshare], [UL_CHECK_SYSCALL([unshare])])
1375 AM_CONDITIONAL([BUILD_UNSHARE], [test "x$build_unshare" = xyes])
1376 AC_CHECK_FUNCS([unshare])
1377
1378 AC_ARG_ENABLE([nsenter],
1379   AS_HELP_STRING([--disable-nsenter], [do not build nsenter]),
1380   [], [UL_DEFAULT_ENABLE([nsenter], [check])]
1381 )
1382 UL_BUILD_INIT([nsenter])
1383 UL_REQUIRES_LINUX([nsenter])
1384 UL_REQUIRES_HAVE([nsenter], [setns_syscall], [setns syscall])
1385 AM_CONDITIONAL([BUILD_NSENTER], [test "x$build_nsenter" = xyes])
1386 AC_CHECK_FUNCS([setns])
1387
1388
1389 AC_ARG_WITH([cap_ng],
1390   AS_HELP_STRING([--without-cap-ng], [compile without libcap-ng]),
1391   [], [with_cap_ng=auto]
1392 )
1393 AS_IF([test "x$with_cap_ng" = xno], [
1394   AM_CONDITIONAL([HAVE_CAP_NG], [false])
1395   have_cap_ng=no
1396 ],[
1397   UL_CHECK_LIB([cap-ng], [capng_apply], [cap_ng])
1398 ])
1399
1400
1401 AC_ARG_ENABLE([setpriv],
1402   AS_HELP_STRING([--disable-setpriv], [do not build setpriv]),
1403   [], [UL_DEFAULT_ENABLE([setpriv], [check])]
1404 )
1405 UL_BUILD_INIT([setpriv])
1406 UL_REQUIRES_LINUX([setpriv])
1407 UL_REQUIRES_HAVE([setpriv], [linux_securebits_h], [securebits.h header file])
1408 UL_REQUIRES_HAVE([setpriv], [cap_ng], [libcap-ng library])
1409 AM_CONDITIONAL([BUILD_SETPRIV], [test "x$build_setpriv" = xyes])
1410
1411
1412 AC_ARG_ENABLE([eject],
1413   AS_HELP_STRING([--disable-eject], [do not build eject]),
1414   [], [UL_DEFAULT_ENABLE([eject], [check])]
1415 )
1416 UL_BUILD_INIT([eject])
1417 UL_REQUIRES_LINUX([eject])
1418 UL_REQUIRES_BUILD([eject], [libmount])
1419 AM_CONDITIONAL([BUILD_EJECT], [test "x$build_eject" = xyes])
1420
1421
1422 AC_ARG_ENABLE([agetty],
1423   AS_HELP_STRING([--disable-agetty], [do not build agetty]),
1424   [], [UL_DEFAULT_ENABLE([agetty], [check])]
1425 )
1426 UL_BUILD_INIT([agetty])
1427 UL_REQUIRES_HAVE([agetty], [utmpx_h], [utmpx.h header])
1428 UL_REQUIRES_HAVE([agetty], [gnu_utmpx], [GNU utmpx functions])
1429 AM_CONDITIONAL([BUILD_AGETTY], [test "x$build_agetty" = xyes])
1430 AS_IF([test "x$have_futimens" = xyes -a "x$have_inotify_init1" = xyes ], [
1431   AC_DEFINE([AGETTY_RELOAD], [1], [Enable agetty --reload feature])
1432 ],[
1433   AC_MSG_WARN([futimens or inotify_init1 not found; agetty(8) will not provide ---reload functionality])
1434 ])
1435
1436
1437 AC_ARG_ENABLE([plymouth_support],
1438   AS_HELP_STRING([--disable-plymouth_support], [do not care about plymouth in sylogin(8) and agetty(8)]),
1439   [], [enable_plymouth_support=check]
1440 )
1441 UL_BUILD_INIT([plymouth_support])
1442 UL_REQUIRES_HAVE([plymouth_support], [tiocglcktrmios], [TIOCGLCKTRMIOS flag])
1443 UL_REQUIRES_HAVE([plymouth_support], [sock_cloexec], [SOCK_CLOEXEC flag])
1444 UL_REQUIRES_HAVE([plymouth_support], [sock_nonblock], [SOCK_NONBLOCK flag])
1445 UL_REQUIRES_HAVE([plymouth_support], [so_passcred], [SO_PASSCRED flag])
1446 AM_CONDITIONAL([USE_PLYMOUTH_SUPPORT], [test "x$build_plymouth_support" = xyes])
1447 AS_IF([test "x$build_plymouth_support" = xyes ], [
1448     AC_DEFINE([USE_PLYMOUTH_SUPPORT], [1], [Enable plymouth support feature for sulogin and aggety])
1449 ])
1450
1451
1452 AC_ARG_WITH([libz],
1453   AS_HELP_STRING([--without-libz], [compile without libz]),
1454   [], [with_libz=auto]
1455 )
1456 AS_IF([test "x$with_libz" = xno], [have_z=no], [
1457   AC_CHECK_LIB([z], [crc32], [have_z=yes], [have_z=no])
1458 ])
1459
1460
1461 AC_ARG_ENABLE([cramfs],
1462   AS_HELP_STRING([--disable-cramfs], [do not build fsck.cramfs, mkfs.cramfs]),
1463   [], [UL_DEFAULT_ENABLE([cramfs], [check])]
1464 )
1465 UL_BUILD_INIT([cramfs])
1466 UL_REQUIRES_HAVE([cramfs], [z], [z library])
1467 AM_CONDITIONAL([BUILD_CRAMFS], [test "x$build_cramfs" = xyes])
1468
1469
1470 AC_ARG_ENABLE([bfs],
1471   AS_HELP_STRING([--disable-bfs], [do not build mkfs.bfs]),
1472   [], [UL_DEFAULT_ENABLE([bfs], [yes])]
1473 )
1474 UL_BUILD_INIT([bfs])
1475 AM_CONDITIONAL([BUILD_BFS], [test "x$build_bfs" = xyes])
1476
1477
1478 AC_ARG_ENABLE([minix],
1479   AS_HELP_STRING([--disable-minix], [do not build fsck.minix, mkfs.minix]),
1480   [], [UL_DEFAULT_ENABLE([minix], [yes])]
1481 )
1482 UL_BUILD_INIT([minix])
1483 AM_CONDITIONAL([BUILD_MINIX], [test "x$build_minix" = xyes])
1484
1485
1486 AC_ARG_ENABLE([fdformat],
1487   AS_HELP_STRING([--disable-fdformat], [do not build fdformat]),
1488   [], [UL_DEFAULT_ENABLE([fdformat], [check])]
1489 )
1490 UL_BUILD_INIT([fdformat])
1491 UL_REQUIRES_LINUX([fdformat])
1492 AM_CONDITIONAL([BUILD_FDFORMAT], [test "x$build_fdformat" = xyes])
1493
1494
1495 AC_ARG_ENABLE([hwclock],
1496   AS_HELP_STRING([--disable-hwclock], [do not build hwclock]),
1497   [], [UL_DEFAULT_ENABLE([hwclock], [check])]
1498 )
1499 have_linuxdummy=$linux_os
1500
1501 UL_BUILD_INIT([hwclock])
1502 UL_REQUIRES_HAVE([hwclock], [io, linuxdummy], [ioperm iopl function or Linux])
1503 AM_CONDITIONAL([BUILD_HWCLOCK], [test "x$build_hwclock" = xyes])
1504
1505
1506 UL_BUILD_INIT([mkfs], [yes])
1507 AM_CONDITIONAL([BUILD_MKFS], [test "x$build_mkfs" = xyes])
1508
1509 UL_BUILD_INIT([isosize], [yes])
1510 AM_CONDITIONAL([BUILD_ISOSIZE], [test "x$build_isosize" = xyes])
1511
1512
1513 UL_BUILD_INIT([fstrim], [check])
1514 UL_REQUIRES_LINUX([fstrim])
1515 UL_REQUIRES_BUILD([fstrim], [libmount])
1516 AM_CONDITIONAL([BUILD_FSTRIM], [test "x$build_fstrim" = xyes])
1517
1518
1519 UL_BUILD_INIT([swapon], [check])
1520 UL_REQUIRES_LINUX([swapon])
1521 UL_REQUIRES_SYSCALL_CHECK([swapon], [UL_CHECK_SYSCALL([swapon])], [swapon])
1522 UL_REQUIRES_SYSCALL_CHECK([swapon], [UL_CHECK_SYSCALL([swapoff])], [swapoff])
1523 UL_REQUIRES_BUILD([swapon], [libblkid])
1524 UL_REQUIRES_BUILD([swapon], [libmount])
1525 UL_REQUIRES_BUILD([swapon], [libsmartcols])
1526 AM_CONDITIONAL([BUILD_SWAPON], [test "x$build_swapon" = xyes])
1527 AC_CHECK_FUNCS([swapon])
1528 AC_CHECK_FUNCS([swapoff])
1529
1530
1531 UL_BUILD_INIT([lsblk], [check])
1532 UL_REQUIRES_LINUX([lsblk])
1533 UL_REQUIRES_BUILD([lsblk], [libblkid])
1534 UL_REQUIRES_BUILD([lsblk], [libmount])
1535 UL_REQUIRES_BUILD([lsblk], [libsmartcols])
1536 AM_CONDITIONAL([BUILD_LSBLK], [test "x$build_lsblk" = xyes])
1537
1538
1539 UL_BUILD_INIT([lscpu], [check])
1540 UL_REQUIRES_LINUX([lscpu])
1541 UL_REQUIRES_BUILD([lscpu], [libsmartcols])
1542 UL_REQUIRES_HAVE([lscpu], [cpu_set_t], [cpu_set_t type])
1543 AM_CONDITIONAL([BUILD_LSCPU], [test "x$build_lscpu" = xyes])
1544
1545
1546 AC_ARG_ENABLE([lslogins],
1547   AS_HELP_STRING([--disable-lslogins], [do not build lslogins]),
1548   [], [UL_DEFAULT_ENABLE([lslogins], [check])]
1549 )
1550 UL_BUILD_INIT([lslogins])
1551 UL_REQUIRES_BUILD([lslogins], [libsmartcols])
1552 UL_REQUIRES_HAVE([lslogins], [shadow_h], [shadow.h header])
1553 UL_REQUIRES_HAVE([lslogins], [utmpx_h], [utmpx.h header])
1554 UL_REQUIRES_HAVE([lslogins], [gnu_utmpx], [GNU utmpx functions])
1555 AM_CONDITIONAL([BUILD_LSLOGINS], [test "x$build_lslogins" = xyes])
1556
1557
1558 UL_BUILD_INIT([chcpu], [check])
1559 UL_REQUIRES_LINUX([chcpu])
1560 UL_REQUIRES_HAVE([chcpu], [cpu_set_t], [cpu_set_t type])
1561 AM_CONDITIONAL([BUILD_CHCPU], [test "x$build_chcpu" = xyes])
1562
1563
1564 AC_ARG_ENABLE([wdctl],
1565   AS_HELP_STRING([--disable-wdctl], [do not build wdctl]),
1566   [], [UL_DEFAULT_ENABLE([wdctl], [check])]
1567 )
1568 UL_BUILD_INIT([wdctl])
1569 UL_REQUIRES_LINUX([wdctl])
1570 UL_REQUIRES_BUILD([wdctl], [libsmartcols])
1571 UL_REQUIRES_HAVE([wdctl], [linux_watchdog_h], [linux/watchdog.h header file])
1572 AM_CONDITIONAL([BUILD_WDCTL], [test "x$build_wdctl" = xyes])
1573
1574
1575 UL_BUILD_INIT([swaplabel], [check])
1576 UL_REQUIRES_BUILD([swaplabel], [libblkid])
1577 AM_CONDITIONAL([BUILD_SWAPLABEL], [test "x$build_swaplabel" = xyes])
1578
1579
1580 UL_BUILD_INIT([mkswap], [yes])
1581 AM_CONDITIONAL([BUILD_MKSWAP], [test "x$build_mkswap" = xyes])
1582 AS_IF([test "x$build_mkswap" = xyes -a "x$build_libuuid" != xyes], [
1583   AC_MSG_WARN([uuid library is not found; mkswap(8) will not generate UUIDs])
1584 ])
1585
1586
1587 AC_ARG_ENABLE([cal],
1588   AS_HELP_STRING([--disable-cal], [do not build cal]),
1589   [], [UL_DEFAULT_ENABLE([cal], [check])]
1590 )
1591 UL_BUILD_INIT([cal])
1592 AM_CONDITIONAL([BUILD_CAL], [test "x$build_cal" = xyes])
1593
1594 AC_ARG_ENABLE([logger],
1595   AS_HELP_STRING([--disable-logger], [do not build logger]),
1596   [], [UL_DEFAULT_ENABLE([logger], [check])]
1597 )
1598 UL_BUILD_INIT([logger])
1599 AM_CONDITIONAL([BUILD_LOGGER], [test "x$build_logger" = xyes])
1600
1601 UL_BUILD_INIT([look], [yes])
1602 AM_CONDITIONAL([BUILD_LOOK], [test "x$build_look" = xyes])
1603
1604 UL_BUILD_INIT([mcookie], [yes])
1605 AM_CONDITIONAL([BUILD_MCOOKIE], [test "x$build_mcookie" = xyes])
1606
1607 UL_BUILD_INIT([namei], [yes])
1608 AM_CONDITIONAL([BUILD_NAMEI], [test "x$build_namei" = xyes])
1609
1610 matriplet="$($CC -print-multiarch 2>/dev/null || true)"
1611 if test "x$matriplet" != "x"; then
1612   AC_DEFINE_UNQUOTED([MULTIARCHTRIPLET], ["$matriplet"],
1613   ["Multi-arch triplet for whereis library search path"])
1614 fi
1615 UL_BUILD_INIT([whereis], [yes])
1616 AM_CONDITIONAL([BUILD_WHEREIS], [test "x$build_whereis" = xyes])
1617
1618 UL_BUILD_INIT([getopt], [yes])
1619 AM_CONDITIONAL([BUILD_GETOPT], [test "x$build_getopt" = xyes])
1620
1621
1622 UL_BUILD_INIT([blockdev], [check])
1623 UL_REQUIRES_LINUX([blockdev])
1624 AM_CONDITIONAL([BUILD_BLOCKDEV], [test "x$build_blockdev" = xyes])
1625
1626
1627 UL_BUILD_INIT([prlimit], [check])
1628 UL_REQUIRES_LINUX([prlimit])
1629 UL_REQUIRES_BUILD([prlimit], [libsmartcols])
1630 UL_REQUIRES_SYSCALL_CHECK([prlimit], [UL_CHECK_SYSCALL([prlimit64])], [prlimit64])
1631 AM_CONDITIONAL([BUILD_PRLIMIT], [test "x$build_prlimit" = xyes])
1632 AS_IF([test "x$build_prlimit" = xyes], [
1633   AC_CHECK_FUNCS([prlimit])
1634 ])
1635
1636
1637 UL_BUILD_INIT([lslocks], [check])
1638 UL_REQUIRES_LINUX([lslocks])
1639 UL_REQUIRES_BUILD([lslocks], [libmount])
1640 UL_REQUIRES_BUILD([lslocks], [libsmartcols])
1641 AM_CONDITIONAL([BUILD_LSLOCKS], [test "x$build_lslocks" = xyes])
1642
1643
1644 AC_ARG_ENABLE([switch_root],
1645   AS_HELP_STRING([--disable-switch_root], [do not build switch_root]),
1646   [], [UL_DEFAULT_ENABLE([switch_root], [check])]
1647 )
1648 UL_BUILD_INIT([switch_root])
1649 UL_REQUIRES_LINUX([switch_root])
1650 UL_REQUIRES_HAVE([switch_root], [openat], [openat function])
1651 UL_REQUIRES_HAVE([switch_root], [dirfd,ddfd], [dirfd or ddfd function])
1652 AM_CONDITIONAL([BUILD_SWITCH_ROOT], [test "x$build_switch_root" = xyes])
1653
1654
1655 AC_ARG_ENABLE([pivot_root],
1656   AS_HELP_STRING([--disable-pivot_root], [do not build pivot_root]),
1657   [], [UL_DEFAULT_ENABLE([pivot_root], [check])]
1658 )
1659 UL_BUILD_INIT([pivot_root])
1660 UL_REQUIRES_LINUX([pivot_root])
1661 UL_REQUIRES_SYSCALL_CHECK([pivot_root], [UL_CHECK_SYSCALL([pivot_root])])
1662 AM_CONDITIONAL([BUILD_PIVOT_ROOT], [test "x$build_pivot_root" = xyes])
1663
1664
1665 UL_BUILD_INIT([flock], [check])
1666 UL_REQUIRES_HAVE([flock], [timer], [timer_create/setitimer function])
1667 AM_CONDITIONAL([BUILD_FLOCK], [test "x$build_flock" = xyes])
1668
1669
1670 AC_ARG_ENABLE([lsmem],
1671   AS_HELP_STRING([--disable-lsmem], [do not build lsmem]),
1672   [], [UL_DEFAULT_ENABLE([lsmem], [check])]
1673 )
1674 UL_BUILD_INIT([lsmem])
1675 UL_REQUIRES_LINUX([lsmem])
1676 UL_REQUIRES_BUILD([lsmem], [libsmartcols])
1677 AM_CONDITIONAL([BUILD_LSMEM], [test "x$build_lsmem" = xyes])
1678
1679
1680 AC_ARG_ENABLE([chmem],
1681   AS_HELP_STRING([--disable-chmem], [do not build chmem]),
1682   [], [UL_DEFAULT_ENABLE([chmem], [check])]
1683 )
1684 UL_BUILD_INIT([chmem])
1685 UL_REQUIRES_LINUX([chmem])
1686 AM_CONDITIONAL([BUILD_CHMEM], [test "x$build_chmem" = xyes])
1687
1688 UL_BUILD_INIT([ipcmk], [yes])
1689 AM_CONDITIONAL([BUILD_IPCMK], [test "x$build_ipcmk" = xyes])
1690
1691
1692 AC_ARG_ENABLE([ipcrm],
1693   AS_HELP_STRING([--disable-ipcrm], [do not build ipcrm]),
1694   [], [UL_DEFAULT_ENABLE([ipcrm], [yes])]
1695 )
1696 UL_BUILD_INIT([ipcrm])
1697 AM_CONDITIONAL([BUILD_IPCRM], [test "x$build_ipcrm" = xyes])
1698
1699 AC_ARG_ENABLE([ipcs],
1700   AS_HELP_STRING([--disable-ipcs], [do not build ipcs]),
1701   [], [UL_DEFAULT_ENABLE([ipcs], [yes])]
1702 )
1703 UL_BUILD_INIT([ipcs])
1704 AM_CONDITIONAL([BUILD_IPCS], [test "x$build_ipcs" = xyes])
1705
1706 UL_BUILD_INIT([choom], [check])
1707 UL_REQUIRES_LINUX([choom])
1708 AM_CONDITIONAL([BUILD_CHOOM], [test "x$build_choom" = xyes])
1709
1710 UL_BUILD_INIT([lsipc], [check])
1711 UL_REQUIRES_LINUX([lsipc])
1712 UL_REQUIRES_BUILD([lsipc], [libsmartcols])
1713 AM_CONDITIONAL([BUILD_LSIPC], [test "x$build_lsipc" = xyes])
1714
1715 UL_BUILD_INIT([lsns], [check])
1716 UL_REQUIRES_LINUX([lsns])
1717 UL_REQUIRES_BUILD([lsns], [libsmartcols])
1718 UL_REQUIRES_BUILD([lsns], [libmount])
1719 AM_CONDITIONAL([BUILD_LSNS], [test "x$build_lsns" = xyes])
1720
1721 UL_BUILD_INIT([renice], [yes])
1722 AM_CONDITIONAL([BUILD_RENICE], [test "x$build_renice" = xyes])
1723
1724
1725 AC_ARG_ENABLE([rfkill],
1726   AS_HELP_STRING([--disable-rfkill], [do not build rfkill]),
1727   [], [UL_DEFAULT_ENABLE([rfkill], [check])]
1728 )
1729 UL_BUILD_INIT([rfkill])
1730 UL_REQUIRES_LINUX([rfkill])
1731 UL_REQUIRES_BUILD([rfkill], [libsmartcols])
1732 AM_CONDITIONAL([BUILD_RFKILL], [test "x$build_rfkill" = xyes])
1733
1734
1735 UL_BUILD_INIT([setsid], [yes])
1736 AM_CONDITIONAL([BUILD_SETSID], [test "x$build_setsid" = xyes])
1737
1738 UL_BUILD_INIT([readprofile], [check])
1739 UL_REQUIRES_LINUX([readprofile])
1740 AM_CONDITIONAL([BUILD_READPROFILE], [test "x$build_readprofile" = xyes])
1741
1742 UL_BUILD_INIT([dmesg], [check])
1743 UL_REQUIRES_LINUX([dmesg])
1744 AM_CONDITIONAL([BUILD_DMESG], [test "x$build_dmesg" = xyes])
1745
1746 UL_BUILD_INIT([ctrlaltdel], [check])
1747 UL_REQUIRES_LINUX([ctrlaltdel])
1748 dnl we assume reboot() to be the 1-argument variant, because even considering
1749 dnl widely used alternative C libraries like uclibc, dietlibc and musl,
1750 dnl reboot() with multiple arguments is yet only found in glibc versions
1751 dnl earlier than 2.x.
1752 UL_REQUIRES_HAVE([ctrlaltdel], [reboot], [reboot function])
1753 AM_CONDITIONAL([BUILD_CTRLALTDEL], [test "x$build_ctrlaltdel" = xyes])
1754
1755 UL_BUILD_INIT([fincore], [check])
1756 UL_REQUIRES_LINUX([fincore])
1757 UL_REQUIRES_BUILD([fincore], [libsmartcols])
1758 AM_CONDITIONAL([BUILD_FINCORE], [test "x$build_fincore" = xyes])
1759
1760 UL_BUILD_INIT([fsfreeze], [check])
1761 UL_REQUIRES_LINUX([fsfreeze])
1762 AM_CONDITIONAL([BUILD_FSFREEZE], [test "x$build_fsfreeze" = xyes])
1763
1764 UL_BUILD_INIT([blkdiscard], [check])
1765 UL_REQUIRES_LINUX([blkdiscard])
1766 AM_CONDITIONAL([BUILD_BLKDISCARD], [test "x$build_blkdiscard" = xyes])
1767
1768 UL_BUILD_INIT([blkzone], [check])
1769 UL_REQUIRES_LINUX([blkzone])
1770 UL_REQUIRES_HAVE([blkzone], [linux_blkzoned_h], [linux/blkzoned.h header])
1771 AM_CONDITIONAL([BUILD_BLKZONE], [test "x$build_blkzone" = xyes])
1772
1773 UL_BUILD_INIT([ldattach], [check])
1774 UL_REQUIRES_LINUX([ldattach])
1775 AM_CONDITIONAL([BUILD_LDATTACH], [test "x$build_ldattach" = xyes])
1776
1777 UL_BUILD_INIT([rtcwake], [check])
1778 UL_REQUIRES_LINUX([rtcwake])
1779 AM_CONDITIONAL([BUILD_RTCWAKE], [test "x$build_rtcwake" = xyes])
1780
1781 UL_BUILD_INIT([setarch], [check])
1782 UL_REQUIRES_LINUX([setarch])
1783 AM_CONDITIONAL([BUILD_SETARCH], [test "x$build_setarch" = xyes])
1784
1785 UL_BUILD_INIT([script], [check])
1786 UL_REQUIRES_HAVE([script], [sys_signalfd_h], [sys/signalfd.h header])
1787 AM_CONDITIONAL([BUILD_SCRIPT], [test "x$build_script" = xyes])
1788
1789 UL_BUILD_INIT([scriptreplay], [yes])
1790 AM_CONDITIONAL([BUILD_SCRIPTREPLAY], [test "x$build_scriptreplay" = xyes])
1791
1792 UL_BUILD_INIT([col], [yes])
1793 AM_CONDITIONAL([BUILD_COL], [test "x$build_col" = xyes])
1794
1795 UL_BUILD_INIT([colcrt], [yes])
1796 AM_CONDITIONAL([BUILD_COLCRT], [test "x$build_colcrt" = xyes])
1797
1798 UL_BUILD_INIT([colrm], [yes])
1799 AM_CONDITIONAL([BUILD_COLRM], [test "x$build_colrm" = xyes])
1800
1801 UL_BUILD_INIT([column], [check])
1802 UL_REQUIRES_BUILD([column], [libsmartcols])
1803 AM_CONDITIONAL([BUILD_COLUMN], [test "x$build_column" = xyes])
1804
1805 UL_BUILD_INIT([hexdump], [yes])
1806 AM_CONDITIONAL([BUILD_HEXDUMP], [test "x$build_hexdump" = xyes])
1807
1808 UL_BUILD_INIT([rev], [yes])
1809 AM_CONDITIONAL([BUILD_REV], [test "x$build_rev" = xyes])
1810
1811
1812 AC_ARG_ENABLE([tunelp],
1813   AS_HELP_STRING([--enable-tunelp], [build tunelp]),
1814   [], [UL_DEFAULT_ENABLE([tunelp], [no])]
1815 )
1816 UL_BUILD_INIT([tunelp])
1817 UL_REQUIRES_LINUX([tunelp])
1818 AM_CONDITIONAL([BUILD_TUNELP], [test "x$build_tunelp" = xyes])
1819
1820
1821 AC_ARG_ENABLE([kill],
1822   AS_HELP_STRING([--disable-kill], [do not build kill]),
1823   [], [UL_DEFAULT_ENABLE([kill], [check])]
1824 )
1825 UL_BUILD_INIT([kill])
1826 UL_REQUIRES_LINUX([kill])
1827 AM_CONDITIONAL([BUILD_KILL], [test "x$build_kill" = xyes])
1828
1829
1830 AC_ARG_ENABLE([last],
1831   AS_HELP_STRING([--disable-last], [do not build last]),
1832   [], [UL_DEFAULT_ENABLE([last], [check])]
1833 )
1834 UL_BUILD_INIT([last])
1835 UL_REQUIRES_HAVE([last], [utmpx_h], [utmpx.h header])
1836 UL_REQUIRES_HAVE([last], [gnu_utmpx], [GNU utmpx functions])
1837 AM_CONDITIONAL([BUILD_LAST], [test "x$build_last" = xyes])
1838
1839
1840 AC_ARG_ENABLE([utmpdump],
1841   AS_HELP_STRING([--disable-utmpdump], [do not build utmpdump]),
1842   [], [UL_DEFAULT_ENABLE([utmpdump], [check])]
1843 )
1844 UL_BUILD_INIT([utmpdump])
1845 UL_REQUIRES_HAVE([utmpdump], [utmpx_h], [utmpx.h header])
1846 UL_REQUIRES_HAVE([utmpdump], [gnu_utmpx], [GNU utmpx functions])
1847 AM_CONDITIONAL([BUILD_UTMPDUMP], [test "x$build_utmpdump" = xyes])
1848
1849
1850 AC_ARG_ENABLE([line],
1851   AS_HELP_STRING([--enable-line], [build line]),
1852   [], [UL_DEFAULT_ENABLE([line], [no])]
1853 )
1854 UL_BUILD_INIT([line])
1855 AM_CONDITIONAL([BUILD_LINE], [test "x$build_line" = xyes])
1856
1857
1858 AC_ARG_ENABLE([mesg],
1859   AS_HELP_STRING([--disable-mesg], [do not build mesg]),
1860   [], [UL_DEFAULT_ENABLE([mesg], [yes])]
1861 )
1862 UL_BUILD_INIT([mesg])
1863 AM_CONDITIONAL([BUILD_MESG], [test "x$build_mesg" = xyes])
1864
1865
1866 AC_ARG_ENABLE([raw],
1867   AS_HELP_STRING([--disable-raw], [do not build raw]),
1868   [], [UL_DEFAULT_ENABLE([raw], [check])]
1869 )
1870 UL_BUILD_INIT([raw])
1871 UL_REQUIRES_LINUX([raw])
1872 UL_REQUIRES_HAVE([raw], [linux_raw_h], [raw.h header file])
1873 AM_CONDITIONAL([BUILD_RAW], [test "x$build_raw" = xyes])
1874
1875
1876 AC_ARG_ENABLE([rename],
1877   AS_HELP_STRING([--disable-rename], [do not build rename]),
1878   [], [UL_DEFAULT_ENABLE([rename], [yes])]
1879 )
1880 UL_BUILD_INIT([rename])
1881 AM_CONDITIONAL([BUILD_RENAME], [test "x$build_rename" = xyes])
1882
1883
1884 AC_ARG_ENABLE([vipw],
1885   AS_HELP_STRING([--enable-vipw], [build vipw]),
1886   [], [UL_DEFAULT_ENABLE([vipw], [no])]
1887 )
1888 UL_BUILD_INIT([vipw])
1889 UL_REQUIRES_HAVE([vipw], [shadow_h], [shadow.h header])
1890 AM_CONDITIONAL([BUILD_VIPW], [test "x$build_vipw" = xyes])
1891
1892
1893 AC_ARG_ENABLE([newgrp],
1894   AS_HELP_STRING([--enable-newgrp], [build newgrp]),
1895   [], [UL_DEFAULT_ENABLE([newgrp], [no])]
1896 )
1897 UL_BUILD_INIT([newgrp])
1898 UL_REQUIRES_HAVE([newgrp], [crypt], [crypt function])
1899 AM_CONDITIONAL([BUILD_NEWGRP], [test "x$build_newgrp" = xyes])
1900
1901
1902 AC_ARG_WITH([user], AS_HELP_STRING([--without-user], [compile without libuser (remote chsh)]),
1903   [], [with_user=check]
1904 )
1905 have_user=no
1906 AS_IF([test "x$with_user" != xno], [
1907   PKG_CHECK_MODULES(LIBUSER,[libuser >= 0.58], [have_user=yes], [have_user=no])
1908   AS_CASE([$with_user:$have_user],
1909     [yes:no],
1910       [AC_MSG_ERROR([user selected but libuser not found])],
1911     [*:yes],
1912       [AC_DEFINE([HAVE_LIBUSER], [1], [Define if libuser is available])]
1913   )
1914   # temporary solution, libuser has stupid .pc where are exported all
1915   # private dependencies to Requires: instead of Requires.private:
1916   AS_IF([test "x$have_user" = xyes], [
1917     LIBUSER_LIBS=-luser
1918   ])
1919 ])
1920 AM_CONDITIONAL([HAVE_USER], [test "x$have_user" = xyes])
1921
1922 AC_ARG_ENABLE([chfn-chsh-password],
1923   AS_HELP_STRING([--disable-chfn-chsh-password], [do not require the user to enter the password in chfn and chsh]),
1924   [], [enable_chfn_chsh_password=yes]
1925 )
1926
1927 AC_ARG_ENABLE([chfn-chsh],
1928   AS_HELP_STRING([--enable-chfn-chsh], [build chfn and chsh]),
1929   [], [UL_DEFAULT_ENABLE([chfn_chsh], [check])]
1930 )
1931 UL_BUILD_INIT([chfn_chsh])
1932 UL_REQUIRES_HAVE([chfn_chsh], [shadow_h], [shadow.h header])
1933 UL_REQUIRES_HAVE([chfn_chsh], [getusershell], [getusershell function])
1934
1935 AS_IF([test "x$enable_chfn_chsh_password" = xyes -o "x$have_user" = xyes], [
1936   UL_REQUIRES_HAVE([chfn_chsh], [security_pam_appl_h], [PAM header file])
1937   AC_DEFINE([CHFN_CHSH_PASSWORD], [1], [Should chfn and chsh require the user to enter the password?])
1938 ])
1939 AM_CONDITIONAL([BUILD_CHFN_CHSH], [test "x$build_chfn_chsh" = xyes])
1940 AM_CONDITIONAL([CHFN_CHSH_PASSWORD], [test "x$enable_chfn_chsh_password" = xyes])
1941
1942 AC_ARG_ENABLE([chsh-only-listed],
1943   AS_HELP_STRING([--disable-chsh-only-listed], [chsh: allow shells not in /etc/shells]),
1944   [], enable_chsh_only_listed=yes
1945 )
1946
1947 AS_IF([test "x$enable_chsh_only_listed" = xyes], [
1948   AC_DEFINE([ONLY_LISTED_SHELLS], [1], [Should chsh allow only shells in /etc/shells?])
1949 ])
1950
1951
1952 AC_ARG_ENABLE([login],
1953   AS_HELP_STRING([--disable-login], [do not build login]),
1954   [], [UL_DEFAULT_ENABLE([login], [check])]
1955 )
1956 UL_BUILD_INIT([login])
1957 UL_REQUIRES_HAVE([login], [security_pam_appl_h], [PAM header file])
1958 UL_REQUIRES_HAVE([login], [security_pam_misc_h, security_openpam_h], [PAM conversation functions])
1959 UL_REQUIRES_HAVE([login], [utmpx_h], [utmpx.h header])
1960 UL_REQUIRES_HAVE([login], [gnu_utmpx], [GNU utmpx functions])
1961 AM_CONDITIONAL([BUILD_LOGIN], [test "x$build_login" = xyes])
1962
1963 AC_ARG_ENABLE([login-chown-vcs],
1964   AS_HELP_STRING([--enable-login-chown-vcs], [let login chown /dev/vcsN]),
1965   [], [enable_login_chown_vcs=no]
1966 )
1967
1968 AS_IF([test "x$enable_login_chown_vcs" = xyes], [
1969   AC_DEFINE([LOGIN_CHOWN_VCS], [1], [Should login chown /dev/vcsN?])
1970 ])
1971
1972 AC_ARG_ENABLE([login-stat-mail],
1973   AS_HELP_STRING([--enable-login-stat-mail], [let login stat() the mailbox]),
1974   [], [enable_login_stat_mail=no]
1975 )
1976
1977 AS_IF([test "x$enable_login_stat_mail" = xyes], [
1978   AC_DEFINE([LOGIN_STAT_MAIL], [1], [Should login stat() the mailbox?])
1979 ])
1980
1981
1982 AC_ARG_ENABLE([nologin],
1983   AS_HELP_STRING([--disable-nologin], [do not build nologin]),
1984   [], [UL_DEFAULT_ENABLE([nologin], [yes])]
1985 )
1986 UL_BUILD_INIT([nologin])
1987 AM_CONDITIONAL([BUILD_NOLOGIN], [test "x$build_nologin" = xyes])
1988
1989
1990 AC_ARG_ENABLE([sulogin],
1991   AS_HELP_STRING([--disable-sulogin], [do not build sulogin]),
1992   [], [UL_DEFAULT_ENABLE([sulogin], [check])]
1993 )
1994 UL_BUILD_INIT([sulogin])
1995 UL_REQUIRES_HAVE([sulogin], [crypt], [crypt function])
1996 UL_REQUIRES_HAVE([sulogin], [shadow_h], [shadow.h header])
1997 AM_CONDITIONAL([BUILD_SULOGIN], [test "x$build_sulogin" = xyes])
1998
1999
2000 AC_ARG_ENABLE([su],
2001   AS_HELP_STRING([--disable-su], [do not build su]),
2002   [], [UL_DEFAULT_ENABLE([su], [check])]
2003 )
2004 UL_BUILD_INIT([su])
2005 UL_REQUIRES_HAVE([su], [security_pam_appl_h], [PAM header file])
2006 UL_REQUIRES_HAVE([su], [utmpx_h], [utmpx.h header])
2007 UL_REQUIRES_HAVE([su], [gnu_utmpx], [GNU utmpx functions])
2008 AM_CONDITIONAL([BUILD_SU], [test "x$build_su" = xyes])
2009
2010
2011 AC_ARG_ENABLE([runuser],
2012   AS_HELP_STRING([--disable-runuser], [do not build runuser]),
2013   [], [UL_DEFAULT_ENABLE([runuser], [check])]
2014 )
2015 UL_BUILD_INIT([runuser])
2016 UL_REQUIRES_HAVE([runuser], [security_pam_appl_h], [PAM header file])
2017 UL_REQUIRES_HAVE([runuser], [utmpx_h], [utmpx.h header])
2018 UL_REQUIRES_HAVE([runuser], [gnu_utmpx], [GNU utmpx functions])
2019 AM_CONDITIONAL([BUILD_RUNUSER], [test "x$build_runuser" = xyes])
2020
2021
2022 AC_ARG_ENABLE([ul],
2023   AS_HELP_STRING([--disable-ul], [do not build ul]),
2024   [], [UL_DEFAULT_ENABLE([ul], [check])]
2025 )
2026 UL_BUILD_INIT([ul])
2027 UL_REQUIRES_HAVE([ul], [ncursesw, ncurses], [ncursesw or ncurses libraries])
2028 AM_CONDITIONAL([BUILD_UL], [test "x$build_ul" = xyes])
2029
2030
2031 AC_ARG_ENABLE([more],
2032   AS_HELP_STRING([--disable-more], [do not build more]),
2033   [], [UL_DEFAULT_ENABLE([more], [check])]
2034 )
2035 UL_BUILD_INIT([more])
2036 UL_REQUIRES_HAVE([more], [ncursesw, ncurses], [ncursesw or ncurses libraries])
2037 AM_CONDITIONAL([BUILD_MORE], [test "x$build_more" = xyes])
2038
2039
2040 AC_ARG_ENABLE([pg],
2041   AS_HELP_STRING([--enable-pg], [build pg]),
2042   [], [UL_DEFAULT_ENABLE([pg], [no])]
2043 )
2044 UL_BUILD_INIT([pg])
2045 UL_REQUIRES_HAVE([pg], [ncursesw, ncurses], [ncursesw or ncurses library])
2046 AM_CONDITIONAL([BUILD_PG], [test "x$build_pg" = xyes])
2047
2048
2049 AC_ARG_ENABLE([setterm],
2050   AS_HELP_STRING([--disable-setterm], [do not build setterm]),
2051   [], [UL_DEFAULT_ENABLE([setterm], [check])]
2052 )
2053 UL_BUILD_INIT([setterm])
2054 UL_REQUIRES_LINUX([setterm])
2055 UL_REQUIRES_HAVE([setterm], [ncursesw, ncurses], [ncursesw or ncurses library])
2056 AM_CONDITIONAL([BUILD_SETTERM], [test "x$build_setterm" = xyes])
2057
2058 # build_schedutils= is just configure-only variable to control
2059 # ionice, taskset and chrt
2060 AC_ARG_ENABLE([schedutils],
2061   AS_HELP_STRING([--disable-schedutils], [do not build chrt, ionice, taskset]),
2062   [], [UL_DEFAULT_ENABLE([schedutils], [check])]
2063 )
2064
2065
2066 UL_ENABLE_ALIAS([ionice], [schedutils])
2067 UL_BUILD_INIT([ionice])
2068 UL_REQUIRES_SYSCALL_CHECK([ionice],
2069         [UL_CHECK_SYSCALL([ioprio_set],
2070           [alpha],      [442],
2071           [i*86],       [289],
2072           [ia64*],      [1274],
2073           [powerpc*],   [273],
2074           [s390*],      [282],
2075           [sparc*],     [196],
2076           [sh*],        [288],
2077           [x86_64*],    [251])],
2078         [ioprio_set])
2079
2080 UL_REQUIRES_SYSCALL_CHECK([ionice],
2081         [UL_CHECK_SYSCALL([ioprio_get],
2082           [alpha],      [443],
2083           [i*86],       [290],
2084           [ia64*],      [1275],
2085           [powerpc*],   [274],
2086           [s390*],      [283],
2087           [sparc*],     [218],
2088           [sh*],        [289],
2089           [x86_64*],    [252])],
2090         [ioprio_get])
2091
2092 AM_CONDITIONAL([BUILD_IONICE], [test "x$build_ionice" = xyes])
2093
2094
2095 UL_ENABLE_ALIAS([taskset], [schedutils])
2096 UL_BUILD_INIT([taskset])
2097 UL_REQUIRES_HAVE([taskset], [cpu_set_t], [cpu_set_t type])
2098 UL_REQUIRES_SYSCALL_CHECK([taskset],
2099         [UL_CHECK_SYSCALL([sched_getaffinity])],
2100         [sched_getaffinity])
2101 AM_CONDITIONAL([BUILD_TASKSET], [test "x$build_taskset" = xyes])
2102
2103
2104 have_schedsetter=no
2105 AS_IF([test "x$ac_cv_func_sched_setscheduler" = xyes], [have_schedsetter=yes],
2106       [test "x$ac_cv_func_sched_setattr" = xyes], [have_schedsetter=yes])
2107
2108 UL_ENABLE_ALIAS([chrt], [schedutils])
2109 UL_BUILD_INIT([chrt])
2110 UL_REQUIRES_HAVE([chrt], [schedsetter], [sched_set functions])
2111 AM_CONDITIONAL([BUILD_CHRT], [test "x$build_chrt" = xyes])
2112
2113 AS_IF([test "x$build_chrt" = xyes], [
2114         UL_CHECK_SYSCALL([sched_setattr])
2115 ])
2116
2117
2118 AC_ARG_ENABLE([wall],
2119   AS_HELP_STRING([--disable-wall], [do not build wall]),
2120   [], [UL_DEFAULT_ENABLE([wall], [check])]
2121 )
2122 UL_BUILD_INIT([wall])
2123 UL_REQUIRES_HAVE([wall], [utmpx_h], [utmpx.h header])
2124 AM_CONDITIONAL([BUILD_WALL], [test "x$build_wall" = xyes])
2125
2126
2127 AC_ARG_ENABLE([write],
2128   AS_HELP_STRING([--enable-write], [build write]),
2129   [], [UL_DEFAULT_ENABLE([write], [no])]
2130 )
2131 UL_BUILD_INIT([write])
2132 UL_REQUIRES_HAVE([write], [utmpx_h], [utmpx.h header])
2133 UL_REQUIRES_HAVE([write], [gnu_utmpx], [GNU utmpx functions])
2134 AM_CONDITIONAL([BUILD_WRITE], [test "x$build_write" = xyes])
2135
2136
2137 AC_ARG_WITH([btrfs],
2138   AS_HELP_STRING([--without-btrfs], [do not build with btrfs support]),
2139   [], [with_btrfs=check]
2140 )
2141 have_btrfs=no
2142 AS_IF([test "x$with_btrfs" != xno], [
2143   AS_CASE([$with_btrfs:$have_linux_btrfs_h],
2144     [yes:no],
2145     [AC_MSG_ERROR([btrfs selected but linux/btrfs.h not found])],
2146     [check:no],
2147        [AC_MSG_WARN([linux/btrfs.h not found, do not build with btrfs support])],
2148     [*:yes],
2149        [have_btrfs=yes
2150         AC_DEFINE([HAVE_BTRFS_SUPPORT], [1], [Define if btrfs stuff is available])]
2151   )
2152 ])
2153 AM_CONDITIONAL([HAVE_BTRFS], [test "x$have_btrfs" = xyes])
2154
2155
2156 AC_ARG_WITH([systemd],
2157   AS_HELP_STRING([--without-systemd], [do not build with systemd support]),
2158   [], [with_systemd=check]
2159 )
2160
2161 have_systemd=no
2162 AS_IF([test "x$with_systemd" != xno], [
2163   # new version -- all libsystemd-* libs merged into libsystemd
2164   PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [have_systemd=yes], [have_systemd=no])
2165   # old versions
2166   AS_IF([test "x$have_systemd" != "xyes"], [
2167     PKG_CHECK_MODULES([SYSTEMD_DAEMON], [libsystemd-daemon],
2168                       [have_systemd_daemon=yes], [have_systemd_daemon=no])
2169     PKG_CHECK_MODULES([SYSTEMD_JOURNAL], [libsystemd-journal],
2170                       [have_systemd_journal=yes], [have_systemd_journal=no])
2171     AS_IF([test "x$have_systemd_daemon" = "xyes" -a "x$have_systemd_journal" = "xyes" ],[
2172            have_systemd=yes])
2173   ])
2174   AS_CASE([$with_systemd:$have_systemd],
2175     [yes:no],
2176       [AC_MSG_ERROR([systemd expected but libsystemd not found])],
2177     [*:yes],
2178        AC_DEFINE([HAVE_LIBSYSTEMD], [1], [Define if libsystemd is available])
2179   )
2180 ])
2181 AM_CONDITIONAL([HAVE_SYSTEMD], [test "x$have_systemd" = xyes])
2182
2183
2184 AC_ARG_WITH([systemdsystemunitdir],
2185   AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [directory for systemd unit files (requires systemd support)]),
2186   [], [with_systemdsystemunitdir=check]
2187 )
2188 AS_IF([test "x$with_systemdsystemunitdir" = xcheck], [
2189   AS_IF([test "x$have_systemd" = xyes], [
2190     with_systemdsystemunitdir=`$PKG_CONFIG --variable=systemdsystemunitdir systemd`
2191   ],[
2192     with_systemdsystemunitdir=no
2193   ])
2194 ])
2195 AS_IF([test "x$with_systemdsystemunitdir" != "xno"], [
2196   AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
2197 ])
2198
2199
2200 AC_ARG_WITH([smack],
2201   AS_HELP_STRING([--with-smack], [build with SMACK support]),
2202   [], [with_smack=no]
2203 )
2204 AS_IF([test "x$with_smack" = xyes], [
2205   AC_DEFINE([HAVE_SMACK], [1], [Add SMACK support])
2206 ])
2207
2208
2209 AC_ARG_WITH([bashcompletiondir],
2210   AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
2211   [],
2212   [AS_IF([`$PKG_CONFIG --exists bash-completion`], [
2213     with_bashcompletiondir=`$PKG_CONFIG --variable=completionsdir bash-completion`
2214   ], [
2215     with_bashcompletiondir=${datadir}/bash-completion/completions
2216   ])
2217 ])
2218 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
2219
2220 AC_ARG_ENABLE([bash-completion],
2221   AS_HELP_STRING([--disable-bash-completion], [do not install bash completion files]),
2222   [], [enable_bash_completion=yes]
2223 )
2224
2225 AM_CONDITIONAL([BUILD_BASH_COMPLETION], [test "x$enable_bash_completion" = xyes])
2226
2227
2228 AC_ARG_WITH([python],
2229   AS_HELP_STRING([--without-python], [do not build python bindings, use --with-python={2,3} to force version]),
2230   [], [with_python=check withval=check]
2231 )
2232
2233 have_python=no
2234 have_libpython=no
2235 AS_IF([test "x$with_python" != xno], [
2236   # We follow distributions default and look for PKG module name "python"
2237   # (minimal version is 2) but if major version is explicitly specified by
2238   # --with-python=2 or --with-python=3 then we look for PKG module "python2" or
2239   # "python3".
2240   AS_IF([test "x$withval" != xno -a "x$withval" != xyes -a "x$withval" != xcheck],
2241         [pymajor="$withval"; PYTHON=python${pymajor}], [pymajor="2"])
2242
2243   # check for python interpreter
2244   AM_PATH_PYTHON([$pymajor], [have_python=yes], [have_python=no])
2245   AS_CASE([$with_python:$have_python],
2246     [yes:no],
2247       [AC_MSG_ERROR([python selected but python interpreter not found])],
2248     [check:no],
2249        [AC_MSG_WARN([python interpreter not found, do not build python bindings])],
2250     [*:yes],
2251        # check for python development stuff
2252        [PKG_CHECK_MODULES([PYTHON], [python-$PYTHON_VERSION],
2253                           [have_libpython=yes], [have_libpython=no])]
2254   )
2255 ])
2256
2257
2258 AC_ARG_ENABLE([pylibmount],
2259   AS_HELP_STRING([--disable-pylibmount], [do not build pylibmount]),
2260   [], [UL_DEFAULT_ENABLE([pylibmount], [check])]
2261 )
2262 UL_BUILD_INIT([pylibmount])
2263 UL_REQUIRES_HAVE([pylibmount], [libpython], [libpython])
2264 UL_REQUIRES_BUILD([pylibmount], [libmount])
2265 AM_CONDITIONAL([BUILD_PYLIBMOUNT], [test "x$build_pylibmount" = "xyes"])
2266
2267 # We need to introduce a verbatim dependency into the Makefile, without automake
2268 # trying to interpret it, so push it as a AM_SUBST_NOTMAKE variable.
2269 verbatim_pylibmount_dependency='
2270
2271 # pylibmountexec module must be installed after usrlib_exec libraries,
2272 # otherwise the libtool relink step will fail to find libmount.la and
2273 # will try -lmount which is possibly not available.
2274 install-pylibmountexecLTLIBRARIES: install-usrlib_execLTLIBRARIES
2275
2276 '
2277 AC_SUBST([verbatim_pylibmount_dependency])
2278 AM_SUBST_NOTMAKE([verbatim_pylibmount_dependency])
2279
2280 AC_ARG_ENABLE([pg-bell],
2281   AS_HELP_STRING([--disable-pg-bell], [let pg not ring the bell on invalid keys]),
2282   [], [enable_pg_bell=yes]
2283 )
2284
2285 AS_IF([test "x$enable_pg_bell" = xyes], [
2286   AC_DEFINE([PG_BELL], [1], [Should pg ring the bell on invalid keys?])
2287 ])
2288
2289
2290 AC_DEFUN([FS_PATHS_DEFAULT], [/sbin:/sbin/fs.d:/sbin/fs])
2291 AC_ARG_ENABLE([fs-paths-default],
2292   AS_HELP_STRING([--enable-fs-paths-default=paths], [default search path for fs helpers @<:@FS_PATHS_DEFAULT@:>@]),
2293   [AS_CASE([$enableval],
2294     [yes], [fs_paths_defaults="FS_PATHS_DEFAULT"],
2295     [no],  [fs_paths_defaults=""],
2296     [fs_paths_defaults="$enableval"]
2297   )],
2298   [fs_paths_defaults="FS_PATHS_DEFAULT"]
2299 )
2300 AC_ARG_ENABLE([fs-paths-extra],
2301   AS_HELP_STRING([--enable-fs-paths-extra=paths], [additional search paths for fs helpers]),
2302   [AS_CASE([$enableval],
2303      [yes|no], [fs_paths_extra=""],
2304      [fs_paths_extra="$enableval"]
2305   )],
2306   [fs_paths_extra=""]
2307 )
2308 fs_paths="$fs_paths_defaults"
2309 AS_IF([test "x$fs_paths_extra" != "x"], [
2310   AS_IF([test "x$fs_paths" != "x"], [
2311     fs_paths="${fs_paths}:"
2312   ])
2313   fs_paths="${fs_paths}${fs_paths_extra}"
2314 ])
2315 AC_DEFINE_UNQUOTED([FS_SEARCH_PATH], "$fs_paths", [search path for fs helpers])
2316
2317
2318 AC_ARG_ENABLE([use-tty-group],
2319   AS_HELP_STRING([--disable-use-tty-group], [do not install wall and write setgid tty]),
2320   [], [enable_use_tty_group=yes]
2321 )
2322 AM_CONDITIONAL([USE_TTY_GROUP], [test "x$enable_use_tty_group" = xyes])
2323
2324 AS_IF([test "x$enable_use_tty_group" = xyes], [
2325   AC_DEFINE([USE_TTY_GROUP], [1], [Should wall and write be installed setgid tty?])
2326 ])
2327
2328
2329 AC_ARG_ENABLE([sulogin-emergency-mount],
2330   AS_HELP_STRING([--enable-sulogin-emergency-mount],
2331                  [use emergency mount of /dev and /proc for sulogin]),
2332   [], [enable_sulogin_emergency_mount=no]
2333 )
2334
2335 AS_IF([test "x$enable_sulogin_emergency_mount" = xyes], [
2336   AC_DEFINE([USE_SULOGIN_EMERGENCY_MOUNT], [1],
2337             [Should sulogin use a emergency mount of /dev and /proc?])
2338 ])
2339
2340
2341 AC_ARG_ENABLE([usrdir-path],
2342   AS_HELP_STRING([--enable-usrdir-path], [use only /usr paths in PATH env. variable (recommended on systems with /bin -> /usr/bin symlinks)]),
2343   [], [enable_usrdir_path=no]
2344 )
2345
2346 AS_IF([test "x$enable_usrdir_path" = xyes], [
2347   AC_DEFINE([USE_USRDIR_PATHS_ONLY], [1], [Define to 1 to remove /bin and /sbin from PATH env.variable])
2348 ])
2349
2350
2351 AC_ARG_ENABLE([makeinstall-chown],
2352   AS_HELP_STRING([--disable-makeinstall-chown], [do not do chown-like operations during "make install"]),
2353   [], [enable_makeinstall_chown=yes]
2354 )
2355 AM_CONDITIONAL([MAKEINSTALL_DO_CHOWN], [test "x$enable_makeinstall_chown" = xyes])
2356
2357
2358 AC_ARG_ENABLE([makeinstall-setuid],
2359   AS_HELP_STRING([--disable-makeinstall-setuid], [do not do setuid chmod operations during "make install"]),
2360   [], [enable_makeinstall_setuid=yes]
2361 )
2362 AM_CONDITIONAL([MAKEINSTALL_DO_SETUID], [test "x$enable_makeinstall_setuid" = xyes])
2363
2364
2365 AC_ARG_ENABLE([colors-default],
2366   AS_HELP_STRING([--disable-colors-default], [do not colorize output from utils by default]),
2367   [], [enable_colors_default=yes]
2368 )
2369 AS_IF([test "x$enable_colors_default" = xyes], [
2370   AC_DEFINE([USE_COLORS_BY_DEFAULT], [1], [Enables colorized output from utils by default])
2371 ])
2372
2373
2374 AC_ARG_VAR([SUID_CFLAGS],
2375            [CFLAGS used for binaries which are usually with the suid bit])
2376 AC_ARG_VAR([SUID_LDFLAGS],
2377            [LDFLAGS used for binaries which are usually with the suid bit])
2378
2379 AC_ARG_VAR([DAEMON_CFLAGS],
2380            [CFLAGS used for binaries which are usually executed as daemons])
2381 AC_ARG_VAR([DAEMON_LDFLAGS],
2382            [LDFLAGS used for binaries which are usually executed as daemons])
2383
2384 AC_ARG_VAR([SOLIB_CFLAGS],
2385            [CFLAGS used for shared libraries])
2386 AC_ARG_VAR([SOLIB_LDFLAGS],
2387            [LDFLAGS used for shared libraries])
2388
2389 AC_ARG_VAR([ADJTIME_PATH],
2390            [Path to hwclock adjtime file, default /etc/adjtime])
2391 AS_IF([test "x$ADJTIME_PATH" = x], [ADJTIME_PATH="/etc/adjtime"])
2392 AC_DEFINE_UNQUOTED([CONFIG_ADJTIME_PATH], "$ADJTIME_PATH", [Path to hwclock adjtime file])
2393
2394
2395 LIBS=""
2396
2397
2398 AC_CONFIG_HEADERS([config.h])
2399
2400 #
2401 # Don't use configure.ac to replace install paths! See Makefile PATHFILES for
2402 # more details.
2403 #
2404 AC_CONFIG_FILES([
2405 Makefile
2406 libblkid/docs/Makefile
2407 libblkid/docs/version.xml
2408 libblkid/src/blkid.h
2409 libfdisk/docs/Makefile
2410 libfdisk/docs/version.xml
2411 libfdisk/src/libfdisk.h
2412 libmount/docs/Makefile
2413 libmount/docs/version.xml
2414 libmount/src/libmount.h
2415 libsmartcols/docs/Makefile
2416 libsmartcols/docs/version.xml
2417 libsmartcols/src/libsmartcols.h
2418 po/Makefile.in
2419 ])
2420
2421 AC_OUTPUT
2422
2423 AC_MSG_RESULT([
2424         ${PACKAGE}  ${VERSION}
2425
2426         prefix:            ${prefix}
2427         exec prefix:       ${exec_prefix}
2428
2429         runstatedir:       ${runstatedir}
2430         bindir:            ${bindir}
2431         sbindir:           ${sbindir}
2432         libdir:            ${libdir}
2433         includedir:        ${includedir}
2434         usrbin_execdir:    ${usrbin_execdir}
2435         usrsbin_execdir:   ${usrsbin_execdir}
2436         usrlib_execdir:    ${usrlib_execdir}
2437
2438         compiler:          ${CC}
2439         cflags:            ${CFLAGS}
2440         suid cflags:       ${SUID_CFLAGS}
2441         ldflags:           ${LDFLAGS}
2442         suid ldflags:      ${SUID_LDFLAGS}
2443
2444         Python:            ${PYTHON}
2445         Python version:    ${PYTHON_VERSION}
2446         Python libs:       ${pyexecdir}
2447
2448         Bash completions:  ${with_bashcompletiondir}
2449         Systemd support:   ${have_systemd}
2450         Systemd unitdir:   ${with_systemdsystemunitdir}
2451         Btrfs support:     ${have_btrfs}
2452         Wide-char support: ${build_widechar}
2453
2454         warnings:
2455
2456 ${WARN_CFLAGS}
2457
2458         Type 'make' or 'make <utilname>' to compile.
2459 ])